qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void menu_show_error()
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 }
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void menu_sub_null()
  37 {
  38 }
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         registercmd("hud_configure");
  87         registercmd("hud_save");
  88         //registercmd("menu_action");
  89
  90         registercmd("+showscores");registercmd("-showscores");
  91         registercmd("+showaccuracy");registercmd("-showaccuracy");
  92
  93 #ifndef CAMERATEST
  94         if(isdemo())
  95         {
  96 #endif
  97                 registercmd("+forward");registercmd("-forward");
  98                 registercmd("+back");registercmd("-back");
  99                 registercmd("+moveup");registercmd("-moveup");
 100                 registercmd("+movedown");registercmd("-movedown");
 101                 registercmd("+moveright");registercmd("-moveright");
 102                 registercmd("+moveleft");registercmd("-moveleft");
 103                 registercmd("+roll_right");registercmd("-roll_right");
 104                 registercmd("+roll_left");registercmd("-roll_left");
 105 #ifndef CAMERATEST
 106         }
 107 #endif
 108         registercvar("hud_usecsqc", "1");
 109         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 110
 111         gametype = 0;
 112
 113         // hud_fields uses strunzone on the titles!
 114         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 115                 hud_title[i] = strzone("(null)");
 116
 117         postinit = false;
 118
 119         calledhooks = 0;
 120
 121         teams = Sort_Spawn();
 122         players = Sort_Spawn();
 123
 124         GetTeam(COLOR_SPECTATOR, true); // add specs first
 125
 126         RegisterWeapons();
 127
 128         WaypointSprite_Load();
 129
 130         // precaches
 131         precache_sound("misc/hit.wav");
 132         precache_sound("misc/typehit.wav");
 133         Projectile_Precache();
 134         Hook_Precache();
 135         GibSplash_Precache();
 136         Casings_Precache();
 137         DamageInfo_Precache();
 138         Vehicles_Precache();
 139         turrets_precache();
 140
 141         if(autocvar_cl_announcer != cl_announcer_prev) {
 142                 Announcer_Precache();
 143                 if(cl_announcer_prev)
 144                         strunzone(cl_announcer_prev);
 145                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 146         }
 147         Tuba_Precache();
 148
 149         if(autocvar_cl_reticle)
 150         {
 151                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 152                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 153         }
 154
 155         get_mi_min_max_texcoords(1); // try the CLEVER way first
 156         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 157         shortmapname = mi_shortname;
 158
 159         if(precache_pic(minimapname) == "")
 160         {
 161                 // but maybe we have a non-clever minimap
 162                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 163                 if(precache_pic(minimapname) == "")
 164                         minimapname = ""; // FAIL
 165                 else
 166                         get_mi_min_max_texcoords(0); // load new texcoords
 167         }
 168
 169         mi_center = (mi_min + mi_max) * 0.5;
 170         mi_scale = mi_max - mi_min;
 171         minimapname = strzone(minimapname);
 172
 173         WarpZone_Init();
 174
 175         hud_configure_prev = -1;
 176         tab_panel = -1;
 177 }
 178
 179 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 180 void CSQC_Shutdown(void)
 181 {
 182 #ifdef USE_FTE
 183 #pragma TARGET id
 184         if(!__engine_check)
 185                 return 0;
 186 #pragma TARGET fte
 187 #endif
 188
 189         WarpZone_Shutdown();
 190
 191         remove(teams);
 192         remove(players);
 193         db_close(binddb);
 194         db_close(tempdb);
 195         if(autocvar_cl_db_saveasdump)
 196                 db_dump(ClientProgsDB, "client.db");
 197         else
 198                 db_save(ClientProgsDB, "client.db");
 199         db_close(ClientProgsDB);
 200
 201         cvar_clientsettemp_restore();
 202
 203         if(camera_active)
 204                 cvar_set("chase_active",ftos(chase_active_backup));
 205
 206         // unset the event chasecam's chase_active
 207         if(autocvar_chase_active < 0)
 208                 cvar_set("chase_active", "0");
 209
 210         if not(isdemo())
 211         {
 212                 if not(calledhooks & HOOK_START)
 213                         localcmd("\n_cl_hook_gamestart nop\n");
 214                 if not(calledhooks & HOOK_END)
 215                         localcmd("\ncl_hook_gameend\n");
 216         }
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, float Team)
 221 {
 222         entity tm;
 223         if(teamplay)
 224         {
 225                 switch(Team)
 226                 {
 227                         case -1:
 228                         case COLOR_TEAM1:
 229                         case COLOR_TEAM2:
 230                         case COLOR_TEAM3:
 231                         case COLOR_TEAM4:
 232                                 break;
 233                         default:
 234                                 if(GetTeam(Team, false) == NULL)
 235                                 {
 236                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 237                                         Team = COLOR_SPECTATOR;
 238                                 }
 239                                 break;
 240                 }
 241         }
 242         else
 243         {
 244                 switch(Team)
 245                 {
 246                         case -1:
 247                         case 0:
 248                                 break;
 249                         default:
 250                                 if(GetTeam(Team, false) == NULL)
 251                                 {
 252                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 253                                         Team = COLOR_SPECTATOR;
 254                                 }
 255                                 break;
 256                 }
 257         }
 258         if(Team == -1) // leave
 259         {
 260                 if(o.has_team)
 261                 {
 262                         tm = GetTeam(o.team, false);
 263                         tm.team_size -= 1;
 264                         o.has_team = 0;
 265                         return TRUE;
 266                 }
 267         }
 268         else
 269         {
 270                 if not(o.has_team)
 271                 {
 272                         o.team = Team;
 273                         tm = GetTeam(Team, true);
 274                         tm.team_size += 1;
 275                         o.has_team = 1;
 276                         return TRUE;
 277                 }
 278                 else if(Team != o.team)
 279                 {
 280                         tm = GetTeam(o.team, false);
 281                         tm.team_size -= 1;
 282                         o.team = Team;
 283                         tm = GetTeam(Team, true);
 284                         tm.team_size += 1;
 285                         return TRUE;
 286                 }
 287         }
 288         return FALSE;
 289 }
 290
 291 void Playerchecker_Think()
 292 {
 293         float i;
 294         entity e;
 295         for(i = 0; i < maxclients; ++i)
 296         {
 297                 e = playerslots[i];
 298                 if(GetPlayerName(i) == "")
 299                 {
 300                         if(e.sort_prev)
 301                         {
 302                                 // player disconnected
 303                                 SetTeam(e, -1);
 304                                 RemovePlayer(e);
 305                                 e.sort_prev = world;
 306                                 //e.gotscores = 0;
 307                         }
 308                 }
 309                 else
 310                 {
 311                         if not(e.sort_prev)
 312                         {
 313                                 // player connected
 314                                 if not(e)
 315                                         playerslots[i] = e = spawn();
 316                                 e.sv_entnum = i;
 317                                 e.ping = 0;
 318                                 e.ping_packetloss = 0;
 319                                 e.ping_movementloss = 0;
 320                                 //e.gotscores = 0; // we might already have the scores...
 321                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 322                                 RegisterPlayer(e);
 323                                 HUD_UpdatePlayerPos(e);
 324                         }
 325                 }
 326         }
 327         self.nextthink = time + 0.2;
 328 }
 329
 330 void Porto_Init();
 331 void TrueAim_Init();
 332 void PostInit(void)
 333 {
 334         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 335
 336         entity playerchecker;
 337         playerchecker = spawn();
 338         playerchecker.think = Playerchecker_Think;
 339         playerchecker.nextthink = time + 0.2;
 340
 341         Porto_Init();
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 348 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 349 float button_zoom;
 350 void Cmd_HUD_SetFields(float);
 351 void Cmd_HUD_Help(float);
 352 float CSQC_ConsoleCommand(string strMessage)
 353 {
 354         float argc;
 355         // Tokenize String
 356         argc = tokenize_console(strMessage);
 357
 358         // Acquire Command
 359         string strCmd;
 360         strCmd = argv(0);
 361
 362         if(strCmd == "hud_configure") { // config hud
 363                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 364                 return true;
 365         } else if(strCmd == "hud_save") { // save hud config
 366                 if(argv(1) == "" || argv(2)) {
 367                         print(_("Usage:\n"));
 368                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 369                 }
 370                 else
 371                         HUD_Panel_ExportCfg(argv(1));
 372                 return true;
 373         } else if(strCmd == "+showscores") {
 374                 scoreboard_showscores = true;
 375                 return true;
 376         } else if(strCmd == "-showscores") {
 377                 scoreboard_showscores = false;
 378                 return true;
 379         } else if(strCmd == "+showaccuracy") {
 380                 scoreboard_showaccuracy = true;
 381                 return true;
 382         } else if(strCmd == "-showaccuracy") {
 383                 scoreboard_showaccuracy = false;
 384                 return true;
 385         }
 386
 387         if(camera_active)
 388         if(strCmd == "+forward" || strCmd == "-back") {
 389                 ++camera_direction_x;
 390                 return true;
 391         } else if(strCmd == "-forward" || strCmd == "+back") {
 392                 --camera_direction_x;
 393                 return true;
 394         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 395                 --camera_direction_y;
 396                 return true;
 397         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 398                 ++camera_direction_y;
 399                 return true;
 400         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 401                 ++camera_direction_z;
 402                 return true;
 403         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 404                 --camera_direction_z;
 405                 return true;
 406         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 407                 ++camera_roll;
 408                 return true;
 409         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 410                 --camera_roll;
 411                 return true;
 412         }
 413
 414         return false;
 415 }
 416
 417 .vector view_ofs;
 418 entity debug_shotorg;
 419 void ShotOrg_Draw()
 420 {
 421         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 422         self.angles = view_angles;
 423         self.angles_x = -self.angles_x;
 424         if not(self.cnt)
 425                 self.drawmask = MASK_NORMAL;
 426         else
 427                 self.drawmask = 0;
 428 }
 429 void ShotOrg_Draw2D()
 430 {
 431         vector coord2d_topleft, coord2d_topright, coord2d;
 432         string s;
 433         vector fs;
 434
 435         s = vtos(self.view_ofs);
 436         s = substring(s, 1, strlen(s) - 2);
 437         if(tokenize_console(s) == 3)
 438                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 439
 440         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 441         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 442
 443         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 444
 445         coord2d = coord2d_topleft;
 446         if(fs_x < 8)
 447         {
 448                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 449                 fs = '8 8 0';
 450         }
 451         coord2d_y -= fs_y;
 452         coord2d_z = 0;
 453         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 454 }
 455
 456 void ShotOrg_Spawn()
 457 {
 458         debug_shotorg = spawn();
 459         debug_shotorg.draw = ShotOrg_Draw;
 460         debug_shotorg.draw2d = ShotOrg_Draw2D;
 461         debug_shotorg.renderflags = RF_VIEWMODEL;
 462         debug_shotorg.effects = EF_FULLBRIGHT;
 463         precache_model("models/shotorg_adjuster.md3");
 464         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 465         debug_shotorg.scale = 2;
 466         debug_shotorg.view_ofs = '25 8 -8';
 467 }
 468
 469 void DrawDebugModel()
 470 {
 471         if(time - floor(time) > 0.5)
 472         {
 473                 PolyDrawModel(self);
 474                 self.drawmask = 0;
 475         }
 476         else
 477         {
 478                 self.renderflags = 0;
 479                 self.drawmask = MASK_NORMAL;
 480         }
 481 }
 482
 483 void GameCommand(string msg)
 484 {
 485         string s;
 486         float argc;
 487         entity e;
 488         argc = tokenize_console(msg);
 489
 490         if(argv(0) == "help" || argc == 0)
 491         {
 492                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 493                 print(_("  settemp cvar value\n"));
 494                 print(_("  scoreboard_columns_set ...\n"));
 495                 print(_("  scoreboard_columns_help\n"));
 496                 GameCommand_Generic("help");
 497                 return;
 498         }
 499
 500         if(GameCommand_Generic(msg))
 501                 return;
 502
 503         string cmd;
 504         cmd = argv(0);
 505         if(cmd == "mv_download") {
 506                 Cmd_MapVote_MapDownload(argc);
 507         }
 508         else if(cmd == "hud_panel_radar_maximized")
 509         {
 510                 if(argc == 1)
 511                         hud_panel_radar_maximized = !hud_panel_radar_maximized;
 512                 else
 513                         hud_panel_radar_maximized = (stof(argv(1)) != 0);
 514         }
 515         else if(cmd == "settemp") {
 516                 cvar_clientsettemp(argv(1), argv(2));
 517         }
 518         else if(cmd == "scoreboard_columns_set") {
 519                 Cmd_HUD_SetFields(argc);
 520         }
 521         else if(cmd == "scoreboard_columns_help") {
 522                 Cmd_HUD_Help(argc);
 523         }
 524 #ifdef BLURTEST
 525         else if(cmd == "blurtest") {
 526                 blurtest_time0 = time;
 527                 blurtest_time1 = time + stof(argv(1));
 528                 blurtest_radius = stof(argv(2));
 529                 blurtest_power = stof(argv(3));
 530         }
 531 #endif
 532         else if(cmd == "shotorg_move") {
 533                 if(!debug_shotorg)
 534                         ShotOrg_Spawn();
 535                 else
 536                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 537                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 538         }
 539         else if(cmd == "shotorg_movez") {
 540                 if(!debug_shotorg)
 541                         ShotOrg_Spawn();
 542                 else
 543                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 544                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 545         }
 546         else if(cmd == "shotorg_set") {
 547                 if(!debug_shotorg)
 548                         ShotOrg_Spawn();
 549                 else
 550                         debug_shotorg.view_ofs = stov(argv(1));
 551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 552         }
 553         else if(cmd == "shotorg_setz") {
 554                 if(!debug_shotorg)
 555                         ShotOrg_Spawn();
 556                 else
 557                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 558                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 559         }
 560         else if(cmd == "shotorg_toggle_hide") {
 561                 if(debug_shotorg)
 562                 {
 563                         debug_shotorg.cnt = !debug_shotorg.cnt;
 564                 }
 565         }
 566         else if(cmd == "shotorg_end") {
 567                 if(debug_shotorg)
 568                 {
 569                         print(vtos(debug_shotorg.view_ofs), "\n");
 570                         remove(debug_shotorg);
 571                         debug_shotorg = world;
 572                 }
 573                 localcmd("sv_cmd debug_shotorg\n");
 574         }
 575         else if(cmd == "sendcvar") {
 576                 // W_FixWeaponOrder will trash argv, so save what we need.
 577                 string thiscvar;
 578                 thiscvar = strzone(argv(1));
 579                 s = cvar_string(thiscvar);
 580                 if(thiscvar == "cl_weaponpriority")
 581                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 582                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 583                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 584                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 585                 strunzone(thiscvar);
 586         }
 587         else if(cmd == "spawn") {
 588                 s = argv(1);
 589                 e = spawn();
 590                 precache_model(s);
 591                 setmodel(e, s);
 592                 setorigin(e, view_origin);
 593                 e.angles = view_angles;
 594                 e.draw = DrawDebugModel;
 595                 e.classname = "debugmodel";
 596         }
 597     else if(cmd == "vyes")
 598     {
 599         if(uid2name_dialog)
 600         {
 601             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 602             vote_prev = 0;
 603             localcmd("setreport cl_allow_uid2name 1\n");
 604             vote_change = -9999;
 605                         uid2name_dialog = 0;
 606         }
 607         else
 608         {
 609             localcmd("cmd vote yes\n");
 610         }
 611     }
 612     else if(cmd == "vno")
 613     {
 614         if(uid2name_dialog)
 615         {
 616             vote_active = 0;
 617             vote_prev = 0;
 618             localcmd("setreport cl_allow_uid2name 0\n");
 619             vote_change = -9999;
 620                         uid2name_dialog = 0;
 621         }
 622         else
 623         {
 624             localcmd("cmd vote no\n");
 625         }
 626     }
 627
 628         else
 629         {
 630                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 631         }
 632
 633         return;
 634 }
 635
 636 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 637 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 638 // All keys are in ascii.
 639 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 640 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 641 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 642 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 643 {
 644         float bSkipKey;
 645         bSkipKey = false;
 646
 647         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 648                 return true;
 649
 650         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 651                 return true;
 652
 653         if(menu_visible)
 654                 if(menu_action(bInputType, nPrimary, nSecondary))
 655                         return TRUE;
 656
 657         return bSkipKey;
 658 }
 659
 660 // END REQUIRED CSQC FUNCTIONS
 661 // --------------------------------------------------------------------------
 662
 663 // --------------------------------------------------------------------------
 664 // BEGIN OPTIONAL CSQC FUNCTIONS
 665 void Ent_RemoveEntCS()
 666 {
 667         entcs_receiver[self.sv_entnum] = world;
 668 }
 669 void Ent_ReadEntCS()
 670 {
 671         float sf;
 672         InterpolateOrigin_Undo();
 673
 674         self.classname = "entcs_receiver";
 675         sf = ReadByte();
 676
 677         if(sf & 1)
 678                 self.sv_entnum = ReadByte();
 679         if(sf & 2)
 680         {
 681                 self.origin_x = ReadShort();
 682                 self.origin_y = ReadShort();
 683                 self.origin_z = ReadShort();
 684         }
 685         if(sf & 4)
 686         {
 687                 self.angles_y = ReadByte() * 360.0 / 256;
 688                 self.angles_x = self.angles_z = 0;
 689         }
 690         if(sf & 8)
 691                 self.healthvalue = ReadByte() * 10;
 692         if(sf & 16)
 693                 self.armorvalue = ReadByte() * 10;
 694
 695         entcs_receiver[self.sv_entnum] = self;
 696         self.entremove = Ent_RemoveEntCS;
 697
 698         InterpolateOrigin_Note();
 699 }
 700
 701 void Ent_Remove();
 702
 703 void Ent_RemovePlayerScore()
 704 {
 705         float i;
 706
 707         if(self.owner)
 708         {
 709                 SetTeam(self.owner, -1);
 710                 self.owner.gotscores = 0;
 711                 for(i = 0; i < MAX_SCORE; ++i)
 712                         self.owner.(scores[i]) = 0; // clear all scores
 713         }
 714 }
 715
 716 void Ent_ReadPlayerScore()
 717 {
 718         float i, n;
 719         float isNew;
 720         entity o;
 721
 722         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 723         // (no I've never heard of M-x replace-string, sed, or anything like that)
 724         isNew = !self.owner; // workaround for DP bug
 725         n = ReadByte()-1;
 726
 727 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 728         if(!isNew && n != self.sv_entnum)
 729         {
 730                 //print(_("A CSQC entity changed its owner!\n"));
 731                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 732                 isNew = true;
 733                 Ent_Remove();
 734                 self.enttype = ENT_CLIENT_SCORES;
 735         }
 736 #endif
 737
 738         self.sv_entnum = n;
 739
 740         if not(playerslots[self.sv_entnum])
 741                 playerslots[self.sv_entnum] = spawn();
 742         o = self.owner = playerslots[self.sv_entnum];
 743         o.sv_entnum = self.sv_entnum;
 744         o.gotscores = 1;
 745
 746         //if not(o.sort_prev)
 747         //      RegisterPlayer(o);
 748         //playerchecker will do this for us later, if it has not already done so
 749
 750         float sf, lf;
 751 #if MAX_SCORE <= 8
 752         sf = ReadByte();
 753         lf = ReadByte();
 754 #else
 755         sf = ReadShort();
 756         lf = ReadShort();
 757 #endif
 758         float p;
 759         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 760                 if(sf & p)
 761                 {
 762                         if(lf & p)
 763                                 o.(scores[i]) = ReadInt24_t();
 764                         else
 765                                 o.(scores[i]) = ReadChar();
 766                 }
 767
 768         if(o.sort_prev)
 769                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 770
 771         self.entremove = Ent_RemovePlayerScore;
 772 }
 773
 774 void Ent_ReadTeamScore()
 775 {
 776         float i;
 777         entity o;
 778
 779         self.team = ReadByte();
 780         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 781
 782         float sf, lf;
 783 #if MAX_TEAMSCORE <= 8
 784         sf = ReadByte();
 785         lf = ReadByte();
 786 #else
 787         sf = ReadShort();
 788         lf = ReadShort();
 789 #endif
 790         float p;
 791         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 792                 if(sf & p)
 793                 {
 794                         if(lf & p)
 795                                 o.(teamscores[i]) = ReadInt24_t();
 796                         else
 797                                 o.(teamscores[i]) = ReadChar();
 798                 }
 799
 800         HUD_UpdateTeamPos(o);
 801 }
 802
 803 void Ent_ClientData()
 804 {
 805         float f;
 806         float newspectatee_status;
 807
 808         f = ReadByte();
 809
 810         scoreboard_showscores_force = (f & 1);
 811
 812         if(f & 2)
 813         {
 814                 newspectatee_status = ReadByte();
 815                 if(newspectatee_status == player_localentnum)
 816                         newspectatee_status = -1; // observing
 817         }
 818         else
 819                 newspectatee_status = 0;
 820
 821         spectatorbutton_zoom = (f & 4);
 822
 823         if(f & 8)
 824         {
 825                 angles_held_status = 1;
 826                 angles_held_x = ReadAngle();
 827                 angles_held_y = ReadAngle();
 828                 angles_held_z = 0;
 829         }
 830         else
 831                 angles_held_status = 0;
 832
 833         if(newspectatee_status != spectatee_status)
 834         {
 835                 // clear race stuff
 836                 race_laptime = 0;
 837                 race_checkpointtime = 0;
 838         }
 839         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 840         {
 841                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 842                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 843                 )
 844                         prev_p_health = -1;
 845                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 846                         prev_health = -1;
 847         }
 848         spectatee_status = newspectatee_status;
 849 }
 850
 851 void Ent_Nagger()
 852 {
 853         float nags, i, j, b, f;
 854
 855         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 856
 857         if(!(nags & 4))
 858         {
 859                 if(vote_called_vote)
 860                         strunzone(vote_called_vote);
 861                 vote_called_vote = string_null;
 862                 vote_active = 0;
 863         }
 864         else
 865         {
 866                 vote_active = 1;
 867         }
 868
 869         if(nags & 64)
 870         {
 871                 vote_yescount = ReadByte();
 872                 vote_nocount = ReadByte();
 873                 vote_needed = ReadByte();
 874                 vote_highlighted = ReadChar();
 875         }
 876
 877         if(nags & 128)
 878         {
 879                 if(vote_called_vote)
 880                         strunzone(vote_called_vote);
 881                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 882         }
 883
 884         if(nags & 1)
 885         {
 886                 for(j = 0; j < maxclients; ++j)
 887                         if(playerslots[j])
 888                                 playerslots[j].ready = 1;
 889                 for(i = 1; i <= maxclients; i += 8)
 890                 {
 891                         f = ReadByte();
 892                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 893                                 if not(f & b)
 894                                         if(playerslots[j])
 895                                                 playerslots[j].ready = 0;
 896                 }
 897         }
 898
 899         ready_waiting = (nags & 1);
 900         ready_waiting_for_me = (nags & 2);
 901         vote_waiting = (nags & 4);
 902         vote_waiting_for_me = (nags & 8);
 903         warmup_stage = (nags & 16);
 904 }
 905
 906 void Ent_RandomSeed()
 907 {
 908         float s;
 909         prandom_debug();
 910         s = ReadShort();
 911         psrandom(s);
 912 }
 913
 914 void Ent_ReadAccuracy(void)
 915 {
 916         float sf, f, w, b;
 917         sf = ReadInt24_t();
 918         if(sf == 0)
 919         {
 920                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 921                         weapon_accuracy[w] = -1;
 922                 return;
 923         }
 924
 925         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 926         {
 927                 if(sf & f)
 928                 {
 929                         b = ReadByte();
 930                         if(b == 0)
 931                                 weapon_accuracy[w] = -1;
 932                         else if(b == 255)
 933                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 934                         else
 935                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 936                 }
 937         }
 938 }
 939
 940 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 941 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 942 void Ent_RadarLink();
 943 void Ent_Init();
 944 void Ent_ScoresInfo();
 945 void CSQC_Ent_Update(float bIsNewEntity)
 946 {
 947         float t;
 948         float savetime;
 949         t = ReadByte();
 950
 951         // set up the "time" global for received entities to be correct for interpolation purposes
 952         savetime = time;
 953         if(servertime)
 954         {
 955                 time = servertime;
 956         }
 957         else
 958         {
 959                 serverprevtime = time;
 960                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 961                 time = serverprevtime + serverdeltatime;
 962         }
 963
 964 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 965         if(self.enttype)
 966                 if(t != self.enttype)
 967                 {
 968                         //print(_("A CSQC entity changed its type!\n"));
 969                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 970                         Ent_Remove();
 971                         bIsNewEntity = 1;
 972                 }
 973 #endif
 974         self.enttype = t;
 975         switch(t)
 976         {
 977                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 978                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 979                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 980                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 981                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 982                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 983                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 984                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 985                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 986                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 987                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 988                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 989                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 990                 case ENT_CLIENT_INIT: Ent_Init(); break;
 991                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 992                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 993                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 994                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 995                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 996                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 997                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 998                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 999                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1000                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
1001                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1002                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1003                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1004                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1005                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1006                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
1007                 case ENT_CLIENT_TURRET: ent_turret(); break;
1008                 default:
1009                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1010                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
1011                         break;
1012         }
1013
1014         time = savetime;
1015 }
1016 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1017 // used when an entity changes its type. For an entity that someone interacts
1018 // with others, make sure it can no longer do so.
1019 void Ent_Remove()
1020 {
1021         if(self.entremove)
1022                 self.entremove();
1023
1024         self.enttype = 0;
1025         self.classname = "";
1026         self.draw = menu_sub_null;
1027         self.entremove = menu_sub_null;
1028         // TODO possibly set more stuff to defaults
1029 }
1030 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1031 void CSQC_Ent_Remove()
1032 {
1033         if(self.enttype)
1034                 Ent_Remove();
1035         remove(self);
1036 }
1037
1038 void Gamemode_Init()
1039 {
1040         if not(isdemo())
1041         {
1042                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1043                 calledhooks |= HOOK_START;
1044         }
1045 }
1046 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1047 void CSQC_Parse_StuffCmd(string strMessage)
1048 {
1049         localcmd(strMessage);
1050 }
1051 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1052 void CSQC_Parse_Print(string strMessage)
1053 {
1054         print(ColorTranslateRGB(strMessage));
1055 }
1056
1057 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1058 void CSQC_Parse_CenterPrint(string strMessage)
1059 {
1060         centerprint(strMessage);
1061 }
1062
1063 string notranslate_fogcmd1 = "\nfog ";
1064 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1065 void Fog_Force()
1066 {
1067         // TODO somehow thwart prvm_globalset client ...
1068
1069         if(forcefog != "")
1070                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1071 }
1072
1073 void Gamemode_Init();
1074 void Ent_ScoresInfo()
1075 {
1076         float i;
1077         self.classname = "ent_client_scores_info";
1078         gametype = ReadByte();
1079         for(i = 0; i < MAX_SCORE; ++i)
1080         {
1081                 scores_label[i] = strzone(ReadString());
1082                 scores_flags[i] = ReadByte();
1083         }
1084         for(i = 0; i < MAX_TEAMSCORE; ++i)
1085         {
1086                 teamscores_label[i] = strzone(ReadString());
1087                 teamscores_flags[i] = ReadByte();
1088         }
1089         HUD_InitScores();
1090         Gamemode_Init();
1091 }
1092
1093 void Ent_Init()
1094 {
1095         self.classname = "ent_client_init";
1096
1097         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1098
1099         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1100         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1101         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1102         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1103         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1104         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1105         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1106         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1107         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1108         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1109         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1110         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1111
1112         if(forcefog)
1113                 strunzone(forcefog);
1114         forcefog = strzone(ReadString());
1115
1116         armorblockpercent = ReadByte() / 255.0;
1117
1118         g_weaponswitchdelay = ReadByte() / 255.0;
1119
1120         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1121         g_balance_grenadelauncher_bouncestop = ReadCoord();
1122         g_balance_electro_secondary_bouncefactor = ReadCoord();
1123         g_balance_electro_secondary_bouncestop = ReadCoord();
1124
1125         nex_scope = !ReadByte();
1126         rifle_scope = !ReadByte();
1127
1128         serverflags = ReadByte();
1129
1130         minelayer_maxmines = ReadByte();
1131
1132         hagar_maxrockets = ReadByte();
1133
1134         g_trueaim_minrange = ReadCoord();
1135
1136         if(!postinit)
1137                 PostInit();
1138 }
1139
1140 void Net_ReadRace()
1141 {
1142         float b;
1143
1144         b = ReadByte();
1145
1146         switch(b)
1147         {
1148                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1149                         race_checkpoint = ReadByte();
1150                         race_time = ReadInt24_t();
1151                         race_previousbesttime = ReadInt24_t();
1152                         if(race_previousbestname)
1153                                 strunzone(race_previousbestname);
1154                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1155
1156                         race_checkpointtime = time;
1157
1158                         if(race_checkpoint == 0 || race_checkpoint == 254)
1159                         {
1160                                 race_penaltyaccumulator = 0;
1161                                 race_laptime = time; // valid
1162                         }
1163
1164                         break;
1165
1166                 case RACE_NET_CHECKPOINT_CLEAR:
1167                         race_laptime = 0;
1168                         race_checkpointtime = 0;
1169                         break;
1170
1171                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1172                         race_laptime = ReadCoord();
1173                         race_checkpointtime = -99999;
1174                         // fall through
1175                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1176                         race_nextcheckpoint = ReadByte();
1177
1178                         race_nextbesttime = ReadInt24_t();
1179                         if(race_nextbestname)
1180                                 strunzone(race_nextbestname);
1181                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1182                         break;
1183
1184                 case RACE_NET_CHECKPOINT_HIT_RACE:
1185                         race_mycheckpoint = ReadByte();
1186                         race_mycheckpointtime = time;
1187                         race_mycheckpointdelta = ReadInt24_t();
1188                         race_mycheckpointlapsdelta = ReadByte();
1189                         if(race_mycheckpointlapsdelta >= 128)
1190                                 race_mycheckpointlapsdelta -= 256;
1191                         if(race_mycheckpointenemy)
1192                                 strunzone(race_mycheckpointenemy);
1193                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1194                         break;
1195
1196                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1197                         race_othercheckpoint = ReadByte();
1198                         race_othercheckpointtime = time;
1199                         race_othercheckpointdelta = ReadInt24_t();
1200                         race_othercheckpointlapsdelta = ReadByte();
1201                         if(race_othercheckpointlapsdelta >= 128)
1202                                 race_othercheckpointlapsdelta -= 256;
1203                         if(race_othercheckpointenemy)
1204                                 strunzone(race_othercheckpointenemy);
1205                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1206                         break;
1207
1208                 case RACE_NET_PENALTY_RACE:
1209                         race_penaltyeventtime = time;
1210                         race_penaltytime = ReadShort();
1211                         //race_penaltyaccumulator += race_penaltytime;
1212                         if(race_penaltyreason)
1213                                 strunzone(race_penaltyreason);
1214                         race_penaltyreason = strzone(ReadString());
1215                         break;
1216
1217                 case RACE_NET_PENALTY_QUALIFYING:
1218                         race_penaltyeventtime = time;
1219                         race_penaltytime = ReadShort();
1220                         race_penaltyaccumulator += race_penaltytime;
1221                         if(race_penaltyreason)
1222                                 strunzone(race_penaltyreason);
1223                         race_penaltyreason = strzone(ReadString());
1224                         break;
1225
1226                 case RACE_NET_SERVER_RECORD:
1227                         race_server_record = ReadInt24_t();
1228                         break;
1229                 case RACE_NET_SPEED_AWARD:
1230                         race_speedaward = ReadInt24_t();
1231                         if(race_speedaward_holder)
1232                                 strunzone(race_speedaward_holder);
1233                         race_speedaward_holder = strzone(ReadString());
1234                         break;
1235                 case RACE_NET_SPEED_AWARD_BEST:
1236                         race_speedaward_alltimebest = ReadInt24_t();
1237                         if(race_speedaward_alltimebest_holder)
1238                                 strunzone(race_speedaward_alltimebest_holder);
1239                         race_speedaward_alltimebest_holder = strzone(ReadString());
1240                         break;
1241                 case RACE_NET_SERVER_RANKINGS:
1242                         float pos, prevpos, del;
1243                         pos = ReadShort();
1244                         prevpos = ReadShort();
1245                         del = ReadShort();
1246
1247                         // move other rankings out of the way
1248                         float i;
1249                         if (prevpos) {
1250                                 for (i=prevpos-1;i>pos-1;--i) {
1251                                         grecordtime[i] = grecordtime[i-1];
1252                                         if(grecordholder[i])
1253                                                 strunzone(grecordholder[i]);
1254                                         grecordholder[i] = strzone(grecordholder[i-1]);
1255                                 }
1256                         } else if (del) { // a record has been deleted by the admin
1257                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1258                                         if (i == RANKINGS_CNT-1) { // clear out last record
1259                                                 grecordtime[i] = 0;
1260                                                 if (grecordholder[i])
1261                                                         strunzone(grecordholder[i]);
1262                                                 grecordholder[i] = string_null;
1263                                         }
1264                                         else {
1265                                                 grecordtime[i] = grecordtime[i+1];
1266                                                 if (grecordholder[i])
1267                                                         strunzone(grecordholder[i]);
1268                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1269                                         }
1270                                 }
1271                         } else { // player has no ranked record yet
1272                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1273                                         grecordtime[i] = grecordtime[i-1];
1274                                         if(grecordholder[i])
1275                                                 strunzone(grecordholder[i]);
1276                                         grecordholder[i] = strzone(grecordholder[i-1]);
1277                                 }
1278                         }
1279
1280                         // store new ranking
1281                         if(grecordholder[pos-1] != "")
1282                                 strunzone(grecordholder[pos-1]);
1283                         grecordholder[pos-1] = strzone(ReadString());
1284                         grecordtime[pos-1] = ReadInt24_t();
1285                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1286                                 race_myrank = pos;
1287                         break;
1288                 case RACE_NET_SERVER_STATUS:
1289                         race_status = ReadShort();
1290                         if(race_status_name)
1291                                 strunzone(race_status_name);
1292                         race_status_name = strzone(ReadString());
1293         }
1294 }
1295
1296 void Net_ReadSpawn()
1297 {
1298         zoomin_effect = 1;
1299         current_viewzoom = 0.6;
1300 }
1301
1302 void Net_TeamNagger()
1303 {
1304         teamnagger = 1;
1305 }
1306
1307 void Net_ReadPingPLReport()
1308 {
1309         float e, pi, pl, ml;
1310         e = ReadByte();
1311         pi = ReadShort();
1312         pl = ReadByte();
1313         ml = ReadByte();
1314         if not(playerslots[e])
1315                 return;
1316         playerslots[e].ping = pi;
1317         playerslots[e].ping_packetloss = pl / 255.0;
1318         playerslots[e].ping_movementloss = ml / 255.0;
1319 }
1320
1321 void Net_WeaponComplain() {
1322         complain_weapon = ReadByte();
1323
1324         if(complain_weapon_name)
1325                 strunzone(complain_weapon_name);
1326         complain_weapon_name = strzone(ReadString());
1327
1328         complain_weapon_type = ReadByte();
1329
1330         complain_weapon_time = time;
1331         weapontime = time; // ping the weapon panel
1332 }
1333
1334 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1335 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1336 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1337 float CSQC_Parse_TempEntity()
1338 {
1339         float bHandled;
1340                 bHandled  = true;
1341         // Acquire TE ID
1342         float nTEID;
1343                 nTEID = ReadByte();
1344
1345                 // NOTE: Could just do return instead of break...
1346         switch(nTEID)
1347         {
1348                 case TE_CSQC_TARGET_MUSIC:
1349                         Net_TargetMusic();
1350                         bHandled = true;
1351                         break;
1352                 case TE_CSQC_PICTURE:
1353                         Net_MapVote_Picture();
1354                         bHandled = true;
1355                         break;
1356                 case TE_CSQC_RACE:
1357                         Net_ReadRace();
1358                         bHandled = true;
1359                         break;
1360                 case TE_CSQC_SPAWN:
1361                         Net_ReadSpawn();
1362                         bHandled = true;
1363                         break;
1364                 case TE_CSQC_ZCURVEPARTICLES:
1365                         Net_ReadZCurveParticles();
1366                         bHandled = true;
1367                         break;
1368                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1369                         Net_ReadNexgunBeamParticle();
1370                         bHandled = true;
1371                         break;
1372                 case TE_CSQC_TEAMNAGGER:
1373                         Net_TeamNagger();
1374                         bHandled = true;
1375                         break;
1376                 case TE_CSQC_LIGHTNINGARC:
1377                         Net_ReadLightningarc();
1378                         bHandled = true;
1379                         break;
1380                 case TE_CSQC_PINGPLREPORT:
1381                         Net_ReadPingPLReport();
1382                         bHandled = true;
1383                         break;
1384                 case TE_CSQC_ANNOUNCE:
1385                         announce_snd = strzone(ReadString());
1386                         bHandled = true;
1387                         break;
1388                 case TE_CSQC_KILLNOTIFY:
1389                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1390                         bHandled = true;
1391                         break;
1392                 case TE_CSQC_KILLCENTERPRINT:
1393                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1394                         bHandled = true;
1395                         break;
1396                 case TE_CSQC_CENTERPRINT_GENERIC:
1397                         float id;
1398                         string s;
1399                         id = ReadByte();
1400                         s = ReadString();
1401                         if (id != 0 && s != "")
1402                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1403                         else
1404                                 centerprint_generic(id, s, 0, 0);
1405                         bHandled = true;
1406                         break;
1407                 case TE_CSQC_WEAPONCOMPLAIN:
1408                         Net_WeaponComplain();
1409                         bHandled = true;
1410                         break;
1411         case TE_CSQC_VEHICLESETUP:
1412             Net_VehicleSetup();
1413             bHandled = true;
1414             break;
1415                 default:
1416                         // No special logic for this temporary entity; return 0 so the engine can handle it
1417                         bHandled = false;
1418                         break;
1419         }
1420
1421         return bHandled;
1422 }
1423
1424 string getcommandkey(string text, string command)
1425 {
1426         string keys;
1427         float n, j, k, l;
1428
1429         if (!autocvar_hud_showbinds)
1430                 return text;
1431
1432         keys = db_get(binddb, command);
1433         if (!keys)
1434         {
1435                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1436                 for(j = 0; j < n; ++j)
1437                 {
1438                         k = stof(argv(j));
1439                         if(k != -1)
1440                         {
1441                                 if ("" == keys)
1442                                         keys = keynumtostring(k);
1443                                 else
1444                                         keys = strcat(keys, ", ", keynumtostring(k));
1445
1446                                 ++l;
1447                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1448                         }
1449
1450                 }
1451                 db_put(binddb, command, keys);
1452         }
1453
1454         if ("" == keys) {
1455                 if (autocvar_hud_showbinds > 1)
1456                         return sprintf(_("%s (not bound)"), text);
1457                 else
1458                         return text;
1459         }
1460         else if (autocvar_hud_showbinds > 1)
1461                 return sprintf(_("%s (%s)"), text, keys);
1462         else
1463                 return keys;
1464 }