qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = menu_sub_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(COLOR_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157
 158         WaypointSprite_Load();
 159
 160         // precaches
 161         precache_model("null");
 162         precache_sound("misc/hit.wav");
 163         precache_sound("misc/typehit.wav");
 164         if (autocvar_cl_precacheplayermodels)
 165         {
 166                 precache_all_playermodels("models/player/*.zym");
 167                 precache_all_playermodels("models/player/*.dpm");
 168                 precache_all_playermodels("models/player/*.md3");
 169                 precache_all_playermodels("models/player/*.psk");
 170                 precache_all_playermodels("models/player/*.iqm");
 171         }
 172
 173         Projectile_Precache();
 174         Hook_Precache();
 175         GibSplash_Precache();
 176         Casings_Precache();
 177         DamageInfo_Precache();
 178         Vehicles_Precache();
 179         turrets_precache();
 180     Announcer_Precache();
 181         Tuba_Precache();
 182
 183         if(autocvar_cl_reticle)
 184         {
 185                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 186                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 187         }
 188
 189         get_mi_min_max_texcoords(1); // try the CLEVER way first
 190         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 191         shortmapname = mi_shortname;
 192
 193         if(precache_pic(minimapname) == "")
 194         {
 195                 // but maybe we have a non-clever minimap
 196                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 197                 if(precache_pic(minimapname) == "")
 198                         minimapname = ""; // FAIL
 199                 else
 200                         get_mi_min_max_texcoords(0); // load new texcoords
 201         }
 202
 203         mi_center = (mi_min + mi_max) * 0.5;
 204         mi_scale = mi_max - mi_min;
 205         minimapname = strzone(minimapname);
 206
 207         WarpZone_Init();
 208
 209         hud_configure_prev = -1;
 210         tab_panel = -1;
 211
 212         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 213 }
 214
 215 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 216 void Shutdown(void)
 217 {
 218 #ifdef USE_FTE
 219 #pragma TARGET id
 220         if(!__engine_check)
 221                 return 0;
 222 #pragma TARGET fte
 223 #endif
 224
 225         WarpZone_Shutdown();
 226
 227         remove(teams);
 228         remove(players);
 229         db_close(binddb);
 230         db_close(tempdb);
 231         if(autocvar_cl_db_saveasdump)
 232                 db_dump(ClientProgsDB, "client.db");
 233         else
 234                 db_save(ClientProgsDB, "client.db");
 235         db_close(ClientProgsDB);
 236
 237         if(camera_active)
 238                 cvar_set("chase_active",ftos(chase_active_backup));
 239
 240         // unset the event chasecam's chase_active
 241         if(autocvar_chase_active < 0)
 242                 cvar_set("chase_active", "0");
 243
 244         if not(isdemo())
 245         {
 246                 if not(calledhooks & HOOK_START)
 247                         localcmd("\n_cl_hook_gamestart nop\n");
 248                 if not(calledhooks & HOOK_END)
 249                         localcmd("\ncl_hook_gameend\n");
 250         }
 251 }
 252
 253 .float has_team;
 254 float SetTeam(entity o, float Team)
 255 {
 256         entity tm;
 257         if(teamplay)
 258         {
 259                 switch(Team)
 260                 {
 261                         case -1:
 262                         case COLOR_TEAM1:
 263                         case COLOR_TEAM2:
 264                         case COLOR_TEAM3:
 265                         case COLOR_TEAM4:
 266                                 break;
 267                         default:
 268                                 if(GetTeam(Team, false) == world)
 269                                 {
 270                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 271                                         Team = COLOR_SPECTATOR;
 272                                 }
 273                                 break;
 274                 }
 275         }
 276         else
 277         {
 278                 switch(Team)
 279                 {
 280                         case -1:
 281                         case 0:
 282                                 break;
 283                         default:
 284                                 if(GetTeam(Team, false) == world)
 285                                 {
 286                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 287                                         Team = COLOR_SPECTATOR;
 288                                 }
 289                                 break;
 290                 }
 291         }
 292         if(Team == -1) // leave
 293         {
 294                 if(o.has_team)
 295                 {
 296                         tm = GetTeam(o.team, false);
 297                         tm.team_size -= 1;
 298                         o.has_team = 0;
 299                         return TRUE;
 300                 }
 301         }
 302         else
 303         {
 304                 if not(o.has_team)
 305                 {
 306                         o.team = Team;
 307                         tm = GetTeam(Team, true);
 308                         tm.team_size += 1;
 309                         o.has_team = 1;
 310                         return TRUE;
 311                 }
 312                 else if(Team != o.team)
 313                 {
 314                         tm = GetTeam(o.team, false);
 315                         tm.team_size -= 1;
 316                         o.team = Team;
 317                         tm = GetTeam(Team, true);
 318                         tm.team_size += 1;
 319                         return TRUE;
 320                 }
 321         }
 322         return FALSE;
 323 }
 324
 325 void Playerchecker_Think()
 326 {
 327         float i;
 328         entity e;
 329         for(i = 0; i < maxclients; ++i)
 330         {
 331                 e = playerslots[i];
 332                 if(GetPlayerName(i) == "")
 333                 {
 334                         if(e.sort_prev)
 335                         {
 336                                 // player disconnected
 337                                 SetTeam(e, -1);
 338                                 RemovePlayer(e);
 339                                 e.sort_prev = world;
 340                                 //e.gotscores = 0;
 341                         }
 342                 }
 343                 else
 344                 {
 345                         if not(e.sort_prev)
 346                         {
 347                                 // player connected
 348                                 if not(e)
 349                                         playerslots[i] = e = spawn();
 350                                 e.sv_entnum = i;
 351                                 e.ping = 0;
 352                                 e.ping_packetloss = 0;
 353                                 e.ping_movementloss = 0;
 354                                 //e.gotscores = 0; // we might already have the scores...
 355                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 356                                 RegisterPlayer(e);
 357                                 HUD_UpdatePlayerPos(e);
 358                         }
 359                 }
 360         }
 361         self.nextthink = time + 0.2;
 362 }
 363
 364 void Porto_Init();
 365 void TrueAim_Init();
 366 void PostInit(void)
 367 {
 368         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 369
 370         entity playerchecker;
 371         playerchecker = spawn();
 372         playerchecker.think = Playerchecker_Think;
 373         playerchecker.nextthink = time + 0.2;
 374
 375         Porto_Init();
 376         TrueAim_Init();
 377
 378         postinit = true;
 379 }
 380
 381 float button_zoom;
 382
 383 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 384 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 385 // All keys are in ascii.
 386 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 387 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 388 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 389 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 390 {
 391         float bSkipKey;
 392         bSkipKey = false;
 393
 394         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 395                 return true;
 396
 397         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 398                 return true;
 399
 400         if(menu_visible)
 401                 if(menu_action(bInputType, nPrimary, nSecondary))
 402                         return TRUE;
 403
 404         return bSkipKey;
 405 }
 406
 407 // END REQUIRED CSQC FUNCTIONS
 408 // --------------------------------------------------------------------------
 409
 410 // --------------------------------------------------------------------------
 411 // BEGIN OPTIONAL CSQC FUNCTIONS
 412 void Ent_RemoveEntCS()
 413 {
 414         entcs_receiver[self.sv_entnum] = world;
 415 }
 416 void Ent_ReadEntCS()
 417 {
 418         float sf;
 419         InterpolateOrigin_Undo();
 420
 421         self.classname = "entcs_receiver";
 422         sf = ReadByte();
 423
 424         if(sf & 1)
 425                 self.sv_entnum = ReadByte();
 426         if(sf & 2)
 427         {
 428                 self.origin_x = ReadShort();
 429                 self.origin_y = ReadShort();
 430                 self.origin_z = ReadShort();
 431         }
 432         if(sf & 4)
 433         {
 434                 self.angles_y = ReadByte() * 360.0 / 256;
 435                 self.angles_x = self.angles_z = 0;
 436         }
 437         if(sf & 8)
 438                 self.healthvalue = ReadByte() * 10;
 439         if(sf & 16)
 440                 self.armorvalue = ReadByte() * 10;
 441
 442         entcs_receiver[self.sv_entnum] = self;
 443         self.entremove = Ent_RemoveEntCS;
 444
 445         InterpolateOrigin_Note();
 446 }
 447
 448 void Ent_Remove();
 449
 450 void Ent_RemovePlayerScore()
 451 {
 452         float i;
 453
 454         if(self.owner)
 455         {
 456                 SetTeam(self.owner, -1);
 457                 self.owner.gotscores = 0;
 458                 for(i = 0; i < MAX_SCORE; ++i)
 459                         self.owner.(scores[i]) = 0; // clear all scores
 460         }
 461 }
 462
 463 void Ent_ReadPlayerScore()
 464 {
 465         float i, n;
 466         float isNew;
 467         entity o;
 468
 469         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 470         // (no I've never heard of M-x replace-string, sed, or anything like that)
 471         isNew = !self.owner; // workaround for DP bug
 472         n = ReadByte()-1;
 473
 474 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 475         if(!isNew && n != self.sv_entnum)
 476         {
 477                 //print(_("A CSQC entity changed its owner!\n"));
 478                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 479                 isNew = true;
 480                 Ent_Remove();
 481                 self.enttype = ENT_CLIENT_SCORES;
 482         }
 483 #endif
 484
 485         self.sv_entnum = n;
 486
 487         if not(playerslots[self.sv_entnum])
 488                 playerslots[self.sv_entnum] = spawn();
 489         o = self.owner = playerslots[self.sv_entnum];
 490         o.sv_entnum = self.sv_entnum;
 491         o.gotscores = 1;
 492
 493         //if not(o.sort_prev)
 494         //      RegisterPlayer(o);
 495         //playerchecker will do this for us later, if it has not already done so
 496
 497         float sf, lf;
 498 #if MAX_SCORE <= 8
 499         sf = ReadByte();
 500         lf = ReadByte();
 501 #else
 502         sf = ReadShort();
 503         lf = ReadShort();
 504 #endif
 505         float p;
 506         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 507                 if(sf & p)
 508                 {
 509                         if(lf & p)
 510                                 o.(scores[i]) = ReadInt24_t();
 511                         else
 512                                 o.(scores[i]) = ReadChar();
 513                 }
 514
 515         if(o.sort_prev)
 516                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 517
 518         self.entremove = Ent_RemovePlayerScore;
 519 }
 520
 521 void Ent_ReadTeamScore()
 522 {
 523         float i;
 524         entity o;
 525
 526         self.team = ReadByte();
 527         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 528
 529         float sf, lf;
 530 #if MAX_TEAMSCORE <= 8
 531         sf = ReadByte();
 532         lf = ReadByte();
 533 #else
 534         sf = ReadShort();
 535         lf = ReadShort();
 536 #endif
 537         float p;
 538         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 539                 if(sf & p)
 540                 {
 541                         if(lf & p)
 542                                 o.(teamscores[i]) = ReadInt24_t();
 543                         else
 544                                 o.(teamscores[i]) = ReadChar();
 545                 }
 546
 547         HUD_UpdateTeamPos(o);
 548 }
 549
 550 void Ent_ClientData()
 551 {
 552         float f;
 553         float newspectatee_status;
 554
 555         f = ReadByte();
 556
 557         scoreboard_showscores_force = (f & 1);
 558
 559         if(f & 2)
 560         {
 561                 newspectatee_status = ReadByte();
 562                 if(newspectatee_status == player_localnum + 1)
 563                         newspectatee_status = -1; // observing
 564         }
 565         else
 566                 newspectatee_status = 0;
 567
 568         spectatorbutton_zoom = (f & 4);
 569
 570         if(f & 8)
 571         {
 572                 angles_held_status = 1;
 573                 angles_held_x = ReadAngle();
 574                 angles_held_y = ReadAngle();
 575                 angles_held_z = 0;
 576         }
 577         else
 578                 angles_held_status = 0;
 579
 580         if(newspectatee_status != spectatee_status)
 581         {
 582                 // clear race stuff
 583                 race_laptime = 0;
 584                 race_checkpointtime = 0;
 585         }
 586         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 587         {
 588                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 589                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 590                 )
 591                         prev_p_health = -1;
 592                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 593                         prev_health = -1;
 594         }
 595         spectatee_status = newspectatee_status;
 596
 597         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 598 }
 599
 600 void Ent_Nagger()
 601 {
 602         float nags, i, j, b, f;
 603
 604         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 605
 606         if(!(nags & 4))
 607         {
 608                 if(vote_called_vote)
 609                         strunzone(vote_called_vote);
 610                 vote_called_vote = string_null;
 611                 vote_active = 0;
 612         }
 613         else
 614         {
 615                 vote_active = 1;
 616         }
 617
 618         if(nags & 64)
 619         {
 620                 vote_yescount = ReadByte();
 621                 vote_nocount = ReadByte();
 622                 vote_needed = ReadByte();
 623                 vote_highlighted = ReadChar();
 624         }
 625
 626         if(nags & 128)
 627         {
 628                 if(vote_called_vote)
 629                         strunzone(vote_called_vote);
 630                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 631         }
 632
 633         if(nags & 1)
 634         {
 635                 for(j = 0; j < maxclients; ++j)
 636                         if(playerslots[j])
 637                                 playerslots[j].ready = 1;
 638                 for(i = 1; i <= maxclients; i += 8)
 639                 {
 640                         f = ReadByte();
 641                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 642                                 if not(f & b)
 643                                         if(playerslots[j])
 644                                                 playerslots[j].ready = 0;
 645                 }
 646         }
 647
 648         ready_waiting = (nags & 1);
 649         ready_waiting_for_me = (nags & 2);
 650         vote_waiting = (nags & 4);
 651         vote_waiting_for_me = (nags & 8);
 652         warmup_stage = (nags & 16);
 653 }
 654
 655 void Ent_RandomSeed()
 656 {
 657         float s;
 658         prandom_debug();
 659         s = ReadShort();
 660         psrandom(s);
 661 }
 662
 663 void Ent_ReadAccuracy(void)
 664 {
 665         float sf, f, w, b;
 666         sf = ReadInt24_t();
 667         if(sf == 0)
 668         {
 669                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 670                         weapon_accuracy[w] = -1;
 671                 return;
 672         }
 673
 674         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 675         {
 676                 if(sf & f)
 677                 {
 678                         b = ReadByte();
 679                         if(b == 0)
 680                                 weapon_accuracy[w] = -1;
 681                         else if(b == 255)
 682                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 683                         else
 684                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 685                 }
 686         }
 687 }
 688
 689 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 690 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 691 void Ent_RadarLink();
 692 void Ent_Init();
 693 void Ent_ScoresInfo();
 694 void CSQC_Ent_Update(float bIsNewEntity)
 695 {
 696         float t;
 697         float savetime;
 698         t = ReadByte();
 699
 700         if(autocvar_developer_csqcentities)
 701                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 702
 703         // set up the "time" global for received entities to be correct for interpolation purposes
 704         savetime = time;
 705         if(servertime)
 706         {
 707                 time = servertime;
 708         }
 709         else
 710         {
 711                 serverprevtime = time;
 712                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 713                 time = serverprevtime + serverdeltatime;
 714         }
 715
 716 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 717         if(self.enttype)
 718         {
 719                 if(t != self.enttype || bIsNewEntity)
 720                 {
 721                         //print(_("A CSQC entity changed its type!\n"));
 722                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 723                         Ent_Remove();
 724                         clearentity(self);
 725                         bIsNewEntity = 1;
 726                 }
 727         }
 728         else
 729         {
 730                 if(!bIsNewEntity)
 731                 {
 732                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 733                         bIsNewEntity = 1;
 734                 }
 735         }
 736 #endif
 737         self.enttype = t;
 738         switch(t)
 739         {
 740                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 741                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 742                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 743                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 744                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 745                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 746                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 747                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 748                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 749                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 750                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 751                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 752                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 753                 case ENT_CLIENT_INIT: Ent_Init(); break;
 754                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 755                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 756                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 757                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 758                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 759                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 760                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 761                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 762                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 763                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 764                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 765                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 766                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 767                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 768                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 769                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 770                 case ENT_CLIENT_TURRET: ent_turret(); break;
 771                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 772                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 773                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 774                 default:
 775                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 776                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 777                         break;
 778         }
 779
 780         time = savetime;
 781 }
 782 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 783 // used when an entity changes its type. For an entity that someone interacts
 784 // with others, make sure it can no longer do so.
 785 void Ent_Remove()
 786 {
 787         if(self.entremove)
 788                 self.entremove();
 789
 790         self.enttype = 0;
 791         self.classname = "";
 792         self.draw = menu_sub_null;
 793         self.entremove = menu_sub_null;
 794         // TODO possibly set more stuff to defaults
 795 }
 796 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 797 void CSQC_Ent_Remove()
 798 {
 799         if(autocvar_developer_csqcentities)
 800                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 801
 802         if(wasfreed(self))
 803         {
 804                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 805                 return;
 806         }
 807         if(self.enttype)
 808                 Ent_Remove();
 809         remove(self);
 810 }
 811
 812 void Gamemode_Init()
 813 {
 814         if not(isdemo())
 815         {
 816                 if(!(calledhooks & HOOK_START))
 817                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 818                 calledhooks |= HOOK_START;
 819         }
 820 }
 821 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 822 void CSQC_Parse_StuffCmd(string strMessage)
 823 {
 824         if(autocvar_developer_csqcentities)
 825                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 826
 827         localcmd(strMessage);
 828 }
 829 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 830 void CSQC_Parse_Print(string strMessage)
 831 {
 832         if(autocvar_developer_csqcentities)
 833                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 834
 835         print(ColorTranslateRGB(strMessage));
 836 }
 837
 838 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 839 void CSQC_Parse_CenterPrint(string strMessage)
 840 {
 841         if(autocvar_developer_csqcentities)
 842                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 843
 844         centerprint_hud(strMessage);
 845 }
 846
 847 string notranslate_fogcmd1 = "\nfog ";
 848 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 849 void Fog_Force()
 850 {
 851         // TODO somehow thwart prvm_globalset client ...
 852
 853         if(forcefog != "")
 854                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 855 }
 856
 857 void Gamemode_Init();
 858 void Ent_ScoresInfo()
 859 {
 860         float i;
 861         self.classname = "ent_client_scores_info";
 862         gametype = ReadInt24_t();
 863         for(i = 0; i < MAX_SCORE; ++i)
 864         {
 865                 scores_label[i] = strzone(ReadString());
 866                 scores_flags[i] = ReadByte();
 867         }
 868         for(i = 0; i < MAX_TEAMSCORE; ++i)
 869         {
 870                 teamscores_label[i] = strzone(ReadString());
 871                 teamscores_flags[i] = ReadByte();
 872         }
 873         HUD_InitScores();
 874         Gamemode_Init();
 875 }
 876
 877 void Ent_Init()
 878 {
 879         self.classname = "ent_client_init";
 880
 881         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 882
 883         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 884         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 885         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 886         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 887         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 888         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 889         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 890         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 891         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 892         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 893         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 894         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 895
 896         if(forcefog)
 897                 strunzone(forcefog);
 898         forcefog = strzone(ReadString());
 899
 900         armorblockpercent = ReadByte() / 255.0;
 901
 902         g_weaponswitchdelay = ReadByte() / 255.0;
 903
 904         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 905         g_balance_grenadelauncher_bouncestop = ReadCoord();
 906         g_balance_electro_secondary_bouncefactor = ReadCoord();
 907         g_balance_electro_secondary_bouncestop = ReadCoord();
 908
 909         nex_scope = !ReadByte();
 910         rifle_scope = !ReadByte();
 911
 912         serverflags = ReadByte();
 913
 914         minelayer_maxmines = ReadByte();
 915
 916         hagar_maxrockets = ReadByte();
 917
 918         g_trueaim_minrange = ReadCoord();
 919         g_balance_porto_secondary = ReadByte();
 920
 921         if(!postinit)
 922                 PostInit();
 923 }
 924
 925 void Net_ReadRace()
 926 {
 927         float b;
 928
 929         b = ReadByte();
 930
 931         switch(b)
 932         {
 933                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 934                         race_checkpoint = ReadByte();
 935                         race_time = ReadInt24_t();
 936                         race_previousbesttime = ReadInt24_t();
 937                         if(race_previousbestname)
 938                                 strunzone(race_previousbestname);
 939                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 940
 941                         race_checkpointtime = time;
 942
 943                         if(race_checkpoint == 0 || race_checkpoint == 254)
 944                         {
 945                                 race_penaltyaccumulator = 0;
 946                                 race_laptime = time; // valid
 947                         }
 948
 949                         break;
 950
 951                 case RACE_NET_CHECKPOINT_CLEAR:
 952                         race_laptime = 0;
 953                         race_checkpointtime = 0;
 954                         break;
 955
 956                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 957                         race_laptime = ReadCoord();
 958                         race_checkpointtime = -99999;
 959                         // fall through
 960                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 961                         race_nextcheckpoint = ReadByte();
 962
 963                         race_nextbesttime = ReadInt24_t();
 964                         if(race_nextbestname)
 965                                 strunzone(race_nextbestname);
 966                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 967                         break;
 968
 969                 case RACE_NET_CHECKPOINT_HIT_RACE:
 970                         race_mycheckpoint = ReadByte();
 971                         race_mycheckpointtime = time;
 972                         race_mycheckpointdelta = ReadInt24_t();
 973                         race_mycheckpointlapsdelta = ReadByte();
 974                         if(race_mycheckpointlapsdelta >= 128)
 975                                 race_mycheckpointlapsdelta -= 256;
 976                         if(race_mycheckpointenemy)
 977                                 strunzone(race_mycheckpointenemy);
 978                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 979                         break;
 980
 981                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
 982                         race_othercheckpoint = ReadByte();
 983                         race_othercheckpointtime = time;
 984                         race_othercheckpointdelta = ReadInt24_t();
 985                         race_othercheckpointlapsdelta = ReadByte();
 986                         if(race_othercheckpointlapsdelta >= 128)
 987                                 race_othercheckpointlapsdelta -= 256;
 988                         if(race_othercheckpointenemy)
 989                                 strunzone(race_othercheckpointenemy);
 990                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 991                         break;
 992
 993                 case RACE_NET_PENALTY_RACE:
 994                         race_penaltyeventtime = time;
 995                         race_penaltytime = ReadShort();
 996                         //race_penaltyaccumulator += race_penaltytime;
 997                         if(race_penaltyreason)
 998                                 strunzone(race_penaltyreason);
 999                         race_penaltyreason = strzone(ReadString());
1000                         break;
1001
1002                 case RACE_NET_PENALTY_QUALIFYING:
1003                         race_penaltyeventtime = time;
1004                         race_penaltytime = ReadShort();
1005                         race_penaltyaccumulator += race_penaltytime;
1006                         if(race_penaltyreason)
1007                                 strunzone(race_penaltyreason);
1008                         race_penaltyreason = strzone(ReadString());
1009                         break;
1010
1011                 case RACE_NET_SERVER_RECORD:
1012                         race_server_record = ReadInt24_t();
1013                         break;
1014                 case RACE_NET_SPEED_AWARD:
1015                         race_speedaward = ReadInt24_t();
1016                         if(race_speedaward_holder)
1017                                 strunzone(race_speedaward_holder);
1018                         race_speedaward_holder = strzone(ReadString());
1019                         break;
1020                 case RACE_NET_SPEED_AWARD_BEST:
1021                         race_speedaward_alltimebest = ReadInt24_t();
1022                         if(race_speedaward_alltimebest_holder)
1023                                 strunzone(race_speedaward_alltimebest_holder);
1024                         race_speedaward_alltimebest_holder = strzone(ReadString());
1025                         break;
1026                 case RACE_NET_SERVER_RANKINGS:
1027                         float pos, prevpos, del;
1028                         pos = ReadShort();
1029                         prevpos = ReadShort();
1030                         del = ReadShort();
1031
1032                         // move other rankings out of the way
1033                         float i;
1034                         if (prevpos) {
1035                                 for (i=prevpos-1;i>pos-1;--i) {
1036                                         grecordtime[i] = grecordtime[i-1];
1037                                         if(grecordholder[i])
1038                                                 strunzone(grecordholder[i]);
1039                                         grecordholder[i] = strzone(grecordholder[i-1]);
1040                                 }
1041                         } else if (del) { // a record has been deleted by the admin
1042                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1043                                         if (i == RANKINGS_CNT-1) { // clear out last record
1044                                                 grecordtime[i] = 0;
1045                                                 if (grecordholder[i])
1046                                                         strunzone(grecordholder[i]);
1047                                                 grecordholder[i] = string_null;
1048                                         }
1049                                         else {
1050                                                 grecordtime[i] = grecordtime[i+1];
1051                                                 if (grecordholder[i])
1052                                                         strunzone(grecordholder[i]);
1053                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1054                                         }
1055                                 }
1056                         } else { // player has no ranked record yet
1057                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1058                                         grecordtime[i] = grecordtime[i-1];
1059                                         if(grecordholder[i])
1060                                                 strunzone(grecordholder[i]);
1061                                         grecordholder[i] = strzone(grecordholder[i-1]);
1062                                 }
1063                         }
1064
1065                         // store new ranking
1066                         if(grecordholder[pos-1] != "")
1067                                 strunzone(grecordholder[pos-1]);
1068                         grecordholder[pos-1] = strzone(ReadString());
1069                         grecordtime[pos-1] = ReadInt24_t();
1070                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1071                                 race_myrank = pos;
1072                         break;
1073                 case RACE_NET_SERVER_STATUS:
1074                         race_status = ReadShort();
1075                         if(race_status_name)
1076                                 strunzone(race_status_name);
1077                         race_status_name = strzone(ReadString());
1078         }
1079 }
1080
1081 void Net_ReadSpawn()
1082 {
1083         zoomin_effect = 1;
1084         current_viewzoom = 0.6;
1085 }
1086
1087 void Net_TeamNagger()
1088 {
1089         teamnagger = 1;
1090 }
1091
1092 void Net_ReadPingPLReport()
1093 {
1094         float e, pi, pl, ml;
1095         e = ReadByte();
1096         pi = ReadShort();
1097         pl = ReadByte();
1098         ml = ReadByte();
1099         if not(playerslots[e])
1100                 return;
1101         playerslots[e].ping = pi;
1102         playerslots[e].ping_packetloss = pl / 255.0;
1103         playerslots[e].ping_movementloss = ml / 255.0;
1104 }
1105
1106 void Net_WeaponComplain() {
1107         complain_weapon = ReadByte();
1108
1109         if(complain_weapon_name)
1110                 strunzone(complain_weapon_name);
1111         complain_weapon_name = strzone(ReadString());
1112
1113         complain_weapon_type = ReadByte();
1114
1115         complain_weapon_time = time;
1116         weapontime = time; // ping the weapon panel
1117 }
1118
1119 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1120 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1121 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1122 float CSQC_Parse_TempEntity()
1123 {
1124         float bHandled;
1125                 bHandled  = true;
1126         // Acquire TE ID
1127         float nTEID;
1128                 nTEID = ReadByte();
1129
1130         if(autocvar_developer_csqcentities)
1131                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1132
1133                 // NOTE: Could just do return instead of break...
1134         switch(nTEID)
1135         {
1136                 case TE_CSQC_TARGET_MUSIC:
1137                         Net_TargetMusic();
1138                         bHandled = true;
1139                         break;
1140                 case TE_CSQC_PICTURE:
1141                         Net_MapVote_Picture();
1142                         bHandled = true;
1143                         break;
1144                 case TE_CSQC_RACE:
1145                         Net_ReadRace();
1146                         bHandled = true;
1147                         break;
1148                 case TE_CSQC_SPAWN:
1149                         Net_ReadSpawn();
1150                         bHandled = true;
1151                         break;
1152                 case TE_CSQC_ZCURVEPARTICLES:
1153                         Net_ReadZCurveParticles();
1154                         bHandled = true;
1155                         break;
1156                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1157                         Net_ReadNexgunBeamParticle();
1158                         bHandled = true;
1159                         break;
1160                 case TE_CSQC_TEAMNAGGER:
1161                         Net_TeamNagger();
1162                         bHandled = true;
1163                         break;
1164                 case TE_CSQC_LIGHTNINGARC:
1165                         Net_ReadLightningarc();
1166                         bHandled = true;
1167                         break;
1168                 case TE_CSQC_PINGPLREPORT:
1169                         Net_ReadPingPLReport();
1170                         bHandled = true;
1171                         break;
1172                 case TE_CSQC_ANNOUNCE:
1173                         Announcer_Play(ReadString());
1174                         bHandled = true;
1175                         break;
1176                 case TE_CSQC_KILLNOTIFY:
1177                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1178                         bHandled = true;
1179                         break;
1180                 case TE_CSQC_KILLCENTERPRINT:
1181                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1182                         bHandled = true;
1183                         break;
1184                 case TE_CSQC_CENTERPRINT_GENERIC:
1185                         float id;
1186                         string s;
1187                         id = ReadByte();
1188                         s = ReadString();
1189                         if (id != 0 && s != "")
1190                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1191                         else
1192                                 centerprint_generic(id, s, 0, 0);
1193                         bHandled = true;
1194                         break;
1195                 case TE_CSQC_WEAPONCOMPLAIN:
1196                         Net_WeaponComplain();
1197                         bHandled = true;
1198                         break;
1199                 case TE_CSQC_VEHICLESETUP:
1200                         Net_VehicleSetup();
1201                         bHandled = true;
1202                         break;
1203                 case TE_CSQC_SVNOTICE:
1204                         cl_notice_read();
1205                         bHandled = true;
1206                         break;
1207                 default:
1208                         // No special logic for this temporary entity; return 0 so the engine can handle it
1209                         bHandled = false;
1210                         break;
1211         }
1212
1213         return bHandled;
1214 }
1215
1216 string getcommandkey(string text, string command)
1217 {
1218         string keys;
1219         float n, j, k, l;
1220
1221         if (!autocvar_hud_showbinds)
1222                 return text;
1223
1224         keys = db_get(binddb, command);
1225         if (!keys)
1226         {
1227                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1228                 for(j = 0; j < n; ++j)
1229                 {
1230                         k = stof(argv(j));
1231                         if(k != -1)
1232                         {
1233                                 if ("" == keys)
1234                                         keys = keynumtostring(k);
1235                                 else
1236                                         keys = strcat(keys, ", ", keynumtostring(k));
1237
1238                                 ++l;
1239                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1240                         }
1241
1242                 }
1243                 db_put(binddb, command, keys);
1244         }
1245
1246         if ("" == keys) {
1247                 if (autocvar_hud_showbinds > 1)
1248                         return sprintf(_("%s (not bound)"), text);
1249                 else
1250                         return text;
1251         }
1252         else if (autocvar_hud_showbinds > 1)
1253                 return sprintf(_("%s (%s)"), text, keys);
1254         else
1255                 return keys;
1256 }