qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 string forcefog;
  36 void WaypointSprite_Load();
  37 void ConsoleCommand_macro_init();
  38 void CSQC_Init(void)
  39 {
  40         prvm_language = cvar_string("prvm_language");
  41 #ifdef USE_FTE
  42 #pragma target ID
  43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  44         if(!__engine_check)
  45         {
  46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  47                 localcmd("\ndisconnect\n");
  48                 return;
  49         }
  50 #pragma target FTE
  51 #endif
  52
  53         check_unacceptable_compiler_bugs();
  54
  55 #ifdef WATERMARK
  56         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
  57 #endif
  58
  59         float i;
  60
  61 #ifdef COMPAT_XON050_ENGINE
  62         // old engine lacks implementation of player_localnum
  63         player_localnum = player_localentnum - 1;
  64 #endif
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         gametype = 0;
  91
  92         // hud_fields uses strunzone on the titles!
  93         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  94                 hud_title[i] = strzone("(null)");
  95
  96         postinit = false;
  97
  98         calledhooks = 0;
  99
 100         teams = Sort_Spawn();
 101         players = Sort_Spawn();
 102
 103         GetTeam(NUM_SPECTATOR, true); // add specs first
 104
 105         // needs to be done so early because of the constants they create
 106         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 107         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 108         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 109         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 110         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 111
 112         WaypointSprite_Load();
 113
 114         // precaches
 115         precache_model("null");
 116         precache_sound("misc/hit.wav");
 117         precache_sound("misc/typehit.wav");
 118
 119         Projectile_Precache();
 120         Hook_Precache();
 121         GibSplash_Precache();
 122         Casings_Precache();
 123         Vehicles_Precache();
 124         turrets_precache();
 125         Tuba_Precache();
 126         CSQCPlayer_Precache();
 127
 128         if(autocvar_cl_reticle)
 129         {
 130                 precache_pic("gfx/reticle_normal");
 131                 // weapon reticles are precached in weapon files
 132         }
 133
 134         get_mi_min_max_texcoords(1); // try the CLEVER way first
 135         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 136         shortmapname = mi_shortname;
 137
 138         if(precache_pic(minimapname) == "")
 139         {
 140                 // but maybe we have a non-clever minimap
 141                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 142                 if(precache_pic(minimapname) == "")
 143                         minimapname = ""; // FAIL
 144                 else
 145                         get_mi_min_max_texcoords(0); // load new texcoords
 146         }
 147
 148         mi_center = (mi_min + mi_max) * 0.5;
 149         mi_scale = mi_max - mi_min;
 150         minimapname = strzone(minimapname);
 151
 152         WarpZone_Init();
 153
 154         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 155         hud_configure_prev = -1;
 156
 157         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 158 }
 159
 160 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 161 void Shutdown(void)
 162 {
 163 #ifdef USE_FTE
 164 #pragma TARGET id
 165         if(!__engine_check)
 166                 return 0;
 167 #pragma TARGET fte
 168 #endif
 169
 170         WarpZone_Shutdown();
 171
 172         remove(teams);
 173         remove(players);
 174         db_close(binddb);
 175         db_close(tempdb);
 176         if(autocvar_cl_db_saveasdump)
 177                 db_dump(ClientProgsDB, "client.db");
 178         else
 179                 db_save(ClientProgsDB, "client.db");
 180         db_close(ClientProgsDB);
 181
 182         if(camera_active)
 183                 cvar_set("chase_active",ftos(chase_active_backup));
 184
 185         // unset the event chasecam's chase_active
 186         if(autocvar_chase_active < 0)
 187                 cvar_set("chase_active", "0");
 188
 189         if (!isdemo())
 190         {
 191                 if (!(calledhooks & HOOK_START))
 192                         localcmd("\n_cl_hook_gamestart nop\n");
 193                 if (!(calledhooks & HOOK_END))
 194                         localcmd("\ncl_hook_gameend\n");
 195         }
 196 }
 197
 198 .float has_team;
 199 float SetTeam(entity o, float Team)
 200 {
 201         entity tm;
 202         if(teamplay)
 203         {
 204                 switch(Team)
 205                 {
 206                         case -1:
 207                         case NUM_TEAM_1:
 208                         case NUM_TEAM_2:
 209                         case NUM_TEAM_3:
 210                         case NUM_TEAM_4:
 211                                 break;
 212                         default:
 213                                 if(GetTeam(Team, false) == world)
 214                                 {
 215                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 216                                         Team = NUM_SPECTATOR;
 217                                 }
 218                                 break;
 219                 }
 220         }
 221         else
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case 0:
 227                                 break;
 228                         default:
 229                                 if(GetTeam(Team, false) == world)
 230                                 {
 231                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 232                                         Team = NUM_SPECTATOR;
 233                                 }
 234                                 break;
 235                 }
 236         }
 237         if(Team == -1) // leave
 238         {
 239                 if(o.has_team)
 240                 {
 241                         tm = GetTeam(o.team, false);
 242                         tm.team_size -= 1;
 243                         o.has_team = 0;
 244                         return TRUE;
 245                 }
 246         }
 247         else
 248         {
 249                 if (!o.has_team)
 250                 {
 251                         o.team = Team;
 252                         tm = GetTeam(Team, true);
 253                         tm.team_size += 1;
 254                         o.has_team = 1;
 255                         return TRUE;
 256                 }
 257                 else if(Team != o.team)
 258                 {
 259                         tm = GetTeam(o.team, false);
 260                         tm.team_size -= 1;
 261                         o.team = Team;
 262                         tm = GetTeam(Team, true);
 263                         tm.team_size += 1;
 264                         return TRUE;
 265                 }
 266         }
 267         return FALSE;
 268 }
 269
 270 void Playerchecker_Think()
 271 {
 272         float i;
 273         entity e;
 274         for(i = 0; i < maxclients; ++i)
 275         {
 276                 e = playerslots[i];
 277                 if(GetPlayerName(i) == "")
 278                 {
 279                         if(e.sort_prev)
 280                         {
 281                                 // player disconnected
 282                                 SetTeam(e, -1);
 283                                 RemovePlayer(e);
 284                                 e.sort_prev = world;
 285                                 //e.gotscores = 0;
 286                         }
 287                 }
 288                 else
 289                 {
 290                         if (!e.sort_prev)
 291                         {
 292                                 // player connected
 293                                 if (!e)
 294                                         playerslots[i] = e = spawn();
 295                                 e.sv_entnum = i;
 296                                 e.ping = 0;
 297                                 e.ping_packetloss = 0;
 298                                 e.ping_movementloss = 0;
 299                                 //e.gotscores = 0; // we might already have the scores...
 300                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 301                                 RegisterPlayer(e);
 302                                 HUD_UpdatePlayerPos(e);
 303                         }
 304                 }
 305         }
 306         self.nextthink = time + 0.2;
 307 }
 308
 309 void Porto_Init();
 310 void TrueAim_Init();
 311 void PostInit(void)
 312 {
 313         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 314
 315         entity playerchecker;
 316         playerchecker = spawn();
 317         playerchecker.think = Playerchecker_Think;
 318         playerchecker.nextthink = time + 0.2;
 319
 320         Porto_Init();
 321         TrueAim_Init();
 322
 323         postinit = true;
 324 }
 325
 326 float button_zoom;
 327
 328 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 329 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 330 // All keys are in ascii.
 331 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 332 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 333 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 334 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 335 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 336 {
 337         float bSkipKey;
 338         bSkipKey = false;
 339
 340         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 341                 return true;
 342
 343         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 344                 return true;
 345
 346         if(menu_visible && menu_action)
 347                 if(menu_action(bInputType, nPrimary, nSecondary))
 348                         return TRUE;
 349
 350         return bSkipKey;
 351 }
 352
 353 // END REQUIRED CSQC FUNCTIONS
 354 // --------------------------------------------------------------------------
 355
 356 // --------------------------------------------------------------------------
 357 // BEGIN OPTIONAL CSQC FUNCTIONS
 358 void Ent_RemoveEntCS()
 359 {
 360         entcs_receiver[self.sv_entnum] = world;
 361 }
 362 void Ent_ReadEntCS()
 363 {
 364         float sf;
 365         InterpolateOrigin_Undo();
 366
 367         self.classname = "entcs_receiver";
 368         sf = ReadByte();
 369
 370         if(sf & 1)
 371                 self.sv_entnum = ReadByte();
 372         if(sf & 2)
 373         {
 374                 self.origin_x = ReadShort();
 375                 self.origin_y = ReadShort();
 376                 self.origin_z = ReadShort();
 377                 setorigin(self, self.origin);
 378         }
 379         if(sf & 4)
 380         {
 381                 self.angles_y = ReadByte() * 360.0 / 256;
 382                 self.angles_x = self.angles_z = 0;
 383         }
 384         if(sf & 8)
 385                 self.healthvalue = ReadByte() * 10;
 386         if(sf & 16)
 387                 self.armorvalue = ReadByte() * 10;
 388
 389         entcs_receiver[self.sv_entnum] = self;
 390         self.entremove = Ent_RemoveEntCS;
 391         self.iflags |= IFLAG_ORIGIN;
 392
 393         InterpolateOrigin_Note();
 394 }
 395
 396 void Ent_Remove();
 397
 398 void Ent_RemovePlayerScore()
 399 {
 400         float i;
 401
 402         if(self.owner)
 403         {
 404                 SetTeam(self.owner, -1);
 405                 self.owner.gotscores = 0;
 406                 for(i = 0; i < MAX_SCORE; ++i)
 407                         self.owner.(scores[i]) = 0; // clear all scores
 408         }
 409 }
 410
 411 void Ent_ReadPlayerScore()
 412 {
 413         float i, n;
 414         float isNew;
 415         entity o;
 416
 417         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 418         // (no I've never heard of M-x replace-string, sed, or anything like that)
 419         isNew = !self.owner; // workaround for DP bug
 420         n = ReadByte()-1;
 421
 422 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 423         if(!isNew && n != self.sv_entnum)
 424         {
 425                 //print("A CSQC entity changed its owner!\n");
 426                 print(sprintf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname));
 427                 isNew = true;
 428                 Ent_Remove();
 429                 self.enttype = ENT_CLIENT_SCORES;
 430         }
 431 #endif
 432
 433         self.sv_entnum = n;
 434
 435         if (!(playerslots[self.sv_entnum]))
 436                 playerslots[self.sv_entnum] = spawn();
 437         o = self.owner = playerslots[self.sv_entnum];
 438         o.sv_entnum = self.sv_entnum;
 439         o.gotscores = 1;
 440
 441         //if (!o.sort_prev)
 442         //      RegisterPlayer(o);
 443         //playerchecker will do this for us later, if it has not already done so
 444
 445         float sf, lf;
 446 #if MAX_SCORE <= 8
 447         sf = ReadByte();
 448         lf = ReadByte();
 449 #else
 450         sf = ReadShort();
 451         lf = ReadShort();
 452 #endif
 453         float p;
 454         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 455                 if(sf & p)
 456                 {
 457                         if(lf & p)
 458                                 o.(scores[i]) = ReadInt24_t();
 459                         else
 460                                 o.(scores[i]) = ReadChar();
 461                 }
 462
 463         if(o.sort_prev)
 464                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 465
 466         self.entremove = Ent_RemovePlayerScore;
 467 }
 468
 469 void Ent_ReadTeamScore()
 470 {
 471         float i;
 472         entity o;
 473
 474         self.team = ReadByte();
 475         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 476
 477         float sf, lf;
 478 #if MAX_TEAMSCORE <= 8
 479         sf = ReadByte();
 480         lf = ReadByte();
 481 #else
 482         sf = ReadShort();
 483         lf = ReadShort();
 484 #endif
 485         float p;
 486         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 487                 if(sf & p)
 488                 {
 489                         if(lf & p)
 490                                 o.(teamscores[i]) = ReadInt24_t();
 491                         else
 492                                 o.(teamscores[i]) = ReadChar();
 493                 }
 494
 495         HUD_UpdateTeamPos(o);
 496 }
 497
 498 void Ent_ClientData()
 499 {
 500         float f;
 501         float newspectatee_status;
 502
 503         f = ReadByte();
 504
 505         scoreboard_showscores_force = (f & 1);
 506
 507         if(f & 2)
 508         {
 509                 newspectatee_status = ReadByte();
 510                 if(newspectatee_status == player_localnum + 1)
 511                         newspectatee_status = -1; // observing
 512         }
 513         else
 514                 newspectatee_status = 0;
 515
 516         spectatorbutton_zoom = (f & 4);
 517
 518         if(f & 8)
 519         {
 520                 angles_held_status = 1;
 521                 angles_held_x = ReadAngle();
 522                 angles_held_y = ReadAngle();
 523                 angles_held_z = 0;
 524         }
 525         else
 526                 angles_held_status = 0;
 527
 528         if(newspectatee_status != spectatee_status)
 529         {
 530                 // clear race stuff
 531                 race_laptime = 0;
 532                 race_checkpointtime = 0;
 533         }
 534         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 535         {
 536                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 537                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 538                 )
 539                         prev_p_health = -1;
 540                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 541                         prev_health = -1;
 542         }
 543         spectatee_status = newspectatee_status;
 544
 545         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 546 }
 547
 548 void Ent_Nagger()
 549 {
 550         float nags, i, j, b, f;
 551
 552         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 553
 554         if(!(nags & 4))
 555         {
 556                 if(vote_called_vote)
 557                         strunzone(vote_called_vote);
 558                 vote_called_vote = string_null;
 559                 vote_active = 0;
 560         }
 561         else
 562         {
 563                 vote_active = 1;
 564         }
 565
 566         if(nags & 64)
 567         {
 568                 vote_yescount = ReadByte();
 569                 vote_nocount = ReadByte();
 570                 vote_needed = ReadByte();
 571                 vote_highlighted = ReadChar();
 572         }
 573
 574         if(nags & 128)
 575         {
 576                 if(vote_called_vote)
 577                         strunzone(vote_called_vote);
 578                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 579         }
 580
 581         if(nags & 1)
 582         {
 583                 for(j = 0; j < maxclients; ++j)
 584                         if(playerslots[j])
 585                                 playerslots[j].ready = 1;
 586                 for(i = 1; i <= maxclients; i += 8)
 587                 {
 588                         f = ReadByte();
 589                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 590                                 if (!(f & b))
 591                                         if(playerslots[j])
 592                                                 playerslots[j].ready = 0;
 593                 }
 594         }
 595
 596         ready_waiting = (nags & 1);
 597         ready_waiting_for_me = (nags & 2);
 598         vote_waiting = (nags & 4);
 599         vote_waiting_for_me = (nags & 8);
 600         warmup_stage = (nags & 16);
 601 }
 602
 603 void Ent_RandomSeed()
 604 {
 605         float s;
 606         prandom_debug();
 607         s = ReadShort();
 608         psrandom(s);
 609 }
 610
 611 void Ent_ReadAccuracy(void)
 612 {
 613         float sf, f, w, b;
 614         sf = ReadInt24_t();
 615         if(sf == 0)
 616         {
 617                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 618                         weapon_accuracy[w] = -1;
 619                 return;
 620         }
 621
 622         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 623         {
 624                 if(sf & f)
 625                 {
 626                         b = ReadByte();
 627                         if(b == 0)
 628                                 weapon_accuracy[w] = -1;
 629                         else if(b == 255)
 630                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 631                         else
 632                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 633                 }
 634                 if(f == 0x800000)
 635                         f = 1;
 636                 else
 637                         f *= 2;
 638         }
 639 }
 640
 641 void Spawn_Draw(void)
 642 {
 643         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 644 }
 645
 646 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 647 {
 648         float teamnum = (ReadByte() - 1);
 649         vector spn_origin;
 650         spn_origin_x = ReadShort();
 651         spn_origin_y = ReadShort();
 652         spn_origin_z = ReadShort();
 653
 654         if(is_new)
 655         {
 656                 self.origin = spn_origin;
 657                 setsize(self, PL_MIN, PL_MAX);
 658                 droptofloor();
 659
 660                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 661                 {
 662                         self.mdl = "models/spawnpoint.md3";
 663                         self.colormod = Team_ColorRGB(teamnum);
 664                         precache_model(self.mdl);
 665                         setmodel(self, self.mdl);
 666                         self.drawmask = MASK_NORMAL;
 667                         //self.movetype = MOVETYPE_NOCLIP;
 668                         //self.draw = Spawn_Draw;
 669                 }*/
 670                 if(autocvar_cl_spawn_point_particles)
 671                 {
 672                         if((serverflags & SERVERFLAG_TEAMPLAY))
 673                         {
 674                                 switch(teamnum)
 675                                 {
 676                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 677                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 678                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 679                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 680                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 681                                 }
 682                         }
 683                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 684
 685                         self.draw = Spawn_Draw;
 686                 }
 687         }
 688
 689         //print(sprintf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt));
 690 }
 691
 692 void Ent_ReadSpawnEvent(float is_new)
 693 {
 694         // If entnum is 0, ONLY do the local spawn actions
 695         // this way the server can disable the sending of
 696         // spawn origin or such to clients if wanted.
 697         float entnum = ReadByte();
 698
 699         if(entnum)
 700         {
 701                 self.origin_x = ReadShort();
 702                 self.origin_y = ReadShort();
 703                 self.origin_z = ReadShort();
 704
 705                 if(is_new)
 706                 {
 707                         float teamnum = GetPlayerColor(entnum - 1);
 708
 709                         if(autocvar_cl_spawn_event_particles)
 710                         {
 711                                 switch(teamnum)
 712                                 {
 713                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 714                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 715                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 716                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 717                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 718                                 }
 719                         }
 720                         if(autocvar_cl_spawn_event_sound)
 721                         {
 722                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 723                         }
 724                 }
 725         }
 726
 727         // local spawn actions
 728         if(is_new && (!entnum || (entnum == player_localentnum)))
 729         {
 730                 zoomin_effect = 1;
 731                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 732
 733                 if(autocvar_cl_unpress_zoom_on_spawn)
 734                 {
 735                         localcmd("-zoom\n");
 736                         button_zoom = FALSE;
 737                 }
 738         }
 739
 740         //print(sprintf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum));
 741 }
 742
 743 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 744 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 745 void Ent_RadarLink();
 746 void Ent_Init();
 747 void Ent_ScoresInfo();
 748 void CSQC_Ent_Update(float bIsNewEntity)
 749 {
 750         float t;
 751         float savetime;
 752         t = ReadByte();
 753
 754         if(autocvar_developer_csqcentities)
 755                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 756
 757         // set up the "time" global for received entities to be correct for interpolation purposes
 758         savetime = time;
 759         if(servertime)
 760         {
 761                 time = servertime;
 762         }
 763         else
 764         {
 765                 serverprevtime = time;
 766                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 767                 time = serverprevtime + serverdeltatime;
 768         }
 769
 770 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 771         if(self.enttype)
 772         {
 773                 if(t != self.enttype || bIsNewEntity)
 774                 {
 775                         //print("A CSQC entity changed its type!\n");
 776                         print(sprintf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t));
 777                         Ent_Remove();
 778                         clearentity(self);
 779                         bIsNewEntity = 1;
 780                 }
 781         }
 782         else
 783         {
 784                 if(!bIsNewEntity)
 785                 {
 786                         print(sprintf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t));
 787                         bIsNewEntity = 1;
 788                 }
 789         }
 790 #endif
 791         self.enttype = t;
 792         switch(t)
 793         {
 794                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 795                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 796                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 797                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 798                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 799                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 800                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 801                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 802                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 803                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 804                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 805                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 806                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 807                 case ENT_CLIENT_INIT: Ent_Init(); break;
 808                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 809                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 810                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 811                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 812                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 813                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 814                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 815                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 816                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 817                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 818                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 819                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 820                 case ENT_CLIENT_ARC_BEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_ARC_BEAM); break;
 821                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 822                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 823                 case ENT_CLIENT_TURRET: ent_turret(); break;
 824                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 825                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 826                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 827                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 828                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 829                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 830
 831                 default:
 832                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 833                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 834                         break;
 835         }
 836
 837         time = savetime;
 838 }
 839 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 840 // used when an entity changes its type. For an entity that someone interacts
 841 // with others, make sure it can no longer do so.
 842 void Ent_Remove()
 843 {
 844         if(self.entremove)
 845                 self.entremove();
 846
 847         if(self.skeletonindex)
 848         {
 849                 skel_delete(self.skeletonindex);
 850                 self.skeletonindex = 0;
 851         }
 852
 853         if(self.snd_looping > 0)
 854         {
 855                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 856                 self.snd_looping = 0;
 857         }
 858
 859         self.enttype = 0;
 860         self.classname = "";
 861         self.draw = menu_sub_null;
 862         self.entremove = menu_sub_null;
 863         // TODO possibly set more stuff to defaults
 864 }
 865 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 866 void CSQC_Ent_Remove()
 867 {
 868         if(autocvar_developer_csqcentities)
 869                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 870
 871         if(wasfreed(self))
 872         {
 873                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 874                 return;
 875         }
 876         if(self.enttype)
 877                 Ent_Remove();
 878         remove(self);
 879 }
 880
 881 void Gamemode_Init()
 882 {
 883         if (!isdemo())
 884         {
 885                 if(!(calledhooks & HOOK_START))
 886                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 887                 calledhooks |= HOOK_START;
 888         }
 889 }
 890 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 891 void CSQC_Parse_StuffCmd(string strMessage)
 892 {
 893         if(autocvar_developer_csqcentities)
 894                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 895
 896         localcmd(strMessage);
 897 }
 898 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 899 void CSQC_Parse_Print(string strMessage)
 900 {
 901         if(autocvar_developer_csqcentities)
 902                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 903
 904         print(ColorTranslateRGB(strMessage));
 905 }
 906
 907 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 908 void CSQC_Parse_CenterPrint(string strMessage)
 909 {
 910         if(autocvar_developer_csqcentities)
 911                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 912
 913         centerprint_hud(strMessage);
 914 }
 915
 916 string notranslate_fogcmd1 = "\nfog ";
 917 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 918 void Fog_Force()
 919 {
 920         // TODO somehow thwart prvm_globalset client ...
 921
 922         if(forcefog != "")
 923                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 924 }
 925
 926 void Gamemode_Init();
 927 void Ent_ScoresInfo()
 928 {
 929         float i;
 930         self.classname = "ent_client_scores_info";
 931         gametype = ReadInt24_t();
 932         for(i = 0; i < MAX_SCORE; ++i)
 933         {
 934                 scores_label[i] = strzone(ReadString());
 935                 scores_flags[i] = ReadByte();
 936         }
 937         for(i = 0; i < MAX_TEAMSCORE; ++i)
 938         {
 939                 teamscores_label[i] = strzone(ReadString());
 940                 teamscores_flags[i] = ReadByte();
 941         }
 942         HUD_InitScores();
 943         Gamemode_Init();
 944 }
 945
 946 void Ent_Init()
 947 {
 948         self.classname = "ent_client_init";
 949
 950         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 951
 952         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 953         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 954         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 955         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 956         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 957         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 958         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 959         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 960
 961         if(forcefog)
 962                 strunzone(forcefog);
 963         forcefog = strzone(ReadString());
 964
 965         armorblockpercent = ReadByte() / 255.0;
 966
 967         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 968         g_balance_grenadelauncher_bouncestop = ReadCoord();
 969         g_balance_electro_secondary_bouncefactor = ReadCoord();
 970         g_balance_electro_secondary_bouncestop = ReadCoord();
 971
 972         vortex_scope = !ReadByte();
 973         rifle_scope = !ReadByte();
 974
 975         serverflags = ReadByte();
 976
 977         minelayer_maxmines = ReadByte();
 978
 979         hagar_maxrockets = ReadByte();
 980
 981         g_trueaim_minrange = ReadCoord();
 982         g_balance_porto_secondary = ReadByte();
 983
 984         if(!postinit)
 985                 PostInit();
 986 }
 987
 988 void Net_ReadRace()
 989 {
 990         float b;
 991
 992         b = ReadByte();
 993
 994         switch(b)
 995         {
 996                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 997                         race_checkpoint = ReadByte();
 998                         race_time = ReadInt24_t();
 999                         race_previousbesttime = ReadInt24_t();
1000                         if(race_previousbestname)
1001                                 strunzone(race_previousbestname);
1002                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1003
1004                         race_checkpointtime = time;
1005
1006                         if(race_checkpoint == 0 || race_checkpoint == 254)
1007                         {
1008                                 race_penaltyaccumulator = 0;
1009                                 race_laptime = time; // valid
1010                         }
1011
1012                         break;
1013
1014                 case RACE_NET_CHECKPOINT_CLEAR:
1015                         race_laptime = 0;
1016                         race_checkpointtime = 0;
1017                         break;
1018
1019                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1020                         race_laptime = ReadCoord();
1021                         race_checkpointtime = -99999;
1022                         // fall through
1023                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1024                         race_nextcheckpoint = ReadByte();
1025
1026                         race_nextbesttime = ReadInt24_t();
1027                         if(race_nextbestname)
1028                                 strunzone(race_nextbestname);
1029                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1030                         break;
1031
1032                 case RACE_NET_CHECKPOINT_HIT_RACE:
1033                         race_mycheckpoint = ReadByte();
1034                         race_mycheckpointtime = time;
1035                         race_mycheckpointdelta = ReadInt24_t();
1036                         race_mycheckpointlapsdelta = ReadByte();
1037                         if(race_mycheckpointlapsdelta >= 128)
1038                                 race_mycheckpointlapsdelta -= 256;
1039                         if(race_mycheckpointenemy)
1040                                 strunzone(race_mycheckpointenemy);
1041                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1042                         break;
1043
1044                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1045                         race_othercheckpoint = ReadByte();
1046                         race_othercheckpointtime = time;
1047                         race_othercheckpointdelta = ReadInt24_t();
1048                         race_othercheckpointlapsdelta = ReadByte();
1049                         if(race_othercheckpointlapsdelta >= 128)
1050                                 race_othercheckpointlapsdelta -= 256;
1051                         if(race_othercheckpointenemy)
1052                                 strunzone(race_othercheckpointenemy);
1053                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1054                         break;
1055
1056                 case RACE_NET_PENALTY_RACE:
1057                         race_penaltyeventtime = time;
1058                         race_penaltytime = ReadShort();
1059                         //race_penaltyaccumulator += race_penaltytime;
1060                         if(race_penaltyreason)
1061                                 strunzone(race_penaltyreason);
1062                         race_penaltyreason = strzone(ReadString());
1063                         break;
1064
1065                 case RACE_NET_PENALTY_QUALIFYING:
1066                         race_penaltyeventtime = time;
1067                         race_penaltytime = ReadShort();
1068                         race_penaltyaccumulator += race_penaltytime;
1069                         if(race_penaltyreason)
1070                                 strunzone(race_penaltyreason);
1071                         race_penaltyreason = strzone(ReadString());
1072                         break;
1073
1074                 case RACE_NET_SERVER_RECORD:
1075                         race_server_record = ReadInt24_t();
1076                         break;
1077                 case RACE_NET_SPEED_AWARD:
1078                         race_speedaward = ReadInt24_t();
1079                         if(race_speedaward_holder)
1080                                 strunzone(race_speedaward_holder);
1081                         race_speedaward_holder = strzone(ReadString());
1082                         break;
1083                 case RACE_NET_SPEED_AWARD_BEST:
1084                         race_speedaward_alltimebest = ReadInt24_t();
1085                         if(race_speedaward_alltimebest_holder)
1086                                 strunzone(race_speedaward_alltimebest_holder);
1087                         race_speedaward_alltimebest_holder = strzone(ReadString());
1088                         break;
1089                 case RACE_NET_SERVER_RANKINGS:
1090                         float pos, prevpos, del;
1091                         pos = ReadShort();
1092                         prevpos = ReadShort();
1093                         del = ReadShort();
1094
1095                         // move other rankings out of the way
1096                         float i;
1097                         if (prevpos) {
1098                                 for (i=prevpos-1;i>pos-1;--i) {
1099                                         grecordtime[i] = grecordtime[i-1];
1100                                         if(grecordholder[i])
1101                                                 strunzone(grecordholder[i]);
1102                                         grecordholder[i] = strzone(grecordholder[i-1]);
1103                                 }
1104                         } else if (del) { // a record has been deleted by the admin
1105                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1106                                         if (i == RANKINGS_CNT-1) { // clear out last record
1107                                                 grecordtime[i] = 0;
1108                                                 if (grecordholder[i])
1109                                                         strunzone(grecordholder[i]);
1110                                                 grecordholder[i] = string_null;
1111                                         }
1112                                         else {
1113                                                 grecordtime[i] = grecordtime[i+1];
1114                                                 if (grecordholder[i])
1115                                                         strunzone(grecordholder[i]);
1116                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1117                                         }
1118                                 }
1119                         } else { // player has no ranked record yet
1120                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1121                                         grecordtime[i] = grecordtime[i-1];
1122                                         if(grecordholder[i])
1123                                                 strunzone(grecordholder[i]);
1124                                         grecordholder[i] = strzone(grecordholder[i-1]);
1125                                 }
1126                         }
1127
1128                         // store new ranking
1129                         if(grecordholder[pos-1] != "")
1130                                 strunzone(grecordholder[pos-1]);
1131                         grecordholder[pos-1] = strzone(ReadString());
1132                         grecordtime[pos-1] = ReadInt24_t();
1133                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1134                                 race_myrank = pos;
1135                         break;
1136                 case RACE_NET_SERVER_STATUS:
1137                         race_status = ReadShort();
1138                         if(race_status_name)
1139                                 strunzone(race_status_name);
1140                         race_status_name = strzone(ReadString());
1141         }
1142 }
1143
1144 void Net_TeamNagger()
1145 {
1146         teamnagger = 1;
1147 }
1148
1149 void Net_ReadPingPLReport()
1150 {
1151         float e, pi, pl, ml;
1152         e = ReadByte();
1153         pi = ReadShort();
1154         pl = ReadByte();
1155         ml = ReadByte();
1156         if (!(playerslots[e]))
1157                 return;
1158         playerslots[e].ping = pi;
1159         playerslots[e].ping_packetloss = pl / 255.0;
1160         playerslots[e].ping_movementloss = ml / 255.0;
1161 }
1162
1163 void Net_WeaponComplain()
1164 {
1165         complain_weapon = ReadByte();
1166
1167         if(complain_weapon_name)
1168                 strunzone(complain_weapon_name);
1169         complain_weapon_name = strzone(W_Name(complain_weapon));
1170
1171         complain_weapon_type = ReadByte();
1172
1173         complain_weapon_time = time;
1174         weapontime = time; // ping the weapon panel
1175
1176         switch(complain_weapon_type)
1177         {
1178                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1179                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1180                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1181         }
1182 }
1183
1184 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1185 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1186 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1187 float CSQC_Parse_TempEntity()
1188 {
1189         float bHandled;
1190                 bHandled  = true;
1191         // Acquire TE ID
1192         float nTEID;
1193                 nTEID = ReadByte();
1194
1195         if(autocvar_developer_csqcentities)
1196                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1197
1198                 // NOTE: Could just do return instead of break...
1199         switch(nTEID)
1200         {
1201                 case TE_CSQC_TARGET_MUSIC:
1202                         Net_TargetMusic();
1203                         bHandled = true;
1204                         break;
1205                 case TE_CSQC_PICTURE:
1206                         Net_MapVote_Picture();
1207                         bHandled = true;
1208                         break;
1209                 case TE_CSQC_RACE:
1210                         Net_ReadRace();
1211                         bHandled = true;
1212                         break;
1213                 case TE_CSQC_VORTEXBEAMPARTICLE:
1214                         Net_ReadVortexBeamParticle();
1215                         bHandled = true;
1216                         break;
1217                 case TE_CSQC_TEAMNAGGER:
1218                         Net_TeamNagger();
1219                         bHandled = true;
1220                         break;
1221                 case TE_CSQC_ARC:
1222                         Net_ReadArc();
1223                         bHandled = true;
1224                         break;
1225                 case TE_CSQC_PINGPLREPORT:
1226                         Net_ReadPingPLReport();
1227                         bHandled = true;
1228                         break;
1229                 case TE_CSQC_WEAPONCOMPLAIN:
1230                         Net_WeaponComplain();
1231                         bHandled = true;
1232                         break;
1233                 case TE_CSQC_VEHICLESETUP:
1234                         Net_VehicleSetup();
1235                         bHandled = true;
1236                         break;
1237                 case TE_CSQC_SVNOTICE:
1238                         cl_notice_read();
1239                         bHandled = true;
1240                         break;
1241                 case TE_CSQC_SHOCKWAVEPARTICLE:
1242                         Net_ReadShockwaveParticle();
1243                         bHandled = true;
1244                         break;
1245                 default:
1246                         // No special logic for this temporary entity; return 0 so the engine can handle it
1247                         bHandled = false;
1248                         break;
1249         }
1250
1251         return bHandled;
1252 }
1253
1254 string getcommandkey(string text, string command)
1255 {
1256         string keys;
1257         float n, j, k, l = 0;
1258
1259         if (!autocvar_hud_showbinds)
1260                 return text;
1261
1262         keys = db_get(binddb, command);
1263         if (keys == "")
1264         {
1265                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1266                 for(j = 0; j < n; ++j)
1267                 {
1268                         k = stof(argv(j));
1269                         if(k != -1)
1270                         {
1271                                 if ("" == keys)
1272                                         keys = keynumtostring(k);
1273                                 else
1274                                         keys = strcat(keys, ", ", keynumtostring(k));
1275
1276                                 ++l;
1277                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1278                                         break;
1279                         }
1280
1281                 }
1282                 if (keys == "")
1283                         keys = "NO_KEY";
1284                 db_put(binddb, command, keys);
1285         }
1286
1287         if (keys == "NO_KEY") {
1288                 if (autocvar_hud_showbinds > 1)
1289                         return sprintf(_("%s (not bound)"), text);
1290                 else
1291                         return text;
1292         }
1293         else if (autocvar_hud_showbinds > 1)
1294                 return sprintf(_("%s (%s)"), text, keys);
1295         else
1296                 return keys;
1297 }