qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 string forcefog;
  36 void WaypointSprite_Load();
  37 void ConsoleCommand_macro_init();
  38 void CSQC_Init(void)
  39 {
  40         prvm_language = cvar_string("prvm_language");
  41 #ifdef USE_FTE
  42 #pragma target ID
  43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  44         if(!__engine_check)
  45         {
  46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  47                 localcmd("\ndisconnect\n");
  48                 return;
  49         }
  50 #pragma target FTE
  51 #endif
  52
  53         check_unacceptable_compiler_bugs();
  54
  55 #ifdef WATERMARK
  56         printf(_("^4CSQC Build information: ^1%s\n"), WATERMARK);
  57 #endif
  58
  59         float i;
  60
  61 #ifdef COMPAT_XON050_ENGINE
  62         // old engine lacks implementation of player_localnum
  63         player_localnum = player_localentnum - 1;
  64 #endif
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         registercvar("cl_nade_type", "3");
  91         registercvar("cl_pokenade_type", "zombie");
  92
  93         gametype = 0;
  94
  95         // hud_fields uses strunzone on the titles!
  96         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  97                 hud_title[i] = strzone("(null)");
  98
  99         postinit = false;
 100
 101         calledhooks = 0;
 102
 103         teams = Sort_Spawn();
 104         players = Sort_Spawn();
 105
 106         GetTeam(NUM_SPECTATOR, true); // add specs first
 107
 108         // needs to be done so early because of the constants they create
 109         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 110         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 111         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 112         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 113         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 114         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 115         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 116
 117         WaypointSprite_Load();
 118
 119         // precaches
 120         precache_model("null");
 121         precache_sound("misc/hit.wav");
 122         precache_sound("misc/typehit.wav");
 123
 124         Projectile_Precache();
 125         Hook_Precache();
 126         GibSplash_Precache();
 127         Casings_Precache();
 128         DamageInfo_Precache();
 129         Vehicles_Precache();
 130         turrets_precache();
 131         Tuba_Precache();
 132         CSQCPlayer_Precache();
 133
 134         if(autocvar_cl_reticle)
 135         {
 136                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 137                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 138         }
 139
 140         get_mi_min_max_texcoords(1); // try the CLEVER way first
 141         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 142         shortmapname = mi_shortname;
 143
 144         if(precache_pic(minimapname) == "")
 145         {
 146                 // but maybe we have a non-clever minimap
 147                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 148                 if(precache_pic(minimapname) == "")
 149                         minimapname = ""; // FAIL
 150                 else
 151                         get_mi_min_max_texcoords(0); // load new texcoords
 152         }
 153
 154         mi_center = (mi_min + mi_max) * 0.5;
 155         mi_scale = mi_max - mi_min;
 156         minimapname = strzone(minimapname);
 157
 158         WarpZone_Init();
 159
 160         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 161         hud_configure_prev = -1;
 162
 163         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 164 }
 165
 166 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 167 void Shutdown(void)
 168 {
 169 #ifdef USE_FTE
 170 #pragma TARGET id
 171         if(!__engine_check)
 172                 return 0;
 173 #pragma TARGET fte
 174 #endif
 175
 176         WarpZone_Shutdown();
 177
 178         remove(teams);
 179         remove(players);
 180         db_close(binddb);
 181         db_close(tempdb);
 182         if(autocvar_cl_db_saveasdump)
 183                 db_dump(ClientProgsDB, "client.db");
 184         else
 185                 db_save(ClientProgsDB, "client.db");
 186         db_close(ClientProgsDB);
 187
 188         if(camera_active)
 189                 cvar_set("chase_active",ftos(chase_active_backup));
 190
 191         // unset the event chasecam's chase_active
 192         if(autocvar_chase_active < 0)
 193                 cvar_set("chase_active", "0");
 194
 195         if (!isdemo())
 196         {
 197                 if (!(calledhooks & HOOK_START))
 198                         localcmd("\n_cl_hook_gamestart nop\n");
 199                 if (!(calledhooks & HOOK_END))
 200                         localcmd("\ncl_hook_gameend\n");
 201         }
 202 }
 203
 204 .float has_team;
 205 float SetTeam(entity o, float Team)
 206 {
 207         entity tm;
 208         if(teamplay)
 209         {
 210                 switch(Team)
 211                 {
 212                         case -1:
 213                         case NUM_TEAM_1:
 214                         case NUM_TEAM_2:
 215                         case NUM_TEAM_3:
 216                         case NUM_TEAM_4:
 217                                 break;
 218                         default:
 219                                 if(GetTeam(Team, false) == world)
 220                                 {
 221                                         dprintf("trying to switch to unsupported team %d\n", Team);
 222                                         Team = NUM_SPECTATOR;
 223                                 }
 224                                 break;
 225                 }
 226         }
 227         else
 228         {
 229                 switch(Team)
 230                 {
 231                         case -1:
 232                         case 0:
 233                                 break;
 234                         default:
 235                                 if(GetTeam(Team, false) == world)
 236                                 {
 237                                         dprintf("trying to switch to unsupported team %d\n", Team);
 238                                         Team = NUM_SPECTATOR;
 239                                 }
 240                                 break;
 241                 }
 242         }
 243         if(Team == -1) // leave
 244         {
 245                 if(o.has_team)
 246                 {
 247                         tm = GetTeam(o.team, false);
 248                         tm.team_size -= 1;
 249                         o.has_team = 0;
 250                         return TRUE;
 251                 }
 252         }
 253         else
 254         {
 255                 if (!o.has_team)
 256                 {
 257                         o.team = Team;
 258                         tm = GetTeam(Team, true);
 259                         tm.team_size += 1;
 260                         o.has_team = 1;
 261                         return TRUE;
 262                 }
 263                 else if(Team != o.team)
 264                 {
 265                         tm = GetTeam(o.team, false);
 266                         tm.team_size -= 1;
 267                         o.team = Team;
 268                         tm = GetTeam(Team, true);
 269                         tm.team_size += 1;
 270                         return TRUE;
 271                 }
 272         }
 273         return FALSE;
 274 }
 275
 276 void Playerchecker_Think()
 277 {
 278         float i;
 279         entity e;
 280         for(i = 0; i < maxclients; ++i)
 281         {
 282                 e = playerslots[i];
 283                 if(GetPlayerName(i) == "")
 284                 {
 285                         if(e.sort_prev)
 286                         {
 287                                 // player disconnected
 288                                 SetTeam(e, -1);
 289                                 RemovePlayer(e);
 290                                 e.sort_prev = world;
 291                                 //e.gotscores = 0;
 292                         }
 293                 }
 294                 else
 295                 {
 296                         if (!e.sort_prev)
 297                         {
 298                                 // player connected
 299                                 if (!e)
 300                                         playerslots[i] = e = spawn();
 301                                 e.sv_entnum = i;
 302                                 e.ping = 0;
 303                                 e.ping_packetloss = 0;
 304                                 e.ping_movementloss = 0;
 305                                 //e.gotscores = 0; // we might already have the scores...
 306                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 307                                 RegisterPlayer(e);
 308                                 HUD_UpdatePlayerPos(e);
 309                         }
 310                 }
 311         }
 312         self.nextthink = time + 0.2;
 313 }
 314
 315 void Porto_Init();
 316 void TrueAim_Init();
 317 void PostInit(void)
 318 {
 319         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 320
 321         entity playerchecker;
 322         playerchecker = spawn();
 323         playerchecker.think = Playerchecker_Think;
 324         playerchecker.nextthink = time + 0.2;
 325
 326         Porto_Init();
 327         TrueAim_Init();
 328
 329         postinit = true;
 330 }
 331
 332 float button_zoom;
 333
 334 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 335 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 336 // All keys are in ascii.
 337 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 338 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 339 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 340 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 341 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 342 {
 343         float bSkipKey;
 344         bSkipKey = false;
 345
 346         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 347                 return true;
 348
 349         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 350                 return true;
 351
 352         if(menu_visible && menu_action)
 353                 if(menu_action(bInputType, nPrimary, nSecondary))
 354                         return TRUE;
 355
 356         return bSkipKey;
 357 }
 358
 359 // END REQUIRED CSQC FUNCTIONS
 360 // --------------------------------------------------------------------------
 361
 362 // --------------------------------------------------------------------------
 363 // BEGIN OPTIONAL CSQC FUNCTIONS
 364 void Ent_RemoveEntCS()
 365 {
 366         entcs_receiver[self.sv_entnum] = world;
 367 }
 368 void Ent_ReadEntCS()
 369 {
 370         float sf;
 371         InterpolateOrigin_Undo();
 372
 373         self.classname = "entcs_receiver";
 374         sf = ReadByte();
 375
 376         if(sf & 1)
 377                 self.sv_entnum = ReadByte();
 378         if(sf & 2)
 379         {
 380                 self.origin_x = ReadShort();
 381                 self.origin_y = ReadShort();
 382                 self.origin_z = ReadShort();
 383                 setorigin(self, self.origin);
 384         }
 385         if(sf & 4)
 386         {
 387                 self.angles_y = ReadByte() * 360.0 / 256;
 388                 self.angles_x = self.angles_z = 0;
 389         }
 390         if(sf & 8)
 391                 self.healthvalue = ReadByte() * 10;
 392         if(sf & 16)
 393                 self.armorvalue = ReadByte() * 10;
 394
 395         entcs_receiver[self.sv_entnum] = self;
 396         self.entremove = Ent_RemoveEntCS;
 397         self.iflags |= IFLAG_ORIGIN;
 398
 399         InterpolateOrigin_Note();
 400 }
 401
 402 void Ent_Remove();
 403
 404 void Ent_RemovePlayerScore()
 405 {
 406         float i;
 407
 408         if(self.owner)
 409         {
 410                 SetTeam(self.owner, -1);
 411                 self.owner.gotscores = 0;
 412                 for(i = 0; i < MAX_SCORE; ++i)
 413                         self.owner.(scores[i]) = 0; // clear all scores
 414         }
 415 }
 416
 417 void Ent_ReadPlayerScore()
 418 {
 419         float i, n;
 420         float isNew;
 421         entity o;
 422
 423         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 424         // (no I've never heard of M-x replace-string, sed, or anything like that)
 425         isNew = !self.owner; // workaround for DP bug
 426         n = ReadByte()-1;
 427
 428 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 429         if(!isNew && n != self.sv_entnum)
 430         {
 431                 //print("A CSQC entity changed its owner!\n");
 432                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 433                 isNew = true;
 434                 Ent_Remove();
 435                 self.enttype = ENT_CLIENT_SCORES;
 436         }
 437 #endif
 438
 439         self.sv_entnum = n;
 440
 441         if (!(playerslots[self.sv_entnum]))
 442                 playerslots[self.sv_entnum] = spawn();
 443         o = self.owner = playerslots[self.sv_entnum];
 444         o.sv_entnum = self.sv_entnum;
 445         o.gotscores = 1;
 446
 447         //if (!o.sort_prev)
 448         //      RegisterPlayer(o);
 449         //playerchecker will do this for us later, if it has not already done so
 450
 451         float sf, lf;
 452 #if MAX_SCORE <= 8
 453         sf = ReadByte();
 454         lf = ReadByte();
 455 #else
 456         sf = ReadShort();
 457         lf = ReadShort();
 458 #endif
 459         float p;
 460         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 461                 if(sf & p)
 462                 {
 463                         if(lf & p)
 464                                 o.(scores[i]) = ReadInt24_t();
 465                         else
 466                                 o.(scores[i]) = ReadChar();
 467                 }
 468
 469         if(o.sort_prev)
 470                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 471
 472         self.entremove = Ent_RemovePlayerScore;
 473 }
 474
 475 void Ent_ReadTeamScore()
 476 {
 477         float i;
 478         entity o;
 479
 480         self.team = ReadByte();
 481         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 482
 483         float sf, lf;
 484 #if MAX_TEAMSCORE <= 8
 485         sf = ReadByte();
 486         lf = ReadByte();
 487 #else
 488         sf = ReadShort();
 489         lf = ReadShort();
 490 #endif
 491         float p;
 492         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 493                 if(sf & p)
 494                 {
 495                         if(lf & p)
 496                                 o.(teamscores[i]) = ReadInt24_t();
 497                         else
 498                                 o.(teamscores[i]) = ReadChar();
 499                 }
 500
 501         HUD_UpdateTeamPos(o);
 502 }
 503
 504 void Ent_ClientData()
 505 {
 506         float f;
 507         float newspectatee_status;
 508
 509         f = ReadByte();
 510
 511         scoreboard_showscores_force = (f & 1);
 512
 513         if(f & 2)
 514         {
 515                 newspectatee_status = ReadByte();
 516                 if(newspectatee_status == player_localnum + 1)
 517                         newspectatee_status = -1; // observing
 518         }
 519         else
 520                 newspectatee_status = 0;
 521
 522         spectatorbutton_zoom = (f & 4);
 523
 524         if(f & 8)
 525         {
 526                 angles_held_status = 1;
 527                 angles_held_x = ReadAngle();
 528                 angles_held_y = ReadAngle();
 529                 angles_held_z = 0;
 530         }
 531         else
 532                 angles_held_status = 0;
 533
 534         if(newspectatee_status != spectatee_status)
 535         {
 536                 // clear race stuff
 537                 race_laptime = 0;
 538                 race_checkpointtime = 0;
 539         }
 540         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 541         {
 542                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 543                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 544                 )
 545                         prev_p_health = -1;
 546                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 547                         prev_health = -1;
 548         }
 549         spectatee_status = newspectatee_status;
 550
 551         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 552 }
 553
 554 void Ent_Nagger()
 555 {
 556         float nags, i, j, b, f;
 557
 558         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 559
 560         if(!(nags & 4))
 561         {
 562                 if(vote_called_vote)
 563                         strunzone(vote_called_vote);
 564                 vote_called_vote = string_null;
 565                 vote_active = 0;
 566         }
 567         else
 568         {
 569                 vote_active = 1;
 570         }
 571
 572         if(nags & 64)
 573         {
 574                 vote_yescount = ReadByte();
 575                 vote_nocount = ReadByte();
 576                 vote_needed = ReadByte();
 577                 vote_highlighted = ReadChar();
 578         }
 579
 580         if(nags & 128)
 581         {
 582                 if(vote_called_vote)
 583                         strunzone(vote_called_vote);
 584                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 585         }
 586
 587         if(nags & 1)
 588         {
 589                 for(j = 0; j < maxclients; ++j)
 590                         if(playerslots[j])
 591                                 playerslots[j].ready = 1;
 592                 for(i = 1; i <= maxclients; i += 8)
 593                 {
 594                         f = ReadByte();
 595                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 596                                 if (!(f & b))
 597                                         if(playerslots[j])
 598                                                 playerslots[j].ready = 0;
 599                 }
 600         }
 601
 602         ready_waiting = (nags & 1);
 603         ready_waiting_for_me = (nags & 2);
 604         vote_waiting = (nags & 4);
 605         vote_waiting_for_me = (nags & 8);
 606         warmup_stage = (nags & 16);
 607 }
 608
 609 void Ent_RandomSeed()
 610 {
 611         float s;
 612         prandom_debug();
 613         s = ReadShort();
 614         psrandom(s);
 615 }
 616
 617 void Ent_ReadAccuracy(void)
 618 {
 619         float sf, f, w, b;
 620         sf = ReadInt24_t();
 621         if(sf == 0)
 622         {
 623                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 624                         weapon_accuracy[w] = -1;
 625                 return;
 626         }
 627
 628         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 629         {
 630                 if(sf & f)
 631                 {
 632                         b = ReadByte();
 633                         if(b == 0)
 634                                 weapon_accuracy[w] = -1;
 635                         else if(b == 255)
 636                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 637                         else
 638                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 639                 }
 640                 if(f == 0x800000)
 641                         f = 1;
 642                 else
 643                         f *= 2;
 644         }
 645 }
 646
 647 void Spawn_Draw(void)
 648 {
 649         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 650 }
 651
 652 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 653 {
 654         float teamnum = (ReadByte() - 1);
 655         vector spn_origin;
 656         spn_origin_x = ReadShort();
 657         spn_origin_y = ReadShort();
 658         spn_origin_z = ReadShort();
 659
 660         if(is_new)
 661         {
 662                 self.origin = spn_origin;
 663                 setsize(self, PL_MIN, PL_MAX);
 664                 droptofloor();
 665
 666                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 667                 {
 668                         self.mdl = "models/spawnpoint.md3";
 669                         self.colormod = Team_ColorRGB(teamnum);
 670                         precache_model(self.mdl);
 671                         setmodel(self, self.mdl);
 672                         self.drawmask = MASK_NORMAL;
 673                         //self.movetype = MOVETYPE_NOCLIP;
 674                         //self.draw = Spawn_Draw;
 675                 }*/
 676                 if(autocvar_cl_spawn_point_particles)
 677                 {
 678                         if((serverflags & SERVERFLAG_TEAMPLAY))
 679                         {
 680                                 switch(teamnum)
 681                                 {
 682                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 683                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 684                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 685                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 686                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 687                                 }
 688                         }
 689                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 690
 691                         self.draw = Spawn_Draw;
 692                 }
 693         }
 694
 695         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 696 }
 697
 698 void Ent_ReadSpawnEvent(float is_new)
 699 {
 700         // If entnum is 0, ONLY do the local spawn actions
 701         // this way the server can disable the sending of
 702         // spawn origin or such to clients if wanted.
 703         float entnum = ReadByte();
 704
 705         if(entnum)
 706         {
 707                 self.origin_x = ReadShort();
 708                 self.origin_y = ReadShort();
 709                 self.origin_z = ReadShort();
 710
 711                 if(is_new)
 712                 {
 713                         float teamnum = GetPlayerColor(entnum - 1);
 714
 715                         if(autocvar_cl_spawn_event_particles)
 716                         {
 717                                 switch(teamnum)
 718                                 {
 719                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 720                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 721                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 722                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 723                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 724                                 }
 725                         }
 726                         if(autocvar_cl_spawn_event_sound)
 727                         {
 728                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 729                         }
 730                 }
 731         }
 732
 733         // local spawn actions
 734         if(is_new && (!entnum || (entnum == player_localentnum)))
 735         {
 736                 zoomin_effect = 1;
 737                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 738
 739                 if(autocvar_cl_unpress_zoom_on_spawn)
 740                 {
 741                         localcmd("-zoom\n");
 742                         button_zoom = FALSE;
 743                 }
 744         }
 745
 746         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 747 }
 748
 749 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 750 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 751 void Ent_RadarLink();
 752 void Ent_Init();
 753 void Ent_ScoresInfo();
 754 void CSQC_Ent_Update(float bIsNewEntity)
 755 {
 756         float t;
 757         float savetime;
 758         t = ReadByte();
 759
 760         if(autocvar_developer_csqcentities)
 761                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 762
 763         // set up the "time" global for received entities to be correct for interpolation purposes
 764         savetime = time;
 765         if(servertime)
 766         {
 767                 time = servertime;
 768         }
 769         else
 770         {
 771                 serverprevtime = time;
 772                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 773                 time = serverprevtime + serverdeltatime;
 774         }
 775
 776 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 777         if(self.enttype)
 778         {
 779                 if(t != self.enttype || bIsNewEntity)
 780                 {
 781                         //print("A CSQC entity changed its type!\n");
 782                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 783                         Ent_Remove();
 784                         clearentity(self);
 785                         bIsNewEntity = 1;
 786                 }
 787         }
 788         else
 789         {
 790                 if(!bIsNewEntity)
 791                 {
 792                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 793                         bIsNewEntity = 1;
 794                 }
 795         }
 796 #endif
 797         self.enttype = t;
 798         switch(t)
 799         {
 800                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 801                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 802                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 803                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 804                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 805                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 806                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 807                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 808                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 809                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 810                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 811                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 812                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 813                 case ENT_CLIENT_INIT: Ent_Init(); break;
 814                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 815                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 816                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 817                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 818                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 819                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 820                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 821                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 822                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 823                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 824                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 825                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 826                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 827                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 828                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 829                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 830                 case ENT_CLIENT_TURRET: ent_turret(); break;
 831                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 832                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 833                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 834                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 835                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 836                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 837
 838                 default:
 839                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 840                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 841                         break;
 842         }
 843
 844         time = savetime;
 845 }
 846 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 847 // used when an entity changes its type. For an entity that someone interacts
 848 // with others, make sure it can no longer do so.
 849 void Ent_Remove()
 850 {
 851         if(self.entremove)
 852                 self.entremove();
 853
 854         if(self.skeletonindex)
 855         {
 856                 skel_delete(self.skeletonindex);
 857                 self.skeletonindex = 0;
 858         }
 859
 860         if(self.snd_looping > 0)
 861         {
 862                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 863                 self.snd_looping = 0;
 864         }
 865
 866         self.enttype = 0;
 867         self.classname = "";
 868         self.draw = menu_sub_null;
 869         self.entremove = menu_sub_null;
 870         // TODO possibly set more stuff to defaults
 871 }
 872 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 873 void CSQC_Ent_Remove()
 874 {
 875         if(autocvar_developer_csqcentities)
 876                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 877
 878         if(wasfreed(self))
 879         {
 880                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 881                 return;
 882         }
 883         if(self.enttype)
 884                 Ent_Remove();
 885         remove(self);
 886 }
 887
 888 void Gamemode_Init()
 889 {
 890         if (!isdemo())
 891         {
 892                 if(!(calledhooks & HOOK_START))
 893                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 894                 calledhooks |= HOOK_START;
 895         }
 896 }
 897 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 898 void CSQC_Parse_StuffCmd(string strMessage)
 899 {
 900         if(autocvar_developer_csqcentities)
 901                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 902
 903         localcmd(strMessage);
 904 }
 905 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 906 void CSQC_Parse_Print(string strMessage)
 907 {
 908         if(autocvar_developer_csqcentities)
 909                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 910
 911         print(ColorTranslateRGB(strMessage));
 912 }
 913
 914 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 915 void CSQC_Parse_CenterPrint(string strMessage)
 916 {
 917         if(autocvar_developer_csqcentities)
 918                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 919
 920         centerprint_hud(strMessage);
 921 }
 922
 923 string notranslate_fogcmd1 = "\nfog ";
 924 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 925 void Fog_Force()
 926 {
 927         // TODO somehow thwart prvm_globalset client ...
 928
 929         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 930                 { localcmd("\nr_drawfog 0\n"); }
 931         else if(forcefog != "")
 932                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 933 }
 934
 935 void Gamemode_Init();
 936 void Ent_ScoresInfo()
 937 {
 938         float i;
 939         self.classname = "ent_client_scores_info";
 940         gametype = ReadInt24_t();
 941         HUD_ModIcons_SetFunc();
 942         for(i = 0; i < MAX_SCORE; ++i)
 943         {
 944                 scores_label[i] = strzone(ReadString());
 945                 scores_flags[i] = ReadByte();
 946         }
 947         for(i = 0; i < MAX_TEAMSCORE; ++i)
 948         {
 949                 teamscores_label[i] = strzone(ReadString());
 950                 teamscores_flags[i] = ReadByte();
 951         }
 952         HUD_InitScores();
 953         Gamemode_Init();
 954 }
 955
 956 void Ent_Init()
 957 {
 958         self.classname = "ent_client_init";
 959
 960         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 961
 962         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 963         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 964         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 965         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 966         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 967         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 968         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 969         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 970         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 971         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 972         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 973         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 974
 975         if(forcefog)
 976                 strunzone(forcefog);
 977         forcefog = strzone(ReadString());
 978
 979         armorblockpercent = ReadByte() / 255.0;
 980
 981         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 982         g_balance_grenadelauncher_bouncestop = ReadCoord();
 983         g_balance_electro_secondary_bouncefactor = ReadCoord();
 984         g_balance_electro_secondary_bouncestop = ReadCoord();
 985
 986         nex_scope = !ReadByte();
 987         rifle_scope = !ReadByte();
 988
 989         serverflags = ReadByte();
 990
 991         minelayer_maxmines = ReadByte();
 992
 993         hagar_maxrockets = ReadByte();
 994
 995         g_trueaim_minrange = ReadCoord();
 996         g_balance_porto_secondary = ReadByte();
 997
 998         if(!postinit)
 999                 PostInit();
1000 }
1001
1002 void Net_ReadRace()
1003 {
1004         float b;
1005
1006         b = ReadByte();
1007
1008         switch(b)
1009         {
1010                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1011                         race_checkpoint = ReadByte();
1012                         race_time = ReadInt24_t();
1013                         race_previousbesttime = ReadInt24_t();
1014                         if(race_previousbestname)
1015                                 strunzone(race_previousbestname);
1016                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1017
1018                         race_checkpointtime = time;
1019
1020                         if(race_checkpoint == 0 || race_checkpoint == 254)
1021                         {
1022                                 race_penaltyaccumulator = 0;
1023                                 race_laptime = time; // valid
1024                         }
1025
1026                         break;
1027
1028                 case RACE_NET_CHECKPOINT_CLEAR:
1029                         race_laptime = 0;
1030                         race_checkpointtime = 0;
1031                         break;
1032
1033                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1034                         race_laptime = ReadCoord();
1035                         race_checkpointtime = -99999;
1036                         // fall through
1037                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1038                         race_nextcheckpoint = ReadByte();
1039
1040                         race_nextbesttime = ReadInt24_t();
1041                         if(race_nextbestname)
1042                                 strunzone(race_nextbestname);
1043                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1044                         break;
1045
1046                 case RACE_NET_CHECKPOINT_HIT_RACE:
1047                         race_mycheckpoint = ReadByte();
1048                         race_mycheckpointtime = time;
1049                         race_mycheckpointdelta = ReadInt24_t();
1050                         race_mycheckpointlapsdelta = ReadByte();
1051                         if(race_mycheckpointlapsdelta >= 128)
1052                                 race_mycheckpointlapsdelta -= 256;
1053                         if(race_mycheckpointenemy)
1054                                 strunzone(race_mycheckpointenemy);
1055                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1056                         break;
1057
1058                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1059                         race_othercheckpoint = ReadByte();
1060                         race_othercheckpointtime = time;
1061                         race_othercheckpointdelta = ReadInt24_t();
1062                         race_othercheckpointlapsdelta = ReadByte();
1063                         if(race_othercheckpointlapsdelta >= 128)
1064                                 race_othercheckpointlapsdelta -= 256;
1065                         if(race_othercheckpointenemy)
1066                                 strunzone(race_othercheckpointenemy);
1067                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1068                         break;
1069
1070                 case RACE_NET_PENALTY_RACE:
1071                         race_penaltyeventtime = time;
1072                         race_penaltytime = ReadShort();
1073                         //race_penaltyaccumulator += race_penaltytime;
1074                         if(race_penaltyreason)
1075                                 strunzone(race_penaltyreason);
1076                         race_penaltyreason = strzone(ReadString());
1077                         break;
1078
1079                 case RACE_NET_PENALTY_QUALIFYING:
1080                         race_penaltyeventtime = time;
1081                         race_penaltytime = ReadShort();
1082                         race_penaltyaccumulator += race_penaltytime;
1083                         if(race_penaltyreason)
1084                                 strunzone(race_penaltyreason);
1085                         race_penaltyreason = strzone(ReadString());
1086                         break;
1087
1088                 case RACE_NET_SERVER_RECORD:
1089                         race_server_record = ReadInt24_t();
1090                         break;
1091                 case RACE_NET_SPEED_AWARD:
1092                         race_speedaward = ReadInt24_t();
1093                         if(race_speedaward_holder)
1094                                 strunzone(race_speedaward_holder);
1095                         race_speedaward_holder = strzone(ReadString());
1096                         break;
1097                 case RACE_NET_SPEED_AWARD_BEST:
1098                         race_speedaward_alltimebest = ReadInt24_t();
1099                         if(race_speedaward_alltimebest_holder)
1100                                 strunzone(race_speedaward_alltimebest_holder);
1101                         race_speedaward_alltimebest_holder = strzone(ReadString());
1102                         break;
1103                 case RACE_NET_SERVER_RANKINGS:
1104                         float pos, prevpos, del;
1105                         pos = ReadShort();
1106                         prevpos = ReadShort();
1107                         del = ReadShort();
1108
1109                         // move other rankings out of the way
1110                         float i;
1111                         if (prevpos) {
1112                                 for (i=prevpos-1;i>pos-1;--i) {
1113                                         grecordtime[i] = grecordtime[i-1];
1114                                         if(grecordholder[i])
1115                                                 strunzone(grecordholder[i]);
1116                                         grecordholder[i] = strzone(grecordholder[i-1]);
1117                                 }
1118                         } else if (del) { // a record has been deleted by the admin
1119                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1120                                         if (i == RANKINGS_CNT-1) { // clear out last record
1121                                                 grecordtime[i] = 0;
1122                                                 if (grecordholder[i])
1123                                                         strunzone(grecordholder[i]);
1124                                                 grecordholder[i] = string_null;
1125                                         }
1126                                         else {
1127                                                 grecordtime[i] = grecordtime[i+1];
1128                                                 if (grecordholder[i])
1129                                                         strunzone(grecordholder[i]);
1130                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1131                                         }
1132                                 }
1133                         } else { // player has no ranked record yet
1134                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1135                                         grecordtime[i] = grecordtime[i-1];
1136                                         if(grecordholder[i])
1137                                                 strunzone(grecordholder[i]);
1138                                         grecordholder[i] = strzone(grecordholder[i-1]);
1139                                 }
1140                         }
1141
1142                         // store new ranking
1143                         if(grecordholder[pos-1] != "")
1144                                 strunzone(grecordholder[pos-1]);
1145                         grecordholder[pos-1] = strzone(ReadString());
1146                         grecordtime[pos-1] = ReadInt24_t();
1147                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1148                                 race_myrank = pos;
1149                         break;
1150                 case RACE_NET_SERVER_STATUS:
1151                         race_status = ReadShort();
1152                         if(race_status_name)
1153                                 strunzone(race_status_name);
1154                         race_status_name = strzone(ReadString());
1155         }
1156 }
1157
1158 void Net_TeamNagger()
1159 {
1160         teamnagger = 1;
1161 }
1162
1163 void Net_ReadPingPLReport()
1164 {
1165         float e, pi, pl, ml;
1166         e = ReadByte();
1167         pi = ReadShort();
1168         pl = ReadByte();
1169         ml = ReadByte();
1170         if (!(playerslots[e]))
1171                 return;
1172         playerslots[e].ping = pi;
1173         playerslots[e].ping_packetloss = pl / 255.0;
1174         playerslots[e].ping_movementloss = ml / 255.0;
1175 }
1176
1177 void Net_WeaponComplain()
1178 {
1179         complain_weapon = ReadByte();
1180
1181         if(complain_weapon_name)
1182                 strunzone(complain_weapon_name);
1183         complain_weapon_name = strzone(ReadString());
1184
1185         complain_weapon_type = ReadByte();
1186
1187         complain_weapon_time = time;
1188         weapontime = time; // ping the weapon panel
1189
1190         switch(complain_weapon_type)
1191         {
1192                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1193                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1194                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1195         }
1196 }
1197
1198 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1199 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1200 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1201 float CSQC_Parse_TempEntity()
1202 {
1203         float bHandled;
1204                 bHandled  = true;
1205         // Acquire TE ID
1206         float nTEID;
1207                 nTEID = ReadByte();
1208
1209         if(autocvar_developer_csqcentities)
1210                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1211
1212                 // NOTE: Could just do return instead of break...
1213         switch(nTEID)
1214         {
1215                 case TE_CSQC_TARGET_MUSIC:
1216                         Net_TargetMusic();
1217                         bHandled = true;
1218                         break;
1219                 case TE_CSQC_PICTURE:
1220                         Net_MapVote_Picture();
1221                         bHandled = true;
1222                         break;
1223                 case TE_CSQC_RACE:
1224                         Net_ReadRace();
1225                         bHandled = true;
1226                         break;
1227                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1228                         Net_ReadNexgunBeamParticle();
1229                         bHandled = true;
1230                         break;
1231                 case TE_CSQC_TEAMNAGGER:
1232                         Net_TeamNagger();
1233                         bHandled = true;
1234                         break;
1235                 case TE_CSQC_LIGHTNINGARC:
1236                         Net_ReadLightningarc();
1237                         bHandled = true;
1238                         break;
1239                 case TE_CSQC_PINGPLREPORT:
1240                         Net_ReadPingPLReport();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_WEAPONCOMPLAIN:
1244                         Net_WeaponComplain();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_VEHICLESETUP:
1248                         Net_VehicleSetup();
1249                         bHandled = true;
1250                         break;
1251                 case TE_CSQC_SVNOTICE:
1252                         cl_notice_read();
1253                         bHandled = true;
1254                         break;
1255                 default:
1256                         // No special logic for this temporary entity; return 0 so the engine can handle it
1257                         bHandled = false;
1258                         break;
1259         }
1260
1261         return bHandled;
1262 }
1263
1264 string getcommandkey(string text, string command)
1265 {
1266         string keys;
1267         float n, j, k, l = 0;
1268
1269         if (!autocvar_hud_showbinds)
1270                 return text;
1271
1272         keys = db_get(binddb, command);
1273         if (keys == "")
1274         {
1275                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1276                 for(j = 0; j < n; ++j)
1277                 {
1278                         k = stof(argv(j));
1279                         if(k != -1)
1280                         {
1281                                 if ("" == keys)
1282                                         keys = keynumtostring(k);
1283                                 else
1284                                         keys = strcat(keys, ", ", keynumtostring(k));
1285
1286                                 ++l;
1287                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1288                                         break;
1289                         }
1290
1291                 }
1292                 if (keys == "")
1293                         keys = "NO_KEY";
1294                 db_put(binddb, command, keys);
1295         }
1296
1297         if (keys == "NO_KEY") {
1298                 if (autocvar_hud_showbinds > 1)
1299                         return sprintf(_("%s (not bound)"), text);
1300                 else
1301                         return text;
1302         }
1303         else if (autocvar_hud_showbinds > 1)
1304                 return sprintf(_("%s (%s)"), text, keys);
1305         else
1306                 return keys;
1307 }