qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90     cl_simple_items = autocvar_cl_simple_items;
  91 #ifdef USE_FTE
  92 #pragma target ID
  93         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  94         if(!__engine_check)
  95         {
  96                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  97                 localcmd("\ndisconnect\n");
  98                 return;
  99         }
 100 #pragma target FTE
 101 #endif
 102
 103         check_unacceptable_compiler_bugs();
 104
 105 #ifdef WATERMARK
 106         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
 107 #endif
 108
 109         float i;
 110
 111 #ifdef COMPAT_XON050_ENGINE
 112         // old engine lacks implementation of player_localnum
 113         player_localnum = player_localentnum - 1;
 114 #endif
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119         compressShortVector_init();
 120
 121         draw_endBoldFont();
 122         menu_visible = FALSE;
 123         menu_show = menu_show_error;
 124         menu_action = menu_sub_null;
 125
 126         for(i = 0; i < 255; ++i)
 127                 if(getplayerkeyvalue(i, "viewentity") == "")
 128                         break;
 129         maxclients = i;
 130
 131         //registercommand("hud_configure");
 132         //registercommand("hud_save");
 133         //registercommand("menu_action");
 134
 135         ConsoleCommand_macro_init();
 136
 137         registercvar("hud_usecsqc", "1");
 138         registercvar("scoreboard_columns", "default");
 139
 140         gametype = 0;
 141
 142         // hud_fields uses strunzone on the titles!
 143         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 144                 hud_title[i] = strzone("(null)");
 145
 146         postinit = false;
 147
 148         calledhooks = 0;
 149
 150         teams = Sort_Spawn();
 151         players = Sort_Spawn();
 152
 153         GetTeam(COLOR_SPECTATOR, true); // add specs first
 154
 155         // needs to be done so early because of the constants they create
 156         RegisterWeapons();
 157         RegisterGametypes();
 158
 159         WaypointSprite_Load();
 160
 161         // precaches
 162         precache_model("null");
 163         precache_sound("misc/hit.wav");
 164         precache_sound("misc/typehit.wav");
 165         if (autocvar_cl_precacheplayermodels)
 166         {
 167                 precache_all_playermodels("models/player/*.zym");
 168                 precache_all_playermodels("models/player/*.dpm");
 169                 precache_all_playermodels("models/player/*.md3");
 170                 precache_all_playermodels("models/player/*.psk");
 171                 precache_all_playermodels("models/player/*.iqm");
 172         }
 173
 174         Projectile_Precache();
 175         Hook_Precache();
 176         GibSplash_Precache();
 177         Casings_Precache();
 178         DamageInfo_Precache();
 179         Vehicles_Precache();
 180         turrets_precache();
 181     Announcer_Precache();
 182         Tuba_Precache();
 183
 184         if(autocvar_cl_reticle)
 185         {
 186                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 187                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 188         }
 189
 190         get_mi_min_max_texcoords(1); // try the CLEVER way first
 191         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 192         shortmapname = mi_shortname;
 193
 194         if(precache_pic(minimapname) == "")
 195         {
 196                 // but maybe we have a non-clever minimap
 197                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 198                 if(precache_pic(minimapname) == "")
 199                         minimapname = ""; // FAIL
 200                 else
 201                         get_mi_min_max_texcoords(0); // load new texcoords
 202         }
 203
 204         mi_center = (mi_min + mi_max) * 0.5;
 205         mi_scale = mi_max - mi_min;
 206         minimapname = strzone(minimapname);
 207
 208         WarpZone_Init();
 209
 210         hud_configure_prev = -1;
 211         tab_panel = -1;
 212
 213         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 214 }
 215
 216 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 217 void Shutdown(void)
 218 {
 219 #ifdef USE_FTE
 220 #pragma TARGET id
 221         if(!__engine_check)
 222                 return 0;
 223 #pragma TARGET fte
 224 #endif
 225
 226         WarpZone_Shutdown();
 227
 228         remove(teams);
 229         remove(players);
 230         db_close(binddb);
 231         db_close(tempdb);
 232         if(autocvar_cl_db_saveasdump)
 233                 db_dump(ClientProgsDB, "client.db");
 234         else
 235                 db_save(ClientProgsDB, "client.db");
 236         db_close(ClientProgsDB);
 237
 238         if(camera_active)
 239                 cvar_set("chase_active",ftos(chase_active_backup));
 240
 241         // unset the event chasecam's chase_active
 242         if(autocvar_chase_active < 0)
 243                 cvar_set("chase_active", "0");
 244
 245         if not(isdemo())
 246         {
 247                 if not(calledhooks & HOOK_START)
 248                         localcmd("\n_cl_hook_gamestart nop\n");
 249                 if not(calledhooks & HOOK_END)
 250                         localcmd("\ncl_hook_gameend\n");
 251         }
 252 }
 253
 254 .float has_team;
 255 float SetTeam(entity o, float Team)
 256 {
 257         entity tm;
 258         if(teamplay)
 259         {
 260                 switch(Team)
 261                 {
 262                         case -1:
 263                         case COLOR_TEAM1:
 264                         case COLOR_TEAM2:
 265                         case COLOR_TEAM3:
 266                         case COLOR_TEAM4:
 267                                 break;
 268                         default:
 269                                 if(GetTeam(Team, false) == world)
 270                                 {
 271                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 272                                         Team = COLOR_SPECTATOR;
 273                                 }
 274                                 break;
 275                 }
 276         }
 277         else
 278         {
 279                 switch(Team)
 280                 {
 281                         case -1:
 282                         case 0:
 283                                 break;
 284                         default:
 285                                 if(GetTeam(Team, false) == world)
 286                                 {
 287                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 288                                         Team = COLOR_SPECTATOR;
 289                                 }
 290                                 break;
 291                 }
 292         }
 293         if(Team == -1) // leave
 294         {
 295                 if(o.has_team)
 296                 {
 297                         tm = GetTeam(o.team, false);
 298                         tm.team_size -= 1;
 299                         o.has_team = 0;
 300                         return TRUE;
 301                 }
 302         }
 303         else
 304         {
 305                 if not(o.has_team)
 306                 {
 307                         o.team = Team;
 308                         tm = GetTeam(Team, true);
 309                         tm.team_size += 1;
 310                         o.has_team = 1;
 311                         return TRUE;
 312                 }
 313                 else if(Team != o.team)
 314                 {
 315                         tm = GetTeam(o.team, false);
 316                         tm.team_size -= 1;
 317                         o.team = Team;
 318                         tm = GetTeam(Team, true);
 319                         tm.team_size += 1;
 320                         return TRUE;
 321                 }
 322         }
 323         return FALSE;
 324 }
 325
 326 void Playerchecker_Think()
 327 {
 328         float i;
 329         entity e;
 330         for(i = 0; i < maxclients; ++i)
 331         {
 332                 e = playerslots[i];
 333                 if(GetPlayerName(i) == "")
 334                 {
 335                         if(e.sort_prev)
 336                         {
 337                                 // player disconnected
 338                                 SetTeam(e, -1);
 339                                 RemovePlayer(e);
 340                                 e.sort_prev = world;
 341                                 //e.gotscores = 0;
 342                         }
 343                 }
 344                 else
 345                 {
 346                         if not(e.sort_prev)
 347                         {
 348                                 // player connected
 349                                 if not(e)
 350                                         playerslots[i] = e = spawn();
 351                                 e.sv_entnum = i;
 352                                 e.ping = 0;
 353                                 e.ping_packetloss = 0;
 354                                 e.ping_movementloss = 0;
 355                                 //e.gotscores = 0; // we might already have the scores...
 356                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 357                                 RegisterPlayer(e);
 358                                 HUD_UpdatePlayerPos(e);
 359                         }
 360                 }
 361         }
 362         self.nextthink = time + 0.2;
 363 }
 364
 365 void Porto_Init();
 366 void TrueAim_Init();
 367 void PostInit(void)
 368 {
 369         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 370
 371         entity playerchecker;
 372         playerchecker = spawn();
 373         playerchecker.think = Playerchecker_Think;
 374         playerchecker.nextthink = time + 0.2;
 375
 376         Porto_Init();
 377         TrueAim_Init();
 378
 379         postinit = true;
 380 }
 381
 382 float button_zoom;
 383
 384 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 385 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 386 // All keys are in ascii.
 387 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 388 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 389 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 390 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 391 {
 392         float bSkipKey;
 393         bSkipKey = false;
 394
 395         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 396                 return true;
 397
 398         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 399                 return true;
 400
 401         if(menu_visible)
 402                 if(menu_action(bInputType, nPrimary, nSecondary))
 403                         return TRUE;
 404
 405         return bSkipKey;
 406 }
 407
 408 // END REQUIRED CSQC FUNCTIONS
 409 // --------------------------------------------------------------------------
 410
 411 // --------------------------------------------------------------------------
 412 // BEGIN OPTIONAL CSQC FUNCTIONS
 413 void Ent_RemoveEntCS()
 414 {
 415         entcs_receiver[self.sv_entnum] = world;
 416 }
 417 void Ent_ReadEntCS()
 418 {
 419         float sf;
 420         InterpolateOrigin_Undo();
 421
 422         self.classname = "entcs_receiver";
 423         sf = ReadByte();
 424
 425         if(sf & 1)
 426                 self.sv_entnum = ReadByte();
 427         if(sf & 2)
 428         {
 429                 self.origin_x = ReadShort();
 430                 self.origin_y = ReadShort();
 431                 self.origin_z = ReadShort();
 432         }
 433         if(sf & 4)
 434         {
 435                 self.angles_y = ReadByte() * 360.0 / 256;
 436                 self.angles_x = self.angles_z = 0;
 437         }
 438         if(sf & 8)
 439                 self.healthvalue = ReadByte() * 10;
 440         if(sf & 16)
 441                 self.armorvalue = ReadByte() * 10;
 442
 443         entcs_receiver[self.sv_entnum] = self;
 444         self.entremove = Ent_RemoveEntCS;
 445
 446         InterpolateOrigin_Note();
 447 }
 448
 449 void Ent_Remove();
 450
 451 void Ent_RemovePlayerScore()
 452 {
 453         float i;
 454
 455         if(self.owner)
 456         {
 457                 SetTeam(self.owner, -1);
 458                 self.owner.gotscores = 0;
 459                 for(i = 0; i < MAX_SCORE; ++i)
 460                         self.owner.(scores[i]) = 0; // clear all scores
 461         }
 462 }
 463
 464 void Ent_ReadPlayerScore()
 465 {
 466         float i, n;
 467         float isNew;
 468         entity o;
 469
 470         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 471         // (no I've never heard of M-x replace-string, sed, or anything like that)
 472         isNew = !self.owner; // workaround for DP bug
 473         n = ReadByte()-1;
 474
 475 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 476         if(!isNew && n != self.sv_entnum)
 477         {
 478                 //print(_("A CSQC entity changed its owner!\n"));
 479                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 480                 isNew = true;
 481                 Ent_Remove();
 482                 self.enttype = ENT_CLIENT_SCORES;
 483         }
 484 #endif
 485
 486         self.sv_entnum = n;
 487
 488         if not(playerslots[self.sv_entnum])
 489                 playerslots[self.sv_entnum] = spawn();
 490         o = self.owner = playerslots[self.sv_entnum];
 491         o.sv_entnum = self.sv_entnum;
 492         o.gotscores = 1;
 493
 494         //if not(o.sort_prev)
 495         //      RegisterPlayer(o);
 496         //playerchecker will do this for us later, if it has not already done so
 497
 498         float sf, lf;
 499 #if MAX_SCORE <= 8
 500         sf = ReadByte();
 501         lf = ReadByte();
 502 #else
 503         sf = ReadShort();
 504         lf = ReadShort();
 505 #endif
 506         float p;
 507         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 508                 if(sf & p)
 509                 {
 510                         if(lf & p)
 511                                 o.(scores[i]) = ReadInt24_t();
 512                         else
 513                                 o.(scores[i]) = ReadChar();
 514                 }
 515
 516         if(o.sort_prev)
 517                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 518
 519         self.entremove = Ent_RemovePlayerScore;
 520 }
 521
 522 void Ent_ReadTeamScore()
 523 {
 524         float i;
 525         entity o;
 526
 527         self.team = ReadByte();
 528         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 529
 530         float sf, lf;
 531 #if MAX_TEAMSCORE <= 8
 532         sf = ReadByte();
 533         lf = ReadByte();
 534 #else
 535         sf = ReadShort();
 536         lf = ReadShort();
 537 #endif
 538         float p;
 539         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 540                 if(sf & p)
 541                 {
 542                         if(lf & p)
 543                                 o.(teamscores[i]) = ReadInt24_t();
 544                         else
 545                                 o.(teamscores[i]) = ReadChar();
 546                 }
 547
 548         HUD_UpdateTeamPos(o);
 549 }
 550
 551 void Ent_ClientData()
 552 {
 553         float f;
 554         float newspectatee_status;
 555
 556         f = ReadByte();
 557
 558         scoreboard_showscores_force = (f & 1);
 559
 560         if(f & 2)
 561         {
 562                 newspectatee_status = ReadByte();
 563                 if(newspectatee_status == player_localnum + 1)
 564                         newspectatee_status = -1; // observing
 565         }
 566         else
 567                 newspectatee_status = 0;
 568
 569         spectatorbutton_zoom = (f & 4);
 570
 571         if(f & 8)
 572         {
 573                 angles_held_status = 1;
 574                 angles_held_x = ReadAngle();
 575                 angles_held_y = ReadAngle();
 576                 angles_held_z = 0;
 577         }
 578         else
 579                 angles_held_status = 0;
 580
 581         if(newspectatee_status != spectatee_status)
 582         {
 583                 // clear race stuff
 584                 race_laptime = 0;
 585                 race_checkpointtime = 0;
 586         }
 587         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 588         {
 589                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 590                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 591                 )
 592                         prev_p_health = -1;
 593                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 594                         prev_health = -1;
 595         }
 596         spectatee_status = newspectatee_status;
 597
 598         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 599 }
 600
 601 void Ent_Nagger()
 602 {
 603         float nags, i, j, b, f;
 604
 605         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 606
 607         if(!(nags & 4))
 608         {
 609                 if(vote_called_vote)
 610                         strunzone(vote_called_vote);
 611                 vote_called_vote = string_null;
 612                 vote_active = 0;
 613         }
 614         else
 615         {
 616                 vote_active = 1;
 617         }
 618
 619         if(nags & 64)
 620         {
 621                 vote_yescount = ReadByte();
 622                 vote_nocount = ReadByte();
 623                 vote_needed = ReadByte();
 624                 vote_highlighted = ReadChar();
 625         }
 626
 627         if(nags & 128)
 628         {
 629                 if(vote_called_vote)
 630                         strunzone(vote_called_vote);
 631                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 632         }
 633
 634         if(nags & 1)
 635         {
 636                 for(j = 0; j < maxclients; ++j)
 637                         if(playerslots[j])
 638                                 playerslots[j].ready = 1;
 639                 for(i = 1; i <= maxclients; i += 8)
 640                 {
 641                         f = ReadByte();
 642                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 643                                 if not(f & b)
 644                                         if(playerslots[j])
 645                                                 playerslots[j].ready = 0;
 646                 }
 647         }
 648
 649         ready_waiting = (nags & 1);
 650         ready_waiting_for_me = (nags & 2);
 651         vote_waiting = (nags & 4);
 652         vote_waiting_for_me = (nags & 8);
 653         warmup_stage = (nags & 16);
 654 }
 655
 656 void Ent_RandomSeed()
 657 {
 658         float s;
 659         prandom_debug();
 660         s = ReadShort();
 661         psrandom(s);
 662 }
 663
 664 void Ent_ReadAccuracy(void)
 665 {
 666         float sf, f, w, b;
 667         sf = ReadInt24_t();
 668         if(sf == 0)
 669         {
 670                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 671                         weapon_accuracy[w] = -1;
 672                 return;
 673         }
 674
 675         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 676         {
 677                 if(sf & f)
 678                 {
 679                         b = ReadByte();
 680                         if(b == 0)
 681                                 weapon_accuracy[w] = -1;
 682                         else if(b == 255)
 683                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 684                         else
 685                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 686                 }
 687         }
 688 }
 689
 690 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 691 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 692 void Ent_RadarLink();
 693 void Ent_Init();
 694 void Ent_ScoresInfo();
 695 void CSQC_Ent_Update(float bIsNewEntity)
 696 {
 697         float t;
 698         float savetime;
 699         t = ReadByte();
 700
 701         // set up the "time" global for received entities to be correct for interpolation purposes
 702         savetime = time;
 703         if(servertime)
 704         {
 705                 time = servertime;
 706         }
 707         else
 708         {
 709                 serverprevtime = time;
 710                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 711                 time = serverprevtime + serverdeltatime;
 712         }
 713
 714 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 715         if(self.enttype)
 716         {
 717                 if(t != self.enttype || bIsNewEntity)
 718                 {
 719                         //print(_("A CSQC entity changed its type!\n"));
 720                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 721                         Ent_Remove();
 722                         clearentity(self);
 723                         bIsNewEntity = 1;
 724                 }
 725         }
 726         else
 727         {
 728                 if(!bIsNewEntity)
 729                 {
 730                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 731                         bIsNewEntity = 1;
 732                 }
 733         }
 734 #endif
 735         self.enttype = t;
 736         switch(t)
 737         {
 738                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 739                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 740                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 741                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 742                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 743                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 744                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 745                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 746                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 747                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 748                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 749                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 750                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 751                 case ENT_CLIENT_INIT: Ent_Init(); break;
 752                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 753                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 754                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 755                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 756                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 757                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 758                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 759                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 760                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 761                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 762                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 763                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 764                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 765                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 766                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 767                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 768                 case ENT_CLIENT_TURRET: ent_turret(); break;
 769                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 770                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 771                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 772                 default:
 773                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 774                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 775                         break;
 776         }
 777
 778         time = savetime;
 779 }
 780 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 781 // used when an entity changes its type. For an entity that someone interacts
 782 // with others, make sure it can no longer do so.
 783 void Ent_Remove()
 784 {
 785         if(self.entremove)
 786                 self.entremove();
 787
 788         self.enttype = 0;
 789         self.classname = "";
 790         self.draw = menu_sub_null;
 791         self.entremove = menu_sub_null;
 792         // TODO possibly set more stuff to defaults
 793 }
 794 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 795 void CSQC_Ent_Remove()
 796 {
 797         if(wasfreed(self))
 798         {
 799                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 800                 return;
 801         }
 802         if(self.enttype)
 803                 Ent_Remove();
 804         remove(self);
 805 }
 806
 807 void Gamemode_Init()
 808 {
 809         if not(isdemo())
 810         {
 811                 if(!(calledhooks & HOOK_START))
 812                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 813                 calledhooks |= HOOK_START;
 814         }
 815 }
 816 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 817 void CSQC_Parse_StuffCmd(string strMessage)
 818 {
 819         localcmd(strMessage);
 820 }
 821 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 822 void CSQC_Parse_Print(string strMessage)
 823 {
 824         print(ColorTranslateRGB(strMessage));
 825 }
 826
 827 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 828 void CSQC_Parse_CenterPrint(string strMessage)
 829 {
 830         centerprint_hud(strMessage);
 831 }
 832
 833 string notranslate_fogcmd1 = "\nfog ";
 834 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 835 void Fog_Force()
 836 {
 837         // TODO somehow thwart prvm_globalset client ...
 838
 839         if(forcefog != "")
 840                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 841 }
 842
 843 void Gamemode_Init();
 844 void Ent_ScoresInfo()
 845 {
 846         float i;
 847         self.classname = "ent_client_scores_info";
 848         gametype = ReadInt24_t();
 849         for(i = 0; i < MAX_SCORE; ++i)
 850         {
 851                 scores_label[i] = strzone(ReadString());
 852                 scores_flags[i] = ReadByte();
 853         }
 854         for(i = 0; i < MAX_TEAMSCORE; ++i)
 855         {
 856                 teamscores_label[i] = strzone(ReadString());
 857                 teamscores_flags[i] = ReadByte();
 858         }
 859         HUD_InitScores();
 860         Gamemode_Init();
 861 }
 862
 863 void Ent_Init()
 864 {
 865         self.classname = "ent_client_init";
 866
 867         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 868
 869         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 870         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 871         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 872         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 873         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 874         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 875         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 876         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 877         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 878         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 879         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 880         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 881
 882         if(forcefog)
 883                 strunzone(forcefog);
 884         forcefog = strzone(ReadString());
 885
 886         armorblockpercent = ReadByte() / 255.0;
 887
 888         g_weaponswitchdelay = ReadByte() / 255.0;
 889
 890         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 891         g_balance_grenadelauncher_bouncestop = ReadCoord();
 892         g_balance_electro_secondary_bouncefactor = ReadCoord();
 893         g_balance_electro_secondary_bouncestop = ReadCoord();
 894
 895         nex_scope = !ReadByte();
 896         rifle_scope = !ReadByte();
 897
 898         serverflags = ReadByte();
 899
 900         minelayer_maxmines = ReadByte();
 901
 902         hagar_maxrockets = ReadByte();
 903
 904         g_trueaim_minrange = ReadCoord();
 905         g_balance_porto_secondary = ReadByte();
 906
 907         if(!postinit)
 908                 PostInit();
 909 }
 910
 911 void Net_ReadRace()
 912 {
 913         float b;
 914
 915         b = ReadByte();
 916
 917         switch(b)
 918         {
 919                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 920                         race_checkpoint = ReadByte();
 921                         race_time = ReadInt24_t();
 922                         race_previousbesttime = ReadInt24_t();
 923                         if(race_previousbestname)
 924                                 strunzone(race_previousbestname);
 925                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 926
 927                         race_checkpointtime = time;
 928
 929                         if(race_checkpoint == 0 || race_checkpoint == 254)
 930                         {
 931                                 race_penaltyaccumulator = 0;
 932                                 race_laptime = time; // valid
 933                         }
 934
 935                         break;
 936
 937                 case RACE_NET_CHECKPOINT_CLEAR:
 938                         race_laptime = 0;
 939                         race_checkpointtime = 0;
 940                         break;
 941
 942                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 943                         race_laptime = ReadCoord();
 944                         race_checkpointtime = -99999;
 945                         // fall through
 946                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 947                         race_nextcheckpoint = ReadByte();
 948
 949                         race_nextbesttime = ReadInt24_t();
 950                         if(race_nextbestname)
 951                                 strunzone(race_nextbestname);
 952                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 953                         break;
 954
 955                 case RACE_NET_CHECKPOINT_HIT_RACE:
 956                         race_mycheckpoint = ReadByte();
 957                         race_mycheckpointtime = time;
 958                         race_mycheckpointdelta = ReadInt24_t();
 959                         race_mycheckpointlapsdelta = ReadByte();
 960                         if(race_mycheckpointlapsdelta >= 128)
 961                                 race_mycheckpointlapsdelta -= 256;
 962                         if(race_mycheckpointenemy)
 963                                 strunzone(race_mycheckpointenemy);
 964                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 965                         break;
 966
 967                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
 968                         race_othercheckpoint = ReadByte();
 969                         race_othercheckpointtime = time;
 970                         race_othercheckpointdelta = ReadInt24_t();
 971                         race_othercheckpointlapsdelta = ReadByte();
 972                         if(race_othercheckpointlapsdelta >= 128)
 973                                 race_othercheckpointlapsdelta -= 256;
 974                         if(race_othercheckpointenemy)
 975                                 strunzone(race_othercheckpointenemy);
 976                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 977                         break;
 978
 979                 case RACE_NET_PENALTY_RACE:
 980                         race_penaltyeventtime = time;
 981                         race_penaltytime = ReadShort();
 982                         //race_penaltyaccumulator += race_penaltytime;
 983                         if(race_penaltyreason)
 984                                 strunzone(race_penaltyreason);
 985                         race_penaltyreason = strzone(ReadString());
 986                         break;
 987
 988                 case RACE_NET_PENALTY_QUALIFYING:
 989                         race_penaltyeventtime = time;
 990                         race_penaltytime = ReadShort();
 991                         race_penaltyaccumulator += race_penaltytime;
 992                         if(race_penaltyreason)
 993                                 strunzone(race_penaltyreason);
 994                         race_penaltyreason = strzone(ReadString());
 995                         break;
 996
 997                 case RACE_NET_SERVER_RECORD:
 998                         race_server_record = ReadInt24_t();
 999                         break;
1000                 case RACE_NET_SPEED_AWARD:
1001                         race_speedaward = ReadInt24_t();
1002                         if(race_speedaward_holder)
1003                                 strunzone(race_speedaward_holder);
1004                         race_speedaward_holder = strzone(ReadString());
1005                         break;
1006                 case RACE_NET_SPEED_AWARD_BEST:
1007                         race_speedaward_alltimebest = ReadInt24_t();
1008                         if(race_speedaward_alltimebest_holder)
1009                                 strunzone(race_speedaward_alltimebest_holder);
1010                         race_speedaward_alltimebest_holder = strzone(ReadString());
1011                         break;
1012                 case RACE_NET_SERVER_RANKINGS:
1013                         float pos, prevpos, del;
1014                         pos = ReadShort();
1015                         prevpos = ReadShort();
1016                         del = ReadShort();
1017
1018                         // move other rankings out of the way
1019                         float i;
1020                         if (prevpos) {
1021                                 for (i=prevpos-1;i>pos-1;--i) {
1022                                         grecordtime[i] = grecordtime[i-1];
1023                                         if(grecordholder[i])
1024                                                 strunzone(grecordholder[i]);
1025                                         grecordholder[i] = strzone(grecordholder[i-1]);
1026                                 }
1027                         } else if (del) { // a record has been deleted by the admin
1028                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1029                                         if (i == RANKINGS_CNT-1) { // clear out last record
1030                                                 grecordtime[i] = 0;
1031                                                 if (grecordholder[i])
1032                                                         strunzone(grecordholder[i]);
1033                                                 grecordholder[i] = string_null;
1034                                         }
1035                                         else {
1036                                                 grecordtime[i] = grecordtime[i+1];
1037                                                 if (grecordholder[i])
1038                                                         strunzone(grecordholder[i]);
1039                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1040                                         }
1041                                 }
1042                         } else { // player has no ranked record yet
1043                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1044                                         grecordtime[i] = grecordtime[i-1];
1045                                         if(grecordholder[i])
1046                                                 strunzone(grecordholder[i]);
1047                                         grecordholder[i] = strzone(grecordholder[i-1]);
1048                                 }
1049                         }
1050
1051                         // store new ranking
1052                         if(grecordholder[pos-1] != "")
1053                                 strunzone(grecordholder[pos-1]);
1054                         grecordholder[pos-1] = strzone(ReadString());
1055                         grecordtime[pos-1] = ReadInt24_t();
1056                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1057                                 race_myrank = pos;
1058                         break;
1059                 case RACE_NET_SERVER_STATUS:
1060                         race_status = ReadShort();
1061                         if(race_status_name)
1062                                 strunzone(race_status_name);
1063                         race_status_name = strzone(ReadString());
1064         }
1065 }
1066
1067 void Net_ReadSpawn()
1068 {
1069         zoomin_effect = 1;
1070         current_viewzoom = 0.6;
1071 }
1072
1073 void Net_TeamNagger()
1074 {
1075         teamnagger = 1;
1076 }
1077
1078 void Net_ReadPingPLReport()
1079 {
1080         float e, pi, pl, ml;
1081         e = ReadByte();
1082         pi = ReadShort();
1083         pl = ReadByte();
1084         ml = ReadByte();
1085         if not(playerslots[e])
1086                 return;
1087         playerslots[e].ping = pi;
1088         playerslots[e].ping_packetloss = pl / 255.0;
1089         playerslots[e].ping_movementloss = ml / 255.0;
1090 }
1091
1092 void Net_WeaponComplain() {
1093         complain_weapon = ReadByte();
1094
1095         if(complain_weapon_name)
1096                 strunzone(complain_weapon_name);
1097         complain_weapon_name = strzone(ReadString());
1098
1099         complain_weapon_type = ReadByte();
1100
1101         complain_weapon_time = time;
1102         weapontime = time; // ping the weapon panel
1103 }
1104
1105 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1106 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1107 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1108 float CSQC_Parse_TempEntity()
1109 {
1110         float bHandled;
1111                 bHandled  = true;
1112         // Acquire TE ID
1113         float nTEID;
1114                 nTEID = ReadByte();
1115
1116                 // NOTE: Could just do return instead of break...
1117         switch(nTEID)
1118         {
1119                 case TE_CSQC_TARGET_MUSIC:
1120                         Net_TargetMusic();
1121                         bHandled = true;
1122                         break;
1123                 case TE_CSQC_PICTURE:
1124                         Net_MapVote_Picture();
1125                         bHandled = true;
1126                         break;
1127                 case TE_CSQC_RACE:
1128                         Net_ReadRace();
1129                         bHandled = true;
1130                         break;
1131                 case TE_CSQC_SPAWN:
1132                         Net_ReadSpawn();
1133                         bHandled = true;
1134                         break;
1135                 case TE_CSQC_ZCURVEPARTICLES:
1136                         Net_ReadZCurveParticles();
1137                         bHandled = true;
1138                         break;
1139                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1140                         Net_ReadNexgunBeamParticle();
1141                         bHandled = true;
1142                         break;
1143                 case TE_CSQC_TEAMNAGGER:
1144                         Net_TeamNagger();
1145                         bHandled = true;
1146                         break;
1147                 case TE_CSQC_LIGHTNINGARC:
1148                         Net_ReadLightningarc();
1149                         bHandled = true;
1150                         break;
1151                 case TE_CSQC_PINGPLREPORT:
1152                         Net_ReadPingPLReport();
1153                         bHandled = true;
1154                         break;
1155                 case TE_CSQC_ANNOUNCE:
1156                         Announcer_Play(ReadString());
1157                         bHandled = true;
1158                         break;
1159                 case TE_CSQC_KILLNOTIFY:
1160                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1161                         bHandled = true;
1162                         break;
1163                 case TE_CSQC_KILLCENTERPRINT:
1164                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1165                         bHandled = true;
1166                         break;
1167                 case TE_CSQC_CENTERPRINT_GENERIC:
1168                         float id;
1169                         string s;
1170                         id = ReadByte();
1171                         s = ReadString();
1172                         if (id != 0 && s != "")
1173                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1174                         else
1175                                 centerprint_generic(id, s, 0, 0);
1176                         bHandled = true;
1177                         break;
1178                 case TE_CSQC_WEAPONCOMPLAIN:
1179                         Net_WeaponComplain();
1180                         bHandled = true;
1181                         break;
1182                 case TE_CSQC_VEHICLESETUP:
1183                         Net_VehicleSetup();
1184                         bHandled = true;
1185                         break;
1186                 case TE_CSQC_SVNOTICE:
1187                         cl_notice_read();
1188                         bHandled = true;
1189                         break;
1190                 default:
1191                         // No special logic for this temporary entity; return 0 so the engine can handle it
1192                         bHandled = false;
1193                         break;
1194         }
1195
1196         return bHandled;
1197 }
1198
1199 string getcommandkey(string text, string command)
1200 {
1201         string keys;
1202         float n, j, k, l;
1203
1204         if (!autocvar_hud_showbinds)
1205                 return text;
1206
1207         keys = db_get(binddb, command);
1208         if (!keys)
1209         {
1210                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1211                 for(j = 0; j < n; ++j)
1212                 {
1213                         k = stof(argv(j));
1214                         if(k != -1)
1215                         {
1216                                 if ("" == keys)
1217                                         keys = keynumtostring(k);
1218                                 else
1219                                         keys = strcat(keys, ", ", keynumtostring(k));
1220
1221                                 ++l;
1222                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1223                         }
1224
1225                 }
1226                 db_put(binddb, command, keys);
1227         }
1228
1229         if ("" == keys) {
1230                 if (autocvar_hud_showbinds > 1)
1231                         return sprintf(_("%s (not bound)"), text);
1232                 else
1233                         return text;
1234         }
1235         else if (autocvar_hud_showbinds > 1)
1236                 return sprintf(_("%s (%s)"), text, keys);
1237         else
1238                 return keys;
1239 }