qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: %s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         precache_sound("misc/hit.wav");
 140         precache_sound("misc/typehit.wav");
 141         Projectile_Precache();
 142         Hook_Precache();
 143         GibSplash_Precache();
 144         Casings_Precache();
 145         DamageInfo_Precache();
 146         if(autocvar_cl_announcer != cl_announcer_prev) {
 147                 Announcer_Precache();
 148                 if(cl_announcer_prev)
 149                         strunzone(cl_announcer_prev);
 150                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 151         }
 152         Tuba_Precache();
 153
 154         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 155         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 156
 157         get_mi_min_max_texcoords(1); // try the CLEVER way first
 158         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 159         shortmapname = mi_shortname;
 160
 161         if(precache_pic(minimapname) == "")
 162         {
 163                 // but maybe we have a non-clever minimap
 164                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 165                 if(precache_pic(minimapname) == "")
 166                         minimapname = ""; // FAIL
 167                 else
 168                         get_mi_min_max_texcoords(0); // load new texcoords
 169         }
 170
 171         mi_center = (mi_min + mi_max) * 0.5;
 172         mi_scale = mi_max - mi_min;
 173         minimapname = strzone(minimapname);
 174
 175         WarpZone_Init();
 176
 177         hud_configure_prev = -1;
 178         tab_panel = -1;
 179 }
 180
 181 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 182 void CSQC_Shutdown(void)
 183 {
 184 #ifdef USE_FTE
 185 #pragma TARGET id
 186         if(!__engine_check)
 187                 return 0;
 188 #pragma TARGET fte
 189 #endif
 190
 191         WarpZone_Shutdown();
 192
 193         remove(teams);
 194         remove(players);
 195         db_close(binddb);
 196         db_close(tempdb);
 197         if(autocvar_cl_db_saveasdump)
 198                 db_dump(ClientProgsDB, "client.db");
 199         else
 200                 db_save(ClientProgsDB, "client.db");
 201         db_close(ClientProgsDB);
 202
 203         cvar_clientsettemp_restore();
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         if not(isdemo())
 209         {
 210                 if not(calledhooks & HOOK_START)
 211                         localcmd("\n_cl_hook_gamestart nop\n");
 212                 if not(calledhooks & HOOK_END)
 213                         localcmd("\ncl_hook_gameend\n");
 214         }
 215 }
 216
 217 .float has_team;
 218 float SetTeam(entity o, float Team)
 219 {
 220         entity tm;
 221         if(teamplay)
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case COLOR_TEAM1:
 227                         case COLOR_TEAM2:
 228                         case COLOR_TEAM3:
 229                         case COLOR_TEAM4:
 230                                 break;
 231                         default:
 232                                 if(GetTeam(Team, false) == NULL)
 233                                 {
 234                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 235                                         Team = COLOR_SPECTATOR;
 236                                 }
 237                                 break;
 238                 }
 239         }
 240         else
 241         {
 242                 switch(Team)
 243                 {
 244                         case -1:
 245                         case 0:
 246                                 break;
 247                         default:
 248                                 if(GetTeam(Team, false) == NULL)
 249                                 {
 250                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 251                                         Team = COLOR_SPECTATOR;
 252                                 }
 253                                 break;
 254                 }
 255         }
 256         if(Team == -1) // leave
 257         {
 258                 if(o.has_team)
 259                 {
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.has_team = 0;
 263                         return TRUE;
 264                 }
 265         }
 266         else
 267         {
 268                 if not(o.has_team)
 269                 {
 270                         o.team = Team;
 271                         tm = GetTeam(Team, true);
 272                         tm.team_size += 1;
 273                         o.has_team = 1;
 274                         return TRUE;
 275                 }
 276                 else if(Team != o.team)
 277                 {
 278                         tm = GetTeam(o.team, false);
 279                         tm.team_size -= 1;
 280                         o.team = Team;
 281                         tm = GetTeam(Team, true);
 282                         tm.team_size += 1;
 283                         return TRUE;
 284                 }
 285         }
 286         return FALSE;
 287 }
 288
 289 void Playerchecker_Think()
 290 {
 291         float i;
 292         entity e;
 293         for(i = 0; i < maxclients; ++i)
 294         {
 295                 e = playerslots[i];
 296                 if(GetPlayerName(i) == "")
 297                 {
 298                         if(e.sort_prev)
 299                         {
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if not(e.sort_prev)
 310                         {
 311                                 // player connected
 312                                 if not(e)
 313                                         playerslots[i] = e = spawn();
 314                                 e.sv_entnum = i;
 315                                 e.ping = 0;
 316                                 e.ping_packetloss = 0;
 317                                 e.ping_movementloss = 0;
 318                                 //e.gotscores = 0; // we might already have the scores...
 319                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 320                                 RegisterPlayer(e);
 321                                 HUD_UpdatePlayerPos(e);
 322                         }
 323                 }
 324         }
 325         self.nextthink = time + 0.2;
 326 }
 327
 328 void Porto_Init();
 329 void TrueAim_Init();
 330 void PostInit(void)
 331 {
 332         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 333
 334         entity playerchecker;
 335         playerchecker = spawn();
 336         playerchecker.think = Playerchecker_Think;
 337         playerchecker.nextthink = time + 0.2;
 338
 339         Porto_Init();
 340         TrueAim_Init();
 341
 342         postinit = true;
 343 }
 344
 345 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 346 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 347 float button_zoom;
 348 void Cmd_HUD_SetFields(float);
 349 void Cmd_HUD_Help(float);
 350 float CSQC_ConsoleCommand(string strMessage)
 351 {
 352         float argc;
 353         // Tokenize String
 354         //argc = tokenize(strMessage);
 355         argc = tokenize_console(strMessage);
 356
 357         // Acquire Command
 358         local string strCmd;
 359         strCmd = argv(0);
 360
 361         if(strCmd == "hud_configure") { // config hud
 362                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 363                 return true;
 364         } else if(strCmd == "hud_save") { // save hud config
 365                 if(argv(1) == "" || argv(2)) {
 366                         print(_("Usage:\n"));
 367                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 368                 }
 369                 else
 370                         HUD_Panel_ExportCfg(argv(1));
 371                 return true;
 372         } else if(strCmd == "+button4") { // zoom
 373                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 374                 if(ignore_plus_zoom)
 375                 {
 376                         --ignore_plus_zoom;
 377                         return false;
 378                 }
 379                 button_zoom = 1;
 380                 return true;
 381         } else if(strCmd == "-button4") { // zoom
 382                 if(ignore_minus_zoom)
 383                 {
 384                         --ignore_minus_zoom;
 385                         return false;
 386                 }
 387                 button_zoom = 0;
 388                 return true;
 389         } else if(strCmd == "+button3") { // secondary
 390                 button_attack2 = 1;
 391                 return false;
 392         } else if(strCmd == "-button3") { // secondary
 393                 button_attack2 = 0;
 394                 return false;
 395         } else if(strCmd == "+showscores") {
 396                 scoreboard_showscores = true;
 397                 return true;
 398         } else if(strCmd == "-showscores") {
 399                 scoreboard_showscores = false;
 400                 return true;
 401         } else if(strCmd == "+showaccuracy") {
 402                 scoreboard_showaccuracy = true;
 403                 return true;
 404         } else if(strCmd == "-showaccuracy") {
 405                 scoreboard_showaccuracy = false;
 406                 return true;
 407         }
 408
 409         if(camera_active)
 410         if(strCmd == "+forward" || strCmd == "-back") {
 411                 ++camera_direction_x;
 412                 return true;
 413         } else if(strCmd == "-forward" || strCmd == "+back") {
 414                 --camera_direction_x;
 415                 return true;
 416         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 417                 --camera_direction_y;
 418                 return true;
 419         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 420                 ++camera_direction_y;
 421                 return true;
 422         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 423                 ++camera_direction_z;
 424                 return true;
 425         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 426                 --camera_direction_z;
 427                 return true;
 428         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 429                 ++camera_roll;
 430                 return true;
 431         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 432                 --camera_roll;
 433                 return true;
 434         }
 435
 436         return false;
 437 }
 438
 439 .vector view_ofs;
 440 entity debug_shotorg;
 441 void ShotOrg_Draw()
 442 {
 443         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 444         self.angles = view_angles;
 445         self.angles_x = -self.angles_x;
 446         if not(self.cnt)
 447                 self.drawmask = MASK_NORMAL;
 448         else
 449                 self.drawmask = 0;
 450 }
 451 void ShotOrg_Draw2D()
 452 {
 453         vector coord2d_topleft, coord2d_topright, coord2d;
 454         string s;
 455         vector fs;
 456
 457         s = vtos(self.view_ofs);
 458         s = substring(s, 1, strlen(s) - 2);
 459         if(tokenize_console(s) == 3)
 460                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 461
 462         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 463         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 464
 465         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 466
 467         coord2d = coord2d_topleft;
 468         if(fs_x < 8)
 469         {
 470                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 471                 fs = '8 8 0';
 472         }
 473         coord2d_y -= fs_y;
 474         coord2d_z = 0;
 475         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 476 }
 477
 478 void ShotOrg_Spawn()
 479 {
 480         debug_shotorg = spawn();
 481         debug_shotorg.draw = ShotOrg_Draw;
 482         debug_shotorg.draw2d = ShotOrg_Draw2D;
 483         debug_shotorg.renderflags = RF_VIEWMODEL;
 484         debug_shotorg.effects = EF_FULLBRIGHT;
 485         precache_model("models/shotorg_adjuster.md3");
 486         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 487         debug_shotorg.scale = 2;
 488         debug_shotorg.view_ofs = '25 8 -8';
 489 }
 490
 491 void DrawDebugModel()
 492 {
 493         if(time - floor(time) > 0.5)
 494         {
 495                 PolyDrawModel(self);
 496                 self.drawmask = 0;
 497         }
 498         else
 499         {
 500                 self.renderflags = 0;
 501                 self.drawmask = MASK_NORMAL;
 502         }
 503 }
 504
 505 void GameCommand(string msg)
 506 {
 507         string s;
 508         float argc;
 509         entity e;
 510         argc = tokenize_console(msg);
 511
 512         if(argv(0) == "help" || argc == 0)
 513         {
 514                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 515                 print(_("  settemp cvar value\n"));
 516                 print(_("  scoreboard_columns_set ...\n"));
 517                 print(_("  scoreboard_columns_help\n"));
 518                 GameCommand_Generic("help");
 519                 return;
 520         }
 521
 522         if(GameCommand_Generic(msg))
 523                 return;
 524
 525         string cmd;
 526         cmd = argv(0);
 527         if(cmd == "mv_download") {
 528                 Cmd_MapVote_MapDownload(argc);
 529         }
 530         else if(cmd == "settemp") {
 531                 cvar_clientsettemp(argv(1), argv(2));
 532         }
 533         else if(cmd == "scoreboard_columns_set") {
 534                 Cmd_HUD_SetFields(argc);
 535         }
 536         else if(cmd == "scoreboard_columns_help") {
 537                 Cmd_HUD_Help(argc);
 538         }
 539 #ifdef BLURTEST
 540         else if(cmd == "blurtest") {
 541                 blurtest_time0 = time;
 542                 blurtest_time1 = time + stof(argv(1));
 543                 blurtest_radius = stof(argv(2));
 544                 blurtest_power = stof(argv(3));
 545         }
 546 #endif
 547         else if(cmd == "shotorg_move") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_movez") {
 555                 if(!debug_shotorg)
 556                         ShotOrg_Spawn();
 557                 else
 558                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 559                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 560         }
 561         else if(cmd == "shotorg_set") {
 562                 if(!debug_shotorg)
 563                         ShotOrg_Spawn();
 564                 else
 565                         debug_shotorg.view_ofs = stov(argv(1));
 566                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 567         }
 568         else if(cmd == "shotorg_setz") {
 569                 if(!debug_shotorg)
 570                         ShotOrg_Spawn();
 571                 else
 572                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 573                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 574         }
 575         else if(cmd == "shotorg_toggle_hide") {
 576                 if(debug_shotorg)
 577                 {
 578                         debug_shotorg.cnt = !debug_shotorg.cnt;
 579                 }
 580         }
 581         else if(cmd == "shotorg_end") {
 582                 if(debug_shotorg)
 583                 {
 584                         print(vtos(debug_shotorg.view_ofs), "\n");
 585                         remove(debug_shotorg);
 586                         debug_shotorg = world;
 587                 }
 588                 localcmd("sv_cmd debug_shotorg\n");
 589         }
 590         else if(cmd == "sendcvar") {
 591                 // W_FixWeaponOrder will trash argv, so save what we need.
 592                 string thiscvar;
 593                 thiscvar = strzone(argv(1));
 594                 s = cvar_string(thiscvar);
 595                 if(thiscvar == "cl_weaponpriority")
 596                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 597                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 598                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 599                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 600                 strunzone(thiscvar);
 601         }
 602         else if(cmd == "spawn") {
 603                 s = argv(1);
 604                 e = spawn();
 605                 precache_model(s);
 606                 setmodel(e, s);
 607                 setorigin(e, view_origin);
 608                 e.angles = view_angles;
 609                 e.draw = DrawDebugModel;
 610                 e.classname = "debugmodel";
 611         }
 612     else if(cmd == "vyes")
 613     {
 614         if(uid2name_dialog)
 615         {
 616             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 617             vote_prev = 0;
 618             cvar_set("cl_allow_uid2name", "1");
 619             vote_change = -9999;
 620                         uid2name_dialog = 0;
 621         }
 622         else
 623         {
 624             localcmd("cmd vote yes\n");
 625         }
 626     }
 627     else if(cmd == "vno")
 628     {
 629         if(uid2name_dialog)
 630         {
 631             vote_active = 0;
 632             vote_prev = 0;
 633             cvar_set("cl_allow_uid2name", "0");
 634             vote_change = -9999;
 635                         uid2name_dialog = 0;
 636         }
 637         else
 638         {
 639             localcmd("cmd vote no\n");
 640         }
 641     }
 642
 643         else
 644         {
 645                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 646         }
 647
 648         return;
 649 }
 650
 651 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 652 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 653 // All keys are in ascii.
 654 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 655 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 656 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 657 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 658 {
 659         local float bSkipKey;
 660         bSkipKey = false;
 661
 662         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 663                 return true;
 664
 665         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 666                 return true;
 667
 668         if(menu_visible)
 669                 if(menu_action(bInputType, nPrimary, nSecondary))
 670                         return TRUE;
 671
 672         return bSkipKey;
 673 }
 674
 675 // END REQUIRED CSQC FUNCTIONS
 676 // --------------------------------------------------------------------------
 677
 678 // --------------------------------------------------------------------------
 679 // BEGIN OPTIONAL CSQC FUNCTIONS
 680 void Ent_ReadEntCS()
 681 {
 682         InterpolateOrigin_Undo();
 683
 684         self.classname = "entcs_receiver";
 685         self.sv_entnum = ReadByte() - 1;
 686         self.origin_x = ReadShort();
 687         self.origin_y = ReadShort();
 688         self.origin_z = ReadShort();
 689         self.angles_y = ReadByte() * 360.0 / 256;
 690         self.origin_z = self.angles_x = self.angles_z = 0;
 691
 692         InterpolateOrigin_Note();
 693 }
 694
 695 void Ent_Remove();
 696
 697 void Ent_RemovePlayerScore()
 698 {
 699         float i;
 700
 701         if(self.owner)
 702         {
 703                 SetTeam(self.owner, -1);
 704                 self.owner.gotscores = 0;
 705                 for(i = 0; i < MAX_SCORE; ++i)
 706                         self.owner.(scores[i]) = 0; // clear all scores
 707         }
 708 }
 709
 710 void Ent_ReadPlayerScore()
 711 {
 712         float i, n;
 713         float isNew;
 714         entity o;
 715
 716         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 717         // (no I've never heard of M-x replace-string, sed, or anything like that)
 718         isNew = !self.owner; // workaround for DP bug
 719         n = ReadByte()-1;
 720
 721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 722         if(!isNew && n != self.sv_entnum)
 723         {
 724                 print(_("A CSQC entity changed its owner!\n"));
 725                 isNew = true;
 726                 Ent_Remove();
 727                 self.enttype = ENT_CLIENT_SCORES;
 728         }
 729 #endif
 730
 731         self.sv_entnum = n;
 732
 733         if not(playerslots[self.sv_entnum])
 734                 playerslots[self.sv_entnum] = spawn();
 735         o = self.owner = playerslots[self.sv_entnum];
 736         o.sv_entnum = self.sv_entnum;
 737         o.gotscores = 1;
 738
 739         //if not(o.sort_prev)
 740         //      RegisterPlayer(o);
 741         //playerchecker will do this for us later, if it has not already done so
 742
 743         float sf, lf;
 744 #if MAX_SCORE <= 8
 745         sf = ReadByte();
 746         lf = ReadByte();
 747 #else
 748         sf = ReadShort();
 749         lf = ReadShort();
 750 #endif
 751         float p;
 752         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 753                 if(sf & p)
 754                 {
 755                         if(lf & p)
 756                                 o.(scores[i]) = ReadInt24_t();
 757                         else
 758                                 o.(scores[i]) = ReadChar();
 759                 }
 760
 761         if(o.sort_prev)
 762                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 763
 764         self.entremove = Ent_RemovePlayerScore;
 765 }
 766
 767 void Ent_ReadTeamScore()
 768 {
 769         float i;
 770         entity o;
 771
 772         self.team = ReadByte();
 773         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 774
 775         float sf, lf;
 776 #if MAX_TEAMSCORE <= 8
 777         sf = ReadByte();
 778         lf = ReadByte();
 779 #else
 780         sf = ReadShort();
 781         lf = ReadShort();
 782 #endif
 783         float p;
 784         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 785                 if(sf & p)
 786                 {
 787                         if(lf & p)
 788                                 o.(teamscores[i]) = ReadInt24_t();
 789                         else
 790                                 o.(teamscores[i]) = ReadChar();
 791                 }
 792
 793         HUD_UpdateTeamPos(o);
 794 }
 795
 796 void Net_Reset()
 797 {
 798 }
 799
 800 void Ent_ClientData()
 801 {
 802         float f;
 803         float newspectatee_status;
 804
 805         f = ReadByte();
 806
 807         scoreboard_showscores_force = (f & 1);
 808
 809         if(f & 2)
 810         {
 811                 newspectatee_status = ReadByte();
 812                 if(newspectatee_status == player_localentnum)
 813                         newspectatee_status = -1; // observing
 814         }
 815         else
 816                 newspectatee_status = 0;
 817
 818         spectatorbutton_zoom = (f & 4);
 819
 820         if(f & 8)
 821         {
 822                 angles_held_status = 1;
 823                 angles_held_x = ReadAngle();
 824                 angles_held_y = ReadAngle();
 825                 angles_held_z = 0;
 826         }
 827         else
 828                 angles_held_status = 0;
 829
 830         if(newspectatee_status != spectatee_status)
 831         {
 832                 float i;
 833
 834                 // clear race stuff
 835                 race_laptime = 0;
 836                 race_checkpointtime = 0;
 837         }
 838         spectatee_status = newspectatee_status;
 839 }
 840
 841 void Ent_Nagger()
 842 {
 843         float nags, i, j, b, f;
 844
 845         nags = ReadByte();
 846
 847         if(nags & 128)
 848         {
 849                 if(vote_called_vote)
 850                         strunzone(vote_called_vote);
 851                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 852         }
 853
 854         if(nags & 1)
 855         {
 856                 for(j = 0; j < maxclients; ++j)
 857                         if(playerslots[j])
 858                                 playerslots[j].ready = 1;
 859                 for(i = 1; i <= maxclients; i += 8)
 860                 {
 861                         f = ReadByte();
 862                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 863                                 if not(f & b)
 864                                         if(playerslots[j])
 865                                                 playerslots[j].ready = 0;
 866                 }
 867         }
 868
 869         ready_waiting = (nags & 1);
 870         ready_waiting_for_me = (nags & 2);
 871         vote_waiting = (nags & 4);
 872         vote_waiting_for_me = (nags & 8);
 873         warmup_stage = (nags & 16);
 874 }
 875
 876 void Ent_RandomSeed()
 877 {
 878         float s;
 879         prandom_debug();
 880         s = ReadShort();
 881         psrandom(s);
 882 }
 883
 884 void Ent_ReadAccuracy(void)
 885 {
 886         float sf, f, w, b;
 887         sf = ReadInt24_t();
 888         if(sf == 0)
 889         {
 890                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 891                         weapon_accuracy[w] = -1;
 892                 return;
 893         }
 894
 895         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 896         {
 897                 if(sf & f)
 898                 {
 899                         b = ReadByte();
 900                         if(b == 0)
 901                                 weapon_accuracy[w] = -1;
 902                         else if(b == 255)
 903                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 904                         else
 905                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 906                 }
 907         }
 908 }
 909
 910 .float health, armorvalue;
 911 void Ent_ShowNames()
 912 {
 913     float sf, the_entnum;
 914
 915     sf = ReadByte();
 916     the_entnum = ReadByte();
 917
 918     if(sf & 1)
 919     {
 920         playerslots[the_entnum].origin_x = ReadShort();
 921         playerslots[the_entnum].origin_y = ReadShort();
 922         playerslots[the_entnum].origin_z = ReadShort();
 923         print("Updated origin = ", vtos(playerslots[the_entnum].origin), " for player # ", ftos(the_entnum), "\n");
 924     }
 925     if(sf & 2)
 926     {
 927         playerslots[the_entnum].health = ReadByte();
 928         playerslots[the_entnum].armorvalue = ReadByte();
 929         print("Updated health/armor = ", ftos(playerslots[the_entnum].health), "/", ftos(playerslots[the_entnum].health), " for player # ", ftos(the_entnum), "\n");
 930     }
 931     if(sf & 4)
 932         playerslots[the_entnum].netname = ReadString();
 933
 934     /*
 935     string thename;
 936     float thehealth, thearmor;
 937
 938     if(shownames_netname)
 939         strunzone(shownames_netname);
 940     thename = strzone(ReadString());
 941     thehealth = ReadByte();
 942     thearmor = ReadByte();
 943
 944     if(autocvar_hud_panel_shownames == 1 && thehealth > 0) // teammates only
 945     {
 946         shownames_netname = thename;
 947         shownames_health = thehealth;
 948         shownames_armor = thearmor;
 949
 950         shownames_time = time + autocvar_hud_panel_shownames_sustain;
 951     }
 952     else if(autocvar_hud_panel_shownames == 2)
 953     {
 954         shownames_netname = thename;
 955         shownames_health = thehealth;
 956         shownames_armor = thearmor;
 957
 958         shownames_time = time + autocvar_hud_panel_shownames_sustain;
 959     }
 960     */
 961 }
 962
 963 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 964 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 965 void Ent_RadarLink();
 966 void Ent_Init();
 967 void Ent_ScoresInfo();
 968 void(float bIsNewEntity) CSQC_Ent_Update =
 969 {
 970         float t;
 971         float savetime;
 972         t = ReadByte();
 973
 974         // set up the "time" global for received entities to be correct for interpolation purposes
 975         savetime = time;
 976         if(servertime)
 977         {
 978                 time = servertime;
 979         }
 980         else
 981         {
 982                 serverprevtime = time;
 983                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 984                 time = serverprevtime + serverdeltatime;
 985         }
 986
 987 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 988         if(self.enttype)
 989                 if(t != self.enttype)
 990                 {
 991                         print(_("A CSQC entity changed its type!\n"));
 992                         Ent_Remove();
 993                         bIsNewEntity = 1;
 994                 }
 995 #endif
 996         self.enttype = t;
 997         switch(t)
 998         {
 999                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
1000                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
1001                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
1002                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
1003                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
1004                 case ENT_CLIENT_LASER: Ent_Laser(); break;
1005                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
1006                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
1007                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
1008                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
1009                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
1010                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
1011                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
1012                 case ENT_CLIENT_INIT: Ent_Init(); break;
1013                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
1014                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
1015                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
1016                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
1017                 case ENT_CLIENT_WALL: Ent_Wall(); break;
1018                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1019                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1020                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1021                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1022                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1023                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1024                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1025                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1026                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1027                 case ENT_CLIENT_SHOWNAMES: Ent_ShowNames(); break;
1028                 default:
1029                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1030                         break;
1031         }
1032
1033         time = savetime;
1034 };
1035 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1036 // used when an entity changes its type. For an entity that someone interacts
1037 // with others, make sure it can no longer do so.
1038 void Ent_Remove()
1039 {
1040         if(self.entremove)
1041                 self.entremove();
1042
1043         self.enttype = 0;
1044         self.classname = "";
1045         self.draw = menu_sub_null;
1046         self.entremove = menu_sub_null;
1047         // TODO possibly set more stuff to defaults
1048 }
1049 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1050 void CSQC_Ent_Remove()
1051 {
1052         if(self.enttype)
1053                 Ent_Remove();
1054         remove(self);
1055 }
1056
1057 void Gamemode_Init()
1058 {
1059         if not(isdemo())
1060         {
1061                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1062                 calledhooks |= HOOK_START;
1063         }
1064 }
1065 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1066 void CSQC_Parse_StuffCmd(string strMessage)
1067 {
1068         localcmd(strMessage);
1069 }
1070 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1071 void CSQC_Parse_Print(string strMessage)
1072 {
1073         print(ColorTranslateRGB(strMessage));
1074 }
1075
1076 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1077 void CSQC_Parse_CenterPrint(string strMessage)
1078 {
1079         centerprint(strMessage);
1080 }
1081
1082 string notranslate_fogcmd1 = "\nfog ";
1083 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1084 void Fog_Force()
1085 {
1086         // TODO somehow thwart prvm_globalset client ...
1087
1088         if(forcefog != "")
1089                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1090 }
1091
1092 void Gamemode_Init();
1093 void Ent_ScoresInfo()
1094 {
1095         float i;
1096         self.classname = "ent_client_scores_info";
1097         gametype = ReadByte();
1098         for(i = 0; i < MAX_SCORE; ++i)
1099         {
1100                 scores_label[i] = strzone(ReadString());
1101                 scores_flags[i] = ReadByte();
1102         }
1103         for(i = 0; i < MAX_TEAMSCORE; ++i)
1104         {
1105                 teamscores_label[i] = strzone(ReadString());
1106                 teamscores_flags[i] = ReadByte();
1107         }
1108         HUD_InitScores();
1109         Gamemode_Init();
1110 }
1111
1112 void Ent_Init()
1113 {
1114         self.classname = "ent_client_init";
1115
1116         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1117
1118         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1119         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1120         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1121         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1122         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1123         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1124         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1125         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1126         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1127         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1128         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1129         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1130
1131         if(forcefog)
1132                 strunzone(forcefog);
1133         forcefog = strzone(ReadString());
1134
1135         armorblockpercent = ReadByte() / 255.0;
1136
1137         g_weaponswitchdelay = ReadByte() / 255.0;
1138
1139         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1140         g_balance_grenadelauncher_bouncestop = ReadCoord();
1141         g_balance_electro_secondary_bouncefactor = ReadCoord();
1142         g_balance_electro_secondary_bouncestop = ReadCoord();
1143
1144         nex_scope = !ReadByte();
1145         sniperrifle_scope = !ReadByte();
1146
1147         serverflags = ReadByte();
1148
1149         minelayer_maxmines = ReadByte();
1150
1151         g_trueaim_minrange = ReadCoord();
1152
1153         if(!postinit)
1154                 PostInit();
1155 }
1156
1157 void Net_ReadRace()
1158 {
1159         float b;
1160
1161         b = ReadByte();
1162
1163         switch(b)
1164         {
1165                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1166                         race_checkpoint = ReadByte();
1167                         race_time = ReadInt24_t();
1168                         race_previousbesttime = ReadInt24_t();
1169                         if(race_previousbestname)
1170                                 strunzone(race_previousbestname);
1171                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1172
1173                         race_checkpointtime = time;
1174
1175                         if(race_checkpoint == 0 || race_checkpoint == 254)
1176                         {
1177                                 race_penaltyaccumulator = 0;
1178                                 race_laptime = time; // valid
1179                         }
1180
1181                         break;
1182
1183                 case RACE_NET_CHECKPOINT_CLEAR:
1184                         race_laptime = 0;
1185                         race_checkpointtime = 0;
1186                         break;
1187
1188                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1189                         race_laptime = ReadCoord();
1190                         race_checkpointtime = -99999;
1191                         // fall through
1192                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1193                         race_nextcheckpoint = ReadByte();
1194
1195                         race_nextbesttime = ReadInt24_t();
1196                         if(race_nextbestname)
1197                                 strunzone(race_nextbestname);
1198                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1199                         break;
1200
1201                 case RACE_NET_CHECKPOINT_HIT_RACE:
1202                         race_mycheckpoint = ReadByte();
1203                         race_mycheckpointtime = time;
1204                         race_mycheckpointdelta = ReadInt24_t();
1205                         race_mycheckpointlapsdelta = ReadByte();
1206                         if(race_mycheckpointlapsdelta >= 128)
1207                                 race_mycheckpointlapsdelta -= 256;
1208                         if(race_mycheckpointenemy)
1209                                 strunzone(race_mycheckpointenemy);
1210                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1211                         break;
1212
1213                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1214                         race_othercheckpoint = ReadByte();
1215                         race_othercheckpointtime = time;
1216                         race_othercheckpointdelta = ReadInt24_t();
1217                         race_othercheckpointlapsdelta = ReadByte();
1218                         if(race_othercheckpointlapsdelta >= 128)
1219                                 race_othercheckpointlapsdelta -= 256;
1220                         if(race_othercheckpointenemy)
1221                                 strunzone(race_othercheckpointenemy);
1222                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1223                         break;
1224
1225                 case RACE_NET_PENALTY_RACE:
1226                         race_penaltyeventtime = time;
1227                         race_penaltytime = ReadShort();
1228                         //race_penaltyaccumulator += race_penaltytime;
1229                         if(race_penaltyreason)
1230                                 strunzone(race_penaltyreason);
1231                         race_penaltyreason = strzone(ReadString());
1232                         break;
1233
1234                 case RACE_NET_PENALTY_QUALIFYING:
1235                         race_penaltyeventtime = time;
1236                         race_penaltytime = ReadShort();
1237                         race_penaltyaccumulator += race_penaltytime;
1238                         if(race_penaltyreason)
1239                                 strunzone(race_penaltyreason);
1240                         race_penaltyreason = strzone(ReadString());
1241                         break;
1242
1243                 case RACE_NET_SERVER_RECORD:
1244                         race_server_record = ReadInt24_t();
1245                         break;
1246                 case RACE_NET_SPEED_AWARD:
1247                         race_speedaward = ReadInt24_t();
1248                         if(race_speedaward_holder)
1249                                 strunzone(race_speedaward_holder);
1250                         race_speedaward_holder = strzone(ReadString());
1251                         break;
1252                 case RACE_NET_SPEED_AWARD_BEST:
1253                         race_speedaward_alltimebest = ReadInt24_t();
1254                         if(race_speedaward_alltimebest_holder)
1255                                 strunzone(race_speedaward_alltimebest_holder);
1256                         race_speedaward_alltimebest_holder = strzone(ReadString());
1257                         break;
1258                 case RACE_NET_SERVER_RANKINGS:
1259                         float pos, prevpos, del;
1260                         pos = ReadShort();
1261                         prevpos = ReadShort();
1262                         del = ReadShort();
1263
1264                         // move other rankings out of the way
1265                         float i;
1266                         if (prevpos) {
1267                                 for (i=prevpos-1;i>pos-1;--i) {
1268                                         grecordtime[i] = grecordtime[i-1];
1269                                         if(grecordholder[i])
1270                                                 strunzone(grecordholder[i]);
1271                                         grecordholder[i] = strzone(grecordholder[i-1]);
1272                                 }
1273                         } else if (del) { // a record has been deleted by the admin
1274                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1275                                         if (i == RANKINGS_CNT-1) { // clear out last record
1276                                                 grecordtime[i] = 0;
1277                                                 if (grecordholder[i])
1278                                                         strunzone(grecordholder[i]);
1279                                                 grecordholder[i] = string_null;
1280                                         }
1281                                         else {
1282                                                 grecordtime[i] = grecordtime[i+1];
1283                                                 if (grecordholder[i])
1284                                                         strunzone(grecordholder[i]);
1285                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1286                                         }
1287                                 }
1288                         } else { // player has no ranked record yet
1289                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1290                                         grecordtime[i] = grecordtime[i-1];
1291                                         if(grecordholder[i])
1292                                                 strunzone(grecordholder[i]);
1293                                         grecordholder[i] = strzone(grecordholder[i-1]);
1294                                 }
1295                         }
1296
1297                         // store new ranking
1298                         if(grecordholder[pos-1] != "")
1299                                 strunzone(grecordholder[pos-1]);
1300                         grecordholder[pos-1] = strzone(ReadString());
1301                         grecordtime[pos-1] = ReadInt24_t();
1302                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1303                                 race_myrank = pos;
1304                         break;
1305                 case RACE_NET_SERVER_STATUS:
1306                         race_status = ReadShort();
1307                         if(race_status_name)
1308                                 strunzone(race_status_name);
1309                         race_status_name = strzone(ReadString());
1310         }
1311 }
1312
1313 void Net_ReadSpawn()
1314 {
1315         zoomin_effect = 1;
1316         current_viewzoom = 0.6;
1317 }
1318
1319 void Net_TeamNagger()
1320 {
1321         teamnagger = 1;
1322 }
1323
1324 void Net_ReadPingPLReport()
1325 {
1326         float e, pi, pl, ml;
1327         e = ReadByte();
1328         pi = ReadShort();
1329         pl = ReadByte();
1330         ml = ReadByte();
1331         if not(playerslots[e])
1332                 return;
1333         playerslots[e].ping = pi;
1334         playerslots[e].ping_packetloss = pl / 255.0;
1335         playerslots[e].ping_movementloss = ml / 255.0;
1336 }
1337
1338 void Net_VoteDialog(float highlight) {
1339         if(highlight) {
1340                 vote_highlighted = ReadByte();
1341                 return;
1342         }
1343
1344         vote_yescount = ReadByte();
1345         vote_nocount = ReadByte();
1346         vote_needed = ReadByte();
1347         vote_active = 1;
1348 }
1349
1350 void Net_VoteDialogReset() {
1351         vote_active = 0;
1352 }
1353
1354 void Net_Notify() {
1355         float type;
1356         type = ReadByte();
1357
1358         if(type == CSQC_KILLNOTIFY)
1359         {
1360                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1361         }
1362         else if(type == CSQC_CENTERPRINT)
1363         {
1364                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1365         }
1366 }
1367
1368 void Net_WeaponComplain() {
1369         complain_weapon = ReadByte();
1370
1371         if(complain_weapon_name)
1372                 strunzone(complain_weapon_name);
1373         complain_weapon_name = strzone(ReadString());
1374
1375         complain_weapon_type = ReadByte();
1376
1377         complain_weapon_time = time;
1378         weapontime = time; // ping the weapon panel
1379 }
1380
1381 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1382 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1383 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1384 float CSQC_Parse_TempEntity()
1385 {
1386         local float bHandled;
1387                 bHandled  = true;
1388         // Acquire TE ID
1389         local float nTEID;
1390                 nTEID = ReadByte();
1391
1392                 // NOTE: Could just do return instead of break...
1393         switch(nTEID)
1394         {
1395                 case TE_CSQC_TARGET_MUSIC:
1396                         Net_TargetMusic();
1397                         bHandled = true;
1398                         break;
1399                 case TE_CSQC_PICTURE:
1400                         Net_MapVote_Picture();
1401                         bHandled = true;
1402                         break;
1403                 case TE_CSQC_RACE:
1404                         Net_ReadRace();
1405                         bHandled = true;
1406                         break;
1407                 case TE_CSQC_SPAWN:
1408                         Net_ReadSpawn();
1409                         bHandled = true;
1410                         break;
1411                 case TE_CSQC_ZCURVEPARTICLES:
1412                         Net_ReadZCurveParticles();
1413                         bHandled = true;
1414                         break;
1415                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1416                         Net_ReadNexgunBeamParticle();
1417                         bHandled = true;
1418                         break;
1419                 case TE_CSQC_TEAMNAGGER:
1420                         Net_TeamNagger();
1421                         bHandled = true;
1422                         break;
1423                 case TE_CSQC_VOTE:
1424                         Net_VoteDialog(ReadByte());
1425                         bHandled = true;
1426                         break;
1427                 case TE_CSQC_VOTERESET:
1428                         Net_VoteDialogReset();
1429                         bHandled = true;
1430                         break;
1431                 case TE_CSQC_LIGHTNINGARC:
1432                         Net_ReadLightningarc();
1433                         bHandled = true;
1434                         break;
1435                 case TE_CSQC_PINGPLREPORT:
1436                         Net_ReadPingPLReport();
1437                         bHandled = true;
1438                         break;
1439                 case TE_CSQC_ANNOUNCE:
1440                         announce_snd = strzone(ReadString());
1441                         bHandled = true;
1442                         break;
1443                 case TE_CSQC_NOTIFY:
1444                         Net_Notify();
1445                         bHandled = true;
1446                         break;
1447                 case TE_CSQC_WEAPONCOMPLAIN:
1448                         Net_WeaponComplain();
1449                         bHandled = true;
1450                         break;
1451                 default:
1452                         // No special logic for this temporary entity; return 0 so the engine can handle it
1453                         bHandled = false;
1454                         break;
1455         }
1456
1457         return bHandled;
1458 }
1459
1460 string getcommandkey(string text, string command)
1461 {
1462         string keys;
1463         float n, j, k, l;
1464
1465         if (!autocvar_hud_showbinds)
1466                 return text;
1467
1468         keys = db_get(binddb, command);
1469         if (!keys)
1470         {
1471                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1472                 for(j = 0; j < n; ++j)
1473                 {
1474                         k = stof(argv(j));
1475                         if(k != -1)
1476                         {
1477                                 if ("" == keys)
1478                                         keys = keynumtostring(k);
1479                                 else
1480                                         keys = strcat(keys, ", ", keynumtostring(k));
1481
1482                                 ++l;
1483                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1484                         }
1485
1486                 }
1487                 db_put(binddb, command, keys);
1488         }
1489
1490         if ("" == keys) {
1491                 if (autocvar_hud_showbinds > 1)
1492                         return sprintf(_("%s (not bound)"), text);
1493                 else
1494                         return text;
1495         }
1496         else if (autocvar_hud_showbinds > 1)
1497                 return sprintf(_("%s (%s)"), text, keys);
1498         else
1499                 return keys;
1500 }