qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(NUM_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 160
 161         WaypointSprite_Load();
 162
 163         // precaches
 164         precache_model("null");
 165         precache_sound("misc/hit.wav");
 166         precache_sound("misc/typehit.wav");
 167         if (autocvar_cl_precacheplayermodels)
 168         {
 169                 precache_all_playermodels("models/player/*.zym");
 170                 precache_all_playermodels("models/player/*.dpm");
 171                 precache_all_playermodels("models/player/*.md3");
 172                 precache_all_playermodels("models/player/*.psk");
 173                 precache_all_playermodels("models/player/*.iqm");
 174         }
 175
 176         Projectile_Precache();
 177         Hook_Precache();
 178         GibSplash_Precache();
 179         Casings_Precache();
 180         DamageInfo_Precache();
 181         Vehicles_Precache();
 182         turrets_precache();
 183         Tuba_Precache();
 184         CSQCPlayer_Precache();
 185
 186         if(autocvar_cl_reticle)
 187         {
 188                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 189                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 190         }
 191
 192         get_mi_min_max_texcoords(1); // try the CLEVER way first
 193         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 194         shortmapname = mi_shortname;
 195
 196         if(precache_pic(minimapname) == "")
 197         {
 198                 // but maybe we have a non-clever minimap
 199                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 200                 if(precache_pic(minimapname) == "")
 201                         minimapname = ""; // FAIL
 202                 else
 203                         get_mi_min_max_texcoords(0); // load new texcoords
 204         }
 205
 206         mi_center = (mi_min + mi_max) * 0.5;
 207         mi_scale = mi_max - mi_min;
 208         minimapname = strzone(minimapname);
 209
 210         WarpZone_Init();
 211
 212         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 213         hud_configure_prev = -1;
 214
 215         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 216 }
 217
 218 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 219 void Shutdown(void)
 220 {
 221 #ifdef USE_FTE
 222 #pragma TARGET id
 223         if(!__engine_check)
 224                 return 0;
 225 #pragma TARGET fte
 226 #endif
 227
 228         WarpZone_Shutdown();
 229
 230         remove(teams);
 231         remove(players);
 232         db_close(binddb);
 233         db_close(tempdb);
 234         if(autocvar_cl_db_saveasdump)
 235                 db_dump(ClientProgsDB, "client.db");
 236         else
 237                 db_save(ClientProgsDB, "client.db");
 238         db_close(ClientProgsDB);
 239
 240         if(camera_active)
 241                 cvar_set("chase_active",ftos(chase_active_backup));
 242
 243         // unset the event chasecam's chase_active
 244         if(autocvar_chase_active < 0)
 245                 cvar_set("chase_active", "0");
 246
 247         if not(isdemo())
 248         {
 249                 if not(calledhooks & HOOK_START)
 250                         localcmd("\n_cl_hook_gamestart nop\n");
 251                 if not(calledhooks & HOOK_END)
 252                         localcmd("\ncl_hook_gameend\n");
 253         }
 254 }
 255
 256 .float has_team;
 257 float SetTeam(entity o, float Team)
 258 {
 259         entity tm;
 260         if(teamplay)
 261         {
 262                 switch(Team)
 263                 {
 264                         case -1:
 265                         case NUM_TEAM_1:
 266                         case NUM_TEAM_2:
 267                         case NUM_TEAM_3:
 268                         case NUM_TEAM_4:
 269                                 break;
 270                         default:
 271                                 if(GetTeam(Team, false) == world)
 272                                 {
 273                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 274                                         Team = NUM_SPECTATOR;
 275                                 }
 276                                 break;
 277                 }
 278         }
 279         else
 280         {
 281                 switch(Team)
 282                 {
 283                         case -1:
 284                         case 0:
 285                                 break;
 286                         default:
 287                                 if(GetTeam(Team, false) == world)
 288                                 {
 289                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 290                                         Team = NUM_SPECTATOR;
 291                                 }
 292                                 break;
 293                 }
 294         }
 295         if(Team == -1) // leave
 296         {
 297                 if(o.has_team)
 298                 {
 299                         tm = GetTeam(o.team, false);
 300                         tm.team_size -= 1;
 301                         o.has_team = 0;
 302                         return TRUE;
 303                 }
 304         }
 305         else
 306         {
 307                 if not(o.has_team)
 308                 {
 309                         o.team = Team;
 310                         tm = GetTeam(Team, true);
 311                         tm.team_size += 1;
 312                         o.has_team = 1;
 313                         return TRUE;
 314                 }
 315                 else if(Team != o.team)
 316                 {
 317                         tm = GetTeam(o.team, false);
 318                         tm.team_size -= 1;
 319                         o.team = Team;
 320                         tm = GetTeam(Team, true);
 321                         tm.team_size += 1;
 322                         return TRUE;
 323                 }
 324         }
 325         return FALSE;
 326 }
 327
 328 void Playerchecker_Think()
 329 {
 330         float i;
 331         entity e;
 332         for(i = 0; i < maxclients; ++i)
 333         {
 334                 e = playerslots[i];
 335                 if(GetPlayerName(i) == "")
 336                 {
 337                         if(e.sort_prev)
 338                         {
 339                                 // player disconnected
 340                                 SetTeam(e, -1);
 341                                 RemovePlayer(e);
 342                                 e.sort_prev = world;
 343                                 //e.gotscores = 0;
 344                         }
 345                 }
 346                 else
 347                 {
 348                         if not(e.sort_prev)
 349                         {
 350                                 // player connected
 351                                 if not(e)
 352                                         playerslots[i] = e = spawn();
 353                                 e.sv_entnum = i;
 354                                 e.ping = 0;
 355                                 e.ping_packetloss = 0;
 356                                 e.ping_movementloss = 0;
 357                                 //e.gotscores = 0; // we might already have the scores...
 358                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 359                                 RegisterPlayer(e);
 360                                 HUD_UpdatePlayerPos(e);
 361                         }
 362                 }
 363         }
 364         self.nextthink = time + 0.2;
 365 }
 366
 367 void Porto_Init();
 368 void TrueAim_Init();
 369 void PostInit(void)
 370 {
 371         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 372
 373         entity playerchecker;
 374         playerchecker = spawn();
 375         playerchecker.think = Playerchecker_Think;
 376         playerchecker.nextthink = time + 0.2;
 377
 378         Porto_Init();
 379         TrueAim_Init();
 380
 381         postinit = true;
 382 }
 383
 384 float button_zoom;
 385
 386 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 387 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 388 // All keys are in ascii.
 389 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 390 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 391 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 392 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 393 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 394 {
 395         float bSkipKey;
 396         bSkipKey = false;
 397
 398         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 399                 return true;
 400
 401         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 402                 return true;
 403
 404         if(menu_visible && menu_action)
 405                 if(menu_action(bInputType, nPrimary, nSecondary))
 406                         return TRUE;
 407
 408         return bSkipKey;
 409 }
 410
 411 // END REQUIRED CSQC FUNCTIONS
 412 // --------------------------------------------------------------------------
 413
 414 // --------------------------------------------------------------------------
 415 // BEGIN OPTIONAL CSQC FUNCTIONS
 416 void Ent_RemoveEntCS()
 417 {
 418         entcs_receiver[self.sv_entnum] = world;
 419 }
 420 void Ent_ReadEntCS()
 421 {
 422         float sf;
 423         InterpolateOrigin_Undo();
 424
 425         self.classname = "entcs_receiver";
 426         sf = ReadByte();
 427
 428         if(sf & 1)
 429                 self.sv_entnum = ReadByte();
 430         if(sf & 2)
 431         {
 432                 self.origin_x = ReadShort();
 433                 self.origin_y = ReadShort();
 434                 self.origin_z = ReadShort();
 435                 setorigin(self, self.origin);
 436         }
 437         if(sf & 4)
 438         {
 439                 self.angles_y = ReadByte() * 360.0 / 256;
 440                 self.angles_x = self.angles_z = 0;
 441         }
 442         if(sf & 8)
 443                 self.healthvalue = ReadByte() * 10;
 444         if(sf & 16)
 445                 self.armorvalue = ReadByte() * 10;
 446
 447         entcs_receiver[self.sv_entnum] = self;
 448         self.entremove = Ent_RemoveEntCS;
 449         self.iflags |= IFLAG_ORIGIN;
 450
 451         InterpolateOrigin_Note();
 452 }
 453
 454 void Ent_Remove();
 455
 456 void Ent_RemovePlayerScore()
 457 {
 458         float i;
 459
 460         if(self.owner)
 461         {
 462                 SetTeam(self.owner, -1);
 463                 self.owner.gotscores = 0;
 464                 for(i = 0; i < MAX_SCORE; ++i)
 465                         self.owner.(scores[i]) = 0; // clear all scores
 466         }
 467 }
 468
 469 void Ent_ReadPlayerScore()
 470 {
 471         float i, n;
 472         float isNew;
 473         entity o;
 474
 475         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 476         // (no I've never heard of M-x replace-string, sed, or anything like that)
 477         isNew = !self.owner; // workaround for DP bug
 478         n = ReadByte()-1;
 479
 480 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 481         if(!isNew && n != self.sv_entnum)
 482         {
 483                 //print(_("A CSQC entity changed its owner!\n"));
 484                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 485                 isNew = true;
 486                 Ent_Remove();
 487                 self.enttype = ENT_CLIENT_SCORES;
 488         }
 489 #endif
 490
 491         self.sv_entnum = n;
 492
 493         if not(playerslots[self.sv_entnum])
 494                 playerslots[self.sv_entnum] = spawn();
 495         o = self.owner = playerslots[self.sv_entnum];
 496         o.sv_entnum = self.sv_entnum;
 497         o.gotscores = 1;
 498
 499         //if not(o.sort_prev)
 500         //      RegisterPlayer(o);
 501         //playerchecker will do this for us later, if it has not already done so
 502
 503         float sf, lf;
 504 #if MAX_SCORE <= 8
 505         sf = ReadByte();
 506         lf = ReadByte();
 507 #else
 508         sf = ReadShort();
 509         lf = ReadShort();
 510 #endif
 511         float p;
 512         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 513                 if(sf & p)
 514                 {
 515                         if(lf & p)
 516                                 o.(scores[i]) = ReadInt24_t();
 517                         else
 518                                 o.(scores[i]) = ReadChar();
 519                 }
 520
 521         if(o.sort_prev)
 522                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 523
 524         self.entremove = Ent_RemovePlayerScore;
 525 }
 526
 527 void Ent_ReadTeamScore()
 528 {
 529         float i;
 530         entity o;
 531
 532         self.team = ReadByte();
 533         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 534
 535         float sf, lf;
 536 #if MAX_TEAMSCORE <= 8
 537         sf = ReadByte();
 538         lf = ReadByte();
 539 #else
 540         sf = ReadShort();
 541         lf = ReadShort();
 542 #endif
 543         float p;
 544         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 545                 if(sf & p)
 546                 {
 547                         if(lf & p)
 548                                 o.(teamscores[i]) = ReadInt24_t();
 549                         else
 550                                 o.(teamscores[i]) = ReadChar();
 551                 }
 552
 553         HUD_UpdateTeamPos(o);
 554 }
 555
 556 void Ent_ClientData()
 557 {
 558         float f;
 559         float newspectatee_status;
 560
 561         f = ReadByte();
 562
 563         scoreboard_showscores_force = (f & 1);
 564
 565         if(f & 2)
 566         {
 567                 newspectatee_status = ReadByte();
 568                 if(newspectatee_status == player_localnum + 1)
 569                         newspectatee_status = -1; // observing
 570         }
 571         else
 572                 newspectatee_status = 0;
 573
 574         spectatorbutton_zoom = (f & 4);
 575
 576         if(f & 8)
 577         {
 578                 angles_held_status = 1;
 579                 angles_held_x = ReadAngle();
 580                 angles_held_y = ReadAngle();
 581                 angles_held_z = 0;
 582         }
 583         else
 584                 angles_held_status = 0;
 585
 586         if(newspectatee_status != spectatee_status)
 587         {
 588                 // clear race stuff
 589                 race_laptime = 0;
 590                 race_checkpointtime = 0;
 591         }
 592         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 593         {
 594                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 595                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 596                 )
 597                         prev_p_health = -1;
 598                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 599                         prev_health = -1;
 600         }
 601         spectatee_status = newspectatee_status;
 602
 603         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 604 }
 605
 606 void Ent_Nagger()
 607 {
 608         float nags, i, j, b, f;
 609
 610         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 611
 612         if(!(nags & 4))
 613         {
 614                 if(vote_called_vote)
 615                         strunzone(vote_called_vote);
 616                 vote_called_vote = string_null;
 617                 vote_active = 0;
 618         }
 619         else
 620         {
 621                 vote_active = 1;
 622         }
 623
 624         if(nags & 64)
 625         {
 626                 vote_yescount = ReadByte();
 627                 vote_nocount = ReadByte();
 628                 vote_needed = ReadByte();
 629                 vote_highlighted = ReadChar();
 630         }
 631
 632         if(nags & 128)
 633         {
 634                 if(vote_called_vote)
 635                         strunzone(vote_called_vote);
 636                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 637         }
 638
 639         if(nags & 1)
 640         {
 641                 for(j = 0; j < maxclients; ++j)
 642                         if(playerslots[j])
 643                                 playerslots[j].ready = 1;
 644                 for(i = 1; i <= maxclients; i += 8)
 645                 {
 646                         f = ReadByte();
 647                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 648                                 if not(f & b)
 649                                         if(playerslots[j])
 650                                                 playerslots[j].ready = 0;
 651                 }
 652         }
 653
 654         ready_waiting = (nags & 1);
 655         ready_waiting_for_me = (nags & 2);
 656         vote_waiting = (nags & 4);
 657         vote_waiting_for_me = (nags & 8);
 658         warmup_stage = (nags & 16);
 659 }
 660
 661 void Ent_RandomSeed()
 662 {
 663         float s;
 664         prandom_debug();
 665         s = ReadShort();
 666         psrandom(s);
 667 }
 668
 669 void Ent_ReadAccuracy(void)
 670 {
 671         float sf, f, w, b;
 672         sf = ReadInt24_t();
 673         if(sf == 0)
 674         {
 675                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 676                         weapon_accuracy[w] = -1;
 677                 return;
 678         }
 679
 680         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 681         {
 682                 if(sf & f)
 683                 {
 684                         b = ReadByte();
 685                         if(b == 0)
 686                                 weapon_accuracy[w] = -1;
 687                         else if(b == 255)
 688                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 689                         else
 690                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 691                 }
 692                 if(f == 0x800000)
 693                         f = 1;
 694                 else
 695                         f *= 2;
 696         }
 697 }
 698
 699 void Spawn_Draw(void)
 700 {
 701         pointparticles(self.cnt, self.origin, '0 0 2', bound(0, frametime, 0.1));
 702 }
 703
 704 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 705 {
 706         float teamnum = ReadByte();
 707         self.origin_x = ReadShort();
 708         self.origin_y = ReadShort();
 709         self.origin_z = ReadShort();
 710
 711         if(is_new)
 712         {
 713                 switch(teamnum)
 714                 {
 715                         default: self.cnt = particleeffectnum("EF_STARDUST"); break;
 716                 }
 717
 718                 //self.colormod = '200 0 0'; //colormapPaletteColor(teamnum - 1, FALSE);
 719
 720                 //setsize(self, PL_MIN, PL_MAX);
 721
 722                 //droptofloor();
 723
 724                 //self.mdl = "models/domination/dom_unclaimed.md3";
 725                 //precache_model(self.mdl);
 726                 //setmodel(self, self.mdl);
 727                 self.drawmask = MASK_NORMAL;
 728                 self.movetype = MOVETYPE_NOCLIP;
 729                 self.draw = Spawn_Draw;
 730
 731         }
 732
 733         print(sprintf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d (%s)\n", is_new, vtos(self.origin), teamnum, "foobar"));
 734 }
 735
 736 void Ent_ReadSpawnEvent(float is_new)
 737 {
 738         // If entnum is 0, ONLY do the local spawn actions
 739         // this way the server can disable the sending of
 740         // spawn origin or such to clients if wanted.
 741         float entnum = ReadByte();
 742
 743         if(entnum)
 744         {
 745                 self.origin_x = ReadShort();
 746                 self.origin_y = ReadShort();
 747                 self.origin_z = ReadShort();
 748
 749                 if(is_new)
 750                 {
 751                         float teamnum = GetPlayerColor(entnum - 1);
 752                         //if(autocvar_cl_spawn_event_sound)
 753                         {
 754                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 755                         }
 756                         //if(autocvar_cl_spawn_event_particles)
 757                         {
 758                                 switch(teamnum)
 759                                 {
 760                                         default: pointparticles(particleeffectnum("red_cap"), self.origin, '0 0 0', 1); break;
 761                                 }
 762                         }
 763                 }
 764         }
 765
 766         // local spawn actions
 767         if(is_new && (!entnum || (entnum == player_localentnum)))
 768         {
 769                 zoomin_effect = 1;
 770                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 771
 772                 if(autocvar_cl_unpress_zoom_on_spawn)
 773                 {
 774                         localcmd("-zoom\n");
 775                         button_zoom = FALSE;
 776                 }
 777         }
 778
 779         print(sprintf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d (%s), localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum, "foobar"));
 780 }
 781
 782 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 783 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 784 void Ent_RadarLink();
 785 void Ent_Init();
 786 void Ent_ScoresInfo();
 787 void CSQC_Ent_Update(float bIsNewEntity)
 788 {
 789         float t;
 790         float savetime;
 791         t = ReadByte();
 792
 793         if(autocvar_developer_csqcentities)
 794                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 795
 796         // set up the "time" global for received entities to be correct for interpolation purposes
 797         savetime = time;
 798         if(servertime)
 799         {
 800                 time = servertime;
 801         }
 802         else
 803         {
 804                 serverprevtime = time;
 805                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 806                 time = serverprevtime + serverdeltatime;
 807         }
 808
 809 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 810         if(self.enttype)
 811         {
 812                 if(t != self.enttype || bIsNewEntity)
 813                 {
 814                         //print(_("A CSQC entity changed its type!\n"));
 815                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 816                         Ent_Remove();
 817                         clearentity(self);
 818                         bIsNewEntity = 1;
 819                 }
 820         }
 821         else
 822         {
 823                 if(!bIsNewEntity)
 824                 {
 825                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 826                         bIsNewEntity = 1;
 827                 }
 828         }
 829 #endif
 830         self.enttype = t;
 831         switch(t)
 832         {
 833                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 834                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 835                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 836                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 837                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 838                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 839                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 840                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 841                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 842                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 843                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 844                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 845                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 846                 case ENT_CLIENT_INIT: Ent_Init(); break;
 847                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 848                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 849                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 850                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 851                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 852                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 853                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 854                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 855                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 856                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 857                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 858                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 859                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 860                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 861                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 862                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 863                 case ENT_CLIENT_TURRET: ent_turret(); break;
 864                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 865                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 866                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 867                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 868                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 869                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 870
 871                 default:
 872                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 873                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 874                         break;
 875         }
 876
 877         time = savetime;
 878 }
 879 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 880 // used when an entity changes its type. For an entity that someone interacts
 881 // with others, make sure it can no longer do so.
 882 void Ent_Remove()
 883 {
 884         if(self.entremove)
 885                 self.entremove();
 886
 887         if(self.skeletonindex)
 888         {
 889                 skel_delete(self.skeletonindex);
 890                 self.skeletonindex = 0;
 891         }
 892
 893         if(self.snd_looping > 0)
 894         {
 895                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 896                 self.snd_looping = 0;
 897         }
 898
 899         self.enttype = 0;
 900         self.classname = "";
 901         self.draw = menu_sub_null;
 902         self.entremove = menu_sub_null;
 903         // TODO possibly set more stuff to defaults
 904 }
 905 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 906 void CSQC_Ent_Remove()
 907 {
 908         if(autocvar_developer_csqcentities)
 909                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 910
 911         if(wasfreed(self))
 912         {
 913                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 914                 return;
 915         }
 916         if(self.enttype)
 917                 Ent_Remove();
 918         remove(self);
 919 }
 920
 921 void Gamemode_Init()
 922 {
 923         if not(isdemo())
 924         {
 925                 if(!(calledhooks & HOOK_START))
 926                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 927                 calledhooks |= HOOK_START;
 928         }
 929 }
 930 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 931 void CSQC_Parse_StuffCmd(string strMessage)
 932 {
 933         if(autocvar_developer_csqcentities)
 934                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 935
 936         localcmd(strMessage);
 937 }
 938 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 939 void CSQC_Parse_Print(string strMessage)
 940 {
 941         if(autocvar_developer_csqcentities)
 942                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 943
 944         print(ColorTranslateRGB(strMessage));
 945 }
 946
 947 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 948 void CSQC_Parse_CenterPrint(string strMessage)
 949 {
 950         if(autocvar_developer_csqcentities)
 951                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 952
 953         centerprint_hud(strMessage);
 954 }
 955
 956 string notranslate_fogcmd1 = "\nfog ";
 957 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 958 void Fog_Force()
 959 {
 960         // TODO somehow thwart prvm_globalset client ...
 961
 962         if(forcefog != "")
 963                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 964 }
 965
 966 void Gamemode_Init();
 967 void Ent_ScoresInfo()
 968 {
 969         float i;
 970         self.classname = "ent_client_scores_info";
 971         gametype = ReadInt24_t();
 972         for(i = 0; i < MAX_SCORE; ++i)
 973         {
 974                 scores_label[i] = strzone(ReadString());
 975                 scores_flags[i] = ReadByte();
 976         }
 977         for(i = 0; i < MAX_TEAMSCORE; ++i)
 978         {
 979                 teamscores_label[i] = strzone(ReadString());
 980                 teamscores_flags[i] = ReadByte();
 981         }
 982         HUD_InitScores();
 983         Gamemode_Init();
 984 }
 985
 986 void Ent_Init()
 987 {
 988         self.classname = "ent_client_init";
 989
 990         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 991
 992         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 993         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 994         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 995         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 996         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 997         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 998         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 999         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1000         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1001         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1002         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1003         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1004
1005         if(forcefog)
1006                 strunzone(forcefog);
1007         forcefog = strzone(ReadString());
1008
1009         armorblockpercent = ReadByte() / 255.0;
1010
1011         g_weaponswitchdelay = ReadByte() / 255.0;
1012
1013         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1014         g_balance_grenadelauncher_bouncestop = ReadCoord();
1015         g_balance_electro_secondary_bouncefactor = ReadCoord();
1016         g_balance_electro_secondary_bouncestop = ReadCoord();
1017
1018         nex_scope = !ReadByte();
1019         rifle_scope = !ReadByte();
1020
1021         serverflags = ReadByte();
1022
1023         minelayer_maxmines = ReadByte();
1024
1025         hagar_maxrockets = ReadByte();
1026
1027         g_trueaim_minrange = ReadCoord();
1028         g_balance_porto_secondary = ReadByte();
1029
1030         if(!postinit)
1031                 PostInit();
1032 }
1033
1034 void Net_ReadRace()
1035 {
1036         float b;
1037
1038         b = ReadByte();
1039
1040         switch(b)
1041         {
1042                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1043                         race_checkpoint = ReadByte();
1044                         race_time = ReadInt24_t();
1045                         race_previousbesttime = ReadInt24_t();
1046                         if(race_previousbestname)
1047                                 strunzone(race_previousbestname);
1048                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1049
1050                         race_checkpointtime = time;
1051
1052                         if(race_checkpoint == 0 || race_checkpoint == 254)
1053                         {
1054                                 race_penaltyaccumulator = 0;
1055                                 race_laptime = time; // valid
1056                         }
1057
1058                         break;
1059
1060                 case RACE_NET_CHECKPOINT_CLEAR:
1061                         race_laptime = 0;
1062                         race_checkpointtime = 0;
1063                         break;
1064
1065                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1066                         race_laptime = ReadCoord();
1067                         race_checkpointtime = -99999;
1068                         // fall through
1069                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1070                         race_nextcheckpoint = ReadByte();
1071
1072                         race_nextbesttime = ReadInt24_t();
1073                         if(race_nextbestname)
1074                                 strunzone(race_nextbestname);
1075                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1076                         break;
1077
1078                 case RACE_NET_CHECKPOINT_HIT_RACE:
1079                         race_mycheckpoint = ReadByte();
1080                         race_mycheckpointtime = time;
1081                         race_mycheckpointdelta = ReadInt24_t();
1082                         race_mycheckpointlapsdelta = ReadByte();
1083                         if(race_mycheckpointlapsdelta >= 128)
1084                                 race_mycheckpointlapsdelta -= 256;
1085                         if(race_mycheckpointenemy)
1086                                 strunzone(race_mycheckpointenemy);
1087                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1088                         break;
1089
1090                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1091                         race_othercheckpoint = ReadByte();
1092                         race_othercheckpointtime = time;
1093                         race_othercheckpointdelta = ReadInt24_t();
1094                         race_othercheckpointlapsdelta = ReadByte();
1095                         if(race_othercheckpointlapsdelta >= 128)
1096                                 race_othercheckpointlapsdelta -= 256;
1097                         if(race_othercheckpointenemy)
1098                                 strunzone(race_othercheckpointenemy);
1099                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1100                         break;
1101
1102                 case RACE_NET_PENALTY_RACE:
1103                         race_penaltyeventtime = time;
1104                         race_penaltytime = ReadShort();
1105                         //race_penaltyaccumulator += race_penaltytime;
1106                         if(race_penaltyreason)
1107                                 strunzone(race_penaltyreason);
1108                         race_penaltyreason = strzone(ReadString());
1109                         break;
1110
1111                 case RACE_NET_PENALTY_QUALIFYING:
1112                         race_penaltyeventtime = time;
1113                         race_penaltytime = ReadShort();
1114                         race_penaltyaccumulator += race_penaltytime;
1115                         if(race_penaltyreason)
1116                                 strunzone(race_penaltyreason);
1117                         race_penaltyreason = strzone(ReadString());
1118                         break;
1119
1120                 case RACE_NET_SERVER_RECORD:
1121                         race_server_record = ReadInt24_t();
1122                         break;
1123                 case RACE_NET_SPEED_AWARD:
1124                         race_speedaward = ReadInt24_t();
1125                         if(race_speedaward_holder)
1126                                 strunzone(race_speedaward_holder);
1127                         race_speedaward_holder = strzone(ReadString());
1128                         break;
1129                 case RACE_NET_SPEED_AWARD_BEST:
1130                         race_speedaward_alltimebest = ReadInt24_t();
1131                         if(race_speedaward_alltimebest_holder)
1132                                 strunzone(race_speedaward_alltimebest_holder);
1133                         race_speedaward_alltimebest_holder = strzone(ReadString());
1134                         break;
1135                 case RACE_NET_SERVER_RANKINGS:
1136                         float pos, prevpos, del;
1137                         pos = ReadShort();
1138                         prevpos = ReadShort();
1139                         del = ReadShort();
1140
1141                         // move other rankings out of the way
1142                         float i;
1143                         if (prevpos) {
1144                                 for (i=prevpos-1;i>pos-1;--i) {
1145                                         grecordtime[i] = grecordtime[i-1];
1146                                         if(grecordholder[i])
1147                                                 strunzone(grecordholder[i]);
1148                                         grecordholder[i] = strzone(grecordholder[i-1]);
1149                                 }
1150                         } else if (del) { // a record has been deleted by the admin
1151                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1152                                         if (i == RANKINGS_CNT-1) { // clear out last record
1153                                                 grecordtime[i] = 0;
1154                                                 if (grecordholder[i])
1155                                                         strunzone(grecordholder[i]);
1156                                                 grecordholder[i] = string_null;
1157                                         }
1158                                         else {
1159                                                 grecordtime[i] = grecordtime[i+1];
1160                                                 if (grecordholder[i])
1161                                                         strunzone(grecordholder[i]);
1162                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1163                                         }
1164                                 }
1165                         } else { // player has no ranked record yet
1166                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1167                                         grecordtime[i] = grecordtime[i-1];
1168                                         if(grecordholder[i])
1169                                                 strunzone(grecordholder[i]);
1170                                         grecordholder[i] = strzone(grecordholder[i-1]);
1171                                 }
1172                         }
1173
1174                         // store new ranking
1175                         if(grecordholder[pos-1] != "")
1176                                 strunzone(grecordholder[pos-1]);
1177                         grecordholder[pos-1] = strzone(ReadString());
1178                         grecordtime[pos-1] = ReadInt24_t();
1179                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1180                                 race_myrank = pos;
1181                         break;
1182                 case RACE_NET_SERVER_STATUS:
1183                         race_status = ReadShort();
1184                         if(race_status_name)
1185                                 strunzone(race_status_name);
1186                         race_status_name = strzone(ReadString());
1187         }
1188 }
1189
1190 void Net_TeamNagger()
1191 {
1192         teamnagger = 1;
1193 }
1194
1195 void Net_ReadPingPLReport()
1196 {
1197         float e, pi, pl, ml;
1198         e = ReadByte();
1199         pi = ReadShort();
1200         pl = ReadByte();
1201         ml = ReadByte();
1202         if not(playerslots[e])
1203                 return;
1204         playerslots[e].ping = pi;
1205         playerslots[e].ping_packetloss = pl / 255.0;
1206         playerslots[e].ping_movementloss = ml / 255.0;
1207 }
1208
1209 void Net_WeaponComplain()
1210 {
1211         complain_weapon = ReadByte();
1212
1213         if(complain_weapon_name)
1214                 strunzone(complain_weapon_name);
1215         complain_weapon_name = strzone(ReadString());
1216
1217         complain_weapon_type = ReadByte();
1218
1219         complain_weapon_time = time;
1220         weapontime = time; // ping the weapon panel
1221
1222         switch(complain_weapon_type)
1223         {
1224                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1225                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1226                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1227         }
1228 }
1229
1230 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1231 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1232 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1233 float CSQC_Parse_TempEntity()
1234 {
1235         float bHandled;
1236                 bHandled  = true;
1237         // Acquire TE ID
1238         float nTEID;
1239                 nTEID = ReadByte();
1240
1241         if(autocvar_developer_csqcentities)
1242                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1243
1244                 // NOTE: Could just do return instead of break...
1245         switch(nTEID)
1246         {
1247                 case TE_CSQC_TARGET_MUSIC:
1248                         Net_TargetMusic();
1249                         bHandled = true;
1250                         break;
1251                 case TE_CSQC_PICTURE:
1252                         Net_MapVote_Picture();
1253                         bHandled = true;
1254                         break;
1255                 case TE_CSQC_RACE:
1256                         Net_ReadRace();
1257                         bHandled = true;
1258                         break;
1259                 case TE_CSQC_ZCURVEPARTICLES:
1260                         Net_ReadZCurveParticles();
1261                         bHandled = true;
1262                         break;
1263                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1264                         Net_ReadNexgunBeamParticle();
1265                         bHandled = true;
1266                         break;
1267                 case TE_CSQC_TEAMNAGGER:
1268                         Net_TeamNagger();
1269                         bHandled = true;
1270                         break;
1271                 case TE_CSQC_LIGHTNINGARC:
1272                         Net_ReadLightningarc();
1273                         bHandled = true;
1274                         break;
1275                 case TE_CSQC_PINGPLREPORT:
1276                         Net_ReadPingPLReport();
1277                         bHandled = true;
1278                         break;
1279                 case TE_CSQC_WEAPONCOMPLAIN:
1280                         Net_WeaponComplain();
1281                         bHandled = true;
1282                         break;
1283                 case TE_CSQC_VEHICLESETUP:
1284                         Net_VehicleSetup();
1285                         bHandled = true;
1286                         break;
1287                 case TE_CSQC_SVNOTICE:
1288                         cl_notice_read();
1289                         bHandled = true;
1290                         break;
1291                 default:
1292                         // No special logic for this temporary entity; return 0 so the engine can handle it
1293                         bHandled = false;
1294                         break;
1295         }
1296
1297         return bHandled;
1298 }
1299
1300 string getcommandkey(string text, string command)
1301 {
1302         string keys;
1303         float n, j, k, l = 0;
1304
1305         if (!autocvar_hud_showbinds)
1306                 return text;
1307
1308         keys = db_get(binddb, command);
1309         if (keys == "")
1310         {
1311                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1312                 for(j = 0; j < n; ++j)
1313                 {
1314                         k = stof(argv(j));
1315                         if(k != -1)
1316                         {
1317                                 if ("" == keys)
1318                                         keys = keynumtostring(k);
1319                                 else
1320                                         keys = strcat(keys, ", ", keynumtostring(k));
1321
1322                                 ++l;
1323                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1324                                         break;
1325                         }
1326
1327                 }
1328                 if (keys == "")
1329                         keys = "NO_KEY";
1330                 db_put(binddb, command, keys);
1331         }
1332
1333         if (keys == "NO_KEY") {
1334                 if (autocvar_hud_showbinds > 1)
1335                         return sprintf(_("%s (not bound)"), text);
1336                 else
1337                         return text;
1338         }
1339         else if (autocvar_hud_showbinds > 1)
1340                 return sprintf(_("%s (%s)"), text, keys);
1341         else
1342                 return keys;
1343 }