qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(NUM_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 160
 161         WaypointSprite_Load();
 162
 163         // precaches
 164         precache_model("null");
 165         precache_sound("misc/hit.wav");
 166         precache_sound("misc/typehit.wav");
 167         if (autocvar_cl_precacheplayermodels)
 168         {
 169                 precache_all_playermodels("models/player/*.zym");
 170                 precache_all_playermodels("models/player/*.dpm");
 171                 precache_all_playermodels("models/player/*.md3");
 172                 precache_all_playermodels("models/player/*.psk");
 173                 precache_all_playermodels("models/player/*.iqm");
 174         }
 175
 176         Projectile_Precache();
 177         Hook_Precache();
 178         GibSplash_Precache();
 179         Casings_Precache();
 180         DamageInfo_Precache();
 181         Vehicles_Precache();
 182         turrets_precache();
 183         Tuba_Precache();
 184         CSQCPlayer_Precache();
 185
 186         if(autocvar_cl_reticle)
 187         {
 188                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 189                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 190         }
 191
 192         get_mi_min_max_texcoords(1); // try the CLEVER way first
 193         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 194         shortmapname = mi_shortname;
 195
 196         if(precache_pic(minimapname) == "")
 197         {
 198                 // but maybe we have a non-clever minimap
 199                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 200                 if(precache_pic(minimapname) == "")
 201                         minimapname = ""; // FAIL
 202                 else
 203                         get_mi_min_max_texcoords(0); // load new texcoords
 204         }
 205
 206         mi_center = (mi_min + mi_max) * 0.5;
 207         mi_scale = mi_max - mi_min;
 208         minimapname = strzone(minimapname);
 209
 210         WarpZone_Init();
 211
 212         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 213         hud_configure_prev = -1;
 214
 215         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 216 }
 217
 218 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 219 void Shutdown(void)
 220 {
 221 #ifdef USE_FTE
 222 #pragma TARGET id
 223         if(!__engine_check)
 224                 return 0;
 225 #pragma TARGET fte
 226 #endif
 227
 228         WarpZone_Shutdown();
 229
 230         remove(teams);
 231         remove(players);
 232         db_close(binddb);
 233         db_close(tempdb);
 234         if(autocvar_cl_db_saveasdump)
 235                 db_dump(ClientProgsDB, "client.db");
 236         else
 237                 db_save(ClientProgsDB, "client.db");
 238         db_close(ClientProgsDB);
 239
 240         if(camera_active)
 241                 cvar_set("chase_active",ftos(chase_active_backup));
 242
 243         // unset the event chasecam's chase_active
 244         if(autocvar_chase_active < 0)
 245                 cvar_set("chase_active", "0");
 246
 247         if not(isdemo())
 248         {
 249                 if not(calledhooks & HOOK_START)
 250                         localcmd("\n_cl_hook_gamestart nop\n");
 251                 if not(calledhooks & HOOK_END)
 252                         localcmd("\ncl_hook_gameend\n");
 253         }
 254 }
 255
 256 .float has_team;
 257 float SetTeam(entity o, float Team)
 258 {
 259         entity tm;
 260         if(teamplay)
 261         {
 262                 switch(Team)
 263                 {
 264                         case -1:
 265                         case NUM_TEAM_1:
 266                         case NUM_TEAM_2:
 267                         case NUM_TEAM_3:
 268                         case NUM_TEAM_4:
 269                                 break;
 270                         default:
 271                                 if(GetTeam(Team, false) == world)
 272                                 {
 273                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 274                                         Team = NUM_SPECTATOR;
 275                                 }
 276                                 break;
 277                 }
 278         }
 279         else
 280         {
 281                 switch(Team)
 282                 {
 283                         case -1:
 284                         case 0:
 285                                 break;
 286                         default:
 287                                 if(GetTeam(Team, false) == world)
 288                                 {
 289                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 290                                         Team = NUM_SPECTATOR;
 291                                 }
 292                                 break;
 293                 }
 294         }
 295         if(Team == -1) // leave
 296         {
 297                 if(o.has_team)
 298                 {
 299                         tm = GetTeam(o.team, false);
 300                         tm.team_size -= 1;
 301                         o.has_team = 0;
 302                         return TRUE;
 303                 }
 304         }
 305         else
 306         {
 307                 if not(o.has_team)
 308                 {
 309                         o.team = Team;
 310                         tm = GetTeam(Team, true);
 311                         tm.team_size += 1;
 312                         o.has_team = 1;
 313                         return TRUE;
 314                 }
 315                 else if(Team != o.team)
 316                 {
 317                         tm = GetTeam(o.team, false);
 318                         tm.team_size -= 1;
 319                         o.team = Team;
 320                         tm = GetTeam(Team, true);
 321                         tm.team_size += 1;
 322                         return TRUE;
 323                 }
 324         }
 325         return FALSE;
 326 }
 327
 328 void Playerchecker_Think()
 329 {
 330         float i;
 331         entity e;
 332         for(i = 0; i < maxclients; ++i)
 333         {
 334                 e = playerslots[i];
 335                 if(GetPlayerName(i) == "")
 336                 {
 337                         if(e.sort_prev)
 338                         {
 339                                 // player disconnected
 340                                 SetTeam(e, -1);
 341                                 RemovePlayer(e);
 342                                 e.sort_prev = world;
 343                                 //e.gotscores = 0;
 344                         }
 345                 }
 346                 else
 347                 {
 348                         if not(e.sort_prev)
 349                         {
 350                                 // player connected
 351                                 if not(e)
 352                                         playerslots[i] = e = spawn();
 353                                 e.sv_entnum = i;
 354                                 e.ping = 0;
 355                                 e.ping_packetloss = 0;
 356                                 e.ping_movementloss = 0;
 357                                 //e.gotscores = 0; // we might already have the scores...
 358                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 359                                 RegisterPlayer(e);
 360                                 HUD_UpdatePlayerPos(e);
 361                         }
 362                 }
 363         }
 364         self.nextthink = time + 0.2;
 365 }
 366
 367 void Porto_Init();
 368 void TrueAim_Init();
 369 void PostInit(void)
 370 {
 371         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 372
 373         entity playerchecker;
 374         playerchecker = spawn();
 375         playerchecker.think = Playerchecker_Think;
 376         playerchecker.nextthink = time + 0.2;
 377
 378         Porto_Init();
 379         TrueAim_Init();
 380
 381         postinit = true;
 382 }
 383
 384 float button_zoom;
 385
 386 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 387 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 388 // All keys are in ascii.
 389 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 390 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 391 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 392 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 393 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 394 {
 395         float bSkipKey;
 396         bSkipKey = false;
 397
 398         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 399                 return true;
 400
 401         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 402                 return true;
 403
 404         if(menu_visible && menu_action)
 405                 if(menu_action(bInputType, nPrimary, nSecondary))
 406                         return TRUE;
 407
 408         return bSkipKey;
 409 }
 410
 411 // END REQUIRED CSQC FUNCTIONS
 412 // --------------------------------------------------------------------------
 413
 414 // --------------------------------------------------------------------------
 415 // BEGIN OPTIONAL CSQC FUNCTIONS
 416 void Ent_RemoveEntCS()
 417 {
 418         entcs_receiver[self.sv_entnum] = world;
 419 }
 420 void Ent_ReadEntCS()
 421 {
 422         float sf;
 423         InterpolateOrigin_Undo();
 424
 425         self.classname = "entcs_receiver";
 426         sf = ReadByte();
 427
 428         if(sf & 1)
 429                 self.sv_entnum = ReadByte();
 430         if(sf & 2)
 431         {
 432                 self.origin_x = ReadShort();
 433                 self.origin_y = ReadShort();
 434                 self.origin_z = ReadShort();
 435                 setorigin(self, self.origin);
 436         }
 437         if(sf & 4)
 438         {
 439                 self.angles_y = ReadByte() * 360.0 / 256;
 440                 self.angles_x = self.angles_z = 0;
 441         }
 442         if(sf & 8)
 443                 self.healthvalue = ReadByte() * 10;
 444         if(sf & 16)
 445                 self.armorvalue = ReadByte() * 10;
 446
 447         entcs_receiver[self.sv_entnum] = self;
 448         self.entremove = Ent_RemoveEntCS;
 449         self.iflags |= IFLAG_ORIGIN;
 450
 451         InterpolateOrigin_Note();
 452 }
 453
 454 void Ent_Remove();
 455
 456 void Ent_RemovePlayerScore()
 457 {
 458         float i;
 459
 460         if(self.owner)
 461         {
 462                 SetTeam(self.owner, -1);
 463                 self.owner.gotscores = 0;
 464                 for(i = 0; i < MAX_SCORE; ++i)
 465                         self.owner.(scores[i]) = 0; // clear all scores
 466         }
 467 }
 468
 469 void Ent_ReadPlayerScore()
 470 {
 471         float i, n;
 472         float isNew;
 473         entity o;
 474
 475         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 476         // (no I've never heard of M-x replace-string, sed, or anything like that)
 477         isNew = !self.owner; // workaround for DP bug
 478         n = ReadByte()-1;
 479
 480 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 481         if(!isNew && n != self.sv_entnum)
 482         {
 483                 //print(_("A CSQC entity changed its owner!\n"));
 484                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 485                 isNew = true;
 486                 Ent_Remove();
 487                 self.enttype = ENT_CLIENT_SCORES;
 488         }
 489 #endif
 490
 491         self.sv_entnum = n;
 492
 493         if not(playerslots[self.sv_entnum])
 494                 playerslots[self.sv_entnum] = spawn();
 495         o = self.owner = playerslots[self.sv_entnum];
 496         o.sv_entnum = self.sv_entnum;
 497         o.gotscores = 1;
 498
 499         //if not(o.sort_prev)
 500         //      RegisterPlayer(o);
 501         //playerchecker will do this for us later, if it has not already done so
 502
 503         float sf, lf;
 504 #if MAX_SCORE <= 8
 505         sf = ReadByte();
 506         lf = ReadByte();
 507 #else
 508         sf = ReadShort();
 509         lf = ReadShort();
 510 #endif
 511         float p;
 512         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 513                 if(sf & p)
 514                 {
 515                         if(lf & p)
 516                                 o.(scores[i]) = ReadInt24_t();
 517                         else
 518                                 o.(scores[i]) = ReadChar();
 519                 }
 520
 521         if(o.sort_prev)
 522                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 523
 524         self.entremove = Ent_RemovePlayerScore;
 525 }
 526
 527 void Ent_ReadTeamScore()
 528 {
 529         float i;
 530         entity o;
 531
 532         self.team = ReadByte();
 533         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 534
 535         float sf, lf;
 536 #if MAX_TEAMSCORE <= 8
 537         sf = ReadByte();
 538         lf = ReadByte();
 539 #else
 540         sf = ReadShort();
 541         lf = ReadShort();
 542 #endif
 543         float p;
 544         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 545                 if(sf & p)
 546                 {
 547                         if(lf & p)
 548                                 o.(teamscores[i]) = ReadInt24_t();
 549                         else
 550                                 o.(teamscores[i]) = ReadChar();
 551                 }
 552
 553         HUD_UpdateTeamPos(o);
 554 }
 555
 556 void Ent_ClientData()
 557 {
 558         float f;
 559         float newspectatee_status;
 560
 561         f = ReadByte();
 562
 563         scoreboard_showscores_force = (f & 1);
 564
 565         if(f & 2)
 566         {
 567                 newspectatee_status = ReadByte();
 568                 if(newspectatee_status == player_localnum + 1)
 569                         newspectatee_status = -1; // observing
 570         }
 571         else
 572                 newspectatee_status = 0;
 573
 574         spectatorbutton_zoom = (f & 4);
 575
 576         if(f & 8)
 577         {
 578                 angles_held_status = 1;
 579                 angles_held_x = ReadAngle();
 580                 angles_held_y = ReadAngle();
 581                 angles_held_z = 0;
 582         }
 583         else
 584                 angles_held_status = 0;
 585
 586         if(newspectatee_status != spectatee_status)
 587         {
 588                 // clear race stuff
 589                 race_laptime = 0;
 590                 race_checkpointtime = 0;
 591         }
 592         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 593         {
 594                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 595                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 596                 )
 597                         prev_p_health = -1;
 598                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 599                         prev_health = -1;
 600         }
 601         spectatee_status = newspectatee_status;
 602
 603         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 604 }
 605
 606 void Ent_Nagger()
 607 {
 608         float nags, i, j, b, f;
 609
 610         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 611
 612         if(!(nags & 4))
 613         {
 614                 if(vote_called_vote)
 615                         strunzone(vote_called_vote);
 616                 vote_called_vote = string_null;
 617                 vote_active = 0;
 618         }
 619         else
 620         {
 621                 vote_active = 1;
 622         }
 623
 624         if(nags & 64)
 625         {
 626                 vote_yescount = ReadByte();
 627                 vote_nocount = ReadByte();
 628                 vote_needed = ReadByte();
 629                 vote_highlighted = ReadChar();
 630         }
 631
 632         if(nags & 128)
 633         {
 634                 if(vote_called_vote)
 635                         strunzone(vote_called_vote);
 636                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 637         }
 638
 639         if(nags & 1)
 640         {
 641                 for(j = 0; j < maxclients; ++j)
 642                         if(playerslots[j])
 643                                 playerslots[j].ready = 1;
 644                 for(i = 1; i <= maxclients; i += 8)
 645                 {
 646                         f = ReadByte();
 647                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 648                                 if not(f & b)
 649                                         if(playerslots[j])
 650                                                 playerslots[j].ready = 0;
 651                 }
 652         }
 653
 654         ready_waiting = (nags & 1);
 655         ready_waiting_for_me = (nags & 2);
 656         vote_waiting = (nags & 4);
 657         vote_waiting_for_me = (nags & 8);
 658         warmup_stage = (nags & 16);
 659 }
 660
 661 void Ent_RandomSeed()
 662 {
 663         float s;
 664         prandom_debug();
 665         s = ReadShort();
 666         psrandom(s);
 667 }
 668
 669 void Ent_ReadAccuracy(void)
 670 {
 671         float sf, f, w, b;
 672         sf = ReadInt24_t();
 673         if(sf == 0)
 674         {
 675                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 676                         weapon_accuracy[w] = -1;
 677                 return;
 678         }
 679
 680         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 681         {
 682                 if(sf & f)
 683                 {
 684                         b = ReadByte();
 685                         if(b == 0)
 686                                 weapon_accuracy[w] = -1;
 687                         else if(b == 255)
 688                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 689                         else
 690                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 691                 }
 692                 if(f == 0x800000)
 693                         f = 1;
 694                 else
 695                         f *= 2;
 696         }
 697 }
 698 .float last_spawn_time;
 699 void Spawn_Draw(void)
 700 {
 701         pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 2', bound(0, frametime, 0.1));
 702 }
 703
 704 void Ent_ReadSpawnPoint(float is_new)
 705 {
 706         float sendflag = ReadByte();
 707
 708         if(sendflag & 1)
 709         {
 710                 self.team = ReadByte();
 711                 self.origin_x = ReadShort();
 712                 self.origin_y = ReadShort();
 713                 self.origin_z = ReadShort();
 714         }
 715         if(sendflag & 2)
 716         {
 717                 self.last_spawn_time = ReadLong();
 718         }
 719
 720         if(self.last_spawn_time) { pointparticles(particleeffectnum("fireball_muzzleflash"), self.origin, '0 0 2', 1); self.last_spawn_time = 0; }
 721
 722
 723         self.colormod = '200 0 0'; //colormapPaletteColor(self.team - 1, FALSE);
 724
 725         //setsize(self, PL_MIN, PL_MAX);
 726
 727         //droptofloor();
 728
 729         //self.mdl = "models/domination/dom_unclaimed.md3";
 730         //precache_model(self.mdl);
 731         //setmodel(self, self.mdl);
 732         self.drawmask = MASK_NORMAL;
 733         self.movetype = MOVETYPE_NOCLIP;
 734         self.draw = Spawn_Draw;
 735
 736         print(sprintf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d (%s)\n", is_new, vtos(self.origin), self.team, "foobar"));
 737 }
 738
 739 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 740 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 741 void Ent_RadarLink();
 742 void Ent_Init();
 743 void Ent_ScoresInfo();
 744 void CSQC_Ent_Update(float bIsNewEntity)
 745 {
 746         float t;
 747         float savetime;
 748         t = ReadByte();
 749
 750         if(autocvar_developer_csqcentities)
 751                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 752
 753         // set up the "time" global for received entities to be correct for interpolation purposes
 754         savetime = time;
 755         if(servertime)
 756         {
 757                 time = servertime;
 758         }
 759         else
 760         {
 761                 serverprevtime = time;
 762                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 763                 time = serverprevtime + serverdeltatime;
 764         }
 765
 766 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 767         if(self.enttype)
 768         {
 769                 if(t != self.enttype || bIsNewEntity)
 770                 {
 771                         //print(_("A CSQC entity changed its type!\n"));
 772                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 773                         Ent_Remove();
 774                         clearentity(self);
 775                         bIsNewEntity = 1;
 776                 }
 777         }
 778         else
 779         {
 780                 if(!bIsNewEntity)
 781                 {
 782                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 783                         bIsNewEntity = 1;
 784                 }
 785         }
 786 #endif
 787         self.enttype = t;
 788         switch(t)
 789         {
 790                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 791                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 792                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 793                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 794                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 795                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 796                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 797                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 798                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 799                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 800                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 801                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 802                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 803                 case ENT_CLIENT_INIT: Ent_Init(); break;
 804                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 805                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 806                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 807                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 808                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 809                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 810                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 811                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 812                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 813                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 814                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 815                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 816                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 817                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 818                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 819                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 820                 case ENT_CLIENT_TURRET: ent_turret(); break;
 821                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 822                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 823                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 824                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 825                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 826
 827                 default:
 828                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 829                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 830                         break;
 831         }
 832
 833         time = savetime;
 834 }
 835 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 836 // used when an entity changes its type. For an entity that someone interacts
 837 // with others, make sure it can no longer do so.
 838 void Ent_Remove()
 839 {
 840         if(self.entremove)
 841                 self.entremove();
 842
 843         if(self.skeletonindex)
 844         {
 845                 skel_delete(self.skeletonindex);
 846                 self.skeletonindex = 0;
 847         }
 848
 849         if(self.snd_looping > 0)
 850         {
 851                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 852                 self.snd_looping = 0;
 853         }
 854
 855         self.enttype = 0;
 856         self.classname = "";
 857         self.draw = menu_sub_null;
 858         self.entremove = menu_sub_null;
 859         // TODO possibly set more stuff to defaults
 860 }
 861 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 862 void CSQC_Ent_Remove()
 863 {
 864         if(autocvar_developer_csqcentities)
 865                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 866
 867         if(wasfreed(self))
 868         {
 869                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 870                 return;
 871         }
 872         if(self.enttype)
 873                 Ent_Remove();
 874         remove(self);
 875 }
 876
 877 void Gamemode_Init()
 878 {
 879         if not(isdemo())
 880         {
 881                 if(!(calledhooks & HOOK_START))
 882                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 883                 calledhooks |= HOOK_START;
 884         }
 885 }
 886 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 887 void CSQC_Parse_StuffCmd(string strMessage)
 888 {
 889         if(autocvar_developer_csqcentities)
 890                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 891
 892         localcmd(strMessage);
 893 }
 894 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 895 void CSQC_Parse_Print(string strMessage)
 896 {
 897         if(autocvar_developer_csqcentities)
 898                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 899
 900         print(ColorTranslateRGB(strMessage));
 901 }
 902
 903 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 904 void CSQC_Parse_CenterPrint(string strMessage)
 905 {
 906         if(autocvar_developer_csqcentities)
 907                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 908
 909         centerprint_hud(strMessage);
 910 }
 911
 912 string notranslate_fogcmd1 = "\nfog ";
 913 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 914 void Fog_Force()
 915 {
 916         // TODO somehow thwart prvm_globalset client ...
 917
 918         if(forcefog != "")
 919                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 920 }
 921
 922 void Gamemode_Init();
 923 void Ent_ScoresInfo()
 924 {
 925         float i;
 926         self.classname = "ent_client_scores_info";
 927         gametype = ReadInt24_t();
 928         for(i = 0; i < MAX_SCORE; ++i)
 929         {
 930                 scores_label[i] = strzone(ReadString());
 931                 scores_flags[i] = ReadByte();
 932         }
 933         for(i = 0; i < MAX_TEAMSCORE; ++i)
 934         {
 935                 teamscores_label[i] = strzone(ReadString());
 936                 teamscores_flags[i] = ReadByte();
 937         }
 938         HUD_InitScores();
 939         Gamemode_Init();
 940 }
 941
 942 void Ent_Init()
 943 {
 944         self.classname = "ent_client_init";
 945
 946         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 947
 948         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 949         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 950         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 951         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 952         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 953         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 954         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 955         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 956         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 957         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 958         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 959         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 960
 961         if(forcefog)
 962                 strunzone(forcefog);
 963         forcefog = strzone(ReadString());
 964
 965         armorblockpercent = ReadByte() / 255.0;
 966
 967         g_weaponswitchdelay = ReadByte() / 255.0;
 968
 969         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 970         g_balance_grenadelauncher_bouncestop = ReadCoord();
 971         g_balance_electro_secondary_bouncefactor = ReadCoord();
 972         g_balance_electro_secondary_bouncestop = ReadCoord();
 973
 974         nex_scope = !ReadByte();
 975         rifle_scope = !ReadByte();
 976
 977         serverflags = ReadByte();
 978
 979         minelayer_maxmines = ReadByte();
 980
 981         hagar_maxrockets = ReadByte();
 982
 983         g_trueaim_minrange = ReadCoord();
 984         g_balance_porto_secondary = ReadByte();
 985
 986         if(!postinit)
 987                 PostInit();
 988 }
 989
 990 void Net_ReadRace()
 991 {
 992         float b;
 993
 994         b = ReadByte();
 995
 996         switch(b)
 997         {
 998                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 999                         race_checkpoint = ReadByte();
1000                         race_time = ReadInt24_t();
1001                         race_previousbesttime = ReadInt24_t();
1002                         if(race_previousbestname)
1003                                 strunzone(race_previousbestname);
1004                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1005
1006                         race_checkpointtime = time;
1007
1008                         if(race_checkpoint == 0 || race_checkpoint == 254)
1009                         {
1010                                 race_penaltyaccumulator = 0;
1011                                 race_laptime = time; // valid
1012                         }
1013
1014                         break;
1015
1016                 case RACE_NET_CHECKPOINT_CLEAR:
1017                         race_laptime = 0;
1018                         race_checkpointtime = 0;
1019                         break;
1020
1021                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1022                         race_laptime = ReadCoord();
1023                         race_checkpointtime = -99999;
1024                         // fall through
1025                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1026                         race_nextcheckpoint = ReadByte();
1027
1028                         race_nextbesttime = ReadInt24_t();
1029                         if(race_nextbestname)
1030                                 strunzone(race_nextbestname);
1031                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1032                         break;
1033
1034                 case RACE_NET_CHECKPOINT_HIT_RACE:
1035                         race_mycheckpoint = ReadByte();
1036                         race_mycheckpointtime = time;
1037                         race_mycheckpointdelta = ReadInt24_t();
1038                         race_mycheckpointlapsdelta = ReadByte();
1039                         if(race_mycheckpointlapsdelta >= 128)
1040                                 race_mycheckpointlapsdelta -= 256;
1041                         if(race_mycheckpointenemy)
1042                                 strunzone(race_mycheckpointenemy);
1043                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1044                         break;
1045
1046                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1047                         race_othercheckpoint = ReadByte();
1048                         race_othercheckpointtime = time;
1049                         race_othercheckpointdelta = ReadInt24_t();
1050                         race_othercheckpointlapsdelta = ReadByte();
1051                         if(race_othercheckpointlapsdelta >= 128)
1052                                 race_othercheckpointlapsdelta -= 256;
1053                         if(race_othercheckpointenemy)
1054                                 strunzone(race_othercheckpointenemy);
1055                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1056                         break;
1057
1058                 case RACE_NET_PENALTY_RACE:
1059                         race_penaltyeventtime = time;
1060                         race_penaltytime = ReadShort();
1061                         //race_penaltyaccumulator += race_penaltytime;
1062                         if(race_penaltyreason)
1063                                 strunzone(race_penaltyreason);
1064                         race_penaltyreason = strzone(ReadString());
1065                         break;
1066
1067                 case RACE_NET_PENALTY_QUALIFYING:
1068                         race_penaltyeventtime = time;
1069                         race_penaltytime = ReadShort();
1070                         race_penaltyaccumulator += race_penaltytime;
1071                         if(race_penaltyreason)
1072                                 strunzone(race_penaltyreason);
1073                         race_penaltyreason = strzone(ReadString());
1074                         break;
1075
1076                 case RACE_NET_SERVER_RECORD:
1077                         race_server_record = ReadInt24_t();
1078                         break;
1079                 case RACE_NET_SPEED_AWARD:
1080                         race_speedaward = ReadInt24_t();
1081                         if(race_speedaward_holder)
1082                                 strunzone(race_speedaward_holder);
1083                         race_speedaward_holder = strzone(ReadString());
1084                         break;
1085                 case RACE_NET_SPEED_AWARD_BEST:
1086                         race_speedaward_alltimebest = ReadInt24_t();
1087                         if(race_speedaward_alltimebest_holder)
1088                                 strunzone(race_speedaward_alltimebest_holder);
1089                         race_speedaward_alltimebest_holder = strzone(ReadString());
1090                         break;
1091                 case RACE_NET_SERVER_RANKINGS:
1092                         float pos, prevpos, del;
1093                         pos = ReadShort();
1094                         prevpos = ReadShort();
1095                         del = ReadShort();
1096
1097                         // move other rankings out of the way
1098                         float i;
1099                         if (prevpos) {
1100                                 for (i=prevpos-1;i>pos-1;--i) {
1101                                         grecordtime[i] = grecordtime[i-1];
1102                                         if(grecordholder[i])
1103                                                 strunzone(grecordholder[i]);
1104                                         grecordholder[i] = strzone(grecordholder[i-1]);
1105                                 }
1106                         } else if (del) { // a record has been deleted by the admin
1107                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1108                                         if (i == RANKINGS_CNT-1) { // clear out last record
1109                                                 grecordtime[i] = 0;
1110                                                 if (grecordholder[i])
1111                                                         strunzone(grecordholder[i]);
1112                                                 grecordholder[i] = string_null;
1113                                         }
1114                                         else {
1115                                                 grecordtime[i] = grecordtime[i+1];
1116                                                 if (grecordholder[i])
1117                                                         strunzone(grecordholder[i]);
1118                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1119                                         }
1120                                 }
1121                         } else { // player has no ranked record yet
1122                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1123                                         grecordtime[i] = grecordtime[i-1];
1124                                         if(grecordholder[i])
1125                                                 strunzone(grecordholder[i]);
1126                                         grecordholder[i] = strzone(grecordholder[i-1]);
1127                                 }
1128                         }
1129
1130                         // store new ranking
1131                         if(grecordholder[pos-1] != "")
1132                                 strunzone(grecordholder[pos-1]);
1133                         grecordholder[pos-1] = strzone(ReadString());
1134                         grecordtime[pos-1] = ReadInt24_t();
1135                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1136                                 race_myrank = pos;
1137                         break;
1138                 case RACE_NET_SERVER_STATUS:
1139                         race_status = ReadShort();
1140                         if(race_status_name)
1141                                 strunzone(race_status_name);
1142                         race_status_name = strzone(ReadString());
1143         }
1144 }
1145
1146 void Net_ReadSpawn()
1147 {
1148         zoomin_effect = 1;
1149         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
1150
1151         if(autocvar_cl_unpress_zoom_on_spawn)
1152         {
1153                 localcmd("-zoom\n");
1154                 button_zoom = FALSE;
1155         }
1156 }
1157
1158 void Net_TeamNagger()
1159 {
1160         teamnagger = 1;
1161 }
1162
1163 void Net_ReadPingPLReport()
1164 {
1165         float e, pi, pl, ml;
1166         e = ReadByte();
1167         pi = ReadShort();
1168         pl = ReadByte();
1169         ml = ReadByte();
1170         if not(playerslots[e])
1171                 return;
1172         playerslots[e].ping = pi;
1173         playerslots[e].ping_packetloss = pl / 255.0;
1174         playerslots[e].ping_movementloss = ml / 255.0;
1175 }
1176
1177 void Net_WeaponComplain()
1178 {
1179         complain_weapon = ReadByte();
1180
1181         if(complain_weapon_name)
1182                 strunzone(complain_weapon_name);
1183         complain_weapon_name = strzone(ReadString());
1184
1185         complain_weapon_type = ReadByte();
1186
1187         complain_weapon_time = time;
1188         weapontime = time; // ping the weapon panel
1189
1190         switch(complain_weapon_type)
1191         {
1192                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1193                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1194                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1195         }
1196 }
1197
1198 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1199 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1200 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1201 float CSQC_Parse_TempEntity()
1202 {
1203         float bHandled;
1204                 bHandled  = true;
1205         // Acquire TE ID
1206         float nTEID;
1207                 nTEID = ReadByte();
1208
1209         if(autocvar_developer_csqcentities)
1210                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1211
1212                 // NOTE: Could just do return instead of break...
1213         switch(nTEID)
1214         {
1215                 case TE_CSQC_TARGET_MUSIC:
1216                         Net_TargetMusic();
1217                         bHandled = true;
1218                         break;
1219                 case TE_CSQC_PICTURE:
1220                         Net_MapVote_Picture();
1221                         bHandled = true;
1222                         break;
1223                 case TE_CSQC_RACE:
1224                         Net_ReadRace();
1225                         bHandled = true;
1226                         break;
1227                 case TE_CSQC_SPAWN:
1228                         Net_ReadSpawn();
1229                         bHandled = true;
1230                         break;
1231                 case TE_CSQC_ZCURVEPARTICLES:
1232                         Net_ReadZCurveParticles();
1233                         bHandled = true;
1234                         break;
1235                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1236                         Net_ReadNexgunBeamParticle();
1237                         bHandled = true;
1238                         break;
1239                 case TE_CSQC_TEAMNAGGER:
1240                         Net_TeamNagger();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_LIGHTNINGARC:
1244                         Net_ReadLightningarc();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_PINGPLREPORT:
1248                         Net_ReadPingPLReport();
1249                         bHandled = true;
1250                         break;
1251                 case TE_CSQC_WEAPONCOMPLAIN:
1252                         Net_WeaponComplain();
1253                         bHandled = true;
1254                         break;
1255                 case TE_CSQC_VEHICLESETUP:
1256                         Net_VehicleSetup();
1257                         bHandled = true;
1258                         break;
1259                 case TE_CSQC_SVNOTICE:
1260                         cl_notice_read();
1261                         bHandled = true;
1262                         break;
1263                 default:
1264                         // No special logic for this temporary entity; return 0 so the engine can handle it
1265                         bHandled = false;
1266                         break;
1267         }
1268
1269         return bHandled;
1270 }
1271
1272 string getcommandkey(string text, string command)
1273 {
1274         string keys;
1275         float n, j, k, l = 0;
1276
1277         if (!autocvar_hud_showbinds)
1278                 return text;
1279
1280         keys = db_get(binddb, command);
1281         if (keys == "")
1282         {
1283                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1284                 for(j = 0; j < n; ++j)
1285                 {
1286                         k = stof(argv(j));
1287                         if(k != -1)
1288                         {
1289                                 if ("" == keys)
1290                                         keys = keynumtostring(k);
1291                                 else
1292                                         keys = strcat(keys, ", ", keynumtostring(k));
1293
1294                                 ++l;
1295                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1296                                         break;
1297                         }
1298
1299                 }
1300                 if (keys == "")
1301                         keys = "NO_KEY";
1302                 db_put(binddb, command, keys);
1303         }
1304
1305         if (keys == "NO_KEY") {
1306                 if (autocvar_hud_showbinds > 1)
1307                         return sprintf(_("%s (not bound)"), text);
1308                 else
1309                         return text;
1310         }
1311         else if (autocvar_hud_showbinds > 1)
1312                 return sprintf(_("%s (%s)"), text, keys);
1313         else
1314                 return keys;
1315 }