qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print("^4CSQC Build information: ", WATERMARK(), "\n");
  65 #endif
  66
  67         float i;
  68         CSQC_CheckEngine();
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = 0;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         //ctf_temp_1 = "";
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  87         //registercmd("ctf_menu");
  88         registercmd("ons_map");
  89         registercmd("hud_configure");
  90         registercmd("hud_save");
  91         //registercmd("menu_action");
  92
  93         registercmd("+button3");
  94         registercmd("-button3");
  95         registercmd("+button4");
  96         registercmd("-button4");
  97         registercmd("+showscores");registercmd("-showscores");
  98         registercmd("+showaccuracy");registercmd("-showaccuracy");
  99
 100 #ifndef CAMERATEST
 101         if(isdemo())
 102         {
 103 #endif
 104                 registercmd("+forward");registercmd("-forward");
 105                 registercmd("+back");registercmd("-back");
 106                 registercmd("+moveup");registercmd("-moveup");
 107                 registercmd("+movedown");registercmd("-movedown");
 108                 registercmd("+moveright");registercmd("-moveright");
 109                 registercmd("+moveleft");registercmd("-moveleft");
 110                 registercmd("+roll_right");registercmd("-roll_right");
 111                 registercmd("+roll_left");registercmd("-roll_left");
 112 #ifndef CAMERATEST
 113         }
 114 #endif
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 117
 118         gametype = 0;
 119
 120         // hud_fields uses strunzone on the titles!
 121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 122                 hud_title[i] = strzone("(null)");
 123
 124         postinit = false;
 125
 126         calledhooks = 0;
 127
 128         teams = Sort_Spawn();
 129         players = Sort_Spawn();
 130
 131         GetTeam(COLOR_SPECTATOR, true); // add specs first
 132
 133         RegisterWeapons();
 134
 135         WaypointSprite_Load();
 136
 137         // precaches
 138         Projectile_Precache();
 139         Hook_Precache();
 140         GibSplash_Precache();
 141         Casings_Precache();
 142         DamageInfo_Precache();
 143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 144                 Announcer_Precache();
 145                 if(cl_announcer_prev)
 146                         strunzone(cl_announcer_prev);
 147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 148         }
 149         Tuba_Precache();
 150
 151         get_mi_min_max_texcoords(1); // try the CLEVER way first
 152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 153         shortmapname = mi_shortname;
 154
 155         if(precache_pic(minimapname) == "")
 156         {
 157                 // but maybe we have a non-clever minimap
 158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 159                 if(precache_pic(minimapname) == "")
 160                         minimapname = ""; // FAIL
 161                 else
 162                         get_mi_min_max_texcoords(0); // load new texcoords
 163         }
 164
 165         mi_center = (mi_min + mi_max) * 0.5;
 166         mi_scale = mi_max - mi_min;
 167         minimapname = strzone(minimapname);
 168
 169         WarpZone_Init();
 170         hud_configure_prev = -1;
 171 }
 172
 173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 174 void CSQC_Shutdown(void)
 175 {
 176 #ifdef USE_FTE
 177 #pragma TARGET id
 178         if(!__engine_check)
 179                 return 0;
 180 #pragma TARGET fte
 181 #endif
 182
 183         WarpZone_Shutdown();
 184
 185         remove(teams);
 186         remove(players);
 187         db_close(binddb);
 188         db_close(tempdb);
 189         if(cvar("cl_db_saveasdump"))
 190                 db_dump(ClientProgsDB, "client.db");
 191         else
 192                 db_save(ClientProgsDB, "client.db");
 193         db_close(ClientProgsDB);
 194
 195         cvar_clientsettemp_restore();
 196
 197         if(camera_active)
 198                 cvar_set("chase_active",ftos(chase_active_backup));
 199
 200         if not(isdemo())
 201         {
 202                 if not(calledhooks & HOOK_START)
 203                         localcmd("\n_cl_hook_gamestart nop\n");
 204                 if not(calledhooks & HOOK_END)
 205                         localcmd("\ncl_hook_gameend\n");
 206         }
 207 }
 208
 209 .float has_team;
 210 float SetTeam(entity o, float Team)
 211 {
 212         entity tm;
 213         if(teamplay)
 214         {
 215                 switch(Team)
 216                 {
 217                         case -1:
 218                         case COLOR_TEAM1:
 219                         case COLOR_TEAM2:
 220                         case COLOR_TEAM3:
 221                         case COLOR_TEAM4:
 222                                 break;
 223                         default:
 224                                 if(GetTeam(Team, false) == NULL)
 225                                 {
 226                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 227                                         Team = COLOR_SPECTATOR;
 228                                 }
 229                                 break;
 230                 }
 231         }
 232         else
 233         {
 234                 switch(Team)
 235                 {
 236                         case -1:
 237                         case 0:
 238                                 break;
 239                         default:
 240                                 if(GetTeam(Team, false) == NULL)
 241                                 {
 242                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 243                                         Team = COLOR_SPECTATOR;
 244                                 }
 245                                 break;
 246                 }
 247         }
 248         if(Team == -1) // leave
 249         {
 250                 if(o.has_team)
 251                 {
 252                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 253                         tm = GetTeam(o.team, false);
 254                         tm.team_size -= 1;
 255                         o.has_team = 0;
 256                         return TRUE;
 257                 }
 258         }
 259         else
 260         {
 261                 if not(o.has_team)
 262                 {
 263                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 264                         o.team = Team;
 265                         tm = GetTeam(Team, true);
 266                         tm.team_size += 1;
 267                         o.has_team = 1;
 268                         return TRUE;
 269                 }
 270                 else if(Team != o.team)
 271                 {
 272                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.team = Team;
 276                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 277                         tm = GetTeam(Team, true);
 278                         tm.team_size += 1;
 279                         return TRUE;
 280                 }
 281         }
 282         return FALSE;
 283 }
 284
 285 void Playerchecker_Think()
 286 {
 287         float i;
 288         entity e;
 289         for(i = 0; i < maxclients; ++i)
 290         {
 291                 e = playerslots[i];
 292                 if(GetPlayerName(i) == "")
 293                 {
 294                         if(e.sort_prev)
 295                         {
 296                                 //print("playerchecker: KILL KILL KILL\n");
 297                                 // player disconnected
 298                                 SetTeam(e, -1);
 299                                 RemovePlayer(e);
 300                                 e.sort_prev = world;
 301                                 //e.gotscores = 0;
 302                         }
 303                 }
 304                 else
 305                 {
 306                         if not(e.sort_prev)
 307                         {
 308                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 309                                 // player connected
 310                                 if not(e)
 311                                         playerslots[i] = e = spawn();
 312                                 e.sv_entnum = i;
 313                                 e.ping = 0;
 314                                 e.ping_packetloss = 0;
 315                                 e.ping_movementloss = 0;
 316                                 //e.gotscores = 0; // we might already have the scores...
 317                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 318                                 RegisterPlayer(e);
 319                                 HUD_UpdatePlayerPos(e);
 320                         }
 321                 }
 322         }
 323         self.nextthink = time + 0.2;
 324 }
 325
 326 void Porto_Init();
 327 void TrueAim_Init();
 328 void PostInit(void)
 329 {
 330         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 331         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
 332
 333         entity playerchecker;
 334         playerchecker = spawn();
 335         playerchecker.think = Playerchecker_Think;
 336         playerchecker.nextthink = time + 0.2;
 337
 338         Porto_Init();
 339         TrueAim_Init();
 340
 341         postinit = true;
 342 }
 343
 344 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 345 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 346 float button_zoom;
 347 void Cmd_HUD_SetFields(float);
 348 void Cmd_HUD_Help(float);
 349 float CSQC_ConsoleCommand(string strMessage)
 350 {
 351         float argc;
 352         // Tokenize String
 353         //argc = tokenize(strMessage);
 354         argc = tokenize_console(strMessage);
 355
 356         // Acquire Command
 357         local string strCmd;
 358         strCmd = argv(0);
 359
 360         if(strCmd == "hud_configure") { // config hud
 361                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
 362                 return true;
 363         } else if(strCmd == "hud_save") { // save hud config
 364                 if(argv(1) == "" || argv(2)) {
 365                         print("Usage:\n");
 366                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
 367                 }
 368                 else
 369                         HUD_Panel_ExportCfg(argv(1));
 370                 return true;
 371         } else if(strCmd == "+button4") { // zoom
 372                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 373                 if(ignore_plus_zoom)
 374                 {
 375                         --ignore_plus_zoom;
 376                         return false;
 377                 }
 378                 button_zoom = 1;
 379                 return true;
 380         } else if(strCmd == "-button4") { // zoom
 381                 if(ignore_minus_zoom)
 382                 {
 383                         --ignore_minus_zoom;
 384                         return false;
 385                 }
 386                 button_zoom = 0;
 387                 return true;
 388         } else if(strCmd == "+button3") { // secondary
 389                 button_attack2 = 1;
 390                 return false;
 391         } else if(strCmd == "-button3") { // secondary
 392                 button_attack2 = 0;
 393                 return false;
 394         } else if(strCmd == "+showscores") {
 395                 scoreboard_showscores = true;
 396                 return true;
 397         } else if(strCmd == "-showscores") {
 398                 scoreboard_showscores = false;
 399                 return true;
 400         } else if(strCmd == "+showaccuracy") {
 401                 scoreboard_showaccuracy = true;
 402                 return true;
 403         } else if(strCmd == "-showaccuracy") {
 404                 scoreboard_showaccuracy = false;
 405                 return true;
 406         }
 407
 408         if(camera_active)
 409         if(strCmd == "+forward" || strCmd == "-back") {
 410                 ++camera_direction_x;
 411                 return true;
 412         } else if(strCmd == "-forward" || strCmd == "+back") {
 413                 --camera_direction_x;
 414                 return true;
 415         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 416                 --camera_direction_y;
 417                 return true;
 418         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 419                 ++camera_direction_y;
 420                 return true;
 421         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 422                 ++camera_direction_z;
 423                 return true;
 424         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 425                 --camera_direction_z;
 426                 return true;
 427         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 428                 ++camera_roll;
 429                 return true;
 430         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 431                 --camera_roll;
 432                 return true;
 433         }
 434
 435         return false;
 436 }
 437
 438 .vector view_ofs;
 439 entity debug_shotorg;
 440 void ShotOrg_Draw()
 441 {
 442         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 443         self.angles = view_angles;
 444         self.angles_x = -self.angles_x;
 445         if not(self.cnt)
 446                 self.drawmask = MASK_NORMAL;
 447         else
 448                 self.drawmask = 0;
 449 }
 450 void ShotOrg_Draw2D()
 451 {
 452         vector coord2d_topleft, coord2d_topright, coord2d;
 453         string s;
 454         vector fs;
 455
 456         s = vtos(self.view_ofs);
 457         s = substring(s, 1, strlen(s) - 2);
 458         if(tokenize_console(s) == 3)
 459                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 460
 461         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 462         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 463
 464         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 465
 466         coord2d = coord2d_topleft;
 467         if(fs_x < 8)
 468         {
 469                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 470                 fs = '8 8 0';
 471         }
 472         coord2d_y -= fs_y;
 473         coord2d_z = 0;
 474         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 475 }
 476
 477 void ShotOrg_Spawn()
 478 {
 479         debug_shotorg = spawn();
 480         debug_shotorg.draw = ShotOrg_Draw;
 481         debug_shotorg.draw2d = ShotOrg_Draw2D;
 482         debug_shotorg.renderflags = RF_VIEWMODEL;
 483         debug_shotorg.effects = EF_FULLBRIGHT;
 484         precache_model("models/shotorg_adjuster.md3");
 485         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 486         debug_shotorg.scale = 2;
 487         debug_shotorg.view_ofs = '25 8 -8';
 488 }
 489
 490 void DrawDebugModel()
 491 {
 492         if(time - floor(time) > 0.5)
 493         {
 494                 PolyDrawModel(self);
 495                 self.drawmask = 0;
 496         }
 497         else
 498         {
 499                 self.renderflags = 0;
 500                 self.drawmask = MASK_NORMAL;
 501         }
 502 }
 503
 504 void GameCommand(string msg)
 505 {
 506         string s;
 507         float argc;
 508         entity e;
 509         argc = tokenize_console(msg);
 510
 511         if(argv(0) == "help" || argc == 0)
 512         {
 513                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 514                 print("  settemp cvar value\n");
 515                 print("  scoreboard_columns_set ...\n");
 516                 print("  scoreboard_columns_help\n");
 517                 GameCommand_Generic("help");
 518                 return;
 519         }
 520
 521         if(GameCommand_Generic(msg))
 522                 return;
 523
 524         string cmd;
 525         cmd = argv(0);
 526         if(cmd == "mv_download") {
 527                 Cmd_MapVote_MapDownload(argc);
 528         }
 529         else if(cmd == "settemp") {
 530                 cvar_clientsettemp(argv(1), argv(2));
 531         }
 532         else if(cmd == "scoreboard_columns_set") {
 533                 Cmd_HUD_SetFields(argc);
 534         }
 535         else if(cmd == "scoreboard_columns_help") {
 536                 Cmd_HUD_Help(argc);
 537         }
 538 #ifdef BLURTEST
 539         else if(cmd == "blurtest") {
 540                 blurtest_time0 = time;
 541                 blurtest_time1 = time + stof(argv(1));
 542                 blurtest_radius = stof(argv(2));
 543                 blurtest_power = stof(argv(3));
 544         }
 545 #endif
 546         else if(cmd == "shotorg_move") {
 547                 if(!debug_shotorg)
 548                         ShotOrg_Spawn();
 549                 else
 550                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 552         }
 553         else if(cmd == "shotorg_movez") {
 554                 if(!debug_shotorg)
 555                         ShotOrg_Spawn();
 556                 else
 557                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 558                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 559         }
 560         else if(cmd == "shotorg_set") {
 561                 if(!debug_shotorg)
 562                         ShotOrg_Spawn();
 563                 else
 564                         debug_shotorg.view_ofs = stov(argv(1));
 565                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 566         }
 567         else if(cmd == "shotorg_setz") {
 568                 if(!debug_shotorg)
 569                         ShotOrg_Spawn();
 570                 else
 571                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 572                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 573         }
 574         else if(cmd == "shotorg_toggle_hide") {
 575                 if(debug_shotorg)
 576                 {
 577                         debug_shotorg.cnt = !debug_shotorg.cnt;
 578                 }
 579         }
 580         else if(cmd == "shotorg_end") {
 581                 if(debug_shotorg)
 582                 {
 583                         print(vtos(debug_shotorg.view_ofs), "\n");
 584                         remove(debug_shotorg);
 585                         debug_shotorg = world;
 586                 }
 587                 localcmd("sv_cmd debug_shotorg\n");
 588         }
 589         else if(cmd == "sendcvar") {
 590                 // W_FixWeaponOrder will trash argv, so save what we need.
 591                 string thiscvar;
 592                 thiscvar = strzone(argv(1));
 593                 s = cvar_string(thiscvar);
 594                 if(thiscvar == "cl_weaponpriority")
 595                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 596                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 597                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 598                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 599                 strunzone(thiscvar);
 600         }
 601         else if(cmd == "spawn") {
 602                 s = argv(1);
 603                 e = spawn();
 604                 precache_model(s);
 605                 setmodel(e, s);
 606                 setorigin(e, view_origin);
 607                 e.angles = view_angles;
 608                 e.draw = DrawDebugModel;
 609                 e.classname = "debugmodel";
 610         }
 611         else
 612         {
 613                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 614         }
 615
 616         return;
 617 }
 618
 619 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 620 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 621 // All keys are in ascii.
 622 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 623 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 624 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 625 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 626 {
 627         local float bSkipKey;
 628         bSkipKey = false;
 629
 630         if(autocvar_cl_allow_uid2name == -1 && (gametype == GAME_CTS || gametype == GAME_RACE) && panel_fg_alpha && !scoreboard_active) // don't lock keys before we actually see what's going on
 631         {
 632                 /*
 633                 string vyes_keys;
 634                 float keys;
 635                 vyes_keys = findkeysforcommand("vyes");
 636                 keys = tokenize(vyes_keys);
 637
 638                 float i;
 639                 for (i = 0; i < keys; ++i)
 640                 {
 641                         print(ftos(nPrimary), " ", argv(i), "\n");
 642                         if(nPrimary == stof(argv(i)))
 643                         {
 644                                 vote_active = 0;
 645                                 cvar_set("cl_allow_uid2name", "1");
 646                                 return TRUE;
 647                         }
 648                 }
 649
 650                 string vno_keys;
 651                 vno_keys = findkeysforcommand("vno");
 652                 keys = tokenize(vno_keys);
 653
 654                 float i;
 655                 for (i = 0; i < keys; ++i)
 656                 {
 657                         if(nPrimary == stof(argv(i)))
 658                         {
 659                                 vote_active = 0;
 660                                 cvar_set("cl_allow_uid2name", "0");
 661                                 return TRUE;
 662                         }
 663                 }
 664                 */ // If only I could grab F1-F12 in CSQC... but no
 665
 666                 if(nPrimary == 121) // ascii value for y
 667                 {
 668                         vote_active = 0;
 669                         cvar_set("cl_allow_uid2name", "1");
 670                         return TRUE;
 671                 }
 672                 else if(nPrimary == 110) // ascii value for n
 673                 {
 674                         vote_active = 0;
 675                         cvar_set("cl_allow_uid2name", "0");
 676                         return TRUE;
 677                 }
 678         }
 679
 680         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 681                 return true;
 682
 683         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 684                 return true;
 685
 686         if(menu_visible)
 687                 if(menu_action(bInputType, nPrimary, nSecondary))
 688                         return TRUE;
 689
 690         return bSkipKey;
 691 }
 692
 693 // END REQUIRED CSQC FUNCTIONS
 694 // --------------------------------------------------------------------------
 695
 696 // --------------------------------------------------------------------------
 697 // BEGIN OPTIONAL CSQC FUNCTIONS
 698 void Ent_ReadEntCS()
 699 {
 700         InterpolateOrigin_Undo();
 701
 702         self.classname = "entcs_receiver";
 703         self.sv_entnum = ReadByte() - 1;
 704         self.origin_x = ReadShort();
 705         self.origin_y = ReadShort();
 706         self.origin_z = ReadShort();
 707         self.angles_y = ReadByte() * 360.0 / 256;
 708         self.origin_z = self.angles_x = self.angles_z = 0;
 709
 710         InterpolateOrigin_Note();
 711 }
 712
 713 void Ent_Remove();
 714
 715 void Ent_RemovePlayerScore()
 716 {
 717         float i;
 718
 719         if(self.owner)
 720         {
 721                 SetTeam(self.owner, -1);
 722                 self.owner.gotscores = 0;
 723                 for(i = 0; i < MAX_SCORE; ++i)
 724                         self.owner.(scores[i]) = 0; // clear all scores
 725         }
 726 }
 727
 728 void Ent_ReadPlayerScore()
 729 {
 730         float i, n;
 731         float isNew;
 732         entity o;
 733
 734         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 735         // (no I've never heard of M-x replace-string, sed, or anything like that)
 736         isNew = !self.owner; // workaround for DP bug
 737         n = ReadByte()-1;
 738
 739 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 740         if(!isNew && n != self.sv_entnum)
 741         {
 742                 print("A CSQC entity changed its owner!\n");
 743                 isNew = true;
 744                 Ent_Remove();
 745                 self.enttype = ENT_CLIENT_SCORES;
 746         }
 747 #endif
 748
 749         self.sv_entnum = n;
 750
 751         if not(playerslots[self.sv_entnum])
 752                 playerslots[self.sv_entnum] = spawn();
 753         o = self.owner = playerslots[self.sv_entnum];
 754         o.sv_entnum = self.sv_entnum;
 755         o.gotscores = 1;
 756
 757         //if not(o.sort_prev)
 758         //      RegisterPlayer(o);
 759         //playerchecker will do this for us later, if it has not already done so
 760
 761         float sf, lf;
 762 #if MAX_SCORE <= 8
 763         sf = ReadByte();
 764         lf = ReadByte();
 765 #else
 766         sf = ReadShort();
 767         lf = ReadShort();
 768 #endif
 769         float p;
 770         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 771                 if(sf & p)
 772                 {
 773                         if(lf & p)
 774                                 o.(scores[i]) = ReadInt24_t();
 775                         else
 776                                 o.(scores[i]) = ReadChar();
 777                 }
 778
 779         if(o.sort_prev)
 780                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 781
 782         self.entremove = Ent_RemovePlayerScore;
 783 }
 784
 785 void Ent_ReadTeamScore()
 786 {
 787         float i;
 788         entity o;
 789
 790         self.team = ReadByte();
 791         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 792
 793         float sf, lf;
 794 #if MAX_TEAMSCORE <= 8
 795         sf = ReadByte();
 796         lf = ReadByte();
 797 #else
 798         sf = ReadShort();
 799         lf = ReadShort();
 800 #endif
 801         float p;
 802         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 803                 if(sf & p)
 804                 {
 805                         if(lf & p)
 806                                 o.(teamscores[i]) = ReadInt24_t();
 807                         else
 808                                 o.(teamscores[i]) = ReadChar();
 809                 }
 810
 811         HUD_UpdateTeamPos(o);
 812 }
 813
 814 void Net_Reset()
 815 {
 816 }
 817
 818 void Ent_ClientData()
 819 {
 820         float f;
 821         float newspectatee_status;
 822
 823         f = ReadByte();
 824
 825         scoreboard_showscores_force = (f & 1);
 826
 827         if(f & 2)
 828         {
 829                 newspectatee_status = ReadByte();
 830                 if(newspectatee_status == player_localentnum)
 831                         newspectatee_status = -1; // observing
 832         }
 833         else
 834                 newspectatee_status = 0;
 835
 836         spectatorbutton_zoom = (f & 4);
 837
 838         if(f & 8)
 839         {
 840                 angles_held_status = 1;
 841                 angles_held_x = ReadAngle();
 842                 angles_held_y = ReadAngle();
 843                 angles_held_z = 0;
 844         }
 845         else
 846                 angles_held_status = 0;
 847
 848         if(newspectatee_status != spectatee_status)
 849         {
 850                 float i;
 851
 852                 // clear race stuff
 853                 race_laptime = 0;
 854                 race_checkpointtime = 0;
 855         }
 856         spectatee_status = newspectatee_status;
 857 }
 858
 859 void Ent_Nagger()
 860 {
 861         float nags, i, j, b, f;
 862
 863         nags = ReadByte();
 864
 865         if(nags & 128)
 866         {
 867                 if(vote_called_vote)
 868                         strunzone(vote_called_vote);
 869                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 870         }
 871
 872         if(nags & 1)
 873         {
 874                 for(j = 0; j < maxclients; ++j)
 875                         if(playerslots[j])
 876                                 playerslots[j].ready = 1;
 877                 for(i = 1; i <= maxclients; i += 8)
 878                 {
 879                         f = ReadByte();
 880                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 881                                 if not(f & b)
 882                                         if(playerslots[j])
 883                                                 playerslots[j].ready = 0;
 884                 }
 885         }
 886
 887         ready_waiting = (nags & 1);
 888         ready_waiting_for_me = (nags & 2);
 889         vote_waiting = (nags & 4);
 890         vote_waiting_for_me = (nags & 8);
 891         warmup_stage = (nags & 16);
 892 }
 893
 894 void Ent_RandomSeed()
 895 {
 896         float s;
 897         prandom_debug();
 898         s = ReadShort();
 899         psrandom(s);
 900 }
 901
 902 void Ent_ReadAccuracy(void)
 903 {
 904         float sf, f, w, b;
 905         sf = ReadInt24_t();
 906         if(sf == 0)
 907         {
 908                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 909                         weapon_accuracy[w] = -1;
 910                 return;
 911         }
 912
 913         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 914         {
 915                 if(sf & f)
 916                 {
 917                         b = ReadByte();
 918                         if(b == 0)
 919                                 weapon_accuracy[w] = -1;
 920                         else
 921                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 922                 }
 923         }
 924 }
 925
 926 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 927 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 928 void Ent_RadarLink();
 929 void Ent_Init();
 930 void Ent_ScoresInfo();
 931 void(float bIsNewEntity) CSQC_Ent_Update =
 932 {
 933         float t;
 934         float savetime;
 935         t = ReadByte();
 936
 937         // set up the "time" global for received entities to be correct for interpolation purposes
 938         savetime = time;
 939         if(servertime)
 940         {
 941                 time = servertime;
 942         }
 943         else
 944         {
 945                 serverprevtime = time;
 946                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 947                 time = serverprevtime + serverdeltatime;
 948         }
 949
 950 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 951         if(self.enttype)
 952                 if(t != self.enttype)
 953                 {
 954                         print("A CSQC entity changed its type!\n");
 955                         Ent_Remove();
 956                         bIsNewEntity = 1;
 957                 }
 958 #endif
 959         self.enttype = t;
 960         switch(t)
 961         {
 962                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 963                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 964                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 965                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 966                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 967                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 968                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 969                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 970                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 971                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 972                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 973                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 974                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 975                 case ENT_CLIENT_INIT: Ent_Init(); break;
 976                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 977                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 978                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 979                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 980                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 981                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 982                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 983                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 984                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 985                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 986                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 987                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 988                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 989                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 990                 default:
 991                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 992                         break;
 993         }
 994
 995         time = savetime;
 996 };
 997 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 998 // used when an entity changes its type. For an entity that someone interacts
 999 // with others, make sure it can no longer do so.
1000 void Ent_Remove()
1001 {
1002         if(self.entremove)
1003                 self.entremove();
1004
1005         self.enttype = 0;
1006         self.classname = "";
1007         self.draw = menu_sub_null;
1008         self.entremove = menu_sub_null;
1009         // TODO possibly set more stuff to defaults
1010 }
1011 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1012 void CSQC_Ent_Remove()
1013 {
1014         if(self.enttype)
1015                 Ent_Remove();
1016         remove(self);
1017 }
1018
1019 void Gamemode_Init()
1020 {
1021         if(gametype == GAME_ONSLAUGHT) {
1022                 print(strcat("Using ", minimapname, " as minimap.\n"));
1023                 precache_pic("gfx/ons-cp-neutral.tga");
1024                 precache_pic("gfx/ons-cp-red.tga");
1025                 precache_pic("gfx/ons-cp-blue.tga");
1026                 precache_pic("gfx/ons-frame.tga");
1027                 precache_pic("gfx/ons-frame-team.tga");
1028         }
1029
1030         if not(isdemo())
1031         {
1032                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1033                 calledhooks |= HOOK_START;
1034         }
1035 }
1036 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1037 void CSQC_Parse_StuffCmd(string strMessage)
1038 {
1039         localcmd(strMessage);
1040 }
1041 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1042 void CSQC_Parse_Print(string strMessage)
1043 {
1044         print(ColorTranslateRGB(strMessage));
1045 }
1046
1047 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1048 void CSQC_Parse_CenterPrint(string strMessage)
1049 {
1050         centerprint(strMessage);
1051 }
1052
1053 string notranslate_fogcmd1 = "\nfog ";
1054 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1055 void Fog_Force()
1056 {
1057         // TODO somehow thwart prvm_globalset client ...
1058
1059         if(forcefog != "")
1060                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1061 }
1062
1063 void Gamemode_Init();
1064 void Ent_ScoresInfo()
1065 {
1066         float i;
1067         self.classname = "ent_client_scores_info";
1068         gametype = ReadByte();
1069         for(i = 0; i < MAX_SCORE; ++i)
1070         {
1071                 scores_label[i] = strzone(ReadString());
1072                 scores_flags[i] = ReadByte();
1073         }
1074         for(i = 0; i < MAX_TEAMSCORE; ++i)
1075         {
1076                 teamscores_label[i] = strzone(ReadString());
1077                 teamscores_flags[i] = ReadByte();
1078         }
1079         HUD_InitScores();
1080         Gamemode_Init();
1081 }
1082
1083 void Ent_Init()
1084 {
1085         self.classname = "ent_client_init";
1086
1087         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1088
1089         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1090         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1091         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1092         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1093         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1094         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1095         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1096         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1097         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1098         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1099         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1100         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1101
1102         if(forcefog)
1103                 strunzone(forcefog);
1104         forcefog = strzone(ReadString());
1105
1106         armorblockpercent = ReadByte() / 255.0;
1107
1108         g_weaponswitchdelay = ReadByte() / 255.0;
1109
1110         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1111         g_balance_grenadelauncher_bouncestop = ReadCoord();
1112         g_balance_electro_secondary_bouncefactor = ReadCoord();
1113         g_balance_electro_secondary_bouncestop = ReadCoord();
1114
1115         nex_scope = !ReadByte();
1116         campingrifle_scope = !ReadByte();
1117
1118         serverflags = ReadByte();
1119
1120         if(!postinit)
1121                 PostInit();
1122 }
1123
1124 void Net_ReadRace()
1125 {
1126         float b;
1127
1128         b = ReadByte();
1129
1130         switch(b)
1131         {
1132                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1133                         race_checkpoint = ReadByte();
1134                         race_time = ReadInt24_t();
1135                         race_previousbesttime = ReadInt24_t();
1136                         if(race_previousbestname)
1137                                 strunzone(race_previousbestname);
1138                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1139
1140                         race_checkpointtime = time;
1141
1142                         if(race_checkpoint == 0 || race_checkpoint == 254)
1143                         {
1144                                 race_penaltyaccumulator = 0;
1145                                 race_laptime = time; // valid
1146                         }
1147
1148                         break;
1149
1150                 case RACE_NET_CHECKPOINT_CLEAR:
1151                         race_laptime = 0;
1152                         race_checkpointtime = 0;
1153                         break;
1154
1155                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1156                         race_laptime = ReadCoord();
1157                         race_checkpointtime = -99999;
1158                         // fall through
1159                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1160                         race_nextcheckpoint = ReadByte();
1161
1162                         race_nextbesttime = ReadInt24_t();
1163                         if(race_nextbestname)
1164                                 strunzone(race_nextbestname);
1165                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1166                         break;
1167
1168                 case RACE_NET_CHECKPOINT_HIT_RACE:
1169                         race_mycheckpoint = ReadByte();
1170                         race_mycheckpointtime = time;
1171                         race_mycheckpointdelta = ReadInt24_t();
1172                         race_mycheckpointlapsdelta = ReadByte();
1173                         if(race_mycheckpointlapsdelta >= 128)
1174                                 race_mycheckpointlapsdelta -= 256;
1175                         if(race_mycheckpointenemy)
1176                                 strunzone(race_mycheckpointenemy);
1177                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1178                         break;
1179
1180                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1181                         race_othercheckpoint = ReadByte();
1182                         race_othercheckpointtime = time;
1183                         race_othercheckpointdelta = ReadInt24_t();
1184                         race_othercheckpointlapsdelta = ReadByte();
1185                         if(race_othercheckpointlapsdelta >= 128)
1186                                 race_othercheckpointlapsdelta -= 256;
1187                         if(race_othercheckpointenemy)
1188                                 strunzone(race_othercheckpointenemy);
1189                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1190                         break;
1191
1192                 case RACE_NET_PENALTY_RACE:
1193                         race_penaltyeventtime = time;
1194                         race_penaltytime = ReadShort();
1195                         //race_penaltyaccumulator += race_penaltytime;
1196                         if(race_penaltyreason)
1197                                 strunzone(race_penaltyreason);
1198                         race_penaltyreason = strzone(ReadString());
1199                         break;
1200
1201                 case RACE_NET_PENALTY_QUALIFYING:
1202                         race_penaltyeventtime = time;
1203                         race_penaltytime = ReadShort();
1204                         race_penaltyaccumulator += race_penaltytime;
1205                         if(race_penaltyreason)
1206                                 strunzone(race_penaltyreason);
1207                         race_penaltyreason = strzone(ReadString());
1208                         break;
1209
1210                 case RACE_NET_SERVER_RECORD:
1211                         race_server_record = ReadInt24_t();
1212                         break;
1213                 case RACE_NET_SPEED_AWARD:
1214                         race_speedaward = ReadInt24_t();
1215                         if(race_speedaward_holder)
1216                                 strunzone(race_speedaward_holder);
1217                         race_speedaward_holder = strzone(ReadString());
1218                         break;
1219                 case RACE_NET_SPEED_AWARD_BEST:
1220                         race_speedaward_alltimebest = ReadInt24_t();
1221                         if(race_speedaward_alltimebest_holder)
1222                                 strunzone(race_speedaward_alltimebest_holder);
1223                         race_speedaward_alltimebest_holder = strzone(ReadString());
1224                         break;
1225                 case RACE_NET_SERVER_RANKINGS:
1226                         float pos, prevpos, del;
1227                         pos = ReadShort();
1228                         prevpos = ReadShort();
1229                         del = ReadShort();
1230
1231                         // move other rankings out of the way
1232                         float i;
1233                         if (prevpos) {
1234                                 for (i=prevpos-1;i>pos-1;--i) {
1235                                         grecordtime[i] = grecordtime[i-1];
1236                                         if(grecordholder[i])
1237                                                 strunzone(grecordholder[i]);
1238                                         grecordholder[i] = strzone(grecordholder[i-1]);
1239                                 }
1240                         } else if (del) { // a record has been deleted by the admin
1241                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1242                                         if (i == RANKINGS_CNT-1) { // clear out last record
1243                                                 grecordtime[i] = 0;
1244                                                 if (grecordholder[i])
1245                                                         strunzone(grecordholder[i]);
1246                                                 grecordholder[i] = string_null;
1247                                         }
1248                                         else {
1249                                                 grecordtime[i] = grecordtime[i+1];
1250                                                 if (grecordholder[i])
1251                                                         strunzone(grecordholder[i]);
1252                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1253                                         }
1254                                 }
1255                         } else { // player has no ranked record yet
1256                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1257                                         grecordtime[i] = grecordtime[i-1];
1258                                         if(grecordholder[i])
1259                                                 strunzone(grecordholder[i]);
1260                                         grecordholder[i] = strzone(grecordholder[i-1]);
1261                                 }
1262                         }
1263
1264                         // store new ranking
1265                         if(grecordholder[pos-1] != "")
1266                                 strunzone(grecordholder[pos-1]);
1267                         grecordholder[pos-1] = strzone(ReadString());
1268                         grecordtime[pos-1] = ReadInt24_t();
1269                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1270                                 race_myrank = pos;
1271                         break;
1272                 case RACE_NET_SERVER_STATUS:
1273                         race_status = ReadShort();
1274                         if(race_status_name)
1275                                 strunzone(race_status_name);
1276                         race_status_name = strzone(ReadString());
1277         }
1278 }
1279
1280 void Net_ReadSpawn()
1281 {
1282         zoomin_effect = 1;
1283         current_viewzoom = 0.6;
1284 }
1285
1286 void Net_TeamNagger()
1287 {
1288         teamnagger = 1;
1289 }
1290
1291 void Net_ReadPingPLReport()
1292 {
1293         float e, pi, pl, ml;
1294         e = ReadByte();
1295         pi = ReadShort();
1296         pl = ReadByte();
1297         ml = ReadByte();
1298         if not(playerslots[e])
1299                 return;
1300         playerslots[e].ping = pi;
1301         playerslots[e].ping_packetloss = pl / 255.0;
1302         playerslots[e].ping_movementloss = ml / 255.0;
1303 }
1304
1305 void Net_VoteDialog(float highlight) {
1306         if(highlight) {
1307                 vote_highlighted = ReadByte();
1308                 return;
1309         }
1310
1311         vote_yescount = ReadByte();
1312         vote_nocount = ReadByte();
1313         vote_needed = ReadByte();
1314         vote_active = 1;
1315 }
1316
1317 void Net_VoteDialogReset() {
1318         vote_active = 0;
1319 }
1320
1321 void Net_Notify() {
1322         float type;
1323         type = ReadByte();
1324
1325         if(type == CSQC_KILLNOTIFY)
1326         {
1327                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1328         }
1329         else if(type == CSQC_CENTERPRINT)
1330         {
1331                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1332         }
1333 }
1334
1335 void Net_WeaponComplain() {
1336         complain_weapon = ReadByte();
1337
1338         if(complain_weapon_name)
1339                 strunzone(complain_weapon_name);
1340         complain_weapon_name = strzone(ReadString());
1341
1342         complain_weapon_type = ReadByte();
1343
1344         complain_weapon_time = time;
1345         weapontime = time; // ping the weapon panel
1346 }
1347
1348 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1349 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1350 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1351 float CSQC_Parse_TempEntity()
1352 {
1353         local float bHandled;
1354                 bHandled  = true;
1355         // Acquire TE ID
1356         local float nTEID;
1357                 nTEID = ReadByte();
1358
1359                 // NOTE: Could just do return instead of break...
1360         switch(nTEID)
1361         {
1362                 case TE_CSQC_TARGET_MUSIC:
1363                         Net_TargetMusic();
1364                         bHandled = true;
1365                         break;
1366                 case TE_CSQC_PICTURE:
1367                         Net_MapVote_Picture();
1368                         bHandled = true;
1369                         break;
1370                 case TE_CSQC_RACE:
1371                         Net_ReadRace();
1372                         bHandled = true;
1373                         break;
1374                 case TE_CSQC_SPAWN:
1375                         Net_ReadSpawn();
1376                         bHandled = true;
1377                         break;
1378                 case TE_CSQC_ZCURVEPARTICLES:
1379                         Net_ReadZCurveParticles();
1380                         bHandled = true;
1381                         break;
1382                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1383                         Net_ReadNexgunBeamParticle();
1384                         bHandled = true;
1385                         break;
1386                 case TE_CSQC_TEAMNAGGER:
1387                         Net_TeamNagger();
1388                         bHandled = true;
1389                         break;
1390                 case TE_CSQC_VOTE:
1391                         Net_VoteDialog(ReadByte());
1392                         bHandled = true;
1393                         break;
1394                 case TE_CSQC_VOTERESET:
1395                         Net_VoteDialogReset();
1396                         bHandled = true;
1397                         break;
1398                 case TE_CSQC_LIGHTNINGARC:
1399                         Net_ReadLightningarc();
1400                         bHandled = true;
1401                         break;
1402                 case TE_CSQC_PINGPLREPORT:
1403                         Net_ReadPingPLReport();
1404                         bHandled = true;
1405                         break;
1406                 case TE_CSQC_ANNOUNCE:
1407                         announce_snd = strzone(ReadString());
1408                         bHandled = true;
1409                         break;
1410                 case TE_CSQC_NOTIFY:
1411                         Net_Notify();
1412                         bHandled = true;
1413                         break;
1414                 case TE_CSQC_WEAPONCOMPLAIN:
1415                         Net_WeaponComplain();
1416                         bHandled = true;
1417                         break;
1418                 case TE_CSQC_CR_MAXBULLETS:
1419                         cr_maxbullets = ReadByte();
1420                         bHandled = true;
1421                         break;
1422                 default:
1423                         // No special logic for this temporary entity; return 0 so the engine can handle it
1424                         bHandled = false;
1425                         break;
1426         }
1427
1428         return bHandled;
1429 }
1430
1431 string getcommandkey(string text, string command)
1432 {
1433         string keys;
1434         float n, j, k, l;
1435
1436         if (!hud_showbinds)
1437                 return text;
1438
1439         keys = db_get(binddb, command);
1440         if (!keys)
1441         {
1442                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1443                 for(j = 0; j < n; ++j)
1444                 {
1445                         k = stof(argv(j));
1446                         if(k != -1)
1447                         {
1448                                 if ("" == keys)
1449                                         keys = keynumtostring(k);
1450                                 else
1451                                         keys = strcat(keys, ", ", keynumtostring(k));
1452
1453                                 ++l;
1454                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1455                         }
1456
1457                 }
1458                 db_put(binddb, command, keys);
1459         }
1460
1461         if ("" == keys) {
1462                 if (hud_showbinds > 1)
1463                         return strcat(text, " (not bound)");
1464                 else
1465                         return text;
1466         }
1467         else if (hud_showbinds > 1)
1468                 return strcat(text, " (", keys, ")");
1469         else
1470                 return keys;
1471 }