qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_RIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float camera_mode;
 346 float reticle_type;
 347 string NextFrameCommand;
 348 void CSQC_SPIDER_HUD();
 349 void CSQC_RAPTOR_HUD();
 350
 351 vector freeze_org, freeze_ang;
 352 entity nightvision_noise, nightvision_noise2;
 353
 354 float pickup_crosshair_time, pickup_crosshair_size;
 355 float hit_time, typehit_time;
 356 float nextsound_hit_time, nextsound_typehit_time;
 357 float hitindication_crosshair_time, hitindication_crosshair_size;
 358 float use_nex_chargepool;
 359
 360 float myhealth, myhealth_prev;
 361 float myhealth_flash;
 362
 363 float old_blurradius, old_bluralpha;
 364 float old_sharpen_intensity;
 365
 366 vector myhealth_gentlergb;
 367
 368 float contentavgalpha, liquidalpha_prev;
 369 vector liquidcolor_prev;
 370
 371 float eventchase_current_distance;
 372
 373 vector damage_blurpostprocess, content_blurpostprocess;
 374
 375 float checkfail[16];
 376
 377 void CSQC_UpdateView(float w, float h)
 378 {
 379         entity e;
 380         float fov;
 381         float f, i, j;
 382         vector v, vo;
 383         vector vf_size, vf_min;
 384         float a;
 385
 386         button_attack2 = (input_buttons & BUTTON_3);
 387         button_zoom = (input_buttons & BUTTON_4);
 388
 389 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 390         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 391         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 392         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 393         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 394         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 395         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 396
 397         vf_size = R_SetView3fv(VF_SIZE);
 398         vf_min = R_SetView3fv(VF_MIN);
 399         vid_width = vf_size_x;
 400         vid_height = vf_size_y;
 401
 402         vector reticle_pos, reticle_size;
 403         vector splash_pos, splash_size;
 404
 405         WaypointSprite_Load();
 406
 407         if(spectatee_status)
 408                 myteam = GetPlayerColor(spectatee_status - 1);
 409         else
 410                 myteam = GetPlayerColor(player_localentnum - 1);
 411
 412         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 413         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 414
 415         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 416         {
 417                 R_SetView(VF_ORIGIN, freeze_org);
 418                 R_SetView(VF_ANGLES, freeze_ang);
 419         }
 420         else
 421         {
 422                 freeze_org = R_SetView3fv(VF_ORIGIN);
 423                 freeze_ang = R_SetView3fv(VF_ANGLES);
 424         }
 425
 426         // event chase camera
 427         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 428         {
 429                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 430                 {
 431                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 432                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 433                         if(!autocvar_chase_active)
 434                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 435
 436                         // make the camera smooth back
 437                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 438                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 439                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 440                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 441
 442                         vector eventchase_target_origin;
 443                         makevectors(view_angles);
 444                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 445                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 446
 447                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 448                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 449                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 450                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 451                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 452
 453                         R_SetView(VF_ORIGIN, trace_endpos);
 454                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 455                 }
 456                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 457                 {
 458                         cvar_set("chase_active", "0");
 459                         eventchase_current_distance = 0; // start from 0 next time
 460                 }
 461         }
 462
 463         WarpZone_FixView();
 464         //WarpZone_FixPMove();
 465
 466         // Render the Scene
 467         view_origin = R_SetView3fv(VF_ORIGIN);
 468         view_angles = R_SetView3fv(VF_ANGLES);
 469         makevectors(view_angles);
 470         view_forward = v_forward;
 471         view_right = v_right;
 472         view_up = v_up;
 473
 474 #ifdef BLURTEST
 475         if(time > blurtest_time0 && time < blurtest_time1)
 476         {
 477                 float r, t;
 478
 479                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 480                 r = t * blurtest_radius;
 481                 f = 1 / pow(t, blurtest_power) - 1;
 482
 483                 cvar_set("r_glsl_postprocess", "1");
 484                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 485         }
 486         else
 487         {
 488                 cvar_set("r_glsl_postprocess", "0");
 489                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 490         }
 491 #endif
 492
 493         TargetMusic_Advance();
 494         Fog_Force();
 495
 496         drawframetime = max(0.000001, time - drawtime);
 497         drawtime = time;
 498
 499         // watch for gametype changes here...
 500         // in ParseStuffCMD the cmd isn't executed yet :/
 501         // might even be better to add the gametype to TE_CSQC_INIT...?
 502         if(!postinit)
 503                 PostInit();
 504
 505         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 506                 if(calledhooks & HOOK_START)
 507                 {
 508                         localcmd("\ncl_hook_gameend\n");
 509                         calledhooks |= HOOK_END;
 510                 }
 511
 512         CheckForGamestartChange();
 513         serverAnnouncer();
 514         maptimeAnnouncer();
 515         carrierAnnouncer();
 516
 517         fov = autocvar_fov;
 518         if(fov <= 59.5)
 519         {
 520                 if(!zoomscript_caught)
 521                 {
 522                         localcmd("+button9\n");
 523                         zoomscript_caught = 1;
 524                 }
 525         }
 526         else
 527         {
 528                 if(zoomscript_caught)
 529                 {
 530                         localcmd("-button9\n");
 531                         zoomscript_caught = 0;
 532                 }
 533         }
 534
 535         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 536         activeweapon = getstati(STAT_SWITCHWEAPON);
 537         f = (serverflags & SERVERFLAG_TEAMPLAY);
 538         if(f != teamplay)
 539         {
 540                 teamplay = f;
 541                 HUD_InitScores();
 542         }
 543
 544         if(last_weapon != activeweapon) {
 545                 weapontime = time;
 546                 last_weapon = activeweapon;
 547
 548                 e = get_weaponinfo(activeweapon);
 549                 if(e.netname != "")
 550                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 551                 else
 552                         localcmd("\ncl_hook_activeweapon none\n");
 553         }
 554
 555         // ALWAYS Clear Current Scene First
 556         R_ClearScene();
 557         R_SetView(VF_ORIGIN, view_origin);
 558         R_SetView(VF_ANGLES, view_angles);
 559
 560         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 561         R_SetView(VF_SIZE, vf_size);
 562         R_SetView(VF_MIN, vf_min);
 563
 564         // Assign Standard Viewflags
 565         // Draw the World (and sky)
 566         R_SetView(VF_DRAWWORLD, 1);
 567
 568         // Set the console size vars
 569         vid_conwidth = autocvar_vid_conwidth;
 570         vid_conheight = autocvar_vid_conheight;
 571         vid_pixelheight = autocvar_vid_pixelheight;
 572
 573         R_SetView(VF_FOV, GetCurrentFov(fov));
 574
 575         // Camera for demo playback
 576         if(camera_active)
 577         {
 578                 if(autocvar_camera_enable)
 579                         CSQC_Demo_Camera();
 580                 else
 581                 {
 582                         cvar_set("chase_active", ftos(chase_active_backup));
 583                         cvar_set("cl_demo_mousegrab", "0");
 584                         camera_active = FALSE;
 585                 }
 586         }
 587 #ifdef CAMERATEST
 588         else if(autocvar_camera_enable)
 589 #else
 590         else if(autocvar_camera_enable && isdemo())
 591 #endif
 592         {
 593                 // Enable required Darkplaces cvars
 594                 chase_active_backup = autocvar_chase_active;
 595                 cvar_set("chase_active", "2");
 596                 cvar_set("cl_demo_mousegrab", "1");
 597                 camera_active = TRUE;
 598                 camera_mode = FALSE;
 599         }
 600
 601         // Draw the Crosshair
 602         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 603
 604         // Draw the Engine Status Bar (the default Quake HUD)
 605         R_SetView(VF_DRAWENGINEHUD, 0);
 606
 607         // Update the mouse position
 608         /*
 609            mousepos_x = vid_conwidth;
 610            mousepos_y = vid_conheight;
 611            mousepos = mousepos*0.5 + getmousepos();
 612          */
 613
 614         e = self;
 615         for(self = world; (self = nextent(self)); )
 616                 if(self.draw)
 617                         self.draw();
 618         self = e;
 619
 620         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 621         R_RenderScene();
 622
 623         // now switch to 2D drawing mode by calling a 2D drawing function
 624         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 625         // next R_RenderScene call
 626         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 627
 628         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 629         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 630         {
 631                 // apply night vision effect
 632                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 633
 634                 if(!nightvision_noise)
 635                 {
 636                         nightvision_noise = spawn();
 637                         nightvision_noise.classname = "nightvision_noise";
 638                 }
 639                 if(!nightvision_noise2)
 640                 {
 641                         nightvision_noise2 = spawn();
 642                         nightvision_noise2.classname = "nightvision_noise2";
 643                 }
 644
 645                 // color tint in yellow
 646                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 647
 648                 // draw BG
 649                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 650                 rgb = '1 1 1';
 651                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 652                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 653                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 654                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 655                 tc_11 = tc_01 + tc_10 - tc_00;
 656                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 657                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 658                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 659                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 660                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 661                 R_EndPolygon();
 662
 663                 // draw FG
 664                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 665                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 666                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 667                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 668                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 669                 tc_11 = tc_01 + tc_10 - tc_00;
 670                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 671                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 672                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 673                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 674                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 675                 R_EndPolygon();
 676         }
 677
 678         // Draw the aiming reticle for weapons that use it
 679         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 680         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 681         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 682         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 683                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 684         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 685                 reticle_type = 2; // nex zoom
 686         else if(button_zoom || zoomscript_caught)
 687                 reticle_type = 1; // normal zoom
 688         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 689                 reticle_type = 2; // nex zoom
 690
 691         if (reticle_type)
 692         {
 693                 if(autocvar_cl_reticle_stretch)
 694                 {
 695                         reticle_size_x = vid_conwidth;
 696                         reticle_size_y = vid_conheight;
 697                         reticle_pos_x = 0;
 698                         reticle_pos_y = 0;
 699                 }
 700                 else
 701                 {
 702                         reticle_size_x = max(vid_conwidth, vid_conheight);
 703                         reticle_size_y = max(vid_conwidth, vid_conheight);
 704                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 705                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 706                 }
 707
 708                 f = current_zoomfraction;
 709                 if(zoomscript_caught)
 710                         f = 1;
 711                 if(autocvar_cl_reticle_item_normal)
 712                 {
 713                         if(reticle_type == 1 && f)
 714                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 715                 }
 716                 if(autocvar_cl_reticle_item_nex)
 717                 {
 718                         if(reticle_type == 2 && f)
 719                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 720                 }
 721         }
 722
 723
 724         // improved polyblend
 725         vector rgb;
 726         if(autocvar_hud_contents)
 727         {
 728                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 729                 vector liquidcolor;
 730
 731                 switch(pointcontents(view_origin))
 732                 {
 733                         case CONTENT_WATER:
 734                                 liquidalpha = autocvar_hud_contents_water_alpha;
 735                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 736                                 incontent = 1;
 737                                 break;
 738
 739                         case CONTENT_LAVA:
 740                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 741                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 742                                 incontent = 1;
 743                                 break;
 744
 745                         case CONTENT_SLIME:
 746                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 747                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 748                                 incontent = 1;
 749                                 break;
 750
 751                         default:
 752                                 liquidalpha = 0;
 753                                 liquidcolor = '0 0 0';
 754                                 incontent = 0;
 755                                 break;
 756                 }
 757
 758                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 759                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 760                         contentfadetime = autocvar_hud_contents_fadeintime;
 761                         liquidalpha_prev = liquidalpha;
 762                         liquidcolor_prev = liquidcolor;
 763                 }
 764                 else
 765                         contentfadetime = autocvar_hud_contents_fadeouttime;
 766
 767                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 768                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 769
 770                 if(contentavgalpha)
 771                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 772
 773                 if(autocvar_hud_postprocessing)
 774                 {
 775                         if(autocvar_hud_contents_blur && contentavgalpha)
 776                         {
 777                                 content_blurpostprocess_x = 1;
 778                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 779                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 780                         }
 781                         else
 782                         {
 783                                 content_blurpostprocess_x = 0;
 784                                 content_blurpostprocess_y = 0;
 785                                 content_blurpostprocess_z = 0;
 786                         }
 787                 }
 788         }
 789
 790         if(autocvar_hud_damage && !autocvar_chase_active)
 791         {
 792                 splash_size_x = max(vid_conwidth, vid_conheight);
 793                 splash_size_y = max(vid_conwidth, vid_conheight);
 794                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 795                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 796
 797                 float myhealth_flash_temp;
 798                 myhealth = getstati(STAT_HEALTH);
 799
 800                 // fade out
 801                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 802                 // add new damage
 803                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 804
 805                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 806                 pain_threshold = autocvar_hud_damage_pain_threshold;
 807                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 808                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 809
 810                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 811                 {
 812                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 813                 }
 814
 815                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 816
 817                 if(myhealth_prev < 1)
 818                 {
 819                         if(myhealth >= 1)
 820                         {
 821                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 822                                 myhealth_flash_temp = 0;
 823                         }
 824                         else
 825                         {
 826                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 827                         }
 828                 }
 829
 830                 if(spectatee_status == -1 || intermission)
 831                 {
 832                         myhealth_flash = 0; // observing, or match ended
 833                         myhealth_flash_temp = 0;
 834                 }
 835
 836                 myhealth_prev = myhealth;
 837
 838                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 839                 {
 840                         if(autocvar_cl_gentle_damage == 2)
 841                         {
 842                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 843                                 {
 844                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 845                                 }
 846                         }
 847                         else
 848                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 849
 850                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 851                 }
 852                 else
 853                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 854
 855                 if(autocvar_hud_postprocessing)
 856                 {
 857                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 858                         {
 859                                 damage_blurpostprocess_x = 1;
 860                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 861                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 862                         }
 863                         else
 864                         {
 865                                 damage_blurpostprocess_x = 0;
 866                                 damage_blurpostprocess_y = 0;
 867                                 damage_blurpostprocess_z = 0;
 868                         }
 869                 }
 870         }
 871
 872         if(autocvar_hud_postprocessing)
 873         {
 874                 // all of this should be done in the engine eventually
 875
 876                 // enable or disable rendering types if they are used or not
 877                 if(cvar("r_glsl_postprocess_uservec1_enable") != (cvar("hud_postprocessing_maxbluralpha") != 0))
 878                         cvar_set("r_glsl_postprocess_uservec1_enable", ftos(cvar("hud_postprocessing_maxbluralpha") != 0));
 879                 if(cvar("r_glsl_postprocess_uservec2_enable") != (cvar("hud_powerup") != 0))
 880                         cvar_set("r_glsl_postprocess_uservec2_enable", ftos(cvar("hud_powerup") != 0));
 881
 882                 // lets apply the postprocess effects from the previous two functions if needed
 883                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 884                 {
 885                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 886                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 887                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 888                         {
 889                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 890                                 old_blurradius = blurradius;
 891                                 old_bluralpha = bluralpha;
 892                         }
 893                 }
 894                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 895                 {
 896                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 897                         old_blurradius = 0;
 898                         old_bluralpha = 0;
 899                 }
 900
 901                 float sharpen_intensity;
 902                 if (getstatf(STAT_STRENGTH_FINISHED) - time > 0)
 903                         sharpen_intensity += (getstatf(STAT_STRENGTH_FINISHED) - time);
 904                 if (getstatf(STAT_INVINCIBLE_FINISHED) - time > 0)
 905                         sharpen_intensity += (getstatf(STAT_INVINCIBLE_FINISHED) - time);
 906
 907                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 908                 {
 909                         sharpen_intensity = bound(0, sharpen_intensity, 5); // powerup warning time is 5 seconds, so fade the effect from there
 910
 911                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 912                         {
 913                                 cvar_set("r_glsl_postprocess_uservec2", strcat("0 ", ftos(-sharpen_intensity * cvar("hud_powerup")), " 0 0"));
 914                                 old_sharpen_intensity = sharpen_intensity;
 915                         }
 916                 }
 917                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 918                 {
 919                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 920                         old_sharpen_intensity = 0;
 921                 }
 922         }
 923
 924         if(menu_visible)
 925                 menu_show();
 926
 927         /*if(gametype == GAME_CTF)
 928           {
 929           ctf_view();
 930           } else */
 931
 932         // draw 2D entities
 933         e = self;
 934         for(self = world; (self = nextent(self)); )
 935                 if(self.draw2d)
 936                         self.draw2d();
 937         self = e;
 938         Draw_ShowNames_All();
 939
 940         scoreboard_active = HUD_WouldDrawScoreboard();
 941
 942         hit_time = getstatf(STAT_HIT_TIME);
 943         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 944         {
 945                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 946                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 947         }
 948         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 949         if(typehit_time > nextsound_typehit_time)
 950         {
 951                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 952                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 953         }
 954
 955         float hud;
 956         hud = getstati(STAT_HUD);
 957         if(hud == HUD_SPIDERBOT)
 958                 CSQC_SPIDER_HUD();
 959         else if(hud == HUD_WAKIZASHI)
 960         CSQC_WAKIZASHI_HUD();
 961     else if(hud == HUD_RAPTOR)
 962         CSQC_RAPTOR_HUD();
 963         else
 964         {
 965                 if(gametype == GAME_FREEZETAG)
 966                 {
 967                         if(getstati(STAT_FROZEN))
 968                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 969                         if(getstatf(STAT_REVIVE_PROGRESS))
 970                         {
 971                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 972                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 973                         }
 974                 }
 975
 976                 if(autocvar_r_letterbox == 0)
 977                         if(autocvar_viewsize < 120)
 978                                 CSQC_common_hud();
 979
 980                 // crosshair goes VERY LAST
 981                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1) {
 982                         string wcross_style;
 983                         float wcross_alpha, wcross_resolution;
 984                         wcross_style = autocvar_crosshair;
 985                         if (wcross_style == "0")
 986                                 return;
 987                         wcross_resolution = autocvar_crosshair_size;
 988                         if (wcross_resolution == 0)
 989                                 return;
 990                         wcross_alpha = autocvar_crosshair_alpha;
 991                         if (wcross_alpha == 0)
 992                                 return;
 993
 994                         // TrueAim check
 995                         float shottype;
 996
 997                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 998                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 999                         wcross_origin_z = 0;
1000                         if(autocvar_crosshair_hittest)
1001                         {
1002                                 vector wcross_oldorigin;
1003                                 wcross_oldorigin = wcross_origin;
1004                                 shottype = TrueAimCheck();
1005                                 if(shottype == SHOTTYPE_HITWORLD)
1006                                 {
1007                                         v = wcross_origin - wcross_oldorigin;
1008                                         v_x /= vid_conwidth;
1009                                         v_y /= vid_conheight;
1010                                         if(vlen(v) > 0.01)
1011                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1012                                 }
1013                                 if(!autocvar_crosshair_hittest_showimpact)
1014                                         wcross_origin = wcross_oldorigin;
1015                         }
1016                         else
1017                                 shottype = SHOTTYPE_HITWORLD;
1018
1019                         vector wcross_color, wcross_size;
1020                         string wcross_wep, wcross_name;
1021                         float wcross_scale, wcross_blur;
1022
1023                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1024                                 e = get_weaponinfo(activeweapon);
1025                                 if (e && e.netname != "")
1026                                 {
1027                                         wcross_wep = e.netname;
1028                                         if(autocvar_crosshair_per_weapon)
1029                                         {
1030                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1031                                                 if (wcross_resolution == 0)
1032                                                         return;
1033                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1034                                                 if (wcross_alpha == 0)
1035                                                         return;
1036
1037                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1038                                                 if(wcross_style == "" || wcross_style == "0")
1039                                                         wcross_style = wcross_wep;
1040                                         }
1041                                 }
1042                         }
1043                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1044                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1045                         else if(autocvar_crosshair_color_by_health)
1046                         {
1047                                 local float x = getstati(STAT_HEALTH);
1048
1049                                 //x = red
1050                                 //y = green
1051                                 //z = blue
1052
1053                                 wcross_color_z = 0;
1054
1055                                 if(x > 200)
1056                                 {
1057                                         wcross_color_x = 0;
1058                                         wcross_color_y = 1;
1059                                 }
1060                                 else if(x > 150)
1061                                 {
1062                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1063                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1064                                 }
1065                                 else if(x > 100)
1066                                 {
1067                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1068                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1069                                         wcross_color_z = 1 - (x-100)*0.02;
1070                                 }
1071                                 else if(x > 50)
1072                                 {
1073                                         wcross_color_x = 1;
1074                                         wcross_color_y = 1;
1075                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1076                                 }
1077                                 else if(x > 20)
1078                                 {
1079                                         wcross_color_x = 1;
1080                                         wcross_color_y = (x-20)*90/27/100;
1081                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1082                                 }
1083                                 else
1084                                 {
1085                                         wcross_color_x = 1;
1086                                         wcross_color_y = 0;
1087                                 }
1088                         }
1089                         else
1090                                 wcross_color = stov(autocvar_crosshair_color);
1091
1092                         wcross_name = strcat("gfx/crosshair", wcross_style);
1093
1094                         if(autocvar_crosshair_effect_scalefade)
1095                         {
1096                                 wcross_scale = wcross_resolution;
1097                                 wcross_resolution = 1;
1098                         }
1099                         else
1100                         {
1101                                 wcross_scale = 1;
1102                         }
1103
1104                         if(autocvar_crosshair_pickup)
1105                         {
1106                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1107                                 {
1108                                         pickup_crosshair_size = 1;
1109                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1110                                 }
1111
1112                                 if(pickup_crosshair_size > 0)
1113                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1114                                 else
1115                                         pickup_crosshair_size = 0;
1116
1117                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1118                         }
1119
1120                         vector hitindication_color;
1121                         if(autocvar_crosshair_hitindication)
1122                         {
1123                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1124                                 if(hitindication_crosshair_time < hit_time)
1125                                 {
1126                                         hitindication_crosshair_size = 1;
1127                                         hitindication_crosshair_time = hit_time;
1128                                 }
1129
1130                                 if(hitindication_crosshair_size > 0)
1131                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1132                                 else
1133                                         hitindication_crosshair_size = 0;
1134
1135                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1136                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1137                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1138                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1139                         }
1140
1141                         if(shottype == SHOTTYPE_HITENEMY)
1142                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1143                         if(shottype == SHOTTYPE_HITTEAM)
1144                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1145
1146                         f = autocvar_crosshair_effect_speed;
1147                         if(f < 0)
1148                                 f *= -2 * g_weaponswitchdelay;
1149                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1150                         {
1151                                 wcross_changedonetime = time + f;
1152                         }
1153                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1154                         {
1155                                 wcross_name_changestarttime = time;
1156                                 wcross_name_changedonetime = time + f;
1157                                 if(wcross_name_goal_prev_prev)
1158                                         strunzone(wcross_name_goal_prev_prev);
1159                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1160                                 wcross_name_goal_prev = strzone(wcross_name);
1161                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1162                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1163                                 wcross_resolution_goal_prev = wcross_resolution;
1164                         }
1165
1166                         wcross_scale_goal_prev = wcross_scale;
1167                         wcross_alpha_goal_prev = wcross_alpha;
1168                         wcross_color_goal_prev = wcross_color;
1169
1170                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1171                         {
1172                                 wcross_blur = 1;
1173                                 wcross_alpha *= 0.75;
1174                         }
1175                         else
1176                                 wcross_blur = 0;
1177                         // *_prev is at time-frametime
1178                         // * is at wcross_changedonetime+f
1179                         // what do we have at time?
1180                         if(time < wcross_changedonetime)
1181                         {
1182                                 f = frametime / (wcross_changedonetime - time + frametime);
1183                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1184                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1185                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1186                         }
1187
1188                         wcross_scale_prev = wcross_scale;
1189                         wcross_alpha_prev = wcross_alpha;
1190                         wcross_color_prev = wcross_color;
1191
1192                         wcross_scale *= 1 - autocvar__menu_alpha;
1193                         wcross_alpha *= 1 - autocvar__menu_alpha;
1194                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1195
1196                         // crosshair rings for weapon stats
1197                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1198                         {
1199                                 // declarations and stats
1200                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1201                                 string ring_image, ring_inner_image;
1202                                 vector ring_rgb, ring_inner_rgb;
1203
1204                                 ring_scale = autocvar_crosshair_ring_size;
1205
1206                                 float weapon_clipload, weapon_clipsize;
1207                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1208                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1209
1210                                 float nex_charge, nex_chargepool;
1211                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1212                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1213
1214                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1215                                         nex_charge_movingavg = nex_charge;
1216
1217
1218                                 // handle the values
1219                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1220                                 {
1221                                         if (nex_chargepool || use_nex_chargepool) {
1222                                                 use_nex_chargepool = 1;
1223                                                 ring_inner_value = nex_chargepool;
1224                                         } else {
1225                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1226                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1227                                         }
1228
1229                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1230                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1231                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1232
1233                                         // draw the outer ring to show the current charge of the weapon
1234                                         ring_value = nex_charge;
1235                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1236                                         ring_rgb = wcross_color;
1237                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1238                                 }
1239                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1240                                 {
1241                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1242                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1243                                         ring_rgb = wcross_color;
1244                                         ring_image = "gfx/crosshair_ring.tga";
1245                                 }
1246                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1247                                 {
1248                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1249                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1250                                         ring_rgb = wcross_color;
1251                                         ring_image = "gfx/crosshair_ring.tga";
1252                                 }
1253
1254                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1255                                 {
1256                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1257                                         ring_scale = autocvar_crosshair_ring_reload_size;
1258                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1259                                         ring_rgb = wcross_color;
1260
1261                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1262                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1263                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1264                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1265                                         else
1266                                                 ring_image = "gfx/crosshair_ring.tga";
1267                                 }
1268
1269                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1270                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1271
1272                                 if (ring_value)
1273                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1274                         }
1275
1276 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1277                         do \
1278                         { \
1279                                 if(wcross_blur > 0) \
1280                                 { \
1281                                         for(i = -2; i <= 2; ++i) \
1282                                                 for(j = -2; j <= 2; ++j) \
1283                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1284                                 } \
1285                                 else \
1286                                 { \
1287                                         M(0,0,sz,wcross_name,wcross_alpha); \
1288                                 } \
1289                         } \
1290                         while(0)
1291
1292 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1293                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1294
1295 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1296                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1297
1298                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1299                         {
1300                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1301                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1302                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1303                                 f = 1 - f;
1304                         }
1305                         else
1306                         {
1307                                 f = 1;
1308                         }
1309
1310                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1311                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1312
1313                         if(autocvar_crosshair_dot)
1314             {
1315                 vector wcross_color_old;
1316                 wcross_color_old = wcross_color;
1317                 if(autocvar_crosshair_dot_color != "0")
1318                     wcross_color = stov(autocvar_crosshair_dot_color);
1319                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1320                 wcross_color = wcross_color_old;
1321             }
1322
1323                         wcross_name_alpha_goal_prev = f;
1324                 }
1325                 else
1326                 {
1327                         wcross_scale_prev = 0;
1328                         wcross_alpha_prev = 0;
1329                         wcross_scale_goal_prev = 0;
1330                         wcross_alpha_goal_prev = 0;
1331                         wcross_changedonetime = 0;
1332                         if(wcross_name_goal_prev)
1333                                 strunzone(wcross_name_goal_prev);
1334                         wcross_name_goal_prev = string_null;
1335                         if(wcross_name_goal_prev_prev)
1336                                 strunzone(wcross_name_goal_prev_prev);
1337                         wcross_name_goal_prev_prev = string_null;
1338                         wcross_name_changestarttime = 0;
1339                         wcross_name_changedonetime = 0;
1340                         wcross_name_alpha_goal_prev = 0;
1341                         wcross_name_alpha_goal_prev_prev = 0;
1342                         wcross_resolution_goal_prev = 0;
1343                         wcross_resolution_goal_prev_prev = 0;
1344                 }
1345         }
1346
1347         if(NextFrameCommand)
1348         {
1349                 localcmd("\n", NextFrameCommand, "\n");
1350                 NextFrameCommand = string_null;
1351         }
1352
1353         // we must do this check AFTER a frame was rendered, or it won't work
1354         if(cs_project_is_b0rked == 0)
1355         {
1356                 string w0, h0;
1357                 w0 = ftos(autocvar_vid_conwidth);
1358                 h0 = ftos(autocvar_vid_conheight);
1359                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1360                 //R_SetView(VF_FOV, '90 90 0');
1361                 R_SetView(VF_ORIGIN, '0 0 0');
1362                 R_SetView(VF_ANGLES, '0 0 0');
1363                 R_SetView(VF_PERSPECTIVE, 1);
1364                 makevectors('0 0 0');
1365                 vector v1, v2;
1366                 cvar_set("vid_conwidth", "800");
1367                 cvar_set("vid_conheight", "600");
1368                 v1 = cs_project(v_forward);
1369                 cvar_set("vid_conwidth", "640");
1370                 cvar_set("vid_conheight", "480");
1371                 v2 = cs_project(v_forward);
1372                 if(v1 == v2)
1373                         cs_project_is_b0rked = 1;
1374                 else
1375                         cs_project_is_b0rked = -1;
1376                 cvar_set("vid_conwidth", w0);
1377                 cvar_set("vid_conheight", h0);
1378         }
1379
1380         if(autocvar__hud_configure)
1381                 HUD_Panel_Mouse();
1382
1383         // let's reset the view back to normal for the end
1384         R_SetView(VF_MIN, '0 0 0');
1385         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1386 }
1387
1388 #define spider_h "gfx/vehicles/hud_bg.tga"
1389 #define spider_b "gfx/vehicles/sbot.tga"
1390 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1391 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1392 #define spider_s "gfx/vehicles/shiled.tga"
1393 #define spider_a1 "gfx/hud/sb_rocket.tga"
1394 #define spider_a2 "gfx/sb_bullets.tga"
1395
1396 void CSQC_SPIDER_HUD()
1397 {
1398         float rockets, reload, heat, hp, shield;
1399         vector picsize, hudloc;
1400
1401     // Fetch health & ammo stats
1402     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1403         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1404         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1405         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1406         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1407
1408     // Draw the crosshairs
1409     picsize = drawgetimagesize(SPIDER_CROSS);
1410     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1411     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1412     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1413
1414     hudloc_y =  4;
1415     hudloc_x = 4;
1416
1417     picsize = drawgetimagesize(spider_h) * 0.5;
1418     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1419
1420     picsize = drawgetimagesize(spider_a2) * 0.5;
1421     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1422
1423     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1424     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1425     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1426
1427     picsize = drawgetimagesize(spider_a1) * 0.85;
1428     if(rockets == 9)
1429     {
1430         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1431         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1432     }
1433     else
1434     {
1435         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1436         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1437     }
1438
1439     picsize = drawgetimagesize(spider_b) * 0.5;
1440     hudloc_y = 10.5;
1441     hudloc_x = 10.5;
1442
1443     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1444     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1445     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1446     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1447
1448
1449         /*
1450         // Draw health bar
1451         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1452         p = p + '0 1 0' * vid_conheight - '0 32 0';
1453         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1454         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1455         p_y += 8;
1456         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1457         p_x += 256 * hp;
1458         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1459
1460         // Draw minigun heat indicator
1461         p = '0.5 0 0' * (vid_conwidth - 256);
1462         p = p + '0 1 0' * vid_conheight - '0 34  0';
1463         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1464         p_x += 256 * (1-heat);
1465         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1466
1467
1468         // Draw rocket icons for loaded/empty tubes.
1469         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1470         pp += '0 1 0' * vid_conheight - '0 64 0';
1471         for(i = 0; i < 8; ++i)
1472         {
1473                 p = pp + '1 0 0' * (rkt_size * i);
1474                 if(rockets == 8)
1475                 {
1476                         if(floor(reload * 8) == i)
1477                         {
1478                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1479                         }
1480                         else if(i < reload * 8)
1481                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1482                         else
1483                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1484                 }
1485                 else
1486                 {
1487                         if(i < rockets)
1488                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1489                         else
1490                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1491                 }
1492         }
1493         */
1494
1495         if (scoreboard_showscores)
1496         {
1497                 HUD_DrawScoreboard();
1498                 HUD_DrawCenterPrint();
1499         }
1500
1501 }
1502
1503 #define raptor_h "gfx/vehicles/hud_bg.tga"
1504 #define raptor_b "gfx/vehicles/raptor.tga"
1505 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1506 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1507 #define raptor_s "gfx/vehicles/shiled.tga"
1508
1509 void CSQC_RAPTOR_HUD()
1510 {
1511         float reload, hp, shield, energy;
1512         vector picsize, hudloc;
1513
1514     // Fetch health & ammo stats
1515     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1516         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1517         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1518         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1519
1520     // Draw the crosshairs
1521     picsize = drawgetimagesize(SPIDER_CROSS);
1522     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1523     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1524     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1525
1526     hudloc_y =  4;
1527     hudloc_x = 4;
1528
1529     picsize = drawgetimagesize(raptor_h) * 0.5;
1530     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1531
1532     picsize = drawgetimagesize(spider_a2) * 0.5;
1533     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1534
1535     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1536     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1537     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1538
1539
1540     picsize = drawgetimagesize(spider_a1) * 0.85;
1541     if(reload == 1)
1542     {
1543         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1544         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1545     }
1546     else
1547     {
1548         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1549         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1550     }
1551
1552     picsize = drawgetimagesize(raptor_b) * 0.5;
1553     hudloc_y = 10.5;
1554     hudloc_x = 10.5;
1555
1556     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1557     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1558     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1559     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1560
1561
1562         if (scoreboard_showscores)
1563         {
1564                 HUD_DrawScoreboard();
1565                 HUD_DrawCenterPrint();
1566         }
1567
1568 }
1569
1570 #define waki_h "gfx/vehicles/hud_bg.tga"
1571 #define waki_b "gfx/vehicles/waki.tga"
1572 #define waki_e "gfx/vehicles/waki_e.tga"
1573 #define waki_g "gfx/vehicles/waki_guns.tga"
1574 #define waki_r "gfx/vehicles/waki_rockets.tga"
1575 #define waki_s "gfx/vehicles/shiled.tga"
1576
1577 #define waki_a1 "gfx/hud/sb_rocket.tga"
1578 #define waki_a2 "gfx/sb_cells.tga"
1579
1580 void CSQC_WAKIZASHI_HUD()
1581 {
1582         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1583         float health, shield, energy, rockets;
1584         vector picsize, hudloc;
1585
1586     picsize = drawgetimagesize(SPIDER_CROSS);
1587     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1588     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1589     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1590
1591 /*
1592 const float STAT_VEHICLESTAT_HEALTH  = 60;
1593 const float STAT_VEHICLESTAT_SHIELD  = 61;
1594 const float STAT_VEHICLESTAT_ENERGY  = 62;
1595 const float STAT_VEHICLESTAT_AMMO1   = 63;
1596 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1597 const float STAT_VEHICLESTAT_AMMO2   = 65;
1598 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1599 */
1600     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1601         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1602         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1603         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1604
1605     hudloc_y =  4;
1606     hudloc_x = 4;
1607
1608     picsize = drawgetimagesize(waki_h) * 0.5;
1609     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1610
1611     picsize = drawgetimagesize(waki_a2) * 0.7;
1612     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1613
1614
1615     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1616     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1617
1618     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1619
1620     picsize = drawgetimagesize(waki_a1) * 0.75;
1621     if(rockets == 1)
1622     {
1623         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1624         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1625     }
1626     else
1627     {
1628         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1629         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1630         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1631     }
1632
1633     picsize = drawgetimagesize(waki_b) * 0.5;
1634     hudloc_y = 10.5;
1635     hudloc_x = 10.5;
1636
1637     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1638     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1639     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1640     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1641
1642
1643
1644         /*
1645         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1646         p = p + '0 1 0' * vid_conheight - '0 32 0';
1647
1648         // Draw health bar
1649         p_y += 8;
1650         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1651         p_x += 256 * health;
1652         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1653
1654         // Draw shiled bar
1655         p_x -= 256 * health;
1656         p_y += 4;
1657         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1658
1659         // Draw energy
1660         //p_x -= 256 * health;
1661         p_y -= 8;
1662         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1663
1664         // Draw rockets bar
1665         p_y += 12;
1666         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1667         */
1668
1669
1670
1671
1672         if (scoreboard_showscores)
1673         {
1674                 HUD_DrawScoreboard();
1675                 HUD_DrawCenterPrint();
1676         }
1677
1678 }
1679
1680 void CSQC_common_hud(void)
1681 {
1682         // HUD_SortFrags(); done in HUD_Draw
1683         float hud;
1684         hud = getstati(STAT_HUD);
1685
1686         //hud = 10;
1687         switch(hud)
1688         {
1689                 case HUD_NORMAL:
1690                         // do some accuracy var caching
1691                         float i;
1692                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1693                         {
1694                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1695                                 {
1696                                         if(acc_color_levels)
1697                                                 strunzone(acc_color_levels);
1698                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1699                                         acc_levels = tokenize(acc_color_levels);
1700                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1701                                                 acc_levels = MAX_ACCURACY_LEVELS;
1702
1703                                         for (i = 0; i < acc_levels; ++i)
1704                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1705                                 }
1706                                 // let know that acc_col[] needs to be loaded
1707                                 acc_col_x[0] = -1;
1708                         }
1709
1710                         HUD_Main(); // always run these functions for alpha checks
1711                         HUD_DrawScoreboard();
1712
1713                         if (scoreboard_active) // scoreboard/accuracy
1714                         {
1715                                 HUD_Reset();
1716                                 // HUD_DrawScoreboard takes care of centerprint_start
1717                         }
1718                         else if (intermission == 2) // map voting screen
1719                         {
1720                                 HUD_FinaleOverlay();
1721                                 HUD_Reset();
1722
1723                                 centerprint_start_x = 0;
1724                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1725                         }
1726                         else // hud
1727                         {
1728                                 centerprint_start_x = 0;
1729                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1730                         }
1731
1732                         HUD_DrawCenterPrint();
1733                         break;
1734
1735                 case HUD_SPIDERBOT:
1736                         CSQC_SPIDER_HUD();
1737                         break;
1738
1739                 case HUD_WAKIZASHI:
1740                         CSQC_WAKIZASHI_HUD();
1741                         break;
1742         }
1743 }
1744
1745
1746 // following vectors must be global to allow seamless switching between camera modes
1747 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1748 void CSQC_Demo_Camera()
1749 {
1750         float speed, attenuation, dimensions;
1751         vector tmp, delta;
1752
1753         if( autocvar_camera_reset || !camera_mode )
1754         {
1755                 camera_offset = '0 0 0';
1756                 current_angles = '0 0 0';
1757                 camera_direction = '0 0 0';
1758                 camera_offset_z += 30;
1759                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1760                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1761                 current_origin = view_origin;
1762                 current_camera_offset  = camera_offset;
1763                 cvar_set("camera_reset", "0");
1764                 camera_mode = CAMERA_CHASE;
1765         }
1766
1767         // Camera angles
1768         if( camera_roll )
1769                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1770
1771         if(autocvar_camera_look_player)
1772         {
1773                 local vector dir;
1774                 local float n;
1775
1776                 dir = normalize(view_origin - current_position);
1777                 n = mouse_angles_z;
1778                 mouse_angles = vectoangles(dir);
1779                 mouse_angles_x = mouse_angles_x * -1;
1780                 mouse_angles_z = n;
1781         }
1782         else
1783         {
1784                 tmp = getmousepos() * 0.1;
1785                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1786                 {
1787                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1788                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1789                 }
1790         }
1791
1792         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1793         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1794         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1795         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1796
1797         // Fix difference when angles don't have the same sign
1798         delta = '0 0 0';
1799         if(mouse_angles_y < -60 && current_angles_y > 60)
1800                 delta = '0 360 0';
1801         if(mouse_angles_y > 60 && current_angles_y < -60)
1802                 delta = '0 -360 0';
1803
1804         if(autocvar_camera_look_player)
1805                 attenuation = autocvar_camera_look_attenuation;
1806         else
1807                 attenuation = autocvar_camera_speed_attenuation;
1808
1809         attenuation = 1 / max(1, attenuation);
1810         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1811
1812         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1813         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1814         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1815         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1816
1817         // Camera position
1818         tmp = '0 0 0';
1819         dimensions = 0;
1820
1821         if( camera_direction_x )
1822         {
1823                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1824                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1825                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1826                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1827                 ++dimensions;
1828         }
1829
1830         if( camera_direction_y )
1831         {
1832                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1833                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1834                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1835                 ++dimensions;
1836         }
1837
1838         if( camera_direction_z )
1839         {
1840                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1841                 ++dimensions;
1842         }
1843
1844         if(autocvar_camera_free)
1845                 speed = autocvar_camera_speed_free;
1846         else
1847                 speed = autocvar_camera_speed_chase;
1848
1849         if(dimensions)
1850         {
1851                 speed = speed * sqrt(1 / dimensions);
1852                 camera_offset += tmp * speed;
1853         }
1854
1855         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1856
1857         // Camera modes
1858         if( autocvar_camera_free )
1859         {
1860                 if ( camera_mode == CAMERA_CHASE )
1861                 {
1862                         current_camera_offset = current_origin + current_camera_offset;
1863                         camera_offset = current_origin + camera_offset;
1864                 }
1865
1866                 camera_mode = CAMERA_FREE;
1867                 current_position = current_camera_offset;
1868         }
1869         else
1870         {
1871                 if ( camera_mode == CAMERA_FREE )
1872                 {
1873                         current_origin = view_origin;
1874                         camera_offset = camera_offset - current_origin;
1875                         current_camera_offset = current_camera_offset - current_origin;
1876                 }
1877
1878                 camera_mode = CAMERA_CHASE;
1879
1880                 if(autocvar_camera_chase_smoothly)
1881                         current_origin += (view_origin - current_origin) * attenuation;
1882                 else
1883                         current_origin = view_origin;
1884
1885                 current_position = current_origin + current_camera_offset;
1886         }
1887
1888         R_SetView(VF_ANGLES, current_angles);
1889         R_SetView(VF_ORIGIN, current_position);
1890 }