qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 void CSQC_UpdateView(float w, float h)
 370 {
 371         entity e;
 372         float fov;
 373         float f, i, j;
 374         vector v, vo;
 375         vector vf_size, vf_min;
 376         float a;
 377
 378         vf_size = R_SetView3fv(VF_SIZE);
 379         vf_min = R_SetView3fv(VF_MIN);
 380         vid_width = vf_size_x;
 381         vid_height = vf_size_y;
 382
 383         vector reticle_pos, reticle_size;
 384
 385         WaypointSprite_Load();
 386
 387         if(spectatee_status)
 388                 myteam = GetPlayerColor(spectatee_status - 1);
 389         else
 390                 myteam = GetPlayerColor(player_localentnum - 1);
 391
 392         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 393         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 394
 395         warpzone_fixview_origin = pmove_org + vo;
 396         warpzone_fixview_cl_viewangles = input_angles;
 397         warpzone_fixview_angles = view_angles;
 398         WarpZone_FixView();
 399         pmove_org = warpzone_fixview_origin - vo;
 400         input_angles = warpzone_fixview_cl_viewangles;
 401         view_angles = warpzone_fixview_angles;
 402
 403         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 404         {
 405                 pmove_org = freeze_pmove_org;
 406                 input_angles = view_angles = freeze_input_angles;
 407                 R_SetView(VF_ORIGIN, pmove_org + vo);
 408                 R_SetView(VF_ANGLES, view_angles);
 409                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 410         }
 411         freeze_pmove_org = pmove_org;
 412         freeze_input_angles = input_angles;
 413
 414         // Render the Scene
 415         if(!intermission || !view_set)
 416         {
 417                 view_origin = pmove_org + vo;
 418                 view_angles = input_angles;
 419                 makevectors(view_angles);
 420                 view_forward = v_forward;
 421                 view_right = v_right;
 422                 view_up = v_up;
 423                 view_set = 1;
 424         }
 425
 426 #ifdef BLURTEST
 427         if(time > blurtest_time0 && time < blurtest_time1)
 428         {
 429                 float r, t;
 430
 431                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 432                 r = t * blurtest_radius;
 433                 f = 1 / pow(t, blurtest_power) - 1;
 434
 435                 cvar_set("r_glsl_postprocess", "1");
 436                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 437         }
 438         else
 439         {
 440                 cvar_set("r_glsl_postprocess", "0");
 441                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 442         }
 443 #endif
 444
 445         TargetMusic_Advance();
 446         Fog_Force();
 447
 448         drawframetime = max(0.000001, time - drawtime);
 449         drawtime = time;
 450
 451         // watch for gametype changes here...
 452         // in ParseStuffCMD the cmd isn't executed yet :/
 453         // might even be better to add the gametype to TE_CSQC_INIT...?
 454         if(!postinit)
 455                 PostInit();
 456
 457         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 458                 if(calledhooks & HOOK_START)
 459                 {
 460                         localcmd("\ncl_hook_gameend\n");
 461                         calledhooks |= HOOK_END;
 462                 }
 463
 464         CheckForGamestartChange();
 465         serverAnnouncer();
 466         maptimeAnnouncer();
 467         carrierAnnouncer();
 468
 469         fov = autocvar_fov;
 470         if(button_zoom || fov <= 59.5)
 471         {
 472                 if(!zoomscript_caught)
 473                 {
 474                         localcmd("+button4\n");
 475                         zoomscript_caught = 1;
 476                         ignore_plus_zoom += 1;
 477                 }
 478         }
 479         else
 480         {
 481                 if(zoomscript_caught)
 482                 {
 483                         localcmd("-button4\n");
 484                         zoomscript_caught = 0;
 485                         ignore_minus_zoom += 1;
 486                 }
 487         }
 488
 489         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 490         activeweapon = getstati(STAT_SWITCHWEAPON);
 491         f = (serverflags & SERVERFLAG_TEAMPLAY);
 492         if(f != teamplay)
 493         {
 494                 teamplay = f;
 495                 HUD_InitScores();
 496         }
 497
 498         if(last_weapon != activeweapon) {
 499                 weapontime = time;
 500                 last_weapon = activeweapon;
 501
 502                 e = get_weaponinfo(activeweapon);
 503                 if(e.netname != "")
 504                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 505                 else
 506                         localcmd("\ncl_hook_activeweapon none\n");
 507         }
 508
 509         // ALWAYS Clear Current Scene First
 510         R_ClearScene();
 511
 512         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 513         R_SetView(VF_SIZE, vf_size);
 514         R_SetView(VF_MIN, vf_min);
 515
 516         // Assign Standard Viewflags
 517         // Draw the World (and sky)
 518         R_SetView(VF_DRAWWORLD, 1);
 519
 520         // Set the console size vars
 521         vid_conwidth = autocvar_vid_conwidth;
 522         vid_conheight = autocvar_vid_conheight;
 523         vid_pixelheight = autocvar_vid_pixelheight;
 524
 525         R_SetView(VF_FOV, GetCurrentFov(fov));
 526
 527         // Camera for demo playback
 528         if(camera_active)
 529         {
 530                 if(autocvar_camera_enable)
 531                         CSQC_Demo_Camera();
 532                 else
 533                 {
 534                         cvar_set("chase_active", ftos(chase_active_backup));
 535                         cvar_set("cl_demo_mousegrab", "0");
 536                         camera_active = FALSE;
 537                 }
 538         }
 539 #ifdef CAMERATEST
 540         else if(autocvar_camera_enable)
 541 #else
 542         else if(autocvar_camera_enable && isdemo())
 543 #endif
 544         {
 545                 // Enable required Darkplaces cvars
 546                 chase_active_backup = autocvar_chase_active;
 547                 cvar_set("chase_active", "2");
 548                 cvar_set("cl_demo_mousegrab", "1");
 549                 camera_active = TRUE;
 550                 camera_mode = FALSE;
 551         }
 552
 553         // Draw the Crosshair
 554         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 555
 556         // Draw the Engine Status Bar (the default Quake HUD)
 557         R_SetView(VF_DRAWENGINEHUD, 0);
 558
 559         // fetch this one only once per frame
 560         hud_showbinds = autocvar_hud_showbinds;
 561         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 562
 563         // Update the mouse position
 564         /*
 565            mousepos_x = vid_conwidth;
 566            mousepos_y = vid_conheight;
 567            mousepos = mousepos*0.5 + getmousepos();
 568          */
 569
 570         e = self;
 571         for(self = world; (self = nextent(self)); )
 572                 if(self.draw)
 573                         self.draw();
 574         self = e;
 575
 576         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 577         R_RenderScene();
 578
 579         // now switch to 2D drawing mode by calling a 2D drawing function
 580         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 581         // next R_RenderScene call
 582         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 583
 584         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 585         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 586         {
 587                 // apply night vision effect
 588                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 589
 590                 if(!nightvision_noise)
 591                 {
 592                         nightvision_noise = spawn();
 593                         nightvision_noise.classname = "nightvision_noise";
 594                 }
 595                 if(!nightvision_noise2)
 596                 {
 597                         nightvision_noise2 = spawn();
 598                         nightvision_noise2.classname = "nightvision_noise2";
 599                 }
 600
 601                 // color tint in yellow
 602                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 603
 604                 // draw BG
 605                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 606                 rgb = '1 1 1';
 607                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 608                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 609                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 610                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 611                 tc_11 = tc_01 + tc_10 - tc_00;
 612                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 613                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 614                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 615                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 616                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 617                 R_EndPolygon();
 618
 619                 // draw FG
 620                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 621                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 622                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 623                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 624                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 625                 tc_11 = tc_01 + tc_10 - tc_00;
 626                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 627                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 628                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 629                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 630                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 631                 R_EndPolygon();
 632         }
 633
 634         // Draw the aiming reticle for weapons that use it
 635         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 636         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 637         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 638         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 639                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 640         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 641                 reticle_type = 2; // nex zoom
 642         else if(button_zoom || zoomscript_caught)
 643                 reticle_type = 1; // normal zoom
 644         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 645                 reticle_type = 2; // nex zoom
 646
 647         if(autocvar_cl_reticle_stretch)
 648         {
 649                 reticle_size_x = vid_conwidth;
 650                 reticle_size_y = vid_conheight;
 651                 reticle_pos_x = 0;
 652                 reticle_pos_y = 0;
 653         }
 654         else
 655         {
 656                 reticle_size_x = max(vid_conwidth, vid_conheight);
 657                 reticle_size_y = max(vid_conwidth, vid_conheight);
 658                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 659                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 660         }
 661
 662         f = current_zoomfraction;
 663         if(zoomscript_caught)
 664                 f = 1;
 665         if(autocvar_cl_reticle_item_normal)
 666         {
 667                 precache_pic("gfx/reticle_normal");
 668                 if(reticle_type == 1 && f)
 669                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 670         }
 671         if(autocvar_cl_reticle_item_nex)
 672         {
 673                 precache_pic("gfx/reticle_nex");
 674                 if(reticle_type == 2 && f)
 675                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 676         }
 677
 678
 679         // improved polyblend
 680         vector rgb;
 681         if(autocvar_hud_contents)
 682         {
 683                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 684                 vector liquidcolor;
 685
 686                 switch(pointcontents(view_origin))
 687                 {
 688                         case CONTENT_WATER:
 689                                 liquidalpha = autocvar_hud_contents_water_alpha;
 690                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 691                                 incontent = 1;
 692                                 break;
 693
 694                         case CONTENT_LAVA:
 695                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 696                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 697                                 incontent = 1;
 698                                 break;
 699
 700                         case CONTENT_SLIME:
 701                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 702                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 703                                 incontent = 1;
 704                                 break;
 705
 706                         default:
 707                                 liquidalpha = 0;
 708                                 liquidcolor = '0 0 0';
 709                                 incontent = 0;
 710                                 break;
 711                 }
 712
 713                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 714                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 715                         contentfadetime = autocvar_hud_contents_fadeintime;
 716                         liquidalpha_prev = liquidalpha;
 717                         liquidcolor_prev = liquidcolor;
 718                 }
 719                 else
 720                         contentfadetime = autocvar_hud_contents_fadeouttime;
 721
 722                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 723                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 724
 725                 if(contentavgalpha)
 726                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 727         }
 728
 729         if(autocvar_hud_damage)
 730         {
 731                 float myhealth_flash_temp;
 732                 myhealth = getstati(STAT_HEALTH);
 733
 734                 // fade out
 735                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 736                 // add new damage
 737                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 738
 739                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 740                 pain_threshold = autocvar_hud_damage_pain_threshold;
 741                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 742                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 743
 744                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 745                 {
 746                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 747                 }
 748
 749                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 750
 751                 if(myhealth_prev < 1)
 752                 {
 753                         if(myhealth >= 1)
 754                         {
 755                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 756                                 myhealth_flash_temp = 0;
 757                         }
 758                         else
 759                         {
 760                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 761                         }
 762                 }
 763
 764                 if(spectatee_status == -1 || intermission)
 765                 {
 766                         myhealth_flash = 0; // observing, or match ended
 767                         myhealth_flash_temp = 0;
 768                 }
 769
 770                 myhealth_prev = myhealth;
 771
 772                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 773                 {
 774                         if(autocvar_cl_gentle_damage == 2)
 775                         {
 776                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 777                                 {
 778                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 779                                 }
 780                         }
 781                         else
 782                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 783
 784                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 785                 }
 786                 else
 787                         drawpic(reticle_pos, "gfx/blood", reticle_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 788         }
 789
 790         // Draw the mouse cursor
 791         // NOTE: drawpic must happen after R_RenderScene for some reason
 792         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 793         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 794         //self = edict_num(player_localnum);
 795         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 796         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 797         // as long as the ctf part isn't in, this is useless
 798         if(menu_visible)
 799                 menu_show();
 800
 801         /*if(gametype == GAME_CTF)
 802           {
 803           ctf_view();
 804           } else */
 805
 806         // draw 2D entities
 807         e = self;
 808         for(self = world; (self = nextent(self)); )
 809                 if(self.draw2d)
 810                         self.draw2d();
 811         self = e;
 812
 813         scoreboard_active = HUD_WouldDrawScoreboard();
 814
 815         hit_time = getstatf(STAT_HIT_TIME);
 816         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 817         {
 818                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 819                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 820         }
 821         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 822         if(typehit_time > nextsound_typehit_time)
 823         {
 824                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 825                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 826         }
 827
 828         float hud;
 829         hud = getstati(STAT_HUD);
 830         if(hud == HUD_SPIDERBOT)
 831                 CSQC_SPIDER_HUD();
 832         else if(hud == HUD_WAKIZASHI)
 833         CSQC_WAKIZASHI_HUD();
 834     else if(hud == HUD_RAPTOR)
 835         CSQC_RAPTOR_HUD();
 836         else
 837         {
 838                 if(gametype == GAME_FREEZETAG)
 839                 {
 840                         if(getstati(STAT_FROZEN))
 841                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 842                         if(getstatf(STAT_REVIVE_PROGRESS))
 843                         {
 844                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 845                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 846                         }
 847                 }
 848
 849                 if(autocvar_r_letterbox == 0)
 850                         if(autocvar_viewsize < 120)
 851                                 CSQC_common_hud();
 852
 853                 // crosshair goes VERY LAST
 854                 if(!scoreboard_active && !camera_active && intermission != 2) {
 855                         string wcross_style;
 856                         float wcross_alpha, wcross_resolution;
 857                         wcross_style = autocvar_crosshair;
 858                         if (wcross_style == "0")
 859                                 return;
 860                         wcross_resolution = autocvar_crosshair_size;
 861                         if (wcross_resolution == 0)
 862                                 return;
 863                         wcross_alpha = autocvar_crosshair_alpha;
 864                         if (wcross_alpha == 0)
 865                                 return;
 866
 867                         // TrueAim check
 868                         float shottype;
 869                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 870                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 871                         wcross_origin_z = 0;
 872                         if(autocvar_crosshair_hittest)
 873                         {
 874                                 vector wcross_oldorigin;
 875                                 wcross_oldorigin = wcross_origin;
 876                                 shottype = TrueAimCheck();
 877                                 if(shottype == SHOTTYPE_HITWORLD)
 878                                 {
 879                                         v = wcross_origin - wcross_oldorigin;
 880                                         v_x /= vid_conwidth;
 881                                         v_y /= vid_conheight;
 882                                         if(vlen(v) > 0.01)
 883                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 884                                 }
 885                                 if(!autocvar_crosshair_hittest_showimpact)
 886                                         wcross_origin = wcross_oldorigin;
 887                         }
 888                         else
 889                                 shottype = SHOTTYPE_HITWORLD;
 890
 891                         vector wcross_color, wcross_size;
 892                         string wcross_wep, wcross_name;
 893                         float wcross_scale, wcross_blur;
 894
 895                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 896                                 e = get_weaponinfo(activeweapon);
 897                                 if (e && e.netname != "")
 898                                 {
 899                                         wcross_wep = e.netname;
 900                                         if(autocvar_crosshair_per_weapon)
 901                                         {
 902                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 903                                                 if (wcross_resolution == 0)
 904                                                         return;
 905                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 906                                                 if (wcross_alpha == 0)
 907                                                         return;
 908
 909                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 910                                                 if(wcross_style == "" || wcross_style == "0")
 911                                                         wcross_style = wcross_wep;
 912                                         }
 913                                 }
 914                         }
 915                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 916                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 917                         else if(autocvar_crosshair_color_by_health)
 918                         {
 919                                 local float x = getstati(STAT_HEALTH);
 920
 921                                 //x = red
 922                                 //y = green
 923                                 //z = blue
 924
 925                                 wcross_color_z = 0;
 926
 927                                 if(x > 200)
 928                                 {
 929                                         wcross_color_x = 0;
 930                                         wcross_color_y = 1;
 931                                 }
 932                                 else if(x > 150)
 933                                 {
 934                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 935                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 936                                 }
 937                                 else if(x > 100)
 938                                 {
 939                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 940                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 941                                         wcross_color_z = 1 - (x-100)*0.02;
 942                                 }
 943                                 else if(x > 50)
 944                                 {
 945                                         wcross_color_x = 1;
 946                                         wcross_color_y = 1;
 947                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 948                                 }
 949                                 else if(x > 20)
 950                                 {
 951                                         wcross_color_x = 1;
 952                                         wcross_color_y = (x-20)*90/27/100;
 953                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 954                                 }
 955                                 else
 956                                 {
 957                                         wcross_color_x = 1;
 958                                         wcross_color_y = 0;
 959                                 }
 960                         }
 961                         else
 962                                 wcross_color = stov(autocvar_crosshair_color);
 963
 964                         wcross_name = strcat("gfx/crosshair", wcross_style);
 965
 966                         if(autocvar_crosshair_effect_scalefade)
 967                         {
 968                                 wcross_scale = wcross_resolution;
 969                                 wcross_resolution = 1;
 970                         }
 971                         else
 972                         {
 973                                 wcross_scale = 1;
 974                         }
 975
 976                         if(autocvar_crosshair_pickup)
 977                         {
 978                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 979                                 {
 980                                         pickup_crosshair_size = 1;
 981                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 982                                 }
 983
 984                                 if(pickup_crosshair_size > 0)
 985                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 986                                 else
 987                                         pickup_crosshair_size = 0;
 988
 989                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 990                         }
 991
 992                         vector hitindication_color;
 993                         if(autocvar_crosshair_hitindication)
 994                         {
 995                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
 996                                 if(hitindication_crosshair_time < hit_time)
 997                                 {
 998                                         hitindication_crosshair_size = 1;
 999                                         hitindication_crosshair_time = hit_time;
1000                                 }
1001
1002                                 if(hitindication_crosshair_size > 0)
1003                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1004                                 else
1005                                         hitindication_crosshair_size = 0;
1006
1007                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1008                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1009                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1010                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1011                         }
1012
1013                         if(shottype == SHOTTYPE_HITENEMY)
1014                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1015                         if(shottype == SHOTTYPE_HITTEAM)
1016                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1017
1018                         f = autocvar_crosshair_effect_speed;
1019                         if(f < 0)
1020                                 f *= -2 * g_weaponswitchdelay;
1021                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1022                         {
1023                                 wcross_changedonetime = time + f;
1024                         }
1025                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1026                         {
1027                                 wcross_name_changestarttime = time;
1028                                 wcross_name_changedonetime = time + f;
1029                                 if(wcross_name_goal_prev_prev)
1030                                         strunzone(wcross_name_goal_prev_prev);
1031                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1032                                 wcross_name_goal_prev = strzone(wcross_name);
1033                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1034                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1035                                 wcross_resolution_goal_prev = wcross_resolution;
1036                         }
1037
1038                         wcross_scale_goal_prev = wcross_scale;
1039                         wcross_alpha_goal_prev = wcross_alpha;
1040                         wcross_color_goal_prev = wcross_color;
1041
1042                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1043                         {
1044                                 wcross_blur = 1;
1045                                 wcross_alpha *= 0.75;
1046                         }
1047                         else
1048                                 wcross_blur = 0;
1049                         // *_prev is at time-frametime
1050                         // * is at wcross_changedonetime+f
1051                         // what do we have at time?
1052                         if(time < wcross_changedonetime)
1053                         {
1054                                 f = frametime / (wcross_changedonetime - time + frametime);
1055                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1056                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1057                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1058                         }
1059
1060                         wcross_scale_prev = wcross_scale;
1061                         wcross_alpha_prev = wcross_alpha;
1062                         wcross_color_prev = wcross_color;
1063
1064                         wcross_scale *= 1 - autocvar__menu_alpha;
1065                         wcross_alpha *= 1 - autocvar__menu_alpha;
1066                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1067
1068                         if (autocvar_crosshair_ring)
1069                         {
1070                                 float ring_value, ring_alpha, ring_inner_value, ring_inner_alpha;
1071                                 string ring_image, ring_inner_image;
1072                                 vector ring_rgb, ring_inner_rgb;
1073
1074                                 float ring_scale = autocvar_crosshair_ring_size;
1075
1076                                 float nex_charge, nex_chargepool;
1077                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1078                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1079
1080                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1081                                         nex_charge_movingavg = nex_charge;
1082
1083                                 if (activeweapon == WEP_SNIPERRIFLE && cr_maxbullets && autocvar_crosshair_ring_sniperrifle) // ring around crosshair representing bullets left in camping rifle clip
1084                                 {
1085                                         ring_value = bound(0, getstati(STAT_BULLETS_LOADED) / cr_maxbullets, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1086                                         ring_alpha = wcross_alpha * autocvar_crosshair_ring_sniperrifle_alpha;
1087                                         ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1088                                         ring_rgb = wcross_color;
1089                                 }
1090                                 else if (activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1091                                 {
1092                                         if (nex_chargepool || use_nex_chargepool) {
1093                                                 use_nex_chargepool = 1;
1094                                                 ring_inner_value = nex_chargepool;
1095                                         } else {
1096                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1097                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1098                                         }
1099
1100                                         ring_inner_alpha = wcross_alpha * autocvar_crosshair_ring_nex_inner_alpha;
1101                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1102                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1103
1104                                         // draw the outer ring to show the current charge of the weapon
1105                                         ring_value = nex_charge;
1106                                         ring_alpha = wcross_alpha * autocvar_crosshair_ring_nex_alpha;
1107                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1108                                         ring_rgb = wcross_color;
1109                                 }
1110                                 else if (activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1111                                 {
1112                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1113                                         ring_alpha = wcross_alpha * autocvar_crosshair_ring_minelayer_alpha;
1114                                         ring_image = "gfx/crosshair_ring.tga";
1115                                         ring_rgb = wcross_color;
1116                                 }
1117
1118                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1119                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, ring_inner_alpha, DRAWFLAG_ADDITIVE);
1120
1121                                 if (ring_value)
1122                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, ring_alpha, DRAWFLAG_ADDITIVE);
1123                         }
1124
1125 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1126                         do \
1127                         { \
1128                                 if(wcross_blur > 0) \
1129                                 { \
1130                                         for(i = -2; i <= 2; ++i) \
1131                                                 for(j = -2; j <= 2; ++j) \
1132                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1133                                 } \
1134                                 else \
1135                                 { \
1136                                         M(0,0,sz,wcross_name,wcross_alpha); \
1137                                 } \
1138                         } \
1139                         while(0)
1140
1141 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1142                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1143
1144 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1145                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1146
1147                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1148                         {
1149                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1150                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1151                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1152                                 f = 1 - f;
1153                         }
1154                         else
1155                         {
1156                                 f = 1;
1157                         }
1158
1159                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1160                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1161
1162                         if(autocvar_crosshair_dot)
1163             {
1164                 vector wcross_color_old;
1165                 wcross_color_old = wcross_color;
1166                 if(autocvar_crosshair_dot_color != "0")
1167                     wcross_color = stov(autocvar_crosshair_dot_color);
1168                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1169                 wcross_color = wcross_color_old;
1170             }
1171
1172                         wcross_name_alpha_goal_prev = f;
1173                 }
1174                 else
1175                 {
1176                         wcross_scale_prev = 0;
1177                         wcross_alpha_prev = 0;
1178                         wcross_scale_goal_prev = 0;
1179                         wcross_alpha_goal_prev = 0;
1180                         wcross_changedonetime = 0;
1181                         if(wcross_name_goal_prev)
1182                                 strunzone(wcross_name_goal_prev);
1183                         wcross_name_goal_prev = string_null;
1184                         if(wcross_name_goal_prev_prev)
1185                                 strunzone(wcross_name_goal_prev_prev);
1186                         wcross_name_goal_prev_prev = string_null;
1187                         wcross_name_changestarttime = 0;
1188                         wcross_name_changedonetime = 0;
1189                         wcross_name_alpha_goal_prev = 0;
1190                         wcross_name_alpha_goal_prev_prev = 0;
1191                         wcross_resolution_goal_prev = 0;
1192                         wcross_resolution_goal_prev_prev = 0;
1193                 }
1194         }
1195
1196         if(NextFrameCommand)
1197         {
1198                 localcmd("\n", NextFrameCommand, "\n");
1199                 NextFrameCommand = string_null;
1200         }
1201
1202         // we must do this check AFTER a frame was rendered, or it won't work
1203         if(cs_project_is_b0rked == 0)
1204         {
1205                 string w0, h0;
1206                 w0 = ftos(autocvar_vid_conwidth);
1207                 h0 = ftos(autocvar_vid_conheight);
1208                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1209                 //R_SetView(VF_FOV, '90 90 0');
1210                 R_SetView(VF_ORIGIN, '0 0 0');
1211                 R_SetView(VF_ANGLES, '0 0 0');
1212                 R_SetView(VF_PERSPECTIVE, 1);
1213                 makevectors('0 0 0');
1214                 vector v1, v2;
1215                 cvar_set("vid_conwidth", "800");
1216                 cvar_set("vid_conheight", "600");
1217                 v1 = cs_project(v_forward);
1218                 cvar_set("vid_conwidth", "640");
1219                 cvar_set("vid_conheight", "480");
1220                 v2 = cs_project(v_forward);
1221                 if(v1 == v2)
1222                         cs_project_is_b0rked = 1;
1223                 else
1224                         cs_project_is_b0rked = -1;
1225                 cvar_set("vid_conwidth", w0);
1226                 cvar_set("vid_conheight", h0);
1227         }
1228
1229         if(autocvar__hud_configure)
1230                 HUD_Panel_Mouse();
1231
1232         // let's reset the view back to normal for the end
1233         R_SetView(VF_MIN, '0 0 0');
1234         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1235 }
1236
1237 #define spider_h "gfx/vehicles/hud_bg.tga"
1238 #define spider_b "gfx/vehicles/sbot.tga"
1239 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1240 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1241 #define spider_s "gfx/vehicles/shiled.tga"
1242 #define spider_a1 "gfx/hud/sb_rocket.tga"
1243 #define spider_a2 "gfx/sb_bullets.tga"
1244
1245 void CSQC_SPIDER_HUD()
1246 {
1247         float rockets, reload, heat, hp, shield;
1248         vector picsize, hudloc;
1249
1250     // Fetch health & ammo stats
1251     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1252         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1253         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1254         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1255         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1256
1257     // Draw the crosshairs
1258     picsize = drawgetimagesize(SPIDER_CROSS);
1259     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1260     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1261     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1262
1263     hudloc_y =  4;
1264     hudloc_x = 4;
1265
1266     picsize = drawgetimagesize(spider_h) * 0.5;
1267     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1268
1269     picsize = drawgetimagesize(spider_a2) * 0.5;
1270     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1271
1272     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1273     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1274     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1275
1276     picsize = drawgetimagesize(spider_a1) * 0.85;
1277     if(rockets == 9)
1278     {
1279         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1280         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1281     }
1282     else
1283     {
1284         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1285         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1286     }
1287
1288     picsize = drawgetimagesize(spider_b) * 0.5;
1289     hudloc_y = 10.5;
1290     hudloc_x = 10.5;
1291
1292     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1293     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1294     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1295     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1296
1297
1298         /*
1299         // Draw health bar
1300         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1301         p = p + '0 1 0' * vid_conheight - '0 32 0';
1302         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1303         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1304         p_y += 8;
1305         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1306         p_x += 256 * hp;
1307         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1308
1309         // Draw minigun heat indicator
1310         p = '0.5 0 0' * (vid_conwidth - 256);
1311         p = p + '0 1 0' * vid_conheight - '0 34  0';
1312         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1313         p_x += 256 * (1-heat);
1314         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1315
1316
1317         // Draw rocket icons for loaded/empty tubes.
1318         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1319         pp += '0 1 0' * vid_conheight - '0 64 0';
1320         for(i = 0; i < 8; ++i)
1321         {
1322                 p = pp + '1 0 0' * (rkt_size * i);
1323                 if(rockets == 8)
1324                 {
1325                         if(floor(reload * 8) == i)
1326                         {
1327                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1328                         }
1329                         else if(i < reload * 8)
1330                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1331                         else
1332                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1333                 }
1334                 else
1335                 {
1336                         if(i < rockets)
1337                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1338                         else
1339                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1340                 }
1341         }
1342         */
1343
1344         if (scoreboard_showscores)
1345         {
1346                 HUD_DrawScoreboard();
1347                 HUD_DrawCenterPrint();
1348         }
1349
1350 }
1351
1352 #define raptor_h "gfx/vehicles/hud_bg.tga"
1353 #define raptor_b "gfx/vehicles/raptor.tga"
1354 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1355 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1356 #define raptor_s "gfx/vehicles/shiled.tga"
1357
1358 void CSQC_RAPTOR_HUD()
1359 {
1360         float reload, hp, shield, energy;
1361         vector picsize, hudloc;
1362
1363     // Fetch health & ammo stats
1364     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1365         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1366         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1367         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1368
1369     // Draw the crosshairs
1370     picsize = drawgetimagesize(SPIDER_CROSS);
1371     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1372     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1373     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1374
1375     hudloc_y =  4;
1376     hudloc_x = 4;
1377
1378     picsize = drawgetimagesize(raptor_h) * 0.5;
1379     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1380
1381     picsize = drawgetimagesize(spider_a2) * 0.5;
1382     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1383
1384     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1385     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1386     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1387
1388
1389     picsize = drawgetimagesize(spider_a1) * 0.85;
1390     if(reload == 1)
1391     {
1392         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1393         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1394     }
1395     else
1396     {
1397         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1398         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1399     }
1400
1401     picsize = drawgetimagesize(raptor_b) * 0.5;
1402     hudloc_y = 10.5;
1403     hudloc_x = 10.5;
1404
1405     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1406     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1407     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1408     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1409
1410
1411         if (scoreboard_showscores)
1412         {
1413                 HUD_DrawScoreboard();
1414                 HUD_DrawCenterPrint();
1415         }
1416
1417 }
1418
1419 #define waki_h "gfx/vehicles/hud_bg.tga"
1420 #define waki_b "gfx/vehicles/waki.tga"
1421 #define waki_e "gfx/vehicles/waki_e.tga"
1422 #define waki_g "gfx/vehicles/waki_guns.tga"
1423 #define waki_r "gfx/vehicles/waki_rockets.tga"
1424 #define waki_s "gfx/vehicles/shiled.tga"
1425
1426 #define waki_a1 "gfx/hud/sb_rocket.tga"
1427 #define waki_a2 "gfx/sb_cells.tga"
1428
1429 void CSQC_WAKIZASHI_HUD()
1430 {
1431         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1432         float health, shield, energy, rockets;
1433         vector picsize, hudloc;
1434
1435     picsize = drawgetimagesize(SPIDER_CROSS);
1436     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1437     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1438     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1439
1440 /*
1441 const float STAT_VEHICLESTAT_HEALTH  = 60;
1442 const float STAT_VEHICLESTAT_SHIELD  = 61;
1443 const float STAT_VEHICLESTAT_ENERGY  = 62;
1444 const float STAT_VEHICLESTAT_AMMO1   = 63;
1445 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1446 const float STAT_VEHICLESTAT_AMMO2   = 65;
1447 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1448 */
1449     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1450         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1451         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1452         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1453
1454     hudloc_y =  4;
1455     hudloc_x = 4;
1456
1457     picsize = drawgetimagesize(waki_h) * 0.5;
1458     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1459
1460     picsize = drawgetimagesize(waki_a2) * 0.7;
1461     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1462
1463
1464     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1465     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1466
1467     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1468
1469     picsize = drawgetimagesize(waki_a1) * 0.75;
1470     if(rockets == 1)
1471     {
1472         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1473         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1474     }
1475     else
1476     {
1477         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1478         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1479         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1480     }
1481
1482     picsize = drawgetimagesize(waki_b) * 0.5;
1483     hudloc_y = 10.5;
1484     hudloc_x = 10.5;
1485
1486     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1487     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1488     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1489     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1490
1491
1492
1493         /*
1494         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1495         p = p + '0 1 0' * vid_conheight - '0 32 0';
1496
1497         // Draw health bar
1498         p_y += 8;
1499         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1500         p_x += 256 * health;
1501         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1502
1503         // Draw shiled bar
1504         p_x -= 256 * health;
1505         p_y += 4;
1506         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1507
1508         // Draw energy
1509         //p_x -= 256 * health;
1510         p_y -= 8;
1511         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1512
1513         // Draw rockets bar
1514         p_y += 12;
1515         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1516         */
1517
1518
1519
1520
1521         if (scoreboard_showscores)
1522         {
1523                 HUD_DrawScoreboard();
1524                 HUD_DrawCenterPrint();
1525         }
1526
1527 }
1528
1529
1530 void CSQC_common_hud(void)
1531 {
1532         // HUD_SortFrags(); done in HUD_Draw
1533         float hud;
1534         hud = getstati(STAT_HUD);
1535
1536         //hud = 10;
1537         switch(hud)
1538         {
1539                 case HUD_NORMAL:
1540                         // do some accuracy var caching
1541                         float i;
1542                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1543                         {
1544                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1545                                 {
1546                                         if(acc_color_levels)
1547                                                 strunzone(acc_color_levels);
1548                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1549                                         acc_levels = tokenize(acc_color_levels);
1550                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1551                                                 acc_levels = MAX_ACCURACY_LEVELS;
1552
1553                                         for (i = 0; i < acc_levels; ++i)
1554                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1555                                 }
1556                                 // let know that acc_col[] needs to be loaded
1557                                 acc_col_x[0] = -1;
1558                         }
1559
1560                         HUD_Main(); // always run these functions for alpha checks
1561                         HUD_DrawScoreboard();
1562
1563                         if (scoreboard_active) // scoreboard/accuracy
1564                         {
1565                                 HUD_Reset();
1566                                 // HUD_DrawScoreboard takes care of centerprint_start
1567                         }
1568                         else if (intermission == 2) // map voting screen
1569                         {
1570                                 HUD_FinaleOverlay();
1571                                 HUD_Reset();
1572
1573                                 centerprint_start_x = 0;
1574                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1575                         }
1576                         else // hud
1577                         {
1578                                 centerprint_start_x = 0;
1579                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1580                         }
1581
1582                         HUD_DrawCenterPrint();
1583                         break;
1584
1585                 case HUD_SPIDERBOT:
1586                         CSQC_SPIDER_HUD();
1587                         break;
1588
1589                 case HUD_WAKIZASHI:
1590                         CSQC_WAKIZASHI_HUD();
1591                         break;
1592         }
1593 }
1594
1595
1596 // following vectors must be global to allow seamless switching between camera modes
1597 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1598 void CSQC_Demo_Camera()
1599 {
1600         float speed, attenuation, dimensions;
1601         vector tmp, delta;
1602
1603         if( autocvar_camera_reset || !camera_mode )
1604         {
1605                 camera_offset = '0 0 0';
1606                 current_angles = '0 0 0';
1607                 camera_direction = '0 0 0';
1608                 camera_offset_z += 30;
1609                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1610                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1611                 current_origin = view_origin;
1612                 current_camera_offset  = camera_offset;
1613                 cvar_set("camera_reset", "0");
1614                 camera_mode = CAMERA_CHASE;
1615         }
1616
1617         // Camera angles
1618         if( camera_roll )
1619                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1620
1621         if(autocvar_camera_look_player)
1622         {
1623                 local vector dir;
1624                 local float n;
1625
1626                 dir = normalize(view_origin - current_position);
1627                 n = mouse_angles_z;
1628                 mouse_angles = vectoangles(dir);
1629                 mouse_angles_x = mouse_angles_x * -1;
1630                 mouse_angles_z = n;
1631         }
1632         else
1633         {
1634                 tmp = getmousepos() * 0.1;
1635                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1636                 {
1637                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1638                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1639                 }
1640         }
1641
1642         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1643         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1644         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1645         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1646
1647         // Fix difference when angles don't have the same sign
1648         delta = '0 0 0';
1649         if(mouse_angles_y < -60 && current_angles_y > 60)
1650                 delta = '0 360 0';
1651         if(mouse_angles_y > 60 && current_angles_y < -60)
1652                 delta = '0 -360 0';
1653
1654         if(autocvar_camera_look_player)
1655                 attenuation = autocvar_camera_look_attenuation;
1656         else
1657                 attenuation = autocvar_camera_speed_attenuation;
1658
1659         attenuation = 1 / max(1, attenuation);
1660         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1661
1662         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1663         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1664         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1665         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1666
1667         // Camera position
1668         tmp = '0 0 0';
1669         dimensions = 0;
1670
1671         if( camera_direction_x )
1672         {
1673                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1674                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1675                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1676                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1677                 ++dimensions;
1678         }
1679
1680         if( camera_direction_y )
1681         {
1682                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1683                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1684                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1685                 ++dimensions;
1686         }
1687
1688         if( camera_direction_z )
1689         {
1690                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1691                 ++dimensions;
1692         }
1693
1694         if(autocvar_camera_free)
1695                 speed = autocvar_camera_speed_free;
1696         else
1697                 speed = autocvar_camera_speed_chase;
1698
1699         if(dimensions)
1700         {
1701                 speed = speed * sqrt(1 / dimensions);
1702                 camera_offset += tmp * speed;
1703         }
1704
1705         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1706
1707         // Camera modes
1708         if( autocvar_camera_free )
1709         {
1710                 if ( camera_mode == CAMERA_CHASE )
1711                 {
1712                         current_camera_offset = current_origin + current_camera_offset;
1713                         camera_offset = current_origin + camera_offset;
1714                 }
1715
1716                 camera_mode = CAMERA_FREE;
1717                 current_position = current_camera_offset;
1718         }
1719         else
1720         {
1721                 if ( camera_mode == CAMERA_FREE )
1722                 {
1723                         current_origin = view_origin;
1724                         camera_offset = camera_offset - current_origin;
1725                         current_camera_offset = current_camera_offset - current_origin;
1726                 }
1727
1728                 camera_mode = CAMERA_CHASE;
1729
1730                 if(autocvar_camera_chase_smoothly)
1731                         current_origin += (view_origin - current_origin) * attenuation;
1732                 else
1733                         current_origin = view_origin;
1734
1735                 current_position = current_origin + current_camera_offset;
1736         }
1737
1738         R_SetView(VF_ANGLES, current_angles);
1739         R_SetView(VF_ORIGIN, current_position);
1740 }