qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 void Porto_Init()
  84 {
  85         porto = spawn();
  86         porto.classname = "porto";
  87         porto.draw = Porto_Draw;
  88         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  89 }
  90
  91 float drawtime;
  92 float avgspeed;
  93 vector GetCurrentFov(float fov)
  94 {
  95         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  96         float velocityzoom, curspeed;
  97         vector v;
  98
  99         zoomsensitivity = autocvar_cl_zoomsensitivity;
 100         zoomfactor = autocvar_cl_zoomfactor;
 101         if(zoomfactor < 1 || zoomfactor > 16)
 102                 zoomfactor = 2.5;
 103         zoomspeed = autocvar_cl_zoomspeed;
 104         if(zoomspeed >= 0)
 105                 if(zoomspeed < 0.5 || zoomspeed > 16)
 106                         zoomspeed = 3.5;
 107
 108         zoomdir = button_zoom;
 109         if(hud == HUD_NORMAL)
 110         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 111                 zoomdir += button_attack2;
 112         if(spectatee_status > 0 || isdemo())
 113         {
 114                 if(spectatorbutton_zoom)
 115                 {
 116                         if(zoomdir)
 117                                 zoomdir = 0;
 118                         else
 119                                 zoomdir = 1;
 120                 }
 121                 // fteqcc failed twice here already, don't optimize this
 122         }
 123
 124         if(zoomdir)
 125                 zoomin_effect = 0;
 126
 127         if(zoomin_effect || camera_active)
 128         {
 129                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 130         }
 131         else
 132         {
 133                 if(zoomspeed < 0) // instant zoom
 134                 {
 135                         if(zoomdir)
 136                                 current_viewzoom = 1 / zoomfactor;
 137                         else
 138                                 current_viewzoom = 1;
 139                 }
 140                 else
 141                 {
 142                         if(zoomdir)
 143                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 144                         else
 145                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 146                 }
 147         }
 148
 149         if(almost_equals(current_viewzoom, 1))
 150                 current_zoomfraction = 0;
 151         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 152                 current_zoomfraction = 1;
 153         else
 154                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 155
 156         if(zoomsensitivity < 1)
 157                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 158         else
 159                 setsensitivityscale(1);
 160
 161         makevectors(view_angles);
 162
 163         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 164         {
 165                 v = pmove_vel;
 166                 if(csqcplayer)
 167                         v = csqcplayer.velocity;
 168
 169                 switch(autocvar_cl_velocityzoom_type)
 170                 {
 171                         case 3: curspeed = max(0, v_forward * v); break;
 172                         case 2: curspeed = (v_forward * v); break;
 173                         case 1: default: curspeed = vlen(v); break;
 174                 }
 175
 176                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 177                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 178                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 179
 180                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 181         }
 182         else
 183                 velocityzoom = 1;
 184
 185         float frustumx, frustumy, fovx, fovy;
 186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 190
 191         return '1 0 0' * fovx + '0 1 0' * fovy;
 192 }
 193
 194 // this function must match W_SetupShot!
 195 float zoomscript_caught;
 196
 197 vector wcross_origin;
 198 float wcross_scale_prev, wcross_alpha_prev;
 199 vector wcross_color_prev;
 200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 201 vector wcross_color_goal_prev;
 202 float wcross_changedonetime;
 203
 204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 206 float wcross_name_changestarttime, wcross_name_changedonetime;
 207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 208 entity trueaim;
 209 entity trueaim_rifle;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221         trueaim_rifle = spawn();
 222         trueaim_rifle.classname = "trueaim_rifle";
 223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224 }
 225
 226 float EnemyHitCheck()
 227 {
 228         float t, n;
 229         wcross_origin = project_3d_to_2d(trace_endpos);
 230         wcross_origin_z = 0;
 231         if(trace_ent)
 232                 n = trace_ent.entnum;
 233         else
 234                 n = trace_networkentity;
 235         if(n < 1)
 236                 return SHOTTYPE_HITWORLD;
 237         if(n > maxclients)
 238                 return SHOTTYPE_HITWORLD;
 239         t = GetPlayerColor(n - 1);
 240         if(teamplay)
 241                 if(t == myteam)
 242                         return SHOTTYPE_HITTEAM;
 243         if(t == COLOR_SPECTATOR)
 244                 return SHOTTYPE_HITWORLD;
 245         return SHOTTYPE_HITENEMY;
 246 }
 247
 248 float TrueAimCheck()
 249 {
 250         float nudge = 1; // added to traceline target and subtracted from result
 251         vector vecs, trueaimpoint, w_shotorg;
 252         vector mi, ma, dv;
 253         float shottype;
 254         entity ta;
 255         float mv;
 256
 257         mi = ma = '0 0 0';
 258         ta = trueaim;
 259         mv = MOVE_NOMONSTERS;
 260
 261         switch(activeweapon)
 262         {
 263                 case WEP_TUBA: // no aim
 264                 case WEP_PORTO: // shoots from eye
 265                 case WEP_HOOK: // no trueaim
 266                 case WEP_GRENADE_LAUNCHER: // toss curve
 267                         return SHOTTYPE_HITWORLD;
 268                 case WEP_NEX:
 269                 case WEP_MINSTANEX:
 270                         mv = MOVE_NORMAL;
 271                         break;
 272                 case WEP_RIFLE:
 273                         ta = trueaim_rifle;
 274                         mv = MOVE_NORMAL;
 275                         if(zoomscript_caught)
 276                         {
 277                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 278                                 return EnemyHitCheck();
 279                         }
 280                         break;
 281                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 282                         mi = '-3 -3 -3';
 283                         ma = '3 3 3';
 284                         break;
 285                 case WEP_FIREBALL: // projectile has a size!
 286                         mi = '-16 -16 -16';
 287                         ma = '16 16 16';
 288                         break;
 289                 case WEP_SEEKER: // projectile has a size!
 290                         mi = '-2 -2 -2';
 291                         ma = '2 2 2';
 292                         break;
 293                 case WEP_ELECTRO: // projectile has a size!
 294                         mi = '0 0 -3';
 295                         ma = '0 0 -3';
 296                         break;
 297         }
 298
 299         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 300
 301         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 302         trueaimpoint = trace_endpos;
 303
 304         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 305                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 306
 307         if(vecs_x > 0)
 308                 vecs_y = -vecs_y;
 309         else
 310                 vecs = '0 0 0';
 311
 312         dv = view_right * vecs_y + view_up * vecs_z;
 313         w_shotorg = view_origin + dv;
 314
 315         // now move the vecs forward as much as requested if possible
 316         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 317         w_shotorg = trace_endpos - view_forward * nudge;
 318
 319         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 320         shottype = EnemyHitCheck();
 321         if(shottype != SHOTTYPE_HITWORLD)
 322                 return shottype;
 323
 324 #if 0
 325         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 326         // or rather, I know why, but see no fix
 327         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 328                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 329                 return SHOTTYPE_HITOBSTRUCTION;
 330 #endif
 331
 332         return SHOTTYPE_HITWORLD;
 333 }
 334
 335 void CSQC_common_hud(void);
 336
 337 void PostInit(void);
 338 void CSQC_Demo_Camera();
 339 float HUD_WouldDrawScoreboard();
 340 float camera_mode;
 341 float CAMERA_FREE = 1;
 342 float CAMERA_CHASE = 2;
 343 float reticle_type;
 344 string NextFrameCommand;
 345 void CSQC_SPIDER_HUD();
 346 void CSQC_RAPTOR_HUD();
 347
 348 vector freeze_org, freeze_ang;
 349 entity nightvision_noise, nightvision_noise2;
 350
 351 #define MAX_TIME_DIFF 5
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353 float hit_time, typehit_time;
 354 float nextsound_hit_time, nextsound_typehit_time;
 355 float hitindication_crosshair_time, hitindication_crosshair_size;
 356 float use_nex_chargepool;
 357
 358 float myhealth, myhealth_prev;
 359 float myhealth_flash;
 360
 361 float old_blurradius, old_bluralpha;
 362 float old_sharpen_intensity;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float eventchase_current_distance;
 370
 371 vector damage_blurpostprocess, content_blurpostprocess;
 372
 373 float checkfail[16];
 374
 375 #define BUTTON_3 4
 376 #define BUTTON_4 8
 377 float cl_notice_run();
 378 void CSQC_UpdateView(float w, float h)
 379 {
 380         entity e;
 381         float fov;
 382         float f, i, j;
 383         vector v;
 384         vector vf_size, vf_min;
 385         float a;
 386
 387         execute_next_frame();
 388
 389         ++framecount;
 390
 391         hud = getstati(STAT_HUD);
 392
 393         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 394                 view_quality = getproperty(VF_MINFPS_QUALITY);
 395         else
 396                 view_quality = 1;
 397
 398         button_attack2 = (input_buttons & BUTTON_3);
 399         button_zoom = (input_buttons & BUTTON_4);
 400
 401         // FIXME do we need this hack?
 402         if(isdemo())
 403         {
 404                 // in demos, input_buttons do not work
 405                 button_zoom = (autocvar__togglezoom == "-");
 406         }
 407
 408 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 409         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 410         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 411         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 412         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 413         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 414         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 415         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 416
 417         vf_size = getpropertyvec(VF_SIZE);
 418         vf_min = getpropertyvec(VF_MIN);
 419         vid_width = vf_size_x;
 420         vid_height = vf_size_y;
 421
 422         vector reticle_pos, reticle_size;
 423         vector splash_pos, splash_size;
 424
 425         WaypointSprite_Load();
 426
 427         CSQCPlayer_SetCamera();
 428
 429 #ifdef COMPAT_XON050_ENGINE
 430         if(spectatee_status)
 431                 myteam = GetPlayerColor(spectatee_status - 1);
 432         else
 433 #endif
 434                 myteam = GetPlayerColor(player_localentnum - 1);
 435
 436         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 437
 438         // event chase camera
 439         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 440         {
 441                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 442                 {
 443                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 444                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 445
 446                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 447                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 448                         if(!autocvar_chase_active)
 449                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 450
 451                         // make the camera smooth back
 452                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 453                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 454                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 455                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 456
 457                         vector eventchase_target_origin;
 458                         makevectors(view_angles);
 459                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 460                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 461                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 462                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 463                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 464                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 465                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 466
 467                         setproperty(VF_ORIGIN, trace_endpos);
 468                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 469                 }
 470                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 471                 {
 472                         cvar_set("chase_active", "0");
 473                         eventchase_current_distance = 0; // start from 0 next time
 474                 }
 475         }
 476         // workaround for camera stuck between player's legs when using chase_active 1
 477         // because the engine stops updating the chase_active camera when the game ends
 478         else if(intermission)
 479         {
 480                 cvar_settemp("chase_active", "-1");
 481                 eventchase_current_distance = 0;
 482         }
 483
 484         // do lockview after event chase camera so that it still applies whenever necessary.
 485         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 486         {
 487                 setproperty(VF_ORIGIN, freeze_org);
 488                 setproperty(VF_ANGLES, freeze_ang);
 489         }
 490         else
 491         {
 492                 freeze_org = getpropertyvec(VF_ORIGIN);
 493                 freeze_ang = getpropertyvec(VF_ANGLES);
 494         }
 495
 496         WarpZone_FixView();
 497         //WarpZone_FixPMove();
 498
 499         // Render the Scene
 500         view_origin = getpropertyvec(VF_ORIGIN);
 501         view_angles = getpropertyvec(VF_ANGLES);
 502         makevectors(view_angles);
 503         view_forward = v_forward;
 504         view_right = v_right;
 505         view_up = v_up;
 506
 507 #ifdef BLURTEST
 508         if(time > blurtest_time0 && time < blurtest_time1)
 509         {
 510                 float r, t;
 511
 512                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 513                 r = t * blurtest_radius;
 514                 f = 1 / pow(t, blurtest_power) - 1;
 515
 516                 cvar_set("r_glsl_postprocess", "1");
 517                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 518         }
 519         else
 520         {
 521                 cvar_set("r_glsl_postprocess", "0");
 522                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 523         }
 524 #endif
 525
 526         TargetMusic_Advance();
 527         Fog_Force();
 528
 529         if(drawtime == 0)
 530                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 531         else
 532                 drawframetime = bound(0.000001, time - drawtime, 1);
 533         drawtime = time;
 534
 535         // watch for gametype changes here...
 536         // in ParseStuffCMD the cmd isn't executed yet :/
 537         // might even be better to add the gametype to TE_CSQC_INIT...?
 538         if(!postinit)
 539                 PostInit();
 540
 541         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 542         {
 543                 if(calledhooks & HOOK_START)
 544                 {
 545                         localcmd("\ncl_hook_gameend\n");
 546                         calledhooks |= HOOK_END;
 547                 }
 548         }
 549
 550         Announcer();
 551
 552         fov = autocvar_fov;
 553         if(fov <= 59.5)
 554         {
 555                 if(!zoomscript_caught)
 556                 {
 557                         localcmd("+button9\n");
 558                         zoomscript_caught = 1;
 559                 }
 560         }
 561         else
 562         {
 563                 if(zoomscript_caught)
 564                 {
 565                         localcmd("-button9\n");
 566                         zoomscript_caught = 0;
 567                 }
 568         }
 569
 570         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 571
 572         // next WANTED weapon (for HUD)
 573         switchweapon = getstati(STAT_SWITCHWEAPON);
 574
 575         // currently switching-to weapon (for crosshair)
 576         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 577
 578         // actually active weapon (for zoom)
 579         activeweapon = getstati(STAT_ACTIVEWEAPON);
 580
 581         f = (serverflags & SERVERFLAG_TEAMPLAY);
 582         if(f != teamplay)
 583         {
 584                 teamplay = f;
 585                 HUD_InitScores();
 586         }
 587
 588         if(last_switchweapon != switchweapon) {
 589                 weapontime = time;
 590                 last_switchweapon = switchweapon;
 591         }
 592         if(last_activeweapon != activeweapon) {
 593                 last_activeweapon = activeweapon;
 594
 595                 e = get_weaponinfo(activeweapon);
 596                 if(e.netname != "")
 597                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 598                 else
 599                         localcmd("\ncl_hook_activeweapon none\n");
 600         }
 601
 602         // ALWAYS Clear Current Scene First
 603         clearscene();
 604 #ifdef WORKAROUND_XON010
 605         if(checkextension("DP_CSQC_ROTATEMOVES"))
 606         {
 607 #endif
 608         setproperty(VF_ORIGIN, view_origin);
 609         setproperty(VF_ANGLES, view_angles);
 610 #ifdef WORKAROUND_XON010
 611         }
 612 #endif
 613
 614         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 615         setproperty(VF_SIZE, vf_size);
 616         setproperty(VF_MIN, vf_min);
 617
 618         // Assign Standard Viewflags
 619         // Draw the World (and sky)
 620         setproperty(VF_DRAWWORLD, 1);
 621
 622         // Set the console size vars
 623         vid_conwidth = autocvar_vid_conwidth;
 624         vid_conheight = autocvar_vid_conheight;
 625         vid_pixelheight = autocvar_vid_pixelheight;
 626
 627         setproperty(VF_FOV, GetCurrentFov(fov));
 628
 629         // Camera for demo playback
 630         if(camera_active)
 631         {
 632                 if(autocvar_camera_enable)
 633                         CSQC_Demo_Camera();
 634                 else
 635                 {
 636                         cvar_set("chase_active", ftos(chase_active_backup));
 637                         cvar_set("cl_demo_mousegrab", "0");
 638                         camera_active = FALSE;
 639                 }
 640         }
 641 #ifdef CAMERATEST
 642         else if(autocvar_camera_enable)
 643 #else
 644         else if(autocvar_camera_enable && isdemo())
 645 #endif
 646         {
 647                 // Enable required Darkplaces cvars
 648                 chase_active_backup = autocvar_chase_active;
 649                 cvar_set("chase_active", "2");
 650                 cvar_set("cl_demo_mousegrab", "1");
 651                 camera_active = TRUE;
 652                 camera_mode = FALSE;
 653         }
 654
 655         // Draw the Crosshair
 656         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 657
 658         // Draw the Engine Status Bar (the default Quake HUD)
 659         setproperty(VF_DRAWENGINESBAR, 0);
 660
 661         // Update the mouse position
 662         /*
 663            mousepos_x = vid_conwidth;
 664            mousepos_y = vid_conheight;
 665            mousepos = mousepos*0.5 + getmousepos();
 666          */
 667
 668         e = self;
 669         for(self = world; (self = nextent(self)); )
 670                 if(self.draw)
 671                         self.draw();
 672         self = e;
 673
 674         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 675         renderscene();
 676
 677         // now switch to 2D drawing mode by calling a 2D drawing function
 678         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 679         // next R_RenderScene call
 680         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 681
 682         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 683         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 684         {
 685                 // apply night vision effect
 686                 vector tc_00, tc_01, tc_10, tc_11;
 687                 vector rgb;
 688                 rgb_x = 0; // fteqcc sucks
 689                 rgb_y = 0; // fteqcc sucks
 690                 rgb_z = 0; // fteqcc sucks
 691
 692                 if(!nightvision_noise)
 693                 {
 694                         nightvision_noise = spawn();
 695                         nightvision_noise.classname = "nightvision_noise";
 696                 }
 697                 if(!nightvision_noise2)
 698                 {
 699                         nightvision_noise2 = spawn();
 700                         nightvision_noise2.classname = "nightvision_noise2";
 701                 }
 702
 703                 // color tint in yellow
 704                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 705
 706                 // draw BG
 707                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 708                 rgb = '1 1 1';
 709                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 710                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 711                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 712                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 713                 tc_11 = tc_01 + tc_10 - tc_00;
 714                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 715                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 716                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 717                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 718                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 719                 R_EndPolygon();
 720
 721                 // draw FG
 722                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 723                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 724                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 725                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 726                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 727                 tc_11 = tc_01 + tc_10 - tc_00;
 728                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 729                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 730                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 731                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 732                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 733                 R_EndPolygon();
 734         }
 735
 736         // Draw the aiming reticle for weapons that use it
 737         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 738         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 739         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 740         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 741                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 742         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 743                 reticle_type = 2; // nex zoom
 744         else if(button_zoom || zoomscript_caught)
 745                 reticle_type = 1; // normal zoom
 746         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 747                 reticle_type = 2; // nex zoom
 748
 749         if(reticle_type && autocvar_cl_reticle)
 750         {
 751                 if(autocvar_cl_reticle_stretch)
 752                 {
 753                         reticle_size_x = vid_conwidth;
 754                         reticle_size_y = vid_conheight;
 755                         reticle_pos_x = 0;
 756                         reticle_pos_y = 0;
 757                 }
 758                 else
 759                 {
 760                         reticle_size_x = max(vid_conwidth, vid_conheight);
 761                         reticle_size_y = max(vid_conwidth, vid_conheight);
 762                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 763                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 764                 }
 765
 766                 f = current_zoomfraction;
 767                 if(zoomscript_caught)
 768                         f = 1;
 769                 if(autocvar_cl_reticle_item_normal)
 770                 {
 771                         if(reticle_type == 1 && f)
 772                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 773                 }
 774                 if(autocvar_cl_reticle_item_nex)
 775                 {
 776                         if(reticle_type == 2 && f)
 777                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 778                 }
 779         }
 780
 781
 782         // improved polyblend
 783         vector rgb;
 784         if(autocvar_hud_contents)
 785         {
 786                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 787                 vector liquidcolor;
 788
 789                 switch(pointcontents(view_origin))
 790                 {
 791                         case CONTENT_WATER:
 792                                 liquidalpha = autocvar_hud_contents_water_alpha;
 793                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 794                                 incontent = 1;
 795                                 break;
 796
 797                         case CONTENT_LAVA:
 798                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 799                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 800                                 incontent = 1;
 801                                 break;
 802
 803                         case CONTENT_SLIME:
 804                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 805                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 806                                 incontent = 1;
 807                                 break;
 808
 809                         default:
 810                                 liquidalpha = 0;
 811                                 liquidcolor = '0 0 0';
 812                                 incontent = 0;
 813                                 break;
 814                 }
 815
 816                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 817                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 818                         contentfadetime = autocvar_hud_contents_fadeintime;
 819                         liquidalpha_prev = liquidalpha;
 820                         liquidcolor_prev = liquidcolor;
 821                 }
 822                 else
 823                         contentfadetime = autocvar_hud_contents_fadeouttime;
 824
 825                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 826                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 827
 828                 if(contentavgalpha)
 829                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 830
 831                 if(autocvar_hud_postprocessing)
 832                 {
 833                         if(autocvar_hud_contents_blur && contentavgalpha)
 834                         {
 835                                 content_blurpostprocess_x = 1;
 836                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 837                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 838                         }
 839                         else
 840                         {
 841                                 content_blurpostprocess_x = 0;
 842                                 content_blurpostprocess_y = 0;
 843                                 content_blurpostprocess_z = 0;
 844                         }
 845                 }
 846         }
 847
 848         if(autocvar_hud_damage)
 849         {
 850                 splash_size_x = max(vid_conwidth, vid_conheight);
 851                 splash_size_y = max(vid_conwidth, vid_conheight);
 852                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 853                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 854
 855                 float myhealth_flash_temp;
 856                 myhealth = getstati(STAT_HEALTH);
 857
 858                 // fade out
 859                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 860                 // add new damage
 861                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 862
 863                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 864                 pain_threshold = autocvar_hud_damage_pain_threshold;
 865                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 866                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 867
 868                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 869                 {
 870                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 871                 }
 872
 873                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 874
 875                 if(myhealth_prev < 1)
 876                 {
 877                         if(myhealth >= 1)
 878                         {
 879                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 880                                 myhealth_flash_temp = 0;
 881                         }
 882                         else
 883                         {
 884                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 885                         }
 886                 }
 887
 888                 if(spectatee_status == -1 || intermission)
 889                 {
 890                         myhealth_flash = 0; // observing, or match ended
 891                         myhealth_flash_temp = 0;
 892                 }
 893
 894                 myhealth_prev = myhealth;
 895
 896                 // IDEA: change damage color/picture based on player model for robot/alien species?
 897                 // pro: matches model better
 898                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 899                 // maybe different reddish pics?
 900                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 901                 {
 902                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 903                         {
 904                                 if(autocvar_cl_gentle_damage == 2)
 905                                 {
 906                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 907                                         {
 908                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 909                                         }
 910                                 }
 911                                 else
 912                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 913
 914                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 915                         }
 916                         else
 917                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 918                 }
 919
 920                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 921                 {
 922                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 923                         {
 924                                 damage_blurpostprocess_x = 1;
 925                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 926                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 927                         }
 928                         else
 929                         {
 930                                 damage_blurpostprocess_x = 0;
 931                                 damage_blurpostprocess_y = 0;
 932                                 damage_blurpostprocess_z = 0;
 933                         }
 934                 }
 935         }
 936
 937         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 938         float e2 = (autocvar_hud_powerup != 0);
 939         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 940         {
 941                 // enable or disable rendering types if they are used or not
 942                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 943                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 944
 945                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 946                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 947                 {
 948                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 949                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 950                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 951                         {
 952                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 953                                 old_blurradius = blurradius;
 954                                 old_bluralpha = bluralpha;
 955                         }
 956                 }
 957                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 958                 {
 959                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 960                         old_blurradius = 0;
 961                         old_bluralpha = 0;
 962                 }
 963
 964                 // edge detection postprocess handling done second (used by hud_powerup)
 965                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 966                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 967                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 968
 969                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 970
 971                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 972                 {
 973                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 974                         {
 975                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 976                                 old_sharpen_intensity = sharpen_intensity;
 977                         }
 978                 }
 979                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 980                 {
 981                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 982                         old_sharpen_intensity = 0;
 983                 }
 984
 985                 if(cvar("r_glsl_postprocess") == 0)
 986                         cvar_set("r_glsl_postprocess", "2");
 987         }
 988         else if(cvar("r_glsl_postprocess") == 2)
 989                 cvar_set("r_glsl_postprocess", "0");
 990
 991         if(menu_visible)
 992                 menu_show();
 993
 994         /*if(gametype == MAPINFO_TYPE_CTF)
 995           {
 996           ctf_view();
 997           } else */
 998
 999         // draw 2D entities
1000         e = self;
1001         for(self = world; (self = nextent(self)); )
1002                 if(self.draw2d)
1003                         self.draw2d();
1004         self = e;
1005         Draw_ShowNames_All();
1006
1007         scoreboard_active = HUD_WouldDrawScoreboard();
1008
1009         hit_time = getstatf(STAT_HIT_TIME);
1010         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1011         {
1012                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1013                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1014
1015                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1016         }
1017         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1018         if(typehit_time > nextsound_typehit_time)
1019         {
1020                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1021                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1022
1023                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1024         }
1025
1026         //else
1027         {
1028                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1029                 {
1030                         if(getstati(STAT_FROZEN))
1031                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1032                         if(getstatf(STAT_REVIVE_PROGRESS))
1033                         {
1034                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1035                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1036                         }
1037                 }
1038
1039                 if(autocvar_r_letterbox == 0)
1040                         if(autocvar_viewsize < 120)
1041                                 CSQC_common_hud();
1042
1043                 // crosshair goes VERY LAST
1044                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1045                 {
1046                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1047                                 return;
1048
1049                         string wcross_style;
1050                         float wcross_alpha, wcross_resolution;
1051                         wcross_style = autocvar_crosshair;
1052                         if (wcross_style == "0")
1053                                 return;
1054                         wcross_resolution = autocvar_crosshair_size;
1055                         if (wcross_resolution == 0)
1056                                 return;
1057                         wcross_alpha = autocvar_crosshair_alpha;
1058                         if (wcross_alpha == 0)
1059                                 return;
1060
1061                         // TrueAim check
1062                         float shottype;
1063
1064                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1065                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1066                         wcross_origin_z = 0;
1067                         if(autocvar_crosshair_hittest)
1068                         {
1069                                 vector wcross_oldorigin;
1070                                 wcross_oldorigin = wcross_origin;
1071                                 shottype = TrueAimCheck();
1072                                 if(shottype == SHOTTYPE_HITWORLD)
1073                                 {
1074                                         v = wcross_origin - wcross_oldorigin;
1075                                         v_x /= vid_conwidth;
1076                                         v_y /= vid_conheight;
1077                                         if(vlen(v) > 0.01)
1078                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1079                                 }
1080                                 if(!autocvar_crosshair_hittest_showimpact)
1081                                         wcross_origin = wcross_oldorigin;
1082                         }
1083                         else
1084                                 shottype = SHOTTYPE_HITWORLD;
1085
1086                         vector wcross_color, wcross_size;
1087                         string wcross_wep, wcross_name;
1088                         float wcross_scale, wcross_blur;
1089
1090                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1091                                 e = get_weaponinfo(switchingweapon);
1092                                 if (e && e.netname != "")
1093                                 {
1094                                         wcross_wep = e.netname;
1095                                         if(autocvar_crosshair_per_weapon)
1096                                         {
1097                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1098                                                 if (wcross_resolution == 0)
1099                                                         return;
1100                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1101                                                 if (wcross_alpha == 0)
1102                                                         return;
1103
1104                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1105                                                 if(wcross_style == "" || wcross_style == "0")
1106                                                         wcross_style = wcross_wep;
1107                                         }
1108                                 }
1109                         }
1110                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1111                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1112                         else if(autocvar_crosshair_color_by_health)
1113                         {
1114                                 float x = getstati(STAT_HEALTH);
1115
1116                                 //x = red
1117                                 //y = green
1118                                 //z = blue
1119
1120                                 wcross_color_z = 0;
1121
1122                                 if(x > 200)
1123                                 {
1124                                         wcross_color_x = 0;
1125                                         wcross_color_y = 1;
1126                                 }
1127                                 else if(x > 150)
1128                                 {
1129                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1130                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1131                                 }
1132                                 else if(x > 100)
1133                                 {
1134                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1135                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1136                                         wcross_color_z = 1 - (x-100)*0.02;
1137                                 }
1138                                 else if(x > 50)
1139                                 {
1140                                         wcross_color_x = 1;
1141                                         wcross_color_y = 1;
1142                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1143                                 }
1144                                 else if(x > 20)
1145                                 {
1146                                         wcross_color_x = 1;
1147                                         wcross_color_y = (x-20)*90/27/100;
1148                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1149                                 }
1150                                 else
1151                                 {
1152                                         wcross_color_x = 1;
1153                                         wcross_color_y = 0;
1154                                 }
1155                         }
1156                         else
1157                                 wcross_color = stov(autocvar_crosshair_color);
1158
1159                         wcross_name = strcat("gfx/crosshair", wcross_style);
1160
1161                         if(autocvar_crosshair_effect_scalefade)
1162                         {
1163                                 wcross_scale = wcross_resolution;
1164                                 wcross_resolution = 1;
1165                         }
1166                         else
1167                         {
1168                                 wcross_scale = 1;
1169                         }
1170
1171                         if(autocvar_crosshair_pickup)
1172                         {
1173                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1174
1175                                 if(pickup_crosshair_time < stat_pickup_time)
1176                                 {
1177                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1178                                                 pickup_crosshair_size = 1;
1179
1180                                         pickup_crosshair_time = stat_pickup_time;
1181                                 }
1182
1183                                 if(pickup_crosshair_size > 0)
1184                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1185                                 else
1186                                         pickup_crosshair_size = 0;
1187
1188                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1189                         }
1190
1191                         if(autocvar_crosshair_hitindication)
1192                         {
1193                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1194
1195                                 if(hitindication_crosshair_time < hit_time)
1196                                 {
1197                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1198                                                 hitindication_crosshair_size = 1;
1199
1200                                         hitindication_crosshair_time = hit_time;
1201                                 }
1202
1203                                 if(hitindication_crosshair_size > 0)
1204                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1205                                 else
1206                                         hitindication_crosshair_size = 0;
1207
1208                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1209                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1210                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1211                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1212                         }
1213
1214                         if(shottype == SHOTTYPE_HITENEMY)
1215                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1216                         if(shottype == SHOTTYPE_HITTEAM)
1217                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1218
1219                         f = autocvar_crosshair_effect_speed;
1220                         if(f < 0)
1221                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1222                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1223                         {
1224                                 wcross_changedonetime = time + f;
1225                         }
1226                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1227                         {
1228                                 wcross_name_changestarttime = time;
1229                                 wcross_name_changedonetime = time + f;
1230                                 if(wcross_name_goal_prev_prev)
1231                                         strunzone(wcross_name_goal_prev_prev);
1232                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1233                                 wcross_name_goal_prev = strzone(wcross_name);
1234                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1235                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1236                                 wcross_resolution_goal_prev = wcross_resolution;
1237                         }
1238
1239                         wcross_scale_goal_prev = wcross_scale;
1240                         wcross_alpha_goal_prev = wcross_alpha;
1241                         wcross_color_goal_prev = wcross_color;
1242
1243                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1244                         {
1245                                 wcross_blur = 1;
1246                                 wcross_alpha *= 0.75;
1247                         }
1248                         else
1249                                 wcross_blur = 0;
1250                         // *_prev is at time-frametime
1251                         // * is at wcross_changedonetime+f
1252                         // what do we have at time?
1253                         if(time < wcross_changedonetime)
1254                         {
1255                                 f = frametime / (wcross_changedonetime - time + frametime);
1256                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1257                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1258                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1259                         }
1260
1261                         wcross_scale_prev = wcross_scale;
1262                         wcross_alpha_prev = wcross_alpha;
1263                         wcross_color_prev = wcross_color;
1264
1265                         wcross_scale *= 1 - autocvar__menu_alpha;
1266                         wcross_alpha *= 1 - autocvar__menu_alpha;
1267                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1268
1269                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1270                         {
1271                                 // crosshair rings for weapon stats
1272                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1273                                 {
1274                                         // declarations and stats
1275                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1276                                         string ring_image, ring_inner_image;
1277                                         vector ring_rgb, ring_inner_rgb;
1278
1279                                         ring_scale = autocvar_crosshair_ring_size;
1280
1281                                         float weapon_clipload, weapon_clipsize;
1282                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1283                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1284
1285                                         float nex_charge, nex_chargepool;
1286                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1287                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1288
1289                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1290                                                 nex_charge_movingavg = nex_charge;
1291
1292
1293                                         // handle the values
1294                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1295                                         {
1296                                                 if (nex_chargepool || use_nex_chargepool) {
1297                                                         use_nex_chargepool = 1;
1298                                                         ring_inner_value = nex_chargepool;
1299                                                 } else {
1300                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1301                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1302                                                 }
1303
1304                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1305                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1306                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1307
1308                                                 // draw the outer ring to show the current charge of the weapon
1309                                                 ring_value = nex_charge;
1310                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1311                                                 ring_rgb = wcross_color;
1312                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1313                                         }
1314                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1315                                         {
1316                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1317                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1318                                                 ring_rgb = wcross_color;
1319                                                 ring_image = "gfx/crosshair_ring.tga";
1320                                         }
1321                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1322                                         {
1323                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1324                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1325                                                 ring_rgb = wcross_color;
1326                                                 ring_image = "gfx/crosshair_ring.tga";
1327                                         }
1328
1329                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1330                                         {
1331                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1332                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1333                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1334                                                 ring_rgb = wcross_color;
1335
1336                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1337                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1338                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1339                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1340                                                 else
1341                                                         ring_image = "gfx/crosshair_ring.tga";
1342                                         }
1343
1344                                         // if in weapon switch animation, fade ring out/in
1345                                         if(g_weaponswitchdelay > 0)
1346                                         {
1347                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1348                                                 if(f > 0 && f < 2)
1349                                                         ring_alpha *= fabs(1 - f);
1350                                         }
1351
1352                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1353                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1354
1355                                         if (ring_value)
1356                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1357                                 }
1358
1359 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1360                                 do \
1361                                 { \
1362                                         if(wcross_blur > 0) \
1363                                         { \
1364                                                 for(i = -2; i <= 2; ++i) \
1365                                                 for(j = -2; j <= 2; ++j) \
1366                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1367                                         } \
1368                                         else \
1369                                         { \
1370                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1371                                         } \
1372                                 } \
1373                                 while(0)
1374
1375 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1376                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1377
1378 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1379                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1380
1381                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1382                                 {
1383                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1384                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1385                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1386                                         f = 1 - f;
1387                                 }
1388                                 else
1389                                 {
1390                                         f = 1;
1391                                 }
1392                                 wcross_name_alpha_goal_prev = f;
1393
1394                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1395                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1396
1397                                 if(autocvar_crosshair_dot)
1398                                 {
1399                                         vector wcross_color_old;
1400                                         wcross_color_old = wcross_color;
1401
1402                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1403                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1404
1405                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1406                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1407                                         wcross_color = wcross_color_old;
1408                                 }
1409                         }
1410                 }
1411                 else
1412                 {
1413                         wcross_scale_prev = 0;
1414                         wcross_alpha_prev = 0;
1415                         wcross_scale_goal_prev = 0;
1416                         wcross_alpha_goal_prev = 0;
1417                         wcross_changedonetime = 0;
1418                         if(wcross_name_goal_prev)
1419                                 strunzone(wcross_name_goal_prev);
1420                         wcross_name_goal_prev = string_null;
1421                         if(wcross_name_goal_prev_prev)
1422                                 strunzone(wcross_name_goal_prev_prev);
1423                         wcross_name_goal_prev_prev = string_null;
1424                         wcross_name_changestarttime = 0;
1425                         wcross_name_changedonetime = 0;
1426                         wcross_name_alpha_goal_prev = 0;
1427                         wcross_name_alpha_goal_prev_prev = 0;
1428                         wcross_resolution_goal_prev = 0;
1429                         wcross_resolution_goal_prev_prev = 0;
1430                 }
1431         }
1432
1433         if(NextFrameCommand)
1434         {
1435                 localcmd("\n", NextFrameCommand, "\n");
1436                 NextFrameCommand = string_null;
1437         }
1438
1439         // we must do this check AFTER a frame was rendered, or it won't work
1440         if(cs_project_is_b0rked == 0)
1441         {
1442                 string w0, h0;
1443                 w0 = ftos(autocvar_vid_conwidth);
1444                 h0 = ftos(autocvar_vid_conheight);
1445                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1446                 //setproperty(VF_FOV, '90 90 0');
1447                 setproperty(VF_ORIGIN, '0 0 0');
1448                 setproperty(VF_ANGLES, '0 0 0');
1449                 setproperty(VF_PERSPECTIVE, 1);
1450                 makevectors('0 0 0');
1451                 vector v1, v2;
1452                 cvar_set("vid_conwidth", "800");
1453                 cvar_set("vid_conheight", "600");
1454                 v1 = cs_project(v_forward);
1455                 cvar_set("vid_conwidth", "640");
1456                 cvar_set("vid_conheight", "480");
1457                 v2 = cs_project(v_forward);
1458                 if(v1 == v2)
1459                         cs_project_is_b0rked = 1;
1460                 else
1461                         cs_project_is_b0rked = -1;
1462                 cvar_set("vid_conwidth", w0);
1463                 cvar_set("vid_conheight", h0);
1464         }
1465
1466         if(autocvar__hud_configure)
1467                 HUD_Panel_Mouse();
1468
1469     if(hud && !intermission)
1470     {
1471         if(hud == HUD_SPIDERBOT)
1472             CSQC_SPIDER_HUD();
1473         else if(hud == HUD_WAKIZASHI)
1474             CSQC_WAKIZASHI_HUD();
1475         else if(hud == HUD_RAPTOR)
1476             CSQC_RAPTOR_HUD();
1477         else if(hud == HUD_BUMBLEBEE)
1478             CSQC_BUMBLE_HUD();
1479         else if(hud == HUD_BUMBLEBEE_GUN)
1480             CSQC_BUMBLE_GUN_HUD();
1481     }
1482
1483         cl_notice_run();
1484
1485         // let's reset the view back to normal for the end
1486         setproperty(VF_MIN, '0 0 0');
1487         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1488 }
1489
1490
1491 void CSQC_common_hud(void)
1492 {
1493     // do some accuracy var caching
1494     float i;
1495     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1496     {
1497         if(autocvar_accuracy_color_levels != acc_color_levels)
1498         {
1499             if(acc_color_levels)
1500                 strunzone(acc_color_levels);
1501             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1502             acc_levels = tokenize_console(acc_color_levels);
1503             if (acc_levels > MAX_ACCURACY_LEVELS)
1504                 acc_levels = MAX_ACCURACY_LEVELS;
1505
1506             for (i = 0; i < acc_levels; ++i)
1507                 acc_lev[i] = stof(argv(i)) / 100.0;
1508         }
1509         // let know that acc_col[] needs to be loaded
1510         acc_col[0] = '-1 0 0';
1511     }
1512
1513     HUD_Main(); // always run these functions for alpha checks
1514     HUD_DrawScoreboard();
1515
1516     if (scoreboard_active) // scoreboard/accuracy
1517         HUD_Reset();
1518     else if (intermission == 2) // map voting screen
1519     {
1520         HUD_FinaleOverlay();
1521         HUD_Reset();
1522     }
1523         /*
1524         switch(hud)
1525         {
1526                 case HUD_SPIDERBOT:
1527                         CSQC_SPIDER_HUD();
1528                         break;
1529
1530                 case HUD_WAKIZASHI:
1531                         CSQC_WAKIZASHI_HUD();
1532                         break;
1533
1534         case HUD_BUMBLEBEE:
1535             CSQC_BUMBLE_HUD();
1536             break;
1537         }
1538         */
1539 }
1540
1541
1542 // following vectors must be global to allow seamless switching between camera modes
1543 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1544 void CSQC_Demo_Camera()
1545 {
1546         float speed, attenuation, dimensions;
1547         vector tmp, delta;
1548
1549         if( autocvar_camera_reset || !camera_mode )
1550         {
1551                 camera_offset = '0 0 0';
1552                 current_angles = '0 0 0';
1553                 camera_direction = '0 0 0';
1554                 camera_offset_z += 30;
1555                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1556                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1557                 current_origin = view_origin;
1558                 current_camera_offset  = camera_offset;
1559                 cvar_set("camera_reset", "0");
1560                 camera_mode = CAMERA_CHASE;
1561         }
1562
1563         // Camera angles
1564         if( camera_roll )
1565                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1566
1567         if(autocvar_camera_look_player)
1568         {
1569                 vector dir;
1570                 float n;
1571
1572                 dir = normalize(view_origin - current_position);
1573                 n = mouse_angles_z;
1574                 mouse_angles = vectoangles(dir);
1575                 mouse_angles_x = mouse_angles_x * -1;
1576                 mouse_angles_z = n;
1577         }
1578         else
1579         {
1580                 tmp = getmousepos() * 0.1;
1581                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1582                 {
1583                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1584                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1585                 }
1586         }
1587
1588         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1589         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1590         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1591         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1592
1593         // Fix difference when angles don't have the same sign
1594         delta = '0 0 0';
1595         if(mouse_angles_y < -60 && current_angles_y > 60)
1596                 delta = '0 360 0';
1597         if(mouse_angles_y > 60 && current_angles_y < -60)
1598                 delta = '0 -360 0';
1599
1600         if(autocvar_camera_look_player)
1601                 attenuation = autocvar_camera_look_attenuation;
1602         else
1603                 attenuation = autocvar_camera_speed_attenuation;
1604
1605         attenuation = 1 / max(1, attenuation);
1606         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1607
1608         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1609         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1610         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1611         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1612
1613         // Camera position
1614         tmp = '0 0 0';
1615         dimensions = 0;
1616
1617         if( camera_direction_x )
1618         {
1619                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1620                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1621                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1622                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1623                 ++dimensions;
1624         }
1625
1626         if( camera_direction_y )
1627         {
1628                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1629                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1630                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1631                 ++dimensions;
1632         }
1633
1634         if( camera_direction_z )
1635         {
1636                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1637                 ++dimensions;
1638         }
1639
1640         if(autocvar_camera_free)
1641                 speed = autocvar_camera_speed_free;
1642         else
1643                 speed = autocvar_camera_speed_chase;
1644
1645         if(dimensions)
1646         {
1647                 speed = speed * sqrt(1 / dimensions);
1648                 camera_offset += tmp * speed;
1649         }
1650
1651         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1652
1653         // Camera modes
1654         if( autocvar_camera_free )
1655         {
1656                 if ( camera_mode == CAMERA_CHASE )
1657                 {
1658                         current_camera_offset = current_origin + current_camera_offset;
1659                         camera_offset = current_origin + camera_offset;
1660                 }
1661
1662                 camera_mode = CAMERA_FREE;
1663                 current_position = current_camera_offset;
1664         }
1665         else
1666         {
1667                 if ( camera_mode == CAMERA_FREE )
1668                 {
1669                         current_origin = view_origin;
1670                         camera_offset = camera_offset - current_origin;
1671                         current_camera_offset = current_camera_offset - current_origin;
1672                 }
1673
1674                 camera_mode = CAMERA_CHASE;
1675
1676                 if(autocvar_camera_chase_smoothly)
1677                         current_origin += (view_origin - current_origin) * attenuation;
1678                 else
1679                         current_origin = view_origin;
1680
1681                 current_position = current_origin + current_camera_offset;
1682         }
1683
1684         setproperty(VF_ANGLES, current_angles);
1685         setproperty(VF_ORIGIN, current_position);
1686 }