Merge branch 'master' into terencehill/cursormode
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 entity porto;
2 vector polyline[16];
3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
4 float DPCONTENTS_SOLID = 1; // blocks player movement
5 float DPCONTENTS_BODY = 32; // blocks player movement
6 float DPCONTENTS_CORPSE = 64; // blocks player movement
7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
8 void Porto_Draw()
9 {
10         vector p, dir, ang, q, nextdir;
11         float idx, portal_number, portal1_idx;
12
13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
14                 return;
15         if(intermission == 1)
16                 return;
17         if(intermission == 2)
18                 return;
19         if (getstati(STAT_HEALTH) <= 0)
20                 return;
21
22         dir = view_forward;
23
24         if(angles_held_status)
25         {
26                 makevectors(angles_held);
27                 dir = v_forward;
28         }
29
30         p = view_origin;
31
32         polyline[0] = p;
33         idx = 1;
34         portal_number = 0;
35         nextdir = dir;
36
37         for(;;)
38         {
39                 dir = nextdir;
40                 traceline(p, p + 65536 * dir, TRUE, porto);
41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
42                         return;
43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
44                 p = trace_endpos;
45                 polyline[idx] = p;
46                 ++idx;
47                 if(idx >= 16)
48                         return;
49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
50                         continue;
51                 ++portal_number;
52                 ang = vectoangles2(trace_plane_normal, dir);
53                 ang_x = -ang_x;
54                 makevectors(ang);
55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
56                         return;
57                 if(portal_number == 1)
58                         portal1_idx = idx;
59                 if(portal_number >= 2)
60                         break;
61         }
62
63         while(idx >= 2)
64         {
65                 p = polyline[idx-2];
66                 q = polyline[idx-1];
67                 if(idx == 2)
68                         p = p - view_up * 16;
69                 if(idx-1 >= portal1_idx)
70                 {
71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
72                 }
73                 else
74                 {
75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
76                 }
77                 --idx;
78         }
79 }
80
81 void Porto_Init()
82 {
83         porto = spawn();
84         porto.classname = "porto";
85         porto.draw = Porto_Draw;
86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
87 }
88
89 float drawtime;
90 float avgspeed;
91 vector GetCurrentFov(float fov)
92 {
93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
94         float velocityzoom, curspeed;
95
96         zoomsensitivity = autocvar_cl_zoomsensitivity;
97         zoomfactor = autocvar_cl_zoomfactor;
98         if(zoomfactor < 1 || zoomfactor > 16)
99                 zoomfactor = 2.5;
100         zoomspeed = autocvar_cl_zoomspeed;
101         if(zoomspeed >= 0)
102                 if(zoomspeed < 0.5 || zoomspeed > 16)
103                         zoomspeed = 3.5;
104
105         zoomdir = button_zoom;
106         if(hud == HUD_NORMAL)
107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
108                 zoomdir += button_attack2;
109         if(spectatee_status > 0 || isdemo())
110         {
111                 if(spectatorbutton_zoom)
112                 {
113                         if(zoomdir)
114                                 zoomdir = 0;
115                         else
116                                 zoomdir = 1;
117                 }
118                 // fteqcc failed twice here already, don't optimize this
119         }
120
121         if(zoomdir)
122                 zoomin_effect = 0;
123
124         if(zoomin_effect || camera_active)
125         {
126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
127         }
128         else
129         {
130                 if(zoomspeed < 0) // instant zoom
131                 {
132                         if(zoomdir)
133                                 current_viewzoom = 1 / zoomfactor;
134                         else
135                                 current_viewzoom = 1;
136                 }
137                 else
138                 {
139                         if(zoomdir)
140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
141                         else
142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
143                 }
144         }
145
146         if(almost_equals(current_viewzoom, 1))
147                 current_zoomfraction = 0;
148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
149                 current_zoomfraction = 1;
150         else
151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
152
153         if(zoomsensitivity < 1)
154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
155         else
156                 setsensitivityscale(1);
157                 
158         makevectors(view_angles);
159
160         if(autocvar_cl_velocityzoom)
161         {
162                 switch(autocvar_cl_velocityzoom_type)
163                 {
164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
165                         case 2: curspeed = (v_forward * pmove_vel); break;
166                         case 1: default: curspeed = vlen(pmove_vel); break;
167                 }
168                 
169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
172                 
173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
174         }
175         else
176                 velocityzoom = 1;
177
178         float frustumx, frustumy, fovx, fovy;
179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
183
184         return '1 0 0' * fovx + '0 1 0' * fovy;
185 }
186
187 // this function must match W_SetupShot!
188 float zoomscript_caught;
189
190 vector wcross_origin;
191 float wcross_scale_prev, wcross_alpha_prev;
192 vector wcross_color_prev;
193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
194 vector wcross_color_goal_prev;
195 float wcross_changedonetime;
196
197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
199 float wcross_name_changestarttime, wcross_name_changedonetime;
200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
201 entity trueaim;
202 entity trueaim_rifle;
203
204 #define SHOTTYPE_HITTEAM 1
205 #define SHOTTYPE_HITOBSTRUCTION 2
206 #define SHOTTYPE_HITWORLD 3
207 #define SHOTTYPE_HITENEMY 4
208
209 void TrueAim_Init()
210 {
211         trueaim = spawn();
212         trueaim.classname = "trueaim";
213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
214         trueaim_rifle = spawn();
215         trueaim_rifle.classname = "trueaim_rifle";
216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
217 }
218
219 float EnemyHitCheck()
220 {
221         float t;
222         wcross_origin = project_3d_to_2d(trace_endpos);
223         wcross_origin_z = 0;
224         if(trace_networkentity < 1)
225                 return SHOTTYPE_HITWORLD;
226         if(trace_networkentity > maxclients)
227                 return SHOTTYPE_HITWORLD;
228         t = GetPlayerColor(trace_networkentity - 1);
229         if(teamplay)
230                 if(t == myteam)
231                         return SHOTTYPE_HITTEAM;
232         if(t == COLOR_SPECTATOR)
233                 return SHOTTYPE_HITWORLD;
234         return SHOTTYPE_HITENEMY;
235 }
236
237 float TrueAimCheck()
238 {
239         float nudge = 1; // added to traceline target and subtracted from result
240         vector vecs, trueaimpoint, w_shotorg;
241         vector mi, ma, dv;
242         float shottype;
243         entity ta;
244         float mv;
245
246         mi = ma = '0 0 0';
247         ta = trueaim;
248         mv = MOVE_NOMONSTERS;
249
250         switch(activeweapon)
251         {
252                 case WEP_TUBA: // no aim
253                 case WEP_PORTO: // shoots from eye
254                 case WEP_HOOK: // no trueaim
255                 case WEP_GRENADE_LAUNCHER: // toss curve
256                         return SHOTTYPE_HITWORLD;
257                 case WEP_NEX:
258                 case WEP_MINSTANEX:
259                         mv = MOVE_NORMAL;
260                         break;
261                 case WEP_RIFLE:
262                         ta = trueaim_rifle;
263                         mv = MOVE_NORMAL;
264                         if(zoomscript_caught)
265                         {
266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
267                                 return EnemyHitCheck();
268                         }
269                         break;
270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
271                         mi = '-3 -3 -3';
272                         ma = '3 3 3';
273                         break;
274                 case WEP_FIREBALL: // projectile has a size!
275                         mi = '-16 -16 -16';
276                         ma = '16 16 16';
277                         break;
278                 case WEP_SEEKER: // projectile has a size!
279                         mi = '-2 -2 -2';
280                         ma = '2 2 2';
281                         break;
282                 case WEP_ELECTRO: // projectile has a size!
283                         mi = '0 0 -3';
284                         ma = '0 0 -3';
285                         break;
286         }
287
288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
289
290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
291         trueaimpoint = trace_endpos;
292
293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
295
296         if(vecs_x > 0)
297                 vecs_y = -vecs_y;
298         else
299                 vecs = '0 0 0';
300
301         dv = view_right * vecs_y + view_up * vecs_z;
302         w_shotorg = view_origin + dv;
303
304         // now move the vecs forward as much as requested if possible
305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
306         w_shotorg = trace_endpos - view_forward * nudge;
307
308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
309         shottype = EnemyHitCheck();
310         if(shottype != SHOTTYPE_HITWORLD)
311                 return shottype;
312
313 #if 0
314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
315         // or rather, I know why, but see no fix
316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
318                 return SHOTTYPE_HITOBSTRUCTION;
319 #endif
320
321         return SHOTTYPE_HITWORLD;
322 }
323
324 void CSQC_common_hud(void);
325
326 void PostInit(void);
327 void CSQC_Demo_Camera();
328 float HUD_WouldDrawScoreboard();
329 float camera_mode;
330 float reticle_type;
331 string NextFrameCommand;
332 void CSQC_SPIDER_HUD();
333 void CSQC_RAPTOR_HUD();
334
335 vector freeze_org, freeze_ang;
336 entity nightvision_noise, nightvision_noise2;
337
338 #define MAX_TIME_DIFF 5
339 float pickup_crosshair_time, pickup_crosshair_size;
340 float hit_time, typehit_time;
341 float nextsound_hit_time, nextsound_typehit_time;
342 float hitindication_crosshair_time, hitindication_crosshair_size;
343 float use_nex_chargepool;
344
345 float myhealth, myhealth_prev;
346 float myhealth_flash;
347
348 float old_blurradius, old_bluralpha;
349 float old_sharpen_intensity;
350
351 vector myhealth_gentlergb;
352
353 float contentavgalpha, liquidalpha_prev;
354 vector liquidcolor_prev;
355
356 float eventchase_current_distance;
357
358 vector damage_blurpostprocess, content_blurpostprocess;
359
360 float checkfail[16];
361
362 void CSQC_UpdateView(float w, float h)
363 {
364         entity e;
365         float fov;
366         float f, i, j;
367         vector v;
368         vector vf_size, vf_min;
369         float a;
370         hud = getstati(STAT_HUD);
371
372         button_attack2 = (input_buttons & BUTTON_3);
373         button_zoom = (input_buttons & BUTTON_4);
374
375         // FIXME do we need this hack?
376         if(isdemo())
377         {
378                 // in demos, input_buttons do not work
379                 button_zoom = (autocvar__togglezoom == "-");
380         }
381
382 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
383         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
384         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
385         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
386         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
387         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
388         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
389         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
390
391         vf_size = R_SetView3fv(VF_SIZE);
392         vf_min = R_SetView3fv(VF_MIN);
393         vid_width = vf_size_x;
394         vid_height = vf_size_y;
395
396         vector reticle_pos, reticle_size;
397         vector splash_pos, splash_size;
398
399         WaypointSprite_Load();
400
401         if(spectatee_status)
402                 myteam = GetPlayerColor(spectatee_status - 1);
403         else
404                 myteam = GetPlayerColor(player_localentnum - 1);
405
406         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
407
408         // event chase camera
409         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
410         {
411                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
412                 {
413                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
414                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
415                         
416                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
417                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
418                         if(!autocvar_chase_active)
419                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
420
421                         // make the camera smooth back
422                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
423                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
424                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
425                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
426
427                         vector eventchase_target_origin;
428                         makevectors(view_angles);
429                         // pass 1, used to check where the camera would go and obtain the trace_fraction
430                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
431                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
432                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
433                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
434                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
435                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
436
437                         R_SetView(VF_ORIGIN, trace_endpos);
438                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
439                 }
440                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
441                 {
442                         cvar_set("chase_active", "0");
443                         eventchase_current_distance = 0; // start from 0 next time
444                 }
445         }
446         
447         // do lockview after event chase camera so that it still applies whenever necessary.
448         if(autocvar_cl_lockview || intermission > 1)
449         {
450                 R_SetView(VF_ORIGIN, freeze_org);
451                 R_SetView(VF_ANGLES, freeze_ang);
452         }
453         else
454         {
455                 freeze_org = R_SetView3fv(VF_ORIGIN);
456                 freeze_ang = R_SetView3fv(VF_ANGLES);
457         }
458
459         WarpZone_FixView();
460         //WarpZone_FixPMove();
461
462         // Render the Scene
463         view_origin = R_SetView3fv(VF_ORIGIN);
464         view_angles = R_SetView3fv(VF_ANGLES);
465         makevectors(view_angles);
466         view_forward = v_forward;
467         view_right = v_right;
468         view_up = v_up;
469
470 #ifdef BLURTEST
471         if(time > blurtest_time0 && time < blurtest_time1)
472         {
473                 float r, t;
474
475                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
476                 r = t * blurtest_radius;
477                 f = 1 / pow(t, blurtest_power) - 1;
478
479                 cvar_set("r_glsl_postprocess", "1");
480                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
481         }
482         else
483         {
484                 cvar_set("r_glsl_postprocess", "0");
485                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
486         }
487 #endif
488
489         TargetMusic_Advance();
490         Fog_Force();
491
492         if(drawtime == 0)
493                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
494         else
495                 drawframetime = bound(0.000001, time - drawtime, 1);
496         drawtime = time;
497
498         // watch for gametype changes here...
499         // in ParseStuffCMD the cmd isn't executed yet :/
500         // might even be better to add the gametype to TE_CSQC_INIT...?
501         if(!postinit)
502                 PostInit();
503
504         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
505         {
506                 if(calledhooks & HOOK_START)
507                 {
508                         localcmd("\ncl_hook_gameend\n");
509                         calledhooks |= HOOK_END;
510                 }
511         }
512         
513   Announcer();
514
515         fov = autocvar_fov;
516         if(fov <= 59.5)
517         {
518                 if(!zoomscript_caught)
519                 {
520                         localcmd("+button9\n");
521                         zoomscript_caught = 1;
522                 }
523         }
524         else
525         {
526                 if(zoomscript_caught)
527                 {
528                         localcmd("-button9\n");
529                         zoomscript_caught = 0;
530                 }
531         }
532
533         ColorTranslateMode = autocvar_cl_stripcolorcodes;
534
535         // next WANTED weapon (for HUD)
536         switchweapon = getstati(STAT_SWITCHWEAPON);
537
538         // currently switching-to weapon (for crosshair)
539         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
540
541         // actually active weapon (for zoom)
542         activeweapon = getstati(STAT_ACTIVEWEAPON);
543
544         f = (serverflags & SERVERFLAG_TEAMPLAY);
545         if(f != teamplay)
546         {
547                 teamplay = f;
548                 HUD_InitScores();
549         }
550
551         if(last_switchweapon != switchweapon) {
552                 weapontime = time;
553                 last_switchweapon = switchweapon;
554         }
555         if(last_activeweapon != activeweapon) {
556                 last_activeweapon = activeweapon;
557
558                 e = get_weaponinfo(activeweapon);
559                 if(e.netname != "")
560                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
561                 else
562                         localcmd("\ncl_hook_activeweapon none\n");
563         }
564
565         // ALWAYS Clear Current Scene First
566         R_ClearScene();
567 #ifdef WORKAROUND_XON010
568         if(checkextension("DP_CSQC_ROTATEMOVES"))
569         {
570 #endif
571         R_SetView(VF_ORIGIN, view_origin);
572         R_SetView(VF_ANGLES, view_angles);
573 #ifdef WORKAROUND_XON010
574         }
575 #endif
576
577         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
578         R_SetView(VF_SIZE, vf_size);
579         R_SetView(VF_MIN, vf_min);
580
581         // Assign Standard Viewflags
582         // Draw the World (and sky)
583         R_SetView(VF_DRAWWORLD, 1);
584
585         // Set the console size vars
586         vid_conwidth = autocvar_vid_conwidth;
587         vid_conheight = autocvar_vid_conheight;
588         vid_pixelheight = autocvar_vid_pixelheight;
589
590         R_SetView(VF_FOV, GetCurrentFov(fov));
591
592         // Camera for demo playback
593         if(camera_active)
594         {
595                 if(autocvar_camera_enable)
596                         CSQC_Demo_Camera();
597                 else
598                 {
599                         cvar_set("chase_active", ftos(chase_active_backup));
600                         cvar_set("cl_demo_mousegrab", "0");
601                         camera_active = FALSE;
602                 }
603         }
604 #ifdef CAMERATEST
605         else if(autocvar_camera_enable)
606 #else
607         else if(autocvar_camera_enable && isdemo())
608 #endif
609         {
610                 // Enable required Darkplaces cvars
611                 chase_active_backup = autocvar_chase_active;
612                 cvar_set("chase_active", "2");
613                 cvar_set("cl_demo_mousegrab", "1");
614                 camera_active = TRUE;
615                 camera_mode = FALSE;
616         }
617
618         // Draw the Crosshair
619         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
620
621         // Draw the Engine Status Bar (the default Quake HUD)
622         R_SetView(VF_DRAWENGINEHUD, 0);
623
624         // Update the mouse position
625         /*
626            mousepos_x = vid_conwidth;
627            mousepos_y = vid_conheight;
628            mousepos = mousepos*0.5 + getmousepos();
629          */
630
631         e = self;
632         for(self = world; (self = nextent(self)); )
633                 if(self.draw)
634                         self.draw();
635         self = e;
636
637         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
638         R_RenderScene();
639
640         // now switch to 2D drawing mode by calling a 2D drawing function
641         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
642         // next R_RenderScene call
643         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
644
645         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
646         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
647         {
648                 // apply night vision effect
649                 vector rgb, tc_00, tc_01, tc_10, tc_11;
650
651                 if(!nightvision_noise)
652                 {
653                         nightvision_noise = spawn();
654                         nightvision_noise.classname = "nightvision_noise";
655                 }
656                 if(!nightvision_noise2)
657                 {
658                         nightvision_noise2 = spawn();
659                         nightvision_noise2.classname = "nightvision_noise2";
660                 }
661
662                 // color tint in yellow
663                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
664
665                 // draw BG
666                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
667                 rgb = '1 1 1';
668                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
669                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
670                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
671                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
672                 tc_11 = tc_01 + tc_10 - tc_00;
673                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
674                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
675                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
676                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
677                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
678                 R_EndPolygon();
679
680                 // draw FG
681                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
682                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
683                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
684                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
685                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
686                 tc_11 = tc_01 + tc_10 - tc_00;
687                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
688                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
689                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
690                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
691                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
692                 R_EndPolygon();
693         }
694         
695         // Draw the aiming reticle for weapons that use it
696         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
697         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
698         // the view to go back to normal, so reticle_type would become 0 as we fade out)
699         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
700                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
701         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
702                 reticle_type = 2; // nex zoom
703         else if(button_zoom || zoomscript_caught)
704                 reticle_type = 1; // normal zoom
705         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
706                 reticle_type = 2; // nex zoom
707     
708         if(reticle_type && autocvar_cl_reticle)
709         {
710                 if(autocvar_cl_reticle_stretch)
711                 {
712                         reticle_size_x = vid_conwidth;
713                         reticle_size_y = vid_conheight;
714                         reticle_pos_x = 0;
715                         reticle_pos_y = 0;
716                 }
717                 else
718                 {
719                         reticle_size_x = max(vid_conwidth, vid_conheight);
720                         reticle_size_y = max(vid_conwidth, vid_conheight);
721                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
722                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
723                 }
724
725                 f = current_zoomfraction;
726                 if(zoomscript_caught)
727                         f = 1;
728                 if(autocvar_cl_reticle_item_normal)
729                 {
730                         if(reticle_type == 1 && f)
731                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
732                 }
733                 if(autocvar_cl_reticle_item_nex)
734                 {
735                         if(reticle_type == 2 && f)
736                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
737                 }
738         }
739
740
741         // improved polyblend
742         vector rgb;
743         if(autocvar_hud_contents)
744         {
745                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
746                 vector liquidcolor;
747
748                 switch(pointcontents(view_origin))
749                 {
750                         case CONTENT_WATER:
751                                 liquidalpha = autocvar_hud_contents_water_alpha;
752                                 liquidcolor = stov(autocvar_hud_contents_water_color);
753                                 incontent = 1;
754                                 break;
755
756                         case CONTENT_LAVA:
757                                 liquidalpha = autocvar_hud_contents_lava_alpha;
758                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
759                                 incontent = 1;
760                                 break;
761
762                         case CONTENT_SLIME:
763                                 liquidalpha = autocvar_hud_contents_slime_alpha;
764                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
765                                 incontent = 1;
766                                 break;
767
768                         default:
769                                 liquidalpha = 0;
770                                 liquidcolor = '0 0 0';
771                                 incontent = 0;
772                                 break;
773                 }
774
775                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
776                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
777                         contentfadetime = autocvar_hud_contents_fadeintime;
778                         liquidalpha_prev = liquidalpha;
779                         liquidcolor_prev = liquidcolor;
780                 }
781                 else
782                         contentfadetime = autocvar_hud_contents_fadeouttime;
783
784                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
785                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
786
787                 if(contentavgalpha)
788                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
789
790                 if(autocvar_hud_postprocessing)
791                 {
792                         if(autocvar_hud_contents_blur && contentavgalpha)
793                         {
794                                 content_blurpostprocess_x = 1;
795                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
796                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
797                         }
798                         else
799                         {
800                                 content_blurpostprocess_x = 0;
801                                 content_blurpostprocess_y = 0;
802                                 content_blurpostprocess_z = 0;
803                         }
804                 }
805         }
806         
807         if(autocvar_hud_damage)
808         {
809                 splash_size_x = max(vid_conwidth, vid_conheight);
810                 splash_size_y = max(vid_conwidth, vid_conheight);
811                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
812                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
813
814                 float myhealth_flash_temp;
815                 myhealth = getstati(STAT_HEALTH);
816
817                 // fade out
818                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
819                 // add new damage
820                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
821
822                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
823                 pain_threshold = autocvar_hud_damage_pain_threshold;
824                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
825                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
826
827                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
828                 {
829                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
830                 }
831
832                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
833
834                 if(myhealth_prev < 1)
835                 {
836                         if(myhealth >= 1)
837                         {
838                                 myhealth_flash = 0; // just spawned, clear the flash immediately
839                                 myhealth_flash_temp = 0;
840                         }
841                         else
842                         {
843                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
844                         }
845                 }
846
847                 if(spectatee_status == -1 || intermission)
848                 {
849                         myhealth_flash = 0; // observing, or match ended
850                         myhealth_flash_temp = 0;
851                 }
852
853                 myhealth_prev = myhealth;
854
855                 // IDEA: change damage color/picture based on player model for robot/alien species?
856                 // pro: matches model better
857                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
858                 // maybe different reddish pics?
859                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
860                 {
861                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
862                         {
863                                 if(autocvar_cl_gentle_damage == 2)
864                                 {
865                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
866                                         {
867                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
868                                         }
869                                 }
870                                 else
871                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
872
873                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
874                         }
875                         else
876                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
877                 }
878
879                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
880                 {
881                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
882                         {
883                                 damage_blurpostprocess_x = 1;
884                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
885                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
886                         }
887                         else
888                         {
889                                 damage_blurpostprocess_x = 0;
890                                 damage_blurpostprocess_y = 0;
891                                 damage_blurpostprocess_z = 0;
892                         }
893                 }
894         }
895
896         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
897         {
898                 // enable or disable rendering types if they are used or not
899                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
900                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
901                 
902                 // blur postprocess handling done first (used by hud_damage and hud_contents)
903                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
904                 {
905                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
906                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
907                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
908                         {
909                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
910                                 old_blurradius = blurradius;
911                                 old_bluralpha = bluralpha;
912                         }
913                 }
914                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
915                 {
916                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
917                         old_blurradius = 0;
918                         old_bluralpha = 0;
919                 }
920
921                 // edge detection postprocess handling done second (used by hud_powerup) 
922                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
923                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
924                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
925                 
926                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
927                 
928                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
929                 {
930                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
931                         {
932                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
933                                 old_sharpen_intensity = sharpen_intensity;
934                         }
935                 }
936                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
937                 {
938                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
939                         old_sharpen_intensity = 0;
940                 }
941         }
942
943         if(menu_visible)
944                 menu_show();
945
946         /*if(gametype == GAME_CTF)
947           {
948           ctf_view();
949           } else */
950
951         // draw 2D entities
952         e = self;
953         for(self = world; (self = nextent(self)); )
954                 if(self.draw2d)
955                         self.draw2d();
956         self = e;
957         Draw_ShowNames_All();
958
959         scoreboard_active = HUD_WouldDrawScoreboard();
960
961         hit_time = getstatf(STAT_HIT_TIME);
962         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
963         {
964                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
965                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
966                         
967                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
968         }
969         typehit_time = getstatf(STAT_TYPEHIT_TIME);
970         if(typehit_time > nextsound_typehit_time) 
971         {
972                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
973                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
974                         
975                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
976         }
977
978         //else
979         {
980                 if(gametype == GAME_FREEZETAG)
981                 {
982                         if(getstati(STAT_FROZEN))
983                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
984                         if(getstatf(STAT_REVIVE_PROGRESS))
985                         {
986                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
987                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
988                         }
989                 }
990
991                 if(autocvar_r_letterbox == 0)
992                         if(autocvar_viewsize < 120)
993                                 CSQC_common_hud();
994
995                 // crosshair goes VERY LAST
996                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
997                         string wcross_style;
998                         float wcross_alpha, wcross_resolution;
999                         wcross_style = autocvar_crosshair;
1000                         if (wcross_style == "0")
1001                                 return;
1002                         wcross_resolution = autocvar_crosshair_size;
1003                         if (wcross_resolution == 0)
1004                                 return;
1005                         wcross_alpha = autocvar_crosshair_alpha;
1006                         if (wcross_alpha == 0)
1007                                 return;
1008
1009                         // TrueAim check
1010                         float shottype;
1011
1012                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1013                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1014                         wcross_origin_z = 0;
1015                         if(autocvar_crosshair_hittest)
1016                         {
1017                                 vector wcross_oldorigin;
1018                                 wcross_oldorigin = wcross_origin;
1019                                 shottype = TrueAimCheck();
1020                                 if(shottype == SHOTTYPE_HITWORLD)
1021                                 {
1022                                         v = wcross_origin - wcross_oldorigin;
1023                                         v_x /= vid_conwidth;
1024                                         v_y /= vid_conheight;
1025                                         if(vlen(v) > 0.01)
1026                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1027                                 }
1028                                 if(!autocvar_crosshair_hittest_showimpact)
1029                                         wcross_origin = wcross_oldorigin;
1030                         }
1031                         else
1032                                 shottype = SHOTTYPE_HITWORLD;
1033
1034                         vector wcross_color, wcross_size;
1035                         string wcross_wep, wcross_name;
1036                         float wcross_scale, wcross_blur;
1037
1038                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1039                                 e = get_weaponinfo(switchingweapon);
1040                                 if (e && e.netname != "")
1041                                 {
1042                                         wcross_wep = e.netname;
1043                                         if(autocvar_crosshair_per_weapon)
1044                                         {
1045                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1046                                                 if (wcross_resolution == 0)
1047                                                         return;
1048                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1049                                                 if (wcross_alpha == 0)
1050                                                         return;
1051
1052                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1053                                                 if(wcross_style == "" || wcross_style == "0")
1054                                                         wcross_style = wcross_wep;
1055                                         }
1056                                 }
1057                         }
1058                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1059                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1060                         else if(autocvar_crosshair_color_by_health)
1061                         {
1062                                 float x = getstati(STAT_HEALTH);
1063
1064                                 //x = red
1065                                 //y = green
1066                                 //z = blue
1067
1068                                 wcross_color_z = 0;
1069
1070                                 if(x > 200)
1071                                 {
1072                                         wcross_color_x = 0;
1073                                         wcross_color_y = 1;
1074                                 }
1075                                 else if(x > 150)
1076                                 {
1077                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1078                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1079                                 }
1080                                 else if(x > 100)
1081                                 {
1082                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1083                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1084                                         wcross_color_z = 1 - (x-100)*0.02;
1085                                 }
1086                                 else if(x > 50)
1087                                 {
1088                                         wcross_color_x = 1;
1089                                         wcross_color_y = 1;
1090                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1091                                 }
1092                                 else if(x > 20)
1093                                 {
1094                                         wcross_color_x = 1;
1095                                         wcross_color_y = (x-20)*90/27/100;
1096                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1097                                 }
1098                                 else
1099                                 {
1100                                         wcross_color_x = 1;
1101                                         wcross_color_y = 0;
1102                                 }
1103                         }
1104                         else
1105                                 wcross_color = stov(autocvar_crosshair_color);
1106
1107                         wcross_name = strcat("gfx/crosshair", wcross_style);
1108
1109                         if(autocvar_crosshair_effect_scalefade)
1110                         {
1111                                 wcross_scale = wcross_resolution;
1112                                 wcross_resolution = 1;
1113                         }
1114                         else
1115                         {
1116                                 wcross_scale = 1;
1117                         }
1118
1119                         if(autocvar_crosshair_pickup)
1120                         {
1121                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1122                                 
1123                                 if(pickup_crosshair_time < stat_pickup_time)
1124                                 {
1125                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1126                                                 pickup_crosshair_size = 1;
1127                                                 
1128                                         pickup_crosshair_time = stat_pickup_time;
1129                                 }
1130
1131                                 if(pickup_crosshair_size > 0)
1132                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1133                                 else
1134                                         pickup_crosshair_size = 0;
1135
1136                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1137                         }
1138
1139                         if(autocvar_crosshair_hitindication)
1140                         {
1141                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1142                                 if(hitindication_crosshair_time < hit_time)
1143                                 {
1144                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1145                                                 hitindication_crosshair_size = 1;
1146                                                 
1147                                         hitindication_crosshair_time = hit_time;
1148                                 }
1149
1150                                 if(hitindication_crosshair_size > 0)
1151                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1152                                 else
1153                                         hitindication_crosshair_size = 0;
1154
1155                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1156                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1157                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1158                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1159                         }
1160
1161                         if(shottype == SHOTTYPE_HITENEMY)
1162                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1163                         if(shottype == SHOTTYPE_HITTEAM)
1164                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1165
1166                         f = autocvar_crosshair_effect_speed;
1167                         if(f < 0)
1168                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1169                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1170                         {
1171                                 wcross_changedonetime = time + f;
1172                         }
1173                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1174                         {
1175                                 wcross_name_changestarttime = time;
1176                                 wcross_name_changedonetime = time + f;
1177                                 if(wcross_name_goal_prev_prev)
1178                                         strunzone(wcross_name_goal_prev_prev);
1179                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1180                                 wcross_name_goal_prev = strzone(wcross_name);
1181                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1182                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1183                                 wcross_resolution_goal_prev = wcross_resolution;
1184                         }
1185
1186                         wcross_scale_goal_prev = wcross_scale;
1187                         wcross_alpha_goal_prev = wcross_alpha;
1188                         wcross_color_goal_prev = wcross_color;
1189
1190                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1191                         {
1192                                 wcross_blur = 1;
1193                                 wcross_alpha *= 0.75;
1194                         }
1195                         else
1196                                 wcross_blur = 0;
1197                         // *_prev is at time-frametime
1198                         // * is at wcross_changedonetime+f
1199                         // what do we have at time?
1200                         if(time < wcross_changedonetime)
1201                         {
1202                                 f = frametime / (wcross_changedonetime - time + frametime);
1203                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1204                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1205                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1206                         }
1207
1208                         wcross_scale_prev = wcross_scale;
1209                         wcross_alpha_prev = wcross_alpha;
1210                         wcross_color_prev = wcross_color;
1211
1212                         wcross_scale *= 1 - autocvar__menu_alpha;
1213                         wcross_alpha *= 1 - autocvar__menu_alpha;
1214                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1215
1216                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1217                         {
1218                                 // crosshair rings for weapon stats
1219                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1220                                 {
1221                                         // declarations and stats
1222                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1223                                         string ring_image, ring_inner_image;
1224                                         vector ring_rgb, ring_inner_rgb;
1225
1226                                         ring_scale = autocvar_crosshair_ring_size;
1227
1228                                         float weapon_clipload, weapon_clipsize;
1229                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1230                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1231
1232                                         float nex_charge, nex_chargepool;
1233                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1234                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1235
1236                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1237                                                 nex_charge_movingavg = nex_charge;
1238
1239
1240                                         // handle the values
1241                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1242                                         {
1243                                                 if (nex_chargepool || use_nex_chargepool) { 
1244                                                         use_nex_chargepool = 1; 
1245                                                         ring_inner_value = nex_chargepool;
1246                                                 } else { 
1247                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1248                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1); 
1249                                                 }
1250
1251                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1252                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1253                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1254
1255                                                 // draw the outer ring to show the current charge of the weapon
1256                                                 ring_value = nex_charge;
1257                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1258                                                 ring_rgb = wcross_color;
1259                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1260                                         }
1261                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer) 
1262                                         {
1263                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1264                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1265                                                 ring_rgb = wcross_color;
1266                                                 ring_image = "gfx/crosshair_ring.tga";
1267                                         }
1268                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1269                                         {
1270                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1271                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1272                                                 ring_rgb = wcross_color;
1273                                                 ring_image = "gfx/crosshair_ring.tga";
1274                                         }
1275
1276                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring 
1277                                         {
1278                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1279                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1280                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1281                                                 ring_rgb = wcross_color;
1282
1283                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1284                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1285                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1286                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1287                                                 else
1288                                                         ring_image = "gfx/crosshair_ring.tga";
1289                                         }
1290
1291                                         // if in weapon switch animation, fade ring out/in
1292                                         if(g_weaponswitchdelay > 0)
1293                                         {
1294                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1295                                                 if(f > 0 && f < 2)
1296                                                         ring_alpha *= fabs(1 - f);
1297                                         }
1298
1299                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1300                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1301
1302                                         if (ring_value)
1303                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1304                                 }
1305
1306 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1307                                 do \
1308                                 { \
1309                                         if(wcross_blur > 0) \
1310                                         { \
1311                                                 for(i = -2; i <= 2; ++i) \
1312                                                 for(j = -2; j <= 2; ++j) \
1313                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1314                                         } \
1315                                         else \
1316                                         { \
1317                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1318                                         } \
1319                                 } \
1320                                 while(0)
1321
1322 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1323                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1324
1325 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1326                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1327
1328                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1329                                 {
1330                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1331                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1332                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1333                                         f = 1 - f;
1334                                 }
1335                                 else
1336                                 {
1337                                         f = 1;
1338                                 }
1339                                 wcross_name_alpha_goal_prev = f;
1340
1341                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1342                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1343
1344                                 if(autocvar_crosshair_dot)
1345                                 {
1346                                         vector wcross_color_old;
1347                                         wcross_color_old = wcross_color;
1348                                         if(autocvar_crosshair_dot_color != "0")
1349                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1350                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1351                                         // FIXME why don't we use wcross_alpha here?
1352                                         wcross_color = wcross_color_old;
1353                                 }
1354                         }
1355                 }
1356                 else
1357                 {
1358                         wcross_scale_prev = 0;
1359                         wcross_alpha_prev = 0;
1360                         wcross_scale_goal_prev = 0;
1361                         wcross_alpha_goal_prev = 0;
1362                         wcross_changedonetime = 0;
1363                         if(wcross_name_goal_prev)
1364                                 strunzone(wcross_name_goal_prev);
1365                         wcross_name_goal_prev = string_null;
1366                         if(wcross_name_goal_prev_prev)
1367                                 strunzone(wcross_name_goal_prev_prev);
1368                         wcross_name_goal_prev_prev = string_null;
1369                         wcross_name_changestarttime = 0;
1370                         wcross_name_changedonetime = 0;
1371                         wcross_name_alpha_goal_prev = 0;
1372                         wcross_name_alpha_goal_prev_prev = 0;
1373                         wcross_resolution_goal_prev = 0;
1374                         wcross_resolution_goal_prev_prev = 0;
1375                 }
1376         }
1377
1378         if(NextFrameCommand)
1379         {
1380                 localcmd("\n", NextFrameCommand, "\n");
1381                 NextFrameCommand = string_null;
1382         }
1383
1384         // we must do this check AFTER a frame was rendered, or it won't work
1385         if(cs_project_is_b0rked == 0)
1386         {
1387                 string w0, h0;
1388                 w0 = ftos(autocvar_vid_conwidth);
1389                 h0 = ftos(autocvar_vid_conheight);
1390                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1391                 //R_SetView(VF_FOV, '90 90 0');
1392                 R_SetView(VF_ORIGIN, '0 0 0');
1393                 R_SetView(VF_ANGLES, '0 0 0');
1394                 R_SetView(VF_PERSPECTIVE, 1);
1395                 makevectors('0 0 0');
1396                 vector v1, v2;
1397                 cvar_set("vid_conwidth", "800");
1398                 cvar_set("vid_conheight", "600");
1399                 v1 = cs_project(v_forward);
1400                 cvar_set("vid_conwidth", "640");
1401                 cvar_set("vid_conheight", "480");
1402                 v2 = cs_project(v_forward);
1403                 if(v1 == v2)
1404                         cs_project_is_b0rked = 1;
1405                 else
1406                         cs_project_is_b0rked = -1;
1407                 cvar_set("vid_conwidth", w0);
1408                 cvar_set("vid_conheight", h0);
1409         }
1410
1411         if(autocvar__hud_configure)
1412                 HUD_Panel_Mouse();
1413     
1414     if(hud && !intermission)
1415     {        
1416         if(hud == HUD_SPIDERBOT)
1417             CSQC_SPIDER_HUD();
1418         else if(hud == HUD_WAKIZASHI)
1419             CSQC_WAKIZASHI_HUD();
1420         else if(hud == HUD_RAPTOR)
1421             CSQC_RAPTOR_HUD();
1422         else if(hud == HUD_BUMBLEBEE)
1423             CSQC_BUMBLE_HUD();
1424     }
1425         // let's reset the view back to normal for the end
1426         R_SetView(VF_MIN, '0 0 0');
1427         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1428 }
1429
1430
1431 void CSQC_common_hud(void)
1432 {
1433     // do some accuracy var caching
1434     float i;
1435     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1436     {
1437         if(autocvar_accuracy_color_levels != acc_color_levels)
1438         {
1439             if(acc_color_levels)
1440                 strunzone(acc_color_levels);
1441             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1442             acc_levels = tokenize_console(acc_color_levels);
1443             if (acc_levels > MAX_ACCURACY_LEVELS)
1444                 acc_levels = MAX_ACCURACY_LEVELS;
1445
1446             for (i = 0; i < acc_levels; ++i)
1447                 acc_lev[i] = stof(argv(i)) / 100.0;
1448         }
1449         // let know that acc_col[] needs to be loaded
1450         acc_col_x[0] = -1;
1451     }
1452
1453     HUD_Main(); // always run these functions for alpha checks
1454     HUD_DrawScoreboard();
1455
1456     if (scoreboard_active) // scoreboard/accuracy
1457         HUD_Reset();
1458     else if (intermission == 2) // map voting screen
1459     {
1460         HUD_FinaleOverlay();
1461         HUD_Reset();
1462     }
1463         /*
1464         switch(hud)
1465         {
1466                 case HUD_SPIDERBOT:
1467                         CSQC_SPIDER_HUD();
1468                         break;
1469
1470                 case HUD_WAKIZASHI:
1471                         CSQC_WAKIZASHI_HUD();
1472                         break;
1473
1474         case HUD_BUMBLEBEE:
1475             CSQC_BUMBLE_HUD();
1476             break;
1477         }
1478         */
1479 }
1480
1481
1482 // following vectors must be global to allow seamless switching between camera modes
1483 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1484 void CSQC_Demo_Camera()
1485 {
1486         float speed, attenuation, dimensions;
1487         vector tmp, delta;
1488
1489         if( autocvar_camera_reset || !camera_mode )
1490         {
1491                 camera_offset = '0 0 0';
1492                 current_angles = '0 0 0';
1493                 camera_direction = '0 0 0';
1494                 camera_offset_z += 30;
1495                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1496                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1497                 current_origin = view_origin;
1498                 current_camera_offset  = camera_offset;
1499                 cvar_set("camera_reset", "0");
1500                 camera_mode = CAMERA_CHASE;
1501         }
1502
1503         // Camera angles
1504         if( camera_roll )
1505                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1506
1507         if(autocvar_camera_look_player)
1508         {
1509                 vector dir;
1510                 float n;
1511
1512                 dir = normalize(view_origin - current_position);
1513                 n = mouse_angles_z;
1514                 mouse_angles = vectoangles(dir);
1515                 mouse_angles_x = mouse_angles_x * -1;
1516                 mouse_angles_z = n;
1517         }
1518         else
1519         {
1520                 tmp = getmousepos() * 0.1;
1521                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1522                 {
1523                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1524                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1525                 }
1526         }
1527
1528         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1529         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1530         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1531         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1532
1533         // Fix difference when angles don't have the same sign
1534         delta = '0 0 0';
1535         if(mouse_angles_y < -60 && current_angles_y > 60)
1536                 delta = '0 360 0';
1537         if(mouse_angles_y > 60 && current_angles_y < -60)
1538                 delta = '0 -360 0';
1539
1540         if(autocvar_camera_look_player)
1541                 attenuation = autocvar_camera_look_attenuation;
1542         else
1543                 attenuation = autocvar_camera_speed_attenuation;
1544
1545         attenuation = 1 / max(1, attenuation);
1546         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1547
1548         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1549         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1550         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1551         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1552
1553         // Camera position
1554         tmp = '0 0 0';
1555         dimensions = 0;
1556
1557         if( camera_direction_x )
1558         {
1559                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1560                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1561                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1562                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1563                 ++dimensions;
1564         }
1565
1566         if( camera_direction_y )
1567         {
1568                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1569                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1570                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1571                 ++dimensions;
1572         }
1573
1574         if( camera_direction_z )
1575         {
1576                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1577                 ++dimensions;
1578         }
1579
1580         if(autocvar_camera_free)
1581                 speed = autocvar_camera_speed_free;
1582         else
1583                 speed = autocvar_camera_speed_chase;
1584
1585         if(dimensions)
1586         {
1587                 speed = speed * sqrt(1 / dimensions);
1588                 camera_offset += tmp * speed;
1589         }
1590
1591         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1592
1593         // Camera modes
1594         if( autocvar_camera_free )
1595         {
1596                 if ( camera_mode == CAMERA_CHASE )
1597                 {
1598                         current_camera_offset = current_origin + current_camera_offset;
1599                         camera_offset = current_origin + camera_offset;
1600                 }
1601
1602                 camera_mode = CAMERA_FREE;
1603                 current_position = current_camera_offset;
1604         }
1605         else
1606         {
1607                 if ( camera_mode == CAMERA_FREE )
1608                 {
1609                         current_origin = view_origin;
1610                         camera_offset = camera_offset - current_origin;
1611                         current_camera_offset = current_camera_offset - current_origin;
1612                 }
1613
1614                 camera_mode = CAMERA_CHASE;
1615
1616                 if(autocvar_camera_chase_smoothly)
1617                         current_origin += (view_origin - current_origin) * attenuation;
1618                 else
1619                         current_origin = view_origin;
1620
1621                 current_position = current_origin + current_camera_offset;
1622         }
1623
1624         R_SetView(VF_ANGLES, current_angles);
1625         R_SetView(VF_ORIGIN, current_position);
1626 }