qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353 float use_nex_charge_pool;
 354
 355 float myhealth, myhealth_prev;
 356 float myhealth_flash;
 357
 358 void CSQC_UpdateView(float w, float h)
 359 {
 360         entity e;
 361         float fov;
 362         float f, i, j;
 363         vector v, vo;
 364         vector vf_size, vf_min;
 365         float a;
 366
 367         vf_size = R_SetView3fv(VF_SIZE);
 368         vf_min = R_SetView3fv(VF_MIN);
 369         vid_width = vf_size_x;
 370         vid_height = vf_size_y;
 371
 372         vector reticle_pos, reticle_size;
 373
 374         WaypointSprite_Load();
 375
 376         if(spectatee_status)
 377                 myteam = GetPlayerColor(spectatee_status - 1);
 378         else
 379                 myteam = GetPlayerColor(player_localentnum - 1);
 380
 381         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 382         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 383
 384         warpzone_fixview_origin = pmove_org + vo;
 385         warpzone_fixview_cl_viewangles = input_angles;
 386         warpzone_fixview_angles = view_angles;
 387         WarpZone_FixView();
 388         pmove_org = warpzone_fixview_origin - vo;
 389         input_angles = warpzone_fixview_cl_viewangles;
 390         view_angles = warpzone_fixview_angles;
 391
 392         if(cvar("cl_lockview") || (autocvar__hud_configure && spectatee_status <= 0))
 393         {
 394                 pmove_org = freeze_pmove_org;
 395                 input_angles = view_angles = freeze_input_angles;
 396                 R_SetView(VF_ORIGIN, pmove_org + vo);
 397                 R_SetView(VF_ANGLES, view_angles);
 398                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 399         }
 400         freeze_pmove_org = pmove_org;
 401         freeze_input_angles = input_angles;
 402
 403         // Render the Scene
 404         if(!intermission || !view_set)
 405         {
 406                 view_origin = pmove_org + vo;
 407                 view_angles = input_angles;
 408                 makevectors(view_angles);
 409                 view_forward = v_forward;
 410                 view_right = v_right;
 411                 view_up = v_up;
 412                 view_set = 1;
 413         }
 414
 415 #ifdef BLURTEST
 416         if(time > blurtest_time0 && time < blurtest_time1)
 417         {
 418                 float r, t;
 419
 420                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 421                 r = t * blurtest_radius;
 422                 f = 1 / pow(t, blurtest_power) - 1;
 423
 424                 cvar_set("r_glsl_postprocess", "1");
 425                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 426         }
 427         else
 428         {
 429                 cvar_set("r_glsl_postprocess", "0");
 430                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 431         }
 432 #endif
 433
 434         TargetMusic_Advance();
 435         Fog_Force();
 436
 437         drawframetime = max(0.000001, time - drawtime);
 438         drawtime = time;
 439
 440         // watch for gametype changes here...
 441         // in ParseStuffCMD the cmd isn't executed yet :/
 442         // might even be better to add the gametype to TE_CSQC_INIT...?
 443         if(!postinit)
 444                 PostInit();
 445
 446         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 447                 if(calledhooks & HOOK_START)
 448                 {
 449                         localcmd("\ncl_hook_gameend\n");
 450                         calledhooks |= HOOK_END;
 451                 }
 452
 453         CheckForGamestartChange();
 454         serverAnnouncer();
 455         maptimeAnnouncer();
 456         carrierAnnouncer();
 457
 458         fov = cvar("fov");
 459         if(button_zoom || fov <= 59.5)
 460         {
 461                 if(!zoomscript_caught)
 462                 {
 463                         localcmd("+button4\n");
 464                         zoomscript_caught = 1;
 465                         ignore_plus_zoom += 1;
 466                 }
 467         }
 468         else
 469         {
 470                 if(zoomscript_caught)
 471                 {
 472                         localcmd("-button4\n");
 473                         zoomscript_caught = 0;
 474                         ignore_minus_zoom += 1;
 475                 }
 476         }
 477
 478         ColorTranslateMode = cvar("cl_stripcolorcodes");
 479         activeweapon = getstati(STAT_SWITCHWEAPON);
 480         f = cvar("teamplay");
 481         if(f != teamplay)
 482         {
 483                 teamplay = f;
 484                 HUD_InitScores();
 485         }
 486
 487         if(last_weapon != activeweapon) {
 488                 weapontime = time;
 489                 last_weapon = activeweapon;
 490
 491                 e = get_weaponinfo(activeweapon);
 492                 if(e.netname != "")
 493                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 494                 else
 495                         localcmd("\ncl_hook_activeweapon none\n");
 496         }
 497
 498         // ALWAYS Clear Current Scene First
 499         R_ClearScene();
 500
 501         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 502         R_SetView(VF_SIZE, vf_size);
 503         R_SetView(VF_MIN, vf_min);
 504
 505         // Assign Standard Viewflags
 506         // Draw the World (and sky)
 507         R_SetView(VF_DRAWWORLD, 1);
 508
 509         // Set the console size vars
 510         vid_conwidth = cvar("vid_conwidth");
 511         vid_conheight = cvar("vid_conheight");
 512         vid_pixelheight = cvar("vid_pixelheight");
 513
 514         R_SetView(VF_FOV, GetCurrentFov(fov));
 515
 516         // Camera for demo playback
 517         if(camera_active)
 518         {
 519                 if(cvar("camera_enable"))
 520                         CSQC_Demo_Camera();
 521                 else
 522                 {
 523                         cvar_set("chase_active", ftos(chase_active_backup));
 524                         cvar_set("cl_demo_mousegrab", "0");
 525                         camera_active = FALSE;
 526                 }
 527         }
 528 #ifdef CAMERATEST
 529         else if(cvar("camera_enable"))
 530 #else
 531         else if(cvar("camera_enable") && isdemo())
 532 #endif
 533         {
 534                 // Enable required Darkplaces cvars
 535                 chase_active_backup = cvar("chase_active");
 536                 cvar_set("chase_active", "2");
 537                 cvar_set("cl_demo_mousegrab", "1");
 538                 camera_active = TRUE;
 539                 camera_mode = FALSE;
 540         }
 541
 542         // Draw the Crosshair
 543         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 544
 545         // Draw the Engine Status Bar (the default Quake HUD)
 546         R_SetView(VF_DRAWENGINEHUD, 0);
 547
 548         // fetch this one only once per frame
 549         hud_showbinds = cvar("hud_showbinds");
 550         hud_showbinds_limit = cvar("hud_showbinds_limit");
 551
 552         // Update the mouse position
 553         /*
 554            mousepos_x = vid_conwidth;
 555            mousepos_y = vid_conheight;
 556            mousepos = mousepos*0.5 + getmousepos();
 557          */
 558
 559         e = self;
 560         for(self = world; (self = nextent(self)); )
 561                 if(self.draw)
 562                         self.draw();
 563         self = e;
 564
 565         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 566         R_RenderScene();
 567
 568         // now switch to 2D drawing mode by calling a 2D drawing function
 569         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 570         // next R_RenderScene call
 571         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 572
 573         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright") >= 1)
 574         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 575         {
 576                 // apply night vision effect
 577                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 578
 579                 if(!nightvision_noise)
 580                 {
 581                         nightvision_noise = spawn();
 582                         nightvision_noise.classname = "nightvision_noise";
 583                 }
 584                 if(!nightvision_noise2)
 585                 {
 586                         nightvision_noise2 = spawn();
 587                         nightvision_noise2.classname = "nightvision_noise2";
 588                 }
 589
 590                 // color tint in yellow
 591                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 592
 593                 // draw BG
 594                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 595                 rgb = '1 1 1';
 596                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 597                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 598                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 599                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 600                 tc_11 = tc_01 + tc_10 - tc_00;
 601                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 602                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 603                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 604                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 605                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 606                 R_EndPolygon();
 607
 608                 // draw FG
 609                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 610                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 611                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 612                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 613                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 614                 tc_11 = tc_01 + tc_10 - tc_00;
 615                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 616                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 617                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 618                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 619                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 620                 R_EndPolygon();
 621         }
 622
 623         // Draw the aiming reticle for weapons that use it
 624         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 625         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 626         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 627         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 628                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 629         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_CAMPINGRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 630                 reticle_type = 2; // nex zoom
 631         else if(button_zoom || zoomscript_caught)
 632                 reticle_type = 1; // normal zoom
 633         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 634                 reticle_type = 2; // nex zoom
 635
 636         if(cvar("cl_reticle_stretch"))
 637         {
 638                 reticle_size_x = vid_conwidth;
 639                 reticle_size_y = vid_conheight;
 640                 reticle_pos_x = 0;
 641                 reticle_pos_y = 0;
 642         }
 643         else
 644         {
 645                 reticle_size_x = max(vid_conwidth, vid_conheight);
 646                 reticle_size_y = max(vid_conwidth, vid_conheight);
 647                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 648                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 649         }
 650
 651         f = current_zoomfraction;
 652         if(zoomscript_caught)
 653                 f = 1;
 654         if(cvar("cl_reticle_item_normal"))
 655         {
 656                 precache_pic("gfx/reticle_normal");
 657                 if(reticle_type == 1 && f)
 658                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 659         }
 660         if(cvar("cl_reticle_item_nex"))
 661         {
 662                 precache_pic("gfx/reticle_nex");
 663                 if(reticle_type == 2 && f)
 664                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 665         }
 666
 667         // improved polyblend
 668         if(cvar("hud_damage"))
 669         {
 670                 float myhealth_flash_temp;
 671                 myhealth = getstati(STAT_HEALTH);
 672
 673                 // fade out
 674                 myhealth_flash = max(0, myhealth_flash - cvar("hud_damage_fade_rate") * frametime);
 675                 // add new damage
 676                 myhealth_flash = bound(0, myhealth_flash + max(0, myhealth_prev - myhealth) * cvar("hud_damage_factor"), cvar("hud_damage_maxalpha"));
 677
 678                 float pain_treshold, pain_treshold_lower, pain_treshold_lower_health;
 679                 pain_treshold = cvar("hud_damage_pain_treshold");
 680                 pain_treshold_lower = cvar("hud_damage_pain_treshold_lower");
 681                 pain_treshold_lower_health = cvar("hud_damage_pain_treshold_lower_health");
 682
 683                 if(pain_treshold_lower && myhealth < pain_treshold_lower_health)
 684                 {
 685                         pain_treshold = pain_treshold - max(cvar("hud_damage_pain_treshold_pulsating_min"), fabs(sin(M_PI * time / cvar("hud_damage_pain_treshold_pulsating_period")))) * pain_treshold_lower * (1 - max(0, myhealth)/pain_treshold_lower_health);
 686                 }
 687
 688                 myhealth_flash_temp = bound(0, myhealth_flash - pain_treshold, 1);
 689
 690                 if(myhealth_prev < 1)
 691                 {
 692                         if(myhealth >= 1)
 693                         {
 694                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 695                                 myhealth_flash_temp = 0;
 696                         }
 697                         else
 698                         {
 699                                 myhealth_flash += cvar("hud_damage_fade_rate") * frametime; // dead
 700                         }
 701                 }
 702
 703                 if(spectatee_status == -1 || intermission)
 704                 {
 705                         myhealth_flash = 0; // observing, or match ended
 706                         myhealth_flash_temp = 0;
 707                 }
 708
 709                 myhealth_prev = myhealth;
 710
 711                 drawpic(reticle_pos, "gfx/blood", reticle_size, stov(cvar_string("hud_damage_color")), bound(0, myhealth_flash_temp, 1), DRAWFLAG_NORMAL);
 712         }
 713
 714         // Draw the mouse cursor
 715         // NOTE: drawpic must happen after R_RenderScene for some reason
 716         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 717         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 718         //self = edict_num(player_localnum);
 719         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 720         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 721         // as long as the ctf part isn't in, this is useless
 722         if(menu_visible)
 723                 menu_show();
 724
 725         /*if(gametype == GAME_CTF)
 726           {
 727           ctf_view();
 728           } else */
 729
 730         // draw 2D entities
 731         e = self;
 732         for(self = world; (self = nextent(self)); )
 733                 if(self.draw2d)
 734                         self.draw2d();
 735         self = e;
 736
 737         scoreboard_active = HUD_WouldDrawScoreboard();
 738
 739         float hud;
 740         hud = getstati(STAT_HUD);
 741         if(hud == HUD_SPIDERBOT)
 742                 CSQC_SPIDER_HUD();
 743         else if(hud == HUD_WAKIZASHI)
 744         CSQC_WAKIZASHI_HUD();
 745     else if(hud == HUD_RAPTOR)
 746         CSQC_RAPTOR_HUD();
 747         else
 748         {
 749                 if(cvar("r_letterbox") == 0)
 750                         if(cvar("viewsize") < 120)
 751                                 CSQC_common_hud();
 752
 753                 // crosshair goes VERY LAST
 754                 if(!scoreboard_active && !camera_active && intermission != 2) {
 755                         string wcross_style;
 756                         float wcross_alpha, wcross_resolution;
 757                         wcross_style = cvar_string("crosshair");
 758                         if (wcross_style == "0")
 759                                 return;
 760                         wcross_resolution = cvar("crosshair_size");
 761                         if (wcross_resolution == 0)
 762                                 return;
 763                         wcross_alpha = cvar("crosshair_alpha");
 764                         if (wcross_alpha == 0)
 765                                 return;
 766
 767                         // TrueAim check
 768                         float shottype;
 769                         float bullets, ring_scale;
 770                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 771                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 772                         wcross_origin_z = 0;
 773                         if(cvar("crosshair_hittest"))
 774                         {
 775                                 vector wcross_oldorigin;
 776                                 wcross_oldorigin = wcross_origin;
 777                                 shottype = TrueAimCheck();
 778                                 if(shottype == SHOTTYPE_HITWORLD)
 779                                 {
 780                                         v = wcross_origin - wcross_oldorigin;
 781                                         v_x /= vid_conwidth;
 782                                         v_y /= vid_conheight;
 783                                         if(vlen(v) > 0.01)
 784                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 785                                 }
 786                                 if(!cvar("crosshair_hittest_showimpact"))
 787                                         wcross_origin = wcross_oldorigin;
 788                         }
 789                         else
 790                                 shottype = SHOTTYPE_HITWORLD;
 791
 792                         vector wcross_color, wcross_size;
 793                         string wcross_wep, wcross_name;
 794                         float wcross_scale, wcross_blur;
 795
 796                         if (cvar("crosshair_per_weapon") || cvar("crosshair_color_per_weapon")) {
 797                                 e = get_weaponinfo(activeweapon);
 798                                 if (e && e.netname != "")
 799                                 {
 800                                         wcross_wep = e.netname;
 801                                         if(cvar("crosshair_per_weapon"))
 802                                         {
 803                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 804                                                 if (wcross_resolution == 0)
 805                                                         return;
 806                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 807                                                 if (wcross_alpha == 0)
 808                                                         return;
 809
 810                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 811                                                 if(wcross_style == "" || wcross_style == "0")
 812                                                         wcross_style = wcross_wep;
 813                                         }
 814                                 }
 815                         }
 816                         if(wcross_wep != "" && cvar("crosshair_color_per_weapon"))
 817                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 818                         else
 819                                 wcross_color = stov(cvar_string("crosshair_color"));
 820
 821                         wcross_name = strcat("gfx/crosshair", wcross_style);
 822
 823                         if(cvar("crosshair_effect_scalefade"))
 824                         {
 825                                 wcross_scale = wcross_resolution;
 826                                 wcross_resolution = 1;
 827                         }
 828                         else
 829                         {
 830                                 wcross_scale = 1;
 831                         }
 832
 833                         if(cvar("crosshair_pickup"))
 834                         {
 835                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 836                                 {
 837                                         pickup_crosshair_size = 1;
 838                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 839                                 }
 840
 841                                 if(pickup_crosshair_size > 0)
 842                                         pickup_crosshair_size -= cvar("crosshair_pickup_speed") * frametime;
 843                                 else
 844                                         pickup_crosshair_size = 0;
 845
 846                                 wcross_scale += sin(pickup_crosshair_size) * cvar("crosshair_pickup");
 847                         }
 848
 849                         if(shottype == SHOTTYPE_HITENEMY)
 850                                 wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 851                         if(shottype == SHOTTYPE_HITTEAM)
 852                                 wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 853
 854                         f = cvar("crosshair_effect_speed");
 855                         if(f < 0)
 856                                 f *= -2 * g_weaponswitchdelay;
 857                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 858                         {
 859                                 wcross_changedonetime = time + f;
 860                         }
 861                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 862                         {
 863                                 wcross_name_changestarttime = time;
 864                                 wcross_name_changedonetime = time + f;
 865                                 if(wcross_name_goal_prev_prev)
 866                                         strunzone(wcross_name_goal_prev_prev);
 867                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
 868                                 wcross_name_goal_prev = strzone(wcross_name);
 869                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 870                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 871                                 wcross_resolution_goal_prev = wcross_resolution;
 872                         }
 873
 874                         wcross_scale_goal_prev = wcross_scale;
 875                         wcross_alpha_goal_prev = wcross_alpha;
 876                         wcross_color_goal_prev = wcross_color;
 877
 878                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 879                         {
 880                                 wcross_blur = 1;
 881                                 wcross_alpha *= 0.75;
 882                         }
 883                         else
 884                                 wcross_blur = 0;
 885                         // *_prev is at time-frametime
 886                         // * is at wcross_changedonetime+f
 887                         // what do we have at time?
 888                         if(time < wcross_changedonetime)
 889                         {
 890                                 f = frametime / (wcross_changedonetime - time + frametime);
 891                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 892                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 893                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 894                         }
 895
 896                         wcross_scale_prev = wcross_scale;
 897                         wcross_alpha_prev = wcross_alpha;
 898                         wcross_color_prev = wcross_color;
 899
 900                         wcross_scale *= 1 - cvar("_menu_alpha");
 901                         wcross_alpha *= 1 - cvar("_menu_alpha");
 902
 903                         ring_scale = cvar("crosshair_ring_size");
 904
 905                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 906
 907                         float nex_charge, nex_charge_pool;
 908                         nex_charge = getstatf(STAT_NEX_CHARGE);
 909                         nex_charge_pool = getstatf(STAT_NEX_CHARGEPOOL);
 910
 911                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 912                                 nex_charge_movingavg = nex_charge;
 913
 914                         // ring around crosshair representing bullets left in camping rifle clip
 915                         if (activeweapon == WEP_CAMPINGRIFLE && cr_maxbullets)
 916                         {
 917                                 bullets = getstati(STAT_BULLETS_LOADED);
 918                                 f = bound(0, bullets / cr_maxbullets, 1);
 919
 920                                 a = cvar("crosshair_ring_campingrifle_alpha");
 921                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 922                         }
 923                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
 924                         {
 925                                 vector rgb;
 926                                 if(nex_charge_pool || use_nex_charge_pool)
 927                                 {
 928                                         use_nex_charge_pool = 1;
 929
 930                                         a = cvar("crosshair_ring_nex_inner_alpha");
 931                                         rgb = eX * cvar("crosshair_ring_nex_inner_color_red") + eY * cvar("crosshair_ring_nex_inner_color_green") + eZ * cvar("crosshair_ring_nex_inner_color_blue");
 932                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_charge_pool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 933                                 }
 934                                 else
 935                                 {
 936                                         // indicate how much we're charging right now with an inner circle
 937                                         a = cvar("crosshair_ring_nex_inner_alpha");
 938                                         nex_charge_movingavg = (1 - cvar("crosshair_ring_nex_currentcharge_movingavg_rate")) * nex_charge_movingavg + cvar("crosshair_ring_nex_currentcharge_movingavg_rate") * nex_charge;
 939
 940                                         rgb = eX * cvar("crosshair_ring_nex_inner_color_red") + eY * cvar("crosshair_ring_nex_inner_color_green") + eZ * cvar("crosshair_ring_nex_inner_color_blue");
 941                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, cvar("crosshair_ring_nex_currentcharge_scale") * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 942                                 }
 943
 944                                 // draw the charge
 945                                 a = cvar("crosshair_ring_nex_outer_alpha");
 946                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 947                         }
 948
 949 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 950                         do \
 951                         { \
 952                                 if(wcross_blur > 0) \
 953                                 { \
 954                                         for(i = -2; i <= 2; ++i) \
 955                                                 for(j = -2; j <= 2; ++j) \
 956                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 957                                 } \
 958                                 else \
 959                                 { \
 960                                         M(0,0,sz,wcross_name,wcross_alpha); \
 961                                 } \
 962                         } \
 963                         while(0)
 964
 965 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 966                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 967
 968 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 969                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 970
 971                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 972                         {
 973                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 974                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 975                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 976                                 f = 1 - f;
 977                         }
 978                         else
 979                         {
 980                                 f = 1;
 981                         }
 982
 983                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 984                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 985
 986                         if(cvar("crosshair_dot"))
 987                                 CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
 988
 989                         wcross_name_alpha_goal_prev = f;
 990                 }
 991                 else
 992                 {
 993                         wcross_scale_prev = 0;
 994                         wcross_alpha_prev = 0;
 995                         wcross_scale_goal_prev = 0;
 996                         wcross_alpha_goal_prev = 0;
 997                         wcross_changedonetime = 0;
 998                         if(wcross_name_goal_prev)
 999                                 strunzone(wcross_name_goal_prev);
1000                         wcross_name_goal_prev = string_null;
1001                         if(wcross_name_goal_prev_prev)
1002                                 strunzone(wcross_name_goal_prev_prev);
1003                         wcross_name_goal_prev_prev = string_null;
1004                         wcross_name_changestarttime = 0;
1005                         wcross_name_changedonetime = 0;
1006                         wcross_name_alpha_goal_prev = 0;
1007                         wcross_name_alpha_goal_prev_prev = 0;
1008                         wcross_resolution_goal_prev = 0;
1009                         wcross_resolution_goal_prev_prev = 0;
1010                 }
1011         }
1012
1013         if(NextFrameCommand)
1014         {
1015                 localcmd("\n", NextFrameCommand, "\n");
1016                 NextFrameCommand = string_null;
1017         }
1018
1019         // we must do this check AFTER a frame was rendered, or it won't work
1020         if(cs_project_is_b0rked == 0)
1021         {
1022                 string w0, h0;
1023                 w0 = cvar_string("vid_conwidth");
1024                 h0 = cvar_string("vid_conheight");
1025                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1026                 //R_SetView(VF_FOV, '90 90 0');
1027                 R_SetView(VF_ORIGIN, '0 0 0');
1028                 R_SetView(VF_ANGLES, '0 0 0');
1029                 R_SetView(VF_PERSPECTIVE, 1);
1030                 makevectors('0 0 0');
1031                 vector v1, v2;
1032                 cvar_set("vid_conwidth", "800");
1033                 cvar_set("vid_conheight", "600");
1034                 v1 = cs_project(v_forward);
1035                 cvar_set("vid_conwidth", "640");
1036                 cvar_set("vid_conheight", "480");
1037                 v2 = cs_project(v_forward);
1038                 if(v1 == v2)
1039                         cs_project_is_b0rked = 1;
1040                 else
1041                         cs_project_is_b0rked = -1;
1042                 cvar_set("vid_conwidth", w0);
1043                 cvar_set("vid_conheight", h0);
1044         }
1045
1046         if(autocvar__hud_configure)
1047                 HUD_Panel_Mouse();
1048
1049         // let's reset the view back to normal for the end
1050         R_SetView(VF_MIN, '0 0 0');
1051         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1052 }
1053
1054 #define spider_h "gfx/vehicles/hud_bg.tga"
1055 #define spider_b "gfx/vehicles/sbot.tga"
1056 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1057 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1058 #define spider_s "gfx/vehicles/shiled.tga"
1059 #define spider_a1 "gfx/hud/sb_rocket.tga"
1060 #define spider_a2 "gfx/sb_bullets.tga"
1061
1062 void CSQC_SPIDER_HUD()
1063 {
1064         float rockets, reload, heat, hp, shield;
1065         vector picsize, hudloc;
1066
1067     // Fetch health & ammo stats
1068     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1069         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1070         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1071         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1072         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1073
1074     // Draw the crosshairs
1075     picsize = drawgetimagesize(SPIDER_CROSS);
1076     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1077     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1078     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1079
1080     hudloc_y =  4;
1081     hudloc_x = 4;
1082
1083     picsize = drawgetimagesize(spider_h) * 0.5;
1084     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1085
1086     picsize = drawgetimagesize(spider_a2) * 0.5;
1087     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1088
1089     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1090     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1091     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1092
1093     picsize = drawgetimagesize(spider_a1) * 0.85;
1094     if(rockets == 9)
1095     {
1096         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1097         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1098     }
1099     else
1100     {
1101         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1102         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1103     }
1104
1105     picsize = drawgetimagesize(spider_b) * 0.5;
1106     hudloc_y = 10.5;
1107     hudloc_x = 10.5;
1108
1109     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1110     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1111     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1112     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1113
1114
1115         /*
1116         // Draw health bar
1117         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1118         p = p + '0 1 0' * vid_conheight - '0 32 0';
1119         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1120         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1121         p_y += 8;
1122         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1123         p_x += 256 * hp;
1124         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1125
1126         // Draw minigun heat indicator
1127         p = '0.5 0 0' * (vid_conwidth - 256);
1128         p = p + '0 1 0' * vid_conheight - '0 34  0';
1129         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1130         p_x += 256 * (1-heat);
1131         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1132
1133
1134         // Draw rocket icons for loaded/empty tubes.
1135         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1136         pp += '0 1 0' * vid_conheight - '0 64 0';
1137         for(i = 0; i < 8; ++i)
1138         {
1139                 p = pp + '1 0 0' * (rkt_size * i);
1140                 if(rockets == 8)
1141                 {
1142                         if(floor(reload * 8) == i)
1143                         {
1144                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1145                         }
1146                         else if(i < reload * 8)
1147                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1148                         else
1149                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1150                 }
1151                 else
1152                 {
1153                         if(i < rockets)
1154                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1155                         else
1156                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1157                 }
1158         }
1159         */
1160
1161         if (scoreboard_showscores)
1162         {
1163                 HUD_DrawScoreboard();
1164                 HUD_DrawCenterPrint();
1165         }
1166
1167 }
1168
1169 #define raptor_h "gfx/vehicles/hud_bg.tga"
1170 #define raptor_b "gfx/vehicles/raptor.tga"
1171 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1172 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1173 #define raptor_s "gfx/vehicles/shiled.tga"
1174
1175 void CSQC_RAPTOR_HUD()
1176 {
1177         float reload, hp, shield, energy;
1178         vector picsize, hudloc;
1179
1180     // Fetch health & ammo stats
1181     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1182         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1183         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1184         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1185
1186     // Draw the crosshairs
1187     picsize = drawgetimagesize(SPIDER_CROSS);
1188     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1189     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1190     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1191
1192     hudloc_y =  4;
1193     hudloc_x = 4;
1194
1195     picsize = drawgetimagesize(raptor_h) * 0.5;
1196     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1197
1198     picsize = drawgetimagesize(spider_a2) * 0.5;
1199     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1200
1201     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1202     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1203     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1204
1205
1206     picsize = drawgetimagesize(spider_a1) * 0.85;
1207     if(reload == 1)
1208     {
1209         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1210         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1211     }
1212     else
1213     {
1214         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1215         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1216     }
1217
1218     picsize = drawgetimagesize(raptor_b) * 0.5;
1219     hudloc_y = 10.5;
1220     hudloc_x = 10.5;
1221
1222     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1223     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1224     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1225     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1226
1227
1228         if (scoreboard_showscores)
1229         {
1230                 HUD_DrawScoreboard();
1231                 HUD_DrawCenterPrint();
1232         }
1233
1234 }
1235
1236 #define waki_h "gfx/vehicles/hud_bg.tga"
1237 #define waki_b "gfx/vehicles/waki.tga"
1238 #define waki_e "gfx/vehicles/waki_e.tga"
1239 #define waki_g "gfx/vehicles/waki_guns.tga"
1240 #define waki_r "gfx/vehicles/waki_rockets.tga"
1241 #define waki_s "gfx/vehicles/shiled.tga"
1242
1243 #define waki_a1 "gfx/hud/sb_rocket.tga"
1244 #define waki_a2 "gfx/sb_cells.tga"
1245
1246 void CSQC_WAKIZASHI_HUD()
1247 {
1248         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1249         float health, shield, energy, rockets;
1250         vector picsize, hudloc;
1251
1252     picsize = drawgetimagesize(SPIDER_CROSS);
1253     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1254     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1255     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1256
1257 /*
1258 const float STAT_VEHICLESTAT_HEALTH  = 60;
1259 const float STAT_VEHICLESTAT_SHIELD  = 61;
1260 const float STAT_VEHICLESTAT_ENERGY  = 62;
1261 const float STAT_VEHICLESTAT_AMMO1   = 63;
1262 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1263 const float STAT_VEHICLESTAT_AMMO2   = 65;
1264 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1265 */
1266     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1267         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1268         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1269         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1270
1271     hudloc_y =  4;
1272     hudloc_x = 4;
1273
1274     picsize = drawgetimagesize(waki_h) * 0.5;
1275     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1276
1277     picsize = drawgetimagesize(waki_a2) * 0.7;
1278     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1279
1280
1281     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1282     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1283
1284     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1285
1286     picsize = drawgetimagesize(waki_a1) * 0.75;
1287     if(rockets == 1)
1288     {
1289         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1290         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1291     }
1292     else
1293     {
1294         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1295         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1296         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1297     }
1298
1299     picsize = drawgetimagesize(waki_b) * 0.5;
1300     hudloc_y = 10.5;
1301     hudloc_x = 10.5;
1302
1303     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1304     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1305     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1306     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1307
1308
1309
1310         /*
1311         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1312         p = p + '0 1 0' * vid_conheight - '0 32 0';
1313
1314         // Draw health bar
1315         p_y += 8;
1316         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1317         p_x += 256 * health;
1318         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1319
1320         // Draw shiled bar
1321         p_x -= 256 * health;
1322         p_y += 4;
1323         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1324
1325         // Draw energy
1326         //p_x -= 256 * health;
1327         p_y -= 8;
1328         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1329
1330         // Draw rockets bar
1331         p_y += 12;
1332         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1333         */
1334
1335
1336
1337
1338         if (scoreboard_showscores)
1339         {
1340                 HUD_DrawScoreboard();
1341                 HUD_DrawCenterPrint();
1342         }
1343
1344 }
1345
1346
1347 void CSQC_common_hud(void)
1348 {
1349         // HUD_SortFrags(); done in HUD_Draw
1350         float hud;
1351         hud = getstati(STAT_HUD);
1352
1353         //hud = 10;
1354         switch(hud)
1355         {
1356                 case HUD_NORMAL:
1357                         // do some accuracy var caching
1358                         float i;
1359                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1360                         {
1361                                 if(cvar_string("accuracy_color_levels") != acc_color_levels)
1362                                 {
1363                                         if(acc_color_levels)
1364                                                 strunzone(acc_color_levels);
1365                                         acc_color_levels = strzone(cvar_string("accuracy_color_levels"));
1366                                         acc_levels = tokenize(acc_color_levels);
1367                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1368                                                 acc_levels = MAX_ACCURACY_LEVELS;
1369
1370                                         for (i = 0; i < acc_levels; ++i)
1371                                                 acc_lev[i] = stof(argv(i));
1372                                 }
1373                                 // let know that acc_col[] needs to be loaded
1374                                 acc_col_x[0] = -1;
1375                         }
1376
1377                         HUD_Main(); // always run these functions for alpha checks
1378                         HUD_DrawScoreboard();
1379
1380                         if (scoreboard_active) // scoreboard/accuracy
1381                         {
1382                                 HUD_Reset();
1383                                 // HUD_DrawScoreboard takes care of centerprint_start
1384                         }
1385                         else if (intermission == 2) // map voting screen
1386                         {
1387                                 HUD_FinaleOverlay();
1388                                 HUD_Reset();
1389
1390                                 centerprint_start_x = 0;
1391                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1392                         }
1393                         else // hud
1394                         {
1395                                 centerprint_start_x = 0;
1396                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1397                         }
1398
1399                         HUD_DrawCenterPrint();
1400                         break;
1401
1402                 case HUD_SPIDERBOT:
1403                         CSQC_SPIDER_HUD();
1404                         break;
1405
1406                 case HUD_WAKIZASHI:
1407                         CSQC_WAKIZASHI_HUD();
1408                         break;
1409         }
1410 }
1411
1412
1413 // following vectors must be global to allow seamless switching between camera modes
1414 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1415 void CSQC_Demo_Camera()
1416 {
1417         float speed, attenuation, dimensions;
1418         vector tmp, delta;
1419
1420         if( cvar("camera_reset") || !camera_mode )
1421         {
1422                 camera_offset = '0 0 0';
1423                 current_angles = '0 0 0';
1424                 camera_direction = '0 0 0';
1425                 camera_offset_z += 30;
1426                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1427                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1428                 current_origin = view_origin;
1429                 current_camera_offset  = camera_offset;
1430                 cvar_set("camera_reset", "0");
1431                 camera_mode = CAMERA_CHASE;
1432         }
1433
1434         // Camera angles
1435         if( camera_roll )
1436                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1437
1438         if(cvar("camera_look_player"))
1439         {
1440                 local vector dir;
1441                 local float n;
1442
1443                 dir = normalize(view_origin - current_position);
1444                 n = mouse_angles_z;
1445                 mouse_angles = vectoangles(dir);
1446                 mouse_angles_x = mouse_angles_x * -1;
1447                 mouse_angles_z = n;
1448         }
1449         else
1450         {
1451                 tmp = getmousepos() * 0.1;
1452                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1453                 {
1454                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1455                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1456                 }
1457         }
1458
1459         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1460         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1461         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1462         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1463
1464         // Fix difference when angles don't have the same sign
1465         delta = '0 0 0';
1466         if(mouse_angles_y < -60 && current_angles_y > 60)
1467                 delta = '0 360 0';
1468         if(mouse_angles_y > 60 && current_angles_y < -60)
1469                 delta = '0 -360 0';
1470
1471         if(cvar("camera_look_player"))
1472                 attenuation = cvar("camera_look_attenuation");
1473         else
1474                 attenuation = cvar("camera_speed_attenuation");
1475
1476         attenuation = 1 / max(1, attenuation);
1477         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1478
1479         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1480         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1481         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1482         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1483
1484         // Camera position
1485         tmp = '0 0 0';
1486         dimensions = 0;
1487
1488         if( camera_direction_x )
1489         {
1490                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1491                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1492                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1493                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1494                 ++dimensions;
1495         }
1496
1497         if( camera_direction_y )
1498         {
1499                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1500                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1501                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1502                 ++dimensions;
1503         }
1504
1505         if( camera_direction_z )
1506         {
1507                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1508                 ++dimensions;
1509         }
1510
1511         if(cvar("camera_free"))
1512                 speed = cvar("camera_speed_free");
1513         else
1514                 speed = cvar("camera_speed_chase");
1515
1516         if(dimensions)
1517         {
1518                 speed = speed * sqrt(1 / dimensions);
1519                 camera_offset += tmp * speed;
1520         }
1521
1522         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1523
1524         // Camera modes
1525         if( cvar("camera_free") )
1526         {
1527                 if ( camera_mode == CAMERA_CHASE )
1528                 {
1529                         current_camera_offset = current_origin + current_camera_offset;
1530                         camera_offset = current_origin + camera_offset;
1531                 }
1532
1533                 camera_mode = CAMERA_FREE;
1534                 current_position = current_camera_offset;
1535         }
1536         else
1537         {
1538                 if ( camera_mode == CAMERA_FREE )
1539                 {
1540                         current_origin = view_origin;
1541                         camera_offset = camera_offset - current_origin;
1542                         current_camera_offset = current_camera_offset - current_origin;
1543                 }
1544
1545                 camera_mode = CAMERA_CHASE;
1546
1547                 if(cvar("camera_chase_smoothly"))
1548                         current_origin += (view_origin - current_origin) * attenuation;
1549                 else
1550                         current_origin = view_origin;
1551
1552                 current_position = current_origin + current_camera_offset;
1553         }
1554
1555         R_SetView(VF_ANGLES, current_angles);
1556         R_SetView(VF_ORIGIN, current_position);
1557 }