qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 if(intermission) { curspeed = 0; }
 168                 else
 169                 {
 170
 171                         makevectors(view_angles);
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon) // WEAPONTODO
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_MORTAR: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_VORTEX:
 291                 case WEP_VAPORIZER:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_DEVASTATOR: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string reticle_image;
 369 string NextFrameCommand;
 370 void CSQC_SPIDER_HUD();
 371 void CSQC_RAPTOR_HUD();
 372
 373 vector freeze_org, freeze_ang;
 374 entity nightvision_noise, nightvision_noise2;
 375
 376 #define MAX_TIME_DIFF 5
 377 float pickup_crosshair_time, pickup_crosshair_size;
 378 float hitsound_time_prev;
 379 float spectatee_status_prev; // for preventing hitsound when switching spectatee
 380 float damage_dealt_total, damage_dealt_total_prev;
 381 float typehit_time, typehit_time_prev;
 382 float hitindication_crosshair_size;
 383 float use_vortex_chargepool;
 384
 385 float myhealth, myhealth_prev;
 386 float myhealth_flash;
 387
 388 float old_blurradius, old_bluralpha;
 389 float old_sharpen_intensity;
 390
 391 vector myhealth_gentlergb;
 392
 393 float contentavgalpha, liquidalpha_prev;
 394 vector liquidcolor_prev;
 395
 396 float eventchase_current_distance;
 397 float WantEventchase()
 398 {
 399         if(autocvar_cl_orthoview)
 400                 return FALSE;
 401         if(intermission)
 402                 return TRUE;
 403         if(spectatee_status >= 0)
 404         {
 405                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 406                         return TRUE;
 407                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 408                         return TRUE;
 409         }
 410         return FALSE;
 411 }
 412
 413 vector damage_blurpostprocess, content_blurpostprocess;
 414
 415 float checkfail[16];
 416
 417 float rainbow_last_flicker;
 418 vector rainbow_prev_color;
 419
 420 #define BUTTON_3 4
 421 #define BUTTON_4 8
 422 float cl_notice_run();
 423 float prev_myteam;
 424 void CSQC_UpdateView(float w, float h)
 425 {
 426         entity e;
 427         float fov;
 428         float f, i, j;
 429         vector v;
 430         vector vf_size, vf_min;
 431         float a;
 432
 433         execute_next_frame();
 434
 435         ++framecount;
 436
 437         hud = getstati(STAT_HUD);
 438
 439         if(autocvar__hud_showbinds_reload) // menu can set this one
 440         {
 441                 db_close(binddb);
 442                 binddb = db_create();
 443                 cvar_set("_hud_showbinds_reload", "0");
 444         }
 445
 446         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 447                 view_quality = getproperty(VF_MINFPS_QUALITY);
 448         else
 449                 view_quality = 1;
 450
 451         button_attack2 = (input_buttons & BUTTON_3);
 452         button_zoom = (input_buttons & BUTTON_4);
 453
 454 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 455         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 456         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 457         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 458         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 459         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 460         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 461         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 462
 463         vf_size = getpropertyvec(VF_SIZE);
 464         vf_min = getpropertyvec(VF_MIN);
 465         vid_width = vf_size_x;
 466         vid_height = vf_size_y;
 467
 468         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 469         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 470
 471         WaypointSprite_Load();
 472
 473         CSQCPlayer_SetCamera();
 474
 475 #ifdef COMPAT_XON050_ENGINE
 476         if(spectatee_status)
 477                 myteam = GetPlayerColor(spectatee_status - 1);
 478         else
 479 #endif
 480                 myteam = GetPlayerColor(player_localentnum - 1);
 481
 482         if(myteam != prev_myteam)
 483         {
 484                 myteamcolors = colormapPaletteColor(myteam, 1);
 485                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 486                         hud_panel[i].update_time = time;
 487                 prev_myteam = myteam;
 488         }
 489
 490         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 491
 492         float is_dead = (getstati(STAT_HEALTH) <= 0);
 493
 494         // FIXME do we need this hack?
 495         if(isdemo())
 496         {
 497                 // in demos, input_buttons do not work
 498                 button_zoom = (autocvar__togglezoom == "-");
 499         }
 500         else if(button_zoom
 501                 && autocvar_cl_unpress_zoom_on_death
 502                 && (spectatee_status >= 0)
 503                 && (is_dead || intermission))
 504         {
 505                 // no zoom while dead or in intermission please
 506                 localcmd("-zoom\n");
 507                 button_zoom = FALSE;
 508         }
 509
 510         // event chase camera
 511         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 512         {
 513                 if(WantEventchase())
 514                 {
 515                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 516                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 517
 518                         // detect maximum viewoffset and use it
 519                         if(autocvar_cl_eventchase_viewoffset)
 520                         {
 521                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 522                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 523                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 524                         }
 525
 526                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 527                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 528                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 529                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 530
 531                         // make the camera smooth back
 532                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 533                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 534                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 535                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 536
 537                         makevectors(view_angles);
 538
 539                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 540                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 541
 542                         // If the boxtrace fails, revert back to line tracing.
 543                         if(trace_startsolid)
 544                         {
 545                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 546                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 547                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 548                         }
 549                         else { setproperty(VF_ORIGIN, trace_endpos); }
 550
 551                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 552                 }
 553                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 554                 {
 555                         cvar_set("chase_active", "0");
 556                         eventchase_current_distance = 0; // start from 0 next time
 557                 }
 558         }
 559         // workaround for camera stuck between player's legs when using chase_active 1
 560         // because the engine stops updating the chase_active camera when the game ends
 561         else if(intermission)
 562         {
 563                 cvar_settemp("chase_active", "-1");
 564                 eventchase_current_distance = 0;
 565         }
 566
 567         // do lockview after event chase camera so that it still applies whenever necessary.
 568         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 569         {
 570                 setproperty(VF_ORIGIN, freeze_org);
 571                 setproperty(VF_ANGLES, freeze_ang);
 572         }
 573         else
 574         {
 575                 freeze_org = getpropertyvec(VF_ORIGIN);
 576                 freeze_ang = getpropertyvec(VF_ANGLES);
 577         }
 578
 579         WarpZone_FixView();
 580         //WarpZone_FixPMove();
 581
 582         vector ov_org = '0 0 0';
 583         vector ov_mid = '0 0 0';
 584         vector ov_worldmin = '0 0 0';
 585         vector ov_worldmax = '0 0 0';
 586         if(autocvar_cl_orthoview)
 587         {
 588                 ov_worldmin = mi_picmin;
 589                 ov_worldmax = mi_picmax;
 590
 591                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 592                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 593                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 594
 595                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 596                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 597
 598                 float ov_nearest = vlen(ov_org - vec3(
 599                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 600                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 601                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 602                 ));
 603
 604                 float ov_furthest = 0;
 605                 float dist = 0;
 606
 607                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 608                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 609                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 610                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 611                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 612                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 613                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 614                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 615
 616                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 617                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 618                 cvar_settemp("r_farclip_world", "0");
 619                 cvar_settemp("r_novis", "1");
 620                 cvar_settemp("r_useportalculling", "0");
 621                 cvar_settemp("r_useinfinitefarclip", "0");
 622
 623                 setproperty(VF_ORIGIN, ov_org);
 624                 setproperty(VF_ANGLES, '90 0 0');
 625
 626                 #if 0
 627                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 628                         vtos(ov_org),
 629                         vtos(getpropertyvec(VF_ANGLES)),
 630                         ov_distance,
 631                         ov_nearest,
 632                         ov_furthest);
 633                 #endif
 634         }
 635
 636         // Render the Scene
 637         view_origin = getpropertyvec(VF_ORIGIN);
 638         view_angles = getpropertyvec(VF_ANGLES);
 639         makevectors(view_angles);
 640         view_forward = v_forward;
 641         view_right = v_right;
 642         view_up = v_up;
 643
 644 #ifdef BLURTEST
 645         if(time > blurtest_time0 && time < blurtest_time1)
 646         {
 647                 float r, t;
 648
 649                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 650                 r = t * blurtest_radius;
 651                 f = 1 / pow(t, blurtest_power) - 1;
 652
 653                 cvar_set("r_glsl_postprocess", "1");
 654                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 655         }
 656         else
 657         {
 658                 cvar_set("r_glsl_postprocess", "0");
 659                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 660         }
 661 #endif
 662
 663         TargetMusic_Advance();
 664         Fog_Force();
 665
 666         if(drawtime == 0)
 667                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 668         else
 669                 drawframetime = bound(0.000001, time - drawtime, 1);
 670         drawtime = time;
 671
 672         // watch for gametype changes here...
 673         // in ParseStuffCMD the cmd isn't executed yet :/
 674         // might even be better to add the gametype to TE_CSQC_INIT...?
 675         if(!postinit)
 676                 PostInit();
 677
 678         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 679         {
 680                 if(calledhooks & HOOK_START)
 681                 {
 682                         localcmd("\ncl_hook_gameend\n");
 683                         calledhooks |= HOOK_END;
 684                 }
 685         }
 686
 687         Announcer();
 688
 689         fov = autocvar_fov;
 690         if(fov <= 59.5)
 691         {
 692                 if(!zoomscript_caught)
 693                 {
 694                         localcmd("+button9\n");
 695                         zoomscript_caught = 1;
 696                 }
 697         }
 698         else
 699         {
 700                 if(zoomscript_caught)
 701                 {
 702                         localcmd("-button9\n");
 703                         zoomscript_caught = 0;
 704                 }
 705         }
 706
 707         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 708
 709         // next WANTED weapon (for HUD)
 710         switchweapon = getstati(STAT_SWITCHWEAPON);
 711
 712         // currently switching-to weapon (for crosshair)
 713         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 714
 715         // actually active weapon (for zoom)
 716         activeweapon = getstati(STAT_ACTIVEWEAPON);
 717
 718         f = (serverflags & SERVERFLAG_TEAMPLAY);
 719         if(f != teamplay)
 720         {
 721                 teamplay = f;
 722                 HUD_InitScores();
 723         }
 724
 725         if(last_switchweapon != switchweapon)
 726         {
 727                 weapontime = time;
 728                 last_switchweapon = switchweapon;
 729                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 730                 {
 731                         localcmd("-zoom\n");
 732                         button_zoom = FALSE;
 733                 }
 734                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 735                 {
 736                         localcmd("-fire\n");
 737                         localcmd("-fire2\n");
 738                         button_attack2 = FALSE;
 739                 }
 740         }
 741         if(last_activeweapon != activeweapon)
 742         {
 743                 last_activeweapon = activeweapon;
 744
 745                 e = get_weaponinfo(activeweapon);
 746                 if(e.netname != "")
 747                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 748                 else
 749                         localcmd("\ncl_hook_activeweapon none\n");
 750         }
 751
 752         // ALWAYS Clear Current Scene First
 753         clearscene();
 754 #ifdef WORKAROUND_XON010
 755         if(checkextension("DP_CSQC_ROTATEMOVES"))
 756         {
 757 #endif
 758         setproperty(VF_ORIGIN, view_origin);
 759         setproperty(VF_ANGLES, view_angles);
 760 #ifdef WORKAROUND_XON010
 761         }
 762 #endif
 763
 764         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 765         setproperty(VF_SIZE, vf_size);
 766         setproperty(VF_MIN, vf_min);
 767
 768         // Assign Standard Viewflags
 769         // Draw the World (and sky)
 770         setproperty(VF_DRAWWORLD, 1);
 771
 772         // Set the console size vars
 773         vid_conwidth = autocvar_vid_conwidth;
 774         vid_conheight = autocvar_vid_conheight;
 775         vid_pixelheight = autocvar_vid_pixelheight;
 776
 777         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 778         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 779
 780         // Camera for demo playback
 781         if(camera_active)
 782         {
 783                 if(autocvar_camera_enable)
 784                         CSQC_Demo_Camera();
 785                 else
 786                 {
 787                         cvar_set("chase_active", ftos(chase_active_backup));
 788                         cvar_set("cl_demo_mousegrab", "0");
 789                         camera_active = FALSE;
 790                 }
 791         }
 792 #ifdef CAMERATEST
 793         else if(autocvar_camera_enable)
 794 #else
 795         else if(autocvar_camera_enable && isdemo())
 796 #endif
 797         {
 798                 // Enable required Darkplaces cvars
 799                 chase_active_backup = autocvar_chase_active;
 800                 cvar_set("chase_active", "2");
 801                 cvar_set("cl_demo_mousegrab", "1");
 802                 camera_active = TRUE;
 803                 camera_mode = FALSE;
 804         }
 805
 806         // Draw the Crosshair
 807         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 808
 809         // Draw the Engine Status Bar (the default Quake HUD)
 810         setproperty(VF_DRAWENGINESBAR, 0);
 811
 812         // Update the mouse position
 813         /*
 814            mousepos_x = vid_conwidth;
 815            mousepos_y = vid_conheight;
 816            mousepos = mousepos*0.5 + getmousepos();
 817          */
 818
 819         e = self;
 820         for(self = world; (self = nextent(self)); )
 821                 if(self.draw)
 822                         self.draw();
 823         self = e;
 824
 825         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 826         renderscene();
 827
 828         // now switch to 2D drawing mode by calling a 2D drawing function
 829         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 830         // next R_RenderScene call
 831         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 832
 833         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 834         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 835         {
 836                 // apply night vision effect
 837                 vector tc_00, tc_01, tc_10, tc_11;
 838                 vector rgb = '0 0 0';
 839
 840                 if(!nightvision_noise)
 841                 {
 842                         nightvision_noise = spawn();
 843                         nightvision_noise.classname = "nightvision_noise";
 844                 }
 845                 if(!nightvision_noise2)
 846                 {
 847                         nightvision_noise2 = spawn();
 848                         nightvision_noise2.classname = "nightvision_noise2";
 849                 }
 850
 851                 // color tint in yellow
 852                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 853
 854                 // draw BG
 855                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 856                 rgb = '1 1 1';
 857                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 858                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 859                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 860                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 861                 tc_11 = tc_01 + tc_10 - tc_00;
 862                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 863                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 864                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 865                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 866                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 867                 R_EndPolygon();
 868
 869                 // draw FG
 870                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 871                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 872                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 873                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 874                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 875                 tc_11 = tc_01 + tc_10 - tc_00;
 876                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 877                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 878                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 879                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 880                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 881                 R_EndPolygon();
 882         }
 883
 884         if(autocvar_cl_reticle)
 885         {
 886                 // Draw the aiming reticle for weapons that use it
 887                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 888                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 889                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
 890                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
 891                 {
 892                         // no zoom reticle while dead
 893                         reticle_type = 0;
 894                 }
 895                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
 896                 {
 897                         if(reticle_image != "") { reticle_type = 2; }
 898                         else { reticle_type = 0; }
 899                 }
 900                 else if(button_zoom || zoomscript_caught)
 901                 {
 902                         // normal zoom
 903                         reticle_type = 1;
 904                 }
 905
 906                 if(reticle_type)
 907                 {
 908                         if(autocvar_cl_reticle_stretch)
 909                         {
 910                                 reticle_size_x = vid_conwidth;
 911                                 reticle_size_y = vid_conheight;
 912                                 reticle_pos_x = 0;
 913                                 reticle_pos_y = 0;
 914                         }
 915                         else
 916                         {
 917                                 reticle_size_x = max(vid_conwidth, vid_conheight);
 918                                 reticle_size_y = max(vid_conwidth, vid_conheight);
 919                                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 920                                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 921                         }
 922
 923                         if(zoomscript_caught)
 924                                 f = 1;
 925                         else
 926                                 f = current_zoomfraction;
 927
 928                         if(f)
 929                         {
 930                                 switch(reticle_type)
 931                                 {
 932                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 933                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 934                                 }
 935                         }
 936                 }
 937         }
 938         else
 939         {
 940                 if(reticle_type != 0) { reticle_type = 0; }
 941         }
 942
 943
 944         // improved polyblend
 945         if(autocvar_hud_contents)
 946         {
 947                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 948                 vector liquidcolor;
 949
 950                 switch(pointcontents(view_origin))
 951                 {
 952                         case CONTENT_WATER:
 953                                 liquidalpha = autocvar_hud_contents_water_alpha;
 954                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 955                                 incontent = 1;
 956                                 break;
 957
 958                         case CONTENT_LAVA:
 959                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 960                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 961                                 incontent = 1;
 962                                 break;
 963
 964                         case CONTENT_SLIME:
 965                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 966                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 967                                 incontent = 1;
 968                                 break;
 969
 970                         default:
 971                                 liquidalpha = 0;
 972                                 liquidcolor = '0 0 0';
 973                                 incontent = 0;
 974                                 break;
 975                 }
 976
 977                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 978                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 979                         contentfadetime = autocvar_hud_contents_fadeintime;
 980                         liquidalpha_prev = liquidalpha;
 981                         liquidcolor_prev = liquidcolor;
 982                 }
 983                 else
 984                         contentfadetime = autocvar_hud_contents_fadeouttime;
 985
 986                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 987                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 988
 989                 if(contentavgalpha)
 990                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 991
 992                 if(autocvar_hud_postprocessing)
 993                 {
 994                         if(autocvar_hud_contents_blur && contentavgalpha)
 995                         {
 996                                 content_blurpostprocess_x = 1;
 997                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 998                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 999                         }
1000                         else
1001                         {
1002                                 content_blurpostprocess_x = 0;
1003                                 content_blurpostprocess_y = 0;
1004                                 content_blurpostprocess_z = 0;
1005                         }
1006                 }
1007         }
1008
1009         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1010         {
1011                 splash_size_x = max(vid_conwidth, vid_conheight);
1012                 splash_size_y = max(vid_conwidth, vid_conheight);
1013                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
1014                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
1015
1016                 float myhealth_flash_temp;
1017                 myhealth = getstati(STAT_HEALTH);
1018
1019                 // fade out
1020                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1021                 // add new damage
1022                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1023
1024                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1025                 pain_threshold = autocvar_hud_damage_pain_threshold;
1026                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1027                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1028
1029                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1030                 {
1031                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1032                 }
1033
1034                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1035
1036                 if(myhealth_prev < 1)
1037                 {
1038                         if(myhealth >= 1)
1039                         {
1040                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1041                                 myhealth_flash_temp = 0;
1042                         }
1043                         else
1044                         {
1045                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1046                         }
1047                 }
1048
1049                 if(spectatee_status == -1 || intermission)
1050                 {
1051                         myhealth_flash = 0; // observing, or match ended
1052                         myhealth_flash_temp = 0;
1053                 }
1054
1055                 myhealth_prev = myhealth;
1056
1057                 // IDEA: change damage color/picture based on player model for robot/alien species?
1058                 // pro: matches model better
1059                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1060                 // maybe different reddish pics?
1061                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1062                 {
1063                         if(autocvar_cl_gentle_damage == 2)
1064                         {
1065                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1066                                 {
1067                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1068                                 }
1069                         }
1070                         else
1071                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1072
1073                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1074                 }
1075                 else
1076                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1077
1078                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1079                 {
1080                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1081                         {
1082                                 damage_blurpostprocess_x = 1;
1083                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1084                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1085                         }
1086                         else
1087                         {
1088                                 damage_blurpostprocess_x = 0;
1089                                 damage_blurpostprocess_y = 0;
1090                                 damage_blurpostprocess_z = 0;
1091                         }
1092                 }
1093         }
1094
1095         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1096         float e2 = (autocvar_hud_powerup != 0);
1097         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1098         {
1099                 // enable or disable rendering types if they are used or not
1100                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1101                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1102
1103                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1104                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1105                 {
1106                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1107                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1108                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1109                         {
1110                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1111                                 old_blurradius = blurradius;
1112                                 old_bluralpha = bluralpha;
1113                         }
1114                 }
1115                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1116                 {
1117                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1118                         old_blurradius = 0;
1119                         old_bluralpha = 0;
1120                 }
1121
1122                 // edge detection postprocess handling done second (used by hud_powerup)
1123                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1124                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1125                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1126
1127                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1128
1129                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1130                 {
1131                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1132                         {
1133                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1134                                 old_sharpen_intensity = sharpen_intensity;
1135                         }
1136                 }
1137                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1138                 {
1139                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1140                         old_sharpen_intensity = 0;
1141                 }
1142
1143                 if(cvar("r_glsl_postprocess") == 0)
1144                         cvar_set("r_glsl_postprocess", "2");
1145         }
1146         else if(cvar("r_glsl_postprocess") == 2)
1147                 cvar_set("r_glsl_postprocess", "0");
1148
1149         if(menu_visible)
1150                 menu_show();
1151
1152         /*if(gametype == MAPINFO_TYPE_CTF)
1153           {
1154           ctf_view();
1155           } else */
1156
1157         // draw 2D entities
1158         e = self;
1159         for(self = world; (self = nextent(self)); )
1160                 if(self.draw2d)
1161                         self.draw2d();
1162         self = e;
1163         Draw_ShowNames_All();
1164
1165         scoreboard_active = HUD_WouldDrawScoreboard();
1166
1167         // varying sound pitch
1168         damage_dealt_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
1169
1170         // detect overflow on server side
1171         if (damage_dealt_total < damage_dealt_total_prev)
1172         {
1173                 dprint("resetting dmg total: ", ftos(damage_dealt_total), " prev: ", ftos(damage_dealt_total_prev), "\n");
1174                 damage_dealt_total_prev = 0;
1175         }
1176
1177         // prevent hitsound when switching spectatee
1178         if (spectatee_status != spectatee_status_prev)
1179         {
1180                 damage_dealt_total_prev = damage_dealt_total;
1181         }
1182         spectatee_status_prev = spectatee_status;
1183
1184         // amount of damage since last hit sound
1185         float unaccounted_damage = damage_dealt_total - damage_dealt_total_prev;
1186
1187
1188         if (autocvar_cl_hitsound == 1)
1189         {
1190                 if ( time - hitsound_time_prev > autocvar_cl_hitsound_antispam_time )
1191                 if ( damage_dealt_total > 0 )
1192                 {
1193                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1194                         hitsound_time_prev = time;
1195                 }
1196         }
1197         else if (unaccounted_damage > 0 && autocvar_cl_hitsound > 0 && time - hitsound_time_prev > autocvar_cl_hitsound_antispam_time)
1198         {
1199                 // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
1200                 float a, b, c, x;
1201                 a = autocvar_cl_hitsound_max_pitch;
1202                 b = autocvar_cl_hitsound_min_pitch;
1203                 c = autocvar_cl_hitsound_nom_damage;
1204                 x = unaccounted_damage;
1205                 float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
1206
1207                 // if sound variation is disabled, set pitch_shift to 1
1208                 if (autocvar_cl_hitsound == 1)
1209                 {
1210                         pitch_shift = 1;
1211                 }
1212
1213                 // if pitch shift is reversed, mirror in (max-min)/2 + min
1214                 if (autocvar_cl_hitsound == 3)
1215                 {
1216                         float mirror_value = (a-b)/2 + b;
1217                         pitch_shift = mirror_value + (mirror_value - pitch_shift);
1218                 }
1219
1220                 dprint("dmg total (dmg): ", ftos(damage_dealt_total), " (+", ftos(unaccounted_damage), "), pitch shift: ", ftos(pitch_shift), "\n");
1221
1222                 // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
1223                 // todo: normalize sound pressure levels? seems unnecessary
1224
1225                 // scale to fit function interface
1226                 float param_pitch_shift = pitch_shift * 100;
1227
1228                 // play sound
1229                 sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, param_pitch_shift, 0);
1230
1231                 // track damage accounted for
1232                 damage_dealt_total_prev = damage_dealt_total;
1233
1234                 // remember when this sound was played to prevent sound spam
1235                 hitsound_time_prev = time;
1236         }
1237         else if (autocvar_cl_hitsound == 0)
1238         {
1239                 // forget the damage to prevent hitsound when enabling it
1240                 damage_dealt_total_prev = damage_dealt_total;
1241         }
1242
1243         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1244         if(typehit_time - typehit_time_prev > autocvar_cl_hitsound_antispam_time)
1245         {
1246                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1247                 typehit_time_prev = typehit_time;
1248         }
1249
1250         //else
1251         {
1252                 if(getstati(STAT_FROZEN))
1253                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1254                 else if (getstatf(STAT_HEALING_ORB)>time)
1255                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1256                 if(!intermission)
1257                 if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1258                 {
1259                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1260                         drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1261                 }
1262                 else if(getstatf(STAT_REVIVE_PROGRESS))
1263                 {
1264                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1265                         drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1266                 }
1267
1268                 if(autocvar_r_letterbox == 0)
1269                         if(autocvar_viewsize < 120)
1270                                 CSQC_common_hud();
1271
1272                 // crosshair goes VERY LAST
1273                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1274                 {
1275                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1276                                 return;
1277
1278                         string wcross_style;
1279                         float wcross_alpha, wcross_resolution;
1280                         wcross_style = autocvar_crosshair;
1281                         if (wcross_style == "0")
1282                                 return;
1283                         wcross_resolution = autocvar_crosshair_size;
1284                         if (wcross_resolution == 0)
1285                                 return;
1286                         wcross_alpha = autocvar_crosshair_alpha;
1287                         if (wcross_alpha == 0)
1288                                 return;
1289
1290                         // TrueAim check
1291                         float shottype;
1292
1293                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1294                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1295                         wcross_origin_z = 0;
1296                         if(autocvar_crosshair_hittest)
1297                         {
1298                                 vector wcross_oldorigin;
1299                                 wcross_oldorigin = wcross_origin;
1300                                 shottype = TrueAimCheck();
1301                                 if(shottype == SHOTTYPE_HITWORLD)
1302                                 {
1303                                         v = wcross_origin - wcross_oldorigin;
1304                                         v_x /= vid_conwidth;
1305                                         v_y /= vid_conheight;
1306                                         if(vlen(v) > 0.01)
1307                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1308                                 }
1309                                 if(!autocvar_crosshair_hittest_showimpact)
1310                                         wcross_origin = wcross_oldorigin;
1311                         }
1312                         else
1313                                 shottype = SHOTTYPE_HITWORLD;
1314
1315                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1316                         string wcross_name = "";
1317                         float wcross_scale, wcross_blur;
1318
1319                         if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1320                         {
1321                                 e = get_weaponinfo(switchingweapon);
1322                                 if(e)
1323                                 {
1324                                         if(autocvar_crosshair_per_weapon)
1325                                         {
1326                                                 // WEAPONTODO: access these through some general settings (with non-balance config settings)
1327                                                 //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1328                                                 //if (wcross_resolution == 0)
1329                                                         //return;
1330
1331                                                 //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1332                                                 wcross_resolution *= e.w_crosshair_size;
1333                                                 wcross_name = e.w_crosshair;
1334                                         }
1335                                 }
1336                         }
1337
1338                         if(wcross_name == "")
1339                                 wcross_name = strcat("gfx/crosshair", wcross_style);
1340
1341                         // MAIN CROSSHAIR COLOR DECISION
1342                         switch(autocvar_crosshair_color_special)
1343                         {
1344                                 case 1: // crosshair_color_per_weapon
1345                                 {
1346                                         if(e)
1347                                         {
1348                                                 wcross_color = e.wpcolor;
1349                                                 break;
1350                                         }
1351                                         else { goto normalcolor; }
1352                                 }
1353
1354                                 case 2: // crosshair_color_by_health
1355                                 {
1356                                         float x = getstati(STAT_HEALTH);
1357
1358                                         //x = red
1359                                         //y = green
1360                                         //z = blue
1361
1362                                         wcross_color_z = 0;
1363
1364                                         if(x > 200)
1365                                         {
1366                                                 wcross_color_x = 0;
1367                                                 wcross_color_y = 1;
1368                                         }
1369                                         else if(x > 150)
1370                                         {
1371                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1372                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1373                                         }
1374                                         else if(x > 100)
1375                                         {
1376                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1377                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1378                                                 wcross_color_z = 1 - (x-100)*0.02;
1379                                         }
1380                                         else if(x > 50)
1381                                         {
1382                                                 wcross_color_x = 1;
1383                                                 wcross_color_y = 1;
1384                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1385                                         }
1386                                         else if(x > 20)
1387                                         {
1388                                                 wcross_color_x = 1;
1389                                                 wcross_color_y = (x-20)*90/27/100;
1390                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1391                                         }
1392                                         else
1393                                         {
1394                                                 wcross_color_x = 1;
1395                                                 wcross_color_y = 0;
1396                                         }
1397                                         break;
1398                                 }
1399
1400                                 case 3: // crosshair_color_rainbow
1401                                 {
1402                                         if(time >= rainbow_last_flicker)
1403                                         {
1404                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1405                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1406                                         }
1407                                         wcross_color = rainbow_prev_color;
1408                                         break;
1409                                 }
1410                                 :normalcolor
1411                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1412                         }
1413
1414                         if(autocvar_crosshair_effect_scalefade)
1415                         {
1416                                 wcross_scale = wcross_resolution;
1417                                 wcross_resolution = 1;
1418                         }
1419                         else
1420                         {
1421                                 wcross_scale = 1;
1422                         }
1423
1424                         if(autocvar_crosshair_pickup)
1425                         {
1426                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1427
1428                                 if(pickup_crosshair_time < stat_pickup_time)
1429                                 {
1430                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1431                                                 pickup_crosshair_size = 1;
1432
1433                                         pickup_crosshair_time = stat_pickup_time;
1434                                 }
1435
1436                                 if(pickup_crosshair_size > 0)
1437                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1438                                 else
1439                                         pickup_crosshair_size = 0;
1440
1441                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1442                         }
1443
1444                         // todo: make crosshair hit indication dependent on damage dealt
1445                         if(autocvar_crosshair_hitindication)
1446                         {
1447                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1448
1449                                 if(unaccounted_damage)
1450                                 {
1451                                         hitindication_crosshair_size = 1;
1452                                 }
1453
1454                                 if(hitindication_crosshair_size > 0)
1455                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1456                                 else
1457                                         hitindication_crosshair_size = 0;
1458
1459                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1460                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1461                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1462                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1463                         }
1464
1465                         if(shottype == SHOTTYPE_HITENEMY)
1466                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1467                         if(shottype == SHOTTYPE_HITTEAM)
1468                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1469
1470                         f = fabs(autocvar_crosshair_effect_time);
1471                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1472                         {
1473                                 wcross_changedonetime = time + f;
1474                         }
1475                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1476                         {
1477                                 wcross_name_changestarttime = time;
1478                                 wcross_name_changedonetime = time + f;
1479                                 if(wcross_name_goal_prev_prev)
1480                                         strunzone(wcross_name_goal_prev_prev);
1481                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1482                                 wcross_name_goal_prev = strzone(wcross_name);
1483                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1484                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1485                                 wcross_resolution_goal_prev = wcross_resolution;
1486                         }
1487
1488                         wcross_scale_goal_prev = wcross_scale;
1489                         wcross_alpha_goal_prev = wcross_alpha;
1490                         wcross_color_goal_prev = wcross_color;
1491
1492                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1493                         {
1494                                 wcross_blur = 1;
1495                                 wcross_alpha *= 0.75;
1496                         }
1497                         else
1498                                 wcross_blur = 0;
1499                         // *_prev is at time-frametime
1500                         // * is at wcross_changedonetime+f
1501                         // what do we have at time?
1502                         if(time < wcross_changedonetime)
1503                         {
1504                                 f = frametime / (wcross_changedonetime - time + frametime);
1505                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1506                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1507                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1508                         }
1509
1510                         wcross_scale_prev = wcross_scale;
1511                         wcross_alpha_prev = wcross_alpha;
1512                         wcross_color_prev = wcross_color;
1513
1514                         wcross_scale *= 1 - autocvar__menu_alpha;
1515                         wcross_alpha *= 1 - autocvar__menu_alpha;
1516                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1517
1518                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1519                         {
1520                                 // crosshair rings for weapon stats
1521                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1522                                 {
1523                                         // declarations and stats
1524                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1525                                         string ring_image = string_null, ring_inner_image = string_null;
1526                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1527
1528                                         ring_scale = autocvar_crosshair_ring_size;
1529
1530                                         float weapon_clipload, weapon_clipsize;
1531                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1532                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1533
1534                                         float vortex_charge, vortex_chargepool;
1535                                         vortex_charge = getstatf(STAT_VORTEX_CHARGE);
1536                                         vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
1537
1538                                         float arc_heat = getstatf(STAT_ARC_HEAT);
1539
1540                                         if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1541                                                 vortex_charge_movingavg = vortex_charge;
1542
1543
1544                                         // handle the values
1545                                         if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1546                                         {
1547                                                 if (vortex_chargepool || use_vortex_chargepool) {
1548                                                         use_vortex_chargepool = 1;
1549                                                         ring_inner_value = vortex_chargepool;
1550                                                 } else {
1551                                                         vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1552                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1553                                                 }
1554
1555                                                 ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1556                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1557                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1558
1559                                                 // draw the outer ring to show the current charge of the weapon
1560                                                 ring_value = vortex_charge;
1561                                                 ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1562                                                 ring_rgb = wcross_color;
1563                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1564                                         }
1565                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1566                                         {
1567                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1568                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1569                                                 ring_rgb = wcross_color;
1570                                                 ring_image = "gfx/crosshair_ring.tga";
1571                                         }
1572                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1573                                         {
1574                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1575                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1576                                                 ring_rgb = wcross_color;
1577                                                 ring_image = "gfx/crosshair_ring.tga";
1578                                         }
1579
1580                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1581                                         {
1582                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1583                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1584                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1585                                                 ring_rgb = wcross_color;
1586
1587                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1588                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1589                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1590                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1591                                                 else
1592                                                         ring_image = "gfx/crosshair_ring.tga";
1593                                         }
1594                                         else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1595                                         {
1596                                                 ring_value = arc_heat;
1597                                                 ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1598                                                         arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1599                                                 ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1600                                                 ring_image = "gfx/crosshair_ring.tga";
1601                                         }
1602
1603                                         // if in weapon switch animation, fade ring out/in
1604                                         if(autocvar_crosshair_effect_time > 0)
1605                                         {
1606                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1607                                                 if (!(f < 1))
1608                                                 {
1609                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1610                                                 }
1611
1612                                                 if(wcross_ring_prev)
1613                                                 {
1614                                                         if(f < 1)
1615                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1616                                                 }
1617                                                 else
1618                                                 {
1619                                                         if(f < 1)
1620                                                                 ring_alpha *= bound(0, f, 1);
1621                                                 }
1622                                         }
1623
1624                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1625                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1626
1627                                         if (ring_value)
1628                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1629                                 }
1630
1631 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1632                                 do \
1633                                 { \
1634                                         if(wcross_blur > 0) \
1635                                         { \
1636                                                 for(i = -2; i <= 2; ++i) \
1637                                                 for(j = -2; j <= 2; ++j) \
1638                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1639                                         } \
1640                                         else \
1641                                         { \
1642                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1643                                         } \
1644                                 } \
1645                                 while(0)
1646
1647 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1648                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1649
1650 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1651                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1652
1653                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1654                                 {
1655                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1656                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1657                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1658                                         f = 1 - f;
1659                                 }
1660                                 else
1661                                 {
1662                                         f = 1;
1663                                 }
1664                                 wcross_name_alpha_goal_prev = f;
1665
1666                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1667                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1668
1669                                 if(autocvar_crosshair_dot)
1670                                 {
1671                                         vector wcross_color_old;
1672                                         wcross_color_old = wcross_color;
1673
1674                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1675                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1676
1677                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1678                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1679                                         wcross_color = wcross_color_old;
1680                                 }
1681                         }
1682                 }
1683                 else
1684                 {
1685                         wcross_scale_prev = 0;
1686                         wcross_alpha_prev = 0;
1687                         wcross_scale_goal_prev = 0;
1688                         wcross_alpha_goal_prev = 0;
1689                         wcross_changedonetime = 0;
1690                         if(wcross_name_goal_prev)
1691                                 strunzone(wcross_name_goal_prev);
1692                         wcross_name_goal_prev = string_null;
1693                         if(wcross_name_goal_prev_prev)
1694                                 strunzone(wcross_name_goal_prev_prev);
1695                         wcross_name_goal_prev_prev = string_null;
1696                         wcross_name_changestarttime = 0;
1697                         wcross_name_changedonetime = 0;
1698                         wcross_name_alpha_goal_prev = 0;
1699                         wcross_name_alpha_goal_prev_prev = 0;
1700                         wcross_resolution_goal_prev = 0;
1701                         wcross_resolution_goal_prev_prev = 0;
1702                 }
1703         }
1704
1705         if(NextFrameCommand)
1706         {
1707                 localcmd("\n", NextFrameCommand, "\n");
1708                 NextFrameCommand = string_null;
1709         }
1710
1711         // we must do this check AFTER a frame was rendered, or it won't work
1712         if(cs_project_is_b0rked == 0)
1713         {
1714                 string w0, h0;
1715                 w0 = ftos(autocvar_vid_conwidth);
1716                 h0 = ftos(autocvar_vid_conheight);
1717                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1718                 //setproperty(VF_FOV, '90 90 0');
1719                 setproperty(VF_ORIGIN, '0 0 0');
1720                 setproperty(VF_ANGLES, '0 0 0');
1721                 setproperty(VF_PERSPECTIVE, 1);
1722                 makevectors('0 0 0');
1723                 vector v1, v2;
1724                 cvar_set("vid_conwidth", "800");
1725                 cvar_set("vid_conheight", "600");
1726                 v1 = cs_project(v_forward);
1727                 cvar_set("vid_conwidth", "640");
1728                 cvar_set("vid_conheight", "480");
1729                 v2 = cs_project(v_forward);
1730                 if(v1 == v2)
1731                         cs_project_is_b0rked = 1;
1732                 else
1733                         cs_project_is_b0rked = -1;
1734                 cvar_set("vid_conwidth", w0);
1735                 cvar_set("vid_conheight", h0);
1736         }
1737
1738         if(autocvar__hud_configure)
1739                 HUD_Panel_Mouse();
1740
1741     if(hud && !intermission)
1742     {
1743         if(hud == HUD_SPIDERBOT)
1744             CSQC_SPIDER_HUD();
1745         else if(hud == HUD_WAKIZASHI)
1746             CSQC_WAKIZASHI_HUD();
1747         else if(hud == HUD_RAPTOR)
1748             CSQC_RAPTOR_HUD();
1749         else if(hud == HUD_BUMBLEBEE)
1750             CSQC_BUMBLE_HUD();
1751         else if(hud == HUD_BUMBLEBEE_GUN)
1752             CSQC_BUMBLE_GUN_HUD();
1753     }
1754
1755         cl_notice_run();
1756
1757         // let's reset the view back to normal for the end
1758         setproperty(VF_MIN, '0 0 0');
1759         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1760 }
1761
1762
1763 void CSQC_common_hud(void)
1764 {
1765         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1766                 Accuracy_LoadLevels();
1767
1768         HUD_Main(); // always run these functions for alpha checks
1769         HUD_DrawScoreboard();
1770
1771         if (scoreboard_active) // scoreboard/accuracy
1772                 HUD_Reset();
1773         else if (intermission == 2) // map voting screen
1774         {
1775                 MapVote_Draw();
1776                 HUD_Reset();
1777         }
1778 }
1779
1780
1781 // following vectors must be global to allow seamless switching between camera modes
1782 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1783 void CSQC_Demo_Camera()
1784 {
1785         float speed, attenuation, dimensions;
1786         vector tmp, delta;
1787
1788         if( autocvar_camera_reset || !camera_mode )
1789         {
1790                 camera_offset = '0 0 0';
1791                 current_angles = '0 0 0';
1792                 camera_direction = '0 0 0';
1793                 camera_offset_z += 30;
1794                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1795                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1796                 current_origin = view_origin;
1797                 current_camera_offset  = camera_offset;
1798                 cvar_set("camera_reset", "0");
1799                 camera_mode = CAMERA_CHASE;
1800         }
1801
1802         // Camera angles
1803         if( camera_roll )
1804                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1805
1806         if(autocvar_camera_look_player)
1807         {
1808                 vector dir;
1809                 float n;
1810
1811                 dir = normalize(view_origin - current_position);
1812                 n = mouse_angles_z;
1813                 mouse_angles = vectoangles(dir);
1814                 mouse_angles_x = mouse_angles_x * -1;
1815                 mouse_angles_z = n;
1816         }
1817         else
1818         {
1819                 tmp = getmousepos() * 0.1;
1820                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1821                 {
1822                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1823                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1824                 }
1825         }
1826
1827         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1828         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1829         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1830         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1831
1832         // Fix difference when angles don't have the same sign
1833         delta = '0 0 0';
1834         if(mouse_angles_y < -60 && current_angles_y > 60)
1835                 delta = '0 360 0';
1836         if(mouse_angles_y > 60 && current_angles_y < -60)
1837                 delta = '0 -360 0';
1838
1839         if(autocvar_camera_look_player)
1840                 attenuation = autocvar_camera_look_attenuation;
1841         else
1842                 attenuation = autocvar_camera_speed_attenuation;
1843
1844         attenuation = 1 / max(1, attenuation);
1845         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1846
1847         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1848         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1849         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1850         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1851
1852         // Camera position
1853         tmp = '0 0 0';
1854         dimensions = 0;
1855
1856         if( camera_direction_x )
1857         {
1858                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1859                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1860                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1861                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1862                 ++dimensions;
1863         }
1864
1865         if( camera_direction_y )
1866         {
1867                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1868                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1869                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1870                 ++dimensions;
1871         }
1872
1873         if( camera_direction_z )
1874         {
1875                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1876                 ++dimensions;
1877         }
1878
1879         if(autocvar_camera_free)
1880                 speed = autocvar_camera_speed_free;
1881         else
1882                 speed = autocvar_camera_speed_chase;
1883
1884         if(dimensions)
1885         {
1886                 speed = speed * sqrt(1 / dimensions);
1887                 camera_offset += tmp * speed;
1888         }
1889
1890         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1891
1892         // Camera modes
1893         if( autocvar_camera_free )
1894         {
1895                 if ( camera_mode == CAMERA_CHASE )
1896                 {
1897                         current_camera_offset = current_origin + current_camera_offset;
1898                         camera_offset = current_origin + camera_offset;
1899                 }
1900
1901                 camera_mode = CAMERA_FREE;
1902                 current_position = current_camera_offset;
1903         }
1904         else
1905         {
1906                 if ( camera_mode == CAMERA_FREE )
1907                 {
1908                         current_origin = view_origin;
1909                         camera_offset = camera_offset - current_origin;
1910                         current_camera_offset = current_camera_offset - current_origin;
1911                 }
1912
1913                 camera_mode = CAMERA_CHASE;
1914
1915                 if(autocvar_camera_chase_smoothly)
1916                         current_origin += (view_origin - current_origin) * attenuation;
1917                 else
1918                         current_origin = view_origin;
1919
1920                 current_position = current_origin + current_camera_offset;
1921         }
1922
1923         setproperty(VF_ANGLES, current_angles);
1924         setproperty(VF_ORIGIN, current_position);
1925 }