qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 /**
  82  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  83  *
  84  * TODO: Use a better solution where a common shared entitiy is used that contains
  85  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  86  * and STAT_FRAGLIMIT to be auto-sent)
  87  */
  88 void CheckForGamestartChange() {
  89         float startTime;
  90         startTime = getstatf(STAT_GAMESTARTTIME);
  91         if (previous_game_starttime != startTime) {
  92                 if ((time + 5.0) < startTime) {
  93                         //if connecting to server while restart was active don't always play prepareforbattle
  94                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  95                 }
  96                 if (time < startTime) {
  97                         restartAnnouncer = spawn();
  98                         restartAnnouncer.think = restartAnnouncer_Think;
  99                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 100                 }
 101         }
 102         previous_game_starttime = startTime;
 103 }
 104
 105 void Porto_Init()
 106 {
 107         porto = spawn();
 108         porto.classname = "porto";
 109         porto.draw = Porto_Draw;
 110         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 111 }
 112
 113 float drawtime;
 114 float avgspeed;
 115 vector GetCurrentFov(float fov)
 116 {
 117         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 118
 119         zoomsensitivity = autocvar_cl_zoomsensitivity;
 120         zoomfactor = autocvar_cl_zoomfactor;
 121         if(zoomfactor < 1 || zoomfactor > 16)
 122                 zoomfactor = 2.5;
 123         zoomspeed = autocvar_cl_zoomspeed;
 124         if(zoomspeed >= 0)
 125                 if(zoomspeed < 0.5 || zoomspeed > 16)
 126                         zoomspeed = 3.5;
 127
 128         zoomdir = button_zoom;
 129         if(hud == HUD_NORMAL)
 130         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 131                 zoomdir += button_attack2;
 132         if(spectatee_status > 0 || isdemo())
 133         {
 134                 if(spectatorbutton_zoom)
 135                 {
 136                         if(zoomdir)
 137                                 zoomdir = 0;
 138                         else
 139                                 zoomdir = 1;
 140                 }
 141                 // fteqcc failed twice here already, don't optimize this
 142         }
 143
 144         if(zoomdir)
 145                 zoomin_effect = 0;
 146
 147         if(zoomin_effect || camera_active)
 148         {
 149                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 150         }
 151         else
 152         {
 153                 if(zoomspeed < 0) // instant zoom
 154                 {
 155                         if(zoomdir)
 156                                 current_viewzoom = 1 / zoomfactor;
 157                         else
 158                                 current_viewzoom = 1;
 159                 }
 160                 else
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 164                         else
 165                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 166                 }
 167         }
 168
 169         if(almost_equals(current_viewzoom, 1))
 170                 current_zoomfraction = 0;
 171         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 172                 current_zoomfraction = 1;
 173         else
 174                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 175
 176         if(zoomsensitivity < 1)
 177                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 178         else
 179                 setsensitivityscale(1);
 180
 181         if (autocvar_cl_velocityzoom)
 182         {
 183                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 184                 avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 185                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 186                 //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 187         }
 188         else
 189                 velocityzoom = 1;
 190
 191         float frustumx, frustumy, fovx, fovy;
 192         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 193         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 194         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 195         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 196
 197         return '1 0 0' * fovx + '0 1 0' * fovy;
 198 }
 199
 200 // this function must match W_SetupShot!
 201 float zoomscript_caught;
 202
 203 vector wcross_origin;
 204 float wcross_scale_prev, wcross_alpha_prev;
 205 vector wcross_color_prev;
 206 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 207 vector wcross_color_goal_prev;
 208 float wcross_changedonetime;
 209
 210 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 211 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 212 float wcross_name_changestarttime, wcross_name_changedonetime;
 213 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 214 entity trueaim;
 215 entity trueaim_rifle;
 216
 217 #define SHOTTYPE_HITTEAM 1
 218 #define SHOTTYPE_HITOBSTRUCTION 2
 219 #define SHOTTYPE_HITWORLD 3
 220 #define SHOTTYPE_HITENEMY 4
 221
 222 void TrueAim_Init()
 223 {
 224         trueaim = spawn();
 225         trueaim.classname = "trueaim";
 226         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 227         trueaim_rifle = spawn();
 228         trueaim_rifle.classname = "trueaim_rifle";
 229         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230 }
 231
 232 float EnemyHitCheck()
 233 {
 234         float t;
 235         wcross_origin = project_3d_to_2d(trace_endpos);
 236         wcross_origin_z = 0;
 237         if(trace_networkentity < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(trace_networkentity > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(trace_networkentity - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == COLOR_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float reticle_type;
 344 string NextFrameCommand;
 345 void CSQC_SPIDER_HUD();
 346 void CSQC_RAPTOR_HUD();
 347
 348 vector freeze_org, freeze_ang;
 349 entity nightvision_noise, nightvision_noise2;
 350
 351 #define MAX_TIME_DIFF 5
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353 float hit_time, typehit_time;
 354 float nextsound_hit_time, nextsound_typehit_time;
 355 float hitindication_crosshair_time, hitindication_crosshair_size;
 356 float use_nex_chargepool;
 357
 358 float myhealth, myhealth_prev;
 359 float myhealth_flash;
 360
 361 float old_blurradius, old_bluralpha;
 362 float old_sharpen_intensity;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float eventchase_current_distance;
 370
 371 vector damage_blurpostprocess, content_blurpostprocess;
 372
 373 float checkfail[16];
 374
 375 void CSQC_UpdateView(float w, float h)
 376 {
 377         entity e;
 378         float fov;
 379         float f, i, j;
 380         vector v;
 381         vector vf_size, vf_min;
 382         float a;
 383         hud = getstati(STAT_HUD);
 384
 385         button_attack2 = (input_buttons & BUTTON_3);
 386         button_zoom = (input_buttons & BUTTON_4);
 387
 388         // FIXME do we need this hack?
 389         if(isdemo())
 390         {
 391                 // in demos, input_buttons do not work
 392                 button_zoom = (autocvar__togglezoom == "-");
 393         }
 394
 395 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 396         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 397         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 398         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 399         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 400         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 401         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 402
 403         vf_size = R_SetView3fv(VF_SIZE);
 404         vf_min = R_SetView3fv(VF_MIN);
 405         vid_width = vf_size_x;
 406         vid_height = vf_size_y;
 407
 408         vector reticle_pos, reticle_size;
 409         vector splash_pos, splash_size;
 410
 411         WaypointSprite_Load();
 412
 413         if(spectatee_status)
 414                 myteam = GetPlayerColor(spectatee_status - 1);
 415         else
 416                 myteam = GetPlayerColor(player_localentnum - 1);
 417
 418         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 419
 420         // event chase camera
 421         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 422         {
 423                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 424                 {
 425                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 426                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
 427
 428                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 429                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 430                         if(!autocvar_chase_active)
 431                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 432
 433                         // make the camera smooth back
 434                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 435                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 436                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 437                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 438
 439                         vector eventchase_target_origin;
 440                         makevectors(view_angles);
 441                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 442                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 443                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 444                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 445                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 446                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 447                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 448
 449                         R_SetView(VF_ORIGIN, trace_endpos);
 450                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 451                 }
 452                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 453                 {
 454                         cvar_set("chase_active", "0");
 455                         eventchase_current_distance = 0; // start from 0 next time
 456                 }
 457         }
 458
 459         // do lockview after event chase camera so that it still applies whenever necessary.
 460         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 461         {
 462                 R_SetView(VF_ORIGIN, freeze_org);
 463                 R_SetView(VF_ANGLES, freeze_ang);
 464         }
 465         else
 466         {
 467                 freeze_org = R_SetView3fv(VF_ORIGIN);
 468                 freeze_ang = R_SetView3fv(VF_ANGLES);
 469         }
 470
 471         WarpZone_FixView();
 472         //WarpZone_FixPMove();
 473
 474         // Render the Scene
 475         view_origin = R_SetView3fv(VF_ORIGIN);
 476         view_angles = R_SetView3fv(VF_ANGLES);
 477         makevectors(view_angles);
 478         view_forward = v_forward;
 479         view_right = v_right;
 480         view_up = v_up;
 481
 482 #ifdef BLURTEST
 483         if(time > blurtest_time0 && time < blurtest_time1)
 484         {
 485                 float r, t;
 486
 487                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 488                 r = t * blurtest_radius;
 489                 f = 1 / pow(t, blurtest_power) - 1;
 490
 491                 cvar_set("r_glsl_postprocess", "1");
 492                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 493         }
 494         else
 495         {
 496                 cvar_set("r_glsl_postprocess", "0");
 497                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 498         }
 499 #endif
 500
 501         TargetMusic_Advance();
 502         Fog_Force();
 503
 504         if(drawtime == 0)
 505                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 506         else
 507                 drawframetime = bound(0.000001, time - drawtime, 1);
 508         drawtime = time;
 509
 510         // watch for gametype changes here...
 511         // in ParseStuffCMD the cmd isn't executed yet :/
 512         // might even be better to add the gametype to TE_CSQC_INIT...?
 513         if(!postinit)
 514                 PostInit();
 515
 516         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 517                 if(calledhooks & HOOK_START)
 518                 {
 519                         localcmd("\ncl_hook_gameend\n");
 520                         calledhooks |= HOOK_END;
 521                 }
 522
 523         CheckForGamestartChange();
 524         serverAnnouncer();
 525         maptimeAnnouncer();
 526         carrierAnnouncer();
 527
 528         fov = autocvar_fov;
 529         if(fov <= 59.5)
 530         {
 531                 if(!zoomscript_caught)
 532                 {
 533                         localcmd("+button9\n");
 534                         zoomscript_caught = 1;
 535                 }
 536         }
 537         else
 538         {
 539                 if(zoomscript_caught)
 540                 {
 541                         localcmd("-button9\n");
 542                         zoomscript_caught = 0;
 543                 }
 544         }
 545
 546         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 547         activeswitchweapon = getstati(STAT_SWITCHWEAPON);
 548         activeweapon = getstati(STAT_WEAPON);
 549         f = (serverflags & SERVERFLAG_TEAMPLAY);
 550         if(f != teamplay)
 551         {
 552                 teamplay = f;
 553                 HUD_InitScores();
 554         }
 555
 556         if(last_weapon != activeweapon) {
 557                 weapontime = time;
 558                 last_weapon = activeweapon;
 559
 560                 e = get_weaponinfo(activeweapon);
 561                 if(e.netname != "")
 562                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 563                 else
 564                         localcmd("\ncl_hook_activeweapon none\n");
 565         }
 566
 567         // ALWAYS Clear Current Scene First
 568         R_ClearScene();
 569 #ifdef WORKAROUND_XON010
 570         if(checkextension("DP_CSQC_ROTATEMOVES"))
 571         {
 572 #endif
 573         R_SetView(VF_ORIGIN, view_origin);
 574         R_SetView(VF_ANGLES, view_angles);
 575 #ifdef WORKAROUND_XON010
 576         }
 577 #endif
 578
 579         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 580         R_SetView(VF_SIZE, vf_size);
 581         R_SetView(VF_MIN, vf_min);
 582
 583         // Assign Standard Viewflags
 584         // Draw the World (and sky)
 585         R_SetView(VF_DRAWWORLD, 1);
 586
 587         // Set the console size vars
 588         vid_conwidth = autocvar_vid_conwidth;
 589         vid_conheight = autocvar_vid_conheight;
 590         vid_pixelheight = autocvar_vid_pixelheight;
 591
 592         R_SetView(VF_FOV, GetCurrentFov(fov));
 593
 594         // Camera for demo playback
 595         if(camera_active)
 596         {
 597                 if(autocvar_camera_enable)
 598                         CSQC_Demo_Camera();
 599                 else
 600                 {
 601                         cvar_set("chase_active", ftos(chase_active_backup));
 602                         cvar_set("cl_demo_mousegrab", "0");
 603                         camera_active = FALSE;
 604                 }
 605         }
 606 #ifdef CAMERATEST
 607         else if(autocvar_camera_enable)
 608 #else
 609         else if(autocvar_camera_enable && isdemo())
 610 #endif
 611         {
 612                 // Enable required Darkplaces cvars
 613                 chase_active_backup = autocvar_chase_active;
 614                 cvar_set("chase_active", "2");
 615                 cvar_set("cl_demo_mousegrab", "1");
 616                 camera_active = TRUE;
 617                 camera_mode = FALSE;
 618         }
 619
 620         // Draw the Crosshair
 621         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 622
 623         // Draw the Engine Status Bar (the default Quake HUD)
 624         R_SetView(VF_DRAWENGINEHUD, 0);
 625
 626         // Update the mouse position
 627         /*
 628            mousepos_x = vid_conwidth;
 629            mousepos_y = vid_conheight;
 630            mousepos = mousepos*0.5 + getmousepos();
 631          */
 632
 633         e = self;
 634         for(self = world; (self = nextent(self)); )
 635                 if(self.draw)
 636                         self.draw();
 637         self = e;
 638
 639         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 640         R_RenderScene();
 641
 642         // now switch to 2D drawing mode by calling a 2D drawing function
 643         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 644         // next R_RenderScene call
 645         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 646
 647         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 648         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 649         {
 650                 // apply night vision effect
 651                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 652
 653                 if(!nightvision_noise)
 654                 {
 655                         nightvision_noise = spawn();
 656                         nightvision_noise.classname = "nightvision_noise";
 657                 }
 658                 if(!nightvision_noise2)
 659                 {
 660                         nightvision_noise2 = spawn();
 661                         nightvision_noise2.classname = "nightvision_noise2";
 662                 }
 663
 664                 // color tint in yellow
 665                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 666
 667                 // draw BG
 668                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 669                 rgb = '1 1 1';
 670                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 671                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 672                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 673                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 674                 tc_11 = tc_01 + tc_10 - tc_00;
 675                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 676                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 677                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 678                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 679                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 680                 R_EndPolygon();
 681
 682                 // draw FG
 683                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 684                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 685                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 686                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 687                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 688                 tc_11 = tc_01 + tc_10 - tc_00;
 689                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 690                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 691                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 692                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 693                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 694                 R_EndPolygon();
 695         }
 696
 697         // Draw the aiming reticle for weapons that use it
 698         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 699         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 700         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 701         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 702                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 703         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 704                 reticle_type = 2; // nex zoom
 705         else if(button_zoom || zoomscript_caught)
 706                 reticle_type = 1; // normal zoom
 707         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 708                 reticle_type = 2; // nex zoom
 709
 710         if (reticle_type)
 711         {
 712                 if(autocvar_cl_reticle_stretch)
 713                 {
 714                         reticle_size_x = vid_conwidth;
 715                         reticle_size_y = vid_conheight;
 716                         reticle_pos_x = 0;
 717                         reticle_pos_y = 0;
 718                 }
 719                 else
 720                 {
 721                         reticle_size_x = max(vid_conwidth, vid_conheight);
 722                         reticle_size_y = max(vid_conwidth, vid_conheight);
 723                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 724                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 725                 }
 726
 727                 f = current_zoomfraction;
 728                 if(zoomscript_caught)
 729                         f = 1;
 730                 if(autocvar_cl_reticle_item_normal)
 731                 {
 732                         if(reticle_type == 1 && f)
 733                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 734                 }
 735                 if(autocvar_cl_reticle_item_nex)
 736                 {
 737                         if(reticle_type == 2 && f)
 738                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 739                 }
 740         }
 741
 742
 743         // improved polyblend
 744         vector rgb;
 745         if(autocvar_hud_contents)
 746         {
 747                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 748                 vector liquidcolor;
 749
 750                 switch(pointcontents(view_origin))
 751                 {
 752                         case CONTENT_WATER:
 753                                 liquidalpha = autocvar_hud_contents_water_alpha;
 754                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 755                                 incontent = 1;
 756                                 break;
 757
 758                         case CONTENT_LAVA:
 759                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 760                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 761                                 incontent = 1;
 762                                 break;
 763
 764                         case CONTENT_SLIME:
 765                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 766                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 767                                 incontent = 1;
 768                                 break;
 769
 770                         default:
 771                                 liquidalpha = 0;
 772                                 liquidcolor = '0 0 0';
 773                                 incontent = 0;
 774                                 break;
 775                 }
 776
 777                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 778                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 779                         contentfadetime = autocvar_hud_contents_fadeintime;
 780                         liquidalpha_prev = liquidalpha;
 781                         liquidcolor_prev = liquidcolor;
 782                 }
 783                 else
 784                         contentfadetime = autocvar_hud_contents_fadeouttime;
 785
 786                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 787                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 788
 789                 if(contentavgalpha)
 790                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 791
 792                 if(autocvar_hud_postprocessing)
 793                 {
 794                         if(autocvar_hud_contents_blur && contentavgalpha)
 795                         {
 796                                 content_blurpostprocess_x = 1;
 797                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 798                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 799                         }
 800                         else
 801                         {
 802                                 content_blurpostprocess_x = 0;
 803                                 content_blurpostprocess_y = 0;
 804                                 content_blurpostprocess_z = 0;
 805                         }
 806                 }
 807         }
 808
 809         if(autocvar_hud_damage && !autocvar_chase_active)
 810         {
 811                 splash_size_x = max(vid_conwidth, vid_conheight);
 812                 splash_size_y = max(vid_conwidth, vid_conheight);
 813                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 814                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 815
 816                 float myhealth_flash_temp;
 817                 myhealth = getstati(STAT_HEALTH);
 818
 819                 // fade out
 820                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 821                 // add new damage
 822                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 823
 824                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 825                 pain_threshold = autocvar_hud_damage_pain_threshold;
 826                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 827                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 828
 829                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 830                 {
 831                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 832                 }
 833
 834                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 835
 836                 if(myhealth_prev < 1)
 837                 {
 838                         if(myhealth >= 1)
 839                         {
 840                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 841                                 myhealth_flash_temp = 0;
 842                         }
 843                         else
 844                         {
 845                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 846                         }
 847                 }
 848
 849                 if(spectatee_status == -1 || intermission)
 850                 {
 851                         myhealth_flash = 0; // observing, or match ended
 852                         myhealth_flash_temp = 0;
 853                 }
 854
 855                 myhealth_prev = myhealth;
 856
 857                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 858                 {
 859                         if(autocvar_cl_gentle_damage == 2)
 860                         {
 861                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 862                                 {
 863                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 864                                 }
 865                         }
 866                         else
 867                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 868
 869                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 870                 }
 871                 else
 872                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 873
 874                 if(autocvar_hud_postprocessing)
 875                 {
 876                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 877                         {
 878                                 damage_blurpostprocess_x = 1;
 879                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 880                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 881                         }
 882                         else
 883                         {
 884                                 damage_blurpostprocess_x = 0;
 885                                 damage_blurpostprocess_y = 0;
 886                                 damage_blurpostprocess_z = 0;
 887                         }
 888                 }
 889         }
 890
 891         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 892         {
 893                 // enable or disable rendering types if they are used or not
 894                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 895                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 896
 897                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 898                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 899                 {
 900                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 901                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 902                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 903                         {
 904                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 905                                 old_blurradius = blurradius;
 906                                 old_bluralpha = bluralpha;
 907                         }
 908                 }
 909                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 910                 {
 911                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 912                         old_blurradius = 0;
 913                         old_bluralpha = 0;
 914                 }
 915
 916                 // edge detection postprocess handling done second (used by hud_powerup)
 917                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 918                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 919                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 920
 921                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 922
 923                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 924                 {
 925                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 926                         {
 927                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 928                                 old_sharpen_intensity = sharpen_intensity;
 929                         }
 930                 }
 931                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 932                 {
 933                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 934                         old_sharpen_intensity = 0;
 935                 }
 936         }
 937
 938         if(menu_visible)
 939                 menu_show();
 940
 941         /*if(gametype == GAME_CTF)
 942           {
 943           ctf_view();
 944           } else */
 945
 946         // draw 2D entities
 947         e = self;
 948         for(self = world; (self = nextent(self)); )
 949                 if(self.draw2d)
 950                         self.draw2d();
 951         self = e;
 952         Draw_ShowNames_All();
 953
 954         scoreboard_active = HUD_WouldDrawScoreboard();
 955
 956         hit_time = getstatf(STAT_HIT_TIME);
 957         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 958         {
 959                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 960                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 961
 962                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 963         }
 964         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 965         if(typehit_time > nextsound_typehit_time)
 966         {
 967                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 968                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 969
 970                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 971         }
 972
 973         //else
 974         {
 975                 if(gametype == GAME_FREEZETAG)
 976                 {
 977                         if(getstati(STAT_FROZEN))
 978                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 979                         if(getstatf(STAT_REVIVE_PROGRESS))
 980                         {
 981                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 982                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 983                         }
 984                 }
 985
 986                 if(autocvar_r_letterbox == 0)
 987                         if(autocvar_viewsize < 120)
 988                                 CSQC_common_hud();
 989
 990                 // crosshair goes VERY LAST
 991                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 992                         string wcross_style;
 993                         float wcross_alpha, wcross_resolution;
 994                         wcross_style = autocvar_crosshair;
 995                         if (wcross_style == "0")
 996                                 return;
 997                         wcross_resolution = autocvar_crosshair_size;
 998                         if (wcross_resolution == 0)
 999                                 return;
1000                         wcross_alpha = autocvar_crosshair_alpha;
1001                         if (wcross_alpha == 0)
1002                                 return;
1003
1004                         // TrueAim check
1005                         float shottype;
1006
1007                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1008                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1009                         wcross_origin_z = 0;
1010                         if(autocvar_crosshair_hittest)
1011                         {
1012                                 vector wcross_oldorigin;
1013                                 wcross_oldorigin = wcross_origin;
1014                                 shottype = TrueAimCheck();
1015                                 if(shottype == SHOTTYPE_HITWORLD)
1016                                 {
1017                                         v = wcross_origin - wcross_oldorigin;
1018                                         v_x /= vid_conwidth;
1019                                         v_y /= vid_conheight;
1020                                         if(vlen(v) > 0.01)
1021                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1022                                 }
1023                                 if(!autocvar_crosshair_hittest_showimpact)
1024                                         wcross_origin = wcross_oldorigin;
1025                         }
1026                         else
1027                                 shottype = SHOTTYPE_HITWORLD;
1028
1029                         vector wcross_color, wcross_size;
1030                         string wcross_wep, wcross_name;
1031                         float wcross_scale, wcross_blur;
1032
1033                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1034                                 e = get_weaponinfo(activeweapon);
1035                                 if (e && e.netname != "")
1036                                 {
1037                                         wcross_wep = e.netname;
1038                                         if(autocvar_crosshair_per_weapon)
1039                                         {
1040                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1041                                                 if (wcross_resolution == 0)
1042                                                         return;
1043                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1044                                                 if (wcross_alpha == 0)
1045                                                         return;
1046
1047                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1048                                                 if(wcross_style == "" || wcross_style == "0")
1049                                                         wcross_style = wcross_wep;
1050                                         }
1051                                 }
1052                         }
1053                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1054                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1055                         else if(autocvar_crosshair_color_by_health)
1056                         {
1057                                 local float x = getstati(STAT_HEALTH);
1058
1059                                 //x = red
1060                                 //y = green
1061                                 //z = blue
1062
1063                                 wcross_color_z = 0;
1064
1065                                 if(x > 200)
1066                                 {
1067                                         wcross_color_x = 0;
1068                                         wcross_color_y = 1;
1069                                 }
1070                                 else if(x > 150)
1071                                 {
1072                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1073                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1074                                 }
1075                                 else if(x > 100)
1076                                 {
1077                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1078                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1079                                         wcross_color_z = 1 - (x-100)*0.02;
1080                                 }
1081                                 else if(x > 50)
1082                                 {
1083                                         wcross_color_x = 1;
1084                                         wcross_color_y = 1;
1085                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1086                                 }
1087                                 else if(x > 20)
1088                                 {
1089                                         wcross_color_x = 1;
1090                                         wcross_color_y = (x-20)*90/27/100;
1091                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1092                                 }
1093                                 else
1094                                 {
1095                                         wcross_color_x = 1;
1096                                         wcross_color_y = 0;
1097                                 }
1098                         }
1099                         else
1100                                 wcross_color = stov(autocvar_crosshair_color);
1101
1102                         wcross_name = strcat("gfx/crosshair", wcross_style);
1103
1104                         if(autocvar_crosshair_effect_scalefade)
1105                         {
1106                                 wcross_scale = wcross_resolution;
1107                                 wcross_resolution = 1;
1108                         }
1109                         else
1110                         {
1111                                 wcross_scale = 1;
1112                         }
1113
1114                         if(autocvar_crosshair_pickup)
1115                         {
1116                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1117
1118                                 if(pickup_crosshair_time < stat_pickup_time)
1119                                 {
1120                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1121                                                 pickup_crosshair_size = 1;
1122
1123                                         pickup_crosshair_time = stat_pickup_time;
1124                                 }
1125
1126                                 if(pickup_crosshair_size > 0)
1127                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1128                                 else
1129                                         pickup_crosshair_size = 0;
1130
1131                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1132                         }
1133
1134                         if(autocvar_crosshair_hitindication)
1135                         {
1136                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1137                                 if(hitindication_crosshair_time < hit_time)
1138                                 {
1139                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1140                                                 hitindication_crosshair_size = 1;
1141
1142                                         hitindication_crosshair_time = hit_time;
1143                                 }
1144
1145                                 if(hitindication_crosshair_size > 0)
1146                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1147                                 else
1148                                         hitindication_crosshair_size = 0;
1149
1150                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1151                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1152                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1153                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1154                         }
1155
1156                         if(shottype == SHOTTYPE_HITENEMY)
1157                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1158                         if(shottype == SHOTTYPE_HITTEAM)
1159                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1160
1161                         f = autocvar_crosshair_effect_speed;
1162                         if(f < 0)
1163                                 f *= -2 * g_weaponswitchdelay;
1164                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1165                         {
1166                                 wcross_changedonetime = time + f;
1167                         }
1168                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1169                         {
1170                                 wcross_name_changestarttime = time;
1171                                 wcross_name_changedonetime = time + f;
1172                                 if(wcross_name_goal_prev_prev)
1173                                         strunzone(wcross_name_goal_prev_prev);
1174                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1175                                 wcross_name_goal_prev = strzone(wcross_name);
1176                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1177                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1178                                 wcross_resolution_goal_prev = wcross_resolution;
1179                         }
1180
1181                         wcross_scale_goal_prev = wcross_scale;
1182                         wcross_alpha_goal_prev = wcross_alpha;
1183                         wcross_color_goal_prev = wcross_color;
1184
1185                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1186                         {
1187                                 wcross_blur = 1;
1188                                 wcross_alpha *= 0.75;
1189                         }
1190                         else
1191                                 wcross_blur = 0;
1192                         // *_prev is at time-frametime
1193                         // * is at wcross_changedonetime+f
1194                         // what do we have at time?
1195                         if(time < wcross_changedonetime)
1196                         {
1197                                 f = frametime / (wcross_changedonetime - time + frametime);
1198                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1199                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1200                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1201                         }
1202
1203                         wcross_scale_prev = wcross_scale;
1204                         wcross_alpha_prev = wcross_alpha;
1205                         wcross_color_prev = wcross_color;
1206
1207                         wcross_scale *= 1 - autocvar__menu_alpha;
1208                         wcross_alpha *= 1 - autocvar__menu_alpha;
1209                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1210
1211                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1212                         {
1213                                 // crosshair rings for weapon stats
1214                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1215                                 {
1216                                         // declarations and stats
1217                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1218                                         string ring_image, ring_inner_image;
1219                                         vector ring_rgb, ring_inner_rgb;
1220
1221                                         ring_scale = autocvar_crosshair_ring_size;
1222
1223                                         float weapon_clipload, weapon_clipsize;
1224                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1225                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1226
1227                                         float nex_charge, nex_chargepool;
1228                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1229                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1230
1231                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1232                                                 nex_charge_movingavg = nex_charge;
1233
1234
1235                                         // handle the values
1236                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1237                                         {
1238                                                 if (nex_chargepool || use_nex_chargepool) {
1239                                                         use_nex_chargepool = 1;
1240                                                         ring_inner_value = nex_chargepool;
1241                                                 } else {
1242                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1243                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1244                                                 }
1245
1246                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1247                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1248                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1249
1250                                                 // draw the outer ring to show the current charge of the weapon
1251                                                 ring_value = nex_charge;
1252                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1253                                                 ring_rgb = wcross_color;
1254                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1255                                         }
1256                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1257                                         {
1258                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1259                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1260                                                 ring_rgb = wcross_color;
1261                                                 ring_image = "gfx/crosshair_ring.tga";
1262                                         }
1263                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1264                                         {
1265                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1266                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1267                                                 ring_rgb = wcross_color;
1268                                                 ring_image = "gfx/crosshair_ring.tga";
1269                                         }
1270
1271                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1272                                         {
1273                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1274                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1275                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1276                                                 ring_rgb = wcross_color;
1277
1278                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1279                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1280                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1281                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1282                                                 else
1283                                                         ring_image = "gfx/crosshair_ring.tga";
1284                                         }
1285
1286                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1287                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1288
1289                                         if (ring_value)
1290                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1291                                 }
1292
1293 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1294                                 do \
1295                                 { \
1296                                         if(wcross_blur > 0) \
1297                                         { \
1298                                                 for(i = -2; i <= 2; ++i) \
1299                                                 for(j = -2; j <= 2; ++j) \
1300                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1301                                         } \
1302                                         else \
1303                                         { \
1304                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1305                                         } \
1306                                 } \
1307                                 while(0)
1308
1309 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1310                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1311
1312 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1313                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1314
1315                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1316                                 {
1317                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1318                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1319                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1320                                         f = 1 - f;
1321                                 }
1322                                 else
1323                                 {
1324                                         f = 1;
1325                                 }
1326                                 wcross_name_alpha_goal_prev = f;
1327
1328                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1329                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1330
1331                                 if(autocvar_crosshair_dot)
1332                                 {
1333                                         vector wcross_color_old;
1334                                         wcross_color_old = wcross_color;
1335                                         if(autocvar_crosshair_dot_color != "0")
1336                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1337                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1338                                         // FIXME why don't we use wcross_alpha here?
1339                                         wcross_color = wcross_color_old;
1340                                 }
1341                         }
1342                 }
1343                 else
1344                 {
1345                         wcross_scale_prev = 0;
1346                         wcross_alpha_prev = 0;
1347                         wcross_scale_goal_prev = 0;
1348                         wcross_alpha_goal_prev = 0;
1349                         wcross_changedonetime = 0;
1350                         if(wcross_name_goal_prev)
1351                                 strunzone(wcross_name_goal_prev);
1352                         wcross_name_goal_prev = string_null;
1353                         if(wcross_name_goal_prev_prev)
1354                                 strunzone(wcross_name_goal_prev_prev);
1355                         wcross_name_goal_prev_prev = string_null;
1356                         wcross_name_changestarttime = 0;
1357                         wcross_name_changedonetime = 0;
1358                         wcross_name_alpha_goal_prev = 0;
1359                         wcross_name_alpha_goal_prev_prev = 0;
1360                         wcross_resolution_goal_prev = 0;
1361                         wcross_resolution_goal_prev_prev = 0;
1362                 }
1363         }
1364
1365         if(NextFrameCommand)
1366         {
1367                 localcmd("\n", NextFrameCommand, "\n");
1368                 NextFrameCommand = string_null;
1369         }
1370
1371         // we must do this check AFTER a frame was rendered, or it won't work
1372         if(cs_project_is_b0rked == 0)
1373         {
1374                 string w0, h0;
1375                 w0 = ftos(autocvar_vid_conwidth);
1376                 h0 = ftos(autocvar_vid_conheight);
1377                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1378                 //R_SetView(VF_FOV, '90 90 0');
1379                 R_SetView(VF_ORIGIN, '0 0 0');
1380                 R_SetView(VF_ANGLES, '0 0 0');
1381                 R_SetView(VF_PERSPECTIVE, 1);
1382                 makevectors('0 0 0');
1383                 vector v1, v2;
1384                 cvar_set("vid_conwidth", "800");
1385                 cvar_set("vid_conheight", "600");
1386                 v1 = cs_project(v_forward);
1387                 cvar_set("vid_conwidth", "640");
1388                 cvar_set("vid_conheight", "480");
1389                 v2 = cs_project(v_forward);
1390                 if(v1 == v2)
1391                         cs_project_is_b0rked = 1;
1392                 else
1393                         cs_project_is_b0rked = -1;
1394                 cvar_set("vid_conwidth", w0);
1395                 cvar_set("vid_conheight", h0);
1396         }
1397
1398         if(autocvar__hud_configure)
1399                 HUD_Panel_Mouse();
1400
1401     if(hud && !intermission)
1402     {
1403         if(hud == HUD_SPIDERBOT)
1404             CSQC_SPIDER_HUD();
1405         else if(hud == HUD_WAKIZASHI)
1406             CSQC_WAKIZASHI_HUD();
1407         else if(hud == HUD_RAPTOR)
1408             CSQC_RAPTOR_HUD();
1409         else if(hud == HUD_BUMBLEBEE)
1410             CSQC_BUMBLE_HUD();
1411     }
1412         // let's reset the view back to normal for the end
1413         R_SetView(VF_MIN, '0 0 0');
1414         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1415 }
1416
1417
1418 void CSQC_common_hud(void)
1419 {
1420     // do some accuracy var caching
1421     float i;
1422     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1423     {
1424         if(autocvar_accuracy_color_levels != acc_color_levels)
1425         {
1426             if(acc_color_levels)
1427                 strunzone(acc_color_levels);
1428             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1429             acc_levels = tokenize(acc_color_levels);
1430             if (acc_levels > MAX_ACCURACY_LEVELS)
1431                 acc_levels = MAX_ACCURACY_LEVELS;
1432
1433             for (i = 0; i < acc_levels; ++i)
1434                 acc_lev[i] = stof(argv(i)) / 100.0;
1435         }
1436         // let know that acc_col[] needs to be loaded
1437         acc_col_x[0] = -1;
1438     }
1439
1440     HUD_Main(); // always run these functions for alpha checks
1441     HUD_DrawScoreboard();
1442
1443     if (scoreboard_active) // scoreboard/accuracy
1444         HUD_Reset();
1445     else if (intermission == 2) // map voting screen
1446     {
1447         HUD_FinaleOverlay();
1448         HUD_Reset();
1449     }
1450         /*
1451         switch(hud)
1452         {
1453                 case HUD_SPIDERBOT:
1454                         CSQC_SPIDER_HUD();
1455                         break;
1456
1457                 case HUD_WAKIZASHI:
1458                         CSQC_WAKIZASHI_HUD();
1459                         break;
1460
1461         case HUD_BUMBLEBEE:
1462             CSQC_BUMBLE_HUD();
1463             break;
1464         }
1465         */
1466 }
1467
1468
1469 // following vectors must be global to allow seamless switching between camera modes
1470 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1471 void CSQC_Demo_Camera()
1472 {
1473         float speed, attenuation, dimensions;
1474         vector tmp, delta;
1475
1476         if( autocvar_camera_reset || !camera_mode )
1477         {
1478                 camera_offset = '0 0 0';
1479                 current_angles = '0 0 0';
1480                 camera_direction = '0 0 0';
1481                 camera_offset_z += 30;
1482                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1483                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1484                 current_origin = view_origin;
1485                 current_camera_offset  = camera_offset;
1486                 cvar_set("camera_reset", "0");
1487                 camera_mode = CAMERA_CHASE;
1488         }
1489
1490         // Camera angles
1491         if( camera_roll )
1492                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1493
1494         if(autocvar_camera_look_player)
1495         {
1496                 local vector dir;
1497                 local float n;
1498
1499                 dir = normalize(view_origin - current_position);
1500                 n = mouse_angles_z;
1501                 mouse_angles = vectoangles(dir);
1502                 mouse_angles_x = mouse_angles_x * -1;
1503                 mouse_angles_z = n;
1504         }
1505         else
1506         {
1507                 tmp = getmousepos() * 0.1;
1508                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1509                 {
1510                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1511                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1512                 }
1513         }
1514
1515         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1516         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1517         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1518         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1519
1520         // Fix difference when angles don't have the same sign
1521         delta = '0 0 0';
1522         if(mouse_angles_y < -60 && current_angles_y > 60)
1523                 delta = '0 360 0';
1524         if(mouse_angles_y > 60 && current_angles_y < -60)
1525                 delta = '0 -360 0';
1526
1527         if(autocvar_camera_look_player)
1528                 attenuation = autocvar_camera_look_attenuation;
1529         else
1530                 attenuation = autocvar_camera_speed_attenuation;
1531
1532         attenuation = 1 / max(1, attenuation);
1533         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1534
1535         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1536         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1537         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1538         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1539
1540         // Camera position
1541         tmp = '0 0 0';
1542         dimensions = 0;
1543
1544         if( camera_direction_x )
1545         {
1546                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1547                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1548                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1549                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1550                 ++dimensions;
1551         }
1552
1553         if( camera_direction_y )
1554         {
1555                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1556                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1557                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1558                 ++dimensions;
1559         }
1560
1561         if( camera_direction_z )
1562         {
1563                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1564                 ++dimensions;
1565         }
1566
1567         if(autocvar_camera_free)
1568                 speed = autocvar_camera_speed_free;
1569         else
1570                 speed = autocvar_camera_speed_chase;
1571
1572         if(dimensions)
1573         {
1574                 speed = speed * sqrt(1 / dimensions);
1575                 camera_offset += tmp * speed;
1576         }
1577
1578         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1579
1580         // Camera modes
1581         if( autocvar_camera_free )
1582         {
1583                 if ( camera_mode == CAMERA_CHASE )
1584                 {
1585                         current_camera_offset = current_origin + current_camera_offset;
1586                         camera_offset = current_origin + camera_offset;
1587                 }
1588
1589                 camera_mode = CAMERA_FREE;
1590                 current_position = current_camera_offset;
1591         }
1592         else
1593         {
1594                 if ( camera_mode == CAMERA_FREE )
1595                 {
1596                         current_origin = view_origin;
1597                         camera_offset = camera_offset - current_origin;
1598                         current_camera_offset = current_camera_offset - current_origin;
1599                 }
1600
1601                 camera_mode = CAMERA_CHASE;
1602
1603                 if(autocvar_camera_chase_smoothly)
1604                         current_origin += (view_origin - current_origin) * attenuation;
1605                 else
1606                         current_origin = view_origin;
1607
1608                 current_position = current_origin + current_camera_offset;
1609         }
1610
1611         R_SetView(VF_ANGLES, current_angles);
1612         R_SetView(VF_ORIGIN, current_position);
1613 }