qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float CAMERA_FREE = 1;
 331 float CAMERA_CHASE = 2;
 332 float reticle_type;
 333 string NextFrameCommand;
 334 void CSQC_SPIDER_HUD();
 335 void CSQC_RAPTOR_HUD();
 336
 337 vector freeze_org, freeze_ang;
 338 entity nightvision_noise, nightvision_noise2;
 339
 340 #define MAX_TIME_DIFF 5
 341 float pickup_crosshair_time, pickup_crosshair_size;
 342 float hit_time, typehit_time;
 343 float nextsound_hit_time, nextsound_typehit_time;
 344 float hitindication_crosshair_time, hitindication_crosshair_size;
 345 float use_nex_chargepool;
 346
 347 float myhealth, myhealth_prev;
 348 float myhealth_flash;
 349
 350 float old_blurradius, old_bluralpha;
 351 float old_sharpen_intensity;
 352
 353 vector myhealth_gentlergb;
 354
 355 float contentavgalpha, liquidalpha_prev;
 356 vector liquidcolor_prev;
 357
 358 float eventchase_current_distance;
 359
 360 vector damage_blurpostprocess, content_blurpostprocess;
 361
 362 float checkfail[16];
 363
 364 #define BUTTON_3 4
 365 #define BUTTON_4 8
 366 void CSQC_UpdateView(float w, float h)
 367 {
 368         entity e;
 369         float fov;
 370         float f, i, j;
 371         vector v;
 372         vector vf_size, vf_min;
 373         float a;
 374         hud = getstati(STAT_HUD);
 375
 376         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 377                 view_quality = getproperty(VF_MINFPS_QUALITY);
 378         else
 379                 view_quality = 1;
 380
 381         button_attack2 = (input_buttons & BUTTON_3);
 382         button_zoom = (input_buttons & BUTTON_4);
 383
 384         // FIXME do we need this hack?
 385         if(isdemo())
 386         {
 387                 // in demos, input_buttons do not work
 388                 button_zoom = (autocvar__togglezoom == "-");
 389         }
 390
 391 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 392         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 393         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 394         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 395         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 396         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 397         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 398         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 399
 400         vf_size = getpropertyvec(VF_SIZE);
 401         vf_min = getpropertyvec(VF_MIN);
 402         vid_width = vf_size_x;
 403         vid_height = vf_size_y;
 404
 405         vector reticle_pos, reticle_size;
 406         vector splash_pos, splash_size;
 407
 408         WaypointSprite_Load();
 409
 410         CSQCPlayer_SetCamera();
 411
 412         if(spectatee_status)
 413                 myteam = GetPlayerColor(spectatee_status - 1);
 414         else
 415                 myteam = GetPlayerColor(player_localentnum - 1);
 416
 417         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 418
 419         // event chase camera
 420         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 421         {
 422                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 423                 {
 424                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 425                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 426
 427                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 428                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 429                         if(!autocvar_chase_active)
 430                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 431
 432                         // make the camera smooth back
 433                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 434                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 435                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 436                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 437
 438                         vector eventchase_target_origin;
 439                         makevectors(view_angles);
 440                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 441                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 442                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 443                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 444                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 445                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 446                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 447
 448                         setproperty(VF_ORIGIN, trace_endpos);
 449                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 450                 }
 451                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 452                 {
 453                         cvar_set("chase_active", "0");
 454                         eventchase_current_distance = 0; // start from 0 next time
 455                 }
 456         }
 457
 458         // do lockview after event chase camera so that it still applies whenever necessary.
 459         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 460         {
 461                 setproperty(VF_ORIGIN, freeze_org);
 462                 setproperty(VF_ANGLES, freeze_ang);
 463         }
 464         else
 465         {
 466                 freeze_org = getpropertyvec(VF_ORIGIN);
 467                 freeze_ang = getpropertyvec(VF_ANGLES);
 468         }
 469
 470         WarpZone_FixView();
 471         //WarpZone_FixPMove();
 472
 473         // Render the Scene
 474         view_origin = getpropertyvec(VF_ORIGIN);
 475         view_angles = getpropertyvec(VF_ANGLES);
 476         makevectors(view_angles);
 477         view_forward = v_forward;
 478         view_right = v_right;
 479         view_up = v_up;
 480
 481 #ifdef BLURTEST
 482         if(time > blurtest_time0 && time < blurtest_time1)
 483         {
 484                 float r, t;
 485
 486                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 487                 r = t * blurtest_radius;
 488                 f = 1 / pow(t, blurtest_power) - 1;
 489
 490                 cvar_set("r_glsl_postprocess", "1");
 491                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 492         }
 493         else
 494         {
 495                 cvar_set("r_glsl_postprocess", "0");
 496                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 497         }
 498 #endif
 499
 500         TargetMusic_Advance();
 501         Fog_Force();
 502
 503         if(drawtime == 0)
 504                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 505         else
 506                 drawframetime = bound(0.000001, time - drawtime, 1);
 507         drawtime = time;
 508
 509         // watch for gametype changes here...
 510         // in ParseStuffCMD the cmd isn't executed yet :/
 511         // might even be better to add the gametype to TE_CSQC_INIT...?
 512         if(!postinit)
 513                 PostInit();
 514
 515         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 516         {
 517                 if(calledhooks & HOOK_START)
 518                 {
 519                         localcmd("\ncl_hook_gameend\n");
 520                         calledhooks |= HOOK_END;
 521                 }
 522         }
 523
 524   Announcer();
 525
 526         fov = autocvar_fov;
 527         if(fov <= 59.5)
 528         {
 529                 if(!zoomscript_caught)
 530                 {
 531                         localcmd("+button9\n");
 532                         zoomscript_caught = 1;
 533                 }
 534         }
 535         else
 536         {
 537                 if(zoomscript_caught)
 538                 {
 539                         localcmd("-button9\n");
 540                         zoomscript_caught = 0;
 541                 }
 542         }
 543
 544         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 545
 546         // next WANTED weapon (for HUD)
 547         switchweapon = getstati(STAT_SWITCHWEAPON);
 548
 549         // currently switching-to weapon (for crosshair)
 550         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 551
 552         // actually active weapon (for zoom)
 553         activeweapon = getstati(STAT_ACTIVEWEAPON);
 554
 555         f = (serverflags & SERVERFLAG_TEAMPLAY);
 556         if(f != teamplay)
 557         {
 558                 teamplay = f;
 559                 HUD_InitScores();
 560         }
 561
 562         if(last_switchweapon != switchweapon) {
 563                 weapontime = time;
 564                 last_switchweapon = switchweapon;
 565         }
 566         if(last_activeweapon != activeweapon) {
 567                 last_activeweapon = activeweapon;
 568
 569                 e = get_weaponinfo(activeweapon);
 570                 if(e.netname != "")
 571                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 572                 else
 573                         localcmd("\ncl_hook_activeweapon none\n");
 574         }
 575
 576         // ALWAYS Clear Current Scene First
 577         clearscene();
 578 #ifdef WORKAROUND_XON010
 579         if(checkextension("DP_CSQC_ROTATEMOVES"))
 580         {
 581 #endif
 582         setproperty(VF_ORIGIN, view_origin);
 583         setproperty(VF_ANGLES, view_angles);
 584 #ifdef WORKAROUND_XON010
 585         }
 586 #endif
 587
 588         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 589         setproperty(VF_SIZE, vf_size);
 590         setproperty(VF_MIN, vf_min);
 591
 592         // Assign Standard Viewflags
 593         // Draw the World (and sky)
 594         setproperty(VF_DRAWWORLD, 1);
 595
 596         // Set the console size vars
 597         vid_conwidth = autocvar_vid_conwidth;
 598         vid_conheight = autocvar_vid_conheight;
 599         vid_pixelheight = autocvar_vid_pixelheight;
 600
 601         setproperty(VF_FOV, GetCurrentFov(fov));
 602
 603         // Camera for demo playback
 604         if(camera_active)
 605         {
 606                 if(autocvar_camera_enable)
 607                         CSQC_Demo_Camera();
 608                 else
 609                 {
 610                         cvar_set("chase_active", ftos(chase_active_backup));
 611                         cvar_set("cl_demo_mousegrab", "0");
 612                         camera_active = FALSE;
 613                 }
 614         }
 615 #ifdef CAMERATEST
 616         else if(autocvar_camera_enable)
 617 #else
 618         else if(autocvar_camera_enable && isdemo())
 619 #endif
 620         {
 621                 // Enable required Darkplaces cvars
 622                 chase_active_backup = autocvar_chase_active;
 623                 cvar_set("chase_active", "2");
 624                 cvar_set("cl_demo_mousegrab", "1");
 625                 camera_active = TRUE;
 626                 camera_mode = FALSE;
 627         }
 628
 629         // Draw the Crosshair
 630         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 631
 632         // Draw the Engine Status Bar (the default Quake HUD)
 633         setproperty(VF_DRAWENGINESBAR, 0);
 634
 635         // Update the mouse position
 636         /*
 637            mousepos_x = vid_conwidth;
 638            mousepos_y = vid_conheight;
 639            mousepos = mousepos*0.5 + getmousepos();
 640          */
 641
 642         e = self;
 643         for(self = world; (self = nextent(self)); )
 644                 if(self.draw)
 645                         self.draw();
 646         self = e;
 647
 648         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 649         renderscene();
 650
 651         // now switch to 2D drawing mode by calling a 2D drawing function
 652         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 653         // next R_RenderScene call
 654         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 655
 656         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 657         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 658         {
 659                 // apply night vision effect
 660                 vector tc_00, tc_01, tc_10, tc_11;
 661                 vector rgb;
 662                 rgb_x = 0; // fteqcc sucks
 663                 rgb_y = 0; // fteqcc sucks
 664                 rgb_z = 0; // fteqcc sucks
 665
 666                 if(!nightvision_noise)
 667                 {
 668                         nightvision_noise = spawn();
 669                         nightvision_noise.classname = "nightvision_noise";
 670                 }
 671                 if(!nightvision_noise2)
 672                 {
 673                         nightvision_noise2 = spawn();
 674                         nightvision_noise2.classname = "nightvision_noise2";
 675                 }
 676
 677                 // color tint in yellow
 678                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 679
 680                 // draw BG
 681                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 682                 rgb = '1 1 1';
 683                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 684                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 685                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 686                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 687                 tc_11 = tc_01 + tc_10 - tc_00;
 688                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 689                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 690                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 691                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 692                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 693                 R_EndPolygon();
 694
 695                 // draw FG
 696                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 697                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 698                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 699                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 700                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 701                 tc_11 = tc_01 + tc_10 - tc_00;
 702                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 703                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 704                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 705                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 706                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 707                 R_EndPolygon();
 708         }
 709
 710         // Draw the aiming reticle for weapons that use it
 711         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 712         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 713         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 714         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 715                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 716         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 717                 reticle_type = 2; // nex zoom
 718         else if(button_zoom || zoomscript_caught)
 719                 reticle_type = 1; // normal zoom
 720         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 721                 reticle_type = 2; // nex zoom
 722
 723         if(reticle_type && autocvar_cl_reticle)
 724         {
 725                 if(autocvar_cl_reticle_stretch)
 726                 {
 727                         reticle_size_x = vid_conwidth;
 728                         reticle_size_y = vid_conheight;
 729                         reticle_pos_x = 0;
 730                         reticle_pos_y = 0;
 731                 }
 732                 else
 733                 {
 734                         reticle_size_x = max(vid_conwidth, vid_conheight);
 735                         reticle_size_y = max(vid_conwidth, vid_conheight);
 736                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 737                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 738                 }
 739
 740                 f = current_zoomfraction;
 741                 if(zoomscript_caught)
 742                         f = 1;
 743                 if(autocvar_cl_reticle_item_normal)
 744                 {
 745                         if(reticle_type == 1 && f)
 746                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 747                 }
 748                 if(autocvar_cl_reticle_item_nex)
 749                 {
 750                         if(reticle_type == 2 && f)
 751                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 752                 }
 753         }
 754
 755
 756         // improved polyblend
 757         vector rgb;
 758         if(autocvar_hud_contents)
 759         {
 760                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 761                 vector liquidcolor;
 762
 763                 switch(pointcontents(view_origin))
 764                 {
 765                         case CONTENT_WATER:
 766                                 liquidalpha = autocvar_hud_contents_water_alpha;
 767                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 768                                 incontent = 1;
 769                                 break;
 770
 771                         case CONTENT_LAVA:
 772                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 773                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 774                                 incontent = 1;
 775                                 break;
 776
 777                         case CONTENT_SLIME:
 778                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 779                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 780                                 incontent = 1;
 781                                 break;
 782
 783                         default:
 784                                 liquidalpha = 0;
 785                                 liquidcolor = '0 0 0';
 786                                 incontent = 0;
 787                                 break;
 788                 }
 789
 790                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 791                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 792                         contentfadetime = autocvar_hud_contents_fadeintime;
 793                         liquidalpha_prev = liquidalpha;
 794                         liquidcolor_prev = liquidcolor;
 795                 }
 796                 else
 797                         contentfadetime = autocvar_hud_contents_fadeouttime;
 798
 799                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 800                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 801
 802                 if(contentavgalpha)
 803                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 804
 805                 if(autocvar_hud_postprocessing)
 806                 {
 807                         if(autocvar_hud_contents_blur && contentavgalpha)
 808                         {
 809                                 content_blurpostprocess_x = 1;
 810                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 811                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 812                         }
 813                         else
 814                         {
 815                                 content_blurpostprocess_x = 0;
 816                                 content_blurpostprocess_y = 0;
 817                                 content_blurpostprocess_z = 0;
 818                         }
 819                 }
 820         }
 821
 822         if(autocvar_hud_damage)
 823         {
 824                 splash_size_x = max(vid_conwidth, vid_conheight);
 825                 splash_size_y = max(vid_conwidth, vid_conheight);
 826                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 827                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 828
 829                 float myhealth_flash_temp;
 830                 myhealth = getstati(STAT_HEALTH);
 831
 832                 // fade out
 833                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 834                 // add new damage
 835                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 836
 837                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 838                 pain_threshold = autocvar_hud_damage_pain_threshold;
 839                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 840                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 841
 842                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 843                 {
 844                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 845                 }
 846
 847                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 848
 849                 if(myhealth_prev < 1)
 850                 {
 851                         if(myhealth >= 1)
 852                         {
 853                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 854                                 myhealth_flash_temp = 0;
 855                         }
 856                         else
 857                         {
 858                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 859                         }
 860                 }
 861
 862                 if(spectatee_status == -1 || intermission)
 863                 {
 864                         myhealth_flash = 0; // observing, or match ended
 865                         myhealth_flash_temp = 0;
 866                 }
 867
 868                 myhealth_prev = myhealth;
 869
 870                 // IDEA: change damage color/picture based on player model for robot/alien species?
 871                 // pro: matches model better
 872                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 873                 // maybe different reddish pics?
 874                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 875                 {
 876                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 877                         {
 878                                 if(autocvar_cl_gentle_damage == 2)
 879                                 {
 880                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 881                                         {
 882                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 883                                         }
 884                                 }
 885                                 else
 886                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 887
 888                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 889                         }
 890                         else
 891                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 892                 }
 893
 894                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 895                 {
 896                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 897                         {
 898                                 damage_blurpostprocess_x = 1;
 899                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 900                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 901                         }
 902                         else
 903                         {
 904                                 damage_blurpostprocess_x = 0;
 905                                 damage_blurpostprocess_y = 0;
 906                                 damage_blurpostprocess_z = 0;
 907                         }
 908                 }
 909         }
 910
 911         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 912         {
 913                 // enable or disable rendering types if they are used or not
 914                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 915                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 916
 917                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 918                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 919                 {
 920                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 921                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 922                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 923                         {
 924                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 925                                 old_blurradius = blurradius;
 926                                 old_bluralpha = bluralpha;
 927                         }
 928                 }
 929                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 930                 {
 931                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 932                         old_blurradius = 0;
 933                         old_bluralpha = 0;
 934                 }
 935
 936                 // edge detection postprocess handling done second (used by hud_powerup)
 937                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 938                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 939                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 940
 941                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 942
 943                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 944                 {
 945                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 946                         {
 947                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 948                                 old_sharpen_intensity = sharpen_intensity;
 949                         }
 950                 }
 951                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 952                 {
 953                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 954                         old_sharpen_intensity = 0;
 955                 }
 956         }
 957
 958         if(menu_visible)
 959                 menu_show();
 960
 961         /*if(gametype == GAME_CTF)
 962           {
 963           ctf_view();
 964           } else */
 965
 966         // draw 2D entities
 967         e = self;
 968         for(self = world; (self = nextent(self)); )
 969                 if(self.draw2d)
 970                         self.draw2d();
 971         self = e;
 972         Draw_ShowNames_All();
 973
 974         scoreboard_active = HUD_WouldDrawScoreboard();
 975
 976         hit_time = getstatf(STAT_HIT_TIME);
 977         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 978         {
 979                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 980                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 981
 982                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 983         }
 984         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 985         if(typehit_time > nextsound_typehit_time)
 986         {
 987                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 988                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 989
 990                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 991         }
 992
 993         //else
 994         {
 995                 if(gametype == GAME_FREEZETAG)
 996                 {
 997                         if(getstati(STAT_FROZEN))
 998                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 999                         if(getstatf(STAT_REVIVE_PROGRESS))
1000                         {
1001                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1002                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1003                         }
1004                 }
1005
1006                 if(autocvar_r_letterbox == 0)
1007                         if(autocvar_viewsize < 120)
1008                                 CSQC_common_hud();
1009
1010                 // crosshair goes VERY LAST
1011                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1012                         string wcross_style;
1013                         float wcross_alpha, wcross_resolution;
1014                         wcross_style = autocvar_crosshair;
1015                         if (wcross_style == "0")
1016                                 return;
1017                         wcross_resolution = autocvar_crosshair_size;
1018                         if (wcross_resolution == 0)
1019                                 return;
1020                         wcross_alpha = autocvar_crosshair_alpha;
1021                         if (wcross_alpha == 0)
1022                                 return;
1023
1024                         // TrueAim check
1025                         float shottype;
1026
1027                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1028                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1029                         wcross_origin_z = 0;
1030                         if(autocvar_crosshair_hittest)
1031                         {
1032                                 vector wcross_oldorigin;
1033                                 wcross_oldorigin = wcross_origin;
1034                                 shottype = TrueAimCheck();
1035                                 if(shottype == SHOTTYPE_HITWORLD)
1036                                 {
1037                                         v = wcross_origin - wcross_oldorigin;
1038                                         v_x /= vid_conwidth;
1039                                         v_y /= vid_conheight;
1040                                         if(vlen(v) > 0.01)
1041                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1042                                 }
1043                                 if(!autocvar_crosshair_hittest_showimpact)
1044                                         wcross_origin = wcross_oldorigin;
1045                         }
1046                         else
1047                                 shottype = SHOTTYPE_HITWORLD;
1048
1049                         vector wcross_color, wcross_size;
1050                         string wcross_wep, wcross_name;
1051                         float wcross_scale, wcross_blur;
1052
1053                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1054                                 e = get_weaponinfo(switchingweapon);
1055                                 if (e && e.netname != "")
1056                                 {
1057                                         wcross_wep = e.netname;
1058                                         if(autocvar_crosshair_per_weapon)
1059                                         {
1060                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1061                                                 if (wcross_resolution == 0)
1062                                                         return;
1063                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1064                                                 if (wcross_alpha == 0)
1065                                                         return;
1066
1067                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1068                                                 if(wcross_style == "" || wcross_style == "0")
1069                                                         wcross_style = wcross_wep;
1070                                         }
1071                                 }
1072                         }
1073                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1074                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1075                         else if(autocvar_crosshair_color_by_health)
1076                         {
1077                                 float x = getstati(STAT_HEALTH);
1078
1079                                 //x = red
1080                                 //y = green
1081                                 //z = blue
1082
1083                                 wcross_color_z = 0;
1084
1085                                 if(x > 200)
1086                                 {
1087                                         wcross_color_x = 0;
1088                                         wcross_color_y = 1;
1089                                 }
1090                                 else if(x > 150)
1091                                 {
1092                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1093                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1094                                 }
1095                                 else if(x > 100)
1096                                 {
1097                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1098                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1099                                         wcross_color_z = 1 - (x-100)*0.02;
1100                                 }
1101                                 else if(x > 50)
1102                                 {
1103                                         wcross_color_x = 1;
1104                                         wcross_color_y = 1;
1105                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1106                                 }
1107                                 else if(x > 20)
1108                                 {
1109                                         wcross_color_x = 1;
1110                                         wcross_color_y = (x-20)*90/27/100;
1111                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1112                                 }
1113                                 else
1114                                 {
1115                                         wcross_color_x = 1;
1116                                         wcross_color_y = 0;
1117                                 }
1118                         }
1119                         else
1120                                 wcross_color = stov(autocvar_crosshair_color);
1121
1122                         wcross_name = strcat("gfx/crosshair", wcross_style);
1123
1124                         if(autocvar_crosshair_effect_scalefade)
1125                         {
1126                                 wcross_scale = wcross_resolution;
1127                                 wcross_resolution = 1;
1128                         }
1129                         else
1130                         {
1131                                 wcross_scale = 1;
1132                         }
1133
1134                         if(autocvar_crosshair_pickup)
1135                         {
1136                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1137
1138                                 if(pickup_crosshair_time < stat_pickup_time)
1139                                 {
1140                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1141                                                 pickup_crosshair_size = 1;
1142
1143                                         pickup_crosshair_time = stat_pickup_time;
1144                                 }
1145
1146                                 if(pickup_crosshair_size > 0)
1147                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1148                                 else
1149                                         pickup_crosshair_size = 0;
1150
1151                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1152                         }
1153
1154                         if(autocvar_crosshair_hitindication)
1155                         {
1156                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1157                                 if(hitindication_crosshair_time < hit_time)
1158                                 {
1159                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1160                                                 hitindication_crosshair_size = 1;
1161
1162                                         hitindication_crosshair_time = hit_time;
1163                                 }
1164
1165                                 if(hitindication_crosshair_size > 0)
1166                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1167                                 else
1168                                         hitindication_crosshair_size = 0;
1169
1170                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1171                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1172                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1173                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1174                         }
1175
1176                         if(shottype == SHOTTYPE_HITENEMY)
1177                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1178                         if(shottype == SHOTTYPE_HITTEAM)
1179                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1180
1181                         f = autocvar_crosshair_effect_speed;
1182                         if(f < 0)
1183                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1184                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1185                         {
1186                                 wcross_changedonetime = time + f;
1187                         }
1188                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1189                         {
1190                                 wcross_name_changestarttime = time;
1191                                 wcross_name_changedonetime = time + f;
1192                                 if(wcross_name_goal_prev_prev)
1193                                         strunzone(wcross_name_goal_prev_prev);
1194                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1195                                 wcross_name_goal_prev = strzone(wcross_name);
1196                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1197                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1198                                 wcross_resolution_goal_prev = wcross_resolution;
1199                         }
1200
1201                         wcross_scale_goal_prev = wcross_scale;
1202                         wcross_alpha_goal_prev = wcross_alpha;
1203                         wcross_color_goal_prev = wcross_color;
1204
1205                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1206                         {
1207                                 wcross_blur = 1;
1208                                 wcross_alpha *= 0.75;
1209                         }
1210                         else
1211                                 wcross_blur = 0;
1212                         // *_prev is at time-frametime
1213                         // * is at wcross_changedonetime+f
1214                         // what do we have at time?
1215                         if(time < wcross_changedonetime)
1216                         {
1217                                 f = frametime / (wcross_changedonetime - time + frametime);
1218                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1219                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1220                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1221                         }
1222
1223                         wcross_scale_prev = wcross_scale;
1224                         wcross_alpha_prev = wcross_alpha;
1225                         wcross_color_prev = wcross_color;
1226
1227                         wcross_scale *= 1 - autocvar__menu_alpha;
1228                         wcross_alpha *= 1 - autocvar__menu_alpha;
1229                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1230
1231                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1232                         {
1233                                 // crosshair rings for weapon stats
1234                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1235                                 {
1236                                         // declarations and stats
1237                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1238                                         string ring_image, ring_inner_image;
1239                                         vector ring_rgb, ring_inner_rgb;
1240
1241                                         ring_scale = autocvar_crosshair_ring_size;
1242
1243                                         float weapon_clipload, weapon_clipsize;
1244                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1245                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1246
1247                                         float nex_charge, nex_chargepool;
1248                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1249                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1250
1251                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1252                                                 nex_charge_movingavg = nex_charge;
1253
1254
1255                                         // handle the values
1256                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1257                                         {
1258                                                 if (nex_chargepool || use_nex_chargepool) {
1259                                                         use_nex_chargepool = 1;
1260                                                         ring_inner_value = nex_chargepool;
1261                                                 } else {
1262                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1263                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1264                                                 }
1265
1266                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1267                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1268                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1269
1270                                                 // draw the outer ring to show the current charge of the weapon
1271                                                 ring_value = nex_charge;
1272                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1273                                                 ring_rgb = wcross_color;
1274                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1275                                         }
1276                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1277                                         {
1278                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1279                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1280                                                 ring_rgb = wcross_color;
1281                                                 ring_image = "gfx/crosshair_ring.tga";
1282                                         }
1283                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1284                                         {
1285                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1286                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1287                                                 ring_rgb = wcross_color;
1288                                                 ring_image = "gfx/crosshair_ring.tga";
1289                                         }
1290
1291                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1292                                         {
1293                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1294                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1295                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1296                                                 ring_rgb = wcross_color;
1297
1298                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1299                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1300                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1301                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1302                                                 else
1303                                                         ring_image = "gfx/crosshair_ring.tga";
1304                                         }
1305
1306                                         // if in weapon switch animation, fade ring out/in
1307                                         if(g_weaponswitchdelay > 0)
1308                                         {
1309                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1310                                                 if(f > 0 && f < 2)
1311                                                         ring_alpha *= fabs(1 - f);
1312                                         }
1313
1314                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1315                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1316
1317                                         if (ring_value)
1318                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1319                                 }
1320
1321 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1322                                 do \
1323                                 { \
1324                                         if(wcross_blur > 0) \
1325                                         { \
1326                                                 for(i = -2; i <= 2; ++i) \
1327                                                 for(j = -2; j <= 2; ++j) \
1328                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1329                                         } \
1330                                         else \
1331                                         { \
1332                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1333                                         } \
1334                                 } \
1335                                 while(0)
1336
1337 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1338                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1339
1340 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1341                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1342
1343                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1344                                 {
1345                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1346                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1347                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1348                                         f = 1 - f;
1349                                 }
1350                                 else
1351                                 {
1352                                         f = 1;
1353                                 }
1354                                 wcross_name_alpha_goal_prev = f;
1355
1356                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1357                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1358
1359                                 if(autocvar_crosshair_dot)
1360                                 {
1361                                         vector wcross_color_old;
1362                                         wcross_color_old = wcross_color;
1363                                         if(autocvar_crosshair_dot_color != "0")
1364                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1365                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1366                                         // FIXME why don't we use wcross_alpha here?
1367                                         wcross_color = wcross_color_old;
1368                                 }
1369                         }
1370                 }
1371                 else
1372                 {
1373                         wcross_scale_prev = 0;
1374                         wcross_alpha_prev = 0;
1375                         wcross_scale_goal_prev = 0;
1376                         wcross_alpha_goal_prev = 0;
1377                         wcross_changedonetime = 0;
1378                         if(wcross_name_goal_prev)
1379                                 strunzone(wcross_name_goal_prev);
1380                         wcross_name_goal_prev = string_null;
1381                         if(wcross_name_goal_prev_prev)
1382                                 strunzone(wcross_name_goal_prev_prev);
1383                         wcross_name_goal_prev_prev = string_null;
1384                         wcross_name_changestarttime = 0;
1385                         wcross_name_changedonetime = 0;
1386                         wcross_name_alpha_goal_prev = 0;
1387                         wcross_name_alpha_goal_prev_prev = 0;
1388                         wcross_resolution_goal_prev = 0;
1389                         wcross_resolution_goal_prev_prev = 0;
1390                 }
1391         }
1392
1393         if(NextFrameCommand)
1394         {
1395                 localcmd("\n", NextFrameCommand, "\n");
1396                 NextFrameCommand = string_null;
1397         }
1398
1399         // we must do this check AFTER a frame was rendered, or it won't work
1400         if(cs_project_is_b0rked == 0)
1401         {
1402                 string w0, h0;
1403                 w0 = ftos(autocvar_vid_conwidth);
1404                 h0 = ftos(autocvar_vid_conheight);
1405                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1406                 //setproperty(VF_FOV, '90 90 0');
1407                 setproperty(VF_ORIGIN, '0 0 0');
1408                 setproperty(VF_ANGLES, '0 0 0');
1409                 setproperty(VF_PERSPECTIVE, 1);
1410                 makevectors('0 0 0');
1411                 vector v1, v2;
1412                 cvar_set("vid_conwidth", "800");
1413                 cvar_set("vid_conheight", "600");
1414                 v1 = cs_project(v_forward);
1415                 cvar_set("vid_conwidth", "640");
1416                 cvar_set("vid_conheight", "480");
1417                 v2 = cs_project(v_forward);
1418                 if(v1 == v2)
1419                         cs_project_is_b0rked = 1;
1420                 else
1421                         cs_project_is_b0rked = -1;
1422                 cvar_set("vid_conwidth", w0);
1423                 cvar_set("vid_conheight", h0);
1424         }
1425
1426         if(autocvar__hud_configure)
1427                 HUD_Panel_Mouse();
1428
1429     if(hud && !intermission)
1430     {
1431         if(hud == HUD_SPIDERBOT)
1432             CSQC_SPIDER_HUD();
1433         else if(hud == HUD_WAKIZASHI)
1434             CSQC_WAKIZASHI_HUD();
1435         else if(hud == HUD_RAPTOR)
1436             CSQC_RAPTOR_HUD();
1437         else if(hud == HUD_BUMBLEBEE)
1438             CSQC_BUMBLE_HUD();
1439     }
1440         // let's reset the view back to normal for the end
1441         setproperty(VF_MIN, '0 0 0');
1442         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1443 }
1444
1445
1446 void CSQC_common_hud(void)
1447 {
1448     // do some accuracy var caching
1449     float i;
1450     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1451     {
1452         if(autocvar_accuracy_color_levels != acc_color_levels)
1453         {
1454             if(acc_color_levels)
1455                 strunzone(acc_color_levels);
1456             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1457             acc_levels = tokenize_console(acc_color_levels);
1458             if (acc_levels > MAX_ACCURACY_LEVELS)
1459                 acc_levels = MAX_ACCURACY_LEVELS;
1460
1461             for (i = 0; i < acc_levels; ++i)
1462                 acc_lev[i] = stof(argv(i)) / 100.0;
1463         }
1464         // let know that acc_col[] needs to be loaded
1465         acc_col_x[0] = -1;
1466     }
1467
1468     HUD_Main(); // always run these functions for alpha checks
1469     HUD_DrawScoreboard();
1470
1471     if (scoreboard_active) // scoreboard/accuracy
1472         HUD_Reset();
1473     else if (intermission == 2) // map voting screen
1474     {
1475         HUD_FinaleOverlay();
1476         HUD_Reset();
1477     }
1478         /*
1479         switch(hud)
1480         {
1481                 case HUD_SPIDERBOT:
1482                         CSQC_SPIDER_HUD();
1483                         break;
1484
1485                 case HUD_WAKIZASHI:
1486                         CSQC_WAKIZASHI_HUD();
1487                         break;
1488
1489         case HUD_BUMBLEBEE:
1490             CSQC_BUMBLE_HUD();
1491             break;
1492         }
1493         */
1494 }
1495
1496
1497 // following vectors must be global to allow seamless switching between camera modes
1498 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1499 void CSQC_Demo_Camera()
1500 {
1501         float speed, attenuation, dimensions;
1502         vector tmp, delta;
1503
1504         if( autocvar_camera_reset || !camera_mode )
1505         {
1506                 camera_offset = '0 0 0';
1507                 current_angles = '0 0 0';
1508                 camera_direction = '0 0 0';
1509                 camera_offset_z += 30;
1510                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1511                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1512                 current_origin = view_origin;
1513                 current_camera_offset  = camera_offset;
1514                 cvar_set("camera_reset", "0");
1515                 camera_mode = CAMERA_CHASE;
1516         }
1517
1518         // Camera angles
1519         if( camera_roll )
1520                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1521
1522         if(autocvar_camera_look_player)
1523         {
1524                 vector dir;
1525                 float n;
1526
1527                 dir = normalize(view_origin - current_position);
1528                 n = mouse_angles_z;
1529                 mouse_angles = vectoangles(dir);
1530                 mouse_angles_x = mouse_angles_x * -1;
1531                 mouse_angles_z = n;
1532         }
1533         else
1534         {
1535                 tmp = getmousepos() * 0.1;
1536                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1537                 {
1538                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1539                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1540                 }
1541         }
1542
1543         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1544         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1545         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1546         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1547
1548         // Fix difference when angles don't have the same sign
1549         delta = '0 0 0';
1550         if(mouse_angles_y < -60 && current_angles_y > 60)
1551                 delta = '0 360 0';
1552         if(mouse_angles_y > 60 && current_angles_y < -60)
1553                 delta = '0 -360 0';
1554
1555         if(autocvar_camera_look_player)
1556                 attenuation = autocvar_camera_look_attenuation;
1557         else
1558                 attenuation = autocvar_camera_speed_attenuation;
1559
1560         attenuation = 1 / max(1, attenuation);
1561         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1562
1563         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1564         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1565         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1566         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1567
1568         // Camera position
1569         tmp = '0 0 0';
1570         dimensions = 0;
1571
1572         if( camera_direction_x )
1573         {
1574                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1575                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1576                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1577                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1578                 ++dimensions;
1579         }
1580
1581         if( camera_direction_y )
1582         {
1583                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1584                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1585                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1586                 ++dimensions;
1587         }
1588
1589         if( camera_direction_z )
1590         {
1591                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1592                 ++dimensions;
1593         }
1594
1595         if(autocvar_camera_free)
1596                 speed = autocvar_camera_speed_free;
1597         else
1598                 speed = autocvar_camera_speed_chase;
1599
1600         if(dimensions)
1601         {
1602                 speed = speed * sqrt(1 / dimensions);
1603                 camera_offset += tmp * speed;
1604         }
1605
1606         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1607
1608         // Camera modes
1609         if( autocvar_camera_free )
1610         {
1611                 if ( camera_mode == CAMERA_CHASE )
1612                 {
1613                         current_camera_offset = current_origin + current_camera_offset;
1614                         camera_offset = current_origin + camera_offset;
1615                 }
1616
1617                 camera_mode = CAMERA_FREE;
1618                 current_position = current_camera_offset;
1619         }
1620         else
1621         {
1622                 if ( camera_mode == CAMERA_FREE )
1623                 {
1624                         current_origin = view_origin;
1625                         camera_offset = camera_offset - current_origin;
1626                         current_camera_offset = current_camera_offset - current_origin;
1627                 }
1628
1629                 camera_mode = CAMERA_CHASE;
1630
1631                 if(autocvar_camera_chase_smoothly)
1632                         current_origin += (view_origin - current_origin) * attenuation;
1633                 else
1634                         current_origin = view_origin;
1635
1636                 current_position = current_origin + current_camera_offset;
1637         }
1638
1639         setproperty(VF_ANGLES, current_angles);
1640         setproperty(VF_ORIGIN, current_position);
1641 }