qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 /**
  82  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  83  *
  84  * TODO: Use a better solution where a common shared entitiy is used that contains
  85  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  86  * and STAT_FRAGLIMIT to be auto-sent)
  87  */
  88 void CheckForGamestartChange() {
  89         float startTime;
  90         startTime = getstatf(STAT_GAMESTARTTIME);
  91         if (previous_game_starttime != startTime) {
  92                 if ((time + 5.0) < startTime) {
  93                         //if connecting to server while restart was active don't always play prepareforbattle
  94                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  95                 }
  96                 if (time < startTime) {
  97                         restartAnnouncer = spawn();
  98                         restartAnnouncer.think = restartAnnouncer_Think;
  99                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 100                 }
 101         }
 102         previous_game_starttime = startTime;
 103 }
 104
 105 void Porto_Init()
 106 {
 107         porto = spawn();
 108         porto.classname = "porto";
 109         porto.draw = Porto_Draw;
 110         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 111 }
 112
 113 float drawtime;
 114 float avgspeed;
 115 vector GetCurrentFov(float fov)
 116 {
 117         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 118
 119         zoomsensitivity = autocvar_cl_zoomsensitivity;
 120         zoomfactor = autocvar_cl_zoomfactor;
 121         if(zoomfactor < 1 || zoomfactor > 16)
 122                 zoomfactor = 2.5;
 123         zoomspeed = autocvar_cl_zoomspeed;
 124         if(zoomspeed >= 0)
 125                 if(zoomspeed < 0.5 || zoomspeed > 16)
 126                         zoomspeed = 3.5;
 127
 128         zoomdir = button_zoom;
 129         if(hud == HUD_NORMAL)
 130         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 131                 zoomdir += button_attack2;
 132         if(spectatee_status > 0 || isdemo())
 133         {
 134                 if(spectatorbutton_zoom)
 135                 {
 136                         if(zoomdir)
 137                                 zoomdir = 0;
 138                         else
 139                                 zoomdir = 1;
 140                 }
 141                 // fteqcc failed twice here already, don't optimize this
 142         }
 143
 144         if(zoomdir)
 145                 zoomin_effect = 0;
 146
 147         if(zoomin_effect || camera_active)
 148         {
 149                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 150         }
 151         else
 152         {
 153                 if(zoomspeed < 0) // instant zoom
 154                 {
 155                         if(zoomdir)
 156                                 current_viewzoom = 1 / zoomfactor;
 157                         else
 158                                 current_viewzoom = 1;
 159                 }
 160                 else
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 164                         else
 165                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 166                 }
 167         }
 168
 169         if(almost_equals(current_viewzoom, 1))
 170                 current_zoomfraction = 0;
 171         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 172                 current_zoomfraction = 1;
 173         else
 174                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 175
 176         if(zoomsensitivity < 1)
 177                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 178         else
 179                 setsensitivityscale(1);
 180
 181         if (autocvar_cl_velocityzoom)
 182         {
 183                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 184                 avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 185                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 186                 //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 187         }
 188         else
 189                 velocityzoom = 1;
 190
 191         float frustumx, frustumy, fovx, fovy;
 192         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 193         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 194         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 195         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 196
 197         return '1 0 0' * fovx + '0 1 0' * fovy;
 198 }
 199
 200 // this function must match W_SetupShot!
 201 float zoomscript_caught;
 202
 203 vector wcross_origin;
 204 float wcross_scale_prev, wcross_alpha_prev;
 205 vector wcross_color_prev;
 206 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 207 vector wcross_color_goal_prev;
 208 float wcross_changedonetime;
 209
 210 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 211 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 212 float wcross_name_changestarttime, wcross_name_changedonetime;
 213 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 214 entity trueaim;
 215 entity trueaim_rifle;
 216
 217 #define SHOTTYPE_HITTEAM 1
 218 #define SHOTTYPE_HITOBSTRUCTION 2
 219 #define SHOTTYPE_HITWORLD 3
 220 #define SHOTTYPE_HITENEMY 4
 221
 222 void TrueAim_Init()
 223 {
 224         trueaim = spawn();
 225         trueaim.classname = "trueaim";
 226         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 227         trueaim_rifle = spawn();
 228         trueaim_rifle.classname = "trueaim_rifle";
 229         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230 }
 231
 232 float EnemyHitCheck()
 233 {
 234         float t;
 235         wcross_origin = project_3d_to_2d(trace_endpos);
 236         wcross_origin_z = 0;
 237         if(trace_networkentity < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(trace_networkentity > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(trace_networkentity - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == COLOR_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float reticle_type;
 344 string NextFrameCommand;
 345 void CSQC_SPIDER_HUD();
 346 void CSQC_RAPTOR_HUD();
 347
 348 vector freeze_org, freeze_ang;
 349 entity nightvision_noise, nightvision_noise2;
 350
 351 #define MAX_TIME_DIFF 5
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353 float hit_time, typehit_time;
 354 float nextsound_hit_time, nextsound_typehit_time;
 355 float hitindication_crosshair_time, hitindication_crosshair_size;
 356 float use_nex_chargepool;
 357
 358 float myhealth, myhealth_prev;
 359 float myhealth_flash;
 360
 361 float old_blurradius, old_bluralpha;
 362 float old_sharpen_intensity;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float eventchase_current_distance;
 370
 371 vector damage_blurpostprocess, content_blurpostprocess;
 372
 373 float checkfail[16];
 374
 375 void CSQC_UpdateView(float w, float h)
 376 {
 377         entity e;
 378         float fov;
 379         float f, i, j;
 380         vector v;
 381         vector vf_size, vf_min;
 382         float a;
 383         hud = getstati(STAT_HUD);
 384
 385         button_attack2 = (input_buttons & BUTTON_3);
 386         button_zoom = (input_buttons & BUTTON_4);
 387
 388         // FIXME do we need this hack?
 389         if(isdemo())
 390         {
 391                 // in demos, input_buttons do not work
 392                 button_zoom = (autocvar__togglezoom == "-");
 393         }
 394
 395 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 396         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 397         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 398         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 399         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 400         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 401         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 402
 403         vf_size = R_SetView3fv(VF_SIZE);
 404         vf_min = R_SetView3fv(VF_MIN);
 405         vid_width = vf_size_x;
 406         vid_height = vf_size_y;
 407
 408         vector reticle_pos, reticle_size;
 409         vector splash_pos, splash_size;
 410
 411         WaypointSprite_Load();
 412
 413         if(spectatee_status)
 414                 myteam = GetPlayerColor(spectatee_status - 1);
 415         else
 416                 myteam = GetPlayerColor(player_localentnum - 1);
 417
 418         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 419
 420         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 421         {
 422                 R_SetView(VF_ORIGIN, freeze_org);
 423                 R_SetView(VF_ANGLES, freeze_ang);
 424         }
 425         else
 426         {
 427                 freeze_org = R_SetView3fv(VF_ORIGIN);
 428                 freeze_ang = R_SetView3fv(VF_ANGLES);
 429         }
 430
 431         // event chase camera
 432         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 433         {
 434                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 435                 {
 436                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 437                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 438                         if(!autocvar_chase_active)
 439                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 440
 441                         // make the camera smooth back
 442                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 443                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 444                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 445                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 446
 447                         vector eventchase_target_origin;
 448                         makevectors(view_angles);
 449                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 450                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 451
 452                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 453                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 454                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 455                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 456                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 457
 458                         R_SetView(VF_ORIGIN, trace_endpos);
 459                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 460                 }
 461                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 462                 {
 463                         cvar_set("chase_active", "0");
 464                         eventchase_current_distance = 0; // start from 0 next time
 465                 }
 466         }
 467
 468         WarpZone_FixView();
 469         //WarpZone_FixPMove();
 470
 471         // Render the Scene
 472         view_origin = R_SetView3fv(VF_ORIGIN);
 473         view_angles = R_SetView3fv(VF_ANGLES);
 474         makevectors(view_angles);
 475         view_forward = v_forward;
 476         view_right = v_right;
 477         view_up = v_up;
 478
 479 #ifdef BLURTEST
 480         if(time > blurtest_time0 && time < blurtest_time1)
 481         {
 482                 float r, t;
 483
 484                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 485                 r = t * blurtest_radius;
 486                 f = 1 / pow(t, blurtest_power) - 1;
 487
 488                 cvar_set("r_glsl_postprocess", "1");
 489                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 490         }
 491         else
 492         {
 493                 cvar_set("r_glsl_postprocess", "0");
 494                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 495         }
 496 #endif
 497
 498         TargetMusic_Advance();
 499         Fog_Force();
 500
 501         if(drawtime == 0)
 502                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 503         else
 504                 drawframetime = bound(0.000001, time - drawtime, 1);
 505         drawtime = time;
 506
 507         // watch for gametype changes here...
 508         // in ParseStuffCMD the cmd isn't executed yet :/
 509         // might even be better to add the gametype to TE_CSQC_INIT...?
 510         if(!postinit)
 511                 PostInit();
 512
 513         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 514                 if(calledhooks & HOOK_START)
 515                 {
 516                         localcmd("\ncl_hook_gameend\n");
 517                         calledhooks |= HOOK_END;
 518                 }
 519
 520         CheckForGamestartChange();
 521         serverAnnouncer();
 522         maptimeAnnouncer();
 523         carrierAnnouncer();
 524
 525         fov = autocvar_fov;
 526         if(fov <= 59.5)
 527         {
 528                 if(!zoomscript_caught)
 529                 {
 530                         localcmd("+button9\n");
 531                         zoomscript_caught = 1;
 532                 }
 533         }
 534         else
 535         {
 536                 if(zoomscript_caught)
 537                 {
 538                         localcmd("-button9\n");
 539                         zoomscript_caught = 0;
 540                 }
 541         }
 542
 543         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 544         activeweapon = getstati(STAT_SWITCHWEAPON);
 545         f = (serverflags & SERVERFLAG_TEAMPLAY);
 546         if(f != teamplay)
 547         {
 548                 teamplay = f;
 549                 HUD_InitScores();
 550         }
 551
 552         if(last_weapon != activeweapon) {
 553                 weapontime = time;
 554                 last_weapon = activeweapon;
 555
 556                 e = get_weaponinfo(activeweapon);
 557                 if(e.netname != "")
 558                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 559                 else
 560                         localcmd("\ncl_hook_activeweapon none\n");
 561         }
 562
 563         // ALWAYS Clear Current Scene First
 564         R_ClearScene();
 565 #ifdef WORKAROUND_XON010
 566         if(checkextension("DP_CSQC_ROTATEMOVES"))
 567         {
 568 #endif
 569         R_SetView(VF_ORIGIN, view_origin);
 570         R_SetView(VF_ANGLES, view_angles);
 571 #ifdef WORKAROUND_XON010
 572         }
 573 #endif
 574
 575         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 576         R_SetView(VF_SIZE, vf_size);
 577         R_SetView(VF_MIN, vf_min);
 578
 579         // Assign Standard Viewflags
 580         // Draw the World (and sky)
 581         R_SetView(VF_DRAWWORLD, 1);
 582
 583         // Set the console size vars
 584         vid_conwidth = autocvar_vid_conwidth;
 585         vid_conheight = autocvar_vid_conheight;
 586         vid_pixelheight = autocvar_vid_pixelheight;
 587
 588         R_SetView(VF_FOV, GetCurrentFov(fov));
 589
 590         // Camera for demo playback
 591         if(camera_active)
 592         {
 593                 if(autocvar_camera_enable)
 594                         CSQC_Demo_Camera();
 595                 else
 596                 {
 597                         cvar_set("chase_active", ftos(chase_active_backup));
 598                         cvar_set("cl_demo_mousegrab", "0");
 599                         camera_active = FALSE;
 600                 }
 601         }
 602 #ifdef CAMERATEST
 603         else if(autocvar_camera_enable)
 604 #else
 605         else if(autocvar_camera_enable && isdemo())
 606 #endif
 607         {
 608                 // Enable required Darkplaces cvars
 609                 chase_active_backup = autocvar_chase_active;
 610                 cvar_set("chase_active", "2");
 611                 cvar_set("cl_demo_mousegrab", "1");
 612                 camera_active = TRUE;
 613                 camera_mode = FALSE;
 614         }
 615
 616         // Draw the Crosshair
 617         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 618
 619         // Draw the Engine Status Bar (the default Quake HUD)
 620         R_SetView(VF_DRAWENGINEHUD, 0);
 621
 622         // Update the mouse position
 623         /*
 624            mousepos_x = vid_conwidth;
 625            mousepos_y = vid_conheight;
 626            mousepos = mousepos*0.5 + getmousepos();
 627          */
 628
 629         e = self;
 630         for(self = world; (self = nextent(self)); )
 631                 if(self.draw)
 632                         self.draw();
 633         self = e;
 634
 635         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 636         R_RenderScene();
 637
 638         // now switch to 2D drawing mode by calling a 2D drawing function
 639         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 640         // next R_RenderScene call
 641         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 642
 643         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 644         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 645         {
 646                 // apply night vision effect
 647                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 648
 649                 if(!nightvision_noise)
 650                 {
 651                         nightvision_noise = spawn();
 652                         nightvision_noise.classname = "nightvision_noise";
 653                 }
 654                 if(!nightvision_noise2)
 655                 {
 656                         nightvision_noise2 = spawn();
 657                         nightvision_noise2.classname = "nightvision_noise2";
 658                 }
 659
 660                 // color tint in yellow
 661                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 662
 663                 // draw BG
 664                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 665                 rgb = '1 1 1';
 666                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 667                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 668                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 669                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 670                 tc_11 = tc_01 + tc_10 - tc_00;
 671                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 672                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 673                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 674                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 675                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 676                 R_EndPolygon();
 677
 678                 // draw FG
 679                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 680                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 681                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 682                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 683                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 684                 tc_11 = tc_01 + tc_10 - tc_00;
 685                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 686                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 687                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 688                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 689                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 690                 R_EndPolygon();
 691         }
 692
 693         // Draw the aiming reticle for weapons that use it
 694         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 695         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 696         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 697         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 698                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 699         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 700                 reticle_type = 2; // nex zoom
 701         else if(button_zoom || zoomscript_caught)
 702                 reticle_type = 1; // normal zoom
 703         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 704                 reticle_type = 2; // nex zoom
 705
 706         if (reticle_type)
 707         {
 708                 if(autocvar_cl_reticle_stretch)
 709                 {
 710                         reticle_size_x = vid_conwidth;
 711                         reticle_size_y = vid_conheight;
 712                         reticle_pos_x = 0;
 713                         reticle_pos_y = 0;
 714                 }
 715                 else
 716                 {
 717                         reticle_size_x = max(vid_conwidth, vid_conheight);
 718                         reticle_size_y = max(vid_conwidth, vid_conheight);
 719                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 720                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 721                 }
 722
 723                 f = current_zoomfraction;
 724                 if(zoomscript_caught)
 725                         f = 1;
 726                 if(autocvar_cl_reticle_item_normal)
 727                 {
 728                         if(reticle_type == 1 && f)
 729                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 730                 }
 731                 if(autocvar_cl_reticle_item_nex)
 732                 {
 733                         if(reticle_type == 2 && f)
 734                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 735                 }
 736         }
 737
 738
 739         // improved polyblend
 740         vector rgb;
 741         if(autocvar_hud_contents)
 742         {
 743                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 744                 vector liquidcolor;
 745
 746                 switch(pointcontents(view_origin))
 747                 {
 748                         case CONTENT_WATER:
 749                                 liquidalpha = autocvar_hud_contents_water_alpha;
 750                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 751                                 incontent = 1;
 752                                 break;
 753
 754                         case CONTENT_LAVA:
 755                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 756                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 757                                 incontent = 1;
 758                                 break;
 759
 760                         case CONTENT_SLIME:
 761                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 762                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 763                                 incontent = 1;
 764                                 break;
 765
 766                         default:
 767                                 liquidalpha = 0;
 768                                 liquidcolor = '0 0 0';
 769                                 incontent = 0;
 770                                 break;
 771                 }
 772
 773                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 774                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 775                         contentfadetime = autocvar_hud_contents_fadeintime;
 776                         liquidalpha_prev = liquidalpha;
 777                         liquidcolor_prev = liquidcolor;
 778                 }
 779                 else
 780                         contentfadetime = autocvar_hud_contents_fadeouttime;
 781
 782                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 783                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 784
 785                 if(contentavgalpha)
 786                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 787
 788                 if(autocvar_hud_postprocessing)
 789                 {
 790                         if(autocvar_hud_contents_blur && contentavgalpha)
 791                         {
 792                                 content_blurpostprocess_x = 1;
 793                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 794                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 795                         }
 796                         else
 797                         {
 798                                 content_blurpostprocess_x = 0;
 799                                 content_blurpostprocess_y = 0;
 800                                 content_blurpostprocess_z = 0;
 801                         }
 802                 }
 803         }
 804
 805         if(autocvar_hud_damage && !autocvar_chase_active)
 806         {
 807                 splash_size_x = max(vid_conwidth, vid_conheight);
 808                 splash_size_y = max(vid_conwidth, vid_conheight);
 809                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 810                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 811
 812                 float myhealth_flash_temp;
 813                 myhealth = getstati(STAT_HEALTH);
 814
 815                 // fade out
 816                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 817                 // add new damage
 818                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 819
 820                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 821                 pain_threshold = autocvar_hud_damage_pain_threshold;
 822                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 823                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 824
 825                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 826                 {
 827                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 828                 }
 829
 830                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 831
 832                 if(myhealth_prev < 1)
 833                 {
 834                         if(myhealth >= 1)
 835                         {
 836                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 837                                 myhealth_flash_temp = 0;
 838                         }
 839                         else
 840                         {
 841                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 842                         }
 843                 }
 844
 845                 if(spectatee_status == -1 || intermission)
 846                 {
 847                         myhealth_flash = 0; // observing, or match ended
 848                         myhealth_flash_temp = 0;
 849                 }
 850
 851                 myhealth_prev = myhealth;
 852
 853                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 854                 {
 855                         if(autocvar_cl_gentle_damage == 2)
 856                         {
 857                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 858                                 {
 859                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 860                                 }
 861                         }
 862                         else
 863                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 864
 865                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 866                 }
 867                 else
 868                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 869
 870                 if(autocvar_hud_postprocessing)
 871                 {
 872                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 873                         {
 874                                 damage_blurpostprocess_x = 1;
 875                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 876                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 877                         }
 878                         else
 879                         {
 880                                 damage_blurpostprocess_x = 0;
 881                                 damage_blurpostprocess_y = 0;
 882                                 damage_blurpostprocess_z = 0;
 883                         }
 884                 }
 885         }
 886
 887         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 888         {
 889                 // enable or disable rendering types if they are used or not
 890                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 891                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 892
 893                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 894                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 895                 {
 896                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 897                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 898                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 899                         {
 900                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 901                                 old_blurradius = blurradius;
 902                                 old_bluralpha = bluralpha;
 903                         }
 904                 }
 905                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 906                 {
 907                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 908                         old_blurradius = 0;
 909                         old_bluralpha = 0;
 910                 }
 911
 912                 // edge detection postprocess handling done second (used by hud_powerup)
 913                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 914                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 915                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 916
 917                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 918
 919                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 920                 {
 921                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 922                         {
 923                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 924                                 old_sharpen_intensity = sharpen_intensity;
 925                         }
 926                 }
 927                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 928                 {
 929                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 930                         old_sharpen_intensity = 0;
 931                 }
 932         }
 933
 934         if(menu_visible)
 935                 menu_show();
 936
 937         /*if(gametype == GAME_CTF)
 938           {
 939           ctf_view();
 940           } else */
 941
 942         // draw 2D entities
 943         e = self;
 944         for(self = world; (self = nextent(self)); )
 945                 if(self.draw2d)
 946                         self.draw2d();
 947         self = e;
 948         Draw_ShowNames_All();
 949
 950         scoreboard_active = HUD_WouldDrawScoreboard();
 951
 952         hit_time = getstatf(STAT_HIT_TIME);
 953         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 954         {
 955                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 956                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 957
 958                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 959         }
 960         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 961         if(typehit_time > nextsound_typehit_time)
 962         {
 963                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 964                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 965
 966                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 967         }
 968
 969         //else
 970         {
 971                 if(gametype == GAME_FREEZETAG)
 972                 {
 973                         if(getstati(STAT_FROZEN))
 974                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 975                         if(getstatf(STAT_REVIVE_PROGRESS))
 976                         {
 977                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 978                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 979                         }
 980                 }
 981
 982                 if(autocvar_r_letterbox == 0)
 983                         if(autocvar_viewsize < 120)
 984                                 CSQC_common_hud();
 985
 986                 // crosshair goes VERY LAST
 987                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 988                         string wcross_style;
 989                         float wcross_alpha, wcross_resolution;
 990                         wcross_style = autocvar_crosshair;
 991                         if (wcross_style == "0")
 992                                 return;
 993                         wcross_resolution = autocvar_crosshair_size;
 994                         if (wcross_resolution == 0)
 995                                 return;
 996                         wcross_alpha = autocvar_crosshair_alpha;
 997                         if (wcross_alpha == 0)
 998                                 return;
 999
1000                         // TrueAim check
1001                         float shottype;
1002
1003                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1004                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1005                         wcross_origin_z = 0;
1006                         if(autocvar_crosshair_hittest)
1007                         {
1008                                 vector wcross_oldorigin;
1009                                 wcross_oldorigin = wcross_origin;
1010                                 shottype = TrueAimCheck();
1011                                 if(shottype == SHOTTYPE_HITWORLD)
1012                                 {
1013                                         v = wcross_origin - wcross_oldorigin;
1014                                         v_x /= vid_conwidth;
1015                                         v_y /= vid_conheight;
1016                                         if(vlen(v) > 0.01)
1017                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1018                                 }
1019                                 if(!autocvar_crosshair_hittest_showimpact)
1020                                         wcross_origin = wcross_oldorigin;
1021                         }
1022                         else
1023                                 shottype = SHOTTYPE_HITWORLD;
1024
1025                         vector wcross_color, wcross_size;
1026                         string wcross_wep, wcross_name;
1027                         float wcross_scale, wcross_blur;
1028
1029                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1030                                 e = get_weaponinfo(activeweapon);
1031                                 if (e && e.netname != "")
1032                                 {
1033                                         wcross_wep = e.netname;
1034                                         if(autocvar_crosshair_per_weapon)
1035                                         {
1036                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1037                                                 if (wcross_resolution == 0)
1038                                                         return;
1039                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1040                                                 if (wcross_alpha == 0)
1041                                                         return;
1042
1043                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1044                                                 if(wcross_style == "" || wcross_style == "0")
1045                                                         wcross_style = wcross_wep;
1046                                         }
1047                                 }
1048                         }
1049                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1050                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1051                         else if(autocvar_crosshair_color_by_health)
1052                         {
1053                                 local float x = getstati(STAT_HEALTH);
1054
1055                                 //x = red
1056                                 //y = green
1057                                 //z = blue
1058
1059                                 wcross_color_z = 0;
1060
1061                                 if(x > 200)
1062                                 {
1063                                         wcross_color_x = 0;
1064                                         wcross_color_y = 1;
1065                                 }
1066                                 else if(x > 150)
1067                                 {
1068                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1069                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1070                                 }
1071                                 else if(x > 100)
1072                                 {
1073                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1074                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1075                                         wcross_color_z = 1 - (x-100)*0.02;
1076                                 }
1077                                 else if(x > 50)
1078                                 {
1079                                         wcross_color_x = 1;
1080                                         wcross_color_y = 1;
1081                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1082                                 }
1083                                 else if(x > 20)
1084                                 {
1085                                         wcross_color_x = 1;
1086                                         wcross_color_y = (x-20)*90/27/100;
1087                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1088                                 }
1089                                 else
1090                                 {
1091                                         wcross_color_x = 1;
1092                                         wcross_color_y = 0;
1093                                 }
1094                         }
1095                         else
1096                                 wcross_color = stov(autocvar_crosshair_color);
1097
1098                         wcross_name = strcat("gfx/crosshair", wcross_style);
1099
1100                         if(autocvar_crosshair_effect_scalefade)
1101                         {
1102                                 wcross_scale = wcross_resolution;
1103                                 wcross_resolution = 1;
1104                         }
1105                         else
1106                         {
1107                                 wcross_scale = 1;
1108                         }
1109
1110                         if(autocvar_crosshair_pickup)
1111                         {
1112                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1113
1114                                 if(pickup_crosshair_time < stat_pickup_time)
1115                                 {
1116                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1117                                                 pickup_crosshair_size = 1;
1118
1119                                         pickup_crosshair_time = stat_pickup_time;
1120                                 }
1121
1122                                 if(pickup_crosshair_size > 0)
1123                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1124                                 else
1125                                         pickup_crosshair_size = 0;
1126
1127                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1128                         }
1129
1130                         if(autocvar_crosshair_hitindication)
1131                         {
1132                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1133                                 if(hitindication_crosshair_time < hit_time)
1134                                 {
1135                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1136                                                 hitindication_crosshair_size = 1;
1137
1138                                         hitindication_crosshair_time = hit_time;
1139                                 }
1140
1141                                 if(hitindication_crosshair_size > 0)
1142                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1143                                 else
1144                                         hitindication_crosshair_size = 0;
1145
1146                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1147                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1148                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1149                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1150                         }
1151
1152                         if(shottype == SHOTTYPE_HITENEMY)
1153                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1154                         if(shottype == SHOTTYPE_HITTEAM)
1155                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1156
1157                         f = autocvar_crosshair_effect_speed;
1158                         if(f < 0)
1159                                 f *= -2 * g_weaponswitchdelay;
1160                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1161                         {
1162                                 wcross_changedonetime = time + f;
1163                         }
1164                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1165                         {
1166                                 wcross_name_changestarttime = time;
1167                                 wcross_name_changedonetime = time + f;
1168                                 if(wcross_name_goal_prev_prev)
1169                                         strunzone(wcross_name_goal_prev_prev);
1170                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1171                                 wcross_name_goal_prev = strzone(wcross_name);
1172                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1173                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1174                                 wcross_resolution_goal_prev = wcross_resolution;
1175                         }
1176
1177                         wcross_scale_goal_prev = wcross_scale;
1178                         wcross_alpha_goal_prev = wcross_alpha;
1179                         wcross_color_goal_prev = wcross_color;
1180
1181                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1182                         {
1183                                 wcross_blur = 1;
1184                                 wcross_alpha *= 0.75;
1185                         }
1186                         else
1187                                 wcross_blur = 0;
1188                         // *_prev is at time-frametime
1189                         // * is at wcross_changedonetime+f
1190                         // what do we have at time?
1191                         if(time < wcross_changedonetime)
1192                         {
1193                                 f = frametime / (wcross_changedonetime - time + frametime);
1194                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1195                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1196                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1197                         }
1198
1199                         wcross_scale_prev = wcross_scale;
1200                         wcross_alpha_prev = wcross_alpha;
1201                         wcross_color_prev = wcross_color;
1202
1203                         wcross_scale *= 1 - autocvar__menu_alpha;
1204                         wcross_alpha *= 1 - autocvar__menu_alpha;
1205                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1206
1207                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1208                         {
1209                                 // crosshair rings for weapon stats
1210                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1211                                 {
1212                                         // declarations and stats
1213                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1214                                         string ring_image, ring_inner_image;
1215                                         vector ring_rgb, ring_inner_rgb;
1216
1217                                         ring_scale = autocvar_crosshair_ring_size;
1218
1219                                         float weapon_clipload, weapon_clipsize;
1220                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1221                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1222
1223                                         float nex_charge, nex_chargepool;
1224                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1225                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1226
1227                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1228                                                 nex_charge_movingavg = nex_charge;
1229
1230
1231                                         // handle the values
1232                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1233                                         {
1234                                                 if (nex_chargepool || use_nex_chargepool) {
1235                                                         use_nex_chargepool = 1;
1236                                                         ring_inner_value = nex_chargepool;
1237                                                 } else {
1238                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1239                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1240                                                 }
1241
1242                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1243                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1244                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1245
1246                                                 // draw the outer ring to show the current charge of the weapon
1247                                                 ring_value = nex_charge;
1248                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1249                                                 ring_rgb = wcross_color;
1250                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1251                                         }
1252                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1253                                         {
1254                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1255                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1256                                                 ring_rgb = wcross_color;
1257                                                 ring_image = "gfx/crosshair_ring.tga";
1258                                         }
1259                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1260                                         {
1261                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1262                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1263                                                 ring_rgb = wcross_color;
1264                                                 ring_image = "gfx/crosshair_ring.tga";
1265                                         }
1266
1267                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1268                                         {
1269                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1270                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1271                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1272                                                 ring_rgb = wcross_color;
1273
1274                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1275                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1276                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1277                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1278                                                 else
1279                                                         ring_image = "gfx/crosshair_ring.tga";
1280                                         }
1281
1282                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1283                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1284
1285                                         if (ring_value)
1286                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1287                                 }
1288
1289 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1290                                 do \
1291                                 { \
1292                                         if(wcross_blur > 0) \
1293                                         { \
1294                                                 for(i = -2; i <= 2; ++i) \
1295                                                 for(j = -2; j <= 2; ++j) \
1296                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1297                                         } \
1298                                         else \
1299                                         { \
1300                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1301                                         } \
1302                                 } \
1303                                 while(0)
1304
1305 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1306                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1307
1308 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1309                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1310
1311                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1312                                 {
1313                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1314                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1315                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1316                                         f = 1 - f;
1317                                 }
1318                                 else
1319                                 {
1320                                         f = 1;
1321                                 }
1322                                 wcross_name_alpha_goal_prev = f;
1323
1324                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1325                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1326
1327                                 if(autocvar_crosshair_dot)
1328                                 {
1329                                         vector wcross_color_old;
1330                                         wcross_color_old = wcross_color;
1331                                         if(autocvar_crosshair_dot_color != "0")
1332                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1333                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1334                                         // FIXME why don't we use wcross_alpha here?
1335                                         wcross_color = wcross_color_old;
1336                                 }
1337                         }
1338                 }
1339                 else
1340                 {
1341                         wcross_scale_prev = 0;
1342                         wcross_alpha_prev = 0;
1343                         wcross_scale_goal_prev = 0;
1344                         wcross_alpha_goal_prev = 0;
1345                         wcross_changedonetime = 0;
1346                         if(wcross_name_goal_prev)
1347                                 strunzone(wcross_name_goal_prev);
1348                         wcross_name_goal_prev = string_null;
1349                         if(wcross_name_goal_prev_prev)
1350                                 strunzone(wcross_name_goal_prev_prev);
1351                         wcross_name_goal_prev_prev = string_null;
1352                         wcross_name_changestarttime = 0;
1353                         wcross_name_changedonetime = 0;
1354                         wcross_name_alpha_goal_prev = 0;
1355                         wcross_name_alpha_goal_prev_prev = 0;
1356                         wcross_resolution_goal_prev = 0;
1357                         wcross_resolution_goal_prev_prev = 0;
1358                 }
1359         }
1360
1361         if(NextFrameCommand)
1362         {
1363                 localcmd("\n", NextFrameCommand, "\n");
1364                 NextFrameCommand = string_null;
1365         }
1366
1367         // we must do this check AFTER a frame was rendered, or it won't work
1368         if(cs_project_is_b0rked == 0)
1369         {
1370                 string w0, h0;
1371                 w0 = ftos(autocvar_vid_conwidth);
1372                 h0 = ftos(autocvar_vid_conheight);
1373                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1374                 //R_SetView(VF_FOV, '90 90 0');
1375                 R_SetView(VF_ORIGIN, '0 0 0');
1376                 R_SetView(VF_ANGLES, '0 0 0');
1377                 R_SetView(VF_PERSPECTIVE, 1);
1378                 makevectors('0 0 0');
1379                 vector v1, v2;
1380                 cvar_set("vid_conwidth", "800");
1381                 cvar_set("vid_conheight", "600");
1382                 v1 = cs_project(v_forward);
1383                 cvar_set("vid_conwidth", "640");
1384                 cvar_set("vid_conheight", "480");
1385                 v2 = cs_project(v_forward);
1386                 if(v1 == v2)
1387                         cs_project_is_b0rked = 1;
1388                 else
1389                         cs_project_is_b0rked = -1;
1390                 cvar_set("vid_conwidth", w0);
1391                 cvar_set("vid_conheight", h0);
1392         }
1393
1394         if(autocvar__hud_configure)
1395                 HUD_Panel_Mouse();
1396
1397     if(hud && !intermission)
1398     {
1399         if(hud == HUD_SPIDERBOT)
1400             CSQC_SPIDER_HUD();
1401         else if(hud == HUD_WAKIZASHI)
1402             CSQC_WAKIZASHI_HUD();
1403         else if(hud == HUD_RAPTOR)
1404             CSQC_RAPTOR_HUD();
1405         else if(hud == HUD_BUMBLEBEE)
1406             CSQC_BUMBLE_HUD();
1407     }
1408         // let's reset the view back to normal for the end
1409         R_SetView(VF_MIN, '0 0 0');
1410         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1411 }
1412
1413
1414 void CSQC_common_hud(void)
1415 {
1416     // do some accuracy var caching
1417     float i;
1418     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1419     {
1420         if(autocvar_accuracy_color_levels != acc_color_levels)
1421         {
1422             if(acc_color_levels)
1423                 strunzone(acc_color_levels);
1424             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1425             acc_levels = tokenize(acc_color_levels);
1426             if (acc_levels > MAX_ACCURACY_LEVELS)
1427                 acc_levels = MAX_ACCURACY_LEVELS;
1428
1429             for (i = 0; i < acc_levels; ++i)
1430                 acc_lev[i] = stof(argv(i)) / 100.0;
1431         }
1432         // let know that acc_col[] needs to be loaded
1433         acc_col_x[0] = -1;
1434     }
1435
1436     HUD_Main(); // always run these functions for alpha checks
1437     HUD_DrawScoreboard();
1438
1439     if (scoreboard_active) // scoreboard/accuracy
1440         HUD_Reset();
1441     else if (intermission == 2) // map voting screen
1442     {
1443         HUD_FinaleOverlay();
1444         HUD_Reset();
1445     }
1446         /*
1447         switch(hud)
1448         {
1449                 case HUD_SPIDERBOT:
1450                         CSQC_SPIDER_HUD();
1451                         break;
1452
1453                 case HUD_WAKIZASHI:
1454                         CSQC_WAKIZASHI_HUD();
1455                         break;
1456
1457         case HUD_BUMBLEBEE:
1458             CSQC_BUMBLE_HUD();
1459             break;
1460         }
1461         */
1462 }
1463
1464
1465 // following vectors must be global to allow seamless switching between camera modes
1466 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1467 void CSQC_Demo_Camera()
1468 {
1469         float speed, attenuation, dimensions;
1470         vector tmp, delta;
1471
1472         if( autocvar_camera_reset || !camera_mode )
1473         {
1474                 camera_offset = '0 0 0';
1475                 current_angles = '0 0 0';
1476                 camera_direction = '0 0 0';
1477                 camera_offset_z += 30;
1478                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1479                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1480                 current_origin = view_origin;
1481                 current_camera_offset  = camera_offset;
1482                 cvar_set("camera_reset", "0");
1483                 camera_mode = CAMERA_CHASE;
1484         }
1485
1486         // Camera angles
1487         if( camera_roll )
1488                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1489
1490         if(autocvar_camera_look_player)
1491         {
1492                 local vector dir;
1493                 local float n;
1494
1495                 dir = normalize(view_origin - current_position);
1496                 n = mouse_angles_z;
1497                 mouse_angles = vectoangles(dir);
1498                 mouse_angles_x = mouse_angles_x * -1;
1499                 mouse_angles_z = n;
1500         }
1501         else
1502         {
1503                 tmp = getmousepos() * 0.1;
1504                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1505                 {
1506                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1507                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1508                 }
1509         }
1510
1511         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1512         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1513         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1514         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1515
1516         // Fix difference when angles don't have the same sign
1517         delta = '0 0 0';
1518         if(mouse_angles_y < -60 && current_angles_y > 60)
1519                 delta = '0 360 0';
1520         if(mouse_angles_y > 60 && current_angles_y < -60)
1521                 delta = '0 -360 0';
1522
1523         if(autocvar_camera_look_player)
1524                 attenuation = autocvar_camera_look_attenuation;
1525         else
1526                 attenuation = autocvar_camera_speed_attenuation;
1527
1528         attenuation = 1 / max(1, attenuation);
1529         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1530
1531         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1532         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1533         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1534         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1535
1536         // Camera position
1537         tmp = '0 0 0';
1538         dimensions = 0;
1539
1540         if( camera_direction_x )
1541         {
1542                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1543                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1544                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1545                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1546                 ++dimensions;
1547         }
1548
1549         if( camera_direction_y )
1550         {
1551                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1552                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1553                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1554                 ++dimensions;
1555         }
1556
1557         if( camera_direction_z )
1558         {
1559                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1560                 ++dimensions;
1561         }
1562
1563         if(autocvar_camera_free)
1564                 speed = autocvar_camera_speed_free;
1565         else
1566                 speed = autocvar_camera_speed_chase;
1567
1568         if(dimensions)
1569         {
1570                 speed = speed * sqrt(1 / dimensions);
1571                 camera_offset += tmp * speed;
1572         }
1573
1574         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1575
1576         // Camera modes
1577         if( autocvar_camera_free )
1578         {
1579                 if ( camera_mode == CAMERA_CHASE )
1580                 {
1581                         current_camera_offset = current_origin + current_camera_offset;
1582                         camera_offset = current_origin + camera_offset;
1583                 }
1584
1585                 camera_mode = CAMERA_FREE;
1586                 current_position = current_camera_offset;
1587         }
1588         else
1589         {
1590                 if ( camera_mode == CAMERA_FREE )
1591                 {
1592                         current_origin = view_origin;
1593                         camera_offset = camera_offset - current_origin;
1594                         current_camera_offset = current_camera_offset - current_origin;
1595                 }
1596
1597                 camera_mode = CAMERA_CHASE;
1598
1599                 if(autocvar_camera_chase_smoothly)
1600                         current_origin += (view_origin - current_origin) * attenuation;
1601                 else
1602                         current_origin = view_origin;
1603
1604                 current_position = current_origin + current_camera_offset;
1605         }
1606
1607         R_SetView(VF_ANGLES, current_angles);
1608         R_SetView(VF_ORIGIN, current_position);
1609 }