qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 if(intermission) { curspeed = 0; }
 168                 else
 169                 {
 170
 171                         makevectors(view_angles);
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon) // WEAPONTODO
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_MORTAR: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_VORTEX:
 291                 case WEP_VAPORIZER:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_DEVASTATOR: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string reticle_image;
 369 string NextFrameCommand;
 370 void CSQC_SPIDER_HUD();
 371 void CSQC_RAPTOR_HUD();
 372
 373 vector freeze_org, freeze_ang;
 374 entity nightvision_noise, nightvision_noise2;
 375
 376 #define MAX_TIME_DIFF 5
 377 float pickup_crosshair_time, pickup_crosshair_size;
 378 float hitindication_crosshair_size;
 379 float use_vortex_chargepool;
 380
 381 float myhealth, myhealth_prev;
 382 float myhealth_flash;
 383
 384 float old_blurradius, old_bluralpha;
 385 float old_sharpen_intensity;
 386
 387 vector myhealth_gentlergb;
 388
 389 float contentavgalpha, liquidalpha_prev;
 390 vector liquidcolor_prev;
 391
 392 float eventchase_current_distance;
 393 float eventchase_running;
 394 float WantEventchase()
 395 {
 396         if(autocvar_cl_orthoview)
 397                 return FALSE;
 398         if(intermission)
 399                 return TRUE;
 400         if(spectatee_status >= 0)
 401         {
 402                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 403                         return TRUE;
 404                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 405                 {
 406                         if(autocvar_cl_eventchase_death == 2)
 407                         {
 408                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 409                                 if(self.velocity == '0 0 0' || eventchase_running)
 410                                         return TRUE;
 411                         }
 412                         else return TRUE;
 413                 }
 414         }
 415         return FALSE;
 416 }
 417
 418 vector damage_blurpostprocess, content_blurpostprocess;
 419
 420 float checkfail[16];
 421
 422 float unaccounted_damage = 0;
 423 void UpdateDamage()
 424 {
 425         // accumulate damage with each stat update
 426         float unaccounted_damage_new = getstati(STAT_DAMAGE_DEALT_TOTAL);
 427         static float damage_dealt_time_prev = 0;
 428         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 429         if (damage_dealt_time != damage_dealt_time_prev)
 430         {
 431                 unaccounted_damage += unaccounted_damage_new;
 432                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 433         }
 434         damage_dealt_time_prev = damage_dealt_time;
 435
 436         // prevent hitsound when switching spectatee
 437         static float spectatee_status_prev = 0;
 438         if (spectatee_status != spectatee_status_prev)
 439                 unaccounted_damage = 0;
 440         spectatee_status_prev = spectatee_status;
 441 }
 442
 443 void UpdateHitsound()
 444 {
 445         // varying sound pitch
 446
 447         static float hitsound_time_prev = 0;
 448         if (COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 449         {
 450                 if (autocvar_cl_hitsound && unaccounted_damage)
 451                 {
 452                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 453                         float a = autocvar_cl_hitsound_max_pitch;
 454                         float b = autocvar_cl_hitsound_min_pitch;
 455                         float c = autocvar_cl_hitsound_nom_damage;
 456                         float x = unaccounted_damage;
 457                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 458
 459                         // if sound variation is disabled, set pitch_shift to 1
 460                         if (autocvar_cl_hitsound == 1)
 461                                 pitch_shift = 1;
 462
 463                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 464                         if (autocvar_cl_hitsound == 3)
 465                         {
 466                                 float mirror_value = (a-b)/2 + b;
 467                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 468                         }
 469
 470                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 471
 472                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 473                         // todo: normalize sound pressure levels? seems unnecessary
 474
 475                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 476                 }
 477                 unaccounted_damage = 0;
 478                 hitsound_time_prev = time;
 479         }
 480
 481         static float typehit_time_prev = 0;
 482         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 483         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 484         {
 485                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 486                 typehit_time_prev = typehit_time;
 487         }
 488 }
 489
 490 void UpdateCrosshair()
 491 {
 492         static float rainbow_last_flicker;
 493     static vector rainbow_prev_color;
 494         entity e = self;
 495         float f, i, j;
 496         vector v;
 497         if(getstati(STAT_FROZEN))
 498                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 499         else if (getstatf(STAT_HEALING_ORB)>time)
 500                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 501         if(!intermission)
 502         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 503         {
 504                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 505                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 506         }
 507         else if(getstatf(STAT_REVIVE_PROGRESS))
 508         {
 509                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 510                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 511         }
 512
 513         if(autocvar_r_letterbox == 0)
 514                 if(autocvar_viewsize < 120)
 515                         CSQC_common_hud();
 516
 517         // crosshair goes VERY LAST
 518         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
 519         {
 520                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 521                         return;
 522
 523                 string wcross_style;
 524                 float wcross_alpha, wcross_resolution;
 525                 wcross_style = autocvar_crosshair;
 526                 if (wcross_style == "0")
 527                         return;
 528                 wcross_resolution = autocvar_crosshair_size;
 529                 if (wcross_resolution == 0)
 530                         return;
 531                 wcross_alpha = autocvar_crosshair_alpha;
 532                 if (wcross_alpha == 0)
 533                         return;
 534
 535                 // TrueAim check
 536                 float shottype;
 537
 538                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 539                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 540                 wcross_origin_z = 0;
 541                 if(autocvar_crosshair_hittest)
 542                 {
 543                         vector wcross_oldorigin;
 544                         wcross_oldorigin = wcross_origin;
 545                         shottype = TrueAimCheck();
 546                         if(shottype == SHOTTYPE_HITWORLD)
 547                         {
 548                                 v = wcross_origin - wcross_oldorigin;
 549                                 v_x /= vid_conwidth;
 550                                 v_y /= vid_conheight;
 551                                 if(vlen(v) > 0.01)
 552                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 553                         }
 554                         if(!autocvar_crosshair_hittest_showimpact)
 555                                 wcross_origin = wcross_oldorigin;
 556                 }
 557                 else
 558                         shottype = SHOTTYPE_HITWORLD;
 559
 560                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 561                 string wcross_name = "";
 562                 float wcross_scale, wcross_blur;
 563
 564                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 565                 {
 566                         e = get_weaponinfo(switchingweapon);
 567                         if(e)
 568                         {
 569                                 if(autocvar_crosshair_per_weapon)
 570                                 {
 571                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 572                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 573                                         //if (wcross_resolution == 0)
 574                                                 //return;
 575
 576                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 577                                         wcross_resolution *= e.w_crosshair_size;
 578                                         wcross_name = e.w_crosshair;
 579                                 }
 580                         }
 581                 }
 582
 583                 if(wcross_name == "")
 584                         wcross_name = strcat("gfx/crosshair", wcross_style);
 585
 586                 // MAIN CROSSHAIR COLOR DECISION
 587                 switch(autocvar_crosshair_color_special)
 588                 {
 589                         case 1: // crosshair_color_per_weapon
 590                         {
 591                                 if(e)
 592                                 {
 593                                         wcross_color = e.wpcolor;
 594                                         break;
 595                                 }
 596                                 else { goto normalcolor; }
 597                         }
 598
 599                         case 2: // crosshair_color_by_health
 600                         {
 601                                 float x = getstati(STAT_HEALTH);
 602
 603                                 //x = red
 604                                 //y = green
 605                                 //z = blue
 606
 607                                 wcross_color_z = 0;
 608
 609                                 if(x > 200)
 610                                 {
 611                                         wcross_color_x = 0;
 612                                         wcross_color_y = 1;
 613                                 }
 614                                 else if(x > 150)
 615                                 {
 616                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 617                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 618                                 }
 619                                 else if(x > 100)
 620                                 {
 621                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 622                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 623                                         wcross_color_z = 1 - (x-100)*0.02;
 624                                 }
 625                                 else if(x > 50)
 626                                 {
 627                                         wcross_color_x = 1;
 628                                         wcross_color_y = 1;
 629                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 630                                 }
 631                                 else if(x > 20)
 632                                 {
 633                                         wcross_color_x = 1;
 634                                         wcross_color_y = (x-20)*90/27/100;
 635                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 636                                 }
 637                                 else
 638                                 {
 639                                         wcross_color_x = 1;
 640                                         wcross_color_y = 0;
 641                                 }
 642                                 break;
 643                         }
 644
 645                         case 3: // crosshair_color_rainbow
 646                         {
 647                                 if(time >= rainbow_last_flicker)
 648                                 {
 649                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 650                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 651                                 }
 652                                 wcross_color = rainbow_prev_color;
 653                                 break;
 654                         }
 655                         :normalcolor
 656                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 657                 }
 658
 659                 if(autocvar_crosshair_effect_scalefade)
 660                 {
 661                         wcross_scale = wcross_resolution;
 662                         wcross_resolution = 1;
 663                 }
 664                 else
 665                 {
 666                         wcross_scale = 1;
 667                 }
 668
 669                 if(autocvar_crosshair_pickup)
 670                 {
 671                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 672
 673                         if(pickup_crosshair_time < stat_pickup_time)
 674                         {
 675                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 676                                         pickup_crosshair_size = 1;
 677
 678                                 pickup_crosshair_time = stat_pickup_time;
 679                         }
 680
 681                         if(pickup_crosshair_size > 0)
 682                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 683                         else
 684                                 pickup_crosshair_size = 0;
 685
 686                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 687                 }
 688
 689                 // todo: make crosshair hit indication dependent on damage dealt
 690                 if(autocvar_crosshair_hitindication)
 691                 {
 692                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 693
 694                         if(unaccounted_damage)
 695                         {
 696                                 hitindication_crosshair_size = 1;
 697                         }
 698
 699                         if(hitindication_crosshair_size > 0)
 700                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 701                         else
 702                                 hitindication_crosshair_size = 0;
 703
 704                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 705                         wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
 706                         wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
 707                         wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
 708                 }
 709
 710                 if(shottype == SHOTTYPE_HITENEMY)
 711                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 712                 if(shottype == SHOTTYPE_HITTEAM)
 713                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 714
 715                 f = fabs(autocvar_crosshair_effect_time);
 716                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 717                 {
 718                         wcross_changedonetime = time + f;
 719                 }
 720                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 721                 {
 722                         wcross_name_changestarttime = time;
 723                         wcross_name_changedonetime = time + f;
 724                         if(wcross_name_goal_prev_prev)
 725                                 strunzone(wcross_name_goal_prev_prev);
 726                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 727                         wcross_name_goal_prev = strzone(wcross_name);
 728                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 729                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 730                         wcross_resolution_goal_prev = wcross_resolution;
 731                 }
 732
 733                 wcross_scale_goal_prev = wcross_scale;
 734                 wcross_alpha_goal_prev = wcross_alpha;
 735                 wcross_color_goal_prev = wcross_color;
 736
 737                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 738                 {
 739                         wcross_blur = 1;
 740                         wcross_alpha *= 0.75;
 741                 }
 742                 else
 743                         wcross_blur = 0;
 744                 // *_prev is at time-frametime
 745                 // * is at wcross_changedonetime+f
 746                 // what do we have at time?
 747                 if(time < wcross_changedonetime)
 748                 {
 749                         f = frametime / (wcross_changedonetime - time + frametime);
 750                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 751                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 752                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 753                 }
 754
 755                 wcross_scale_prev = wcross_scale;
 756                 wcross_alpha_prev = wcross_alpha;
 757                 wcross_color_prev = wcross_color;
 758
 759                 wcross_scale *= 1 - autocvar__menu_alpha;
 760                 wcross_alpha *= 1 - autocvar__menu_alpha;
 761                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 762
 763                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 764                 {
 765                         // crosshair rings for weapon stats
 766                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 767                         {
 768                                 // declarations and stats
 769                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 770                                 string ring_image = string_null, ring_inner_image = string_null;
 771                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 772
 773                                 ring_scale = autocvar_crosshair_ring_size;
 774
 775                                 float weapon_clipload, weapon_clipsize;
 776                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 777                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 778
 779                                 float ok_ammo_charge, ok_ammo_chargepool;
 780                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 781                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOl);
 782
 783                                 float vortex_charge, vortex_chargepool;
 784                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 785                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 786
 787                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 788
 789                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 790                                         vortex_charge_movingavg = vortex_charge;
 791
 792
 793                                 // handle the values
 794                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 795                                 {
 796                                         if (vortex_chargepool || use_vortex_chargepool) {
 797                                                 use_vortex_chargepool = 1;
 798                                                 ring_inner_value = vortex_chargepool;
 799                                         } else {
 800                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 801                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 802                                         }
 803
 804                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 805                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 806                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 807
 808                                         // draw the outer ring to show the current charge of the weapon
 809                                         ring_value = vortex_charge;
 810                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 811                                         ring_rgb = wcross_color;
 812                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 813                                 }
 814                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 815                                 {
 816                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 817                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 818                                         ring_rgb = wcross_color;
 819                                         ring_image = "gfx/crosshair_ring.tga";
 820                                 }
 821                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 822                                 {
 823                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 824                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 825                                         ring_rgb = wcross_color;
 826                                         ring_image = "gfx/crosshair_ring.tga";
 827                                 }
 828                                 else if (ok_ammo_charge)
 829                                 {
 830                                         ring_value = ok_ammo_chargepool;
 831                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 832                                         ring_rgb = wcross_color;
 833                                         ring_image = "gfx/crosshair_ring.tga";
 834                                 }
 835                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 836                                 {
 837                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 838                                         ring_scale = autocvar_crosshair_ring_reload_size;
 839                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 840                                         ring_rgb = wcross_color;
 841
 842                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 843                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 844                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 845                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 846                                         else
 847                                                 ring_image = "gfx/crosshair_ring.tga";
 848                                 }
 849                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 850                                 {
 851                                         ring_value = arc_heat;
 852                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 853                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 854                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 855                                         ring_image = "gfx/crosshair_ring.tga";
 856                                 }
 857
 858                                 // if in weapon switch animation, fade ring out/in
 859                                 if(autocvar_crosshair_effect_time > 0)
 860                                 {
 861                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 862                                         if (!(f < 1))
 863                                         {
 864                                                 wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
 865                                         }
 866
 867                                         if(wcross_ring_prev)
 868                                         {
 869                                                 if(f < 1)
 870                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 871                                         }
 872                                         else
 873                                         {
 874                                                 if(f < 1)
 875                                                         ring_alpha *= bound(0, f, 1);
 876                                         }
 877                                 }
 878
 879                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 880                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 881
 882                                 if (ring_value)
 883                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 884                         }
 885
 886 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 887                         do \
 888                         { \
 889                                 if(wcross_blur > 0) \
 890                                 { \
 891                                         for(i = -2; i <= 2; ++i) \
 892                                         for(j = -2; j <= 2; ++j) \
 893                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 894                                 } \
 895                                 else \
 896                                 { \
 897                                         M(0,0,sz,wcross_name,wcross_alpha); \
 898                                 } \
 899                         } \
 900                         while(0)
 901
 902 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 903                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 904
 905 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 906                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 907
 908                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 909                         {
 910                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 911                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 912                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 913                                 f = 1 - f;
 914                         }
 915                         else
 916                         {
 917                                 f = 1;
 918                         }
 919                         wcross_name_alpha_goal_prev = f;
 920
 921                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 922                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 923
 924                         if(autocvar_crosshair_dot)
 925                         {
 926                                 vector wcross_color_old;
 927                                 wcross_color_old = wcross_color;
 928
 929                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 930                                         wcross_color = stov(autocvar_crosshair_dot_color);
 931
 932                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 933                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 934                                 wcross_color = wcross_color_old;
 935                         }
 936                 }
 937         }
 938         else
 939         {
 940                 wcross_scale_prev = 0;
 941                 wcross_alpha_prev = 0;
 942                 wcross_scale_goal_prev = 0;
 943                 wcross_alpha_goal_prev = 0;
 944                 wcross_changedonetime = 0;
 945                 if(wcross_name_goal_prev)
 946                         strunzone(wcross_name_goal_prev);
 947                 wcross_name_goal_prev = string_null;
 948                 if(wcross_name_goal_prev_prev)
 949                         strunzone(wcross_name_goal_prev_prev);
 950                 wcross_name_goal_prev_prev = string_null;
 951                 wcross_name_changestarttime = 0;
 952                 wcross_name_changedonetime = 0;
 953                 wcross_name_alpha_goal_prev = 0;
 954                 wcross_name_alpha_goal_prev_prev = 0;
 955                 wcross_resolution_goal_prev = 0;
 956                 wcross_resolution_goal_prev_prev = 0;
 957         }
 958 }
 959
 960 #define BUTTON_3 4
 961 #define BUTTON_4 8
 962 float cl_notice_run();
 963 float prev_myteam;
 964 void CSQC_UpdateView(float w, float h)
 965 {
 966         entity e;
 967         float fov;
 968         float f, i;
 969         vector vf_size, vf_min;
 970         float a;
 971
 972         execute_next_frame();
 973
 974         ++framecount;
 975
 976         hud = getstati(STAT_HUD);
 977
 978         if(autocvar__hud_showbinds_reload) // menu can set this one
 979         {
 980                 db_close(binddb);
 981                 binddb = db_create();
 982                 cvar_set("_hud_showbinds_reload", "0");
 983         }
 984
 985         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 986                 view_quality = getproperty(VF_MINFPS_QUALITY);
 987         else
 988                 view_quality = 1;
 989
 990         button_attack2 = (input_buttons & BUTTON_3);
 991         button_zoom = (input_buttons & BUTTON_4);
 992
 993 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 994         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 995         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 996         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 997         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 998         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 999         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1000         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1001
1002         vf_size = getpropertyvec(VF_SIZE);
1003         vf_min = getpropertyvec(VF_MIN);
1004         vid_width = vf_size_x;
1005         vid_height = vf_size_y;
1006
1007         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1008         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1009
1010         WaypointSprite_Load();
1011
1012         CSQCPlayer_SetCamera();
1013
1014 #ifdef COMPAT_XON050_ENGINE
1015         if(spectatee_status)
1016                 myteam = GetPlayerColor(spectatee_status - 1);
1017         else
1018 #endif
1019                 myteam = GetPlayerColor(player_localentnum - 1);
1020
1021         if(myteam != prev_myteam)
1022         {
1023                 myteamcolors = colormapPaletteColor(myteam, 1);
1024                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1025                         hud_panel[i].update_time = time;
1026                 prev_myteam = myteam;
1027         }
1028
1029         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1030
1031         float is_dead = (getstati(STAT_HEALTH) <= 0);
1032
1033         // FIXME do we need this hack?
1034         if(isdemo())
1035         {
1036                 // in demos, input_buttons do not work
1037                 button_zoom = (autocvar__togglezoom == "-");
1038         }
1039         else if(button_zoom
1040                 && autocvar_cl_unpress_zoom_on_death
1041                 && (spectatee_status >= 0)
1042                 && (is_dead || intermission))
1043         {
1044                 // no zoom while dead or in intermission please
1045                 localcmd("-zoom\n");
1046                 button_zoom = FALSE;
1047         }
1048
1049         // event chase camera
1050         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1051         {
1052                 if(WantEventchase())
1053                 {
1054                         eventchase_running = TRUE;
1055
1056                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1057                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1058
1059                         // detect maximum viewoffset and use it
1060                         if(autocvar_cl_eventchase_viewoffset)
1061                         {
1062                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
1063                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1064                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
1065                         }
1066
1067                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1068                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1069                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1070                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1071
1072                         // make the camera smooth back
1073                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1074                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1075                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1076                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1077
1078                         makevectors(view_angles);
1079
1080                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1081                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1082
1083                         // If the boxtrace fails, revert back to line tracing.
1084                         if(trace_startsolid)
1085                         {
1086                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1087                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1088                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
1089                         }
1090                         else { setproperty(VF_ORIGIN, trace_endpos); }
1091
1092                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1093                 }
1094                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1095                 {
1096                         eventchase_running = FALSE;
1097                         cvar_set("chase_active", "0");
1098                         eventchase_current_distance = 0; // start from 0 next time
1099                 }
1100         }
1101         // workaround for camera stuck between player's legs when using chase_active 1
1102         // because the engine stops updating the chase_active camera when the game ends
1103         else if(intermission)
1104         {
1105                 cvar_settemp("chase_active", "-1");
1106                 eventchase_current_distance = 0;
1107         }
1108
1109         // do lockview after event chase camera so that it still applies whenever necessary.
1110         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1111         {
1112                 setproperty(VF_ORIGIN, freeze_org);
1113                 setproperty(VF_ANGLES, freeze_ang);
1114         }
1115         else
1116         {
1117                 freeze_org = getpropertyvec(VF_ORIGIN);
1118                 freeze_ang = getpropertyvec(VF_ANGLES);
1119         }
1120
1121         WarpZone_FixView();
1122         //WarpZone_FixPMove();
1123
1124         vector ov_org = '0 0 0';
1125         vector ov_mid = '0 0 0';
1126         vector ov_worldmin = '0 0 0';
1127         vector ov_worldmax = '0 0 0';
1128         if(autocvar_cl_orthoview)
1129         {
1130                 ov_worldmin = mi_picmin;
1131                 ov_worldmax = mi_picmax;
1132
1133                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
1134                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
1135                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1136
1137                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1138                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
1139
1140                 float ov_nearest = vlen(ov_org - vec3(
1141                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
1142                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
1143                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
1144                 ));
1145
1146                 float ov_furthest = 0;
1147                 float dist = 0;
1148
1149                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1150                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1151                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1152                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1153                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1154                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1155                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1156                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1157
1158                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1159                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1160                 cvar_settemp("r_farclip_world", "0");
1161                 cvar_settemp("r_novis", "1");
1162                 cvar_settemp("r_useportalculling", "0");
1163                 cvar_settemp("r_useinfinitefarclip", "0");
1164
1165                 setproperty(VF_ORIGIN, ov_org);
1166                 setproperty(VF_ANGLES, '90 0 0');
1167
1168                 #if 0
1169                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1170                         vtos(ov_org),
1171                         vtos(getpropertyvec(VF_ANGLES)),
1172                         ov_distance,
1173                         ov_nearest,
1174                         ov_furthest);
1175                 #endif
1176         }
1177
1178         // Render the Scene
1179         view_origin = getpropertyvec(VF_ORIGIN);
1180         view_angles = getpropertyvec(VF_ANGLES);
1181         makevectors(view_angles);
1182         view_forward = v_forward;
1183         view_right = v_right;
1184         view_up = v_up;
1185
1186 #ifdef BLURTEST
1187         if(time > blurtest_time0 && time < blurtest_time1)
1188         {
1189                 float r, t;
1190
1191                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1192                 r = t * blurtest_radius;
1193                 f = 1 / pow(t, blurtest_power) - 1;
1194
1195                 cvar_set("r_glsl_postprocess", "1");
1196                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1197         }
1198         else
1199         {
1200                 cvar_set("r_glsl_postprocess", "0");
1201                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1202         }
1203 #endif
1204
1205         TargetMusic_Advance();
1206         Fog_Force();
1207
1208         if(drawtime == 0)
1209                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1210         else
1211                 drawframetime = bound(0.000001, time - drawtime, 1);
1212         drawtime = time;
1213
1214         // watch for gametype changes here...
1215         // in ParseStuffCMD the cmd isn't executed yet :/
1216         // might even be better to add the gametype to TE_CSQC_INIT...?
1217         if(!postinit)
1218                 PostInit();
1219
1220         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1221         {
1222                 if(calledhooks & HOOK_START)
1223                 {
1224                         localcmd("\ncl_hook_gameend\n");
1225                         calledhooks |= HOOK_END;
1226                 }
1227         }
1228
1229         Announcer();
1230
1231         fov = autocvar_fov;
1232         if(fov <= 59.5)
1233         {
1234                 if(!zoomscript_caught)
1235                 {
1236                         localcmd("+button9\n");
1237                         zoomscript_caught = 1;
1238                 }
1239         }
1240         else
1241         {
1242                 if(zoomscript_caught)
1243                 {
1244                         localcmd("-button9\n");
1245                         zoomscript_caught = 0;
1246                 }
1247         }
1248
1249         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1250
1251         // next WANTED weapon (for HUD)
1252         switchweapon = getstati(STAT_SWITCHWEAPON);
1253
1254         // currently switching-to weapon (for crosshair)
1255         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1256
1257         // actually active weapon (for zoom)
1258         activeweapon = getstati(STAT_ACTIVEWEAPON);
1259
1260         f = (serverflags & SERVERFLAG_TEAMPLAY);
1261         if(f != teamplay)
1262         {
1263                 teamplay = f;
1264                 HUD_InitScores();
1265         }
1266
1267         if(last_switchweapon != switchweapon)
1268         {
1269                 weapontime = time;
1270                 last_switchweapon = switchweapon;
1271                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1272                 {
1273                         localcmd("-zoom\n");
1274                         button_zoom = FALSE;
1275                 }
1276                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1277                 {
1278                         localcmd("-fire\n");
1279                         localcmd("-fire2\n");
1280                         button_attack2 = FALSE;
1281                 }
1282         }
1283         if(last_activeweapon != activeweapon)
1284         {
1285                 last_activeweapon = activeweapon;
1286
1287                 e = get_weaponinfo(activeweapon);
1288                 if(e.netname != "")
1289                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1290                 else
1291                         localcmd("\ncl_hook_activeweapon none\n");
1292         }
1293
1294         // ALWAYS Clear Current Scene First
1295         clearscene();
1296 #ifdef WORKAROUND_XON010
1297         if(checkextension("DP_CSQC_ROTATEMOVES"))
1298         {
1299 #endif
1300         setproperty(VF_ORIGIN, view_origin);
1301         setproperty(VF_ANGLES, view_angles);
1302 #ifdef WORKAROUND_XON010
1303         }
1304 #endif
1305
1306         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1307         setproperty(VF_SIZE, vf_size);
1308         setproperty(VF_MIN, vf_min);
1309
1310         // Assign Standard Viewflags
1311         // Draw the World (and sky)
1312         setproperty(VF_DRAWWORLD, 1);
1313
1314         // Set the console size vars
1315         vid_conwidth = autocvar_vid_conwidth;
1316         vid_conheight = autocvar_vid_conheight;
1317         vid_pixelheight = autocvar_vid_pixelheight;
1318
1319         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1320         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1321
1322         // Camera for demo playback
1323         if(camera_active)
1324         {
1325                 if(autocvar_camera_enable)
1326                         CSQC_Demo_Camera();
1327                 else
1328                 {
1329                         cvar_set("chase_active", ftos(chase_active_backup));
1330                         cvar_set("cl_demo_mousegrab", "0");
1331                         camera_active = FALSE;
1332                 }
1333         }
1334 #ifdef CAMERATEST
1335         else if(autocvar_camera_enable)
1336 #else
1337         else if(autocvar_camera_enable && isdemo())
1338 #endif
1339         {
1340                 // Enable required Darkplaces cvars
1341                 chase_active_backup = autocvar_chase_active;
1342                 cvar_set("chase_active", "2");
1343                 cvar_set("cl_demo_mousegrab", "1");
1344                 camera_active = TRUE;
1345                 camera_mode = FALSE;
1346         }
1347
1348         // Draw the Crosshair
1349         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1350
1351         // Draw the Engine Status Bar (the default Quake HUD)
1352         setproperty(VF_DRAWENGINESBAR, 0);
1353
1354         // Update the mouse position
1355         /*
1356            mousepos_x = vid_conwidth;
1357            mousepos_y = vid_conheight;
1358            mousepos = mousepos*0.5 + getmousepos();
1359          */
1360
1361         e = self;
1362         for(self = world; (self = nextent(self)); )
1363                 if(self.draw)
1364                         self.draw();
1365         self = e;
1366
1367         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1368         renderscene();
1369
1370         // now switch to 2D drawing mode by calling a 2D drawing function
1371         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1372         // next R_RenderScene call
1373         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1374
1375         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1376         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1377         {
1378                 // apply night vision effect
1379                 vector tc_00, tc_01, tc_10, tc_11;
1380                 vector rgb = '0 0 0';
1381
1382                 if(!nightvision_noise)
1383                 {
1384                         nightvision_noise = spawn();
1385                         nightvision_noise.classname = "nightvision_noise";
1386                 }
1387                 if(!nightvision_noise2)
1388                 {
1389                         nightvision_noise2 = spawn();
1390                         nightvision_noise2.classname = "nightvision_noise2";
1391                 }
1392
1393                 // color tint in yellow
1394                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1395
1396                 // draw BG
1397                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1398                 rgb = '1 1 1';
1399                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1400                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1401                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1402                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1403                 tc_11 = tc_01 + tc_10 - tc_00;
1404                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1405                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1406                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1407                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1408                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1409                 R_EndPolygon();
1410
1411                 // draw FG
1412                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1413                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1414                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1415                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1416                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1417                 tc_11 = tc_01 + tc_10 - tc_00;
1418                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1419                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1420                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1421                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1422                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1423                 R_EndPolygon();
1424         }
1425
1426         if(autocvar_cl_reticle)
1427         {
1428                 // Draw the aiming reticle for weapons that use it
1429                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1430                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1431                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1432                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1433                 {
1434                         // no zoom reticle while dead
1435                         reticle_type = 0;
1436                 }
1437                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1438                 {
1439                         if(reticle_image != "") { reticle_type = 2; }
1440                         else { reticle_type = 0; }
1441                 }
1442                 else if(button_zoom || zoomscript_caught)
1443                 {
1444                         // normal zoom
1445                         reticle_type = 1;
1446                 }
1447
1448                 if(reticle_type)
1449                 {
1450                         if(autocvar_cl_reticle_stretch)
1451                         {
1452                                 reticle_size_x = vid_conwidth;
1453                                 reticle_size_y = vid_conheight;
1454                                 reticle_pos_x = 0;
1455                                 reticle_pos_y = 0;
1456                         }
1457                         else
1458                         {
1459                                 reticle_size_x = max(vid_conwidth, vid_conheight);
1460                                 reticle_size_y = max(vid_conwidth, vid_conheight);
1461                                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
1462                                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
1463                         }
1464
1465                         if(zoomscript_caught)
1466                                 f = 1;
1467                         else
1468                                 f = current_zoomfraction;
1469
1470                         if(f)
1471                         {
1472                                 switch(reticle_type)
1473                                 {
1474                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1475                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1476                                 }
1477                         }
1478                 }
1479         }
1480         else
1481         {
1482                 if(reticle_type != 0) { reticle_type = 0; }
1483         }
1484
1485
1486         // improved polyblend
1487         if(autocvar_hud_contents)
1488         {
1489                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1490                 vector liquidcolor;
1491
1492                 switch(pointcontents(view_origin))
1493                 {
1494                         case CONTENT_WATER:
1495                                 liquidalpha = autocvar_hud_contents_water_alpha;
1496                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1497                                 incontent = 1;
1498                                 break;
1499
1500                         case CONTENT_LAVA:
1501                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1502                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1503                                 incontent = 1;
1504                                 break;
1505
1506                         case CONTENT_SLIME:
1507                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1508                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1509                                 incontent = 1;
1510                                 break;
1511
1512                         default:
1513                                 liquidalpha = 0;
1514                                 liquidcolor = '0 0 0';
1515                                 incontent = 0;
1516                                 break;
1517                 }
1518
1519                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1520                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1521                         contentfadetime = autocvar_hud_contents_fadeintime;
1522                         liquidalpha_prev = liquidalpha;
1523                         liquidcolor_prev = liquidcolor;
1524                 }
1525                 else
1526                         contentfadetime = autocvar_hud_contents_fadeouttime;
1527
1528                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1529                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1530
1531                 if(contentavgalpha)
1532                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1533
1534                 if(autocvar_hud_postprocessing)
1535                 {
1536                         if(autocvar_hud_contents_blur && contentavgalpha)
1537                         {
1538                                 content_blurpostprocess_x = 1;
1539                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
1540                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1541                         }
1542                         else
1543                         {
1544                                 content_blurpostprocess_x = 0;
1545                                 content_blurpostprocess_y = 0;
1546                                 content_blurpostprocess_z = 0;
1547                         }
1548                 }
1549         }
1550
1551         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1552         {
1553                 splash_size_x = max(vid_conwidth, vid_conheight);
1554                 splash_size_y = max(vid_conwidth, vid_conheight);
1555                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
1556                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
1557
1558                 float myhealth_flash_temp;
1559                 myhealth = getstati(STAT_HEALTH);
1560
1561                 // fade out
1562                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1563                 // add new damage
1564                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1565
1566                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1567                 pain_threshold = autocvar_hud_damage_pain_threshold;
1568                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1569                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1570
1571                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1572                 {
1573                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1574                 }
1575
1576                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1577
1578                 if(myhealth_prev < 1)
1579                 {
1580                         if(myhealth >= 1)
1581                         {
1582                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1583                                 myhealth_flash_temp = 0;
1584                         }
1585                         else
1586                         {
1587                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1588                         }
1589                 }
1590
1591                 if(spectatee_status == -1 || intermission)
1592                 {
1593                         myhealth_flash = 0; // observing, or match ended
1594                         myhealth_flash_temp = 0;
1595                 }
1596
1597                 myhealth_prev = myhealth;
1598
1599                 // IDEA: change damage color/picture based on player model for robot/alien species?
1600                 // pro: matches model better
1601                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1602                 // maybe different reddish pics?
1603                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1604                 {
1605                         if(autocvar_cl_gentle_damage == 2)
1606                         {
1607                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1608                                 {
1609                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1610                                 }
1611                         }
1612                         else
1613                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1614
1615                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1616                 }
1617                 else
1618                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1619
1620                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1621                 {
1622                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1623                         {
1624                                 damage_blurpostprocess_x = 1;
1625                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1626                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1627                         }
1628                         else
1629                         {
1630                                 damage_blurpostprocess_x = 0;
1631                                 damage_blurpostprocess_y = 0;
1632                                 damage_blurpostprocess_z = 0;
1633                         }
1634                 }
1635         }
1636
1637         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1638         float e2 = (autocvar_hud_powerup != 0);
1639         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1640         {
1641                 // enable or disable rendering types if they are used or not
1642                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1643                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1644
1645                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1646                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1647                 {
1648                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1649                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1650                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1651                         {
1652                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1653                                 old_blurradius = blurradius;
1654                                 old_bluralpha = bluralpha;
1655                         }
1656                 }
1657                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1658                 {
1659                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1660                         old_blurradius = 0;
1661                         old_bluralpha = 0;
1662                 }
1663
1664                 // edge detection postprocess handling done second (used by hud_powerup)
1665                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1666                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1667                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1668
1669                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1670
1671                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1672                 {
1673                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1674                         {
1675                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1676                                 old_sharpen_intensity = sharpen_intensity;
1677                         }
1678                 }
1679                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1680                 {
1681                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1682                         old_sharpen_intensity = 0;
1683                 }
1684
1685                 if(cvar("r_glsl_postprocess") == 0)
1686                         cvar_set("r_glsl_postprocess", "2");
1687         }
1688         else if(cvar("r_glsl_postprocess") == 2)
1689                 cvar_set("r_glsl_postprocess", "0");
1690
1691         if(menu_visible)
1692                 menu_show();
1693
1694         /*if(gametype == MAPINFO_TYPE_CTF)
1695           {
1696           ctf_view();
1697           } else */
1698
1699         // draw 2D entities
1700         e = self;
1701         for(self = world; (self = nextent(self)); )
1702                 if(self.draw2d)
1703                         self.draw2d();
1704         self = e;
1705         Draw_ShowNames_All();
1706
1707         scoreboard_active = HUD_WouldDrawScoreboard();
1708
1709         UpdateDamage();
1710         UpdateHitsound();
1711         UpdateCrosshair();
1712
1713         if(NextFrameCommand)
1714         {
1715                 localcmd("\n", NextFrameCommand, "\n");
1716                 NextFrameCommand = string_null;
1717         }
1718
1719         // we must do this check AFTER a frame was rendered, or it won't work
1720         if(cs_project_is_b0rked == 0)
1721         {
1722                 string w0, h0;
1723                 w0 = ftos(autocvar_vid_conwidth);
1724                 h0 = ftos(autocvar_vid_conheight);
1725                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1726                 //setproperty(VF_FOV, '90 90 0');
1727                 setproperty(VF_ORIGIN, '0 0 0');
1728                 setproperty(VF_ANGLES, '0 0 0');
1729                 setproperty(VF_PERSPECTIVE, 1);
1730                 makevectors('0 0 0');
1731                 vector v1, v2;
1732                 cvar_set("vid_conwidth", "800");
1733                 cvar_set("vid_conheight", "600");
1734                 v1 = cs_project(v_forward);
1735                 cvar_set("vid_conwidth", "640");
1736                 cvar_set("vid_conheight", "480");
1737                 v2 = cs_project(v_forward);
1738                 if(v1 == v2)
1739                         cs_project_is_b0rked = 1;
1740                 else
1741                         cs_project_is_b0rked = -1;
1742                 cvar_set("vid_conwidth", w0);
1743                 cvar_set("vid_conheight", h0);
1744         }
1745
1746         if(autocvar__hud_configure)
1747                 HUD_Panel_Mouse();
1748
1749     if(hud && !intermission)
1750     {
1751         if(hud == HUD_SPIDERBOT)
1752             CSQC_SPIDER_HUD();
1753         else if(hud == HUD_WAKIZASHI)
1754             CSQC_WAKIZASHI_HUD();
1755         else if(hud == HUD_RAPTOR)
1756             CSQC_RAPTOR_HUD();
1757         else if(hud == HUD_BUMBLEBEE)
1758             CSQC_BUMBLE_HUD();
1759         else if(hud == HUD_BUMBLEBEE_GUN)
1760             CSQC_BUMBLE_GUN_HUD();
1761     }
1762
1763         cl_notice_run();
1764
1765         // let's reset the view back to normal for the end
1766         setproperty(VF_MIN, '0 0 0');
1767         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1768 }
1769
1770
1771 void CSQC_common_hud(void)
1772 {
1773         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1774                 Accuracy_LoadLevels();
1775
1776         HUD_Main(); // always run these functions for alpha checks
1777         HUD_DrawScoreboard();
1778
1779         if (scoreboard_active) // scoreboard/accuracy
1780                 HUD_Reset();
1781         else if (intermission == 2) // map voting screen
1782         {
1783                 MapVote_Draw();
1784                 HUD_Reset();
1785         }
1786 }
1787
1788
1789 // following vectors must be global to allow seamless switching between camera modes
1790 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1791 void CSQC_Demo_Camera()
1792 {
1793         float speed, attenuation, dimensions;
1794         vector tmp, delta;
1795
1796         if( autocvar_camera_reset || !camera_mode )
1797         {
1798                 camera_offset = '0 0 0';
1799                 current_angles = '0 0 0';
1800                 camera_direction = '0 0 0';
1801                 camera_offset_z += 30;
1802                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1803                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1804                 current_origin = view_origin;
1805                 current_camera_offset  = camera_offset;
1806                 cvar_set("camera_reset", "0");
1807                 camera_mode = CAMERA_CHASE;
1808         }
1809
1810         // Camera angles
1811         if( camera_roll )
1812                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1813
1814         if(autocvar_camera_look_player)
1815         {
1816                 vector dir;
1817                 float n;
1818
1819                 dir = normalize(view_origin - current_position);
1820                 n = mouse_angles_z;
1821                 mouse_angles = vectoangles(dir);
1822                 mouse_angles_x = mouse_angles_x * -1;
1823                 mouse_angles_z = n;
1824         }
1825         else
1826         {
1827                 tmp = getmousepos() * 0.1;
1828                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1829                 {
1830                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1831                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1832                 }
1833         }
1834
1835         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1836         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1837         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1838         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1839
1840         // Fix difference when angles don't have the same sign
1841         delta = '0 0 0';
1842         if(mouse_angles_y < -60 && current_angles_y > 60)
1843                 delta = '0 360 0';
1844         if(mouse_angles_y > 60 && current_angles_y < -60)
1845                 delta = '0 -360 0';
1846
1847         if(autocvar_camera_look_player)
1848                 attenuation = autocvar_camera_look_attenuation;
1849         else
1850                 attenuation = autocvar_camera_speed_attenuation;
1851
1852         attenuation = 1 / max(1, attenuation);
1853         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1854
1855         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1856         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1857         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1858         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1859
1860         // Camera position
1861         tmp = '0 0 0';
1862         dimensions = 0;
1863
1864         if( camera_direction_x )
1865         {
1866                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1867                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1868                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1869                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1870                 ++dimensions;
1871         }
1872
1873         if( camera_direction_y )
1874         {
1875                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1876                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1877                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1878                 ++dimensions;
1879         }
1880
1881         if( camera_direction_z )
1882         {
1883                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1884                 ++dimensions;
1885         }
1886
1887         if(autocvar_camera_free)
1888                 speed = autocvar_camera_speed_free;
1889         else
1890                 speed = autocvar_camera_speed_chase;
1891
1892         if(dimensions)
1893         {
1894                 speed = speed * sqrt(1 / dimensions);
1895                 camera_offset += tmp * speed;
1896         }
1897
1898         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1899
1900         // Camera modes
1901         if( autocvar_camera_free )
1902         {
1903                 if ( camera_mode == CAMERA_CHASE )
1904                 {
1905                         current_camera_offset = current_origin + current_camera_offset;
1906                         camera_offset = current_origin + camera_offset;
1907                 }
1908
1909                 camera_mode = CAMERA_FREE;
1910                 current_position = current_camera_offset;
1911         }
1912         else
1913         {
1914                 if ( camera_mode == CAMERA_FREE )
1915                 {
1916                         current_origin = view_origin;
1917                         camera_offset = camera_offset - current_origin;
1918                         current_camera_offset = current_camera_offset - current_origin;
1919                 }
1920
1921                 camera_mode = CAMERA_CHASE;
1922
1923                 if(autocvar_camera_chase_smoothly)
1924                         current_origin += (view_origin - current_origin) * attenuation;
1925                 else
1926                         current_origin = view_origin;
1927
1928                 current_position = current_origin + current_camera_offset;
1929         }
1930
1931         setproperty(VF_ANGLES, current_angles);
1932         setproperty(VF_ORIGIN, current_position);
1933 }