qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float chase_current_distance;
 370 vector chase_target_origin;
 371
 372 void CSQC_UpdateView(float w, float h)
 373 {
 374         entity e;
 375         float fov;
 376         float f, i, j;
 377         vector v, vo;
 378         vector vf_size, vf_min;
 379         float a;
 380
 381         vf_size = R_SetView3fv(VF_SIZE);
 382         vf_min = R_SetView3fv(VF_MIN);
 383         vid_width = vf_size_x;
 384         vid_height = vf_size_y;
 385
 386         vector reticle_pos, reticle_size;
 387         vector splash_pos, splash_size;
 388
 389         WaypointSprite_Load();
 390
 391         if(spectatee_status)
 392                 myteam = GetPlayerColor(spectatee_status - 1);
 393         else
 394                 myteam = GetPlayerColor(player_localentnum - 1);
 395
 396         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 397         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 398
 399         warpzone_fixview_origin = pmove_org + vo;
 400         warpzone_fixview_cl_viewangles = input_angles;
 401         warpzone_fixview_angles = view_angles;
 402         WarpZone_FixView();
 403         pmove_org = warpzone_fixview_origin - vo;
 404         input_angles = warpzone_fixview_cl_viewangles;
 405         view_angles = warpzone_fixview_angles;
 406
 407         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 408         {
 409                 pmove_org = freeze_pmove_org;
 410                 input_angles = view_angles = freeze_input_angles;
 411                 R_SetView(VF_ORIGIN, pmove_org + vo);
 412                 R_SetView(VF_ANGLES, view_angles);
 413                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 414         }
 415         freeze_pmove_org = pmove_org;
 416         freeze_input_angles = input_angles;
 417
 418         // event chase cam
 419         if(spectatee_status >= 0 && (autocvar_cl_chase_death || autocvar_cl_chase_intermission))
 420         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually
 421         {
 422                 if((autocvar_cl_chase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || (autocvar_cl_chase_intermission && intermission))
 423                 {
 424                         // We must enable chase_active to get a third person view (weapon view model hidden and own player model showing).
 425                         // Ideally, there should be another way to enable third person cameras, such as an R_SetView() function.
 426                         if(!autocvar_chase_active)
 427                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, not by the user (which would be 1)
 428
 429                         // make the camera smooth back
 430                         if(autocvar_cl_chase_speed && chase_current_distance < autocvar_cl_chase_distance)
 431                                 chase_current_distance += autocvar_cl_chase_speed * (autocvar_cl_chase_distance - chase_current_distance) * frametime; // slow down the further we get
 432                         else if(chase_current_distance != autocvar_cl_chase_distance)
 433                                 chase_current_distance = autocvar_cl_chase_distance;
 434
 435                         if not(intermission > 1) // don't update view origin during the map voting screen
 436                         {
 437                                 makevectors(view_angles);
 438                                 // pass 1, used to check where the camera would go and obtain the trace_fraction
 439                                 chase_target_origin = pmove_org - view_forward * chase_current_distance;
 440
 441                                 traceline(pmove_org, chase_target_origin, MOVE_NORMAL, self);
 442                                 // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera going through walls
 443                                 // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 444                                 chase_target_origin = pmove_org - view_forward * chase_current_distance * (trace_fraction - 0.1);
 445                         }
 446
 447                         R_SetView(VF_ORIGIN, chase_target_origin);
 448                 }
 449                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 450                 {
 451                         cvar_set("chase_active", "0");
 452                         chase_current_distance = 0; // start from 0 next time
 453                 }
 454         }
 455
 456         // Render the Scene
 457         if(!intermission || !view_set || (intermission && autocvar_cl_chase_intermission))
 458         {
 459                 view_origin = pmove_org + vo;
 460                 view_angles = input_angles;
 461                 makevectors(view_angles);
 462                 view_forward = v_forward;
 463                 view_right = v_right;
 464                 view_up = v_up;
 465                 view_set = 1;
 466         }
 467
 468 #ifdef BLURTEST
 469         if(time > blurtest_time0 && time < blurtest_time1)
 470         {
 471                 float r, t;
 472
 473                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 474                 r = t * blurtest_radius;
 475                 f = 1 / pow(t, blurtest_power) - 1;
 476
 477                 cvar_set("r_glsl_postprocess", "1");
 478                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 479         }
 480         else
 481         {
 482                 cvar_set("r_glsl_postprocess", "0");
 483                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 484         }
 485 #endif
 486
 487         TargetMusic_Advance();
 488         Fog_Force();
 489
 490         drawframetime = max(0.000001, time - drawtime);
 491         drawtime = time;
 492
 493         // watch for gametype changes here...
 494         // in ParseStuffCMD the cmd isn't executed yet :/
 495         // might even be better to add the gametype to TE_CSQC_INIT...?
 496         if(!postinit)
 497                 PostInit();
 498
 499         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 500                 if(calledhooks & HOOK_START)
 501                 {
 502                         localcmd("\ncl_hook_gameend\n");
 503                         calledhooks |= HOOK_END;
 504                 }
 505
 506         CheckForGamestartChange();
 507         serverAnnouncer();
 508         maptimeAnnouncer();
 509         carrierAnnouncer();
 510
 511         fov = autocvar_fov;
 512         if(button_zoom || fov <= 59.5)
 513         {
 514                 if(!zoomscript_caught)
 515                 {
 516                         localcmd("+button4\n");
 517                         zoomscript_caught = 1;
 518                         ignore_plus_zoom += 1;
 519                 }
 520         }
 521         else
 522         {
 523                 if(zoomscript_caught)
 524                 {
 525                         localcmd("-button4\n");
 526                         zoomscript_caught = 0;
 527                         ignore_minus_zoom += 1;
 528                 }
 529         }
 530
 531         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 532         activeweapon = getstati(STAT_SWITCHWEAPON);
 533         f = (serverflags & SERVERFLAG_TEAMPLAY);
 534         if(f != teamplay)
 535         {
 536                 teamplay = f;
 537                 HUD_InitScores();
 538         }
 539
 540         if(last_weapon != activeweapon) {
 541                 weapontime = time;
 542                 last_weapon = activeweapon;
 543
 544                 e = get_weaponinfo(activeweapon);
 545                 if(e.netname != "")
 546                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 547                 else
 548                         localcmd("\ncl_hook_activeweapon none\n");
 549         }
 550
 551         // ALWAYS Clear Current Scene First
 552         R_ClearScene();
 553
 554         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 555         R_SetView(VF_SIZE, vf_size);
 556         R_SetView(VF_MIN, vf_min);
 557
 558         // Assign Standard Viewflags
 559         // Draw the World (and sky)
 560         R_SetView(VF_DRAWWORLD, 1);
 561
 562         // Set the console size vars
 563         vid_conwidth = autocvar_vid_conwidth;
 564         vid_conheight = autocvar_vid_conheight;
 565         vid_pixelheight = autocvar_vid_pixelheight;
 566
 567         R_SetView(VF_FOV, GetCurrentFov(fov));
 568
 569         // Camera for demo playback
 570         if(camera_active)
 571         {
 572                 if(autocvar_camera_enable)
 573                         CSQC_Demo_Camera();
 574                 else
 575                 {
 576                         cvar_set("chase_active", ftos(chase_active_backup));
 577                         cvar_set("cl_demo_mousegrab", "0");
 578                         camera_active = FALSE;
 579                 }
 580         }
 581 #ifdef CAMERATEST
 582         else if(autocvar_camera_enable)
 583 #else
 584         else if(autocvar_camera_enable && isdemo())
 585 #endif
 586         {
 587                 // Enable required Darkplaces cvars
 588                 chase_active_backup = autocvar_chase_active;
 589                 cvar_set("chase_active", "2");
 590                 cvar_set("cl_demo_mousegrab", "1");
 591                 camera_active = TRUE;
 592                 camera_mode = FALSE;
 593         }
 594
 595         // Draw the Crosshair
 596         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 597
 598         // Draw the Engine Status Bar (the default Quake HUD)
 599         R_SetView(VF_DRAWENGINEHUD, 0);
 600
 601         // fetch this one only once per frame
 602         hud_showbinds = autocvar_hud_showbinds;
 603         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 604
 605         // Update the mouse position
 606         /*
 607            mousepos_x = vid_conwidth;
 608            mousepos_y = vid_conheight;
 609            mousepos = mousepos*0.5 + getmousepos();
 610          */
 611
 612         e = self;
 613         for(self = world; (self = nextent(self)); )
 614                 if(self.draw)
 615                         self.draw();
 616         self = e;
 617
 618         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 619         R_RenderScene();
 620
 621         // now switch to 2D drawing mode by calling a 2D drawing function
 622         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 623         // next R_RenderScene call
 624         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 625
 626         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 627         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 628         {
 629                 // apply night vision effect
 630                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 631
 632                 if(!nightvision_noise)
 633                 {
 634                         nightvision_noise = spawn();
 635                         nightvision_noise.classname = "nightvision_noise";
 636                 }
 637                 if(!nightvision_noise2)
 638                 {
 639                         nightvision_noise2 = spawn();
 640                         nightvision_noise2.classname = "nightvision_noise2";
 641                 }
 642
 643                 // color tint in yellow
 644                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 645
 646                 // draw BG
 647                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 648                 rgb = '1 1 1';
 649                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 650                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 651                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 652                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 653                 tc_11 = tc_01 + tc_10 - tc_00;
 654                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 655                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 656                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 657                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 658                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 659                 R_EndPolygon();
 660
 661                 // draw FG
 662                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 663                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 664                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 665                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 666                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 667                 tc_11 = tc_01 + tc_10 - tc_00;
 668                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 669                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 670                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 671                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 672                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 673                 R_EndPolygon();
 674         }
 675
 676         // Draw the aiming reticle for weapons that use it
 677         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 678         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 679         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 680         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 681                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 682         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 683                 reticle_type = 2; // nex zoom
 684         else if(button_zoom || zoomscript_caught)
 685                 reticle_type = 1; // normal zoom
 686         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 687                 reticle_type = 2; // nex zoom
 688
 689         if (reticle_type)
 690         {
 691                 if(autocvar_cl_reticle_stretch)
 692                 {
 693                         reticle_size_x = vid_conwidth;
 694                         reticle_size_y = vid_conheight;
 695                         reticle_pos_x = 0;
 696                         reticle_pos_y = 0;
 697                 }
 698                 else
 699                 {
 700                         reticle_size_x = max(vid_conwidth, vid_conheight);
 701                         reticle_size_y = max(vid_conwidth, vid_conheight);
 702                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 703                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 704                 }
 705
 706                 f = current_zoomfraction;
 707                 if(zoomscript_caught)
 708                         f = 1;
 709                 if(autocvar_cl_reticle_item_normal)
 710                 {
 711                         if(reticle_type == 1 && f)
 712                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 713                 }
 714                 if(autocvar_cl_reticle_item_nex)
 715                 {
 716                         if(reticle_type == 2 && f)
 717                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 718                 }
 719         }
 720
 721
 722         // improved polyblend
 723         vector rgb;
 724         if(autocvar_hud_contents)
 725         {
 726                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 727                 vector liquidcolor;
 728
 729                 switch(pointcontents(view_origin))
 730                 {
 731                         case CONTENT_WATER:
 732                                 liquidalpha = autocvar_hud_contents_water_alpha;
 733                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 734                                 incontent = 1;
 735                                 break;
 736
 737                         case CONTENT_LAVA:
 738                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 739                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 740                                 incontent = 1;
 741                                 break;
 742
 743                         case CONTENT_SLIME:
 744                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 745                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 746                                 incontent = 1;
 747                                 break;
 748
 749                         default:
 750                                 liquidalpha = 0;
 751                                 liquidcolor = '0 0 0';
 752                                 incontent = 0;
 753                                 break;
 754                 }
 755
 756                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 757                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 758                         contentfadetime = autocvar_hud_contents_fadeintime;
 759                         liquidalpha_prev = liquidalpha;
 760                         liquidcolor_prev = liquidcolor;
 761                 }
 762                 else
 763                         contentfadetime = autocvar_hud_contents_fadeouttime;
 764
 765                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 766                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 767
 768                 if(contentavgalpha)
 769                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 770         }
 771
 772         if(autocvar_hud_damage)
 773         {
 774                 splash_size_x = max(vid_conwidth, vid_conheight);
 775                 splash_size_y = max(vid_conwidth, vid_conheight);
 776                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 777                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 778
 779                 float myhealth_flash_temp;
 780                 myhealth = getstati(STAT_HEALTH);
 781
 782                 // fade out
 783                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 784                 // add new damage
 785                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 786
 787                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 788                 pain_threshold = autocvar_hud_damage_pain_threshold;
 789                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 790                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 791
 792                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 793                 {
 794                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 795                 }
 796
 797                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 798
 799                 if(myhealth_prev < 1)
 800                 {
 801                         if(myhealth >= 1)
 802                         {
 803                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 804                                 myhealth_flash_temp = 0;
 805                         }
 806                         else
 807                         {
 808                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 809                         }
 810                 }
 811
 812                 if(spectatee_status == -1 || intermission)
 813                 {
 814                         myhealth_flash = 0; // observing, or match ended
 815                         myhealth_flash_temp = 0;
 816                 }
 817
 818                 myhealth_prev = myhealth;
 819
 820                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 821                 {
 822                         if(autocvar_cl_gentle_damage == 2)
 823                         {
 824                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 825                                 {
 826                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 827                                 }
 828                         }
 829                         else
 830                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 831
 832                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 833                 }
 834                 else
 835                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 836         }
 837
 838         // Draw the mouse cursor
 839         // NOTE: drawpic must happen after R_RenderScene for some reason
 840         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 841         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 842         //self = edict_num(player_localnum);
 843         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 844         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 845         // as long as the ctf part isn't in, this is useless
 846         if(menu_visible)
 847                 menu_show();
 848
 849         /*if(gametype == GAME_CTF)
 850           {
 851           ctf_view();
 852           } else */
 853
 854         // draw 2D entities
 855         e = self;
 856         for(self = world; (self = nextent(self)); )
 857                 if(self.draw2d)
 858                         self.draw2d();
 859         self = e;
 860
 861         scoreboard_active = HUD_WouldDrawScoreboard();
 862
 863         hit_time = getstatf(STAT_HIT_TIME);
 864         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 865         {
 866                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 867                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 868         }
 869         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 870         if(typehit_time > nextsound_typehit_time)
 871         {
 872                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 873                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 874         }
 875
 876         float hud;
 877         hud = getstati(STAT_HUD);
 878         if(hud == HUD_SPIDERBOT)
 879                 CSQC_SPIDER_HUD();
 880         else if(hud == HUD_WAKIZASHI)
 881         CSQC_WAKIZASHI_HUD();
 882     else if(hud == HUD_RAPTOR)
 883         CSQC_RAPTOR_HUD();
 884         else
 885         {
 886                 if(gametype == GAME_FREEZETAG)
 887                 {
 888                         if(getstati(STAT_FROZEN))
 889                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 890                         if(getstatf(STAT_REVIVE_PROGRESS))
 891                         {
 892                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 893                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 894                         }
 895                 }
 896
 897                 if(autocvar_r_letterbox == 0)
 898                         if(autocvar_viewsize < 120)
 899                                 CSQC_common_hud();
 900
 901                 // crosshair goes VERY LAST
 902                 if(!scoreboard_active && !camera_active && intermission != 2) {
 903                         string wcross_style;
 904                         float wcross_alpha, wcross_resolution;
 905                         wcross_style = autocvar_crosshair;
 906                         if (wcross_style == "0")
 907                                 return;
 908                         wcross_resolution = autocvar_crosshair_size;
 909                         if (wcross_resolution == 0)
 910                                 return;
 911                         wcross_alpha = autocvar_crosshair_alpha;
 912                         if (wcross_alpha == 0)
 913                                 return;
 914
 915                         // TrueAim check
 916                         float shottype;
 917
 918                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 919                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 920                         wcross_origin_z = 0;
 921                         if(autocvar_crosshair_hittest)
 922                         {
 923                                 vector wcross_oldorigin;
 924                                 wcross_oldorigin = wcross_origin;
 925                                 shottype = TrueAimCheck();
 926                                 if(shottype == SHOTTYPE_HITWORLD)
 927                                 {
 928                                         v = wcross_origin - wcross_oldorigin;
 929                                         v_x /= vid_conwidth;
 930                                         v_y /= vid_conheight;
 931                                         if(vlen(v) > 0.01)
 932                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 933                                 }
 934                                 if(!autocvar_crosshair_hittest_showimpact)
 935                                         wcross_origin = wcross_oldorigin;
 936                         }
 937                         else
 938                                 shottype = SHOTTYPE_HITWORLD;
 939
 940                         vector wcross_color, wcross_size;
 941                         string wcross_wep, wcross_name;
 942                         float wcross_scale, wcross_blur;
 943
 944                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 945                                 e = get_weaponinfo(activeweapon);
 946                                 if (e && e.netname != "")
 947                                 {
 948                                         wcross_wep = e.netname;
 949                                         if(autocvar_crosshair_per_weapon)
 950                                         {
 951                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 952                                                 if (wcross_resolution == 0)
 953                                                         return;
 954                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 955                                                 if (wcross_alpha == 0)
 956                                                         return;
 957
 958                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 959                                                 if(wcross_style == "" || wcross_style == "0")
 960                                                         wcross_style = wcross_wep;
 961                                         }
 962                                 }
 963                         }
 964                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 965                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 966                         else if(autocvar_crosshair_color_by_health)
 967                         {
 968                                 local float x = getstati(STAT_HEALTH);
 969
 970                                 //x = red
 971                                 //y = green
 972                                 //z = blue
 973
 974                                 wcross_color_z = 0;
 975
 976                                 if(x > 200)
 977                                 {
 978                                         wcross_color_x = 0;
 979                                         wcross_color_y = 1;
 980                                 }
 981                                 else if(x > 150)
 982                                 {
 983                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 984                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 985                                 }
 986                                 else if(x > 100)
 987                                 {
 988                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 989                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 990                                         wcross_color_z = 1 - (x-100)*0.02;
 991                                 }
 992                                 else if(x > 50)
 993                                 {
 994                                         wcross_color_x = 1;
 995                                         wcross_color_y = 1;
 996                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 997                                 }
 998                                 else if(x > 20)
 999                                 {
1000                                         wcross_color_x = 1;
1001                                         wcross_color_y = (x-20)*90/27/100;
1002                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1003                                 }
1004                                 else
1005                                 {
1006                                         wcross_color_x = 1;
1007                                         wcross_color_y = 0;
1008                                 }
1009                         }
1010                         else
1011                                 wcross_color = stov(autocvar_crosshair_color);
1012
1013                         wcross_name = strcat("gfx/crosshair", wcross_style);
1014
1015                         if(autocvar_crosshair_effect_scalefade)
1016                         {
1017                                 wcross_scale = wcross_resolution;
1018                                 wcross_resolution = 1;
1019                         }
1020                         else
1021                         {
1022                                 wcross_scale = 1;
1023                         }
1024
1025                         if(autocvar_crosshair_pickup)
1026                         {
1027                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1028                                 {
1029                                         pickup_crosshair_size = 1;
1030                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1031                                 }
1032
1033                                 if(pickup_crosshair_size > 0)
1034                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1035                                 else
1036                                         pickup_crosshair_size = 0;
1037
1038                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1039                         }
1040
1041                         vector hitindication_color;
1042                         if(autocvar_crosshair_hitindication)
1043                         {
1044                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1045                                 if(hitindication_crosshair_time < hit_time)
1046                                 {
1047                                         hitindication_crosshair_size = 1;
1048                                         hitindication_crosshair_time = hit_time;
1049                                 }
1050
1051                                 if(hitindication_crosshair_size > 0)
1052                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1053                                 else
1054                                         hitindication_crosshair_size = 0;
1055
1056                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1057                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1058                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1059                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1060                         }
1061
1062                         if(shottype == SHOTTYPE_HITENEMY)
1063                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1064                         if(shottype == SHOTTYPE_HITTEAM)
1065                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1066
1067                         f = autocvar_crosshair_effect_speed;
1068                         if(f < 0)
1069                                 f *= -2 * g_weaponswitchdelay;
1070                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1071                         {
1072                                 wcross_changedonetime = time + f;
1073                         }
1074                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1075                         {
1076                                 wcross_name_changestarttime = time;
1077                                 wcross_name_changedonetime = time + f;
1078                                 if(wcross_name_goal_prev_prev)
1079                                         strunzone(wcross_name_goal_prev_prev);
1080                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1081                                 wcross_name_goal_prev = strzone(wcross_name);
1082                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1083                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1084                                 wcross_resolution_goal_prev = wcross_resolution;
1085                         }
1086
1087                         wcross_scale_goal_prev = wcross_scale;
1088                         wcross_alpha_goal_prev = wcross_alpha;
1089                         wcross_color_goal_prev = wcross_color;
1090
1091                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1092                         {
1093                                 wcross_blur = 1;
1094                                 wcross_alpha *= 0.75;
1095                         }
1096                         else
1097                                 wcross_blur = 0;
1098                         // *_prev is at time-frametime
1099                         // * is at wcross_changedonetime+f
1100                         // what do we have at time?
1101                         if(time < wcross_changedonetime)
1102                         {
1103                                 f = frametime / (wcross_changedonetime - time + frametime);
1104                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1105                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1106                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1107                         }
1108
1109                         wcross_scale_prev = wcross_scale;
1110                         wcross_alpha_prev = wcross_alpha;
1111                         wcross_color_prev = wcross_color;
1112
1113                         wcross_scale *= 1 - autocvar__menu_alpha;
1114                         wcross_alpha *= 1 - autocvar__menu_alpha;
1115                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1116
1117                         // crosshair rings for weapon stats
1118                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1119                         {
1120                                 // declarations and stats
1121                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1122                                 string ring_image, ring_inner_image;
1123                                 vector ring_rgb, ring_inner_rgb;
1124
1125                                 ring_scale = autocvar_crosshair_ring_size;
1126
1127                                 float weapon_clipload, weapon_clipsize;
1128                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1129                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1130
1131                                 float nex_charge, nex_chargepool;
1132                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1133                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1134
1135                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1136                                         nex_charge_movingavg = nex_charge;
1137
1138
1139                                 // handle the values
1140                                 if (activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1141                                 {
1142                                         if (nex_chargepool || use_nex_chargepool) {
1143                                                 use_nex_chargepool = 1;
1144                                                 ring_inner_value = nex_chargepool;
1145                                         } else {
1146                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1147                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1148                                         }
1149
1150                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1151                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1152                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1153
1154                                         // draw the outer ring to show the current charge of the weapon
1155                                         ring_value = nex_charge;
1156                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1157                                         ring_rgb = wcross_color;
1158                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1159                                 }
1160                                 else if (activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1161                                 {
1162                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1163                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1164                                         ring_rgb = wcross_color;
1165                                         ring_image = "gfx/crosshair_ring.tga";
1166                                 }
1167
1168                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1169                                 {
1170                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1171                                         ring_scale = autocvar_crosshair_ring_reload_size;
1172                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1173                                         ring_rgb = wcross_color;
1174
1175                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1176                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1177                                         if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1178                                                 ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1179                                         else
1180                                                 ring_image = "gfx/crosshair_ring.tga";
1181                                 }
1182
1183                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1184                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1185
1186                                 if (ring_value)
1187                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1188                         }
1189
1190 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1191                         do \
1192                         { \
1193                                 if(wcross_blur > 0) \
1194                                 { \
1195                                         for(i = -2; i <= 2; ++i) \
1196                                                 for(j = -2; j <= 2; ++j) \
1197                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1198                                 } \
1199                                 else \
1200                                 { \
1201                                         M(0,0,sz,wcross_name,wcross_alpha); \
1202                                 } \
1203                         } \
1204                         while(0)
1205
1206 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1207                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1208
1209 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1210                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1211
1212                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1213                         {
1214                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1215                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1216                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1217                                 f = 1 - f;
1218                         }
1219                         else
1220                         {
1221                                 f = 1;
1222                         }
1223
1224                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1225                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1226
1227                         if(autocvar_crosshair_dot)
1228             {
1229                 vector wcross_color_old;
1230                 wcross_color_old = wcross_color;
1231                 if(autocvar_crosshair_dot_color != "0")
1232                     wcross_color = stov(autocvar_crosshair_dot_color);
1233                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1234                 wcross_color = wcross_color_old;
1235             }
1236
1237                         wcross_name_alpha_goal_prev = f;
1238                 }
1239                 else
1240                 {
1241                         wcross_scale_prev = 0;
1242                         wcross_alpha_prev = 0;
1243                         wcross_scale_goal_prev = 0;
1244                         wcross_alpha_goal_prev = 0;
1245                         wcross_changedonetime = 0;
1246                         if(wcross_name_goal_prev)
1247                                 strunzone(wcross_name_goal_prev);
1248                         wcross_name_goal_prev = string_null;
1249                         if(wcross_name_goal_prev_prev)
1250                                 strunzone(wcross_name_goal_prev_prev);
1251                         wcross_name_goal_prev_prev = string_null;
1252                         wcross_name_changestarttime = 0;
1253                         wcross_name_changedonetime = 0;
1254                         wcross_name_alpha_goal_prev = 0;
1255                         wcross_name_alpha_goal_prev_prev = 0;
1256                         wcross_resolution_goal_prev = 0;
1257                         wcross_resolution_goal_prev_prev = 0;
1258                 }
1259         }
1260
1261         if(NextFrameCommand)
1262         {
1263                 localcmd("\n", NextFrameCommand, "\n");
1264                 NextFrameCommand = string_null;
1265         }
1266
1267         // we must do this check AFTER a frame was rendered, or it won't work
1268         if(cs_project_is_b0rked == 0)
1269         {
1270                 string w0, h0;
1271                 w0 = ftos(autocvar_vid_conwidth);
1272                 h0 = ftos(autocvar_vid_conheight);
1273                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1274                 //R_SetView(VF_FOV, '90 90 0');
1275                 R_SetView(VF_ORIGIN, '0 0 0');
1276                 R_SetView(VF_ANGLES, '0 0 0');
1277                 R_SetView(VF_PERSPECTIVE, 1);
1278                 makevectors('0 0 0');
1279                 vector v1, v2;
1280                 cvar_set("vid_conwidth", "800");
1281                 cvar_set("vid_conheight", "600");
1282                 v1 = cs_project(v_forward);
1283                 cvar_set("vid_conwidth", "640");
1284                 cvar_set("vid_conheight", "480");
1285                 v2 = cs_project(v_forward);
1286                 if(v1 == v2)
1287                         cs_project_is_b0rked = 1;
1288                 else
1289                         cs_project_is_b0rked = -1;
1290                 cvar_set("vid_conwidth", w0);
1291                 cvar_set("vid_conheight", h0);
1292         }
1293
1294         if(autocvar__hud_configure)
1295                 HUD_Panel_Mouse();
1296
1297         // let's reset the view back to normal for the end
1298         R_SetView(VF_MIN, '0 0 0');
1299         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1300 }
1301
1302 #define spider_h "gfx/vehicles/hud_bg.tga"
1303 #define spider_b "gfx/vehicles/sbot.tga"
1304 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1305 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1306 #define spider_s "gfx/vehicles/shiled.tga"
1307 #define spider_a1 "gfx/hud/sb_rocket.tga"
1308 #define spider_a2 "gfx/sb_bullets.tga"
1309
1310 void CSQC_SPIDER_HUD()
1311 {
1312         float rockets, reload, heat, hp, shield;
1313         vector picsize, hudloc;
1314
1315     // Fetch health & ammo stats
1316     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1317         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1318         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1319         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1320         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1321
1322     // Draw the crosshairs
1323     picsize = drawgetimagesize(SPIDER_CROSS);
1324     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1325     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1326     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1327
1328     hudloc_y =  4;
1329     hudloc_x = 4;
1330
1331     picsize = drawgetimagesize(spider_h) * 0.5;
1332     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1333
1334     picsize = drawgetimagesize(spider_a2) * 0.5;
1335     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1336
1337     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1338     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1339     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1340
1341     picsize = drawgetimagesize(spider_a1) * 0.85;
1342     if(rockets == 9)
1343     {
1344         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1345         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1346     }
1347     else
1348     {
1349         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1350         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1351     }
1352
1353     picsize = drawgetimagesize(spider_b) * 0.5;
1354     hudloc_y = 10.5;
1355     hudloc_x = 10.5;
1356
1357     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1358     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1359     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1360     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1361
1362
1363         /*
1364         // Draw health bar
1365         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1366         p = p + '0 1 0' * vid_conheight - '0 32 0';
1367         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1368         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1369         p_y += 8;
1370         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1371         p_x += 256 * hp;
1372         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1373
1374         // Draw minigun heat indicator
1375         p = '0.5 0 0' * (vid_conwidth - 256);
1376         p = p + '0 1 0' * vid_conheight - '0 34  0';
1377         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1378         p_x += 256 * (1-heat);
1379         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1380
1381
1382         // Draw rocket icons for loaded/empty tubes.
1383         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1384         pp += '0 1 0' * vid_conheight - '0 64 0';
1385         for(i = 0; i < 8; ++i)
1386         {
1387                 p = pp + '1 0 0' * (rkt_size * i);
1388                 if(rockets == 8)
1389                 {
1390                         if(floor(reload * 8) == i)
1391                         {
1392                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1393                         }
1394                         else if(i < reload * 8)
1395                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1396                         else
1397                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1398                 }
1399                 else
1400                 {
1401                         if(i < rockets)
1402                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1403                         else
1404                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1405                 }
1406         }
1407         */
1408
1409         if (scoreboard_showscores)
1410         {
1411                 HUD_DrawScoreboard();
1412                 HUD_DrawCenterPrint();
1413         }
1414
1415 }
1416
1417 #define raptor_h "gfx/vehicles/hud_bg.tga"
1418 #define raptor_b "gfx/vehicles/raptor.tga"
1419 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1420 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1421 #define raptor_s "gfx/vehicles/shiled.tga"
1422
1423 void CSQC_RAPTOR_HUD()
1424 {
1425         float reload, hp, shield, energy;
1426         vector picsize, hudloc;
1427
1428     // Fetch health & ammo stats
1429     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1430         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1431         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1432         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1433
1434     // Draw the crosshairs
1435     picsize = drawgetimagesize(SPIDER_CROSS);
1436     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1437     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1438     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1439
1440     hudloc_y =  4;
1441     hudloc_x = 4;
1442
1443     picsize = drawgetimagesize(raptor_h) * 0.5;
1444     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1445
1446     picsize = drawgetimagesize(spider_a2) * 0.5;
1447     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1448
1449     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1450     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1451     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1452
1453
1454     picsize = drawgetimagesize(spider_a1) * 0.85;
1455     if(reload == 1)
1456     {
1457         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1458         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1459     }
1460     else
1461     {
1462         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1463         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1464     }
1465
1466     picsize = drawgetimagesize(raptor_b) * 0.5;
1467     hudloc_y = 10.5;
1468     hudloc_x = 10.5;
1469
1470     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1471     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1472     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1473     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1474
1475
1476         if (scoreboard_showscores)
1477         {
1478                 HUD_DrawScoreboard();
1479                 HUD_DrawCenterPrint();
1480         }
1481
1482 }
1483
1484 #define waki_h "gfx/vehicles/hud_bg.tga"
1485 #define waki_b "gfx/vehicles/waki.tga"
1486 #define waki_e "gfx/vehicles/waki_e.tga"
1487 #define waki_g "gfx/vehicles/waki_guns.tga"
1488 #define waki_r "gfx/vehicles/waki_rockets.tga"
1489 #define waki_s "gfx/vehicles/shiled.tga"
1490
1491 #define waki_a1 "gfx/hud/sb_rocket.tga"
1492 #define waki_a2 "gfx/sb_cells.tga"
1493
1494 void CSQC_WAKIZASHI_HUD()
1495 {
1496         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1497         float health, shield, energy, rockets;
1498         vector picsize, hudloc;
1499
1500     picsize = drawgetimagesize(SPIDER_CROSS);
1501     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1502     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1503     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1504
1505 /*
1506 const float STAT_VEHICLESTAT_HEALTH  = 60;
1507 const float STAT_VEHICLESTAT_SHIELD  = 61;
1508 const float STAT_VEHICLESTAT_ENERGY  = 62;
1509 const float STAT_VEHICLESTAT_AMMO1   = 63;
1510 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1511 const float STAT_VEHICLESTAT_AMMO2   = 65;
1512 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1513 */
1514     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1515         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1516         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1517         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1518
1519     hudloc_y =  4;
1520     hudloc_x = 4;
1521
1522     picsize = drawgetimagesize(waki_h) * 0.5;
1523     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1524
1525     picsize = drawgetimagesize(waki_a2) * 0.7;
1526     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1527
1528
1529     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1530     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1531
1532     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1533
1534     picsize = drawgetimagesize(waki_a1) * 0.75;
1535     if(rockets == 1)
1536     {
1537         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1538         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1539     }
1540     else
1541     {
1542         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1543         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1544         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1545     }
1546
1547     picsize = drawgetimagesize(waki_b) * 0.5;
1548     hudloc_y = 10.5;
1549     hudloc_x = 10.5;
1550
1551     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1552     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1553     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1554     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1555
1556
1557
1558         /*
1559         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1560         p = p + '0 1 0' * vid_conheight - '0 32 0';
1561
1562         // Draw health bar
1563         p_y += 8;
1564         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1565         p_x += 256 * health;
1566         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1567
1568         // Draw shiled bar
1569         p_x -= 256 * health;
1570         p_y += 4;
1571         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1572
1573         // Draw energy
1574         //p_x -= 256 * health;
1575         p_y -= 8;
1576         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1577
1578         // Draw rockets bar
1579         p_y += 12;
1580         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1581         */
1582
1583
1584
1585
1586         if (scoreboard_showscores)
1587         {
1588                 HUD_DrawScoreboard();
1589                 HUD_DrawCenterPrint();
1590         }
1591
1592 }
1593
1594
1595 void CSQC_common_hud(void)
1596 {
1597         // HUD_SortFrags(); done in HUD_Draw
1598         float hud;
1599         hud = getstati(STAT_HUD);
1600
1601         //hud = 10;
1602         switch(hud)
1603         {
1604                 case HUD_NORMAL:
1605                         // do some accuracy var caching
1606                         float i;
1607                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1608                         {
1609                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1610                                 {
1611                                         if(acc_color_levels)
1612                                                 strunzone(acc_color_levels);
1613                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1614                                         acc_levels = tokenize(acc_color_levels);
1615                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1616                                                 acc_levels = MAX_ACCURACY_LEVELS;
1617
1618                                         for (i = 0; i < acc_levels; ++i)
1619                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1620                                 }
1621                                 // let know that acc_col[] needs to be loaded
1622                                 acc_col_x[0] = -1;
1623                         }
1624
1625                         HUD_Main(); // always run these functions for alpha checks
1626                         HUD_DrawScoreboard();
1627
1628                         if (scoreboard_active) // scoreboard/accuracy
1629                         {
1630                                 HUD_Reset();
1631                                 // HUD_DrawScoreboard takes care of centerprint_start
1632                         }
1633                         else if (intermission == 2) // map voting screen
1634                         {
1635                                 HUD_FinaleOverlay();
1636                                 HUD_Reset();
1637
1638                                 centerprint_start_x = 0;
1639                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1640                         }
1641                         else // hud
1642                         {
1643                                 centerprint_start_x = 0;
1644                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1645                         }
1646
1647                         HUD_DrawCenterPrint();
1648                         break;
1649
1650                 case HUD_SPIDERBOT:
1651                         CSQC_SPIDER_HUD();
1652                         break;
1653
1654                 case HUD_WAKIZASHI:
1655                         CSQC_WAKIZASHI_HUD();
1656                         break;
1657         }
1658 }
1659
1660
1661 // following vectors must be global to allow seamless switching between camera modes
1662 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1663 void CSQC_Demo_Camera()
1664 {
1665         float speed, attenuation, dimensions;
1666         vector tmp, delta;
1667
1668         if( autocvar_camera_reset || !camera_mode )
1669         {
1670                 camera_offset = '0 0 0';
1671                 current_angles = '0 0 0';
1672                 camera_direction = '0 0 0';
1673                 camera_offset_z += 30;
1674                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1675                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1676                 current_origin = view_origin;
1677                 current_camera_offset  = camera_offset;
1678                 cvar_set("camera_reset", "0");
1679                 camera_mode = CAMERA_CHASE;
1680         }
1681
1682         // Camera angles
1683         if( camera_roll )
1684                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1685
1686         if(autocvar_camera_look_player)
1687         {
1688                 local vector dir;
1689                 local float n;
1690
1691                 dir = normalize(view_origin - current_position);
1692                 n = mouse_angles_z;
1693                 mouse_angles = vectoangles(dir);
1694                 mouse_angles_x = mouse_angles_x * -1;
1695                 mouse_angles_z = n;
1696         }
1697         else
1698         {
1699                 tmp = getmousepos() * 0.1;
1700                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1701                 {
1702                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1703                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1704                 }
1705         }
1706
1707         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1708         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1709         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1710         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1711
1712         // Fix difference when angles don't have the same sign
1713         delta = '0 0 0';
1714         if(mouse_angles_y < -60 && current_angles_y > 60)
1715                 delta = '0 360 0';
1716         if(mouse_angles_y > 60 && current_angles_y < -60)
1717                 delta = '0 -360 0';
1718
1719         if(autocvar_camera_look_player)
1720                 attenuation = autocvar_camera_look_attenuation;
1721         else
1722                 attenuation = autocvar_camera_speed_attenuation;
1723
1724         attenuation = 1 / max(1, attenuation);
1725         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1726
1727         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1728         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1729         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1730         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1731
1732         // Camera position
1733         tmp = '0 0 0';
1734         dimensions = 0;
1735
1736         if( camera_direction_x )
1737         {
1738                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1739                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1740                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1741                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1742                 ++dimensions;
1743         }
1744
1745         if( camera_direction_y )
1746         {
1747                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1748                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1749                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1750                 ++dimensions;
1751         }
1752
1753         if( camera_direction_z )
1754         {
1755                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1756                 ++dimensions;
1757         }
1758
1759         if(autocvar_camera_free)
1760                 speed = autocvar_camera_speed_free;
1761         else
1762                 speed = autocvar_camera_speed_chase;
1763
1764         if(dimensions)
1765         {
1766                 speed = speed * sqrt(1 / dimensions);
1767                 camera_offset += tmp * speed;
1768         }
1769
1770         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1771
1772         // Camera modes
1773         if( autocvar_camera_free )
1774         {
1775                 if ( camera_mode == CAMERA_CHASE )
1776                 {
1777                         current_camera_offset = current_origin + current_camera_offset;
1778                         camera_offset = current_origin + camera_offset;
1779                 }
1780
1781                 camera_mode = CAMERA_FREE;
1782                 current_position = current_camera_offset;
1783         }
1784         else
1785         {
1786                 if ( camera_mode == CAMERA_FREE )
1787                 {
1788                         current_origin = view_origin;
1789                         camera_offset = camera_offset - current_origin;
1790                         current_camera_offset = current_camera_offset - current_origin;
1791                 }
1792
1793                 camera_mode = CAMERA_CHASE;
1794
1795                 if(autocvar_camera_chase_smoothly)
1796                         current_origin += (view_origin - current_origin) * attenuation;
1797                 else
1798                         current_origin = view_origin;
1799
1800                 current_position = current_origin + current_camera_offset;
1801         }
1802
1803         R_SetView(VF_ANGLES, current_angles);
1804         R_SetView(VF_ORIGIN, current_position);
1805 }