qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard ();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 void CSQC_UpdateView(float w, float h)
 353 {
 354         entity e;
 355         float fov;
 356         float f, i, j;
 357         vector v, vo;
 358         vector vf_size, vf_min;
 359
 360         vf_size = R_SetView3fv(VF_SIZE);
 361         vf_min = R_SetView3fv(VF_MIN);
 362         vid_width = vf_size_x;
 363         vid_height = vf_size_y;
 364
 365         vector reticle_pos, reticle_size;
 366
 367         WaypointSprite_Load();
 368
 369         if(spectatee_status)
 370                 myteam = GetPlayerColor(spectatee_status - 1);
 371         else
 372                 myteam = GetPlayerColor(player_localentnum - 1);
 373
 374         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 375         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 376
 377         warpzone_fixview_origin = pmove_org + vo;
 378         warpzone_fixview_cl_viewangles = input_angles;
 379         warpzone_fixview_angles = view_angles;
 380         WarpZone_FixView();
 381         pmove_org = warpzone_fixview_origin - vo;
 382         input_angles = warpzone_fixview_cl_viewangles;
 383         view_angles = warpzone_fixview_angles;
 384
 385         if(cvar("cl_lockview") || autocvar__hud_configure)
 386         {
 387                 pmove_org = freeze_pmove_org;
 388                 input_angles = view_angles = freeze_input_angles;
 389                 R_SetView(VF_ORIGIN, pmove_org + vo);
 390                 R_SetView(VF_ANGLES, view_angles);
 391                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 392         }
 393         freeze_pmove_org = pmove_org;
 394         freeze_input_angles = input_angles;
 395
 396         // Render the Scene
 397         if(!intermission || !view_set)
 398         {
 399                 view_origin = pmove_org + vo;
 400                 view_angles = input_angles;
 401                 makevectors(view_angles);
 402                 view_forward = v_forward;
 403                 view_right = v_right;
 404                 view_up = v_up;
 405                 view_set = 1;
 406         }
 407
 408 #ifdef BLURTEST
 409         if(time > blurtest_time0 && time < blurtest_time1)
 410         {
 411                 float r, t;
 412
 413                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 414                 r = t * blurtest_radius;
 415                 f = 1 / pow(t, blurtest_power) - 1;
 416
 417                 cvar_set("r_glsl_postprocess", "1");
 418                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 419         }
 420         else
 421         {
 422                 cvar_set("r_glsl_postprocess", "0");
 423                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 424         }
 425 #endif
 426
 427         TargetMusic_Advance();
 428         Fog_Force();
 429
 430         drawframetime = max(0.000001, time - drawtime);
 431         drawtime = time;
 432
 433         // watch for gametype changes here...
 434         // in ParseStuffCMD the cmd isn't executed yet :/
 435         // might even be better to add the gametype to TE_CSQC_INIT...?
 436         if(!postinit)
 437                 PostInit();
 438
 439         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 440                 if(calledhooks & HOOK_START)
 441                 {
 442                         localcmd("\ncl_hook_gameend\n");
 443                         calledhooks |= HOOK_END;
 444                 }
 445
 446         CheckForGamestartChange();
 447         serverAnnouncer();
 448         maptimeAnnouncer();
 449         carrierAnnouncer();
 450
 451         fov = cvar("fov");
 452         if(button_zoom || fov <= 59.5)
 453         {
 454                 if(!zoomscript_caught)
 455                 {
 456                         localcmd("+button4\n");
 457                         zoomscript_caught = 1;
 458                         ignore_plus_zoom += 1;
 459                 }
 460         }
 461         else
 462         {
 463                 if(zoomscript_caught)
 464                 {
 465                         localcmd("-button4\n");
 466                         zoomscript_caught = 0;
 467                         ignore_minus_zoom += 1;
 468                 }
 469         }
 470
 471         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
 472         ColorTranslateMode = cvar("cl_stripcolorcodes");
 473         activeweapon = getstati(STAT_SWITCHWEAPON);
 474         f = cvar("teamplay");
 475         if(f != teamplay)
 476         {
 477                 teamplay = f;
 478                 HUD_InitScores();
 479         }
 480
 481         if(last_weapon != activeweapon) {
 482                 weapontime = time;
 483                 last_weapon = activeweapon;
 484
 485                 e = get_weaponinfo(activeweapon);
 486                 if(e.netname != "")
 487                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 488                 else
 489                         localcmd("\ncl_hook_activeweapon none\n");
 490         }
 491
 492         // ALWAYS Clear Current Scene First
 493         R_ClearScene();
 494
 495         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 496         R_SetView(VF_SIZE, vf_size);
 497         R_SetView(VF_MIN, vf_min);
 498
 499         // Assign Standard Viewflags
 500         // Draw the World (and sky)
 501         R_SetView(VF_DRAWWORLD, 1);
 502
 503         // Set the console size vars
 504         vid_conwidth = cvar("vid_conwidth");
 505         vid_conheight = cvar("vid_conheight");
 506         vid_pixelheight = cvar("vid_pixelheight");
 507
 508         R_SetView(VF_FOV, GetCurrentFov(fov));
 509
 510         // Camera for demo playback
 511         if(camera_active)
 512         {
 513                 if(cvar("camera_enable"))
 514                         CSQC_Demo_Camera();
 515                 else
 516                 {
 517                         cvar_set("chase_active", ftos(chase_active_backup));
 518                         cvar_set("cl_demo_mousegrab", "0");
 519                         camera_active = FALSE;
 520                 }
 521         }
 522 #ifdef CAMERATEST
 523         else if(cvar("camera_enable"))
 524 #else
 525         else if(cvar("camera_enable") && isdemo())
 526 #endif
 527         {
 528                 // Enable required Darkplaces cvars
 529                 chase_active_backup = cvar("chase_active");
 530                 cvar_set("chase_active", "2");
 531                 cvar_set("cl_demo_mousegrab", "1");
 532                 camera_active = TRUE;
 533                 camera_mode = FALSE;
 534         }
 535
 536         // Draw the Crosshair
 537         float scoreboard_active;
 538         scoreboard_active = HUD_WouldDrawScoreboard();
 539         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 540
 541         // Draw the Engine Status Bar (the default Quake HUD)
 542         R_SetView(VF_DRAWENGINEHUD, 0);
 543
 544         // fetch this one only once per frame
 545         hud_showbinds = cvar("hud_showbinds");
 546         hud_showbinds_limit = cvar("hud_showbinds_limit");
 547
 548         // Update the mouse position
 549         /*
 550            mousepos_x = vid_conwidth;
 551            mousepos_y = vid_conheight;
 552            mousepos = mousepos*0.5 + getmousepos();
 553          */
 554
 555         e = self;
 556         for(self = world; (self = nextent(self)); )
 557                 if(self.draw)
 558                         self.draw();
 559         self = e;
 560
 561         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 562         R_RenderScene();
 563
 564         // now switch to 2D drawing mode by calling a 2D drawing function
 565         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 566         // next R_RenderScene call
 567         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 568
 569         if(cvar("r_fakelight") >= 2)
 570         {
 571                 // apply night vision effect
 572                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 573                 float a;
 574
 575                 if(!nightvision_noise)
 576                 {
 577                         nightvision_noise = spawn();
 578                         nightvision_noise.classname = "nightvision_noise";
 579                 }
 580                 if(!nightvision_noise2)
 581                 {
 582                         nightvision_noise2 = spawn();
 583                         nightvision_noise2.classname = "nightvision_noise2";
 584                 }
 585
 586                 // color tint in yellow
 587                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 588
 589                 // draw BG
 590                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 591                 rgb = '1 1 1';
 592                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 593                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 594                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 595                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 596                 tc_11 = tc_01 + tc_10 - tc_00;
 597                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 598                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 599                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 600                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 601                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 602                 R_EndPolygon();
 603
 604                 // draw FG
 605                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 606                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 607                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 608                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 609                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 610                 tc_11 = tc_01 + tc_10 - tc_00;
 611                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 612                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 613                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 614                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 615                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 616                 R_EndPolygon();
 617         }
 618
 619         // Draw the aiming reticle for weapons that use it
 620         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 621         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 622         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 623         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 624                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 625         else if(button_zoom || zoomscript_caught)
 626                 reticle_type = 1; // normal zoom
 627         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 628                 reticle_type = 2; // nex zoom
 629
 630         if(cvar("cl_reticle_stretch"))
 631         {
 632                 reticle_size_x = vid_conwidth;
 633                 reticle_size_y = vid_conheight;
 634                 reticle_pos_x = 0;
 635                 reticle_pos_y = 0;
 636         }
 637         else
 638         {
 639                 reticle_size_x = max(vid_conwidth, vid_conheight);
 640                 reticle_size_y = max(vid_conwidth, vid_conheight);
 641                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 642                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 643         }
 644
 645         f = current_zoomfraction;
 646         if(zoomscript_caught)
 647                 f = 1;
 648         if(cvar("cl_reticle_item_normal"))
 649         {
 650                 precache_pic("gfx/reticle_normal");
 651                 if(reticle_type == 1 && f)
 652                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 653         }
 654         if(cvar("cl_reticle_item_nex"))
 655         {
 656                 precache_pic("gfx/reticle_nex");
 657                 if(reticle_type == 2 && f)
 658                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 659         }
 660
 661         // Draw the mouse cursor
 662         // NOTE: drawpic must happen after R_RenderScene for some reason
 663         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 664         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 665         //self = edict_num(player_localnum);
 666         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 667         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 668         // as long as the ctf part isn't in, this is useless
 669         if(menu_visible)
 670                 menu_show();
 671
 672         /*if(gametype == GAME_CTF)
 673           {
 674           ctf_view();
 675           } else */
 676
 677         // draw 2D entities
 678         e = self;
 679         for(self = world; (self = nextent(self)); )
 680                 if(self.draw2d)
 681                         self.draw2d();
 682         self = e;
 683
 684         float hud;
 685         hud = getstati(STAT_HUD);
 686         if(hud == HUD_SPIDERBOT)
 687         {
 688                 CSQC_SPIDER_HUD();
 689         }
 690         else if(hud == HUD_WAKIZASHI)
 691         CSQC_WAKIZASHI_HUD();
 692     else if(hud == HUD_RAPTOR)
 693         CSQC_RAPTOR_HUD();
 694         else
 695         {
 696                 if(cvar("r_letterbox") == 0)
 697                         if(cvar("viewsize") < 120)
 698                                 CSQC_common_hud();
 699
 700                 // crosshair goes VERY LAST
 701                 if(!scoreboard_active && !camera_active && intermission != 2) {
 702                         // TrueAim check
 703                         float shottype;
 704                         float bullets, ring_scale;
 705                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 706                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 707                         wcross_origin_z = 0;
 708                         if(cvar("crosshair_hittest"))
 709                         {
 710                                 vector wcross_oldorigin;
 711                                 wcross_oldorigin = wcross_origin;
 712                                 shottype = TrueAimCheck();
 713                                 if(shottype == SHOTTYPE_HITWORLD)
 714                                 {
 715                                         v = wcross_origin - wcross_oldorigin;
 716                                         v_x /= vid_conwidth;
 717                                         v_y /= vid_conheight;
 718                                         if(vlen(v) > 0.01)
 719                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 720                                 }
 721                                 if(!cvar("crosshair_hittest_showimpact"))
 722                                         wcross_origin = wcross_oldorigin;
 723                         }
 724                         else
 725                                 shottype = SHOTTYPE_HITWORLD;
 726
 727                         string wcross_style;
 728                         wcross_style = cvar_string("crosshair");
 729
 730                         if (wcross_style != "0") {
 731                                 vector wcross_color, wcross_size;
 732                                 string wcross_wep, wcross_name;
 733                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 734
 735                                 wcross_color_x = cvar("crosshair_color_red");
 736                                 wcross_color_y = cvar("crosshair_color_green");
 737                                 wcross_color_z = cvar("crosshair_color_blue");
 738                                 wcross_alpha = cvar("crosshair_color_alpha");
 739                                 wcross_resolution = cvar("crosshair_size");
 740                                 if (cvar("crosshair_per_weapon")) {
 741                                         e = get_weaponinfo(activeweapon);
 742                                         if (e && e.netname != "")
 743                                         {
 744                                                 wcross_wep = e.netname;
 745                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 746                                                 if(wcross_style == "")
 747                                                         wcross_style = e.netname;
 748
 749                                                 if(!cvar("crosshair_color_override"))
 750                                                 {
 751                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 752                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 753                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 754                                                 }
 755
 756                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 757                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 758                                         }
 759                                 }
 760
 761                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 762
 763                                 if(cvar("crosshair_effect_scalefade"))
 764                                 {
 765                                         wcross_scale = wcross_resolution;
 766                                         wcross_resolution = 1;
 767                                 }
 768                                 else
 769                                 {
 770                                         wcross_scale = 1;
 771                                 }
 772
 773                                 if(shottype == SHOTTYPE_HITENEMY)
 774                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 775                                 if(shottype == SHOTTYPE_HITTEAM)
 776                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 777
 778                                 f = cvar("crosshair_effect_speed");
 779                                 if(f < 0)
 780                                         f *= -2 * g_weaponswitchdelay;
 781                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 782                                 {
 783                                         wcross_changedonetime = time + f;
 784                                 }
 785                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 786                                 {
 787                                         wcross_name_changestarttime = time;
 788                                         wcross_name_changedonetime = time + f;
 789                                         if(wcross_name_goal_prev_prev)
 790                                                 strunzone(wcross_name_goal_prev_prev);
 791                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 792                                         wcross_name_goal_prev = strzone(wcross_name);
 793                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 794                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 795                                         wcross_resolution_goal_prev = wcross_resolution;
 796                                 }
 797
 798                                 wcross_scale_goal_prev = wcross_scale;
 799                                 wcross_alpha_goal_prev = wcross_alpha;
 800                                 wcross_color_goal_prev = wcross_color;
 801
 802                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 803                                 {
 804                                         wcross_blur = 1;
 805                                         wcross_alpha *= 0.75;
 806                                 }
 807                                 else
 808                                         wcross_blur = 0;
 809                                 // *_prev is at time-frametime
 810                                 // * is at wcross_changedonetime+f
 811                                 // what do we have at time?
 812                                 if(time < wcross_changedonetime)
 813                                 {
 814                                         f = frametime / (wcross_changedonetime - time + frametime);
 815                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 816                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 817                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 818                                 }
 819
 820                                 wcross_scale_prev = wcross_scale;
 821                                 wcross_alpha_prev = wcross_alpha;
 822                                 wcross_color_prev = wcross_color;
 823
 824                                 wcross_scale *= 1 - cvar("_menu_alpha");
 825                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 826
 827                                 // ring around crosshair representing bullets left in camping rifle clip
 828                                 if (activeweapon == WEP_CAMPINGRIFLE)
 829                                 {
 830                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 831                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 4);
 832                                 }
 833                                 else
 834                                         bullets = 0;
 835
 836 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 837                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 838
 839 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 840                                 do \
 841                                 { \
 842                                         if(wcross_blur > 0) \
 843                                         { \
 844                                                 for(i = -2; i <= 2; ++i) \
 845                                                         for(j = -2; j <= 2; ++j) \
 846                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 847                                         } \
 848                                         else \
 849                                         { \
 850                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 851                                         } \
 852                                 } \
 853                                 while(0)
 854
 855 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 856                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 857
 858 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 859                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 860
 861                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 862                                 {
 863                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 864                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 865                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 866                                         f = 1 - f;
 867                                 }
 868                                 else
 869                                 {
 870                                         f = 1;
 871                                 }
 872
 873                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 874                                 if(bullets)
 875                                 {
 876                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 877                                 }
 878                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 879                                 wcross_name_alpha_goal_prev = f;
 880                         }
 881                 }
 882                 else
 883                 {
 884                         wcross_scale_prev = 0;
 885                         wcross_alpha_prev = 0;
 886                         wcross_scale_goal_prev = 0;
 887                         wcross_alpha_goal_prev = 0;
 888                         wcross_changedonetime = 0;
 889                         if(wcross_name_goal_prev)
 890                                 strunzone(wcross_name_goal_prev);
 891                         wcross_name_goal_prev = string_null;
 892                         if(wcross_name_goal_prev_prev)
 893                                 strunzone(wcross_name_goal_prev_prev);
 894                         wcross_name_goal_prev_prev = string_null;
 895                         wcross_name_changestarttime = 0;
 896                         wcross_name_changedonetime = 0;
 897                         wcross_name_alpha_goal_prev = 0;
 898                         wcross_name_alpha_goal_prev_prev = 0;
 899                         wcross_resolution_goal_prev = 0;
 900                         wcross_resolution_goal_prev_prev = 0;
 901                 }
 902         }
 903
 904         if(NextFrameCommand)
 905         {
 906                 localcmd("\n", NextFrameCommand, "\n");
 907                 NextFrameCommand = string_null;
 908         }
 909
 910         // we must do this check AFTER a frame was rendered, or it won't work
 911         if(cs_project_is_b0rked == 0)
 912         {
 913                 string w0, h0;
 914                 w0 = cvar_string("vid_conwidth");
 915                 h0 = cvar_string("vid_conheight");
 916                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 917                 //R_SetView(VF_FOV, '90 90 0');
 918                 R_SetView(VF_ORIGIN, '0 0 0');
 919                 R_SetView(VF_ANGLES, '0 0 0');
 920                 R_SetView(VF_PERSPECTIVE, 1);
 921                 makevectors('0 0 0');
 922                 vector v1, v2;
 923                 cvar_set("vid_conwidth", "800");
 924                 cvar_set("vid_conheight", "600");
 925                 v1 = cs_project(v_forward);
 926                 cvar_set("vid_conwidth", "640");
 927                 cvar_set("vid_conheight", "480");
 928                 v2 = cs_project(v_forward);
 929                 if(v1 == v2)
 930                         cs_project_is_b0rked = 1;
 931                 else
 932                         cs_project_is_b0rked = -1;
 933                 cvar_set("vid_conwidth", w0);
 934                 cvar_set("vid_conheight", h0);
 935         }
 936
 937         if(autocvar__hud_configure)
 938                 HUD_Panel_Mouse();
 939
 940         // let's reset the view back to normal for the end
 941         R_SetView(VF_MIN, '0 0 0');
 942         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
 943
 944         // be safe against triggerbots until everyone has the fixed engine
 945         // this call is meant to overwrite the trace globals by something
 946         // unsuspicious
 947         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 948 }
 949
 950 #define spider_h "gfx/vehicles/hud_bg.tga"
 951 #define spider_b "gfx/vehicles/sbot.tga"
 952 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 953 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 954 #define spider_s "gfx/vehicles/shiled.tga"
 955 #define spider_a1 "gfx/hud/sb_rocket.tga"
 956 #define spider_a2 "gfx/sb_bullets.tga"
 957
 958 void CSQC_SPIDER_HUD()
 959 {
 960         float rockets, reload, heat, hp, shield;
 961         vector picsize, hudloc;
 962
 963     // Fetch health & ammo stats
 964     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 965         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 966         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
 967         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 968         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 969
 970     // Draw the crosshairs
 971     picsize = drawgetimagesize(SPIDER_CROSS);
 972     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 973     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 974     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 975
 976     hudloc_y =  4;
 977     hudloc_x = 4;
 978
 979     picsize = drawgetimagesize(spider_h) * 0.5;
 980     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 981
 982     picsize = drawgetimagesize(spider_a2) * 0.5;
 983     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 984
 985     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
 986     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
 987     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 988
 989     picsize = drawgetimagesize(spider_a1) * 0.85;
 990     if(rockets == 9)
 991     {
 992         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
 993         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 994     }
 995     else
 996     {
 997         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 998         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 999     }
1000
1001     picsize = drawgetimagesize(spider_b) * 0.5;
1002     hudloc_y = 10.5;
1003     hudloc_x = 10.5;
1004
1005     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1006     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1007     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1008     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1009
1010
1011         /*
1012         // Draw health bar
1013         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1014         p = p + '0 1 0' * vid_conheight - '0 32 0';
1015         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1016         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1017         p_y += 8;
1018         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1019         p_x += 256 * hp;
1020         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1021
1022         // Draw minigun heat indicator
1023         p = '0.5 0 0' * (vid_conwidth - 256);
1024         p = p + '0 1 0' * vid_conheight - '0 34  0';
1025         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1026         p_x += 256 * (1-heat);
1027         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1028
1029
1030         // Draw rocket icons for loaded/empty tubes.
1031         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1032         pp += '0 1 0' * vid_conheight - '0 64 0';
1033         for(i = 0; i < 8; ++i)
1034         {
1035                 p = pp + '1 0 0' * (rkt_size * i);
1036                 if(rockets == 8)
1037                 {
1038                         if(floor(reload * 8) == i)
1039                         {
1040                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1041                         }
1042                         else if(i < reload * 8)
1043                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1044                         else
1045                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1046                 }
1047                 else
1048                 {
1049                         if(i < rockets)
1050                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1051                         else
1052                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1053                 }
1054         }
1055         */
1056
1057         if (scoreboard_showscores)
1058         {
1059                 HUD_DrawScoreboard();
1060                 HUD_DrawCenterPrint();
1061         }
1062
1063 }
1064
1065 #define raptor_h "gfx/vehicles/hud_bg.tga"
1066 #define raptor_b "gfx/vehicles/raptor.tga"
1067 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1068 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1069 #define raptor_s "gfx/vehicles/shiled.tga"
1070
1071 void CSQC_RAPTOR_HUD()
1072 {
1073         float rockets, reload, heat, hp, shield, energy;
1074         vector picsize, hudloc;
1075
1076     // Fetch health & ammo stats
1077     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1078         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1079         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1080         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1081
1082     // Draw the crosshairs
1083     picsize = drawgetimagesize(SPIDER_CROSS);
1084     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1085     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1086     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1087
1088     hudloc_y =  4;
1089     hudloc_x = 4;
1090
1091     picsize = drawgetimagesize(raptor_h) * 0.5;
1092     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1093
1094     picsize = drawgetimagesize(spider_a2) * 0.5;
1095     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1096
1097     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1098     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1099     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1100
1101
1102     picsize = drawgetimagesize(spider_a1) * 0.85;
1103     if(reload == 1)
1104     {
1105         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1106         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1107     }
1108     else
1109     {
1110         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1111         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1112     }
1113
1114     picsize = drawgetimagesize(raptor_b) * 0.5;
1115     hudloc_y = 10.5;
1116     hudloc_x = 10.5;
1117
1118     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1119     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1120     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1121     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1122
1123
1124         if (scoreboard_showscores)
1125         {
1126                 HUD_DrawScoreboard();
1127                 HUD_DrawCenterPrint();
1128         }
1129
1130 }
1131
1132 #define waki_h "gfx/vehicles/hud_bg.tga"
1133 #define waki_b "gfx/vehicles/waki.tga"
1134 #define waki_e "gfx/vehicles/waki_e.tga"
1135 #define waki_g "gfx/vehicles/waki_guns.tga"
1136 #define waki_r "gfx/vehicles/waki_rockets.tga"
1137 #define waki_s "gfx/vehicles/shiled.tga"
1138
1139 #define waki_a1 "gfx/hud/sb_rocket.tga"
1140 #define waki_a2 "gfx/sb_cells.tga"
1141
1142 void CSQC_WAKIZASHI_HUD()
1143 {
1144         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1145         float health, shield, energy, rockets;
1146         vector picsize, hudloc;
1147
1148     picsize = drawgetimagesize(SPIDER_CROSS);
1149     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1150     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1151     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1152
1153 /*
1154 const float STAT_VEHICLESTAT_HEALTH  = 60;
1155 const float STAT_VEHICLESTAT_SHIELD  = 61;
1156 const float STAT_VEHICLESTAT_ENERGY  = 62;
1157 const float STAT_VEHICLESTAT_AMMO1   = 63;
1158 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1159 const float STAT_VEHICLESTAT_AMMO2   = 65;
1160 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1161 */
1162     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1163         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1164         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1165         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1166
1167     hudloc_y =  4;
1168     hudloc_x = 4;
1169
1170     picsize = drawgetimagesize(waki_h) * 0.5;
1171     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1172
1173     picsize = drawgetimagesize(waki_a2) * 0.7;
1174     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1175
1176
1177     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1178     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1179
1180     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1181
1182     picsize = drawgetimagesize(waki_a1) * 0.75;
1183     if(rockets == 1)
1184     {
1185         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1186         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1187     }
1188     else
1189     {
1190         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1191         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1192         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1193     }
1194
1195     picsize = drawgetimagesize(waki_b) * 0.5;
1196     hudloc_y = 10.5;
1197     hudloc_x = 10.5;
1198
1199     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1200     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1201     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1202     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1203
1204
1205
1206         /*
1207         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1208         p = p + '0 1 0' * vid_conheight - '0 32 0';
1209
1210         // Draw health bar
1211         p_y += 8;
1212         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1213         p_x += 256 * health;
1214         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1215
1216         // Draw shiled bar
1217         p_x -= 256 * health;
1218         p_y += 4;
1219         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1220
1221         // Draw energy
1222         //p_x -= 256 * health;
1223         p_y -= 8;
1224         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1225
1226         // Draw rockets bar
1227         p_y += 12;
1228         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1229         */
1230
1231
1232
1233
1234         if (scoreboard_showscores)
1235         {
1236                 HUD_DrawScoreboard();
1237                 HUD_DrawCenterPrint();
1238         }
1239
1240 }
1241
1242
1243 void CSQC_common_hud(void)
1244 {
1245         // HUD_SortFrags(); done in HUD_Draw
1246         float hud;
1247         hud = getstati(STAT_HUD);
1248
1249         //hud = 10;
1250         switch(hud)
1251         {
1252                 case HUD_NORMAL:
1253                         // do some accuracy var caching
1254                         float i;
1255                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1256                         {
1257                                 acc_levels = tokenize(cvar_string("hud_panel_weapons_accuracy_color_levels"));
1258                                 if (acc_levels > MAX_ACCURACY_LEVELS)
1259                                         acc_levels = MAX_ACCURACY_LEVELS;
1260
1261                                 for (i = 0; i < acc_levels; ++i)
1262                                         acc_lev[i] = stof(argv(i));
1263                         }
1264
1265                         HUD_Main(); // always run these functions for alpha checks
1266                         HUD_DrawScoreboard();
1267
1268                         if (scoreboard_showscores || scoreboard_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1) // scoreboard/accuracy
1269                         {
1270                                 HUD_Reset();
1271                                 // HUD_DrawScoreboard takes care of centerprint_start
1272                         }
1273                         else if (intermission == 2) // map voting screen
1274                         {
1275                                 HUD_FinaleOverlay();
1276                                 HUD_Reset();
1277
1278                                 centerprint_start_x = 0;
1279                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1280                         }
1281                         else // hud
1282                         {
1283                                 centerprint_start_x = 0;
1284                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1285                         }
1286
1287                         HUD_DrawCenterPrint();
1288                         break;
1289
1290                 case HUD_SPIDERBOT:
1291                         CSQC_SPIDER_HUD();
1292                         break;
1293
1294                 case HUD_WAKIZASHI:
1295                         CSQC_WAKIZASHI_HUD();
1296                         break;
1297         }
1298 }
1299
1300
1301 // following vectors must be global to allow seamless switching between camera modes
1302 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1303 void CSQC_Demo_Camera()
1304 {
1305         float speed, attenuation, dimensions;
1306         vector tmp, delta;
1307
1308         if( cvar("camera_reset") || !camera_mode )
1309         {
1310                 camera_offset = '0 0 0';
1311                 current_angles = '0 0 0';
1312                 camera_direction = '0 0 0';
1313                 camera_offset_z += 30;
1314                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1315                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1316                 current_origin = view_origin;
1317                 current_camera_offset  = camera_offset;
1318                 cvar_set("camera_reset", "0");
1319                 camera_mode = CAMERA_CHASE;
1320         }
1321
1322         // Camera angles
1323         if( camera_roll )
1324                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1325
1326         if(cvar("camera_look_player"))
1327         {
1328                 local vector dir;
1329                 local float n;
1330
1331                 dir = normalize(view_origin - current_position);
1332                 n = mouse_angles_z;
1333                 mouse_angles = vectoangles(dir);
1334                 mouse_angles_x = mouse_angles_x * -1;
1335                 mouse_angles_z = n;
1336         }
1337         else
1338         {
1339                 tmp = getmousepos() * 0.1;
1340                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1341                 {
1342                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1343                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1344                 }
1345         }
1346
1347         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1348         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1349         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1350         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1351
1352         // Fix difference when angles don't have the same sign
1353         delta = '0 0 0';
1354         if(mouse_angles_y < -60 && current_angles_y > 60)
1355                 delta = '0 360 0';
1356         if(mouse_angles_y > 60 && current_angles_y < -60)
1357                 delta = '0 -360 0';
1358
1359         if(cvar("camera_look_player"))
1360                 attenuation = cvar("camera_look_attenuation");
1361         else
1362                 attenuation = cvar("camera_speed_attenuation");
1363
1364         attenuation = 1 / max(1, attenuation);
1365         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1366
1367         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1368         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1369         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1370         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1371
1372         // Camera position
1373         tmp = '0 0 0';
1374         dimensions = 0;
1375
1376         if( camera_direction_x )
1377         {
1378                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1379                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1380                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1381                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1382                 ++dimensions;
1383         }
1384
1385         if( camera_direction_y )
1386         {
1387                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1388                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1389                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1390                 ++dimensions;
1391         }
1392
1393         if( camera_direction_z )
1394         {
1395                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1396                 ++dimensions;
1397         }
1398
1399         if(cvar("camera_free"))
1400                 speed = cvar("camera_speed_free");
1401         else
1402                 speed = cvar("camera_speed_chase");
1403
1404         if(dimensions)
1405         {
1406                 speed = speed * sqrt(1 / dimensions);
1407                 camera_offset += tmp * speed;
1408         }
1409
1410         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1411
1412         // Camera modes
1413         if( cvar("camera_free") )
1414         {
1415                 if ( camera_mode == CAMERA_CHASE )
1416                 {
1417                         current_camera_offset = current_origin + current_camera_offset;
1418                         camera_offset = current_origin + camera_offset;
1419                 }
1420
1421                 camera_mode = CAMERA_FREE;
1422                 current_position = current_camera_offset;
1423         }
1424         else
1425         {
1426                 if ( camera_mode == CAMERA_FREE )
1427                 {
1428                         current_origin = view_origin;
1429                         camera_offset = camera_offset - current_origin;
1430                         current_camera_offset = current_camera_offset - current_origin;
1431                 }
1432
1433                 camera_mode = CAMERA_CHASE;
1434
1435                 if(cvar("camera_chase_smoothly"))
1436                         current_origin += (view_origin - current_origin) * attenuation;
1437                 else
1438                         current_origin = view_origin;
1439
1440                 current_position = current_origin + current_camera_offset;
1441         }
1442
1443         R_SetView(VF_ANGLES, current_angles);
1444         R_SetView(VF_ORIGIN, current_position);
1445 }