qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(void)
 203 {
 204         float fovx, fovy;
 205         float width = (mi_picmax_x - mi_picmin_x);
 206         float height = (mi_picmax_y - mi_picmin_y);
 207         float distance_to_middle_of_world = vlen(view_origin);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 322
 323         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 324         trueaimpoint = trace_endpos;
 325
 326         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 327                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 328
 329         if(vecs_x > 0)
 330                 vecs_y = -vecs_y;
 331         else
 332                 vecs = '0 0 0';
 333
 334         dv = view_right * vecs_y + view_up * vecs_z;
 335         w_shotorg = view_origin + dv;
 336
 337         // now move the vecs forward as much as requested if possible
 338         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 339         w_shotorg = trace_endpos - view_forward * nudge;
 340
 341         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 342         shottype = EnemyHitCheck();
 343         if(shottype != SHOTTYPE_HITWORLD)
 344                 return shottype;
 345
 346 #if 0
 347         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 348         // or rather, I know why, but see no fix
 349         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 350                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 351                 return SHOTTYPE_HITOBSTRUCTION;
 352 #endif
 353
 354         return SHOTTYPE_HITWORLD;
 355 }
 356
 357 void CSQC_common_hud(void);
 358
 359 void PostInit(void);
 360 void CSQC_Demo_Camera();
 361 float HUD_WouldDrawScoreboard();
 362 float camera_mode;
 363 const float CAMERA_FREE = 1;
 364 const float CAMERA_CHASE = 2;
 365 float reticle_type;
 366 string NextFrameCommand;
 367 void CSQC_SPIDER_HUD();
 368 void CSQC_RAPTOR_HUD();
 369
 370 vector freeze_org, freeze_ang;
 371 entity nightvision_noise, nightvision_noise2;
 372
 373 #define MAX_TIME_DIFF 5
 374 float pickup_crosshair_time, pickup_crosshair_size;
 375 float hit_time, typehit_time;
 376 float nextsound_hit_time, nextsound_typehit_time;
 377 float hitindication_crosshair_time, hitindication_crosshair_size;
 378 float use_nex_chargepool;
 379
 380 float myhealth, myhealth_prev;
 381 float myhealth_flash;
 382
 383 float old_blurradius, old_bluralpha;
 384 float old_sharpen_intensity;
 385
 386 vector myhealth_gentlergb;
 387
 388 float contentavgalpha, liquidalpha_prev;
 389 vector liquidcolor_prev;
 390
 391 float eventchase_current_distance;
 392
 393 vector damage_blurpostprocess, content_blurpostprocess;
 394
 395 float checkfail[16];
 396
 397 float rainbow_last_flicker;
 398 vector rainbow_prev_color;
 399 float autocvar_cl_orthoview_distanceoverride;
 400 #define BUTTON_3 4
 401 #define BUTTON_4 8
 402 float cl_notice_run();
 403 float prev_myteam;
 404 void CSQC_UpdateView(float w, float h)
 405 {
 406         entity e;
 407         float fov;
 408         float f, i, j;
 409         vector v;
 410         vector vf_size, vf_min;
 411         float a;
 412
 413         execute_next_frame();
 414
 415         ++framecount;
 416
 417         hud = getstati(STAT_HUD);
 418
 419         if(autocvar__hud_showbinds_reload) // menu can set this one
 420         {
 421                 db_close(binddb);
 422                 binddb = db_create();
 423                 cvar_set("_hud_showbinds_reload", "0");
 424         }
 425
 426         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 427                 view_quality = getproperty(VF_MINFPS_QUALITY);
 428         else
 429                 view_quality = 1;
 430
 431         button_attack2 = (input_buttons & BUTTON_3);
 432         button_zoom = (input_buttons & BUTTON_4);
 433
 434 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 435         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 436         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 437         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 438         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 439         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 440         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 441         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 442
 443         vf_size = getpropertyvec(VF_SIZE);
 444         vf_min = getpropertyvec(VF_MIN);
 445         vid_width = vf_size_x;
 446         vid_height = vf_size_y;
 447
 448         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 449         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 450
 451         WaypointSprite_Load();
 452
 453         CSQCPlayer_SetCamera();
 454
 455 #ifdef COMPAT_XON050_ENGINE
 456         if(spectatee_status)
 457                 myteam = GetPlayerColor(spectatee_status - 1);
 458         else
 459 #endif
 460                 myteam = GetPlayerColor(player_localentnum - 1);
 461
 462         if(myteam != prev_myteam)
 463         {
 464                 myteamcolors = colormapPaletteColor(myteam, 1);
 465                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 466                         hud_panel[i].update_time = time;
 467                 prev_myteam = myteam;
 468         }
 469
 470         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 471
 472         float is_dead = (getstati(STAT_HEALTH) <= 0);
 473
 474         // FIXME do we need this hack?
 475         if(isdemo())
 476         {
 477                 // in demos, input_buttons do not work
 478                 button_zoom = (autocvar__togglezoom == "-");
 479         }
 480         else if(button_zoom
 481                 && autocvar_cl_unpress_zoom_on_death
 482                 && (spectatee_status >= 0)
 483                 && (is_dead || intermission))
 484         {
 485                 // no zoom while dead or in intermission please
 486                 localcmd("-zoom\n");
 487                 button_zoom = FALSE;
 488         }
 489
 490         // event chase camera
 491         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 492         {
 493                 if((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission)
 494                 {
 495                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 496                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 497
 498                         // detect maximum viewoffset and use it
 499                         if(autocvar_cl_eventchase_viewoffset)
 500                         {
 501                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 502                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 503                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 504                         }
 505
 506                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 507                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 508                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 509                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 510
 511                         // make the camera smooth back
 512                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 513                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 514                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 515                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 516
 517                         makevectors(view_angles);
 518
 519                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 520                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 521
 522                         // If the boxtrace fails, revert back to line tracing.
 523                         if(trace_startsolid)
 524                         {
 525                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 526                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 527                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 528                         }
 529                         else { setproperty(VF_ORIGIN, trace_endpos); }
 530
 531                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 532                 }
 533                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 534                 {
 535                         cvar_set("chase_active", "0");
 536                         eventchase_current_distance = 0; // start from 0 next time
 537                 }
 538         }
 539         // workaround for camera stuck between player's legs when using chase_active 1
 540         // because the engine stops updating the chase_active camera when the game ends
 541         else if(intermission)
 542         {
 543                 cvar_settemp("chase_active", "-1");
 544                 eventchase_current_distance = 0;
 545         }
 546
 547         // do lockview after event chase camera so that it still applies whenever necessary.
 548         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 549         {
 550                 setproperty(VF_ORIGIN, freeze_org);
 551                 setproperty(VF_ANGLES, freeze_ang);
 552         }
 553         else
 554         {
 555                 freeze_org = getpropertyvec(VF_ORIGIN);
 556                 freeze_ang = getpropertyvec(VF_ANGLES);
 557         }
 558
 559         WarpZone_FixView();
 560         //WarpZone_FixPMove();
 561
 562         if(autocvar_cl_orthoview)
 563         {
 564                 float ov_width = (mi_picmax_x - mi_picmin_x);
 565                 float ov_height = (mi_picmax_y - mi_picmin_y);
 566                 float ov_distance = (512 * max(ov_width, ov_height));
 567                 if(autocvar_cl_orthoview_distanceoverride) { ov_distance = autocvar_cl_orthoview_distanceoverride; }
 568                 vector ov_org = ('0 0 1' * ov_distance);
 569
 570                 #define FL2VEC(x,y,z) (('1 0 0' * x) + ('0 1 0' * y) + ('0 0 1' * z))
 571
 572                 float ov_nearest = vlen(ov_org - FL2VEC(
 573                         bound(mi_picmin_x, ov_org_x, mi_picmax_x),
 574                         bound(mi_picmin_y, ov_org_y, mi_picmax_y),
 575                         bound(mi_picmin_z, ov_org_z, mi_picmax_z)
 576                 ));
 577
 578                 float ov_furthest = 0;
 579                 float dist = 0;
 580
 581                 if((dist = vlen(FL2VEC(mi_picmin_x, mi_picmin_y, mi_picmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 582                 if((dist = vlen(FL2VEC(mi_picmax_x, mi_picmin_y, mi_picmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 583                 if((dist = vlen(FL2VEC(mi_picmin_x, mi_picmax_y, mi_picmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 584                 if((dist = vlen(FL2VEC(mi_picmin_x, mi_picmin_y, mi_picmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 585                 if((dist = vlen(FL2VEC(mi_picmax_x, mi_picmax_y, mi_picmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 586                 if((dist = vlen(FL2VEC(mi_picmin_x, mi_picmax_y, mi_picmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 587                 if((dist = vlen(FL2VEC(mi_picmax_x, mi_picmin_y, mi_picmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 588                 if((dist = vlen(FL2VEC(mi_picmax_x, mi_picmax_y, mi_picmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 589
 590                 cvar_set("r_nearclip", ftos(ov_nearest));
 591                 cvar_set("r_farclip_base", ftos(ov_furthest));
 592                 cvar_set("r_farclip_world", "0");
 593                 cvar_set("r_useinfinitefarclip", "0");
 594
 595                 setproperty(VF_ORIGIN, ov_org);
 596                 setproperty(VF_ANGLES, '90 0 0');
 597         }
 598
 599         // Render the Scene
 600         view_origin = getpropertyvec(VF_ORIGIN);
 601         view_angles = getpropertyvec(VF_ANGLES);
 602         makevectors(view_angles);
 603         view_forward = v_forward;
 604         view_right = v_right;
 605         view_up = v_up;
 606
 607 #ifdef BLURTEST
 608         if(time > blurtest_time0 && time < blurtest_time1)
 609         {
 610                 float r, t;
 611
 612                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 613                 r = t * blurtest_radius;
 614                 f = 1 / pow(t, blurtest_power) - 1;
 615
 616                 cvar_set("r_glsl_postprocess", "1");
 617                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 618         }
 619         else
 620         {
 621                 cvar_set("r_glsl_postprocess", "0");
 622                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 623         }
 624 #endif
 625
 626         TargetMusic_Advance();
 627         Fog_Force();
 628
 629         if(drawtime == 0)
 630                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 631         else
 632                 drawframetime = bound(0.000001, time - drawtime, 1);
 633         drawtime = time;
 634
 635         // watch for gametype changes here...
 636         // in ParseStuffCMD the cmd isn't executed yet :/
 637         // might even be better to add the gametype to TE_CSQC_INIT...?
 638         if(!postinit)
 639                 PostInit();
 640
 641         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 642         {
 643                 if(calledhooks & HOOK_START)
 644                 {
 645                         localcmd("\ncl_hook_gameend\n");
 646                         calledhooks |= HOOK_END;
 647                 }
 648         }
 649
 650         Announcer();
 651
 652         fov = autocvar_fov;
 653         if(fov <= 59.5)
 654         {
 655                 if(!zoomscript_caught)
 656                 {
 657                         localcmd("+button9\n");
 658                         zoomscript_caught = 1;
 659                 }
 660         }
 661         else
 662         {
 663                 if(zoomscript_caught)
 664                 {
 665                         localcmd("-button9\n");
 666                         zoomscript_caught = 0;
 667                 }
 668         }
 669
 670         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 671
 672         // next WANTED weapon (for HUD)
 673         switchweapon = getstati(STAT_SWITCHWEAPON);
 674
 675         // currently switching-to weapon (for crosshair)
 676         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 677
 678         // actually active weapon (for zoom)
 679         activeweapon = getstati(STAT_ACTIVEWEAPON);
 680
 681         f = (serverflags & SERVERFLAG_TEAMPLAY);
 682         if(f != teamplay)
 683         {
 684                 teamplay = f;
 685                 HUD_InitScores();
 686         }
 687
 688         if(last_switchweapon != switchweapon)
 689         {
 690                 weapontime = time;
 691                 last_switchweapon = switchweapon;
 692                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 693                 {
 694                         localcmd("-zoom\n");
 695                         button_zoom = FALSE;
 696                 }
 697                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 698                 {
 699                         localcmd("-fire\n");
 700                         localcmd("-fire2\n");
 701                         button_attack2 = FALSE;
 702                 }
 703         }
 704         if(last_activeweapon != activeweapon)
 705         {
 706                 last_activeweapon = activeweapon;
 707
 708                 e = get_weaponinfo(activeweapon);
 709                 if(e.netname != "")
 710                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 711                 else
 712                         localcmd("\ncl_hook_activeweapon none\n");
 713         }
 714
 715         // ALWAYS Clear Current Scene First
 716         clearscene();
 717 #ifdef WORKAROUND_XON010
 718         if(checkextension("DP_CSQC_ROTATEMOVES"))
 719         {
 720 #endif
 721         setproperty(VF_ORIGIN, view_origin);
 722         setproperty(VF_ANGLES, view_angles);
 723 #ifdef WORKAROUND_XON010
 724         }
 725 #endif
 726
 727         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 728         setproperty(VF_SIZE, vf_size);
 729         setproperty(VF_MIN, vf_min);
 730
 731         // Assign Standard Viewflags
 732         // Draw the World (and sky)
 733         setproperty(VF_DRAWWORLD, 1);
 734
 735         // Set the console size vars
 736         vid_conwidth = autocvar_vid_conwidth;
 737         vid_conheight = autocvar_vid_conheight;
 738         vid_pixelheight = autocvar_vid_pixelheight;
 739
 740         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV()); }
 741         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 742
 743         // Camera for demo playback
 744         if(camera_active)
 745         {
 746                 if(autocvar_camera_enable)
 747                         CSQC_Demo_Camera();
 748                 else
 749                 {
 750                         cvar_set("chase_active", ftos(chase_active_backup));
 751                         cvar_set("cl_demo_mousegrab", "0");
 752                         camera_active = FALSE;
 753                 }
 754         }
 755 #ifdef CAMERATEST
 756         else if(autocvar_camera_enable)
 757 #else
 758         else if(autocvar_camera_enable && isdemo())
 759 #endif
 760         {
 761                 // Enable required Darkplaces cvars
 762                 chase_active_backup = autocvar_chase_active;
 763                 cvar_set("chase_active", "2");
 764                 cvar_set("cl_demo_mousegrab", "1");
 765                 camera_active = TRUE;
 766                 camera_mode = FALSE;
 767         }
 768
 769         // Draw the Crosshair
 770         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 771
 772         // Draw the Engine Status Bar (the default Quake HUD)
 773         setproperty(VF_DRAWENGINESBAR, 0);
 774
 775         // Update the mouse position
 776         /*
 777            mousepos_x = vid_conwidth;
 778            mousepos_y = vid_conheight;
 779            mousepos = mousepos*0.5 + getmousepos();
 780          */
 781
 782         e = self;
 783         for(self = world; (self = nextent(self)); )
 784                 if(self.draw)
 785                         self.draw();
 786         self = e;
 787
 788         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 789         renderscene();
 790
 791         // now switch to 2D drawing mode by calling a 2D drawing function
 792         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 793         // next R_RenderScene call
 794         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 795
 796         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 797         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 798         {
 799                 // apply night vision effect
 800                 vector tc_00, tc_01, tc_10, tc_11;
 801                 vector rgb;
 802                 rgb_x = 0; // fteqcc sucks
 803                 rgb_y = 0; // fteqcc sucks
 804                 rgb_z = 0; // fteqcc sucks
 805
 806                 if(!nightvision_noise)
 807                 {
 808                         nightvision_noise = spawn();
 809                         nightvision_noise.classname = "nightvision_noise";
 810                 }
 811                 if(!nightvision_noise2)
 812                 {
 813                         nightvision_noise2 = spawn();
 814                         nightvision_noise2.classname = "nightvision_noise2";
 815                 }
 816
 817                 // color tint in yellow
 818                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 819
 820                 // draw BG
 821                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 822                 rgb = '1 1 1';
 823                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 824                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 825                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 826                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 827                 tc_11 = tc_01 + tc_10 - tc_00;
 828                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 829                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 830                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 831                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 832                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 833                 R_EndPolygon();
 834
 835                 // draw FG
 836                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 837                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 838                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 839                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 840                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 841                 tc_11 = tc_01 + tc_10 - tc_00;
 842                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 843                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 844                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 845                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 846                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 847                 R_EndPolygon();
 848         }
 849
 850         // Draw the aiming reticle for weapons that use it
 851         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 852         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 853         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 854         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 855                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 856         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 857                 reticle_type = 2; // nex zoom
 858         else if(button_zoom || zoomscript_caught)
 859                 reticle_type = 1; // normal zoom
 860         else if((activeweapon == WEP_NEX) && button_attack2)
 861                 reticle_type = 2; // nex zoom
 862
 863         if(reticle_type && autocvar_cl_reticle)
 864         {
 865                 if(autocvar_cl_reticle_stretch)
 866                 {
 867                         reticle_size_x = vid_conwidth;
 868                         reticle_size_y = vid_conheight;
 869                         reticle_pos_x = 0;
 870                         reticle_pos_y = 0;
 871                 }
 872                 else
 873                 {
 874                         reticle_size_x = max(vid_conwidth, vid_conheight);
 875                         reticle_size_y = max(vid_conwidth, vid_conheight);
 876                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 877                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 878                 }
 879
 880                 f = current_zoomfraction;
 881                 if(zoomscript_caught)
 882                         f = 1;
 883                 if(autocvar_cl_reticle_item_normal)
 884                 {
 885                         if(reticle_type == 1 && f)
 886                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 887                 }
 888                 if(autocvar_cl_reticle_item_nex)
 889                 {
 890                         if(reticle_type == 2 && f)
 891                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 892                 }
 893         }
 894
 895
 896         // improved polyblend
 897         if(autocvar_hud_contents)
 898         {
 899                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 900                 vector liquidcolor;
 901
 902                 switch(pointcontents(view_origin))
 903                 {
 904                         case CONTENT_WATER:
 905                                 liquidalpha = autocvar_hud_contents_water_alpha;
 906                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 907                                 incontent = 1;
 908                                 break;
 909
 910                         case CONTENT_LAVA:
 911                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 912                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 913                                 incontent = 1;
 914                                 break;
 915
 916                         case CONTENT_SLIME:
 917                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 918                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 919                                 incontent = 1;
 920                                 break;
 921
 922                         default:
 923                                 liquidalpha = 0;
 924                                 liquidcolor = '0 0 0';
 925                                 incontent = 0;
 926                                 break;
 927                 }
 928
 929                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 930                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 931                         contentfadetime = autocvar_hud_contents_fadeintime;
 932                         liquidalpha_prev = liquidalpha;
 933                         liquidcolor_prev = liquidcolor;
 934                 }
 935                 else
 936                         contentfadetime = autocvar_hud_contents_fadeouttime;
 937
 938                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 939                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 940
 941                 if(contentavgalpha)
 942                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 943
 944                 if(autocvar_hud_postprocessing)
 945                 {
 946                         if(autocvar_hud_contents_blur && contentavgalpha)
 947                         {
 948                                 content_blurpostprocess_x = 1;
 949                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 950                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 951                         }
 952                         else
 953                         {
 954                                 content_blurpostprocess_x = 0;
 955                                 content_blurpostprocess_y = 0;
 956                                 content_blurpostprocess_z = 0;
 957                         }
 958                 }
 959         }
 960
 961         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 962         {
 963                 splash_size_x = max(vid_conwidth, vid_conheight);
 964                 splash_size_y = max(vid_conwidth, vid_conheight);
 965                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 966                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 967
 968                 float myhealth_flash_temp;
 969                 myhealth = getstati(STAT_HEALTH);
 970
 971                 // fade out
 972                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 973                 // add new damage
 974                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 975
 976                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 977                 pain_threshold = autocvar_hud_damage_pain_threshold;
 978                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 979                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 980
 981                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 982                 {
 983                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 984                 }
 985
 986                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 987
 988                 if(myhealth_prev < 1)
 989                 {
 990                         if(myhealth >= 1)
 991                         {
 992                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 993                                 myhealth_flash_temp = 0;
 994                         }
 995                         else
 996                         {
 997                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 998                         }
 999                 }
1000
1001                 if(spectatee_status == -1 || intermission)
1002                 {
1003                         myhealth_flash = 0; // observing, or match ended
1004                         myhealth_flash_temp = 0;
1005                 }
1006
1007                 myhealth_prev = myhealth;
1008
1009                 // IDEA: change damage color/picture based on player model for robot/alien species?
1010                 // pro: matches model better
1011                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1012                 // maybe different reddish pics?
1013                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1014                 {
1015                         if(autocvar_cl_gentle_damage == 2)
1016                         {
1017                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1018                                 {
1019                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1020                                 }
1021                         }
1022                         else
1023                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1024
1025                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1026                 }
1027                 else
1028                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1029
1030                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1031                 {
1032                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1033                         {
1034                                 damage_blurpostprocess_x = 1;
1035                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1036                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1037                         }
1038                         else
1039                         {
1040                                 damage_blurpostprocess_x = 0;
1041                                 damage_blurpostprocess_y = 0;
1042                                 damage_blurpostprocess_z = 0;
1043                         }
1044                 }
1045         }
1046
1047         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1048         float e2 = (autocvar_hud_powerup != 0);
1049         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1050         {
1051                 // enable or disable rendering types if they are used or not
1052                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1053                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1054
1055                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1056                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1057                 {
1058                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1059                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1060                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1061                         {
1062                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1063                                 old_blurradius = blurradius;
1064                                 old_bluralpha = bluralpha;
1065                         }
1066                 }
1067                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1068                 {
1069                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1070                         old_blurradius = 0;
1071                         old_bluralpha = 0;
1072                 }
1073
1074                 // edge detection postprocess handling done second (used by hud_powerup)
1075                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1076                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1077                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1078
1079                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1080
1081                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1082                 {
1083                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1084                         {
1085                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1086                                 old_sharpen_intensity = sharpen_intensity;
1087                         }
1088                 }
1089                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1090                 {
1091                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1092                         old_sharpen_intensity = 0;
1093                 }
1094
1095                 if(cvar("r_glsl_postprocess") == 0)
1096                         cvar_set("r_glsl_postprocess", "2");
1097         }
1098         else if(cvar("r_glsl_postprocess") == 2)
1099                 cvar_set("r_glsl_postprocess", "0");
1100
1101         if(menu_visible)
1102                 menu_show();
1103
1104         /*if(gametype == MAPINFO_TYPE_CTF)
1105           {
1106           ctf_view();
1107           } else */
1108
1109         // draw 2D entities
1110         e = self;
1111         for(self = world; (self = nextent(self)); )
1112                 if(self.draw2d)
1113                         self.draw2d();
1114         self = e;
1115         Draw_ShowNames_All();
1116
1117         scoreboard_active = HUD_WouldDrawScoreboard();
1118
1119         hit_time = getstatf(STAT_HIT_TIME);
1120         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1121         {
1122                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1123                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1124
1125                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1126         }
1127         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1128         if(typehit_time > nextsound_typehit_time)
1129         {
1130                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1131                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1132
1133                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1134         }
1135
1136         //else
1137         {
1138                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1139                 {
1140                         if(getstati(STAT_FROZEN))
1141                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1142                         if(getstatf(STAT_REVIVE_PROGRESS))
1143                         {
1144                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1145                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1146                         }
1147                 }
1148
1149                 if(autocvar_r_letterbox == 0)
1150                         if(autocvar_viewsize < 120)
1151                                 CSQC_common_hud();
1152
1153                 // crosshair goes VERY LAST
1154                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1155                 {
1156                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1157                                 return;
1158
1159                         string wcross_style;
1160                         float wcross_alpha, wcross_resolution;
1161                         wcross_style = autocvar_crosshair;
1162                         if (wcross_style == "0")
1163                                 return;
1164                         wcross_resolution = autocvar_crosshair_size;
1165                         if (wcross_resolution == 0)
1166                                 return;
1167                         wcross_alpha = autocvar_crosshair_alpha;
1168                         if (wcross_alpha == 0)
1169                                 return;
1170
1171                         // TrueAim check
1172                         float shottype;
1173
1174                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1175                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1176                         wcross_origin_z = 0;
1177                         if(autocvar_crosshair_hittest)
1178                         {
1179                                 vector wcross_oldorigin;
1180                                 wcross_oldorigin = wcross_origin;
1181                                 shottype = TrueAimCheck();
1182                                 if(shottype == SHOTTYPE_HITWORLD)
1183                                 {
1184                                         v = wcross_origin - wcross_oldorigin;
1185                                         v_x /= vid_conwidth;
1186                                         v_y /= vid_conheight;
1187                                         if(vlen(v) > 0.01)
1188                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1189                                 }
1190                                 if(!autocvar_crosshair_hittest_showimpact)
1191                                         wcross_origin = wcross_oldorigin;
1192                         }
1193                         else
1194                                 shottype = SHOTTYPE_HITWORLD;
1195
1196                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1197                         string wcross_wep = "", wcross_name;
1198                         float wcross_scale, wcross_blur;
1199
1200                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1201                         {
1202                                 e = get_weaponinfo(switchingweapon);
1203                                 if (e && e.netname != "")
1204                                 {
1205                                         wcross_wep = e.netname;
1206                                         if(autocvar_crosshair_per_weapon)
1207                                         {
1208                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1209                                                 if (wcross_resolution == 0)
1210                                                         return;
1211                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1212                                                 if (wcross_alpha == 0)
1213                                                         return;
1214
1215                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1216                                                 if(wcross_style == "" || wcross_style == "0")
1217                                                         wcross_style = wcross_wep;
1218                                         }
1219                                 }
1220                         }
1221
1222                         //print(sprintf("crosshair style: %s\n", wcross_style));
1223                         wcross_name = strcat("gfx/crosshair", wcross_style);
1224
1225                         // MAIN CROSSHAIR COLOR DECISION
1226                         switch(autocvar_crosshair_color_special)
1227                         {
1228                                 case 1: // crosshair_color_per_weapon
1229                                 {
1230                                         if(wcross_wep != "")
1231                                         {
1232                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1233                                                 break;
1234                                         }
1235                                         else { goto normalcolor; }
1236                                 }
1237
1238                                 case 2: // crosshair_color_by_health
1239                                 {
1240                                         float x = getstati(STAT_HEALTH);
1241
1242                                         //x = red
1243                                         //y = green
1244                                         //z = blue
1245
1246                                         wcross_color_z = 0;
1247
1248                                         if(x > 200)
1249                                         {
1250                                                 wcross_color_x = 0;
1251                                                 wcross_color_y = 1;
1252                                         }
1253                                         else if(x > 150)
1254                                         {
1255                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1256                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1257                                         }
1258                                         else if(x > 100)
1259                                         {
1260                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1261                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1262                                                 wcross_color_z = 1 - (x-100)*0.02;
1263                                         }
1264                                         else if(x > 50)
1265                                         {
1266                                                 wcross_color_x = 1;
1267                                                 wcross_color_y = 1;
1268                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1269                                         }
1270                                         else if(x > 20)
1271                                         {
1272                                                 wcross_color_x = 1;
1273                                                 wcross_color_y = (x-20)*90/27/100;
1274                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1275                                         }
1276                                         else
1277                                         {
1278                                                 wcross_color_x = 1;
1279                                                 wcross_color_y = 0;
1280                                         }
1281                                         break;
1282                                 }
1283
1284                                 case 3: // crosshair_color_rainbow
1285                                 {
1286                                         if(time >= rainbow_last_flicker)
1287                                         {
1288                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1289                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1290                                         }
1291                                         wcross_color = rainbow_prev_color;
1292                                         break;
1293                                 }
1294                                 :normalcolor
1295                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1296                         }
1297
1298                         if(autocvar_crosshair_effect_scalefade)
1299                         {
1300                                 wcross_scale = wcross_resolution;
1301                                 wcross_resolution = 1;
1302                         }
1303                         else
1304                         {
1305                                 wcross_scale = 1;
1306                         }
1307
1308                         if(autocvar_crosshair_pickup)
1309                         {
1310                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1311
1312                                 if(pickup_crosshair_time < stat_pickup_time)
1313                                 {
1314                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1315                                                 pickup_crosshair_size = 1;
1316
1317                                         pickup_crosshair_time = stat_pickup_time;
1318                                 }
1319
1320                                 if(pickup_crosshair_size > 0)
1321                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1322                                 else
1323                                         pickup_crosshair_size = 0;
1324
1325                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1326                         }
1327
1328                         if(autocvar_crosshair_hitindication)
1329                         {
1330                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1331
1332                                 if(hitindication_crosshair_time < hit_time)
1333                                 {
1334                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1335                                                 hitindication_crosshair_size = 1;
1336
1337                                         hitindication_crosshair_time = hit_time;
1338                                 }
1339
1340                                 if(hitindication_crosshair_size > 0)
1341                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1342                                 else
1343                                         hitindication_crosshair_size = 0;
1344
1345                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1346                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1347                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1348                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1349                         }
1350
1351                         if(shottype == SHOTTYPE_HITENEMY)
1352                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1353                         if(shottype == SHOTTYPE_HITTEAM)
1354                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1355
1356                         f = fabs(autocvar_crosshair_effect_time);
1357                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1358                         {
1359                                 wcross_changedonetime = time + f;
1360                         }
1361                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1362                         {
1363                                 wcross_name_changestarttime = time;
1364                                 wcross_name_changedonetime = time + f;
1365                                 if(wcross_name_goal_prev_prev)
1366                                         strunzone(wcross_name_goal_prev_prev);
1367                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1368                                 wcross_name_goal_prev = strzone(wcross_name);
1369                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1370                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1371                                 wcross_resolution_goal_prev = wcross_resolution;
1372                         }
1373
1374                         wcross_scale_goal_prev = wcross_scale;
1375                         wcross_alpha_goal_prev = wcross_alpha;
1376                         wcross_color_goal_prev = wcross_color;
1377
1378                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1379                         {
1380                                 wcross_blur = 1;
1381                                 wcross_alpha *= 0.75;
1382                         }
1383                         else
1384                                 wcross_blur = 0;
1385                         // *_prev is at time-frametime
1386                         // * is at wcross_changedonetime+f
1387                         // what do we have at time?
1388                         if(time < wcross_changedonetime)
1389                         {
1390                                 f = frametime / (wcross_changedonetime - time + frametime);
1391                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1392                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1393                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1394                         }
1395
1396                         wcross_scale_prev = wcross_scale;
1397                         wcross_alpha_prev = wcross_alpha;
1398                         wcross_color_prev = wcross_color;
1399
1400                         wcross_scale *= 1 - autocvar__menu_alpha;
1401                         wcross_alpha *= 1 - autocvar__menu_alpha;
1402                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1403
1404                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1405                         {
1406                                 // crosshair rings for weapon stats
1407                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1408                                 {
1409                                         // declarations and stats
1410                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1411                                         string ring_image = string_null, ring_inner_image = string_null;
1412                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1413
1414                                         ring_scale = autocvar_crosshair_ring_size;
1415
1416                                         float weapon_clipload, weapon_clipsize;
1417                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1418                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1419
1420                                         float nex_charge, nex_chargepool;
1421                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1422                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1423
1424                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1425                                                 nex_charge_movingavg = nex_charge;
1426
1427
1428                                         // handle the values
1429                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1430                                         {
1431                                                 if (nex_chargepool || use_nex_chargepool) {
1432                                                         use_nex_chargepool = 1;
1433                                                         ring_inner_value = nex_chargepool;
1434                                                 } else {
1435                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1436                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1437                                                 }
1438
1439                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1440                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1441                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1442
1443                                                 // draw the outer ring to show the current charge of the weapon
1444                                                 ring_value = nex_charge;
1445                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1446                                                 ring_rgb = wcross_color;
1447                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1448                                         }
1449                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1450                                         {
1451                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1452                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1453                                                 ring_rgb = wcross_color;
1454                                                 ring_image = "gfx/crosshair_ring.tga";
1455                                         }
1456                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1457                                         {
1458                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1459                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1460                                                 ring_rgb = wcross_color;
1461                                                 ring_image = "gfx/crosshair_ring.tga";
1462                                         }
1463
1464                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1465                                         {
1466                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1467                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1468                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1469                                                 ring_rgb = wcross_color;
1470
1471                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1472                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1473                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1474                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1475                                                 else
1476                                                         ring_image = "gfx/crosshair_ring.tga";
1477                                         }
1478
1479                                         // if in weapon switch animation, fade ring out/in
1480                                         if(autocvar_crosshair_effect_time > 0)
1481                                         {
1482                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1483                                                 if not(f < 1)
1484                                                 {
1485                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1486                                                 }
1487
1488                                                 if(wcross_ring_prev)
1489                                                 {
1490                                                         if(f < 1)
1491                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1492                                                 }
1493                                                 else
1494                                                 {
1495                                                         if(f < 1)
1496                                                                 ring_alpha *= bound(0, f, 1);
1497                                                 }
1498                                         }
1499
1500                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1501                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1502
1503                                         if (ring_value)
1504                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1505                                 }
1506
1507 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1508                                 do \
1509                                 { \
1510                                         if(wcross_blur > 0) \
1511                                         { \
1512                                                 for(i = -2; i <= 2; ++i) \
1513                                                 for(j = -2; j <= 2; ++j) \
1514                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1515                                         } \
1516                                         else \
1517                                         { \
1518                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1519                                         } \
1520                                 } \
1521                                 while(0)
1522
1523 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1524                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1525
1526 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1527                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1528
1529                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1530                                 {
1531                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1532                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1533                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1534                                         f = 1 - f;
1535                                 }
1536                                 else
1537                                 {
1538                                         f = 1;
1539                                 }
1540                                 wcross_name_alpha_goal_prev = f;
1541
1542                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1543                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1544
1545                                 if(autocvar_crosshair_dot)
1546                                 {
1547                                         vector wcross_color_old;
1548                                         wcross_color_old = wcross_color;
1549
1550                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1551                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1552
1553                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1554                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1555                                         wcross_color = wcross_color_old;
1556                                 }
1557                         }
1558                 }
1559                 else
1560                 {
1561                         wcross_scale_prev = 0;
1562                         wcross_alpha_prev = 0;
1563                         wcross_scale_goal_prev = 0;
1564                         wcross_alpha_goal_prev = 0;
1565                         wcross_changedonetime = 0;
1566                         if(wcross_name_goal_prev)
1567                                 strunzone(wcross_name_goal_prev);
1568                         wcross_name_goal_prev = string_null;
1569                         if(wcross_name_goal_prev_prev)
1570                                 strunzone(wcross_name_goal_prev_prev);
1571                         wcross_name_goal_prev_prev = string_null;
1572                         wcross_name_changestarttime = 0;
1573                         wcross_name_changedonetime = 0;
1574                         wcross_name_alpha_goal_prev = 0;
1575                         wcross_name_alpha_goal_prev_prev = 0;
1576                         wcross_resolution_goal_prev = 0;
1577                         wcross_resolution_goal_prev_prev = 0;
1578                 }
1579         }
1580
1581         if(NextFrameCommand)
1582         {
1583                 localcmd("\n", NextFrameCommand, "\n");
1584                 NextFrameCommand = string_null;
1585         }
1586
1587         // we must do this check AFTER a frame was rendered, or it won't work
1588         if(cs_project_is_b0rked == 0)
1589         {
1590                 string w0, h0;
1591                 w0 = ftos(autocvar_vid_conwidth);
1592                 h0 = ftos(autocvar_vid_conheight);
1593                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1594                 //setproperty(VF_FOV, '90 90 0');
1595                 setproperty(VF_ORIGIN, '0 0 0');
1596                 setproperty(VF_ANGLES, '0 0 0');
1597                 setproperty(VF_PERSPECTIVE, 1);
1598                 makevectors('0 0 0');
1599                 vector v1, v2;
1600                 cvar_set("vid_conwidth", "800");
1601                 cvar_set("vid_conheight", "600");
1602                 v1 = cs_project(v_forward);
1603                 cvar_set("vid_conwidth", "640");
1604                 cvar_set("vid_conheight", "480");
1605                 v2 = cs_project(v_forward);
1606                 if(v1 == v2)
1607                         cs_project_is_b0rked = 1;
1608                 else
1609                         cs_project_is_b0rked = -1;
1610                 cvar_set("vid_conwidth", w0);
1611                 cvar_set("vid_conheight", h0);
1612         }
1613
1614         if(autocvar__hud_configure)
1615                 HUD_Panel_Mouse();
1616
1617     if(hud && !intermission)
1618     {
1619         if(hud == HUD_SPIDERBOT)
1620             CSQC_SPIDER_HUD();
1621         else if(hud == HUD_WAKIZASHI)
1622             CSQC_WAKIZASHI_HUD();
1623         else if(hud == HUD_RAPTOR)
1624             CSQC_RAPTOR_HUD();
1625         else if(hud == HUD_BUMBLEBEE)
1626             CSQC_BUMBLE_HUD();
1627         else if(hud == HUD_BUMBLEBEE_GUN)
1628             CSQC_BUMBLE_GUN_HUD();
1629     }
1630
1631         cl_notice_run();
1632
1633         // let's reset the view back to normal for the end
1634         setproperty(VF_MIN, '0 0 0');
1635         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1636 }
1637
1638
1639 void CSQC_common_hud(void)
1640 {
1641         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1642                 Accuracy_LoadLevels();
1643
1644     HUD_Main(); // always run these functions for alpha checks
1645     HUD_DrawScoreboard();
1646
1647     if (scoreboard_active) // scoreboard/accuracy
1648         HUD_Reset();
1649     else if (intermission == 2) // map voting screen
1650     {
1651         HUD_FinaleOverlay();
1652         HUD_Reset();
1653     }
1654         /*
1655         switch(hud)
1656         {
1657                 case HUD_SPIDERBOT:
1658                         CSQC_SPIDER_HUD();
1659                         break;
1660
1661                 case HUD_WAKIZASHI:
1662                         CSQC_WAKIZASHI_HUD();
1663                         break;
1664
1665         case HUD_BUMBLEBEE:
1666             CSQC_BUMBLE_HUD();
1667             break;
1668         }
1669         */
1670 }
1671
1672
1673 // following vectors must be global to allow seamless switching between camera modes
1674 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1675 void CSQC_Demo_Camera()
1676 {
1677         float speed, attenuation, dimensions;
1678         vector tmp, delta;
1679
1680         if( autocvar_camera_reset || !camera_mode )
1681         {
1682                 camera_offset = '0 0 0';
1683                 current_angles = '0 0 0';
1684                 camera_direction = '0 0 0';
1685                 camera_offset_z += 30;
1686                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1687                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1688                 current_origin = view_origin;
1689                 current_camera_offset  = camera_offset;
1690                 cvar_set("camera_reset", "0");
1691                 camera_mode = CAMERA_CHASE;
1692         }
1693
1694         // Camera angles
1695         if( camera_roll )
1696                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1697
1698         if(autocvar_camera_look_player)
1699         {
1700                 vector dir;
1701                 float n;
1702
1703                 dir = normalize(view_origin - current_position);
1704                 n = mouse_angles_z;
1705                 mouse_angles = vectoangles(dir);
1706                 mouse_angles_x = mouse_angles_x * -1;
1707                 mouse_angles_z = n;
1708         }
1709         else
1710         {
1711                 tmp = getmousepos() * 0.1;
1712                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1713                 {
1714                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1715                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1716                 }
1717         }
1718
1719         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1720         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1721         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1722         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1723
1724         // Fix difference when angles don't have the same sign
1725         delta = '0 0 0';
1726         if(mouse_angles_y < -60 && current_angles_y > 60)
1727                 delta = '0 360 0';
1728         if(mouse_angles_y > 60 && current_angles_y < -60)
1729                 delta = '0 -360 0';
1730
1731         if(autocvar_camera_look_player)
1732                 attenuation = autocvar_camera_look_attenuation;
1733         else
1734                 attenuation = autocvar_camera_speed_attenuation;
1735
1736         attenuation = 1 / max(1, attenuation);
1737         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1738
1739         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1740         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1741         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1742         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1743
1744         // Camera position
1745         tmp = '0 0 0';
1746         dimensions = 0;
1747
1748         if( camera_direction_x )
1749         {
1750                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1751                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1752                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1753                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1754                 ++dimensions;
1755         }
1756
1757         if( camera_direction_y )
1758         {
1759                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1760                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1761                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1762                 ++dimensions;
1763         }
1764
1765         if( camera_direction_z )
1766         {
1767                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1768                 ++dimensions;
1769         }
1770
1771         if(autocvar_camera_free)
1772                 speed = autocvar_camera_speed_free;
1773         else
1774                 speed = autocvar_camera_speed_chase;
1775
1776         if(dimensions)
1777         {
1778                 speed = speed * sqrt(1 / dimensions);
1779                 camera_offset += tmp * speed;
1780         }
1781
1782         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1783
1784         // Camera modes
1785         if( autocvar_camera_free )
1786         {
1787                 if ( camera_mode == CAMERA_CHASE )
1788                 {
1789                         current_camera_offset = current_origin + current_camera_offset;
1790                         camera_offset = current_origin + camera_offset;
1791                 }
1792
1793                 camera_mode = CAMERA_FREE;
1794                 current_position = current_camera_offset;
1795         }
1796         else
1797         {
1798                 if ( camera_mode == CAMERA_FREE )
1799                 {
1800                         current_origin = view_origin;
1801                         camera_offset = camera_offset - current_origin;
1802                         current_camera_offset = current_camera_offset - current_origin;
1803                 }
1804
1805                 camera_mode = CAMERA_CHASE;
1806
1807                 if(autocvar_camera_chase_smoothly)
1808                         current_origin += (view_origin - current_origin) * attenuation;
1809                 else
1810                         current_origin = view_origin;
1811
1812                 current_position = current_origin + current_camera_offset;
1813         }
1814
1815         setproperty(VF_ANGLES, current_angles);
1816         setproperty(VF_ORIGIN, current_position);
1817 }