qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 void CSQC_UpdateView(float w, float h)
 370 {
 371         entity e;
 372         float fov;
 373         float f, i, j;
 374         vector v, vo;
 375         vector vf_size, vf_min;
 376         float a;
 377
 378         vf_size = R_SetView3fv(VF_SIZE);
 379         vf_min = R_SetView3fv(VF_MIN);
 380         vid_width = vf_size_x;
 381         vid_height = vf_size_y;
 382
 383         vector reticle_pos, reticle_size;
 384
 385         WaypointSprite_Load();
 386
 387         if(spectatee_status)
 388                 myteam = GetPlayerColor(spectatee_status - 1);
 389         else
 390                 myteam = GetPlayerColor(player_localentnum - 1);
 391
 392         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 393         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 394
 395         warpzone_fixview_origin = pmove_org + vo;
 396         warpzone_fixview_cl_viewangles = input_angles;
 397         warpzone_fixview_angles = view_angles;
 398         WarpZone_FixView();
 399         pmove_org = warpzone_fixview_origin - vo;
 400         input_angles = warpzone_fixview_cl_viewangles;
 401         view_angles = warpzone_fixview_angles;
 402
 403         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 404         {
 405                 pmove_org = freeze_pmove_org;
 406                 input_angles = view_angles = freeze_input_angles;
 407                 R_SetView(VF_ORIGIN, pmove_org + vo);
 408                 R_SetView(VF_ANGLES, view_angles);
 409                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 410         }
 411         freeze_pmove_org = pmove_org;
 412         freeze_input_angles = input_angles;
 413
 414         // Render the Scene
 415         if(!intermission || !view_set)
 416         {
 417                 view_origin = pmove_org + vo;
 418                 view_angles = input_angles;
 419                 makevectors(view_angles);
 420                 view_forward = v_forward;
 421                 view_right = v_right;
 422                 view_up = v_up;
 423                 view_set = 1;
 424         }
 425
 426 #ifdef BLURTEST
 427         if(time > blurtest_time0 && time < blurtest_time1)
 428         {
 429                 float r, t;
 430
 431                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 432                 r = t * blurtest_radius;
 433                 f = 1 / pow(t, blurtest_power) - 1;
 434
 435                 cvar_set("r_glsl_postprocess", "1");
 436                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 437         }
 438         else
 439         {
 440                 cvar_set("r_glsl_postprocess", "0");
 441                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 442         }
 443 #endif
 444
 445         TargetMusic_Advance();
 446         Fog_Force();
 447
 448         drawframetime = max(0.000001, time - drawtime);
 449         drawtime = time;
 450
 451         // watch for gametype changes here...
 452         // in ParseStuffCMD the cmd isn't executed yet :/
 453         // might even be better to add the gametype to TE_CSQC_INIT...?
 454         if(!postinit)
 455                 PostInit();
 456
 457         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 458                 if(calledhooks & HOOK_START)
 459                 {
 460                         localcmd("\ncl_hook_gameend\n");
 461                         calledhooks |= HOOK_END;
 462                 }
 463
 464         CheckForGamestartChange();
 465         serverAnnouncer();
 466         maptimeAnnouncer();
 467         carrierAnnouncer();
 468
 469         fov = autocvar_fov;
 470         if(button_zoom || fov <= 59.5)
 471         {
 472                 if(!zoomscript_caught)
 473                 {
 474                         localcmd("+button4\n");
 475                         zoomscript_caught = 1;
 476                         ignore_plus_zoom += 1;
 477                 }
 478         }
 479         else
 480         {
 481                 if(zoomscript_caught)
 482                 {
 483                         localcmd("-button4\n");
 484                         zoomscript_caught = 0;
 485                         ignore_minus_zoom += 1;
 486                 }
 487         }
 488
 489         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 490         activeweapon = getstati(STAT_SWITCHWEAPON);
 491         f = (serverflags & SERVERFLAG_TEAMPLAY);
 492         if(f != teamplay)
 493         {
 494                 teamplay = f;
 495                 HUD_InitScores();
 496         }
 497
 498         if(last_weapon != activeweapon) {
 499                 weapontime = time;
 500                 last_weapon = activeweapon;
 501
 502                 e = get_weaponinfo(activeweapon);
 503                 if(e.netname != "")
 504                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 505                 else
 506                         localcmd("\ncl_hook_activeweapon none\n");
 507         }
 508
 509         // ALWAYS Clear Current Scene First
 510         R_ClearScene();
 511
 512         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 513         R_SetView(VF_SIZE, vf_size);
 514         R_SetView(VF_MIN, vf_min);
 515
 516         // Assign Standard Viewflags
 517         // Draw the World (and sky)
 518         R_SetView(VF_DRAWWORLD, 1);
 519
 520         // Set the console size vars
 521         vid_conwidth = autocvar_vid_conwidth;
 522         vid_conheight = autocvar_vid_conheight;
 523         vid_pixelheight = autocvar_vid_pixelheight;
 524
 525         R_SetView(VF_FOV, GetCurrentFov(fov));
 526
 527         // Camera for demo playback
 528         if(camera_active)
 529         {
 530                 if(autocvar_camera_enable)
 531                         CSQC_Demo_Camera();
 532                 else
 533                 {
 534                         cvar_set("chase_active", ftos(chase_active_backup));
 535                         cvar_set("cl_demo_mousegrab", "0");
 536                         camera_active = FALSE;
 537                 }
 538         }
 539 #ifdef CAMERATEST
 540         else if(autocvar_camera_enable)
 541 #else
 542         else if(autocvar_camera_enable && isdemo())
 543 #endif
 544         {
 545                 // Enable required Darkplaces cvars
 546                 chase_active_backup = autocvar_chase_active;
 547                 cvar_set("chase_active", "2");
 548                 cvar_set("cl_demo_mousegrab", "1");
 549                 camera_active = TRUE;
 550                 camera_mode = FALSE;
 551         }
 552
 553         // Draw the Crosshair
 554         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 555
 556         // Draw the Engine Status Bar (the default Quake HUD)
 557         R_SetView(VF_DRAWENGINEHUD, 0);
 558
 559         // Update the mouse position
 560         /*
 561            mousepos_x = vid_conwidth;
 562            mousepos_y = vid_conheight;
 563            mousepos = mousepos*0.5 + getmousepos();
 564          */
 565
 566         e = self;
 567         for(self = world; (self = nextent(self)); )
 568                 if(self.draw)
 569                         self.draw();
 570         self = e;
 571
 572         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 573         R_RenderScene();
 574
 575         // now switch to 2D drawing mode by calling a 2D drawing function
 576         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 577         // next R_RenderScene call
 578         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 579
 580         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 581         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 582         {
 583                 // apply night vision effect
 584                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 585
 586                 if(!nightvision_noise)
 587                 {
 588                         nightvision_noise = spawn();
 589                         nightvision_noise.classname = "nightvision_noise";
 590                 }
 591                 if(!nightvision_noise2)
 592                 {
 593                         nightvision_noise2 = spawn();
 594                         nightvision_noise2.classname = "nightvision_noise2";
 595                 }
 596
 597                 // color tint in yellow
 598                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 599
 600                 // draw BG
 601                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 602                 rgb = '1 1 1';
 603                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 604                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 605                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 606                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 607                 tc_11 = tc_01 + tc_10 - tc_00;
 608                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 609                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 610                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 611                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 612                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 613                 R_EndPolygon();
 614
 615                 // draw FG
 616                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 617                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 618                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 619                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 620                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 621                 tc_11 = tc_01 + tc_10 - tc_00;
 622                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 623                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 624                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 625                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 626                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 627                 R_EndPolygon();
 628         }
 629
 630         // Draw the aiming reticle for weapons that use it
 631         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 632         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 633         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 634         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 635                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 636         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 637                 reticle_type = 2; // nex zoom
 638         else if(button_zoom || zoomscript_caught)
 639                 reticle_type = 1; // normal zoom
 640         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 641                 reticle_type = 2; // nex zoom
 642
 643         if(autocvar_cl_reticle_stretch)
 644         {
 645                 reticle_size_x = vid_conwidth;
 646                 reticle_size_y = vid_conheight;
 647                 reticle_pos_x = 0;
 648                 reticle_pos_y = 0;
 649         }
 650         else
 651         {
 652                 reticle_size_x = max(vid_conwidth, vid_conheight);
 653                 reticle_size_y = max(vid_conwidth, vid_conheight);
 654                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 655                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 656         }
 657
 658         f = current_zoomfraction;
 659         if(zoomscript_caught)
 660                 f = 1;
 661         if(autocvar_cl_reticle_item_normal)
 662         {
 663                 precache_pic("gfx/reticle_normal");
 664                 if(reticle_type == 1 && f)
 665                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 666         }
 667         if(autocvar_cl_reticle_item_nex)
 668         {
 669                 precache_pic("gfx/reticle_nex");
 670                 if(reticle_type == 2 && f)
 671                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 672         }
 673
 674
 675         // improved polyblend
 676         vector rgb;
 677         if(autocvar_hud_contents)
 678         {
 679                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 680                 vector liquidcolor;
 681
 682                 switch(pointcontents(view_origin))
 683                 {
 684                         case CONTENT_WATER:
 685                                 liquidalpha = autocvar_hud_contents_water_alpha;
 686                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 687                                 incontent = 1;
 688                                 break;
 689
 690                         case CONTENT_LAVA:
 691                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 692                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 693                                 incontent = 1;
 694                                 break;
 695
 696                         case CONTENT_SLIME:
 697                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 698                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 699                                 incontent = 1;
 700                                 break;
 701
 702                         default:
 703                                 liquidalpha = 0;
 704                                 liquidcolor = '0 0 0';
 705                                 incontent = 0;
 706                                 break;
 707                 }
 708
 709                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 710                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 711                         contentfadetime = autocvar_hud_contents_fadeintime;
 712                         liquidalpha_prev = liquidalpha;
 713                         liquidcolor_prev = liquidcolor;
 714                 }
 715                 else
 716                         contentfadetime = autocvar_hud_contents_fadeouttime;
 717
 718                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 719                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 720
 721                 if(contentavgalpha)
 722                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 723         }
 724
 725         if(autocvar_hud_damage)
 726         {
 727                 float myhealth_flash_temp;
 728                 myhealth = getstati(STAT_HEALTH);
 729
 730                 // fade out
 731                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 732                 // add new damage
 733                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 734
 735                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 736                 pain_threshold = autocvar_hud_damage_pain_threshold;
 737                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 738                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 739
 740                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 741                 {
 742                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 743                 }
 744
 745                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 746
 747                 if(myhealth_prev < 1)
 748                 {
 749                         if(myhealth >= 1)
 750                         {
 751                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 752                                 myhealth_flash_temp = 0;
 753                         }
 754                         else
 755                         {
 756                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 757                         }
 758                 }
 759
 760                 if(spectatee_status == -1 || intermission)
 761                 {
 762                         myhealth_flash = 0; // observing, or match ended
 763                         myhealth_flash_temp = 0;
 764                 }
 765
 766                 myhealth_prev = myhealth;
 767
 768                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 769                 {
 770                         if(autocvar_cl_gentle_damage == 2)
 771                         {
 772                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 773                                 {
 774                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 775                                 }
 776                         }
 777                         else
 778                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 779
 780                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 781                 }
 782                 else
 783                         drawpic(reticle_pos, "gfx/blood", reticle_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 784         }
 785
 786         // Draw the mouse cursor
 787         // NOTE: drawpic must happen after R_RenderScene for some reason
 788         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 789         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 790         //self = edict_num(player_localnum);
 791         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 792         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 793         // as long as the ctf part isn't in, this is useless
 794         if(menu_visible)
 795                 menu_show();
 796
 797         /*if(gametype == GAME_CTF)
 798           {
 799           ctf_view();
 800           } else */
 801
 802         // draw 2D entities
 803         e = self;
 804         for(self = world; (self = nextent(self)); )
 805                 if(self.draw2d)
 806                         self.draw2d();
 807         self = e;
 808
 809         scoreboard_active = HUD_WouldDrawScoreboard();
 810
 811         hit_time = getstatf(STAT_HIT_TIME);
 812         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 813         {
 814                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 815                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 816         }
 817         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 818         if(typehit_time > nextsound_typehit_time)
 819         {
 820                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 821                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 822         }
 823
 824         float hud;
 825         hud = getstati(STAT_HUD);
 826         if(hud == HUD_SPIDERBOT)
 827                 CSQC_SPIDER_HUD();
 828         else if(hud == HUD_WAKIZASHI)
 829         CSQC_WAKIZASHI_HUD();
 830     else if(hud == HUD_RAPTOR)
 831         CSQC_RAPTOR_HUD();
 832         else
 833         {
 834                 if(gametype == GAME_FREEZETAG)
 835                 {
 836                         if(getstati(STAT_FROZEN))
 837                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 838                         if(getstatf(STAT_REVIVE_PROGRESS))
 839                         {
 840                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 841                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 842                         }
 843                 }
 844
 845                 if(autocvar_r_letterbox == 0)
 846                         if(autocvar_viewsize < 120)
 847                                 CSQC_common_hud();
 848
 849                 // crosshair goes VERY LAST
 850                 if(!scoreboard_active && !camera_active && intermission != 2) {
 851                         string wcross_style;
 852                         float wcross_alpha, wcross_resolution;
 853                         wcross_style = autocvar_crosshair;
 854                         if (wcross_style == "0")
 855                                 return;
 856                         wcross_resolution = autocvar_crosshair_size;
 857                         if (wcross_resolution == 0)
 858                                 return;
 859                         wcross_alpha = autocvar_crosshair_alpha;
 860                         if (wcross_alpha == 0)
 861                                 return;
 862
 863                         // TrueAim check
 864                         float shottype;
 865                         float bullets, ring_scale;
 866                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 867                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 868                         wcross_origin_z = 0;
 869                         if(autocvar_crosshair_hittest)
 870                         {
 871                                 vector wcross_oldorigin;
 872                                 wcross_oldorigin = wcross_origin;
 873                                 shottype = TrueAimCheck();
 874                                 if(shottype == SHOTTYPE_HITWORLD)
 875                                 {
 876                                         v = wcross_origin - wcross_oldorigin;
 877                                         v_x /= vid_conwidth;
 878                                         v_y /= vid_conheight;
 879                                         if(vlen(v) > 0.01)
 880                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 881                                 }
 882                                 if(!autocvar_crosshair_hittest_showimpact)
 883                                         wcross_origin = wcross_oldorigin;
 884                         }
 885                         else
 886                                 shottype = SHOTTYPE_HITWORLD;
 887
 888                         vector wcross_color, wcross_size;
 889                         string wcross_wep, wcross_name;
 890                         float wcross_scale, wcross_blur;
 891
 892                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 893                                 e = get_weaponinfo(activeweapon);
 894                                 if (e && e.netname != "")
 895                                 {
 896                                         wcross_wep = e.netname;
 897                                         if(autocvar_crosshair_per_weapon)
 898                                         {
 899                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 900                                                 if (wcross_resolution == 0)
 901                                                         return;
 902                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 903                                                 if (wcross_alpha == 0)
 904                                                         return;
 905
 906                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 907                                                 if(wcross_style == "" || wcross_style == "0")
 908                                                         wcross_style = wcross_wep;
 909                                         }
 910                                 }
 911                         }
 912                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 913                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 914                         else if(autocvar_crosshair_color_by_health)
 915                         {
 916                                 local float x = getstati(STAT_HEALTH);
 917
 918                                 //x = red
 919                                 //y = green
 920                                 //z = blue
 921
 922                                 wcross_color_z = 0;
 923
 924                                 if(x > 200)
 925                                 {
 926                                         wcross_color_x = 0;
 927                                         wcross_color_y = 1;
 928                                 }
 929                                 else if(x > 150)
 930                                 {
 931                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 932                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 933                                 }
 934                                 else if(x > 100)
 935                                 {
 936                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 937                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 938                                         wcross_color_z = 1 - (x-100)*0.02;
 939                                 }
 940                                 else if(x > 50)
 941                                 {
 942                                         wcross_color_x = 1;
 943                                         wcross_color_y = 1;
 944                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 945                                 }
 946                                 else if(x > 20)
 947                                 {
 948                                         wcross_color_x = 1;
 949                                         wcross_color_y = (x-20)*90/27/100;
 950                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 951                                 }
 952                                 else
 953                                 {
 954                                         wcross_color_x = 1;
 955                                         wcross_color_y = 0;
 956                                 }
 957                         }
 958                         else
 959                                 wcross_color = stov(autocvar_crosshair_color);
 960
 961                         wcross_name = strcat("gfx/crosshair", wcross_style);
 962
 963                         if(autocvar_crosshair_effect_scalefade)
 964                         {
 965                                 wcross_scale = wcross_resolution;
 966                                 wcross_resolution = 1;
 967                         }
 968                         else
 969                         {
 970                                 wcross_scale = 1;
 971                         }
 972
 973                         if(autocvar_crosshair_pickup)
 974                         {
 975                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 976                                 {
 977                                         pickup_crosshair_size = 1;
 978                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 979                                 }
 980
 981                                 if(pickup_crosshair_size > 0)
 982                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 983                                 else
 984                                         pickup_crosshair_size = 0;
 985
 986                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 987                         }
 988
 989                         vector hitindication_color;
 990                         if(autocvar_crosshair_hitindication)
 991                         {
 992                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
 993                                 if(hitindication_crosshair_time < hit_time)
 994                                 {
 995                                         hitindication_crosshair_size = 1;
 996                                         hitindication_crosshair_time = hit_time;
 997                                 }
 998
 999                                 if(hitindication_crosshair_size > 0)
1000                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1001                                 else
1002                                         hitindication_crosshair_size = 0;
1003
1004                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1005                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1006                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1007                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1008                         }
1009
1010                         if(shottype == SHOTTYPE_HITENEMY)
1011                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1012                         if(shottype == SHOTTYPE_HITTEAM)
1013                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1014
1015                         f = autocvar_crosshair_effect_speed;
1016                         if(f < 0)
1017                                 f *= -2 * g_weaponswitchdelay;
1018                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1019                         {
1020                                 wcross_changedonetime = time + f;
1021                         }
1022                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1023                         {
1024                                 wcross_name_changestarttime = time;
1025                                 wcross_name_changedonetime = time + f;
1026                                 if(wcross_name_goal_prev_prev)
1027                                         strunzone(wcross_name_goal_prev_prev);
1028                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1029                                 wcross_name_goal_prev = strzone(wcross_name);
1030                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1031                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1032                                 wcross_resolution_goal_prev = wcross_resolution;
1033                         }
1034
1035                         wcross_scale_goal_prev = wcross_scale;
1036                         wcross_alpha_goal_prev = wcross_alpha;
1037                         wcross_color_goal_prev = wcross_color;
1038
1039                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1040                         {
1041                                 wcross_blur = 1;
1042                                 wcross_alpha *= 0.75;
1043                         }
1044                         else
1045                                 wcross_blur = 0;
1046                         // *_prev is at time-frametime
1047                         // * is at wcross_changedonetime+f
1048                         // what do we have at time?
1049                         if(time < wcross_changedonetime)
1050                         {
1051                                 f = frametime / (wcross_changedonetime - time + frametime);
1052                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1053                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1054                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1055                         }
1056
1057                         wcross_scale_prev = wcross_scale;
1058                         wcross_alpha_prev = wcross_alpha;
1059                         wcross_color_prev = wcross_color;
1060
1061                         wcross_scale *= 1 - autocvar__menu_alpha;
1062                         wcross_alpha *= 1 - autocvar__menu_alpha;
1063
1064                         ring_scale = autocvar_crosshair_ring_size;
1065
1066                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1067
1068                         float nex_charge, nex_chargepool;
1069                         nex_charge = getstatf(STAT_NEX_CHARGE);
1070                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1071
1072                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1073                                 nex_charge_movingavg = nex_charge;
1074
1075                         // ring around crosshair representing bullets left in camping rifle clip
1076                         if (activeweapon == WEP_SNIPERRIFLE && cr_maxbullets)
1077                         {
1078                                 bullets = getstati(STAT_BULLETS_LOADED);
1079                                 f = bound(0, bullets / cr_maxbullets, 1);
1080
1081                                 a = autocvar_crosshair_ring_sniperrifle_alpha;
1082                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1083                         }
1084                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
1085                         {
1086                                 if(nex_chargepool || use_nex_chargepool)
1087                                 {
1088                                         use_nex_chargepool = 1;
1089
1090                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1091                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1092                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_chargepool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1093                                 }
1094                                 else
1095                                 {
1096                                         // indicate how much we're charging right now with an inner circle
1097                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1098                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1099
1100                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1101                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1102                                 }
1103
1104                                 // draw the charge
1105                                 a = autocvar_crosshair_ring_nex_outer_alpha;
1106                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1107                         }
1108
1109 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1110                         do \
1111                         { \
1112                                 if(wcross_blur > 0) \
1113                                 { \
1114                                         for(i = -2; i <= 2; ++i) \
1115                                                 for(j = -2; j <= 2; ++j) \
1116                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1117                                 } \
1118                                 else \
1119                                 { \
1120                                         M(0,0,sz,wcross_name,wcross_alpha); \
1121                                 } \
1122                         } \
1123                         while(0)
1124
1125 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1126                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1127
1128 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1129                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1130
1131                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1132                         {
1133                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1134                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1135                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1136                                 f = 1 - f;
1137                         }
1138                         else
1139                         {
1140                                 f = 1;
1141                         }
1142
1143                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1144                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1145
1146                         if(autocvar_crosshair_dot)
1147             {
1148                 vector wcross_color_old;
1149                 wcross_color_old = wcross_color;
1150                 if(autocvar_crosshair_dot_color != "0")
1151                     wcross_color = stov(autocvar_crosshair_dot_color);
1152                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1153                 wcross_color = wcross_color_old;
1154             }
1155
1156                         wcross_name_alpha_goal_prev = f;
1157                 }
1158                 else
1159                 {
1160                         wcross_scale_prev = 0;
1161                         wcross_alpha_prev = 0;
1162                         wcross_scale_goal_prev = 0;
1163                         wcross_alpha_goal_prev = 0;
1164                         wcross_changedonetime = 0;
1165                         if(wcross_name_goal_prev)
1166                                 strunzone(wcross_name_goal_prev);
1167                         wcross_name_goal_prev = string_null;
1168                         if(wcross_name_goal_prev_prev)
1169                                 strunzone(wcross_name_goal_prev_prev);
1170                         wcross_name_goal_prev_prev = string_null;
1171                         wcross_name_changestarttime = 0;
1172                         wcross_name_changedonetime = 0;
1173                         wcross_name_alpha_goal_prev = 0;
1174                         wcross_name_alpha_goal_prev_prev = 0;
1175                         wcross_resolution_goal_prev = 0;
1176                         wcross_resolution_goal_prev_prev = 0;
1177                 }
1178         }
1179
1180         if(NextFrameCommand)
1181         {
1182                 localcmd("\n", NextFrameCommand, "\n");
1183                 NextFrameCommand = string_null;
1184         }
1185
1186         // we must do this check AFTER a frame was rendered, or it won't work
1187         if(cs_project_is_b0rked == 0)
1188         {
1189                 string w0, h0;
1190                 w0 = ftos(autocvar_vid_conwidth);
1191                 h0 = ftos(autocvar_vid_conheight);
1192                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1193                 //R_SetView(VF_FOV, '90 90 0');
1194                 R_SetView(VF_ORIGIN, '0 0 0');
1195                 R_SetView(VF_ANGLES, '0 0 0');
1196                 R_SetView(VF_PERSPECTIVE, 1);
1197                 makevectors('0 0 0');
1198                 vector v1, v2;
1199                 cvar_set("vid_conwidth", "800");
1200                 cvar_set("vid_conheight", "600");
1201                 v1 = cs_project(v_forward);
1202                 cvar_set("vid_conwidth", "640");
1203                 cvar_set("vid_conheight", "480");
1204                 v2 = cs_project(v_forward);
1205                 if(v1 == v2)
1206                         cs_project_is_b0rked = 1;
1207                 else
1208                         cs_project_is_b0rked = -1;
1209                 cvar_set("vid_conwidth", w0);
1210                 cvar_set("vid_conheight", h0);
1211         }
1212
1213         prev_spectatee_status = spectatee_status;
1214
1215         if(autocvar__hud_configure)
1216                 HUD_Panel_Mouse();
1217
1218         // let's reset the view back to normal for the end
1219         R_SetView(VF_MIN, '0 0 0');
1220         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1221 }
1222
1223 #define spider_h "gfx/vehicles/hud_bg.tga"
1224 #define spider_b "gfx/vehicles/sbot.tga"
1225 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1226 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1227 #define spider_s "gfx/vehicles/shiled.tga"
1228 #define spider_a1 "gfx/hud/sb_rocket.tga"
1229 #define spider_a2 "gfx/sb_bullets.tga"
1230
1231 void CSQC_SPIDER_HUD()
1232 {
1233         float rockets, reload, heat, hp, shield;
1234         vector picsize, hudloc;
1235
1236     // Fetch health & ammo stats
1237     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1238         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1239         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1240         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1241         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1242
1243     // Draw the crosshairs
1244     picsize = drawgetimagesize(SPIDER_CROSS);
1245     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1246     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1247     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1248
1249     hudloc_y =  4;
1250     hudloc_x = 4;
1251
1252     picsize = drawgetimagesize(spider_h) * 0.5;
1253     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1254
1255     picsize = drawgetimagesize(spider_a2) * 0.5;
1256     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1257
1258     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1259     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1260     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1261
1262     picsize = drawgetimagesize(spider_a1) * 0.85;
1263     if(rockets == 9)
1264     {
1265         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1266         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1267     }
1268     else
1269     {
1270         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1271         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1272     }
1273
1274     picsize = drawgetimagesize(spider_b) * 0.5;
1275     hudloc_y = 10.5;
1276     hudloc_x = 10.5;
1277
1278     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1279     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1280     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1281     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1282
1283
1284         /*
1285         // Draw health bar
1286         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1287         p = p + '0 1 0' * vid_conheight - '0 32 0';
1288         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1289         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1290         p_y += 8;
1291         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1292         p_x += 256 * hp;
1293         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1294
1295         // Draw minigun heat indicator
1296         p = '0.5 0 0' * (vid_conwidth - 256);
1297         p = p + '0 1 0' * vid_conheight - '0 34  0';
1298         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1299         p_x += 256 * (1-heat);
1300         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1301
1302
1303         // Draw rocket icons for loaded/empty tubes.
1304         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1305         pp += '0 1 0' * vid_conheight - '0 64 0';
1306         for(i = 0; i < 8; ++i)
1307         {
1308                 p = pp + '1 0 0' * (rkt_size * i);
1309                 if(rockets == 8)
1310                 {
1311                         if(floor(reload * 8) == i)
1312                         {
1313                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1314                         }
1315                         else if(i < reload * 8)
1316                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1317                         else
1318                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1319                 }
1320                 else
1321                 {
1322                         if(i < rockets)
1323                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1324                         else
1325                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1326                 }
1327         }
1328         */
1329
1330         if (scoreboard_showscores)
1331         {
1332                 HUD_DrawScoreboard();
1333                 HUD_DrawCenterPrint();
1334         }
1335
1336 }
1337
1338 #define raptor_h "gfx/vehicles/hud_bg.tga"
1339 #define raptor_b "gfx/vehicles/raptor.tga"
1340 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1341 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1342 #define raptor_s "gfx/vehicles/shiled.tga"
1343
1344 void CSQC_RAPTOR_HUD()
1345 {
1346         float reload, hp, shield, energy;
1347         vector picsize, hudloc;
1348
1349     // Fetch health & ammo stats
1350     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1351         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1352         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1353         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1354
1355     // Draw the crosshairs
1356     picsize = drawgetimagesize(SPIDER_CROSS);
1357     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1358     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1359     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1360
1361     hudloc_y =  4;
1362     hudloc_x = 4;
1363
1364     picsize = drawgetimagesize(raptor_h) * 0.5;
1365     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1366
1367     picsize = drawgetimagesize(spider_a2) * 0.5;
1368     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1369
1370     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1371     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1372     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1373
1374
1375     picsize = drawgetimagesize(spider_a1) * 0.85;
1376     if(reload == 1)
1377     {
1378         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1379         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1380     }
1381     else
1382     {
1383         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1384         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1385     }
1386
1387     picsize = drawgetimagesize(raptor_b) * 0.5;
1388     hudloc_y = 10.5;
1389     hudloc_x = 10.5;
1390
1391     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1392     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1393     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1394     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1395
1396
1397         if (scoreboard_showscores)
1398         {
1399                 HUD_DrawScoreboard();
1400                 HUD_DrawCenterPrint();
1401         }
1402
1403 }
1404
1405 #define waki_h "gfx/vehicles/hud_bg.tga"
1406 #define waki_b "gfx/vehicles/waki.tga"
1407 #define waki_e "gfx/vehicles/waki_e.tga"
1408 #define waki_g "gfx/vehicles/waki_guns.tga"
1409 #define waki_r "gfx/vehicles/waki_rockets.tga"
1410 #define waki_s "gfx/vehicles/shiled.tga"
1411
1412 #define waki_a1 "gfx/hud/sb_rocket.tga"
1413 #define waki_a2 "gfx/sb_cells.tga"
1414
1415 void CSQC_WAKIZASHI_HUD()
1416 {
1417         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1418         float health, shield, energy, rockets;
1419         vector picsize, hudloc;
1420
1421     picsize = drawgetimagesize(SPIDER_CROSS);
1422     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1423     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1424     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1425
1426 /*
1427 const float STAT_VEHICLESTAT_HEALTH  = 60;
1428 const float STAT_VEHICLESTAT_SHIELD  = 61;
1429 const float STAT_VEHICLESTAT_ENERGY  = 62;
1430 const float STAT_VEHICLESTAT_AMMO1   = 63;
1431 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1432 const float STAT_VEHICLESTAT_AMMO2   = 65;
1433 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1434 */
1435     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1436         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1437         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1438         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1439
1440     hudloc_y =  4;
1441     hudloc_x = 4;
1442
1443     picsize = drawgetimagesize(waki_h) * 0.5;
1444     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1445
1446     picsize = drawgetimagesize(waki_a2) * 0.7;
1447     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1448
1449
1450     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1451     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1452
1453     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1454
1455     picsize = drawgetimagesize(waki_a1) * 0.75;
1456     if(rockets == 1)
1457     {
1458         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1459         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1460     }
1461     else
1462     {
1463         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1464         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1465         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1466     }
1467
1468     picsize = drawgetimagesize(waki_b) * 0.5;
1469     hudloc_y = 10.5;
1470     hudloc_x = 10.5;
1471
1472     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1473     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1474     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1475     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1476
1477
1478
1479         /*
1480         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1481         p = p + '0 1 0' * vid_conheight - '0 32 0';
1482
1483         // Draw health bar
1484         p_y += 8;
1485         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1486         p_x += 256 * health;
1487         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1488
1489         // Draw shiled bar
1490         p_x -= 256 * health;
1491         p_y += 4;
1492         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1493
1494         // Draw energy
1495         //p_x -= 256 * health;
1496         p_y -= 8;
1497         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1498
1499         // Draw rockets bar
1500         p_y += 12;
1501         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1502         */
1503
1504
1505
1506
1507         if (scoreboard_showscores)
1508         {
1509                 HUD_DrawScoreboard();
1510                 HUD_DrawCenterPrint();
1511         }
1512
1513 }
1514
1515
1516 void CSQC_common_hud(void)
1517 {
1518         // HUD_SortFrags(); done in HUD_Draw
1519         float hud;
1520         hud = getstati(STAT_HUD);
1521
1522         //hud = 10;
1523         switch(hud)
1524         {
1525                 case HUD_NORMAL:
1526                         // do some accuracy var caching
1527                         float i;
1528                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1529                         {
1530                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1531                                 {
1532                                         if(acc_color_levels)
1533                                                 strunzone(acc_color_levels);
1534                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1535                                         acc_levels = tokenize(acc_color_levels);
1536                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1537                                                 acc_levels = MAX_ACCURACY_LEVELS;
1538
1539                                         for (i = 0; i < acc_levels; ++i)
1540                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1541                                 }
1542                                 // let know that acc_col[] needs to be loaded
1543                                 acc_col_x[0] = -1;
1544                         }
1545
1546                         HUD_Main(); // always run these functions for alpha checks
1547                         HUD_DrawScoreboard();
1548
1549                         if (scoreboard_active) // scoreboard/accuracy
1550                         {
1551                                 HUD_Reset();
1552                                 // HUD_DrawScoreboard takes care of centerprint_start
1553                         }
1554                         else if (intermission == 2) // map voting screen
1555                         {
1556                                 HUD_FinaleOverlay();
1557                                 HUD_Reset();
1558
1559                                 centerprint_start_x = 0;
1560                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1561                         }
1562                         else // hud
1563                         {
1564                                 centerprint_start_x = 0;
1565                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1566                         }
1567
1568                         HUD_DrawCenterPrint();
1569                         break;
1570
1571                 case HUD_SPIDERBOT:
1572                         CSQC_SPIDER_HUD();
1573                         break;
1574
1575                 case HUD_WAKIZASHI:
1576                         CSQC_WAKIZASHI_HUD();
1577                         break;
1578         }
1579 }
1580
1581
1582 // following vectors must be global to allow seamless switching between camera modes
1583 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1584 void CSQC_Demo_Camera()
1585 {
1586         float speed, attenuation, dimensions;
1587         vector tmp, delta;
1588
1589         if( autocvar_camera_reset || !camera_mode )
1590         {
1591                 camera_offset = '0 0 0';
1592                 current_angles = '0 0 0';
1593                 camera_direction = '0 0 0';
1594                 camera_offset_z += 30;
1595                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1596                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1597                 current_origin = view_origin;
1598                 current_camera_offset  = camera_offset;
1599                 cvar_set("camera_reset", "0");
1600                 camera_mode = CAMERA_CHASE;
1601         }
1602
1603         // Camera angles
1604         if( camera_roll )
1605                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1606
1607         if(autocvar_camera_look_player)
1608         {
1609                 local vector dir;
1610                 local float n;
1611
1612                 dir = normalize(view_origin - current_position);
1613                 n = mouse_angles_z;
1614                 mouse_angles = vectoangles(dir);
1615                 mouse_angles_x = mouse_angles_x * -1;
1616                 mouse_angles_z = n;
1617         }
1618         else
1619         {
1620                 tmp = getmousepos() * 0.1;
1621                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1622                 {
1623                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1624                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1625                 }
1626         }
1627
1628         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1629         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1630         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1631         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1632
1633         // Fix difference when angles don't have the same sign
1634         delta = '0 0 0';
1635         if(mouse_angles_y < -60 && current_angles_y > 60)
1636                 delta = '0 360 0';
1637         if(mouse_angles_y > 60 && current_angles_y < -60)
1638                 delta = '0 -360 0';
1639
1640         if(autocvar_camera_look_player)
1641                 attenuation = autocvar_camera_look_attenuation;
1642         else
1643                 attenuation = autocvar_camera_speed_attenuation;
1644
1645         attenuation = 1 / max(1, attenuation);
1646         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1647
1648         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1649         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1650         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1651         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1652
1653         // Camera position
1654         tmp = '0 0 0';
1655         dimensions = 0;
1656
1657         if( camera_direction_x )
1658         {
1659                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1660                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1661                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1662                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1663                 ++dimensions;
1664         }
1665
1666         if( camera_direction_y )
1667         {
1668                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1669                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1670                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1671                 ++dimensions;
1672         }
1673
1674         if( camera_direction_z )
1675         {
1676                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1677                 ++dimensions;
1678         }
1679
1680         if(autocvar_camera_free)
1681                 speed = autocvar_camera_speed_free;
1682         else
1683                 speed = autocvar_camera_speed_chase;
1684
1685         if(dimensions)
1686         {
1687                 speed = speed * sqrt(1 / dimensions);
1688                 camera_offset += tmp * speed;
1689         }
1690
1691         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1692
1693         // Camera modes
1694         if( autocvar_camera_free )
1695         {
1696                 if ( camera_mode == CAMERA_CHASE )
1697                 {
1698                         current_camera_offset = current_origin + current_camera_offset;
1699                         camera_offset = current_origin + camera_offset;
1700                 }
1701
1702                 camera_mode = CAMERA_FREE;
1703                 current_position = current_camera_offset;
1704         }
1705         else
1706         {
1707                 if ( camera_mode == CAMERA_FREE )
1708                 {
1709                         current_origin = view_origin;
1710                         camera_offset = camera_offset - current_origin;
1711                         current_camera_offset = current_camera_offset - current_origin;
1712                 }
1713
1714                 camera_mode = CAMERA_CHASE;
1715
1716                 if(autocvar_camera_chase_smoothly)
1717                         current_origin += (view_origin - current_origin) * attenuation;
1718                 else
1719                         current_origin = view_origin;
1720
1721                 current_position = current_origin + current_camera_offset;
1722         }
1723
1724         R_SetView(VF_ANGLES, current_angles);
1725         R_SetView(VF_ORIGIN, current_position);
1726 }