qcsrc/client/command/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 #include "../../common/command/command.qh"
   7 #include "cl_cmd.qh"
   8
   9 #include "../autocvars.qh"
  10 #include "../defs.qh"
  11 #include "../hud.qh"
  12 #include "../hud_config.qh"
  13 #include "../main.qh"
  14 #include "../mapvoting.qh"
  15 #include "../miscfunctions.qh"
  16
  17 #include "../mutators/events.qh"
  18
  19 #include "../../common/mapinfo.qh"
  20
  21 #include "../../common/command/generic.qh"
  22
  23 void DrawDebugModel()
  24 {
  25         if(time - floor(time) > 0.5)
  26         {
  27                 PolyDrawModel(self);
  28                 self.drawmask = 0;
  29         }
  30         else
  31         {
  32                 self.renderflags = 0;
  33                 self.drawmask = MASK_NORMAL;
  34         }
  35 }
  36
  37
  38 // =======================
  39 //  Command Sub-Functions
  40 // =======================
  41
  42 void LocalCommand_blurtest(int request)
  43 {
  44         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  45         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  46
  47         #ifdef BLURTEST
  48         switch(request)
  49         {
  50                 case CMD_REQUEST_COMMAND:
  51                 {
  52                         blurtest_time0 = time;
  53                         blurtest_time1 = time + stof(argv(1));
  54                         blurtest_radius = stof(argv(2));
  55                         blurtest_power = stof(argv(3));
  56                         print("Enabled blurtest\n");
  57                         return;
  58                 }
  59
  60                 default:
  61                 case CMD_REQUEST_USAGE:
  62                 {
  63                         print("\nUsage:^3 cl_cmd blurtest\n");
  64                         print("  No arguments required.\n");
  65                         return;
  66                 }
  67         }
  68         #else
  69         if(request)
  70         {
  71                 print("Blurtest is not enabled on this client.\n");
  72                 return;
  73         }
  74         #endif
  75 }
  76
  77 void LocalCommand_boxparticles(int request, int argc)
  78 {
  79         switch(request)
  80         {
  81                 case CMD_REQUEST_COMMAND:
  82                 {
  83                         if (argc == 9)
  84                         {
  85                                 int effect = particleeffectnum(argv(1));
  86                                 if (effect >= 0)
  87                                 {
  88                                         int index = stoi(argv(2));
  89                                         entity own;
  90                                         if(index <= 0)
  91                                                 own = entitybyindex(-index);
  92                                         else
  93                                                 own = findfloat(world, entnum, index);
  94                                         vector org_from = stov(argv(3));
  95                                         vector org_to = stov(argv(4));
  96                                         vector dir_from = stov(argv(5));
  97                                         vector dir_to = stov(argv(6));
  98                                         int countmultiplier = stoi(argv(7));
  99                                         int flags = stoi(argv(8));
 100                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
 101                                         return;
 102                                 }
 103                         }
 104                 }
 105
 106                 default:
 107                         print("Incorrect parameters for ^2boxparticles^7\n");
 108                 case CMD_REQUEST_USAGE:
 109                 {
 110                         print("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
 111                         print("  'effectname' is the name of a particle effect in effectinfo.txt\n");
 112                         print("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
 113                         print("  'org_from' is the starting origin of the box\n");
 114                         print("  'org_to' is the ending origin of the box\n");
 115                         print("  'dir_from' is the minimum velocity\n");
 116                         print("  'dir_to' is the maximum velocity\n");
 117                         print("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 118                         print("  'flags' can contain:\n");
 119                         print("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 120                         print("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 121                         print("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 122                         print("    128 to draw a trail, not a box\n");
 123                         return;
 124                 }
 125         }
 126 }
 127
 128 void LocalCommand_create_scrshot_ent(int request)
 129 {
 130         switch(request)
 131         {
 132                 case CMD_REQUEST_COMMAND:
 133                 {
 134                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 135                         int fh = fopen(filename, FILE_WRITE);
 136
 137                         if(fh >= 0)
 138                         {
 139                                 fputs(fh, "{\n");
 140                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 141                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 142                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 143                                 fputs(fh, "}\n");
 144
 145                                 print("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 146
 147                                 fclose(fh);
 148                         }
 149                         else
 150                         {
 151                                 print("^1Error: ^7Could not dump to file!\n");
 152                         }
 153                         return;
 154                 }
 155
 156                 default:
 157                 case CMD_REQUEST_USAGE:
 158                 {
 159                         print("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 160                         print("  No arguments required.\n");
 161                         return;
 162                 }
 163         }
 164 }
 165
 166 void LocalCommand_debugmodel(int request, int argc)
 167 {
 168         switch(request)
 169         {
 170                 case CMD_REQUEST_COMMAND:
 171                 {
 172                         string modelname = argv(1);
 173                         entity debugmodel_entity;
 174
 175                         debugmodel_entity = spawn();
 176                         precache_model(modelname);
 177                         setmodel(debugmodel_entity, modelname);
 178                         setorigin(debugmodel_entity, view_origin);
 179                         debugmodel_entity.angles = view_angles;
 180                         debugmodel_entity.draw = DrawDebugModel;
 181                         debugmodel_entity.classname = "debugmodel";
 182
 183                         return;
 184                 }
 185
 186                 default:
 187                 case CMD_REQUEST_USAGE:
 188                 {
 189                         print("\nUsage:^3 cl_cmd debugmodel model\n");
 190                         print("  Where 'model' is a string of the model name to use for the debug model.\n");
 191                         return;
 192                 }
 193         }
 194 }
 195
 196 void LocalCommand_handlevote(int request, int argc)
 197 {
 198         switch(request)
 199         {
 200                 case CMD_REQUEST_COMMAND:
 201                 {
 202                         int vote_selection;
 203                         string vote_string;
 204
 205                         if(InterpretBoolean(argv(1)))
 206                         {
 207                                 vote_selection = 2;
 208                                 vote_string = "yes";
 209                         }
 210                         else
 211                         {
 212                                 vote_selection = 1;
 213                                 vote_string = "no";
 214                         }
 215
 216                         if(vote_selection)
 217                         {
 218                                 if(uid2name_dialog) // handled by "uid2name" option
 219                                 {
 220                                         vote_active = 0;
 221                                         vote_prev = 0;
 222                                         vote_change = -9999;
 223                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 224                                         uid2name_dialog = 0;
 225                                 }
 226                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 227
 228                                 return;
 229                         }
 230                 }
 231
 232                 default:
 233                         print("Incorrect parameters for ^2handlevote^7\n");
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         print("\nUsage:^3 cl_cmd handlevote vote\n");
 237                         print("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 void LocalCommand_hud(int request, int argc)
 244 {
 245         switch(request)
 246         {
 247                 case CMD_REQUEST_COMMAND:
 248                 {
 249                         switch(argv(1))
 250                         {
 251                                 case "configure":
 252                                 {
 253                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 254                                         return;
 255                                 }
 256
 257                                 case "save":
 258                                 {
 259                                         if(argv(2))
 260                                         {
 261                                                 HUD_Panel_ExportCfg(argv(2));
 262                                                 return;
 263                                         }
 264                                         else
 265                                         {
 266                                                 break; // go to usage, we're missing the paramater needed here.
 267                                         }
 268                                 }
 269
 270                                 case "scoreboard_columns_set":
 271                                 {
 272                                         Cmd_HUD_SetFields(argc);
 273                                         return;
 274                                 }
 275
 276                                 case "scoreboard_columns_help":
 277                                 {
 278                                         Cmd_HUD_Help();
 279                                         return;
 280                                 }
 281
 282                                 case "radar":
 283                                 {
 284                                         if(argv(2))
 285                                                 hud_panel_radar_maximized = InterpretBoolean(argv(2));
 286                                         else
 287                                                 hud_panel_radar_maximized = !hud_panel_radar_maximized;
 288                                         return;
 289                                 }
 290                         }
 291                 }
 292
 293                 default:
 294                         print("Incorrect parameters for ^2hud^7\n");
 295                 case CMD_REQUEST_USAGE:
 296                 {
 297                         print("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 298                         print("  Where 'action' is the command to complete,\n");
 299                         print("  'configname' is the name to save to for \"save\" action,\n");
 300                         print("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 301                         print("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 302                         print("  Full list of commands here: \"configure, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 303                         return;
 304                 }
 305         }
 306 }
 307
 308 void LocalCommand_localprint(int request, int argc)
 309 {
 310         switch(request)
 311         {
 312                 case CMD_REQUEST_COMMAND:
 313                 {
 314                         if(argv(1))
 315                         {
 316                                 centerprint_hud(argv(1));
 317                                 return;
 318                         }
 319                 }
 320
 321                 default:
 322                         print("Incorrect parameters for ^2localprint^7\n");
 323                 case CMD_REQUEST_USAGE:
 324                 {
 325                         print("\nUsage:^3 cl_cmd localprint \"message\"\n");
 326                         print("  'message' is the centerprint message to send to yourself.\n");
 327                         return;
 328                 }
 329         }
 330 }
 331
 332 void LocalCommand_mv_download(int request, int argc)
 333 {
 334         switch(request)
 335         {
 336                 case CMD_REQUEST_COMMAND:
 337                 {
 338                         if(argv(1))
 339                         {
 340                                 Cmd_MapVote_MapDownload(argc);
 341                                 return;
 342                         }
 343                 }
 344
 345                 default:
 346                         print("Incorrect parameters for ^2mv_download^7\n");
 347                 case CMD_REQUEST_USAGE:
 348                 {
 349                         print("\nUsage:^3 cl_cmd mv_download mapid\n");
 350                         print("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 351                         return;
 352                 }
 353         }
 354 }
 355
 356 void LocalCommand_find(int request, int argc)
 357 {
 358         switch(request)
 359         {
 360                 case CMD_REQUEST_COMMAND:
 361                 {
 362                         entity client;
 363
 364                         for(client = world; (client = find(client, classname, argv(1))); )
 365                                 print(etos(client), "\n");
 366
 367                         return;
 368                 }
 369
 370                 default:
 371                         print("Incorrect parameters for ^2find^7\n");
 372                 case CMD_REQUEST_USAGE:
 373                 {
 374                         print("\nUsage:^3 cl_cmd find classname\n");
 375                         print("  Where 'classname' is the classname to search for.\n");
 376                         return;
 377                 }
 378         }
 379 }
 380
 381 void LocalCommand_sendcvar(int request, int argc)
 382 {
 383         switch(request)
 384         {
 385                 case CMD_REQUEST_COMMAND:
 386                 {
 387                         if(argv(1))
 388                         {
 389                                 // W_FixWeaponOrder will trash argv, so save what we need.
 390                                 string thiscvar = strzone(argv(1));
 391                                 string s = cvar_string(thiscvar);
 392
 393                                 if(thiscvar == "cl_weaponpriority")
 394                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 395                                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 396                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 397
 398                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 399                                 strunzone(thiscvar);
 400                                 return;
 401                         }
 402                 }
 403
 404                 default:
 405                         print("Incorrect parameters for ^2sendcvar^7\n");
 406                 case CMD_REQUEST_USAGE:
 407                 {
 408                         print("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 409                         print("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 410                         return;
 411                 }
 412         }
 413 }
 414
 415 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 416 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 417 void LocalCommand_(int request)
 418 {
 419         switch(request)
 420         {
 421                 case CMD_REQUEST_COMMAND:
 422                 {
 423
 424                         return;
 425                 }
 426
 427                 default:
 428                 case CMD_REQUEST_USAGE:
 429                 {
 430                         print("\nUsage:^3 cl_cmd \n");
 431                         print("  No arguments required.\n");
 432                         return;
 433                 }
 434         }
 435 }
 436 */
 437
 438
 439 // ==================================
 440 //  Macro system for client commands
 441 // ==================================
 442
 443 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 444 #define CLIENT_COMMANDS(request,arguments) \
 445         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 446         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 447         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 448         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 449         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 450         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 451         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 452         CLIENT_COMMAND("find", LocalCommand_find(request, arguments), "Search through entities for matching classname") \
 453         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 454         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 455         /* nothing */
 456
 457 void LocalCommand_macro_help()
 458 {
 459         #define CLIENT_COMMAND(name,function,description) \
 460                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 461
 462         CLIENT_COMMANDS(0, 0);
 463         #undef CLIENT_COMMAND
 464
 465         return;
 466 }
 467
 468 bool LocalCommand_macro_command(int argc)
 469 {
 470         #define CLIENT_COMMAND(name,function,description) \
 471                 { if(name == strtolower(argv(0))) { function; return true; } }
 472
 473         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc);
 474         #undef CLIENT_COMMAND
 475
 476         return false;
 477 }
 478
 479 bool LocalCommand_macro_usage(int argc)
 480 {
 481         #define CLIENT_COMMAND(name,function,description) \
 482                 { if(name == strtolower(argv(1))) { function; return true; } }
 483
 484         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc);
 485         #undef CLIENT_COMMAND
 486
 487         return false;
 488 }
 489
 490 void LocalCommand_macro_write_aliases(int fh)
 491 {
 492         #define CLIENT_COMMAND(name,function,description) \
 493                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 494
 495         CLIENT_COMMANDS(0, 0);
 496         #undef CLIENT_COMMAND
 497
 498         return;
 499 }
 500
 501
 502 // =========================================
 503 //  Main Function Called By Engine (cl_cmd)
 504 // =========================================
 505 // If this function exists, client code handles gamecommand instead of the engine code.
 506
 507 void GameCommand(string command)
 508 {
 509         int argc = tokenize_console(command);
 510
 511         // Guide for working with argc arguments by example:
 512         // argc:   1    - 2      - 3     - 4
 513         // argv:   0    - 1      - 2     - 3
 514         // cmd     vote - master - login - password
 515         string s = strtolower(argv(0));
 516         if (s == "help")
 517         {
 518                 if(argc == 1)
 519                 {
 520                         print("\nClient console commands:\n");
 521                         LocalCommand_macro_help();
 522
 523                         print("\nGeneric commands shared by all programs:\n");
 524                         GenericCommand_macro_help();
 525
 526                         print("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 527                         print("For help about a specific command, type cl_cmd help COMMAND\n");
 528
 529                         return;
 530                 }
 531                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 532                 {
 533                         return;
 534                 }
 535                 else if(LocalCommand_macro_usage(argc)) // now try for normal commands too
 536                 {
 537                         return;
 538                 }
 539         }
 540         // continue as usual and scan for normal commands
 541         if (GenericCommand(command)// handled by common/command/generic.qc
 542         || LocalCommand_macro_command(argc) // handled by one of the above LocalCommand_* functions
 543         || MUTATOR_CALLHOOK(CSQC_ConsoleCommand, s, argc, command) // handled by a mutator
 544         ) return;
 545
 546         // nothing above caught the command, must be invalid
 547         print(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 548
 549         return;
 550 }
 551
 552
 553 // ===================================
 554 //  Macro system for console commands
 555 // ===================================
 556
 557 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 558 // Please add client commands to the function above this, as this is only for special reasons.
 559 #define CONSOLE_COMMANDS_NORMAL() \
 560         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 561         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 562         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 563         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 564         /* nothing */
 565
 566 #define CONSOLE_COMMANDS_MOVEMENT() \
 567         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 568         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 569         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 570         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 571         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 572         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 573         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 574         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 575         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 576         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 577         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 578         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 579         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 580         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 581         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 582         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 583         /* nothing */
 584
 585 void ConsoleCommand_macro_init()
 586 {
 587         // first init normal commands
 588         #define CONSOLE_COMMAND(name,execution) \
 589                 { registercommand(name); }
 590
 591         CONSOLE_COMMANDS_NORMAL();
 592         #undef CONSOLE_COMMAND
 593
 594         // then init movement commands
 595         #ifndef CAMERATEST
 596         if(isdemo())
 597         {
 598         #endif
 599                 #define CONSOLE_COMMAND(name,execution) \
 600                         { registercommand(name); }
 601
 602                 CONSOLE_COMMANDS_MOVEMENT();
 603                 #undef CONSOLE_COMMAND
 604         #ifndef CAMERATEST
 605         }
 606         #endif
 607 }
 608
 609 bool ConsoleCommand_macro_normal(string s, int argc)
 610 {
 611         #define CONSOLE_COMMAND(name,execution) \
 612                 { if (name == s) { { execution } return true; } }
 613
 614         CONSOLE_COMMANDS_NORMAL();
 615         #undef CONSOLE_COMMAND
 616
 617         return false;
 618 }
 619
 620 bool ConsoleCommand_macro_movement(string s, int argc)
 621 {
 622         if(camera_active)
 623         {
 624                 #define CONSOLE_COMMAND(name,execution) \
 625                         { if (name == s) { { execution } return true; } }
 626
 627                 CONSOLE_COMMANDS_MOVEMENT();
 628                 #undef CONSOLE_COMMAND
 629         }
 630
 631         return false;
 632 }
 633
 634
 635 // ======================================================
 636 //  Main Function Called By Engine (registered commands)
 637 // ======================================================
 638 // Used to parse commands in the console that have been registered with the "registercommand" function
 639
 640 bool CSQC_ConsoleCommand(string command)
 641 {
 642         int argc = tokenize_console(command);
 643         string s = strtolower(argv(0));
 644         // Return value should be true if CSQC handled the command, otherwise return false to have the engine handle it.
 645         return (ConsoleCommand_macro_normal(s, argc)
 646         || ConsoleCommand_macro_movement(s, argc)
 647         );
 648 }