qcsrc/client/csqcmodel_hooks.qc

   1 .float isplayermodel;
   2
   3 // FEATURE: LOD
   4 .float lodmodelindex0;
   5 .float lodmodelindex1;
   6 .float lodmodelindex2;
   7 void CSQCPlayer_LOD_Apply(void)
   8 {
   9         // LOD model loading
  10         if(self.lodmodelindex0 != self.modelindex)
  11         {
  12                 string modelname = self.model;
  13                 string s;
  14
  15                 if(!fexists(modelname))
  16                 {
  17                         print(sprintf(_("Trying to use non existing model %s. "), modelname));
  18                         modelname = cvar_defstring("_cl_playermodel");
  19                         print(sprintf(_("Reverted to %s.\n"), modelname));
  20                 }
  21
  22                 // set modelindex
  23                 self.lodmodelindex0 = self.modelindex;
  24                 self.lodmodelindex1 = self.modelindex;
  25                 self.lodmodelindex2 = self.modelindex;
  26
  27                 // FIXME: this only supports 3-letter extensions
  28                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  29                 if(fexists(s))
  30                 {
  31                         precache_model(s);
  32                         setmodel(self, s);
  33                         if(self.modelindex)
  34                                 self.lodmodelindex1 = self.modelindex;
  35                 }
  36
  37                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  38                 if(fexists(s))
  39                 {
  40                         precache_model(s);
  41                         setmodel(self, s);
  42                         if(self.modelindex)
  43                                 self.lodmodelindex2 = self.modelindex;
  44                 }
  45
  46                 setmodel(self, modelname); // make everything normal again
  47         }
  48
  49         // apply LOD
  50         if(autocvar_cl_playerdetailreduction <= 0)
  51         {
  52                 if(autocvar_cl_playerdetailreduction <= -2)
  53                         self.modelindex = self.lodmodelindex2;
  54                 else if(autocvar_cl_playerdetailreduction <= -1)
  55                         self.modelindex = self.lodmodelindex1;
  56                 else
  57                         self.modelindex = self.lodmodelindex0;
  58         }
  59         else
  60         {
  61                 float distance = vlen(self.origin - other.origin);
  62                 float f = (distance + 100.0) * autocvar_cl_playerdetailreduction;
  63                 f *= 1.0 / bound(0.01, view_quality, 1);
  64                 if(f > autocvar_cl_loddistance2)
  65                         self.modelindex = self.lodmodelindex2;
  66                 else if(f > autocvar_cl_loddistance1)
  67                         self.modelindex = self.lodmodelindex1;
  68                 else
  69                         self.modelindex = self.lodmodelindex0;
  70         }
  71 }
  72
  73 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  74 string forceplayermodels_model;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77 float forceplayermodels_attempted;
  78 .string forceplayermodels_savemodel;
  79 .float forceplayermodels_savemodelindex;
  80 .float forceplayermodels_saveskin;
  81 void CSQCPlayer_ForceModel_PreUpdate(void)
  82 {
  83         self.model = self.forceplayermodels_savemodel;
  84         self.modelindex = self.forceplayermodels_savemodelindex;
  85         self.skin = self.forceplayermodels_saveskin;
  86 }
  87 void CSQCPlayer_ForceModel_PostUpdate(void)
  88 {
  89         self.forceplayermodels_savemodel = self.model;
  90         self.forceplayermodels_savemodelindex = self.modelindex;
  91         self.forceplayermodels_saveskin = self.skin;
  92 }
  93 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
  94 {
  95         // first, try finding it from the server
  96
  97         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
  98         {
  99                 if(islocalplayer)
 100                 {
 101                         // trust server's idea of "own player model"
 102                         forceplayermodels_model = self.model;
 103                         forceplayermodels_modelindex = self.modelindex;
 104                         forceplayermodels_skin = self.skin;
 105                         forceplayermodels_attempted = 1;
 106                 }
 107         }
 108
 109         // forcemodel finding
 110         if(!forceplayermodels_attempted)
 111         {
 112                 // only if this failed, find it out on our own
 113                 entity e;
 114                 e = spawn();
 115                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 116                 forceplayermodels_model = e.model;
 117                 forceplayermodels_modelindex = e.modelindex;
 118                 forceplayermodels_skin = autocvar__cl_playerskin;
 119                 forceplayermodels_attempted = 1;
 120                 remove(e);
 121         }
 122
 123         // apply it
 124         if(autocvar_cl_forceplayermodels && forceplayermodels_modelindex)
 125         {
 126                 self.model = forceplayermodels_model;
 127                 self.modelindex = forceplayermodels_modelindex;
 128                 self.skin = forceplayermodels_skin;
 129         }
 130         else
 131         {
 132                 self.model = self.forceplayermodels_savemodel;
 133                 self.modelindex = self.forceplayermodels_savemodelindex;
 134                 self.skin = self.forceplayermodels_saveskin;
 135         }
 136 }
 137
 138 // FEATURE: fallback frames
 139 .float csqcmodel_saveframe;
 140 .float csqcmodel_saveframe2;
 141 .float csqcmodel_saveframe3;
 142 .float csqcmodel_saveframe4;
 143 .float csqcmodel_framecount;
 144 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 145 {
 146         self.frame = self.csqcmodel_saveframe;
 147         self.frame2 = self.csqcmodel_saveframe2;
 148         self.frame3 = self.csqcmodel_saveframe3;
 149         self.frame4 = self.csqcmodel_saveframe4;
 150 }
 151 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 152 {
 153         self.csqcmodel_saveframe = self.frame;
 154         self.csqcmodel_saveframe2 = self.frame2;
 155         self.csqcmodel_saveframe3 = self.frame3;
 156         self.csqcmodel_saveframe4 = self.frame4;
 157
 158         // hack for death animations: set their frametime to zero in case a
 159         // player "pops in"
 160         if(isnew)
 161         {
 162 #define FIX_FRAMETIME(f,ft) \
 163                 switch(self.f) \
 164                 { \
 165                         case 0: \
 166                         case 1: \
 167                                 self.ft = 0; \
 168                                 break; \
 169                 }
 170                 FIX_FRAMETIME(frame, frame1time)
 171                 FIX_FRAMETIME(frame2, frame2time)
 172                 FIX_FRAMETIME(frame3, frame3time)
 173                 FIX_FRAMETIME(frame4, frame4time)
 174         }
 175 }
 176 float CSQCPlayer_FallbackFrame(float f)
 177 {
 178         if(frameduration(self.modelindex, f) > 0)
 179                 return f; // goooooood
 180         switch(f)
 181         {
 182                 case 23: return 11; // anim_melee -> anim_shoot
 183                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 184                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 185                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 186                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 187                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 188                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 189                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 190         }
 191         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 192         return f;
 193 }
 194 void CSQCPlayer_FallbackFrame_Apply(void)
 195 {
 196         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 197         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 198         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 199         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 200 }
 201
 202 // FEATURE: auto glowmod
 203 .vector glowmod;
 204 void CSQCPlayer_GlowMod_Apply(void)
 205 {
 206         if(self.colormap > 0)
 207                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 208         else
 209                 self.glowmod = '1 1 1';
 210 }
 211
 212 // FEATURE: auto tag_index
 213 .entity tag_entity;
 214 .float tag_entity_lastmodelindex;
 215 .float tag_index;
 216 void CSQCModel_AutoTagIndex_Apply(void)
 217 {
 218         if(self.tag_entity && wasfreed(self.tag_entity))
 219                 self.tag_entity = world;
 220
 221         if(self.tag_networkentity)
 222         {
 223                 // we are ATTACHED!
 224                 float changed = 0;
 225                 if(self.tag_entity.entnum != self.tag_networkentity)
 226                 {
 227                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 228                         changed = 1;
 229                 }
 230                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 231                 {
 232                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 233                         changed = 1;
 234                 }
 235                 if(changed)
 236                 {
 237                         if(self.tag_entity)
 238                         {
 239                                 // the best part is: IT EXISTS
 240                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 241                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 242                                         {
 243                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 244                                                 if(!self.tag_index)
 245                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 246                                                 if(!self.tag_index)
 247                                                 {
 248                                                         // we need to prevent this from 'appening
 249                                                         self.tag_entity = world;
 250                                                         self.drawmask = 0;
 251                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 252                                                 }
 253                                         }
 254
 255                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 256                                         if(substring(self.tag_entity.model, 0, 14) == "models/player/")
 257                                         {
 258                                                 self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 259                                                 if(!self.tag_index)
 260                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 261                                         }
 262
 263                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 264                                 {
 265                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 266                                         if(!self.tag_index)
 267                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 268                                 }
 269                         }
 270                         else
 271                         {
 272                                 // damn, see you next frame
 273                                 self.drawmask = 0;
 274                         }
 275                 }
 276         }
 277 }
 278
 279 // FEATURE: EF_NODRAW workalike
 280 float EF_BRIGHTFIELD    = 1;
 281 float EF_BRIGHTLIGHT    = 4;
 282 float EF_DIMLIGHT       = 8;
 283 float EF_DOUBLESIDED = 32768;
 284 float EF_NOSELFSHADOW = 65536;
 285 float MF_ROCKET  =   1; // leave a trail
 286 float MF_GRENADE =   2; // leave a trail
 287 float MF_GIB     =   4; // leave a trail
 288 float MF_ROTATE  =   8; // rotate (bonus items)
 289 float MF_TRACER  =  16; // green split trail
 290 float MF_ZOMGIB  =  32; // small blood trail
 291 float MF_TRACER2 =  64; // orange split trail
 292 float MF_TRACER3 = 128; // purple trail
 293 .float csqcmodel_effects;
 294 .float csqcmodel_modelflags;
 295 void CSQCModel_Effects_PreUpdate(void)
 296 {
 297         self.effects = self.csqcmodel_effects;
 298         self.modelflags = self.csqcmodel_modelflags;
 299 }
 300 void CSQCModel_Effects_PostUpdate(void)
 301 {
 302         self.csqcmodel_effects = self.effects;
 303         self.csqcmodel_modelflags = self.modelflags;
 304         self.effects = 0;
 305         self.modelflags = 0;
 306         if(self.csqcmodel_teleported)
 307                 Projectile_ResetTrail(self.origin);
 308 }
 309 void CSQCModel_Effects_Apply(void)
 310 {
 311         float eff = self.csqcmodel_effects;
 312         eff &~= CSQCMODEL_EF_INVISIBLE;
 313
 314         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 315         self.effects = 0;
 316         self.traileffect = 0;
 317
 318         if(eff & EF_BRIGHTFIELD)
 319                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 320         // ignoring EF_MUZZLEFLASH
 321         if(eff & EF_BRIGHTLIGHT)
 322                 adddynamiclight(self.origin, 400, '3 3 3');
 323         if(eff & EF_DIMLIGHT)
 324                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 325         if((eff & EF_NODRAW) || (self.csqcmodel_effects & CSQCMODEL_EF_INVISIBLE) || (self.alpha < 0))
 326                 self.drawmask = 0;
 327         if(eff & EF_ADDITIVE)
 328                 self.renderflags |= RF_ADDITIVE;
 329         if(eff & EF_BLUE)
 330                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 331         if(eff & EF_RED)
 332                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 333         // ignoring EF_NOGUNBOB
 334         if(eff & EF_FULLBRIGHT)
 335                 self.renderflags |= RF_FULLBRIGHT;
 336         if(eff & EF_FLAME)
 337                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 338         if(eff & EF_STARDUST)
 339                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 340         if(eff & EF_NOSHADOW)
 341                 self.renderflags |= RF_NOSHADOW;
 342         if(eff & EF_NODEPTHTEST)
 343                 self.renderflags |= RF_DEPTHHACK;
 344         // ignoring EF_SELECTABLE
 345         if(eff & EF_DOUBLESIDED)
 346                 self.effects |= EF_DOUBLESIDED;
 347         if(eff & EF_NOSELFSHADOW)
 348                 self.effects |= EF_NOSELFSHADOW;
 349         // ignoring EF_UNUSED17, EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 350         if(self.csqcmodel_modelflags & MF_ROCKET)
 351                 self.traileffect = particleeffectnum("TR_ROCKET");
 352         if(self.csqcmodel_modelflags & MF_GRENADE)
 353                 self.traileffect = particleeffectnum("TR_GRENADE");
 354         if(self.csqcmodel_modelflags & MF_GIB)
 355                 self.traileffect = particleeffectnum("TR_BLOOD");
 356         if(self.csqcmodel_modelflags & MF_ROTATE)
 357         {
 358                 self.renderflags |= RF_USEAXIS;
 359                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 360         }
 361         if(self.csqcmodel_modelflags & MF_TRACER)
 362                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 363         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 364                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 365         if(self.csqcmodel_modelflags & MF_TRACER2)
 366                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 367         if(self.csqcmodel_modelflags & MF_TRACER3)
 368                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 369
 370         if(self.drawmask)
 371                 Projectile_DrawTrail(self.origin);
 372         else
 373                 Projectile_ResetTrail(self.origin);
 374 }
 375
 376 // general functions
 377 void CSQCModel_Hook_PreDraw(float isplayer, float islocalplayer)
 378 {
 379         if(!self.modelindex || self.model == "null")
 380         {
 381                 self.drawmask = 0;
 382                 return;
 383         }
 384         else
 385                 self.drawmask = MASK_NORMAL;
 386
 387         if(self.isplayermodel) // this checks if it's a player MODEL!
 388         {
 389                 CSQCPlayer_GlowMod_Apply();
 390                 CSQCPlayer_ForceModel_Apply(islocalplayer);
 391                 CSQCPlayer_LOD_Apply();
 392                 CSQCPlayer_FallbackFrame_Apply();
 393         }
 394
 395         if(!isplayer) // this checks if it's a player SLOT!
 396                 CSQCModel_AutoTagIndex_Apply();
 397
 398         CSQCModel_Effects_Apply();
 399 }
 400
 401 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 402 {
 403         // revert to values from server
 404         CSQCModel_Effects_PreUpdate();
 405         if(self.isplayermodel)
 406         {
 407                 CSQCPlayer_FallbackFrame_PreUpdate();
 408                 CSQCPlayer_ForceModel_PreUpdate();
 409         }
 410 }
 411
 412 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 413 {
 414         // is it a player model? (shared state)
 415         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/");
 416
 417         // save values set by server
 418         if(self.isplayermodel)
 419         {
 420                 CSQCPlayer_ForceModel_PostUpdate();
 421                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 422         }
 423         CSQCModel_Effects_PostUpdate();
 424 }