qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 vector mi = self.mins;
  18                 vector ma = self.maxs;
  19
  20                 // set modelindex
  21                 self.lodmodelindex0 = self.modelindex;
  22                 self.lodmodelindex1 = self.modelindex;
  23                 self.lodmodelindex2 = self.modelindex;
  24
  25                 // FIXME: this only supports 3-letter extensions
  26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  27                 if(fexists(s))
  28                 {
  29                         precache_model(s);
  30                         setmodel(self, s);
  31                         if(self.modelindex)
  32                                 self.lodmodelindex1 = self.modelindex;
  33                 }
  34
  35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  36                 if(fexists(s))
  37                 {
  38                         precache_model(s);
  39                         setmodel(self, s);
  40                         if(self.modelindex)
  41                                 self.lodmodelindex2 = self.modelindex;
  42                 }
  43
  44                 setmodel(self, modelname); // make everything normal again
  45                 setsize(self, mi, ma);
  46         }
  47
  48         // apply LOD
  49         if(autocvar_cl_playerdetailreduction <= 0)
  50         {
  51                 if(autocvar_cl_playerdetailreduction <= -2)
  52                         self.modelindex = self.lodmodelindex2;
  53                 else if(autocvar_cl_playerdetailreduction <= -1)
  54                         self.modelindex = self.lodmodelindex1;
  55                 else
  56                         self.modelindex = self.lodmodelindex0;
  57         }
  58         else
  59         {
  60                 float distance = vlen(self.origin - view_origin);
  61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  62                 f *= 1.0 / bound(0.01, view_quality, 1);
  63                 if(f > autocvar_cl_loddistance2)
  64                         self.modelindex = self.lodmodelindex2;
  65                 else if(f > autocvar_cl_loddistance1)
  66                         self.modelindex = self.lodmodelindex1;
  67                 else
  68                         self.modelindex = self.lodmodelindex0;
  69         }
  70 }
  71
  72 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  73 string forceplayermodels_model;
  74 float forceplayermodels_modelisgoodmodel;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_myisgoodmodel;
  80 float forceplayermodels_mymodelindex;
  81
  82 float forceplayermodels_attempted;
  83
  84 .string forceplayermodels_savemodel;
  85 .float forceplayermodels_savemodelindex;
  86 .float forceplayermodels_saveskin;
  87 .float forceplayermodels_savecolormap;
  88
  89 .string forceplayermodels_isgoodmodel_mdl;
  90 .float forceplayermodels_isgoodmodel;
  91
  92 string forceplayermodels_goodmodel;
  93 float forceplayermodels_goodmodelindex;
  94
  95 void CSQCPlayer_ForceModel_PreUpdate(void)
  96 {
  97         self.model = self.forceplayermodels_savemodel;
  98         self.modelindex = self.forceplayermodels_savemodelindex;
  99         self.skin = self.forceplayermodels_saveskin;
 100         self.colormap = self.forceplayermodels_savecolormap;
 101 }
 102 void CSQCPlayer_ForceModel_PostUpdate(void)
 103 {
 104         self.forceplayermodels_savemodel = self.model;
 105         self.forceplayermodels_savemodelindex = self.modelindex;
 106         self.forceplayermodels_saveskin = self.skin;
 107         self.forceplayermodels_savecolormap = self.colormap;
 108
 109         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 110         {
 111                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 112                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 113                 if(!self.forceplayermodels_isgoodmodel)
 114                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 115         }
 116 }
 117 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 118 {
 119         // which one is ALWAYS good?
 120         if not(forceplayermodels_goodmodel)
 121         {
 122                 entity e;
 123                 e = spawn();
 124                 precache_model(cvar_defstring("_cl_playermodel"));
 125                 setmodel(e, cvar_defstring("_cl_playermodel"));
 126                 forceplayermodels_goodmodel = e.model;
 127                 forceplayermodels_goodmodelindex = e.modelindex;
 128                 remove(e);
 129         }
 130
 131         // first, try finding it from the server
 132         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 133         {
 134                 if(islocalplayer)
 135                 {
 136                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 137                         {
 138                                 // trust server's idea of "own player model"
 139                                 forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 140                                 forceplayermodels_model = self.forceplayermodels_savemodel;
 141                                 forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 142                                 forceplayermodels_skin = self.forceplayermodels_saveskin;
 143                                 forceplayermodels_attempted = 1;
 144                         }
 145                 }
 146         }
 147
 148         // forcemodel finding
 149         if(!forceplayermodels_attempted)
 150         {
 151                 forceplayermodels_attempted = 1;
 152
 153                 // only if this failed, find it out on our own
 154                 entity e;
 155                 e = spawn();
 156                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 157                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 158                 forceplayermodels_model = e.model;
 159                 forceplayermodels_modelindex = e.modelindex;
 160                 forceplayermodels_skin = autocvar__cl_playerskin;
 161                 remove(e);
 162         }
 163
 164         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 165         {
 166                 entity e;
 167                 e = spawn();
 168                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 169                 forceplayermodels_myisgoodmodel = fexists(e.model);
 170                 forceplayermodels_mymodel = e.model;
 171                 forceplayermodels_mymodelindex = e.modelindex;
 172                 remove(e);
 173         }
 174
 175         // apply it
 176         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && islocalplayer)
 177         {
 178                 self.model = forceplayermodels_mymodel;
 179                 self.modelindex = forceplayermodels_mymodelindex;
 180                 self.skin = autocvar_cl_forcemyplayerskin;
 181         }
 182         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 183         {
 184                 self.model = forceplayermodels_model;
 185                 self.modelindex = forceplayermodels_modelindex;
 186                 self.skin = forceplayermodels_skin;
 187         }
 188         else if(self.forceplayermodels_isgoodmodel)
 189         {
 190                 self.model = self.forceplayermodels_savemodel;
 191                 self.modelindex = self.forceplayermodels_savemodelindex;
 192                 self.skin = self.forceplayermodels_saveskin;
 193         }
 194         else
 195         {
 196                 self.model = forceplayermodels_goodmodel;
 197                 self.modelindex = forceplayermodels_goodmodelindex;
 198                 self.skin = self.forceplayermodels_saveskin;
 199         }
 200
 201         // forceplayercolors too
 202         if(!teamplay)
 203         {
 204                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 205                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 206                 else if(autocvar_cl_forceplayercolors)
 207                         self.colormap = player_localnum + 1;
 208         }
 209 }
 210
 211 // FEATURE: fallback frames
 212 .float csqcmodel_saveframe;
 213 .float csqcmodel_saveframe2;
 214 .float csqcmodel_saveframe3;
 215 .float csqcmodel_saveframe4;
 216 .float csqcmodel_framecount;
 217
 218 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 219 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 220 {
 221         self.frame = self.csqcmodel_saveframe;
 222         self.frame2 = self.csqcmodel_saveframe2;
 223         self.frame3 = self.csqcmodel_saveframe3;
 224         self.frame4 = self.csqcmodel_saveframe4;
 225 }
 226 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 227 {
 228         self.csqcmodel_saveframe = self.frame;
 229         self.csqcmodel_saveframe2 = self.frame2;
 230         self.csqcmodel_saveframe3 = self.frame3;
 231         self.csqcmodel_saveframe4 = self.frame4;
 232
 233         // hack for death animations: set their frametime to zero in case a
 234         // player "pops in"
 235         if(isnew)
 236         {
 237 #define FIX_FRAMETIME(f,ft) \
 238                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 239                 { \
 240                         self.ft = self.death_time; \
 241                 }
 242                 FIX_FRAMETIME(frame, frame1time)
 243                 FIX_FRAMETIME(frame2, frame2time)
 244                 FIX_FRAMETIME(frame3, frame3time)
 245                 FIX_FRAMETIME(frame4, frame4time)
 246         }
 247         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 248 }
 249 float CSQCPlayer_FallbackFrame(float f)
 250 {
 251         if(frameduration(self.modelindex, f) > 0)
 252                 return f; // goooooood
 253         if(frameduration(self.modelindex, 1) <= 0)
 254                 return f; // this is a static model. We can't fix it if we wanted to
 255         switch(f)
 256         {
 257                 case 23: return 11; // anim_melee -> anim_shoot
 258                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 259                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 260                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 261                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 262                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 263                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 264                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 265         }
 266         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 267         return f;
 268 }
 269 void CSQCPlayer_FallbackFrame_Apply(void)
 270 {
 271         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 272         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 273         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 274         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 275 }
 276
 277 // FEATURE: auto tag_index
 278 .entity tag_entity;
 279 .float tag_entity_lastmodelindex;
 280 .float tag_index;
 281 void CSQCModel_AutoTagIndex_Apply(void)
 282 {
 283         if(self.tag_entity && wasfreed(self.tag_entity))
 284                 self.tag_entity = world;
 285
 286         if(self.tag_networkentity)
 287         {
 288                 // we are ATTACHED!
 289                 float changed = 0;
 290                 if(self.tag_entity.entnum != self.tag_networkentity)
 291                 {
 292                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 293                         changed = 1;
 294                 }
 295
 296                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 297                 if(self.tag_entity.classname == "csqcmodel")
 298                 {
 299                         entity oldself = self;
 300                         self = self.tag_entity;
 301                         CSQCModel_Hook_PreDraw();
 302                         self = oldself;
 303                 }
 304
 305                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 306                 {
 307                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 308                         changed = 1;
 309                 }
 310                 if(changed)
 311                 {
 312                         if(self.tag_entity)
 313                         {
 314                                 // the best part is: IT EXISTS
 315                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 316                                 {
 317                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 318                                         {
 319                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 320                                                 if(!self.tag_index)
 321                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 322                                                 if(!self.tag_index)
 323                                                 {
 324                                                         // we need to prevent this from 'appening
 325                                                         self.tag_entity = world;
 326                                                         self.drawmask = 0;
 327                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 328                                                 }
 329                                         }
 330                                         else if(self.tag_entity.isplayermodel)
 331                                         {
 332                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 333                                                 if(!self.tag_index)
 334                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 335                                                 if(!self.tag_index)
 336                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 337                                         }
 338                                 }
 339
 340                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 341                                 {
 342                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 343                                         if(!self.tag_index)
 344                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 345                                 }
 346                         }
 347                         else
 348                         {
 349                                 // damn, see you next frame
 350                                 self.drawmask = 0;
 351                         }
 352                 }
 353         }
 354 }
 355
 356 // FEATURE: EF_NODRAW workalike
 357 float EF_BRIGHTFIELD    = 1;
 358 float EF_BRIGHTLIGHT    = 4;
 359 float EF_DIMLIGHT       = 8;
 360 float EF_DOUBLESIDED = 32768;
 361 float EF_NOSELFSHADOW = 65536;
 362 float EF_DYNAMICMODELLIGHT = 131072;
 363 float MF_ROCKET  =   1; // leave a trail
 364 float MF_GRENADE =   2; // leave a trail
 365 float MF_GIB     =   4; // leave a trail
 366 float MF_ROTATE  =   8; // rotate (bonus items)
 367 float MF_TRACER  =  16; // green split trail
 368 float MF_ZOMGIB  =  32; // small blood trail
 369 float MF_TRACER2 =  64; // orange split trail
 370 float MF_TRACER3 = 128; // purple trail
 371 .float csqcmodel_effects;
 372 .float csqcmodel_modelflags;
 373 void CSQCModel_Effects_PreUpdate(void)
 374 {
 375         self.effects = self.csqcmodel_effects;
 376         self.modelflags = self.csqcmodel_modelflags;
 377 }
 378 void CSQCModel_Effects_PostUpdate(void)
 379 {
 380         self.csqcmodel_effects = self.effects;
 381         self.csqcmodel_modelflags = self.modelflags;
 382         self.effects = 0;
 383         self.modelflags = 0;
 384         if(self.csqcmodel_teleported)
 385                 Projectile_ResetTrail(self.origin);
 386 }
 387 void CSQCModel_Effects_Apply(void)
 388 {
 389         float eff = self.csqcmodel_effects;
 390         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 391
 392         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 393         self.effects = 0;
 394         self.traileffect = 0;
 395
 396         if(eff & EF_BRIGHTFIELD)
 397                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 398         // ignoring EF_MUZZLEFLASH
 399         if(eff & EF_BRIGHTLIGHT)
 400                 adddynamiclight(self.origin, 400, '3 3 3');
 401         if(eff & EF_DIMLIGHT)
 402                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 403         if((eff & EF_NODRAW) || (self.alpha < 0))
 404                 self.drawmask = 0;
 405         if(eff & EF_ADDITIVE)
 406                 self.renderflags |= RF_ADDITIVE;
 407         if(eff & EF_BLUE)
 408                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 409         if(eff & EF_RED)
 410                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 411         // ignoring EF_NOGUNBOB
 412         if(eff & EF_FULLBRIGHT)
 413                 self.renderflags |= RF_FULLBRIGHT;
 414         if(eff & EF_FLAME)
 415                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 416         if(eff & EF_STARDUST)
 417                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 418         if(eff & EF_NOSHADOW)
 419                 self.renderflags |= RF_NOSHADOW;
 420         if(eff & EF_NODEPTHTEST)
 421                 self.renderflags |= RF_DEPTHHACK;
 422         // ignoring EF_SELECTABLE
 423         if(eff & EF_DOUBLESIDED)
 424                 self.effects |= EF_DOUBLESIDED;
 425         if(eff & EF_NOSELFSHADOW)
 426                 self.effects |= EF_NOSELFSHADOW;
 427         if(eff & EF_DYNAMICMODELLIGHT)
 428                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 429         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 430         if(self.csqcmodel_modelflags & MF_ROCKET)
 431                 self.traileffect = particleeffectnum("TR_ROCKET");
 432         if(self.csqcmodel_modelflags & MF_GRENADE)
 433                 self.traileffect = particleeffectnum("TR_GRENADE");
 434         if(self.csqcmodel_modelflags & MF_GIB)
 435                 self.traileffect = particleeffectnum("TR_BLOOD");
 436         if(self.csqcmodel_modelflags & MF_ROTATE)
 437         {
 438                 self.renderflags |= RF_USEAXIS;
 439                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 440         }
 441         if(self.csqcmodel_modelflags & MF_TRACER)
 442                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 443         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 444                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 445         if(self.csqcmodel_modelflags & MF_TRACER2)
 446                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 447         if(self.csqcmodel_modelflags & MF_TRACER3)
 448                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 449
 450         if(self.drawmask)
 451                 Projectile_DrawTrail(self.origin);
 452         else
 453                 Projectile_ResetTrail(self.origin);
 454
 455         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 456                 self.renderflags |= RF_ADDITIVE;
 457                 // also special in CSQCPlayer_GlowMod_Apply
 458 }
 459
 460 // FEATURE: auto glowmod
 461 .vector glowmod;
 462 void CSQCPlayer_GlowMod_Apply(void)
 463 {
 464         float cm = self.colormap;
 465
 466         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 467                 cm = 1024;
 468
 469         if(self.colormap > 0)
 470                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 471         else
 472                 self.glowmod = '1 1 1';
 473
 474         if(autocvar_cl_deathglow > 0)
 475                 if(self.csqcmodel_isdead)
 476                 {
 477                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 478                         // prevent the zero vector
 479                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 480                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 481                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 482                 }
 483 }
 484
 485 // general functions
 486 .float csqcmodel_predraw_run;
 487 void CSQCModel_Hook_PreDraw()
 488 {
 489         if(self.csqcmodel_predraw_run == framecount)
 490                 return;
 491         self.csqcmodel_predraw_run = framecount;
 492
 493         if(!self.modelindex || self.model == "null")
 494         {
 495                 self.drawmask = 0;
 496                 return;
 497         }
 498         else
 499                 self.drawmask = MASK_NORMAL;
 500
 501         if(self.isplayermodel) // this checks if it's a player MODEL!
 502         {
 503                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 504                 CSQCPlayer_GlowMod_Apply();
 505                 CSQCPlayer_LOD_Apply();
 506                 CSQCPlayer_FallbackFrame_Apply();
 507         }
 508
 509         CSQCModel_AutoTagIndex_Apply();
 510
 511         CSQCModel_Effects_Apply();
 512 }
 513
 514 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 515 {
 516         // revert to values from server
 517         CSQCModel_Effects_PreUpdate();
 518         if(self.isplayermodel)
 519         {
 520                 CSQCPlayer_FallbackFrame_PreUpdate();
 521                 CSQCPlayer_ForceModel_PreUpdate();
 522         }
 523 }
 524
 525 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 526 {
 527         // is it a player model? (shared state)
 528         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 529
 530         // save values set by server
 531         if(self.isplayermodel)
 532         {
 533                 CSQCPlayer_ForceModel_PostUpdate();
 534                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 535         }
 536         CSQCModel_Effects_PostUpdate();
 537 }