qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 vector mi = self.mins;
  18                 vector ma = self.maxs;
  19
  20                 // set modelindex
  21                 self.lodmodelindex0 = self.modelindex;
  22                 self.lodmodelindex1 = self.modelindex;
  23                 self.lodmodelindex2 = self.modelindex;
  24
  25                 // FIXME: this only supports 3-letter extensions
  26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  27                 if(fexists(s))
  28                 {
  29                         precache_model(s);
  30                         setmodel(self, s);
  31                         if(self.modelindex)
  32                                 self.lodmodelindex1 = self.modelindex;
  33                 }
  34
  35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  36                 if(fexists(s))
  37                 {
  38                         precache_model(s);
  39                         setmodel(self, s);
  40                         if(self.modelindex)
  41                                 self.lodmodelindex2 = self.modelindex;
  42                 }
  43
  44                 setmodel(self, modelname); // make everything normal again
  45                 setsize(self, mi, ma);
  46         }
  47
  48         // apply LOD
  49         if(autocvar_cl_playerdetailreduction <= 0)
  50         {
  51                 if(autocvar_cl_playerdetailreduction <= -2)
  52                         self.modelindex = self.lodmodelindex2;
  53                 else if(autocvar_cl_playerdetailreduction <= -1)
  54                         self.modelindex = self.lodmodelindex1;
  55                 else
  56                         self.modelindex = self.lodmodelindex0;
  57         }
  58         else
  59         {
  60                 float distance = vlen(self.origin - view_origin);
  61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  62                 f *= 1.0 / bound(0.01, view_quality, 1);
  63                 if(f > autocvar_cl_loddistance2)
  64                         self.modelindex = self.lodmodelindex2;
  65                 else if(f > autocvar_cl_loddistance1)
  66                         self.modelindex = self.lodmodelindex1;
  67                 else
  68                         self.modelindex = self.lodmodelindex0;
  69         }
  70 }
  71
  72 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  73 string forceplayermodels_model;
  74 float forceplayermodels_modelisgoodmodel;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_myisgoodmodel;
  80 float forceplayermodels_mymodelindex;
  81
  82 float forceplayermodels_attempted;
  83
  84 .string forceplayermodels_savemodel;
  85 .float forceplayermodels_savemodelindex;
  86 .float forceplayermodels_saveskin;
  87 .float forceplayermodels_savecolormap;
  88
  89 .string forceplayermodels_isgoodmodel_mdl;
  90 .float forceplayermodels_isgoodmodel;
  91
  92 string forceplayermodels_goodmodel;
  93 float forceplayermodels_goodmodelindex;
  94
  95 void CSQCPlayer_ForceModel_PreUpdate(void)
  96 {
  97         self.model = self.forceplayermodels_savemodel;
  98         self.modelindex = self.forceplayermodels_savemodelindex;
  99         self.skin = self.forceplayermodels_saveskin;
 100         self.colormap = self.forceplayermodels_savecolormap;
 101 }
 102 void CSQCPlayer_ForceModel_PostUpdate(void)
 103 {
 104         self.forceplayermodels_savemodel = self.model;
 105         self.forceplayermodels_savemodelindex = self.modelindex;
 106         self.forceplayermodels_saveskin = self.skin;
 107         self.forceplayermodels_savecolormap = self.colormap;
 108
 109         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 110         {
 111                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 112                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 113                 if(!self.forceplayermodels_isgoodmodel)
 114                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 115         }
 116 }
 117 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 118 {
 119         // which one is ALWAYS good?
 120         if not(forceplayermodels_goodmodel)
 121         {
 122                 entity e;
 123                 e = spawn();
 124                 precache_model(cvar_defstring("_cl_playermodel"));
 125                 setmodel(e, cvar_defstring("_cl_playermodel"));
 126                 forceplayermodels_goodmodel = e.model;
 127                 forceplayermodels_goodmodelindex = e.modelindex;
 128                 remove(e);
 129         }
 130
 131         // first, try finding it from the server
 132         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 133         {
 134                 if(islocalplayer)
 135                 {
 136                         // trust server's idea of "own player model"
 137                         forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 138                         forceplayermodels_model = self.forceplayermodels_savemodel;
 139                         forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 140                         forceplayermodels_skin = self.forceplayermodels_saveskin;
 141                         forceplayermodels_attempted = 1;
 142                 }
 143         }
 144
 145         // forcemodel finding
 146         if(!forceplayermodels_attempted)
 147         {
 148                 forceplayermodels_attempted = 1;
 149
 150                 // only if this failed, find it out on our own
 151                 entity e;
 152                 e = spawn();
 153                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 154                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 155                 forceplayermodels_model = e.model;
 156                 forceplayermodels_modelindex = e.modelindex;
 157                 forceplayermodels_skin = autocvar__cl_playerskin;
 158                 remove(e);
 159         }
 160
 161         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 162         {
 163                 entity e;
 164                 e = spawn();
 165                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 166                 forceplayermodels_myisgoodmodel = fexists(e.model);
 167                 forceplayermodels_mymodel = e.model;
 168                 forceplayermodels_mymodelindex = e.modelindex;
 169                 remove(e);
 170         }
 171
 172         // apply it
 173         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && islocalplayer)
 174         {
 175                 self.model = forceplayermodels_mymodel;
 176                 self.modelindex = forceplayermodels_mymodelindex;
 177                 self.skin = autocvar_cl_forcemyplayerskin;
 178         }
 179         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 180         {
 181                 self.model = forceplayermodels_model;
 182                 self.modelindex = forceplayermodels_modelindex;
 183                 self.skin = forceplayermodels_skin;
 184         }
 185         else if(self.forceplayermodels_isgoodmodel)
 186         {
 187                 self.model = self.forceplayermodels_savemodel;
 188                 self.modelindex = self.forceplayermodels_savemodelindex;
 189                 self.skin = self.forceplayermodels_saveskin;
 190         }
 191         else
 192         {
 193                 self.model = forceplayermodels_goodmodel;
 194                 self.modelindex = forceplayermodels_goodmodelindex;
 195                 self.skin = self.forceplayermodels_saveskin;
 196         }
 197
 198         // forceplayercolors too
 199         if(teamplay)
 200         {
 201                 // own team's color is never forced
 202                 float forcecolor_friend = 0;
 203                 float forcecolor_enemy = 0;
 204                 float teams_count = 0;
 205                 float my_colors = 1024 + autocvar__cl_color;
 206                 entity tm;
 207
 208                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 209                         if(tm.team != COLOR_SPECTATOR)
 210                                 ++teams_count;
 211
 212                 if(autocvar_cl_forcemyplayercolors)
 213                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 214                 if(autocvar_cl_forceplayercolors && teams_count == 2)
 215                         forcecolor_enemy = 1024 + my_colors;
 216
 217                 if(forcecolor_enemy && !forcecolor_friend)
 218                 {
 219                         // only enemy color is forced?
 220                         // verify it is not equal to the friend color
 221                         if(forcecolor_enemy == 1024 + 17 * myteam)
 222                                 forcecolor_enemy = 0;
 223                 }
 224
 225                 if(forcecolor_friend && !forcecolor_enemy)
 226                 {
 227                         // only friend color is forced?
 228                         // verify it is not equal to the enemy color
 229                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 230                                 // note: we even compare against our own team.
 231                                 // if we rejected because we matched our OWN team color,
 232                                 // this is not bad; we then simply keep our color as is
 233                                 // anyway.
 234                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 235                                         forcecolor_friend = 0;
 236                 }
 237
 238                 float cm;
 239                 cm = self.forceplayermodels_savecolormap;
 240                 cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(self.colormap - 1, "colors")) + 1024);
 241
 242                 if(cm == 1024 + 17 * myteam)
 243                 {
 244                         if(forcecolor_friend)
 245                                 self.colormap = forcecolor_friend;
 246                 }
 247                 else
 248                 {
 249                         if(forcecolor_enemy)
 250                                 self.colormap = forcecolor_enemy;
 251                 }
 252         }
 253         else
 254         {
 255                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 256                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 257                 else if(autocvar_cl_forceplayercolors)
 258                         self.colormap = player_localnum + 1;
 259         }
 260 }
 261
 262 // FEATURE: fallback frames
 263 .float csqcmodel_saveframe;
 264 .float csqcmodel_saveframe2;
 265 .float csqcmodel_saveframe3;
 266 .float csqcmodel_saveframe4;
 267 .float csqcmodel_framecount;
 268
 269 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 270 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 271 {
 272         self.frame = self.csqcmodel_saveframe;
 273         self.frame2 = self.csqcmodel_saveframe2;
 274         self.frame3 = self.csqcmodel_saveframe3;
 275         self.frame4 = self.csqcmodel_saveframe4;
 276 }
 277 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 278 {
 279         self.csqcmodel_saveframe = self.frame;
 280         self.csqcmodel_saveframe2 = self.frame2;
 281         self.csqcmodel_saveframe3 = self.frame3;
 282         self.csqcmodel_saveframe4 = self.frame4;
 283
 284         // hack for death animations: set their frametime to zero in case a
 285         // player "pops in"
 286         if(isnew)
 287         {
 288 #define FIX_FRAMETIME(f,ft) \
 289                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 290                 { \
 291                         self.ft = self.death_time; \
 292                 }
 293                 FIX_FRAMETIME(frame, frame1time)
 294                 FIX_FRAMETIME(frame2, frame2time)
 295                 FIX_FRAMETIME(frame3, frame3time)
 296                 FIX_FRAMETIME(frame4, frame4time)
 297         }
 298         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 299 }
 300 float CSQCPlayer_FallbackFrame(float f)
 301 {
 302         if(frameduration(self.modelindex, f) > 0)
 303                 return f; // goooooood
 304         if(frameduration(self.modelindex, 1) <= 0)
 305                 return f; // this is a static model. We can't fix it if we wanted to
 306         switch(f)
 307         {
 308                 case 23: return 11; // anim_melee -> anim_shoot
 309                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 310                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 311                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 312                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 313                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 314                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 315                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 316         }
 317         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 318         return f;
 319 }
 320 void CSQCPlayer_FallbackFrame_Apply(void)
 321 {
 322         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 323         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 324         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 325         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 326 }
 327
 328 // FEATURE: auto tag_index
 329 .entity tag_entity;
 330 .float tag_entity_lastmodelindex;
 331 .float tag_index;
 332 void CSQCModel_AutoTagIndex_Apply(void)
 333 {
 334         if(self.tag_entity && wasfreed(self.tag_entity))
 335                 self.tag_entity = world;
 336
 337         if(self.tag_networkentity)
 338         {
 339                 // we are ATTACHED!
 340                 float changed = 0;
 341                 if(self.tag_entity.entnum != self.tag_networkentity)
 342                 {
 343                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 344                         changed = 1;
 345                 }
 346
 347                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 348                 if(self.tag_entity.classname == "csqcmodel")
 349                 {
 350                         entity oldself = self;
 351                         self = self.tag_entity;
 352                         CSQCModel_Hook_PreDraw();
 353                         self = oldself;
 354                 }
 355
 356                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 357                 {
 358                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 359                         changed = 1;
 360                 }
 361                 if(changed)
 362                 {
 363                         if(self.tag_entity)
 364                         {
 365                                 // the best part is: IT EXISTS
 366                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 367                                 {
 368                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 369                                         {
 370                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 371                                                 if(!self.tag_index)
 372                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 373                                                 if(!self.tag_index)
 374                                                 {
 375                                                         // we need to prevent this from 'appening
 376                                                         self.tag_entity = world;
 377                                                         self.drawmask = 0;
 378                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 379                                                 }
 380                                         }
 381                                         else if(self.tag_entity.isplayermodel)
 382                                         {
 383                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 384                                                 if(!self.tag_index)
 385                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 386                                                 if(!self.tag_index)
 387                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 388                                         }
 389                                 }
 390
 391                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 392                                 {
 393                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 394                                         if(!self.tag_index)
 395                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 396                                 }
 397                         }
 398                         else
 399                         {
 400                                 // damn, see you next frame
 401                                 self.drawmask = 0;
 402                         }
 403                 }
 404         }
 405 }
 406
 407 // FEATURE: EF_NODRAW workalike
 408 float EF_BRIGHTFIELD    = 1;
 409 float EF_BRIGHTLIGHT    = 4;
 410 float EF_DIMLIGHT       = 8;
 411 float EF_DOUBLESIDED = 32768;
 412 float EF_NOSELFSHADOW = 65536;
 413 float EF_DYNAMICMODELLIGHT = 131072;
 414 float MF_ROCKET  =   1; // leave a trail
 415 float MF_GRENADE =   2; // leave a trail
 416 float MF_GIB     =   4; // leave a trail
 417 float MF_ROTATE  =   8; // rotate (bonus items)
 418 float MF_TRACER  =  16; // green split trail
 419 float MF_ZOMGIB  =  32; // small blood trail
 420 float MF_TRACER2 =  64; // orange split trail
 421 float MF_TRACER3 = 128; // purple trail
 422 .float csqcmodel_effects;
 423 .float csqcmodel_modelflags;
 424 void CSQCModel_Effects_PreUpdate(void)
 425 {
 426         self.effects = self.csqcmodel_effects;
 427         self.modelflags = self.csqcmodel_modelflags;
 428 }
 429 void CSQCModel_Effects_PostUpdate(void)
 430 {
 431         self.csqcmodel_effects = self.effects;
 432         self.csqcmodel_modelflags = self.modelflags;
 433         self.effects = 0;
 434         self.modelflags = 0;
 435         if(self.csqcmodel_teleported)
 436                 Projectile_ResetTrail(self.origin);
 437 }
 438 void CSQCModel_Effects_Apply(void)
 439 {
 440         float eff = self.csqcmodel_effects;
 441         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 442
 443         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 444         self.effects = 0;
 445         self.traileffect = 0;
 446
 447         if(eff & EF_BRIGHTFIELD)
 448                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 449         // ignoring EF_MUZZLEFLASH
 450         if(eff & EF_BRIGHTLIGHT)
 451                 adddynamiclight(self.origin, 400, '3 3 3');
 452         if(eff & EF_DIMLIGHT)
 453                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 454         if((eff & EF_NODRAW) || (self.alpha < 0))
 455                 self.drawmask = 0;
 456         if(eff & EF_ADDITIVE)
 457                 self.renderflags |= RF_ADDITIVE;
 458         if(eff & EF_BLUE)
 459                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 460         if(eff & EF_RED)
 461                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 462         // ignoring EF_NOGUNBOB
 463         if(eff & EF_FULLBRIGHT)
 464                 self.renderflags |= RF_FULLBRIGHT;
 465         if(eff & EF_FLAME)
 466                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 467         if(eff & EF_STARDUST)
 468                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 469         if(eff & EF_NOSHADOW)
 470                 self.renderflags |= RF_NOSHADOW;
 471         if(eff & EF_NODEPTHTEST)
 472                 self.renderflags |= RF_DEPTHHACK;
 473         // ignoring EF_SELECTABLE
 474         if(eff & EF_DOUBLESIDED)
 475                 self.effects |= EF_DOUBLESIDED;
 476         if(eff & EF_NOSELFSHADOW)
 477                 self.effects |= EF_NOSELFSHADOW;
 478         if(eff & EF_DYNAMICMODELLIGHT)
 479                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 480         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 481         if(self.csqcmodel_modelflags & MF_ROCKET)
 482                 self.traileffect = particleeffectnum("TR_ROCKET");
 483         if(self.csqcmodel_modelflags & MF_GRENADE)
 484                 self.traileffect = particleeffectnum("TR_GRENADE");
 485         if(self.csqcmodel_modelflags & MF_GIB)
 486                 self.traileffect = particleeffectnum("TR_BLOOD");
 487         if(self.csqcmodel_modelflags & MF_ROTATE)
 488         {
 489                 self.renderflags |= RF_USEAXIS;
 490                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 491         }
 492         if(self.csqcmodel_modelflags & MF_TRACER)
 493                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 494         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 495                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 496         if(self.csqcmodel_modelflags & MF_TRACER2)
 497                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 498         if(self.csqcmodel_modelflags & MF_TRACER3)
 499                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 500
 501         if(self.drawmask)
 502                 Projectile_DrawTrail(self.origin);
 503         else
 504                 Projectile_ResetTrail(self.origin);
 505
 506         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 507                 self.renderflags |= RF_ADDITIVE;
 508                 // also special in CSQCPlayer_GlowMod_Apply
 509 }
 510
 511 // FEATURE: auto glowmod
 512 .vector glowmod;
 513 void CSQCPlayer_GlowMod_Apply(void)
 514 {
 515         float cm = self.colormap;
 516
 517         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 518                 cm = 1024;
 519
 520         if(self.colormap > 0)
 521                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 522         else
 523                 self.glowmod = '1 1 1';
 524
 525         if(autocvar_cl_deathglow > 0)
 526                 if(self.csqcmodel_isdead)
 527                 {
 528                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 529                         // prevent the zero vector
 530                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 531                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 532                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 533                 }
 534 }
 535
 536 // general functions
 537 .float csqcmodel_predraw_run;
 538 void CSQCModel_Hook_PreDraw()
 539 {
 540         if(self.csqcmodel_predraw_run == framecount)
 541                 return;
 542         self.csqcmodel_predraw_run = framecount;
 543
 544         if(!self.modelindex || self.model == "null")
 545         {
 546                 self.drawmask = 0;
 547                 return;
 548         }
 549         else
 550                 self.drawmask = MASK_NORMAL;
 551
 552         if(self.isplayermodel) // this checks if it's a player MODEL!
 553         {
 554                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 555                 CSQCPlayer_GlowMod_Apply();
 556                 CSQCPlayer_LOD_Apply();
 557                 CSQCPlayer_FallbackFrame_Apply();
 558         }
 559
 560         CSQCModel_AutoTagIndex_Apply();
 561
 562         CSQCModel_Effects_Apply();
 563 }
 564
 565 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 566 {
 567         // revert to values from server
 568         CSQCModel_Effects_PreUpdate();
 569         if(self.isplayermodel)
 570         {
 571                 CSQCPlayer_FallbackFrame_PreUpdate();
 572                 CSQCPlayer_ForceModel_PreUpdate();
 573         }
 574 }
 575
 576 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 577 {
 578         // is it a player model? (shared state)
 579         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 580
 581         // save values set by server
 582         if(self.isplayermodel)
 583         {
 584                 CSQCPlayer_ForceModel_PostUpdate();
 585                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 586         }
 587         CSQCModel_Effects_PostUpdate();
 588 }