qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 // set modelindex
  18                 self.lodmodelindex0 = self.modelindex;
  19                 self.lodmodelindex1 = self.modelindex;
  20                 self.lodmodelindex2 = self.modelindex;
  21
  22                 // FIXME: this only supports 3-letter extensions
  23                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  24                 if(fexists(s))
  25                 {
  26                         precache_model(s);
  27                         setmodel(self, s);
  28                         if(self.modelindex)
  29                                 self.lodmodelindex1 = self.modelindex;
  30                 }
  31
  32                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  33                 if(fexists(s))
  34                 {
  35                         precache_model(s);
  36                         setmodel(self, s);
  37                         if(self.modelindex)
  38                                 self.lodmodelindex2 = self.modelindex;
  39                 }
  40
  41                 setmodel(self, modelname); // make everything normal again
  42         }
  43
  44         // apply LOD
  45         if(autocvar_cl_playerdetailreduction <= 0)
  46         {
  47                 if(autocvar_cl_playerdetailreduction <= -2)
  48                         self.modelindex = self.lodmodelindex2;
  49                 else if(autocvar_cl_playerdetailreduction <= -1)
  50                         self.modelindex = self.lodmodelindex1;
  51                 else
  52                         self.modelindex = self.lodmodelindex0;
  53         }
  54         else
  55         {
  56                 float distance = vlen(self.origin - view_origin);
  57                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  58                 f *= 1.0 / bound(0.01, view_quality, 1);
  59                 if(f > autocvar_cl_loddistance2)
  60                         self.modelindex = self.lodmodelindex2;
  61                 else if(f > autocvar_cl_loddistance1)
  62                         self.modelindex = self.lodmodelindex1;
  63                 else
  64                         self.modelindex = self.lodmodelindex0;
  65         }
  66 }
  67
  68 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  69 string forceplayermodels_model;
  70 float forceplayermodels_modelisgoodmodel;
  71 float forceplayermodels_modelindex;
  72 float forceplayermodels_skin;
  73
  74 string forceplayermodels_mymodel;
  75 float forceplayermodels_myisgoodmodel;
  76 float forceplayermodels_mymodelindex;
  77
  78 float forceplayermodels_attempted;
  79
  80 .string forceplayermodels_savemodel;
  81 .float forceplayermodels_savemodelindex;
  82 .float forceplayermodels_saveskin;
  83 .float forceplayermodels_savecolormap;
  84
  85 .string forceplayermodels_isgoodmodel_mdl;
  86 .float forceplayermodels_isgoodmodel;
  87
  88 string forceplayermodels_goodmodel;
  89 float forceplayermodels_goodmodelindex;
  90
  91 void CSQCPlayer_ForceModel_PreUpdate(void)
  92 {
  93         self.model = self.forceplayermodels_savemodel;
  94         self.modelindex = self.forceplayermodels_savemodelindex;
  95         self.skin = self.forceplayermodels_saveskin;
  96         self.colormap = self.forceplayermodels_savecolormap;
  97 }
  98 void CSQCPlayer_ForceModel_PostUpdate(void)
  99 {
 100         self.forceplayermodels_savemodel = self.model;
 101         self.forceplayermodels_savemodelindex = self.modelindex;
 102         self.forceplayermodels_saveskin = self.skin;
 103         self.forceplayermodels_savecolormap = self.colormap;
 104
 105         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 106         {
 107                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 108                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 109                 if(!self.forceplayermodels_isgoodmodel)
 110                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 111         }
 112 }
 113 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 114 {
 115         // which one is ALWAYS good?
 116         if not(forceplayermodels_goodmodel)
 117         {
 118                 entity e;
 119                 e = spawn();
 120                 precache_model(cvar_defstring("_cl_playermodel"));
 121                 setmodel(e, cvar_defstring("_cl_playermodel"));
 122                 forceplayermodels_goodmodel = e.model;
 123                 forceplayermodels_goodmodelindex = e.modelindex;
 124                 remove(e);
 125         }
 126
 127         // first, try finding it from the server
 128         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 129         {
 130                 if(islocalplayer)
 131                 {
 132                         // trust server's idea of "own player model"
 133                         forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 134                         forceplayermodels_model = self.forceplayermodels_savemodel;
 135                         forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 136                         forceplayermodels_skin = self.forceplayermodels_saveskin;
 137                         forceplayermodels_attempted = 1;
 138                 }
 139         }
 140
 141         // forcemodel finding
 142         if(!forceplayermodels_attempted)
 143         {
 144                 forceplayermodels_attempted = 1;
 145
 146                 // only if this failed, find it out on our own
 147                 entity e;
 148                 e = spawn();
 149                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 150                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 151                 forceplayermodels_model = e.model;
 152                 forceplayermodels_modelindex = e.modelindex;
 153                 forceplayermodels_skin = autocvar__cl_playerskin;
 154                 remove(e);
 155         }
 156
 157         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 158         {
 159                 entity e;
 160                 e = spawn();
 161                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 162                 forceplayermodels_myisgoodmodel = fexists(e.model);
 163                 forceplayermodels_mymodel = e.model;
 164                 forceplayermodels_mymodelindex = e.modelindex;
 165                 remove(e);
 166         }
 167
 168         // apply it
 169         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && islocalplayer)
 170         {
 171                 self.model = forceplayermodels_mymodel;
 172                 self.modelindex = forceplayermodels_mymodelindex;
 173                 self.skin = autocvar_cl_forcemyplayerskin;
 174         }
 175         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 176         {
 177                 self.model = forceplayermodels_model;
 178                 self.modelindex = forceplayermodels_modelindex;
 179                 self.skin = forceplayermodels_skin;
 180         }
 181         else if(self.forceplayermodels_isgoodmodel)
 182         {
 183                 self.model = self.forceplayermodels_savemodel;
 184                 self.modelindex = self.forceplayermodels_savemodelindex;
 185                 self.skin = self.forceplayermodels_saveskin;
 186         }
 187         else
 188         {
 189                 self.model = forceplayermodels_goodmodel;
 190                 self.modelindex = forceplayermodels_goodmodelindex;
 191                 self.skin = self.forceplayermodels_saveskin;
 192         }
 193
 194         // forceplayercolors too
 195         if(!teamplay)
 196         {
 197                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 198                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 199                 else if(autocvar_cl_forceplayercolors)
 200                         self.colormap = player_localnum + 1;
 201         }
 202 }
 203
 204 // FEATURE: fallback frames
 205 .float csqcmodel_saveframe;
 206 .float csqcmodel_saveframe2;
 207 .float csqcmodel_saveframe3;
 208 .float csqcmodel_saveframe4;
 209 .float csqcmodel_framecount;
 210
 211 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 212 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 213 {
 214         self.frame = self.csqcmodel_saveframe;
 215         self.frame2 = self.csqcmodel_saveframe2;
 216         self.frame3 = self.csqcmodel_saveframe3;
 217         self.frame4 = self.csqcmodel_saveframe4;
 218 }
 219 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 220 {
 221         self.csqcmodel_saveframe = self.frame;
 222         self.csqcmodel_saveframe2 = self.frame2;
 223         self.csqcmodel_saveframe3 = self.frame3;
 224         self.csqcmodel_saveframe4 = self.frame4;
 225
 226         // hack for death animations: set their frametime to zero in case a
 227         // player "pops in"
 228         if(isnew)
 229         {
 230 #define FIX_FRAMETIME(f,ft) \
 231                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 232                 { \
 233                         self.ft = self.death_time; \
 234                 }
 235                 FIX_FRAMETIME(frame, frame1time)
 236                 FIX_FRAMETIME(frame2, frame2time)
 237                 FIX_FRAMETIME(frame3, frame3time)
 238                 FIX_FRAMETIME(frame4, frame4time)
 239         }
 240         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 241 }
 242 float CSQCPlayer_FallbackFrame(float f)
 243 {
 244         if(frameduration(self.modelindex, f) > 0)
 245                 return f; // goooooood
 246         if(frameduration(self.modelindex, 1) <= 0)
 247                 return f; // this is a static model. We can't fix it if we wanted to
 248         switch(f)
 249         {
 250                 case 23: return 11; // anim_melee -> anim_shoot
 251                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 252                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 253                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 254                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 255                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 256                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 257                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 258         }
 259         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 260         return f;
 261 }
 262 void CSQCPlayer_FallbackFrame_Apply(void)
 263 {
 264         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 265         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 266         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 267         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 268 }
 269
 270 // FEATURE: auto tag_index
 271 .entity tag_entity;
 272 .float tag_entity_lastmodelindex;
 273 .float tag_index;
 274 void CSQCModel_AutoTagIndex_Apply(void)
 275 {
 276         if(self.tag_entity && wasfreed(self.tag_entity))
 277                 self.tag_entity = world;
 278
 279         if(self.tag_networkentity)
 280         {
 281                 // we are ATTACHED!
 282                 float changed = 0;
 283                 if(self.tag_entity.entnum != self.tag_networkentity)
 284                 {
 285                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 286                         changed = 1;
 287                 }
 288
 289                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 290                 if(self.tag_entity.classname == "csqcmodel")
 291                 {
 292                         entity oldself = self;
 293                         self = self.tag_entity;
 294                         CSQCModel_Hook_PreDraw();
 295                         self = oldself;
 296                 }
 297
 298                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 299                 {
 300                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 301                         changed = 1;
 302                 }
 303                 if(changed)
 304                 {
 305                         if(self.tag_entity)
 306                         {
 307                                 // the best part is: IT EXISTS
 308                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 309                                 {
 310                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 311                                         {
 312                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 313                                                 if(!self.tag_index)
 314                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 315                                                 if(!self.tag_index)
 316                                                 {
 317                                                         // we need to prevent this from 'appening
 318                                                         self.tag_entity = world;
 319                                                         self.drawmask = 0;
 320                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 321                                                 }
 322                                         }
 323                                         else if(self.tag_entity.isplayermodel)
 324                                         {
 325                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 326                                                 if(!self.tag_index)
 327                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 328                                                 if(!self.tag_index)
 329                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 330                                         }
 331                                 }
 332
 333                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 334                                 {
 335                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 336                                         if(!self.tag_index)
 337                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 338                                 }
 339                         }
 340                         else
 341                         {
 342                                 // damn, see you next frame
 343                                 self.drawmask = 0;
 344                         }
 345                 }
 346         }
 347 }
 348
 349 // FEATURE: EF_NODRAW workalike
 350 float EF_BRIGHTFIELD    = 1;
 351 float EF_BRIGHTLIGHT    = 4;
 352 float EF_DIMLIGHT       = 8;
 353 float EF_DOUBLESIDED = 32768;
 354 float EF_NOSELFSHADOW = 65536;
 355 float EF_DYNAMICMODELLIGHT = 131072;
 356 float MF_ROCKET  =   1; // leave a trail
 357 float MF_GRENADE =   2; // leave a trail
 358 float MF_GIB     =   4; // leave a trail
 359 float MF_ROTATE  =   8; // rotate (bonus items)
 360 float MF_TRACER  =  16; // green split trail
 361 float MF_ZOMGIB  =  32; // small blood trail
 362 float MF_TRACER2 =  64; // orange split trail
 363 float MF_TRACER3 = 128; // purple trail
 364 .float csqcmodel_effects;
 365 .float csqcmodel_modelflags;
 366 void CSQCModel_Effects_PreUpdate(void)
 367 {
 368         self.effects = self.csqcmodel_effects;
 369         self.modelflags = self.csqcmodel_modelflags;
 370 }
 371 void CSQCModel_Effects_PostUpdate(void)
 372 {
 373         self.csqcmodel_effects = self.effects;
 374         self.csqcmodel_modelflags = self.modelflags;
 375         self.effects = 0;
 376         self.modelflags = 0;
 377         if(self.csqcmodel_teleported)
 378                 Projectile_ResetTrail(self.origin);
 379 }
 380 void CSQCModel_Effects_Apply(void)
 381 {
 382         float eff = self.csqcmodel_effects;
 383         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 384
 385         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 386         self.effects = 0;
 387         self.traileffect = 0;
 388
 389         if(eff & EF_BRIGHTFIELD)
 390                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 391         // ignoring EF_MUZZLEFLASH
 392         if(eff & EF_BRIGHTLIGHT)
 393                 adddynamiclight(self.origin, 400, '3 3 3');
 394         if(eff & EF_DIMLIGHT)
 395                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 396         if((eff & EF_NODRAW) || (self.alpha < 0))
 397                 self.drawmask = 0;
 398         if(eff & EF_ADDITIVE)
 399                 self.renderflags |= RF_ADDITIVE;
 400         if(eff & EF_BLUE)
 401                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 402         if(eff & EF_RED)
 403                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 404         // ignoring EF_NOGUNBOB
 405         if(eff & EF_FULLBRIGHT)
 406                 self.renderflags |= RF_FULLBRIGHT;
 407         if(eff & EF_FLAME)
 408                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 409         if(eff & EF_STARDUST)
 410                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 411         if(eff & EF_NOSHADOW)
 412                 self.renderflags |= RF_NOSHADOW;
 413         if(eff & EF_NODEPTHTEST)
 414                 self.renderflags |= RF_DEPTHHACK;
 415         // ignoring EF_SELECTABLE
 416         if(eff & EF_DOUBLESIDED)
 417                 self.effects |= EF_DOUBLESIDED;
 418         if(eff & EF_NOSELFSHADOW)
 419                 self.effects |= EF_NOSELFSHADOW;
 420         if(eff & EF_DYNAMICMODELLIGHT)
 421                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 422         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 423         if(self.csqcmodel_modelflags & MF_ROCKET)
 424                 self.traileffect = particleeffectnum("TR_ROCKET");
 425         if(self.csqcmodel_modelflags & MF_GRENADE)
 426                 self.traileffect = particleeffectnum("TR_GRENADE");
 427         if(self.csqcmodel_modelflags & MF_GIB)
 428                 self.traileffect = particleeffectnum("TR_BLOOD");
 429         if(self.csqcmodel_modelflags & MF_ROTATE)
 430         {
 431                 self.renderflags |= RF_USEAXIS;
 432                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 433         }
 434         if(self.csqcmodel_modelflags & MF_TRACER)
 435                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 436         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 437                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 438         if(self.csqcmodel_modelflags & MF_TRACER2)
 439                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 440         if(self.csqcmodel_modelflags & MF_TRACER3)
 441                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 442
 443         if(self.drawmask)
 444                 Projectile_DrawTrail(self.origin);
 445         else
 446                 Projectile_ResetTrail(self.origin);
 447
 448         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 449                 self.renderflags |= RF_ADDITIVE;
 450                 // also special in CSQCPlayer_GlowMod_Apply
 451 }
 452
 453 // FEATURE: auto glowmod
 454 .vector glowmod;
 455 void CSQCPlayer_GlowMod_Apply(void)
 456 {
 457         float cm = self.colormap;
 458
 459         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 460                 cm = 1024;
 461
 462         if(self.colormap > 0)
 463                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 464         else
 465                 self.glowmod = '1 1 1';
 466
 467         if(autocvar_cl_deathglow > 0)
 468                 if(self.csqcmodel_isdead)
 469                 {
 470                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 471                         // prevent the zero vector
 472                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 473                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 474                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 475                 }
 476 }
 477
 478 // general functions
 479 .float csqcmodel_predraw_run;
 480 void CSQCModel_Hook_PreDraw()
 481 {
 482         if(self.csqcmodel_predraw_run == framecount)
 483                 return;
 484         self.csqcmodel_predraw_run = framecount;
 485
 486         if(!self.modelindex || self.model == "null")
 487         {
 488                 self.drawmask = 0;
 489                 return;
 490         }
 491         else
 492                 self.drawmask = MASK_NORMAL;
 493
 494         if(self.isplayermodel) // this checks if it's a player MODEL!
 495         {
 496                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 497                 CSQCPlayer_GlowMod_Apply();
 498                 CSQCPlayer_LOD_Apply();
 499                 CSQCPlayer_FallbackFrame_Apply();
 500         }
 501
 502         CSQCModel_AutoTagIndex_Apply();
 503
 504         CSQCModel_Effects_Apply();
 505 }
 506
 507 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 508 {
 509         // revert to values from server
 510         CSQCModel_Effects_PreUpdate();
 511         if(self.isplayermodel)
 512         {
 513                 CSQCPlayer_FallbackFrame_PreUpdate();
 514                 CSQCPlayer_ForceModel_PreUpdate();
 515         }
 516 }
 517
 518 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 519 {
 520         // is it a player model? (shared state)
 521         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 522
 523         // save values set by server
 524         if(self.isplayermodel)
 525         {
 526                 CSQCPlayer_ForceModel_PostUpdate();
 527                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 528         }
 529         CSQCModel_Effects_PostUpdate();
 530 }