qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 vector mi = self.mins;
  18                 vector ma = self.maxs;
  19
  20                 // set modelindex
  21                 self.lodmodelindex0 = self.modelindex;
  22                 self.lodmodelindex1 = self.modelindex;
  23                 self.lodmodelindex2 = self.modelindex;
  24
  25                 // FIXME: this only supports 3-letter extensions
  26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  27                 if(fexists(s))
  28                 {
  29                         precache_model(s);
  30                         setmodel(self, s);
  31                         if(self.modelindex)
  32                                 self.lodmodelindex1 = self.modelindex;
  33                 }
  34
  35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  36                 if(fexists(s))
  37                 {
  38                         precache_model(s);
  39                         setmodel(self, s);
  40                         if(self.modelindex)
  41                                 self.lodmodelindex2 = self.modelindex;
  42                 }
  43
  44                 setmodel(self, modelname); // make everything normal again
  45                 setsize(self, mi, ma);
  46         }
  47
  48         // apply LOD
  49         if(autocvar_cl_playerdetailreduction <= 0)
  50         {
  51                 if(autocvar_cl_playerdetailreduction <= -2)
  52                         self.modelindex = self.lodmodelindex2;
  53                 else if(autocvar_cl_playerdetailreduction <= -1)
  54                         self.modelindex = self.lodmodelindex1;
  55                 else
  56                         self.modelindex = self.lodmodelindex0;
  57         }
  58         else
  59         {
  60                 float distance = vlen(self.origin - view_origin);
  61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  62                 f *= 1.0 / bound(0.01, view_quality, 1);
  63                 if(f > autocvar_cl_loddistance2)
  64                         self.modelindex = self.lodmodelindex2;
  65                 else if(f > autocvar_cl_loddistance1)
  66                         self.modelindex = self.lodmodelindex1;
  67                 else
  68                         self.modelindex = self.lodmodelindex0;
  69         }
  70 }
  71
  72 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  73 string forceplayermodels_model;
  74 float forceplayermodels_modelisgoodmodel;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_myisgoodmodel;
  80 float forceplayermodels_mymodelindex;
  81
  82 float forceplayermodels_attempted;
  83
  84 .string forceplayermodels_savemodel;
  85 .float forceplayermodels_savemodelindex;
  86 .float forceplayermodels_saveskin;
  87 .float forceplayermodels_savecolormap;
  88
  89 .string forceplayermodels_isgoodmodel_mdl;
  90 .float forceplayermodels_isgoodmodel;
  91
  92 string forceplayermodels_goodmodel;
  93 float forceplayermodels_goodmodelindex;
  94
  95 void CSQCPlayer_ForceModel_PreUpdate(void)
  96 {
  97         self.model = self.forceplayermodels_savemodel;
  98         self.modelindex = self.forceplayermodels_savemodelindex;
  99         self.skin = self.forceplayermodels_saveskin;
 100         self.colormap = self.forceplayermodels_savecolormap;
 101 }
 102 void CSQCPlayer_ForceModel_PostUpdate(void)
 103 {
 104         self.forceplayermodels_savemodel = self.model;
 105         self.forceplayermodels_savemodelindex = self.modelindex;
 106         self.forceplayermodels_saveskin = self.skin;
 107         self.forceplayermodels_savecolormap = self.colormap;
 108
 109         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 110         {
 111                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 112                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 113                 if(!self.forceplayermodels_isgoodmodel)
 114                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 115         }
 116 }
 117 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 118 {
 119         // which one is ALWAYS good?
 120         if not(forceplayermodels_goodmodel)
 121         {
 122                 entity e;
 123                 e = spawn();
 124                 precache_model(cvar_defstring("_cl_playermodel"));
 125                 setmodel(e, cvar_defstring("_cl_playermodel"));
 126                 forceplayermodels_goodmodel = e.model;
 127                 forceplayermodels_goodmodelindex = e.modelindex;
 128                 remove(e);
 129         }
 130
 131         // first, try finding it from the server
 132         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 133         {
 134                 if(islocalplayer)
 135                 {
 136                         // trust server's idea of "own player model"
 137                         forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 138                         forceplayermodels_model = self.forceplayermodels_savemodel;
 139                         forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 140                         forceplayermodels_skin = self.forceplayermodels_saveskin;
 141                         forceplayermodels_attempted = 1;
 142                 }
 143         }
 144
 145         // forcemodel finding
 146         if(!forceplayermodels_attempted)
 147         {
 148                 forceplayermodels_attempted = 1;
 149
 150                 // only if this failed, find it out on our own
 151                 entity e;
 152                 e = spawn();
 153                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 154                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 155                 forceplayermodels_model = e.model;
 156                 forceplayermodels_modelindex = e.modelindex;
 157                 forceplayermodels_skin = autocvar__cl_playerskin;
 158                 remove(e);
 159         }
 160
 161         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 162         {
 163                 entity e;
 164                 e = spawn();
 165                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 166                 forceplayermodels_myisgoodmodel = fexists(e.model);
 167                 forceplayermodels_mymodel = e.model;
 168                 forceplayermodels_mymodelindex = e.modelindex;
 169                 remove(e);
 170         }
 171
 172         // apply it
 173         float isfriend;
 174         if(teamplay)
 175         {
 176                 cm = self.forceplayermodels_savecolormap;
 177                 cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(self.colormap - 1, "colors")) + 1024);
 178
 179                 isfriend = (cm == 1024 + 17 * myteam);
 180         }
 181         else
 182                 isfriend = islocalplayer;
 183
 184         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 185         {
 186                 self.model = forceplayermodels_mymodel;
 187                 self.modelindex = forceplayermodels_mymodelindex;
 188                 self.skin = autocvar_cl_forcemyplayerskin;
 189         }
 190         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 191         {
 192                 self.model = forceplayermodels_model;
 193                 self.modelindex = forceplayermodels_modelindex;
 194                 self.skin = forceplayermodels_skin;
 195         }
 196         else if(self.forceplayermodels_isgoodmodel)
 197         {
 198                 self.model = self.forceplayermodels_savemodel;
 199                 self.modelindex = self.forceplayermodels_savemodelindex;
 200                 self.skin = self.forceplayermodels_saveskin;
 201         }
 202         else
 203         {
 204                 self.model = forceplayermodels_goodmodel;
 205                 self.modelindex = forceplayermodels_goodmodelindex;
 206                 self.skin = self.forceplayermodels_saveskin;
 207         }
 208
 209         // forceplayercolors too
 210         if(teamplay)
 211         {
 212                 // own team's color is never forced
 213                 float forcecolor_friend = 0;
 214                 float forcecolor_enemy = 0;
 215                 float teams_count = 0;
 216                 float my_colors = 1024 + autocvar__cl_color;
 217                 entity tm;
 218
 219                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 220                         if(tm.team != COLOR_SPECTATOR)
 221                                 ++teams_count;
 222
 223                 if(autocvar_cl_forcemyplayercolors)
 224                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 225                 if(autocvar_cl_forceplayercolors && teams_count == 2)
 226                         forcecolor_enemy = 1024 + my_colors;
 227
 228                 if(forcecolor_enemy && !forcecolor_friend)
 229                 {
 230                         // only enemy color is forced?
 231                         // verify it is not equal to the friend color
 232                         if(forcecolor_enemy == 1024 + 17 * myteam)
 233                                 forcecolor_enemy = 0;
 234                 }
 235
 236                 if(forcecolor_friend && !forcecolor_enemy)
 237                 {
 238                         // only friend color is forced?
 239                         // verify it is not equal to the enemy color
 240                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 241                                 // note: we even compare against our own team.
 242                                 // if we rejected because we matched our OWN team color,
 243                                 // this is not bad; we then simply keep our color as is
 244                                 // anyway.
 245                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 246                                         forcecolor_friend = 0;
 247                 }
 248
 249                 float cm;
 250                 cm = self.forceplayermodels_savecolormap;
 251                 cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(self.colormap - 1, "colors")) + 1024);
 252
 253                 if(cm == 1024 + 17 * myteam)
 254                 {
 255                         if(forcecolor_friend)
 256                                 self.colormap = forcecolor_friend;
 257                 }
 258                 else
 259                 {
 260                         if(forcecolor_enemy)
 261                                 self.colormap = forcecolor_enemy;
 262                 }
 263         }
 264         else
 265         {
 266                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 267                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 268                 else if(autocvar_cl_forceplayercolors)
 269                         self.colormap = player_localnum + 1;
 270         }
 271 }
 272
 273 // FEATURE: fallback frames
 274 .float csqcmodel_saveframe;
 275 .float csqcmodel_saveframe2;
 276 .float csqcmodel_saveframe3;
 277 .float csqcmodel_saveframe4;
 278 .float csqcmodel_framecount;
 279
 280 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 281 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 282 {
 283         self.frame = self.csqcmodel_saveframe;
 284         self.frame2 = self.csqcmodel_saveframe2;
 285         self.frame3 = self.csqcmodel_saveframe3;
 286         self.frame4 = self.csqcmodel_saveframe4;
 287 }
 288 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 289 {
 290         self.csqcmodel_saveframe = self.frame;
 291         self.csqcmodel_saveframe2 = self.frame2;
 292         self.csqcmodel_saveframe3 = self.frame3;
 293         self.csqcmodel_saveframe4 = self.frame4;
 294
 295         // hack for death animations: set their frametime to zero in case a
 296         // player "pops in"
 297         if(isnew)
 298         {
 299 #define FIX_FRAMETIME(f,ft) \
 300                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 301                 { \
 302                         self.ft = self.death_time; \
 303                 }
 304                 FIX_FRAMETIME(frame, frame1time)
 305                 FIX_FRAMETIME(frame2, frame2time)
 306                 FIX_FRAMETIME(frame3, frame3time)
 307                 FIX_FRAMETIME(frame4, frame4time)
 308         }
 309         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 310 }
 311 float CSQCPlayer_FallbackFrame(float f)
 312 {
 313         if(frameduration(self.modelindex, f) > 0)
 314                 return f; // goooooood
 315         if(frameduration(self.modelindex, 1) <= 0)
 316                 return f; // this is a static model. We can't fix it if we wanted to
 317         switch(f)
 318         {
 319                 case 23: return 11; // anim_melee -> anim_shoot
 320                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 321                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 322                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 323                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 324                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 325                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 326                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 327         }
 328         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 329         return f;
 330 }
 331 void CSQCPlayer_FallbackFrame_Apply(void)
 332 {
 333         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 334         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 335         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 336         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 337 }
 338
 339 // FEATURE: auto tag_index
 340 .entity tag_entity;
 341 .float tag_entity_lastmodelindex;
 342 .float tag_index;
 343 void CSQCModel_AutoTagIndex_Apply(void)
 344 {
 345         if(self.tag_entity && wasfreed(self.tag_entity))
 346                 self.tag_entity = world;
 347
 348         if(self.tag_networkentity)
 349         {
 350                 // we are ATTACHED!
 351                 float changed = 0;
 352                 if(self.tag_entity.entnum != self.tag_networkentity)
 353                 {
 354                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 355                         changed = 1;
 356                 }
 357
 358                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 359                 if(self.tag_entity.classname == "csqcmodel")
 360                 {
 361                         entity oldself = self;
 362                         self = self.tag_entity;
 363                         CSQCModel_Hook_PreDraw();
 364                         self = oldself;
 365                 }
 366
 367                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 368                 {
 369                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 370                         changed = 1;
 371                 }
 372                 if(changed)
 373                 {
 374                         if(self.tag_entity)
 375                         {
 376                                 // the best part is: IT EXISTS
 377                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 378                                 {
 379                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 380                                         {
 381                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 382                                                 if(!self.tag_index)
 383                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 384                                                 if(!self.tag_index)
 385                                                 {
 386                                                         // we need to prevent this from 'appening
 387                                                         self.tag_entity = world;
 388                                                         self.drawmask = 0;
 389                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 390                                                 }
 391                                         }
 392                                         else if(self.tag_entity.isplayermodel)
 393                                         {
 394                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 395                                                 if(!self.tag_index)
 396                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 397                                                 if(!self.tag_index)
 398                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 399                                         }
 400                                 }
 401
 402                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 403                                 {
 404                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 405                                         if(!self.tag_index)
 406                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 407                                 }
 408                         }
 409                         else
 410                         {
 411                                 // damn, see you next frame
 412                                 self.drawmask = 0;
 413                         }
 414                 }
 415         }
 416 }
 417
 418 // FEATURE: EF_NODRAW workalike
 419 float EF_BRIGHTFIELD    = 1;
 420 float EF_BRIGHTLIGHT    = 4;
 421 float EF_DIMLIGHT       = 8;
 422 float EF_DOUBLESIDED = 32768;
 423 float EF_NOSELFSHADOW = 65536;
 424 float EF_DYNAMICMODELLIGHT = 131072;
 425 float MF_ROCKET  =   1; // leave a trail
 426 float MF_GRENADE =   2; // leave a trail
 427 float MF_GIB     =   4; // leave a trail
 428 float MF_ROTATE  =   8; // rotate (bonus items)
 429 float MF_TRACER  =  16; // green split trail
 430 float MF_ZOMGIB  =  32; // small blood trail
 431 float MF_TRACER2 =  64; // orange split trail
 432 float MF_TRACER3 = 128; // purple trail
 433 .float csqcmodel_effects;
 434 .float csqcmodel_modelflags;
 435 void CSQCModel_Effects_PreUpdate(void)
 436 {
 437         self.effects = self.csqcmodel_effects;
 438         self.modelflags = self.csqcmodel_modelflags;
 439 }
 440 void CSQCModel_Effects_PostUpdate(void)
 441 {
 442         self.csqcmodel_effects = self.effects;
 443         self.csqcmodel_modelflags = self.modelflags;
 444         self.effects = 0;
 445         self.modelflags = 0;
 446         if(self.csqcmodel_teleported)
 447                 Projectile_ResetTrail(self.origin);
 448 }
 449 void CSQCModel_Effects_Apply(void)
 450 {
 451         float eff = self.csqcmodel_effects;
 452         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 453
 454         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 455         self.effects = 0;
 456         self.traileffect = 0;
 457
 458         if(eff & EF_BRIGHTFIELD)
 459                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 460         // ignoring EF_MUZZLEFLASH
 461         if(eff & EF_BRIGHTLIGHT)
 462                 adddynamiclight(self.origin, 400, '3 3 3');
 463         if(eff & EF_DIMLIGHT)
 464                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 465         if((eff & EF_NODRAW) || (self.alpha < 0))
 466                 self.drawmask = 0;
 467         if(eff & EF_ADDITIVE)
 468                 self.renderflags |= RF_ADDITIVE;
 469         if(eff & EF_BLUE)
 470                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 471         if(eff & EF_RED)
 472                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 473         // ignoring EF_NOGUNBOB
 474         if(eff & EF_FULLBRIGHT)
 475                 self.renderflags |= RF_FULLBRIGHT;
 476         if(eff & EF_FLAME)
 477                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 478         if(eff & EF_STARDUST)
 479                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 480         if(eff & EF_NOSHADOW)
 481                 self.renderflags |= RF_NOSHADOW;
 482         if(eff & EF_NODEPTHTEST)
 483                 self.renderflags |= RF_DEPTHHACK;
 484         // ignoring EF_SELECTABLE
 485         if(eff & EF_DOUBLESIDED)
 486                 self.effects |= EF_DOUBLESIDED;
 487         if(eff & EF_NOSELFSHADOW)
 488                 self.effects |= EF_NOSELFSHADOW;
 489         if(eff & EF_DYNAMICMODELLIGHT)
 490                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 491         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 492         if(self.csqcmodel_modelflags & MF_ROCKET)
 493                 self.traileffect = particleeffectnum("TR_ROCKET");
 494         if(self.csqcmodel_modelflags & MF_GRENADE)
 495                 self.traileffect = particleeffectnum("TR_GRENADE");
 496         if(self.csqcmodel_modelflags & MF_GIB)
 497                 self.traileffect = particleeffectnum("TR_BLOOD");
 498         if(self.csqcmodel_modelflags & MF_ROTATE)
 499         {
 500                 self.renderflags |= RF_USEAXIS;
 501                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 502         }
 503         if(self.csqcmodel_modelflags & MF_TRACER)
 504                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 505         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 506                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 507         if(self.csqcmodel_modelflags & MF_TRACER2)
 508                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 509         if(self.csqcmodel_modelflags & MF_TRACER3)
 510                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 511
 512         if(self.drawmask)
 513                 Projectile_DrawTrail(self.origin);
 514         else
 515                 Projectile_ResetTrail(self.origin);
 516
 517         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 518                 self.renderflags |= RF_ADDITIVE;
 519                 // also special in CSQCPlayer_GlowMod_Apply
 520 }
 521
 522 // FEATURE: auto glowmod
 523 .vector glowmod;
 524 void CSQCPlayer_GlowMod_Apply(void)
 525 {
 526         float cm = self.colormap;
 527
 528         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 529                 cm = 1024;
 530
 531         if(self.colormap > 0)
 532                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 533         else
 534                 self.glowmod = '1 1 1';
 535
 536         if(autocvar_cl_deathglow > 0)
 537                 if(self.csqcmodel_isdead)
 538                 {
 539                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 540                         // prevent the zero vector
 541                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 542                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 543                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 544                 }
 545 }
 546
 547 // general functions
 548 .float csqcmodel_predraw_run;
 549 void CSQCModel_Hook_PreDraw()
 550 {
 551         if(self.csqcmodel_predraw_run == framecount)
 552                 return;
 553         self.csqcmodel_predraw_run = framecount;
 554
 555         if(!self.modelindex || self.model == "null")
 556         {
 557                 self.drawmask = 0;
 558                 return;
 559         }
 560         else
 561                 self.drawmask = MASK_NORMAL;
 562
 563         if(self.isplayermodel) // this checks if it's a player MODEL!
 564         {
 565                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 566                 CSQCPlayer_GlowMod_Apply();
 567                 CSQCPlayer_LOD_Apply();
 568                 CSQCPlayer_FallbackFrame_Apply();
 569         }
 570
 571         CSQCModel_AutoTagIndex_Apply();
 572
 573         CSQCModel_Effects_Apply();
 574 }
 575
 576 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 577 {
 578         // revert to values from server
 579         CSQCModel_Effects_PreUpdate();
 580         if(self.isplayermodel)
 581         {
 582                 CSQCPlayer_FallbackFrame_PreUpdate();
 583                 CSQCPlayer_ForceModel_PreUpdate();
 584         }
 585 }
 586
 587 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 588 {
 589         // is it a player model? (shared state)
 590         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 591
 592         // save values set by server
 593         if(self.isplayermodel)
 594         {
 595                 CSQCPlayer_ForceModel_PostUpdate();
 596                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 597         }
 598         CSQCModel_Effects_PostUpdate();
 599 }