qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float stringwidth_colors(string s, vector theSize)
 136 {
 137         return stringwidth(s, TRUE, theSize);
 138 }
 139
 140 float stringwidth_nocolors(string s, vector theSize)
 141 {
 142         return stringwidth(s, FALSE, theSize);
 143 }
 144
 145 void drawstringright(vector position, string text, vector scale, vector rgb, float theAlpha, float flag)
 146 {
 147         position_x -= 2 / 3 * strlen(text) * scale_x;
 148         drawstring(position, text, scale, rgb, theAlpha, flag);
 149 }
 150
 151 void drawstringcenter(vector position, string text, vector scale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * scale_x);
 154         drawstring(position, text, scale, rgb, theAlpha, flag);
 155 }
 156
 157 // return the string of the onscreen race timer
 158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 159 {
 160         string col;
 161         string timestr;
 162         string cpname;
 163         string lapstr;
 164         lapstr = "";
 165
 166         if(histime == 0) // goal hit
 167         {
 168                 if(mytime > 0)
 169                 {
 170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 171                         col = "^1";
 172                 }
 173                 else if(mytime == 0)
 174                 {
 175                         timestr = "+0.0";
 176                         col = "^3";
 177                 }
 178                 else
 179                 {
 180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 181                         col = "^2";
 182                 }
 183
 184                 if(lapdelta > 0)
 185                 {
 186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 187                         col = "^2";
 188                 }
 189                 else if(lapdelta < 0)
 190                 {
 191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 192                         col = "^1";
 193                 }
 194         }
 195         else if(histime > 0) // anticipation
 196         {
 197                 if(mytime >= histime)
 198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 199                 else
 200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 201                 col = "^3";
 202         }
 203         else
 204         {
 205                 col = "^7";
 206                 timestr = "";
 207         }
 208
 209         if(cp == 254)
 210                 cpname = _("Start line");
 211         else if(cp == 255)
 212                 cpname = _("Finish line");
 213         else if(cp)
 214                 cpname = sprintf(_("Intermediate %d"), cp);
 215         else
 216                 cpname = _("Finish line");
 217
 218         if(histime < 0)
 219                 return strcat(col, cpname);
 220         else if(hisname == "")
 221                 return strcat(col, sprintf(_("%s (%s)"), cpname, timestr));
 222         else
 223                 return strcat(col, sprintf(_("%s (%s %s)"), cpname, timestr, strcat(hisname, col, lapstr)));
 224 }
 225
 226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 227 float race_CheckName(string net_name) {
 228         float i;
 229         for (i=RANKINGS_CNT-1;i>=0;--i)
 230                 if(grecordholder[i] == net_name)
 231                         return i+1;
 232         return 0;
 233 }
 234
 235 float GetPlayerColorForce(float i)
 236 {
 237         if(!teamplay)
 238                 return 0;
 239         else
 240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 241 }
 242
 243 float GetPlayerColor(float i)
 244 {
 245         if(!playerslots[i].gotscores) // unconnected
 246                 return NUM_SPECTATOR;
 247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 248                 return NUM_SPECTATOR;
 249         else
 250                 return GetPlayerColorForce(i);
 251 }
 252
 253 string GetPlayerName(float i)
 254 {
 255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 256 }
 257
 258
 259 /*
 260 ==================
 261 HUD panels
 262 ==================
 263 */
 264
 265 // draw the background/borders
 266 #define HUD_Panel_DrawBg(theAlpha)\
 267 if(panel_bg != "0" && panel_bg != "")\
 268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 269
 270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 272 {
 273         if(!length_ratio || !theAlpha)
 274                 return;
 275         if(length_ratio > 1)
 276                 length_ratio = 1;
 277         if (baralign == 3)
 278         {
 279                 if(length_ratio < -1)
 280                         length_ratio = -1;
 281         }
 282         else if(length_ratio < 0)
 283                 return;
 284
 285         vector square;
 286         vector width, height;
 287         if(vertical) {
 288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 289                 if(precache_pic(pic) == "") {
 290                         pic = "gfx/hud/default/progressbar_vertical";
 291                 }
 292
 293         if (baralign == 1) // bottom align
 294                         theOrigin_y += (1 - length_ratio) * theSize_y;
 295         else if (baralign == 2) // center align
 296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 297         else if (baralign == 3) // center align, positive values down, negative up
 298                 {
 299                         theSize_y *= 0.5;
 300                         if (length_ratio > 0)
 301                                 theOrigin_y += theSize_y;
 302                         else
 303                         {
 304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 305                                 length_ratio = -length_ratio;
 306                         }
 307                 }
 308                 theSize_y *= length_ratio;
 309
 310                 vector bH;
 311                 width = eX * theSize_x;
 312                 height = eY * theSize_y;
 313                 if(theSize_y <= theSize_x * 2)
 314                 {
 315                         // button not high enough
 316                         // draw just upper and lower part then
 317                         square = eY * theSize_y * 0.5;
 318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 321                 }
 322                 else
 323                 {
 324                         square = eY * theSize_x;
 325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 328                 }
 329         } else {
 330                 pic = strcat(hud_skin_path, "/", pic);
 331                 if(precache_pic(pic) == "") {
 332                         pic = "gfx/hud/default/progressbar";
 333                 }
 334
 335                 if (baralign == 1) // right align
 336                         theOrigin_x += (1 - length_ratio) * theSize_x;
 337         else if (baralign == 2) // center align
 338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 339         else if (baralign == 3) // center align, positive values on the right, negative on the left
 340                 {
 341                         theSize_x *= 0.5;
 342                         if (length_ratio > 0)
 343                                 theOrigin_x += theSize_x;
 344                         else
 345                         {
 346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 347                                 length_ratio = -length_ratio;
 348                         }
 349                 }
 350                 theSize_x *= length_ratio;
 351
 352                 vector bW;
 353                 width = eX * theSize_x;
 354                 height = eY * theSize_y;
 355                 if(theSize_x <= theSize_y * 2)
 356                 {
 357                         // button not wide enough
 358                         // draw just left and right part then
 359                         square = eX * theSize_x * 0.5;
 360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 363                 }
 364                 else
 365                 {
 366                         square = eX * theSize_y;
 367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 370                 }
 371         }
 372 }
 373
 374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 375 {
 376         if(!theAlpha)
 377                 return;
 378
 379         string pic;
 380         pic = strcat(hud_skin_path, "/num_leading");
 381         if(precache_pic(pic) == "") {
 382                 pic = "gfx/hud/default/num_leading";
 383         }
 384
 385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 386         if(mySize_x/mySize_y > 2)
 387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 389 }
 390
 391 // Weapon icons (#0)
 392 //
 393 entity weaponorder[WEP_MAXCOUNT];
 394 void weaponorder_swap(float i, float j, entity pass)
 395 {
 396         entity h;
 397         h = weaponorder[i];
 398         weaponorder[i] = weaponorder[j];
 399         weaponorder[j] = h;
 400 }
 401
 402 string weaponorder_cmp_str;
 403 float weaponorder_cmp(float i, float j, entity pass)
 404 {
 405         float ai, aj;
 406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 409 }
 410
 411 float GetAmmoStat(float i)
 412 {
 413         switch(i)
 414         {
 415                 case 0: return STAT_SHELLS;
 416                 case 1: return STAT_NAILS;
 417                 case 2: return STAT_ROCKETS;
 418                 case 3: return STAT_CELLS;
 419                 case 4: return STAT_FUEL;
 420                 default: return -1;
 421         }
 422 }
 423
 424 float GetAmmoTypeForWep(float i)
 425 {
 426         switch(i)
 427         {
 428                 case WEP_SHOTGUN: return 0;
 429                 case WEP_UZI: return 1;
 430                 case WEP_GRENADE_LAUNCHER: return 2;
 431                 case WEP_MINE_LAYER: return 2;
 432                 case WEP_ELECTRO: return 3;
 433                 case WEP_CRYLINK: return 3;
 434                 case WEP_HLAC: return 3;
 435                 case WEP_MINSTANEX: return 3;
 436                 case WEP_NEX: return 3;
 437                 case WEP_RIFLE: return 1;
 438                 case WEP_HAGAR: return 2;
 439                 case WEP_ROCKET_LAUNCHER: return 2;
 440                 case WEP_SEEKER: return 2;
 441                 case WEP_FIREBALL: return 4;
 442                 case WEP_HOOK: return 3;
 443                 default: return -1;
 444         }
 445 }
 446
 447 void HUD_Weapons(void)
 448 {
 449         // declarations
 450         WepSet weapons_stat = WepSet_GetFromStat();
 451         float i, f, a;
 452         float screen_ar, center_x = 0, center_y;
 453         float weapon_count, weapon_id;
 454         float row, column, rows = 0, columns;
 455         float aspect = autocvar_hud_panel_weapons_aspect;
 456
 457         float panel_weapon_accuracy;
 458
 459         float timeout = autocvar_hud_panel_weapons_timeout;
 460         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 461         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 462
 463         float ammo_type, ammo_full;
 464         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 465         vector ammo_color = '1 0 1';
 466         float ammo_alpha = 1;
 467
 468         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 469         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 470
 471         vector weapon_pos, weapon_size = '0 0 0';
 472         local noref vector old_panel_size; // fteqcc sucks
 473         vector color;
 474
 475         // check to see if we want to continue
 476         if(hud != HUD_NORMAL) { return; }
 477
 478         if(!autocvar__hud_configure)
 479         {
 480                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 481                         return;
 482                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 483                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 484                 {
 485                         weaponprevtime = time;
 486                         return;
 487                 }
 488         }
 489
 490         // update generic hud functions
 491         HUD_Panel_UpdateCvars();
 492         HUD_Panel_ApplyFadeAlpha();
 493
 494         draw_beginBoldFont();
 495
 496         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 497         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 498         {
 499                 float weapon_cnt;
 500                 if(weaponorder_bypriority)
 501                         strunzone(weaponorder_bypriority);
 502                 if(weaponorder_byimpulse)
 503                         strunzone(weaponorder_byimpulse);
 504
 505                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 506                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 507                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 508
 509                 weapon_cnt = 0;
 510                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 511                 {
 512                         self = get_weaponinfo(i);
 513                         if(self.impulse >= 0)
 514                         {
 515                                 weaponorder[weapon_cnt] = self;
 516                                 ++weapon_cnt;
 517                         }
 518                 }
 519                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 520                         weaponorder[i] = world;
 521                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 522
 523                 weaponorder_cmp_str = string_null;
 524         }
 525
 526         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 527                 complain_weapon = 0;
 528
 529         // determine which weapons are going to be shown
 530         if (autocvar_hud_panel_weapons_onlyowned)
 531         {
 532                 if(autocvar__hud_configure)
 533                 {
 534                         if (!weapons_stat)
 535                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 536                                         weapons_stat |= WepSet_FromWeapon(i);
 537
 538                         if(menu_enabled != 2)
 539                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 540                 }
 541
 542                 // do we own this weapon?
 543                 weapon_count = 0;
 544                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 545                         if(weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon))
 546                                 ++weapon_count;
 547
 548                 // add it anyway if weaponcomplain is shown
 549                 if(complain_weapon)
 550                         ++weapon_count;
 551
 552                 // might as well commit suicide now, no reason to live ;)
 553                 if (weapon_count == 0)
 554                 {
 555                         draw_endBoldFont();
 556                         return;
 557                 }
 558
 559                 old_panel_size = panel_size;
 560                 if(panel_bg_padding)
 561                         old_panel_size -= '2 2 0' * panel_bg_padding;
 562
 563                 // first find values for the standard table (with all the weapons)
 564                 rows = old_panel_size_y/old_panel_size_x;
 565                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
 566                 columns = ceil(WEP_COUNT/rows);
 567                 weapon_size_x = old_panel_size_x / columns;
 568                 weapon_size_y = old_panel_size_y / rows;
 569
 570                 // change table values to include only the owned weapons
 571                 // weapon_size won't be changed
 572                 if(weapon_count <= rows)
 573                 {
 574                         rows = weapon_count;
 575                         columns = 1;
 576                 }
 577                 else
 578                         columns = ceil(weapon_count / rows);
 579
 580                 // reduce size of the panel
 581                 panel_size_x = columns * weapon_size_x;
 582                 panel_size_y = rows * weapon_size_y;
 583                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 584                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 585                 if(panel_bg_padding)
 586                         panel_size += '2 2 0' * panel_bg_padding;
 587         }
 588         else
 589                 weapon_count = WEP_COUNT;
 590
 591         // animation for fading in/out the panel respectively when not in use
 592         if(!autocvar__hud_configure)
 593         {
 594                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 595                 {
 596                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 597
 598                         // fade the panel alpha
 599                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 600                         {
 601                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 602                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 603                         }
 604                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 605                         {
 606                                 panel_bg_alpha *= (1 - f);
 607                                 panel_fg_alpha *= (1 - f);
 608                         }
 609
 610                         // move the panel off the screen
 611                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 612                         {
 613                                 f *= f; // for a cooler movement
 614                                 center_x = panel_pos_x + panel_size_x/2;
 615                                 center_y = panel_pos_y + panel_size_y/2;
 616                                 screen_ar = vid_conwidth/vid_conheight;
 617                                 if (center_x/center_y < screen_ar) //bottom left
 618                                 {
 619                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 620                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 621                                         else //left
 622                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 623                                 }
 624                                 else //top right
 625                                 {
 626                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 627                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 628                                         else //top
 629                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 630                                 }
 631                                 if(f == 1)
 632                                         center_x = -1; // mark the panel as off screen
 633                         }
 634                         weaponprevtime = time - (1 - f) * timein_effect_length;
 635                 }
 636                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 637                 {
 638                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 639
 640                         // fade the panel alpha
 641                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 642                         {
 643                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 644                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 645                         }
 646                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 647                         {
 648                                 panel_bg_alpha *= (f);
 649                                 panel_fg_alpha *= (f);
 650                         }
 651
 652                         // move the panel back on screen
 653                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 654                         {
 655                                 f *= f; // for a cooler movement
 656                                 f = 1 - f;
 657                                 center_x = panel_pos_x + panel_size_x/2;
 658                                 center_y = panel_pos_y + panel_size_y/2;
 659                                 screen_ar = vid_conwidth/vid_conheight;
 660                                 if (center_x/center_y < screen_ar) //bottom left
 661                                 {
 662                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 663                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 664                                         else //left
 665                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 666                                 }
 667                                 else //top right
 668                                 {
 669                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 670                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 671                                         else //top
 672                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 673                                 }
 674                         }
 675                 }
 676         }
 677
 678         // draw the background, then change the virtual size of it to better fit other items inside
 679         HUD_Panel_DrawBg(1);
 680
 681         if(center_x == -1)
 682         {
 683                 draw_endBoldFont();
 684                 return;
 685         }
 686
 687         if(panel_bg_padding)
 688         {
 689                 panel_pos += '1 1 0' * panel_bg_padding;
 690                 panel_size -= '2 2 0' * panel_bg_padding;
 691         }
 692
 693         // after the sizing and animations are done, update the other values
 694
 695         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 696         {
 697                 rows = panel_size_y/panel_size_x;
 698                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
 699                 columns = ceil(weapon_count/rows);
 700                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 701         }
 702
 703         // calculate position/size for visual bar displaying ammount of ammo status
 704         if (autocvar_hud_panel_weapons_ammo)
 705         {
 706                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 707                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 708
 709                 if(weapon_size_x/weapon_size_y > aspect)
 710                 {
 711                         barsize_x = aspect * weapon_size_y;
 712                         barsize_y = weapon_size_y;
 713                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 714                 }
 715                 else
 716                 {
 717                         barsize_y = 1/aspect * weapon_size_x;
 718                         barsize_x = weapon_size_x;
 719                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 720                 }
 721         }
 722         if(autocvar_hud_panel_weapons_accuracy)
 723                 Accuracy_LoadColors();
 724
 725         row = column = 0;
 726         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 727         {
 728                 // retrieve information about the current weapon to be drawn
 729                 self = weaponorder[i];
 730                 weapon_id = self.impulse;
 731
 732                 // skip if this weapon doesn't exist
 733                 if(!self || weapon_id < 0) { continue; }
 734
 735                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 736                 if(autocvar_hud_panel_weapons_onlyowned)
 737                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 738                         continue;
 739
 740                 // figure out the drawing position of weapon
 741                 weapon_pos = (panel_pos
 742                         + eX * column * weapon_size_x
 743                         + eY * row * weapon_size_y);
 744
 745                 // draw background behind currently selected weapon
 746                 if(self.weapon == switchweapon)
 747                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 748
 749                 // draw the weapon accuracy
 750                 if(autocvar_hud_panel_weapons_accuracy)
 751                 {
 752                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 753                         if(panel_weapon_accuracy >= 0)
 754                         {
 755                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 756                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 757                         }
 758                 }
 759
 760                 // drawing all the weapon items
 761                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 762                 {
 763                         // draw the weapon image
 764                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 765
 766                         // draw weapon label string
 767                         switch(autocvar_hud_panel_weapons_label)
 768                         {
 769                                 case 1: // weapon number
 770                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 771                                         break;
 772
 773                                 case 2: // bind
 774                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 775                                         break;
 776
 777                                 case 3: // weapon name
 778                                         drawstring(weapon_pos, self.netname, '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 779                                         break;
 780
 781                                 default: // nothing
 782                                         break;
 783                         }
 784
 785                         // draw ammo status bar
 786                         if(autocvar_hud_panel_weapons_ammo && self.weapon != WEP_TUBA && self.weapon != WEP_LASER && self.weapon != WEP_PORTO)
 787                         {
 788                                 a = 0;
 789                                 ammo_type = GetAmmoTypeForWep(self.weapon);
 790                                 if(ammo_type != -1)
 791                                         a = getstati(GetAmmoStat(ammo_type)); // how much ammo do we have?
 792
 793                                 if(a > 0)
 794                                 {
 795                                         switch(ammo_type) {
 796                                                 case 0: ammo_full = autocvar_hud_panel_weapons_ammo_full_shells; break;
 797                                                 case 1: ammo_full = autocvar_hud_panel_weapons_ammo_full_nails; break;
 798                                                 case 2: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 799                                                 case 3: ammo_full = autocvar_hud_panel_weapons_ammo_full_cells; break;
 800                                                 case 4: ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel; break;
 801                                                 default: ammo_full = 60;
 802                                         }
 803
 804                                         drawsetcliparea(
 805                                                 weapon_pos_x + baroffset_x,
 806                                                 weapon_pos_y + baroffset_y,
 807                                                 barsize_x * bound(0, a/ammo_full, 1),
 808                                                 barsize_y);
 809                                         drawpic_aspect_skin(weapon_pos, "weapon_ammo", weapon_size, ammo_color, ammo_alpha, DRAWFLAG_NORMAL);
 810                                         drawresetcliparea();
 811                                 }
 812                         }
 813                 }
 814                 else // draw a "ghost weapon icon" if you don't have the weapon
 815                 {
 816                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 817                 }
 818
 819                 // draw the complain message
 820                 if(self.weapon == complain_weapon)
 821                 {
 822                         if(fadetime)
 823                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 824                         else
 825                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 826
 827                         string s;
 828                         if(complain_weapon_type == 0) {
 829                                 s = _("Out of ammo");
 830                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 831                         }
 832                         else if(complain_weapon_type == 1) {
 833                                 s = _("Don't have");
 834                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 835                         }
 836                         else {
 837                                 s = _("Unavailable");
 838                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 839                         }
 840                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 841                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 842                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 843                 }
 844
 845                 // continue with new position for the next weapon
 846                 ++row;
 847                 if(row >= rows)
 848                 {
 849                         row = 0;
 850                         ++column;
 851                 }
 852         }
 853
 854         draw_endBoldFont();
 855 }
 856
 857 // Ammo (#1)
 858 //
 859 // TODO: macro
 860 float GetAmmoItemCode(float i)
 861 {
 862         switch(i)
 863         {
 864                 case 0: return IT_SHELLS;
 865                 case 1: return IT_NAILS;
 866                 case 2: return IT_ROCKETS;
 867                 case 3: return IT_CELLS;
 868                 case 4: return IT_FUEL;
 869                 default: return -1;
 870         }
 871 }
 872
 873 string GetAmmoPicture(float i)
 874 {
 875         switch(i)
 876         {
 877                 case 0: return "ammo_shells";
 878                 case 1: return "ammo_bullets";
 879                 case 2: return "ammo_rockets";
 880                 case 3: return "ammo_cells";
 881                 case 4: return "ammo_fuel";
 882                 default: return "";
 883         }
 884 }
 885
 886 void DrawAmmoItem(vector myPos, vector mySize, float itemcode, float currently_selected, float infinite_ammo)
 887 {
 888         float a;
 889         if(autocvar__hud_configure)
 890         {
 891                 currently_selected = (itemcode == 2); //rockets always selected
 892                 a = 31 + mod(itemcode*93, 128);
 893         }
 894         else
 895                 a = getstati(GetAmmoStat(itemcode)); // how much ammo do we have of type itemcode?
 896
 897         vector color;
 898         if(infinite_ammo)
 899                 color = '0 0.5 0.75';
 900         else if(a < 10)
 901                 color = '0.7 0 0';
 902         else
 903                 color = '1 1 1';
 904
 905         float theAlpha;
 906         if(currently_selected)
 907                 theAlpha = 1;
 908         else
 909                 theAlpha = 0.7;
 910
 911         vector picpos, numpos;
 912         if(autocvar_hud_panel_ammo_iconalign)
 913         {
 914                 numpos = myPos;
 915                 picpos = myPos + eX * 2 * mySize_y;
 916         }
 917         else
 918         {
 919                 numpos = myPos + eX * mySize_y;
 920                 picpos = myPos;
 921         }
 922
 923         if (currently_selected)
 924                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 925
 926     if(a > 0 && autocvar_hud_panel_ammo_progressbar)
 927         HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, a/autocvar_hud_panel_ammo_maxammo, 0, 0, color, autocvar_hud_progressbar_alpha * panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 928
 929     if(autocvar_hud_panel_ammo_text)
 930     {
 931         if(a > 0 || infinite_ammo)
 932             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 933         else // "ghost" ammo count
 934             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 935     }
 936         if(a > 0 || infinite_ammo)
 937                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 938         else // "ghost" ammo icon
 939                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 940 }
 941
 942 void HUD_Ammo(void)
 943 {
 944     if(hud != HUD_NORMAL) return;
 945         if(!autocvar__hud_configure)
 946         {
 947                 if(!autocvar_hud_panel_ammo) return;
 948                 if(spectatee_status == -1) return;
 949         }
 950
 951         HUD_Panel_UpdateCvars();
 952         HUD_Panel_ApplyFadeAlpha();
 953
 954         draw_beginBoldFont();
 955
 956         vector pos, mySize;
 957         pos = panel_pos;
 958         mySize = panel_size;
 959
 960         HUD_Panel_DrawBg(1);
 961         if(panel_bg_padding)
 962         {
 963                 pos += '1 1 0' * panel_bg_padding;
 964                 mySize -= '2 2 0' * panel_bg_padding;
 965         }
 966
 967         float rows = 0, columns, row, column;
 968         vector ammo_size;
 969         if (autocvar_hud_panel_ammo_onlycurrent)
 970                 ammo_size = mySize;
 971         else
 972         {
 973                 rows = mySize_y/mySize_x;
 974                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
 975                 //                               ^^^ ammo item aspect goes here
 976
 977                 columns = ceil(AMMO_COUNT/rows);
 978
 979                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
 980         }
 981
 982         local vector offset = '0 0 0'; // fteqcc sucks
 983         float newSize;
 984         if(ammo_size_x/ammo_size_y > 3)
 985         {
 986                 newSize = 3 * ammo_size_y;
 987                 offset_x = ammo_size_x - newSize;
 988                 pos_x += offset_x/2;
 989                 ammo_size_x = newSize;
 990         }
 991         else
 992         {
 993                 newSize = 1/3 * ammo_size_x;
 994                 offset_y = ammo_size_y - newSize;
 995                 pos_y += offset_y/2;
 996                 ammo_size_y = newSize;
 997         }
 998
 999         float i, stat_items, currently_selected, infinite_ammo;
1000         infinite_ammo = FALSE;
1001         if (autocvar_hud_panel_ammo_onlycurrent)
1002         {
1003                 if(autocvar__hud_configure)
1004                 {
1005                         DrawAmmoItem(pos, ammo_size, 2, true, FALSE); //show rockets
1006                 }
1007                 else
1008                 {
1009                         stat_items = getstati(STAT_ITEMS, 0, 24);
1010                         if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1011                                 infinite_ammo = TRUE;
1012                         for (i = 0; i < AMMO_COUNT; ++i) {
1013                                 currently_selected = stat_items & GetAmmoItemCode(i);
1014                                 if (currently_selected)
1015                                 {
1016                                         DrawAmmoItem(pos, ammo_size, i, true, infinite_ammo);
1017                                         break;
1018                                 }
1019                         }
1020                 }
1021         }
1022         else
1023         {
1024                 stat_items = getstati(STAT_ITEMS, 0, 24);
1025                 if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1026                         infinite_ammo = TRUE;
1027                 row = column = 0;
1028                 for (i = 0; i < AMMO_COUNT; ++i) {
1029                         currently_selected = stat_items & GetAmmoItemCode(i);
1030                         DrawAmmoItem(pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y), ammo_size, i, currently_selected, infinite_ammo);
1031                         ++row;
1032                         if(row >= rows)
1033                         {
1034                                 row = 0;
1035                                 column = column + 1;
1036                         }
1037                 }
1038         }
1039
1040         draw_endBoldFont();
1041 }
1042
1043 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1044 {
1045         vector newPos = '0 0 0', newSize = '0 0 0';
1046         vector picpos, numpos;
1047
1048         if (vertical)
1049         {
1050                 if(mySize_y/mySize_x > 2)
1051                 {
1052                         newSize_y = 2 * mySize_x;
1053                         newSize_x = mySize_x;
1054
1055                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1056                         newPos_x = myPos_x;
1057                 }
1058                 else
1059                 {
1060                         newSize_x = 1/2 * mySize_y;
1061                         newSize_y = mySize_y;
1062
1063                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1064                         newPos_y = myPos_y;
1065                 }
1066
1067                 if(icon_right_align)
1068                 {
1069                         numpos = newPos;
1070                         picpos = newPos + eY * newSize_x;
1071                 }
1072                 else
1073                 {
1074                         picpos = newPos;
1075                         numpos = newPos + eY * newSize_x;
1076                 }
1077
1078                 newSize_y /= 2;
1079                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1080                 // make number smaller than icon, it looks better
1081                 // reduce only y to draw numbers with different number of digits with the same y size
1082                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1083                 newSize_y *= 0.7;
1084                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1085                 return;
1086         }
1087
1088         if(mySize_x/mySize_y > 3)
1089         {
1090                 newSize_x = 3 * mySize_y;
1091                 newSize_y = mySize_y;
1092
1093                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1094                 newPos_y = myPos_y;
1095         }
1096         else
1097         {
1098                 newSize_y = 1/3 * mySize_x;
1099                 newSize_x = mySize_x;
1100
1101                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1102                 newPos_x = myPos_x;
1103         }
1104
1105         if(icon_right_align) // right align
1106         {
1107                 numpos = newPos;
1108                 picpos = newPos + eX * 2 * newSize_y;
1109         }
1110         else // left align
1111         {
1112                 numpos = newPos + eX * newSize_y;
1113                 picpos = newPos;
1114         }
1115
1116         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1117         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1118         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1119         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1120 }
1121
1122 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1123 {
1124         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1125 }
1126
1127 // Powerups (#2)
1128 //
1129 void HUD_Powerups(void)
1130 {
1131         float strength_time, shield_time, superweapons_time;
1132         if(!autocvar__hud_configure)
1133         {
1134                 if(!autocvar_hud_panel_powerups) return;
1135                 if(spectatee_status == -1) return;
1136                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1137                 if (getstati(STAT_HEALTH) <= 0) return;
1138
1139                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1140                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1141                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1142
1143                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1144                         superweapons_time = 99; // force max
1145
1146                 // prevent stuff to show up on mismatch that will be fixed next frame
1147                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1148                         superweapons_time = 0;
1149         }
1150         else
1151         {
1152                 strength_time = 15;
1153                 shield_time = 27;
1154                 superweapons_time = 13;
1155         }
1156
1157         HUD_Panel_UpdateCvars();
1158         HUD_Panel_ApplyFadeAlpha();
1159
1160         draw_beginBoldFont();
1161
1162         vector pos, mySize;
1163         pos = panel_pos;
1164         mySize = panel_size;
1165
1166         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1167         if(panel_bg_padding)
1168         {
1169                 pos += '1 1 0' * panel_bg_padding;
1170                 mySize -= '2 2 0' * panel_bg_padding;
1171         }
1172
1173         float panel_ar = mySize_x/mySize_y;
1174         float is_vertical = (panel_ar < 1);
1175         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1176
1177         float superweapons_is = -1;
1178
1179         if(superweapons_time)
1180         {
1181                 if(strength_time)
1182                 {
1183                         if(shield_time)
1184                                 superweapons_is = 0;
1185                         else
1186                                 superweapons_is = 2;
1187                 }
1188                 else
1189                 {
1190                         if(shield_time)
1191                                 superweapons_is = 1;
1192                         else
1193                                 superweapons_is = 2;
1194                 }
1195         }
1196
1197         // FIXME handle superweapons here
1198         if(superweapons_is == 0)
1199         {
1200                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1201                 {
1202                         mySize_x *= (1.0 / 3.0);
1203                         superweapons_offset_x = mySize_x;
1204                         if (autocvar_hud_panel_powerups_flip)
1205                                 shield_offset_x = 2*mySize_x;
1206                         else
1207                                 strength_offset_x = 2*mySize_x;
1208                 }
1209                 else
1210                 {
1211                         mySize_y *= (1.0 / 3.0);
1212                         superweapons_offset_y = mySize_y;
1213                         if (autocvar_hud_panel_powerups_flip)
1214                                 shield_offset_y = 2*mySize_y;
1215                         else
1216                                 strength_offset_y = 2*mySize_y;
1217                 }
1218         }
1219         else
1220         {
1221                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1222                 {
1223                         mySize_x *= 0.5;
1224                         if (autocvar_hud_panel_powerups_flip)
1225                                 shield_offset_x = mySize_x;
1226                         else
1227                                 strength_offset_x = mySize_x;
1228                 }
1229                 else
1230                 {
1231                         mySize_y *= 0.5;
1232                         if (autocvar_hud_panel_powerups_flip)
1233                                 shield_offset_y = mySize_y;
1234                         else
1235                                 strength_offset_y = mySize_y;
1236                 }
1237         }
1238
1239         float shield_baralign, strength_baralign, superweapons_baralign;
1240         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1241
1242         if (autocvar_hud_panel_powerups_flip)
1243         {
1244                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1245                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1246                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1247                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1248         }
1249         else
1250         {
1251                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1252                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1253                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1254                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1255         }
1256
1257         if(superweapons_is == 0)
1258         {
1259                 superweapons_iconalign = strength_iconalign;
1260                 superweapons_baralign = 2;
1261         }
1262         else if(superweapons_is == 1)
1263         {
1264                 superweapons_offset = strength_offset;
1265                 superweapons_iconalign = strength_iconalign;
1266                 superweapons_baralign = strength_baralign;
1267         }
1268         else // if(superweapons_is == 2)
1269         {
1270                 superweapons_offset = shield_offset;
1271                 superweapons_iconalign = shield_iconalign;
1272                 superweapons_baralign = shield_baralign;
1273         }
1274
1275         if(shield_time)
1276         {
1277                 const float maxshield = 30;
1278                 float shield = ceil(shield_time);
1279                 if(autocvar_hud_panel_powerups_progressbar)
1280                 {
1281                         HUD_Panel_GetProgressBarColor(shield);
1282                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1283                 }
1284                 if(autocvar_hud_panel_powerups_text)
1285                 {
1286                         if(shield > 1)
1287                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1288                         if(shield <= 5)
1289                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1290                 }
1291         }
1292
1293         if(strength_time)
1294         {
1295                 const float maxstrength = 30;
1296                 float strength = ceil(strength_time);
1297                 if(autocvar_hud_panel_powerups_progressbar)
1298                 {
1299                         HUD_Panel_GetProgressBarColor(strength);
1300                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1301                 }
1302                 if(autocvar_hud_panel_powerups_text)
1303                 {
1304                         if(strength > 1)
1305                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1306                         if(strength <= 5)
1307                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1308                 }
1309         }
1310
1311         if(superweapons_time)
1312         {
1313                 const float maxsuperweapons = 30;
1314                 float superweapons = ceil(superweapons_time);
1315                 if(autocvar_hud_panel_powerups_progressbar)
1316                 {
1317                         HUD_Panel_GetProgressBarColor(superweapons);
1318                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1319                 }
1320                 if(autocvar_hud_panel_powerups_text)
1321                 {
1322                         if(superweapons > 1)
1323                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1324                         if(superweapons <= 5)
1325                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1326                 }
1327         }
1328
1329         draw_endBoldFont();
1330 }
1331
1332 // Health/armor (#3)
1333 //
1334
1335 // prev_* vars contain the health/armor at the previous FRAME
1336 // set to -1 when player is dead or was not playing
1337 float prev_health, prev_armor;
1338 float health_damagetime, armor_damagetime;
1339 float health_beforedamage, armor_beforedamage;
1340 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1341 float old_p_health, old_p_armor;
1342 float old_p_healthtime, old_p_armortime;
1343 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1344 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1345 float prev_p_health, prev_p_armor;
1346
1347 void HUD_HealthArmor(void)
1348 {
1349         float armor, health, fuel;
1350         if(!autocvar__hud_configure)
1351         {
1352                 if(!autocvar_hud_panel_healtharmor) return;
1353                 if(hud != HUD_NORMAL) return;
1354                 if(spectatee_status == -1) return;
1355
1356                 health = getstati(STAT_HEALTH);
1357                 if(health <= 0)
1358                 {
1359                         prev_health = -1;
1360                         return;
1361                 }
1362                 armor = getstati(STAT_ARMOR);
1363
1364                 // code to check for spectatee_status changes is in Ent_ClientData()
1365                 // prev_p_health and prev_health can be set to -1 there
1366
1367                 if (prev_p_health == -1)
1368                 {
1369                         // no effect
1370                         health_beforedamage = 0;
1371                         armor_beforedamage = 0;
1372                         health_damagetime = 0;
1373                         armor_damagetime = 0;
1374                         prev_health = health;
1375                         prev_armor = armor;
1376                         old_p_health = health;
1377                         old_p_armor = armor;
1378                         prev_p_health = health;
1379                         prev_p_armor = armor;
1380                 }
1381                 else if (prev_health == -1)
1382                 {
1383                         //start the load effect
1384                         health_damagetime = 0;
1385                         armor_damagetime = 0;
1386                         prev_health = 0;
1387                         prev_armor = 0;
1388                 }
1389                 fuel = getstati(STAT_FUEL);
1390         }
1391         else
1392         {
1393                 health = 150;
1394                 armor = 75;
1395                 fuel = 20;
1396         }
1397
1398         HUD_Panel_UpdateCvars();
1399         HUD_Panel_ApplyFadeAlpha();
1400         vector pos, mySize;
1401         pos = panel_pos;
1402         mySize = panel_size;
1403
1404         HUD_Panel_DrawBg(1);
1405         if(panel_bg_padding)
1406         {
1407                 pos += '1 1 0' * panel_bg_padding;
1408                 mySize -= '2 2 0' * panel_bg_padding;
1409         }
1410
1411         float baralign = autocvar_hud_panel_healtharmor_baralign;
1412         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1413
1414     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1415     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1416         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1417         {
1418                 vector v;
1419                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1420
1421                 float x;
1422                 x = floor(v_x + 1);
1423
1424         float maxtotal = maxhealth + maxarmor;
1425                 string biggercount;
1426                 if(v_z) // NOT fully armored
1427                 {
1428                         biggercount = "health";
1429                         if(autocvar_hud_panel_healtharmor_progressbar)
1430                         {
1431                                 HUD_Panel_GetProgressBarColor(health);
1432                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1433                         }
1434                         if(armor)
1435             if(autocvar_hud_panel_healtharmor_text)
1436                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1437                 }
1438                 else
1439                 {
1440                         biggercount = "armor";
1441                         if(autocvar_hud_panel_healtharmor_progressbar)
1442                         {
1443                                 HUD_Panel_GetProgressBarColor(armor);
1444                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1445                         }
1446                         if(health)
1447             if(autocvar_hud_panel_healtharmor_text)
1448                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1449                 }
1450         if(autocvar_hud_panel_healtharmor_text)
1451                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1452
1453                 if(fuel)
1454                 {
1455                         HUD_Panel_GetProgressBarColor(fuel);
1456                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), progressbar_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1457                 }
1458         }
1459         else
1460         {
1461                 float panel_ar = mySize_x/mySize_y;
1462                 float is_vertical = (panel_ar < 1);
1463                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1464                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1465                 {
1466                         mySize_x *= 0.5;
1467                         if (autocvar_hud_panel_healtharmor_flip)
1468                                 health_offset_x = mySize_x;
1469                         else
1470                                 armor_offset_x = mySize_x;
1471                 }
1472                 else
1473                 {
1474                         mySize_y *= 0.5;
1475                         if (autocvar_hud_panel_healtharmor_flip)
1476                                 health_offset_y = mySize_y;
1477                         else
1478                                 armor_offset_y = mySize_y;
1479                 }
1480
1481                 float health_baralign, armor_baralign, fuel_baralign;
1482                 float health_iconalign, armor_iconalign;
1483                 if (autocvar_hud_panel_healtharmor_flip)
1484                 {
1485                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1486                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1487                         fuel_baralign = health_baralign;
1488                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1489                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1490                 }
1491                 else
1492                 {
1493                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1494                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1495                         fuel_baralign = armor_baralign;
1496                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1497                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1498                 }
1499
1500                 //if(health)
1501                 {
1502                         if(autocvar_hud_panel_healtharmor_progressbar)
1503                         {
1504                                 HUD_Panel_GetProgressBarColor(health);
1505                                 float p_health, pain_health_alpha;
1506                                 p_health = health;
1507                                 pain_health_alpha = 1;
1508                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1509                                 {
1510                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1511                                         {
1512                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1513                                                 {
1514                                                         if (time - old_p_healthtime < 1)
1515                                                                 old_p_health = prev_p_health;
1516                                                         else
1517                                                                 old_p_health = prev_health;
1518                                                         old_p_healthtime = time;
1519                                                 }
1520                                                 if (time - old_p_healthtime < 1)
1521                                                 {
1522                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1523                                                         prev_p_health = p_health;
1524                                                 }
1525                                         }
1526                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1527                                         {
1528                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1529                                                 {
1530                                                         if (time - health_damagetime >= 1)
1531                                                                 health_beforedamage = prev_health;
1532                                                         health_damagetime = time;
1533                                                 }
1534                                                 if (time - health_damagetime < 1)
1535                                                 {
1536                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1537                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1538                                                 }
1539                                         }
1540                                         prev_health = health;
1541
1542                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1543                                         {
1544                                                 float BLINK_FACTOR = 0.15;
1545                                                 float BLINK_BASE = 0.85;
1546                                                 float BLINK_FREQ = 9;
1547                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1548                                         }
1549                                 }
1550                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1551                         }
1552                         if(autocvar_hud_panel_healtharmor_text)
1553                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1554                 }
1555
1556                 if(armor)
1557                 {
1558                         if(autocvar_hud_panel_healtharmor_progressbar)
1559                         {
1560                                 HUD_Panel_GetProgressBarColor(armor);
1561                                 float p_armor;
1562                                 p_armor = armor;
1563                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1564                                 {
1565                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1566                                         {
1567                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1568                                                 {
1569                                                         if (time - old_p_armortime < 1)
1570                                                                 old_p_armor = prev_p_armor;
1571                                                         else
1572                                                                 old_p_armor = prev_armor;
1573                                                         old_p_armortime = time;
1574                                                 }
1575                                                 if (time - old_p_armortime < 1)
1576                                                 {
1577                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1578                                                         prev_p_armor = p_armor;
1579                                                 }
1580                                         }
1581                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1582                                         {
1583                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1584                                                 {
1585                                                         if (time - armor_damagetime >= 1)
1586                                                                 armor_beforedamage = prev_armor;
1587                                                         armor_damagetime = time;
1588                                                 }
1589                                                 if (time - armor_damagetime < 1)
1590                                                 {
1591                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1592                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1593                                                 }
1594                                         }
1595                                         prev_armor = armor;
1596                                 }
1597                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1598                         }
1599                         if(autocvar_hud_panel_healtharmor_text)
1600                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1601                 }
1602
1603                 if(fuel)
1604                 {
1605                         if (is_vertical)
1606                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1607                         else
1608                                 mySize_y *= 0.2;
1609                         if (panel_ar >= 4)
1610                                 mySize_x *= 2; //restore full panel size
1611                         else if (panel_ar < 1/4)
1612                                 mySize_y *= 2; //restore full panel size
1613                         HUD_Panel_GetProgressBarColor(fuel);
1614                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, progressbar_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1615                 }
1616         }
1617 }
1618
1619 // Notification area (#4)
1620 //
1621
1622 void HUD_Notify_Push(string icon, string attacker, string victim)
1623 {
1624         if(icon != "")
1625         {
1626                 --kn_index;
1627                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
1628                 notify_times[kn_index] = time;
1629
1630                 // icon
1631                 if(notify_icon[kn_index]) { strunzone(notify_icon[kn_index]); }
1632                 notify_icon[kn_index] = strzone(icon);
1633
1634                 // attacker
1635                 if(notify_attackers[kn_index]) { strunzone(notify_attackers[kn_index]); }
1636                 notify_attackers[kn_index] = strzone(attacker);
1637
1638                 // victim
1639                 if(notify_victims[kn_index]) { strunzone(notify_victims[kn_index]); }
1640                 notify_victims[kn_index] = strzone(victim);
1641         }
1642 }
1643
1644 void HUD_Notify(void)
1645 {
1646         if(!autocvar__hud_configure)
1647         {
1648                 if(!autocvar_hud_panel_notify) return;
1649         }
1650
1651         HUD_Panel_UpdateCvars();
1652         HUD_Panel_ApplyFadeAlpha();
1653         vector pos, mySize;
1654         pos = panel_pos;
1655         mySize = panel_size;
1656
1657         HUD_Panel_DrawBg(1);
1658         if(panel_bg_padding)
1659         {
1660                 pos += '1 1 0' * panel_bg_padding;
1661                 mySize -= '2 2 0' * panel_bg_padding;
1662         }
1663
1664         float entries, height;
1665         entries = bound(1, floor(KN_MAX_ENTRIES * mySize_y/mySize_x), KN_MAX_ENTRIES);
1666         height = mySize_y/entries;
1667
1668         vector fontsize;
1669         float fontheight = height * autocvar_hud_panel_notify_fontsize;
1670         fontsize = '0.5 0.5 0' * fontheight;
1671
1672         float a;
1673         float when;
1674         when = autocvar_hud_panel_notify_time;
1675         float fadetime;
1676         fadetime = autocvar_hud_panel_notify_fadetime;
1677
1678         vector pos_attacker, pos_victim, pos_icon;
1679         float width_attacker;
1680         string attacker, victim, icon;
1681
1682         float i, j, step, limit;
1683         if(autocvar_hud_panel_notify_flip) //order items from the top down
1684         {
1685                 i = 0;
1686                 step = +1;
1687                 limit = entries;
1688         }
1689         else //order items from the bottom up
1690         {
1691                 i = entries - 1;
1692                 step = -1;
1693                 limit = -1;
1694         }
1695
1696         for(j = kn_index;  i != limit;  i += step, ++j)
1697         {
1698                 if(autocvar__hud_configure)
1699                 {
1700                         if (step == +1)
1701                                 a = i;
1702                         else // inverse order
1703                                 a = entries - 1 - i;
1704                         attacker = textShortenToWidth(sprintf(_("Player %d"), a+1), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1705                         victim = textShortenToWidth(sprintf(_("Player %d"), a+2), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1706                         icon = strcat("weapon", get_weaponinfo(WEP_FIRST + mod(floor(a*2.4), WEP_LAST)).netname);
1707                         a = bound(0, (when - a) / 4, 1);
1708                         goto hud_config_notifyprint;
1709                 }
1710                 else
1711                 {
1712                         if (j == KN_MAX_ENTRIES)
1713                                 j = 0;
1714
1715                         if(notify_times[j] + when > time)
1716                                 a = 1;
1717                         else if(fadetime)
1718                         {
1719                                 a = bound(0, (notify_times[j] + when + fadetime - time) / fadetime, 1);
1720                                 if(!a)
1721                                 {
1722                                         break;
1723                                 }
1724                         }
1725                         else
1726                         {
1727                                 break;
1728                         }
1729
1730                         attacker = notify_attackers[j];
1731                         victim = notify_victims[j];
1732                         icon = notify_icon[j];
1733                 }
1734
1735                 //type = notify_deathtype[j];
1736                 //w = DEATH_WEAPONOF(type);
1737
1738                 if(icon != "")
1739                 {
1740                         if((attacker != "") && (victim == ""))
1741                         {
1742                                 // Y [used by] X
1743                                 attacker = textShortenToWidth(attacker, 0.73 * mySize_x - height, fontsize, stringwidth_colors);
1744                                 pos_attacker = pos + eX * (0.27 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1745                                 pos_icon = pos + eX * 0.25 * mySize_x - eX * height + eY * i * height;
1746
1747                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1748                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1749                         }
1750                         else if((attacker != "") && (victim != ""))
1751                         {
1752                                 // X [did action to] Y
1753                                 attacker = textShortenToWidth(attacker, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1754                                 victim = textShortenToWidth(victim, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1755 :hud_config_notifyprint
1756                                 width_attacker = stringwidth(attacker, TRUE, fontsize);
1757                                 pos_attacker = pos + eX * (0.48 * mySize_x - height - width_attacker) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1758                                 pos_victim = pos + eX * (0.52 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1759                                 pos_icon = pos + eX * 0.5 * mySize_x - eX * height + eY * i * height;
1760
1761                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1762                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1763                                 drawcolorcodedstring(pos_victim, victim, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1764                         }
1765                 }
1766         }
1767 }
1768
1769 // Timer (#5)
1770 //
1771 // TODO: macro
1772 string seconds_tostring(float sec)
1773 {
1774         float minutes;
1775         minutes = floor(sec / 60);
1776
1777         sec -= minutes * 60;
1778         return sprintf("%d:%02d", minutes, sec);
1779 }
1780
1781 void HUD_Timer(void)
1782 {
1783         if(!autocvar__hud_configure)
1784         {
1785                 if(!autocvar_hud_panel_timer) return;
1786         }
1787
1788         HUD_Panel_UpdateCvars();
1789         HUD_Panel_ApplyFadeAlpha();
1790
1791         draw_beginBoldFont();
1792
1793         vector pos, mySize;
1794         pos = panel_pos;
1795         mySize = panel_size;
1796
1797         HUD_Panel_DrawBg(1);
1798         if(panel_bg_padding)
1799         {
1800                 pos += '1 1 0' * panel_bg_padding;
1801                 mySize -= '2 2 0' * panel_bg_padding;
1802         }
1803
1804         string timer;
1805         float timelimit, elapsedTime, timeleft, minutesLeft;
1806
1807         timelimit = getstatf(STAT_TIMELIMIT);
1808
1809         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1810         timeleft = ceil(timeleft);
1811
1812         minutesLeft = floor(timeleft / 60);
1813
1814         vector timer_color;
1815         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1816                 timer_color = '1 1 1'; //white
1817         else if(minutesLeft >= 1)
1818                 timer_color = '1 1 0'; //yellow
1819         else
1820                 timer_color = '1 0 0'; //red
1821
1822         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1823                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1824                         //while restart is still active, show 00:00
1825                         timer = seconds_tostring(0);
1826                 } else {
1827                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1828                         timer = seconds_tostring(elapsedTime);
1829                 }
1830         } else {
1831                 timer = seconds_tostring(timeleft);
1832         }
1833
1834         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1835
1836         draw_endBoldFont();
1837 }
1838
1839 // Radar (#6)
1840 //
1841 void HUD_Radar(void)
1842 {
1843         if (!autocvar__hud_configure)
1844         {
1845                 if (hud_panel_radar_maximized)
1846                 {
1847                         if (!hud_draw_maximized) return;
1848                 }
1849                 else
1850                 {
1851                         if (autocvar_hud_panel_radar == 0) return;
1852                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1853                 }
1854         }
1855
1856         HUD_Panel_UpdateCvars();
1857         HUD_Panel_ApplyFadeAlpha();
1858
1859         float f = 0;
1860
1861         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1862         {
1863                 panel_size = autocvar_hud_panel_radar_maximized_size;
1864                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1865                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1866                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1867                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1868
1869                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1870                 if(precache_pic(panel_bg) == "") { panel_bg = "gfx/hud/default/border_default"; } // fallback
1871
1872                 switch(hud_panel_radar_maximized_zoommode)
1873                 {
1874                         default:
1875                         case 0:
1876                                 f = current_zoomfraction;
1877                                 break;
1878                         case 1:
1879                                 f = 1 - current_zoomfraction;
1880                                 break;
1881                         case 2:
1882                                 f = 0;
1883                                 break;
1884                         case 3:
1885                                 f = 1;
1886                                 break;
1887                 }
1888
1889                 switch(hud_panel_radar_maximized_rotation)
1890                 {
1891                         case 0:
1892                                 teamradar_angle = view_angles_y - 90;
1893                                 break;
1894                         default:
1895                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1896                                 break;
1897                 }
1898         }
1899         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1900         {
1901                 switch(hud_panel_radar_zoommode)
1902                 {
1903                         default:
1904                         case 0:
1905                                 f = current_zoomfraction;
1906                                 break;
1907                         case 1:
1908                                 f = 1 - current_zoomfraction;
1909                                 break;
1910                         case 2:
1911                                 f = 0;
1912                                 break;
1913                         case 3:
1914                                 f = 1;
1915                                 break;
1916                 }
1917
1918                 switch(hud_panel_radar_rotation)
1919                 {
1920                         case 0:
1921                                 teamradar_angle = view_angles_y - 90;
1922                                 break;
1923                         default:
1924                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1925                                 break;
1926                 }
1927         }
1928
1929         vector pos, mySize;
1930         pos = panel_pos;
1931         mySize = panel_size;
1932
1933         HUD_Panel_DrawBg(1);
1934         if(panel_bg_padding)
1935         {
1936                 pos += '1 1 0' * panel_bg_padding;
1937                 mySize -= '2 2 0' * panel_bg_padding;
1938         }
1939
1940         float color2;
1941         entity tm;
1942         float scale2d, normalsize, bigsize;
1943
1944         teamradar_origin2d = pos + 0.5 * mySize;
1945         teamradar_size2d = mySize;
1946
1947         if(minimapname == "")
1948                 return;
1949
1950         teamradar_loadcvars();
1951
1952         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1953         teamradar_size2d = mySize;
1954
1955         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1956
1957         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1958         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1959         {
1960                 // max-min distance must fit the radar in any rotation
1961                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
1962         }
1963         else
1964         {
1965                 vector c0, c1, c2, c3, span;
1966                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
1967                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
1968                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
1969                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
1970                 span = '0 0 0';
1971                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
1972                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
1973
1974                 // max-min distance must fit the radar in x=x, y=y
1975                 bigsize = min(
1976                         teamradar_size2d_x * scale2d / (1.05 * span_x),
1977                         teamradar_size2d_y * scale2d / (1.05 * span_y)
1978                 );
1979         }
1980
1981         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
1982         if(bigsize > normalsize)
1983                 normalsize = bigsize;
1984
1985         teamradar_size =
1986                   f * bigsize
1987                 + (1 - f) * normalsize;
1988         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
1989                   f * mi_center
1990                 + (1 - f) * view_origin);
1991
1992         drawsetcliparea(
1993                 pos_x,
1994                 pos_y,
1995                 mySize_x,
1996                 mySize_y
1997         );
1998
1999         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2000
2001         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2002                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2003         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2004                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2005         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2006         {
2007                 color2 = GetPlayerColor(tm.sv_entnum);
2008                 //if(color == NUM_SPECTATOR || color == color2)
2009                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2010         }
2011         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2012
2013         drawresetcliparea();
2014 }
2015
2016 // Score (#7)
2017 //
2018 void HUD_UpdatePlayerTeams();
2019 void HUD_Score_Rankings(vector pos, vector mySize, entity me, float team_count)
2020 {
2021         float score;
2022         entity tm = world, pl;
2023 #define SCOREPANEL_MAX_ENTRIES 6
2024 #define SCOREPANEL_ASPECTRATIO 2
2025         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2026         vector fontsize = '1 1 0' * (mySize_y/entries);
2027
2028         vector rgb, score_color;
2029         rgb = '1 1 1';
2030         score_color = '1 1 1';
2031
2032         float name_size = mySize_x*0.75;
2033         float spacing_size = mySize_x*0.04;
2034         const float highlight_alpha = 0.2;
2035         float i = 0, me_printed = 0, first_pl = 0;
2036         string s;
2037         if (autocvar__hud_configure)
2038         {
2039                 float players_per_team = 0;
2040                 if (team_count)
2041                 {
2042                         // show team scores in the first line
2043                         float score_size = mySize_x / team_count;
2044                         players_per_team = max(2, ceil((entries - 1) / team_count));
2045                         for(i=0; i<team_count; ++i) {
2046                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2047                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2048                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2049                         }
2050                         first_pl = 1;
2051                         pos_y += fontsize_y;
2052                 }
2053                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2054                 for (i=first_pl; i<entries; ++i)
2055                 {
2056                         //simulate my score is lower than all displayed players,
2057                         //so that I don't appear at all showing pure rankings.
2058                         //This is to better show the difference between the 2 ranking views
2059                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2060                         {
2061                                 rgb = '1 1 0';
2062                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2063                                 s = GetPlayerName(player_localnum);
2064                                 score = 7;
2065                         }
2066                         else
2067                         {
2068                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2069                                 score -= 3;
2070                         }
2071
2072                         if (team_count)
2073                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2074                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2075                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2076                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2077                         pos_y += fontsize_y;
2078                 }
2079                 return;
2080         }
2081
2082         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2083                 HUD_UpdatePlayerTeams();
2084         if (team_count)
2085         {
2086                 // show team scores in the first line
2087                 float score_size = mySize_x / team_count;
2088                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2089                         if(tm.team == NUM_SPECTATOR)
2090                                 continue;
2091                         if (tm.team == myteam)
2092                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2093                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2094                         ++i;
2095                 }
2096                 first_pl = 1;
2097                 pos_y += fontsize_y;
2098                 tm = teams.sort_next;
2099         }
2100         i = first_pl;
2101
2102         do
2103         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2104         {
2105                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2106                         continue;
2107
2108                 if (i == entries-1 && !me_printed && pl != me)
2109                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2110                 {
2111                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2112                                 if (pl.team != NUM_SPECTATOR)
2113                                         break;
2114
2115                         if (pl)
2116                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2117                         else
2118                                 rgb = '1 0 0'; //last: red
2119                         pl = me;
2120                 }
2121
2122                 if (pl == me)
2123                 {
2124                         if (i == first_pl)
2125                                 rgb = '0 1 0'; //first: green
2126                         me_printed = 1;
2127                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2128                 }
2129                 if (team_count)
2130                         score_color = Team_ColorRGB(pl.team) * 0.8;
2131                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2132                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2133                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2134                 pos_y += fontsize_y;
2135                 ++i;
2136         }
2137         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2138 }
2139
2140 void HUD_Score(void)
2141 {
2142         if(!autocvar__hud_configure)
2143         {
2144                 if(!autocvar_hud_panel_score) return;
2145                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2146         }
2147
2148         HUD_Panel_UpdateCvars();
2149         HUD_Panel_ApplyFadeAlpha();
2150         vector pos, mySize;
2151         pos = panel_pos;
2152         mySize = panel_size;
2153
2154         HUD_Panel_DrawBg(1);
2155         if(panel_bg_padding)
2156         {
2157                 pos += '1 1 0' * panel_bg_padding;
2158                 mySize -= '2 2 0' * panel_bg_padding;
2159         }
2160
2161         float score, distribution = 0;
2162         string sign;
2163         vector distribution_color;
2164         entity tm, pl, me;
2165
2166 #ifdef COMPAT_XON050_ENGINE
2167         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
2168 #else
2169         me = playerslots[player_localentnum - 1];
2170 #endif
2171
2172         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2173                 string timer, distrtimer;
2174
2175                 pl = players.sort_next;
2176                 if(pl == me)
2177                         pl = pl.sort_next;
2178                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2179                         if(pl.scores[ps_primary] == 0)
2180                                 pl = world;
2181
2182                 score = me.(scores[ps_primary]);
2183                 timer = TIME_ENCODED_TOSTRING(score);
2184
2185                 draw_beginBoldFont();
2186                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2187                         // distribution display
2188                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2189
2190                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2191
2192                         if (distribution <= 0) {
2193                                 distribution_color = '0 1 0';
2194                                 sign = "-";
2195                         }
2196                         else {
2197                                 distribution_color = '1 0 0';
2198                                 sign = "+";
2199                         }
2200                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2201                 }
2202                 // race record display
2203                 if (distribution <= 0)
2204                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2205                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2206                 draw_endBoldFont();
2207         } else if (!teamplay) { // non-teamgames
2208                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2209                 {
2210                         HUD_Score_Rankings(pos, mySize, me, 0);
2211                         return;
2212                 }
2213                 // me vector := [team/connected frags id]
2214                 pl = players.sort_next;
2215                 if(pl == me)
2216                         pl = pl.sort_next;
2217
2218                 if(autocvar__hud_configure)
2219                         distribution = 42;
2220                 else if(pl)
2221                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2222                 else
2223                         distribution = 0;
2224
2225                 score = me.(scores[ps_primary]);
2226                 if(autocvar__hud_configure)
2227                         score = 123;
2228
2229                 if(distribution >= 5)
2230                         distribution_color = eY;
2231                 else if(distribution >= 0)
2232                         distribution_color = '1 1 1';
2233                 else if(distribution >= -5)
2234                         distribution_color = '1 1 0';
2235                 else
2236                         distribution_color = eX;
2237
2238                 string distribution_str;
2239                 distribution_str = ftos(distribution);
2240                 draw_beginBoldFont();
2241                 if (distribution >= 0)
2242                 {
2243                         if (distribution > 0)
2244                                 distribution_str = strcat("+", distribution_str);
2245                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2246                 }
2247                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2248                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2249                 draw_endBoldFont();
2250         } else { // teamgames
2251                 float scores_count = 0, row, column, rows = 0, columns = 0;
2252                 local noref vector offset = '0 0 0';
2253                 vector score_pos, score_size; //for scores other than myteam
2254                 if (spectatee_status == -1 || autocvar_hud_panel_score_rankings)
2255                 {
2256                         for(tm = teams.sort_next; tm, tm.team != NUM_SPECTATOR; tm = tm.sort_next)
2257                                 ++scores_count;
2258                         if (autocvar_hud_panel_score_rankings)
2259                         {
2260                                 HUD_Score_Rankings(pos, mySize, me, scores_count);
2261                                 return;
2262                         }
2263                         rows = mySize_y/mySize_x;
2264                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * scores_count + rows * rows) + rows + 0.5) / 2), scores_count);
2265                         //                               ^^^ ammo item aspect goes here
2266
2267                         columns = ceil(scores_count/rows);
2268
2269                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2270
2271                         float newSize;
2272                         if(score_size_x/score_size_y > 3)
2273                         {
2274                                 newSize = 3 * score_size_y;
2275                                 offset_x = score_size_x - newSize;
2276                                 pos_x += offset_x/2;
2277                                 score_size_x = newSize;
2278                         }
2279                         else
2280                         {
2281                                 newSize = 1/3 * score_size_x;
2282                                 offset_y = score_size_y - newSize;
2283                                 pos_y += offset_y/2;
2284                                 score_size_y = newSize;
2285                         }
2286                 }
2287                 else
2288                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2289
2290                 float max_fragcount;
2291                 max_fragcount = -99;
2292                 draw_beginBoldFont();
2293                 row = column = 0;
2294                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2295                         if(tm.team == NUM_SPECTATOR)
2296                                 continue;
2297                         score = tm.(teamscores[ts_primary]);
2298                         if(autocvar__hud_configure)
2299                                 score = 123;
2300
2301                         if (score > max_fragcount)
2302                                 max_fragcount = score;
2303
2304                         if (spectatee_status == -1)
2305                         {
2306                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2307                                 if (max_fragcount == score)
2308                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2309                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2310                                 ++row;
2311                                 if(row >= rows)
2312                                 {
2313                                         row = 0;
2314                                         ++column;
2315                                 }
2316                         }
2317                         else if(tm.team == myteam) {
2318                                 if (max_fragcount == score)
2319                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2320                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2321                         } else {
2322                                 if (max_fragcount == score)
2323                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2324                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2325                                 ++rows;
2326                         }
2327                 }
2328                 draw_endBoldFont();
2329         }
2330 }
2331
2332 // Race timer (#8)
2333 //
2334 void HUD_RaceTimer (void)
2335 {
2336         if(!autocvar__hud_configure)
2337         {
2338                 if(!autocvar_hud_panel_racetimer) return;
2339                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2340                 if(spectatee_status == -1) return;
2341         }
2342
2343         HUD_Panel_UpdateCvars();
2344         HUD_Panel_ApplyFadeAlpha();
2345
2346         draw_beginBoldFont();
2347
2348         vector pos, mySize;
2349         pos = panel_pos;
2350         mySize = panel_size;
2351
2352         HUD_Panel_DrawBg(1);
2353         if(panel_bg_padding)
2354         {
2355                 pos += '1 1 0' * panel_bg_padding;
2356                 mySize -= '2 2 0' * panel_bg_padding;
2357         }
2358
2359         // always force 4:1 aspect
2360         vector newSize = '0 0 0';
2361         if(mySize_x/mySize_y > 4)
2362         {
2363                 newSize_x = 4 * mySize_y;
2364                 newSize_y = mySize_y;
2365
2366                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2367         }
2368         else
2369         {
2370                 newSize_y = 1/4 * mySize_x;
2371                 newSize_x = mySize_x;
2372
2373                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2374         }
2375         mySize = newSize;
2376
2377         float a, t;
2378         string s, forcetime;
2379
2380         if(autocvar__hud_configure)
2381         {
2382                 s = "0:13:37";
2383                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2384                 s = _("^1Intermediate 1 (+15.42)");
2385                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2386                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2387                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2388         }
2389         else if(race_checkpointtime)
2390         {
2391                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2392                 s = "";
2393                 forcetime = "";
2394                 if(a > 0) // just hit a checkpoint?
2395                 {
2396                         if(race_checkpoint != 254)
2397                         {
2398                                 if(race_time && race_previousbesttime)
2399                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2400                                 else
2401                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2402                                 if(race_time)
2403                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2404                         }
2405                 }
2406                 else
2407                 {
2408                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2409                         {
2410                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2411                                 if(a > 0) // next one?
2412                                 {
2413                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2414                                 }
2415                         }
2416                 }
2417
2418                 if(s != "" && a > 0)
2419                 {
2420                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2421                 }
2422
2423                 if(race_penaltytime)
2424                 {
2425                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2426                         if(a > 0)
2427                         {
2428                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2429                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2430                         }
2431                 }
2432
2433                 if(forcetime != "")
2434                 {
2435                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2436                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2437                 }
2438                 else
2439                         a = 1;
2440
2441                 if(race_laptime && race_checkpoint != 255)
2442                 {
2443                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2444                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2445                 }
2446         }
2447         else
2448         {
2449                 if(race_mycheckpointtime)
2450                 {
2451                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2452                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2453                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2454                 }
2455                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2456                 {
2457                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2458                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2459                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2460                 }
2461
2462                 if(race_penaltytime && !race_penaltyaccumulator)
2463                 {
2464                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2465                         a = bound(0, (1 + t - time), 1);
2466                         if(a > 0)
2467                         {
2468                                 if(time < t)
2469                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2470                                 else
2471                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2472                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2473                         }
2474                 }
2475         }
2476
2477         draw_endBoldFont();
2478 }
2479
2480 // Vote window (#9)
2481 //
2482 float vote_yescount;
2483 float vote_nocount;
2484 float vote_needed;
2485 float vote_highlighted; // currently selected vote
2486
2487 float vote_active; // is there an active vote?
2488 float vote_prev; // previous state of vote_active to check for a change
2489 float vote_alpha;
2490 float vote_change; // "time" when vote_active changed
2491
2492 void HUD_Vote(void)
2493 {
2494         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2495         {
2496                 vote_active = 1;
2497                 if (autocvar__hud_configure)
2498                 {
2499                         vote_yescount = 0;
2500                         vote_nocount = 0;
2501                         print(_("^1You must answer before entering hud configure mode\n"));
2502                         cvar_set("_hud_configure", "0");
2503                 }
2504                 if(vote_called_vote)
2505                         strunzone(vote_called_vote);
2506                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2507                 uid2name_dialog = 1;
2508         }
2509
2510         if(!autocvar__hud_configure)
2511         {
2512                 if(!autocvar_hud_panel_vote) return;
2513
2514                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2515                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2516
2517                 if(panel_bg_alpha_str == "") {
2518                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2519                 }
2520                 panel_bg_alpha = stof(panel_bg_alpha_str);
2521         }
2522         else
2523         {
2524                 vote_yescount = 3;
2525                 vote_nocount = 2;
2526                 vote_needed = 4;
2527         }
2528
2529         string s;
2530         float a;
2531         if(vote_active != vote_prev) {
2532                 vote_change = time;
2533                 vote_prev = vote_active;
2534         }
2535
2536         if(vote_active || autocvar__hud_configure)
2537                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2538         else
2539                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2540
2541         if(!vote_alpha)
2542                 return;
2543
2544         HUD_Panel_UpdateCvars();
2545         HUD_Panel_ApplyFadeAlpha();
2546
2547         if(uid2name_dialog)
2548         {
2549                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2550                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2551         }
2552
2553     // these must be below above block
2554         vector pos, mySize;
2555         pos = panel_pos;
2556         mySize = panel_size;
2557
2558         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2559         HUD_Panel_DrawBg(a);
2560         a = panel_fg_alpha * a;
2561
2562         if(panel_bg_padding)
2563         {
2564                 pos += '1 1 0' * panel_bg_padding;
2565                 mySize -= '2 2 0' * panel_bg_padding;
2566         }
2567
2568         // always force 3:1 aspect
2569         vector newSize = '0 0 0';
2570         if(mySize_x/mySize_y > 3)
2571         {
2572                 newSize_x = 3 * mySize_y;
2573                 newSize_y = mySize_y;
2574
2575                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2576         }
2577         else
2578         {
2579                 newSize_y = 1/3 * mySize_x;
2580                 newSize_x = mySize_x;
2581
2582                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2583         }
2584         mySize = newSize;
2585
2586         s = _("A vote has been called for:");
2587         if(uid2name_dialog)
2588                 s = _("Allow servers to store and display your name?");
2589         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2590         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2591         if(autocvar__hud_configure)
2592                 s = _("^1Configure the HUD");
2593         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2594
2595         // print the yes/no counts
2596     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2597         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2598     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2599         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2600
2601         // draw the progress bar backgrounds
2602         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2603
2604         // draw the highlights
2605         if(vote_highlighted == 1) {
2606                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2607                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2608         }
2609         else if(vote_highlighted == -1) {
2610                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2611                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2612         }
2613
2614         // draw the progress bars
2615         if(vote_yescount && vote_needed)
2616         {
2617                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2618                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2619         }
2620
2621         if(vote_nocount && vote_needed)
2622         {
2623                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2624                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2625         }
2626
2627         drawresetcliparea();
2628 }
2629
2630 // Mod icons panel (#10)
2631 //
2632
2633 float mod_active; // is there any active mod icon?
2634
2635 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2636 {
2637         float stat;
2638         string pic;
2639         vector color;
2640 #ifdef GMQCC
2641         stat = -1;
2642         pic = "";
2643         color = '0 0 0';
2644 #endif
2645         switch(i)
2646         {
2647                 case 0:
2648                         stat = getstati(STAT_REDALIVE);
2649                         pic = "player_red.tga";
2650                         color = '1 0 0';
2651                         break;
2652                 case 1:
2653                         stat = getstati(STAT_BLUEALIVE);
2654                         pic = "player_blue.tga";
2655                         color = '0 0 1';
2656                         break;
2657                 case 2:
2658                         stat = getstati(STAT_YELLOWALIVE);
2659                         pic = "player_yellow.tga";
2660                         color = '1 1 0';
2661                         break;
2662                 default:
2663                 case 3:
2664                         stat = getstati(STAT_PINKALIVE);
2665                         pic = "player_pink.tga";
2666                         color = '1 0 1';
2667                         break;
2668         }
2669
2670         if(mySize_x/mySize_y > aspect_ratio)
2671         {
2672                 i = aspect_ratio * mySize_y;
2673                 myPos_x = myPos_x + (mySize_x - i) / 2;
2674                 mySize_x = i;
2675         }
2676         else
2677         {
2678                 i = 1/aspect_ratio * mySize_x;
2679                 myPos_y = myPos_y + (mySize_y - i) / 2;
2680                 mySize_y = i;
2681         }
2682
2683         if(layout)
2684         {
2685                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2686                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2687         }
2688         else
2689                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2690 }
2691
2692 // Clan Arena and Freeze Tag HUD modicons
2693 void HUD_Mod_CA(vector myPos, vector mySize)
2694 {
2695         mod_active = 1; // required in each mod function that always shows something
2696         entity tm;
2697         float teams_count = 0;
2698         for(tm = teams.sort_next; tm; tm = tm.sort_next)
2699                 if(tm.team != NUM_SPECTATOR)
2700                         ++teams_count;
2701
2702         float layout;
2703         if(gametype == MAPINFO_TYPE_CA)
2704                 layout = autocvar_hud_panel_modicons_ca_layout;
2705         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2706                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2707         float rows, columns, aspect_ratio;
2708         rows = mySize_y/mySize_x;
2709         aspect_ratio = (layout) ? 2 : 1;
2710         rows = bound(1, floor((sqrt((4 * aspect_ratio * teams_count + rows) * rows) + rows + 0.5) / 2), teams_count);
2711         columns = ceil(teams_count/rows);
2712
2713         int i;
2714         float row = 0, column = 0;
2715         vector pos, itemSize;
2716         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2717         for(i=0; i<teams_count; ++i)
2718         {
2719                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2720
2721                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2722
2723                 ++row;
2724                 if(row >= rows)
2725                 {
2726                         row = 0;
2727                         ++column;
2728                 }
2729         }
2730 }
2731
2732 // CTF HUD modicon section
2733 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2734 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2735 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2736
2737 void HUD_Mod_CTF_Reset(void)
2738 {
2739         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2740 }
2741
2742 void HUD_Mod_CTF(vector pos, vector mySize)
2743 {
2744         vector redflag_pos, blueflag_pos;
2745         vector flag_size;
2746         float f; // every function should have that
2747
2748         float redflag, blueflag; // current status
2749         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2750         float stat_items;
2751
2752         stat_items = getstati(STAT_ITEMS, 0, 24);
2753         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2754         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2755
2756         if(redflag || blueflag)
2757                 mod_active = 1;
2758         else
2759                 mod_active = 0;
2760
2761         if(autocvar__hud_configure)
2762         {
2763                 redflag = 1;
2764                 blueflag = 2;
2765         }
2766
2767         // when status CHANGES, set old status into prevstatus and current status into status
2768         if (redflag != redflag_prevframe)
2769         {
2770                 redflag_statuschange_time = time;
2771                 redflag_prevstatus = redflag_prevframe;
2772                 redflag_prevframe = redflag;
2773         }
2774
2775         if (blueflag != blueflag_prevframe)
2776         {
2777                 blueflag_statuschange_time = time;
2778                 blueflag_prevstatus = blueflag_prevframe;
2779                 blueflag_prevframe = blueflag;
2780         }
2781
2782         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2783         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2784
2785         float BLINK_FACTOR = 0.15;
2786         float BLINK_BASE = 0.85;
2787         // note:
2788         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2789         // thus
2790         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2791         // ensure RMS == 1
2792         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2793
2794         string red_icon, red_icon_prevstatus;
2795         float red_alpha, red_alpha_prevstatus;
2796         red_alpha = red_alpha_prevstatus = 1;
2797         switch(redflag) {
2798                 case 1: red_icon = "flag_red_taken"; break;
2799                 case 2: red_icon = "flag_red_lost"; break;
2800                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2801                 default:
2802                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2803                                 red_icon = "flag_red_shielded";
2804                         else
2805                                 red_icon = string_null;
2806                         break;
2807         }
2808         switch(redflag_prevstatus) {
2809                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2810                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2811                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2812                 default:
2813                         if(redflag == 3)
2814                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2815                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2816                                 red_icon_prevstatus = "flag_red_shielded";
2817                         else
2818                                 red_icon_prevstatus = string_null;
2819                         break;
2820         }
2821
2822         string blue_icon, blue_icon_prevstatus;
2823         float blue_alpha, blue_alpha_prevstatus;
2824         blue_alpha = blue_alpha_prevstatus = 1;
2825         switch(blueflag) {
2826                 case 1: blue_icon = "flag_blue_taken"; break;
2827                 case 2: blue_icon = "flag_blue_lost"; break;
2828                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2829                 default:
2830                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2831                                 blue_icon = "flag_blue_shielded";
2832                         else
2833                                 blue_icon = string_null;
2834                         break;
2835         }
2836         switch(blueflag_prevstatus) {
2837                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2838                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2839                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2840                 default:
2841                         if(blueflag == 3)
2842                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2843                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2844                                 blue_icon_prevstatus = "flag_blue_shielded";
2845                         else
2846                                 blue_icon_prevstatus = string_null;
2847                         break;
2848         }
2849
2850         if(mySize_x > mySize_y) {
2851                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2852                         redflag_pos = pos;
2853                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2854                 } else {
2855                         blueflag_pos = pos;
2856                         redflag_pos = pos + eX * 0.5 * mySize_x;
2857                 }
2858                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2859         } else {
2860                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2861                         redflag_pos = pos;
2862                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2863                 } else {
2864                         blueflag_pos = pos;
2865                         redflag_pos = pos + eY * 0.5 * mySize_y;
2866                 }