qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float stringwidth_colors(string s, vector theSize)
 136 {
 137         return stringwidth(s, TRUE, theSize);
 138 }
 139
 140 float stringwidth_nocolors(string s, vector theSize)
 141 {
 142         return stringwidth(s, FALSE, theSize);
 143 }
 144
 145 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 146 {
 147         position_x -= 2 / 3 * strlen(text) * theScale_x;
 148         drawstring(position, text, theScale, rgb, theAlpha, flag);
 149 }
 150
 151 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale_x);
 154         drawstring(position, text, theScale, rgb, theAlpha, flag);
 155 }
 156
 157 // return the string of the onscreen race timer
 158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 159 {
 160         string col;
 161         string timestr;
 162         string cpname;
 163         string lapstr;
 164         lapstr = "";
 165
 166         if(histime == 0) // goal hit
 167         {
 168                 if(mytime > 0)
 169                 {
 170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 171                         col = "^1";
 172                 }
 173                 else if(mytime == 0)
 174                 {
 175                         timestr = "+0.0";
 176                         col = "^3";
 177                 }
 178                 else
 179                 {
 180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 181                         col = "^2";
 182                 }
 183
 184                 if(lapdelta > 0)
 185                 {
 186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 187                         col = "^2";
 188                 }
 189                 else if(lapdelta < 0)
 190                 {
 191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 192                         col = "^1";
 193                 }
 194         }
 195         else if(histime > 0) // anticipation
 196         {
 197                 if(mytime >= histime)
 198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 199                 else
 200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 201                 col = "^3";
 202         }
 203         else
 204         {
 205                 col = "^7";
 206                 timestr = "";
 207         }
 208
 209         if(cp == 254)
 210                 cpname = _("Start line");
 211         else if(cp == 255)
 212                 cpname = _("Finish line");
 213         else if(cp)
 214                 cpname = sprintf(_("Intermediate %d"), cp);
 215         else
 216                 cpname = _("Finish line");
 217
 218         if(histime < 0)
 219                 return strcat(col, cpname);
 220         else if(hisname == "")
 221                 return strcat(col, sprintf(_("%s (%s)"), cpname, timestr));
 222         else
 223                 return strcat(col, sprintf(_("%s (%s %s)"), cpname, timestr, strcat(hisname, col, lapstr)));
 224 }
 225
 226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 227 float race_CheckName(string net_name) {
 228         float i;
 229         for (i=RANKINGS_CNT-1;i>=0;--i)
 230                 if(grecordholder[i] == net_name)
 231                         return i+1;
 232         return 0;
 233 }
 234
 235 float GetPlayerColorForce(float i)
 236 {
 237         if(!teamplay)
 238                 return 0;
 239         else
 240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 241 }
 242
 243 float GetPlayerColor(float i)
 244 {
 245         if(!playerslots[i].gotscores) // unconnected
 246                 return NUM_SPECTATOR;
 247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 248                 return NUM_SPECTATOR;
 249         else
 250                 return GetPlayerColorForce(i);
 251 }
 252
 253 string GetPlayerName(float i)
 254 {
 255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 256 }
 257
 258
 259 /*
 260 ==================
 261 HUD panels
 262 ==================
 263 */
 264
 265 // draw the background/borders
 266 #define HUD_Panel_DrawBg(theAlpha)\
 267 if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")\
 268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 269
 270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 272 {
 273         if(!length_ratio || !theAlpha)
 274                 return;
 275         if(length_ratio > 1)
 276                 length_ratio = 1;
 277         if (baralign == 3)
 278         {
 279                 if(length_ratio < -1)
 280                         length_ratio = -1;
 281         }
 282         else if(length_ratio < 0)
 283                 return;
 284
 285         vector square;
 286         vector width, height;
 287         if(vertical) {
 288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 289                 if(precache_pic(pic) == "") {
 290                         pic = "gfx/hud/default/progressbar_vertical";
 291                 }
 292
 293         if (baralign == 1) // bottom align
 294                         theOrigin_y += (1 - length_ratio) * theSize_y;
 295         else if (baralign == 2) // center align
 296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 297         else if (baralign == 3) // center align, positive values down, negative up
 298                 {
 299                         theSize_y *= 0.5;
 300                         if (length_ratio > 0)
 301                                 theOrigin_y += theSize_y;
 302                         else
 303                         {
 304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 305                                 length_ratio = -length_ratio;
 306                         }
 307                 }
 308                 theSize_y *= length_ratio;
 309
 310                 vector bH;
 311                 width = eX * theSize_x;
 312                 height = eY * theSize_y;
 313                 if(theSize_y <= theSize_x * 2)
 314                 {
 315                         // button not high enough
 316                         // draw just upper and lower part then
 317                         square = eY * theSize_y * 0.5;
 318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 321                 }
 322                 else
 323                 {
 324                         square = eY * theSize_x;
 325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 328                 }
 329         } else {
 330                 pic = strcat(hud_skin_path, "/", pic);
 331                 if(precache_pic(pic) == "") {
 332                         pic = "gfx/hud/default/progressbar";
 333                 }
 334
 335                 if (baralign == 1) // right align
 336                         theOrigin_x += (1 - length_ratio) * theSize_x;
 337         else if (baralign == 2) // center align
 338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 339         else if (baralign == 3) // center align, positive values on the right, negative on the left
 340                 {
 341                         theSize_x *= 0.5;
 342                         if (length_ratio > 0)
 343                                 theOrigin_x += theSize_x;
 344                         else
 345                         {
 346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 347                                 length_ratio = -length_ratio;
 348                         }
 349                 }
 350                 theSize_x *= length_ratio;
 351
 352                 vector bW;
 353                 width = eX * theSize_x;
 354                 height = eY * theSize_y;
 355                 if(theSize_x <= theSize_y * 2)
 356                 {
 357                         // button not wide enough
 358                         // draw just left and right part then
 359                         square = eX * theSize_x * 0.5;
 360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 363                 }
 364                 else
 365                 {
 366                         square = eX * theSize_y;
 367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 370                 }
 371         }
 372 }
 373
 374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 375 {
 376         if(!theAlpha)
 377                 return;
 378
 379         string pic;
 380         pic = strcat(hud_skin_path, "/num_leading");
 381         if(precache_pic(pic) == "") {
 382                 pic = "gfx/hud/default/num_leading";
 383         }
 384
 385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 386         if(mySize_x/mySize_y > 2)
 387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 389 }
 390
 391 // Weapon icons (#0)
 392 //
 393 entity weaponorder[WEP_MAXCOUNT];
 394 void weaponorder_swap(float i, float j, entity pass)
 395 {
 396         entity h;
 397         h = weaponorder[i];
 398         weaponorder[i] = weaponorder[j];
 399         weaponorder[j] = h;
 400 }
 401
 402 string weaponorder_cmp_str;
 403 float weaponorder_cmp(float i, float j, entity pass)
 404 {
 405         float ai, aj;
 406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 409 }
 410
 411 void HUD_Weapons(void)
 412 {
 413         // declarations
 414         WepSet weapons_stat = WepSet_GetFromStat();
 415         float i, f, a;
 416         float screen_ar, center_x = 0, center_y;
 417         float weapon_count, weapon_id;
 418         float row, column, rows = 0, columns;
 419         float aspect = autocvar_hud_panel_weapons_aspect;
 420
 421         float panel_weapon_accuracy;
 422
 423         float timeout = autocvar_hud_panel_weapons_timeout;
 424         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 425         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 426
 427         float ammo_full;
 428         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 429         vector ammo_color = '1 0 1';
 430         float ammo_alpha = 1;
 431
 432         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 433         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 434
 435         vector weapon_pos, weapon_size = '0 0 0';
 436         local noref vector old_panel_size; // fteqcc sucks
 437         vector color;
 438
 439         // check to see if we want to continue
 440         if(hud != HUD_NORMAL) { return; }
 441
 442         if(!autocvar__hud_configure)
 443         {
 444                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 445                         return;
 446                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 447                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 448                 {
 449                         weaponprevtime = time;
 450                         return;
 451                 }
 452         }
 453
 454         // update generic hud functions
 455         HUD_Panel_UpdateCvars();
 456
 457         draw_beginBoldFont();
 458
 459         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 460         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 461         {
 462                 float weapon_cnt;
 463                 if(weaponorder_bypriority)
 464                         strunzone(weaponorder_bypriority);
 465                 if(weaponorder_byimpulse)
 466                         strunzone(weaponorder_byimpulse);
 467
 468                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 469                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 470                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 471
 472                 weapon_cnt = 0;
 473                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 474                 {
 475                         self = get_weaponinfo(i);
 476                         if(self.impulse >= 0)
 477                         {
 478                                 weaponorder[weapon_cnt] = self;
 479                                 ++weapon_cnt;
 480                         }
 481                 }
 482                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 483                         weaponorder[i] = world;
 484                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 485
 486                 weaponorder_cmp_str = string_null;
 487         }
 488
 489         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 490                 complain_weapon = 0;
 491
 492         // determine which weapons are going to be shown
 493         if (autocvar_hud_panel_weapons_onlyowned)
 494         {
 495                 if(autocvar__hud_configure)
 496                 {
 497                         if (!weapons_stat)
 498                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 499                                         weapons_stat |= WepSet_FromWeapon(i);
 500
 501                         if(menu_enabled != 2)
 502                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 503                 }
 504
 505                 // do we own this weapon?
 506                 weapon_count = 0;
 507                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 508                         if(weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon))
 509                                 ++weapon_count;
 510
 511                 // add it anyway if weaponcomplain is shown
 512                 if(complain_weapon)
 513                         ++weapon_count;
 514
 515                 // might as well commit suicide now, no reason to live ;)
 516                 if (weapon_count == 0)
 517                 {
 518                         draw_endBoldFont();
 519                         return;
 520                 }
 521
 522                 old_panel_size = panel_size;
 523                 if(panel_bg_padding)
 524                         old_panel_size -= '2 2 0' * panel_bg_padding;
 525
 526                 // first find values for the standard table (with all the weapons)
 527                 rows = old_panel_size_y/old_panel_size_x;
 528                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
 529                 columns = ceil(WEP_COUNT/rows);
 530                 weapon_size_x = old_panel_size_x / columns;
 531                 weapon_size_y = old_panel_size_y / rows;
 532
 533                 // change table values to include only the owned weapons
 534                 float columns_save = columns;
 535                 if(weapon_count <= rows)
 536                 {
 537                         rows = weapon_count;
 538                         columns = 1;
 539                 }
 540                 else
 541                         columns = ceil(weapon_count / rows);
 542
 543                 // enlarge weapon_size to match desired aspect ratio in order to capitalize on panel space
 544                 if(columns < columns_save)
 545                         weapon_size_x = min(old_panel_size_x / columns, aspect * weapon_size_y);
 546
 547                 // reduce size of the panel
 548                 panel_size_x = columns * weapon_size_x;
 549                 panel_size_y = rows * weapon_size_y;
 550                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 551                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 552                 if(panel_bg_padding)
 553                         panel_size += '2 2 0' * panel_bg_padding;
 554         }
 555         else
 556                 weapon_count = WEP_COUNT;
 557
 558         // animation for fading in/out the panel respectively when not in use
 559         if(!autocvar__hud_configure)
 560         {
 561                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 562                 {
 563                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 564
 565                         // fade the panel alpha
 566                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 567                         {
 568                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 569                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 570                         }
 571                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 572                         {
 573                                 panel_bg_alpha *= (1 - f);
 574                                 panel_fg_alpha *= (1 - f);
 575                         }
 576
 577                         // move the panel off the screen
 578                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 579                         {
 580                                 f *= f; // for a cooler movement
 581                                 center_x = panel_pos_x + panel_size_x/2;
 582                                 center_y = panel_pos_y + panel_size_y/2;
 583                                 screen_ar = vid_conwidth/vid_conheight;
 584                                 if (center_x/center_y < screen_ar) //bottom left
 585                                 {
 586                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 587                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 588                                         else //left
 589                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 590                                 }
 591                                 else //top right
 592                                 {
 593                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 594                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 595                                         else //top
 596                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 597                                 }
 598                                 if(f == 1)
 599                                         center_x = -1; // mark the panel as off screen
 600                         }
 601                         weaponprevtime = time - (1 - f) * timein_effect_length;
 602                 }
 603                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 604                 {
 605                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 606
 607                         // fade the panel alpha
 608                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 609                         {
 610                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 611                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 612                         }
 613                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 614                         {
 615                                 panel_bg_alpha *= (f);
 616                                 panel_fg_alpha *= (f);
 617                         }
 618
 619                         // move the panel back on screen
 620                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 621                         {
 622                                 f *= f; // for a cooler movement
 623                                 f = 1 - f;
 624                                 center_x = panel_pos_x + panel_size_x/2;
 625                                 center_y = panel_pos_y + panel_size_y/2;
 626                                 screen_ar = vid_conwidth/vid_conheight;
 627                                 if (center_x/center_y < screen_ar) //bottom left
 628                                 {
 629                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 630                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 631                                         else //left
 632                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 633                                 }
 634                                 else //top right
 635                                 {
 636                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 637                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 638                                         else //top
 639                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 640                                 }
 641                         }
 642                 }
 643         }
 644
 645         // draw the background, then change the virtual size of it to better fit other items inside
 646         HUD_Panel_DrawBg(1);
 647
 648         if(center_x == -1)
 649         {
 650                 draw_endBoldFont();
 651                 return;
 652         }
 653
 654         if(panel_bg_padding)
 655         {
 656                 panel_pos += '1 1 0' * panel_bg_padding;
 657                 panel_size -= '2 2 0' * panel_bg_padding;
 658         }
 659
 660         // after the sizing and animations are done, update the other values
 661
 662         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 663         {
 664                 rows = panel_size_y/panel_size_x;
 665                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
 666                 columns = ceil(weapon_count/rows);
 667                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 668         }
 669
 670         // calculate position/size for visual bar displaying ammount of ammo status
 671         if (autocvar_hud_panel_weapons_ammo)
 672         {
 673                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 674                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 675
 676                 if(weapon_size_x/weapon_size_y > aspect)
 677                 {
 678                         barsize_x = aspect * weapon_size_y;
 679                         barsize_y = weapon_size_y;
 680                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 681                 }
 682                 else
 683                 {
 684                         barsize_y = 1/aspect * weapon_size_x;
 685                         barsize_x = weapon_size_x;
 686                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 687                 }
 688         }
 689         if(autocvar_hud_panel_weapons_accuracy)
 690                 Accuracy_LoadColors();
 691
 692         row = column = 0;
 693         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 694         {
 695                 // retrieve information about the current weapon to be drawn
 696                 self = weaponorder[i];
 697                 weapon_id = self.impulse;
 698
 699                 // skip if this weapon doesn't exist
 700                 if(!self || weapon_id < 0) { continue; }
 701
 702                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 703                 if(autocvar_hud_panel_weapons_onlyowned)
 704                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 705                         continue;
 706
 707                 // figure out the drawing position of weapon
 708                 weapon_pos = (panel_pos
 709                         + eX * column * weapon_size_x
 710                         + eY * row * weapon_size_y);
 711
 712                 // draw background behind currently selected weapon
 713                 if(self.weapon == switchweapon)
 714                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 715
 716                 // draw the weapon accuracy
 717                 if(autocvar_hud_panel_weapons_accuracy)
 718                 {
 719                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 720                         if(panel_weapon_accuracy >= 0)
 721                         {
 722                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 723                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 724                         }
 725                 }
 726
 727                 // drawing all the weapon items
 728                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 729                 {
 730                         // draw the weapon image
 731                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 732
 733                         // draw weapon label string
 734                         switch(autocvar_hud_panel_weapons_label)
 735                         {
 736                                 case 1: // weapon number
 737                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 738                                         break;
 739
 740                                 case 2: // bind
 741                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 742                                         break;
 743
 744                                 case 3: // weapon name
 745                                         drawstring(weapon_pos, strtolower(self.message), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 746                                         break;
 747
 748                                 default: // nothing
 749                                         break;
 750                         }
 751
 752                         // draw ammo status bar
 753                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 754                         {
 755                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 756
 757                                 if(a > 0)
 758                                 {
 759                                         switch(self.ammo_field)
 760                                         {
 761                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 762                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 763                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 764                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 765                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 766                                                 default: ammo_full = 60;
 767                                         }
 768
 769                                         drawsetcliparea(
 770                                                 weapon_pos_x + baroffset_x,
 771                                                 weapon_pos_y + baroffset_y,
 772                                                 barsize_x * bound(0, a/ammo_full, 1),
 773                                                 barsize_y
 774                                         );
 775
 776                                         drawpic_aspect_skin(
 777                                                 weapon_pos,
 778                                                 "weapon_ammo",
 779                                                 weapon_size,
 780                                                 ammo_color,
 781                                                 ammo_alpha,
 782                                                 DRAWFLAG_NORMAL
 783                                         );
 784
 785                                         drawresetcliparea();
 786                                 }
 787                         }
 788                 }
 789                 else // draw a "ghost weapon icon" if you don't have the weapon
 790                 {
 791                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 792                 }
 793
 794                 // draw the complain message
 795                 if(self.weapon == complain_weapon)
 796                 {
 797                         if(fadetime)
 798                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 799                         else
 800                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 801
 802                         string s;
 803                         if(complain_weapon_type == 0) {
 804                                 s = _("Out of ammo");
 805                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 806                         }
 807                         else if(complain_weapon_type == 1) {
 808                                 s = _("Don't have");
 809                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 810                         }
 811                         else {
 812                                 s = _("Unavailable");
 813                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 814                         }
 815                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 816                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 817                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 818                 }
 819
 820                 // continue with new position for the next weapon
 821                 ++row;
 822                 if(row >= rows)
 823                 {
 824                         row = 0;
 825                         ++column;
 826                 }
 827         }
 828
 829         draw_endBoldFont();
 830 }
 831
 832 // Ammo (#1)
 833 void DrawAmmoItem(vector myPos, vector mySize, .float ammotype, float currently_selected, float infinite_ammo)
 834 {
 835         float a = 0;
 836         if(ammotype != ammo_none)
 837         {
 838                 if(autocvar__hud_configure)
 839                 {
 840                         currently_selected = (ammotype == ammo_rockets); //rockets always selected
 841                         a = 60;
 842                 }
 843                 else
 844                 {
 845                         // how much ammo do we have of this ammotype?
 846                         a = getstati(GetAmmoStat(ammotype));
 847                 }
 848         }
 849         else
 850         {
 851                 #if 0
 852                 infinite_ammo = TRUE;
 853                 #else
 854                 return; // just don't draw infinite ammo at all.
 855                 #endif
 856         }
 857
 858         vector color;
 859         if(infinite_ammo)
 860                 color = '0 0.5 0.75';
 861         else if(a < 10)
 862                 color = '0.7 0 0';
 863         else
 864                 color = '1 1 1';
 865
 866         float theAlpha;
 867         if(currently_selected)
 868                 theAlpha = 1;
 869         else
 870                 theAlpha = 0.7;
 871
 872         vector picpos, numpos;
 873         if(autocvar_hud_panel_ammo_iconalign)
 874         {
 875                 numpos = myPos;
 876                 picpos = myPos + eX * 2 * mySize_y;
 877         }
 878         else
 879         {
 880                 numpos = myPos + eX * mySize_y;
 881                 picpos = myPos;
 882         }
 883
 884         if(currently_selected)
 885                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 886
 887     if(a > 0 && autocvar_hud_panel_ammo_progressbar)
 888         HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, a/autocvar_hud_panel_ammo_maxammo, 0, 0, color, autocvar_hud_progressbar_alpha * panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 889
 890     if(autocvar_hud_panel_ammo_text)
 891     {
 892         if(a > 0 || infinite_ammo)
 893             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 894         else // "ghost" ammo count
 895             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 896     }
 897         if(a > 0 || infinite_ammo)
 898                 drawpic_aspect_skin(picpos, GetAmmoPicture(ammotype), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 899         else // "ghost" ammo icon
 900                 drawpic_aspect_skin(picpos, GetAmmoPicture(ammotype), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 901 }
 902
 903 void HUD_Ammo(void)
 904 {
 905         if(hud != HUD_NORMAL) return;
 906         if(!autocvar__hud_configure)
 907         {
 908                 if(!autocvar_hud_panel_ammo) return;
 909                 if(spectatee_status == -1) return;
 910         }
 911
 912         HUD_Panel_UpdateCvars();
 913
 914         draw_beginBoldFont();
 915
 916         vector pos, mySize;
 917         pos = panel_pos;
 918         mySize = panel_size;
 919
 920         HUD_Panel_DrawBg(1);
 921         if(panel_bg_padding)
 922         {
 923                 pos += '1 1 0' * panel_bg_padding;
 924                 mySize -= '2 2 0' * panel_bg_padding;
 925         }
 926
 927         const float AMMO_COUNT = 4;
 928         float rows = 0, columns, row, column;
 929         vector ammo_size;
 930         if(autocvar_hud_panel_ammo_onlycurrent)
 931                 ammo_size = mySize;
 932         else
 933         {
 934                 rows = mySize_y/mySize_x;
 935                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
 936                 //                               ^^^ ammo item aspect goes here
 937
 938                 columns = ceil(AMMO_COUNT/rows);
 939
 940                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
 941         }
 942
 943         local vector offset = '0 0 0'; // fteqcc sucks
 944         float newSize;
 945         if(ammo_size_x/ammo_size_y > 3)
 946         {
 947                 newSize = 3 * ammo_size_y;
 948                 offset_x = ammo_size_x - newSize;
 949                 pos_x += offset_x/2;
 950                 ammo_size_x = newSize;
 951         }
 952         else
 953         {
 954                 newSize = 1/3 * ammo_size_x;
 955                 offset_y = ammo_size_y - newSize;
 956                 pos_y += offset_y/2;
 957                 ammo_size_y = newSize;
 958         }
 959
 960         float i;
 961         float infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
 962         if(autocvar_hud_panel_ammo_onlycurrent)
 963         {
 964                 if(autocvar__hud_configure)
 965                 {
 966                         DrawAmmoItem(pos, ammo_size, ammo_rockets, TRUE, FALSE);
 967                 }
 968                 else
 969                 {
 970                         DrawAmmoItem(
 971                                 pos,
 972                                 ammo_size,
 973                                 (get_weaponinfo(switchweapon)).ammo_field,
 974                                 TRUE,
 975                                 infinite_ammo
 976                         );
 977                 }
 978         }
 979         else
 980         {
 981                 .float ammotype;
 982                 row = column = 0;
 983                 for(i = 0; i < AMMO_COUNT; ++i)
 984                 {
 985                         ammotype = GetAmmoFieldFromNum(i);
 986                         DrawAmmoItem(
 987                                 pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y),
 988                                 ammo_size,
 989                                 ammotype,
 990                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
 991                                 infinite_ammo
 992                         );
 993
 994                         ++row;
 995                         if(row >= rows)
 996                         {
 997                                 row = 0;
 998                                 column = column + 1;
 999                         }
1000                 }
1001         }
1002
1003         draw_endBoldFont();
1004 }
1005
1006 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1007 {
1008         vector newPos = '0 0 0', newSize = '0 0 0';
1009         vector picpos, numpos;
1010
1011         if (vertical)
1012         {
1013                 if(mySize_y/mySize_x > 2)
1014                 {
1015                         newSize_y = 2 * mySize_x;
1016                         newSize_x = mySize_x;
1017
1018                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1019                         newPos_x = myPos_x;
1020                 }
1021                 else
1022                 {
1023                         newSize_x = 1/2 * mySize_y;
1024                         newSize_y = mySize_y;
1025
1026                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1027                         newPos_y = myPos_y;
1028                 }
1029
1030                 if(icon_right_align)
1031                 {
1032                         numpos = newPos;
1033                         picpos = newPos + eY * newSize_x;
1034                 }
1035                 else
1036                 {
1037                         picpos = newPos;
1038                         numpos = newPos + eY * newSize_x;
1039                 }
1040
1041                 newSize_y /= 2;
1042                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1043                 // make number smaller than icon, it looks better
1044                 // reduce only y to draw numbers with different number of digits with the same y size
1045                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1046                 newSize_y *= 0.7;
1047                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1048                 return;
1049         }
1050
1051         if(mySize_x/mySize_y > 3)
1052         {
1053                 newSize_x = 3 * mySize_y;
1054                 newSize_y = mySize_y;
1055
1056                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1057                 newPos_y = myPos_y;
1058         }
1059         else
1060         {
1061                 newSize_y = 1/3 * mySize_x;
1062                 newSize_x = mySize_x;
1063
1064                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1065                 newPos_x = myPos_x;
1066         }
1067
1068         if(icon_right_align) // right align
1069         {
1070                 numpos = newPos;
1071                 picpos = newPos + eX * 2 * newSize_y;
1072         }
1073         else // left align
1074         {
1075                 numpos = newPos + eX * newSize_y;
1076                 picpos = newPos;
1077         }
1078
1079         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1080         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1081         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1082         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1083 }
1084
1085 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1086 {
1087         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1088 }
1089
1090 // Powerups (#2)
1091 //
1092 void HUD_Powerups(void)
1093 {
1094         float strength_time, shield_time, superweapons_time;
1095         if(!autocvar__hud_configure)
1096         {
1097                 if(!autocvar_hud_panel_powerups) return;
1098                 if(spectatee_status == -1) return;
1099                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1100                 if (getstati(STAT_HEALTH) <= 0) return;
1101
1102                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1103                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1104                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1105
1106                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1107                         superweapons_time = 99; // force max
1108
1109                 // prevent stuff to show up on mismatch that will be fixed next frame
1110                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1111                         superweapons_time = 0;
1112         }
1113         else
1114         {
1115                 strength_time = 15;
1116                 shield_time = 27;
1117                 superweapons_time = 13;
1118         }
1119
1120         HUD_Panel_UpdateCvars();
1121
1122         draw_beginBoldFont();
1123
1124         vector pos, mySize;
1125         pos = panel_pos;
1126         mySize = panel_size;
1127
1128         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1129         if(panel_bg_padding)
1130         {
1131                 pos += '1 1 0' * panel_bg_padding;
1132                 mySize -= '2 2 0' * panel_bg_padding;
1133         }
1134
1135         float panel_ar = mySize_x/mySize_y;
1136         float is_vertical = (panel_ar < 1);
1137         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1138
1139         float superweapons_is = -1;
1140
1141         if(superweapons_time)
1142         {
1143                 if(strength_time)
1144                 {
1145                         if(shield_time)
1146                                 superweapons_is = 0;
1147                         else
1148                                 superweapons_is = 2;
1149                 }
1150                 else
1151                 {
1152                         if(shield_time)
1153                                 superweapons_is = 1;
1154                         else
1155                                 superweapons_is = 2;
1156                 }
1157         }
1158
1159         // FIXME handle superweapons here
1160         if(superweapons_is == 0)
1161         {
1162                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1163                 {
1164                         mySize_x *= (1.0 / 3.0);
1165                         superweapons_offset_x = mySize_x;
1166                         if (autocvar_hud_panel_powerups_flip)
1167                                 shield_offset_x = 2*mySize_x;
1168                         else
1169                                 strength_offset_x = 2*mySize_x;
1170                 }
1171                 else
1172                 {
1173                         mySize_y *= (1.0 / 3.0);
1174                         superweapons_offset_y = mySize_y;
1175                         if (autocvar_hud_panel_powerups_flip)
1176                                 shield_offset_y = 2*mySize_y;
1177                         else
1178                                 strength_offset_y = 2*mySize_y;
1179                 }
1180         }
1181         else
1182         {
1183                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1184                 {
1185                         mySize_x *= 0.5;
1186                         if (autocvar_hud_panel_powerups_flip)
1187                                 shield_offset_x = mySize_x;
1188                         else
1189                                 strength_offset_x = mySize_x;
1190                 }
1191                 else
1192                 {
1193                         mySize_y *= 0.5;
1194                         if (autocvar_hud_panel_powerups_flip)
1195                                 shield_offset_y = mySize_y;
1196                         else
1197                                 strength_offset_y = mySize_y;
1198                 }
1199         }
1200
1201         float shield_baralign, strength_baralign, superweapons_baralign;
1202         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1203
1204         if (autocvar_hud_panel_powerups_flip)
1205         {
1206                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1207                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1208                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1209                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1210         }
1211         else
1212         {
1213                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1214                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1215                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1216                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1217         }
1218
1219         if(superweapons_is == 0)
1220         {
1221                 superweapons_iconalign = strength_iconalign;
1222                 superweapons_baralign = 2;
1223         }
1224         else if(superweapons_is == 1)
1225         {
1226                 superweapons_offset = strength_offset;
1227                 superweapons_iconalign = strength_iconalign;
1228                 superweapons_baralign = strength_baralign;
1229         }
1230         else // if(superweapons_is == 2)
1231         {
1232                 superweapons_offset = shield_offset;
1233                 superweapons_iconalign = shield_iconalign;
1234                 superweapons_baralign = shield_baralign;
1235         }
1236
1237         if(shield_time)
1238         {
1239                 const float maxshield = 30;
1240                 float shield = ceil(shield_time);
1241                 if(autocvar_hud_panel_powerups_progressbar)
1242                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1243                 if(autocvar_hud_panel_powerups_text)
1244                 {
1245                         if(shield > 1)
1246                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1247                         if(shield <= 5)
1248                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1249                 }
1250         }
1251
1252         if(strength_time)
1253         {
1254                 const float maxstrength = 30;
1255                 float strength = ceil(strength_time);
1256                 if(autocvar_hud_panel_powerups_progressbar)
1257                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1258                 if(autocvar_hud_panel_powerups_text)
1259                 {
1260                         if(strength > 1)
1261                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1262                         if(strength <= 5)
1263                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1264                 }
1265         }
1266
1267         if(superweapons_time)
1268         {
1269                 const float maxsuperweapons = 30;
1270                 float superweapons = ceil(superweapons_time);
1271                 if(autocvar_hud_panel_powerups_progressbar)
1272                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1273                 if(autocvar_hud_panel_powerups_text)
1274                 {
1275                         if(superweapons > 1)
1276                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1277                         if(superweapons <= 5)
1278                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1279                 }
1280         }
1281
1282         draw_endBoldFont();
1283 }
1284
1285 // Health/armor (#3)
1286 //
1287
1288 // prev_* vars contain the health/armor at the previous FRAME
1289 // set to -1 when player is dead or was not playing
1290 float prev_health, prev_armor;
1291 float health_damagetime, armor_damagetime;
1292 float health_beforedamage, armor_beforedamage;
1293 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1294 float old_p_health, old_p_armor;
1295 float old_p_healthtime, old_p_armortime;
1296 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1297 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1298 float prev_p_health, prev_p_armor;
1299
1300 void HUD_HealthArmor(void)
1301 {
1302         float armor, health, fuel;
1303         if(!autocvar__hud_configure)
1304         {
1305                 if(!autocvar_hud_panel_healtharmor) return;
1306                 if(hud != HUD_NORMAL) return;
1307                 if(spectatee_status == -1) return;
1308
1309                 health = getstati(STAT_HEALTH);
1310                 if(health <= 0)
1311                 {
1312                         prev_health = -1;
1313                         return;
1314                 }
1315                 armor = getstati(STAT_ARMOR);
1316
1317                 // code to check for spectatee_status changes is in Ent_ClientData()
1318                 // prev_p_health and prev_health can be set to -1 there
1319
1320                 if (prev_p_health == -1)
1321                 {
1322                         // no effect
1323                         health_beforedamage = 0;
1324                         armor_beforedamage = 0;
1325                         health_damagetime = 0;
1326                         armor_damagetime = 0;
1327                         prev_health = health;
1328                         prev_armor = armor;
1329                         old_p_health = health;
1330                         old_p_armor = armor;
1331                         prev_p_health = health;
1332                         prev_p_armor = armor;
1333                 }
1334                 else if (prev_health == -1)
1335                 {
1336                         //start the load effect
1337                         health_damagetime = 0;
1338                         armor_damagetime = 0;
1339                         prev_health = 0;
1340                         prev_armor = 0;
1341                 }
1342                 fuel = getstati(STAT_FUEL);
1343         }
1344         else
1345         {
1346                 health = 150;
1347                 armor = 75;
1348                 fuel = 20;
1349         }
1350
1351         HUD_Panel_UpdateCvars();
1352         vector pos, mySize;
1353         pos = panel_pos;
1354         mySize = panel_size;
1355
1356         HUD_Panel_DrawBg(1);
1357         if(panel_bg_padding)
1358         {
1359                 pos += '1 1 0' * panel_bg_padding;
1360                 mySize -= '2 2 0' * panel_bg_padding;
1361         }
1362
1363         float baralign = autocvar_hud_panel_healtharmor_baralign;
1364         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1365
1366     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1367     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1368         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1369         {
1370                 vector v;
1371                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1372
1373                 float x;
1374                 x = floor(v_x + 1);
1375
1376         float maxtotal = maxhealth + maxarmor;
1377                 string biggercount;
1378                 if(v_z) // NOT fully armored
1379                 {
1380                         biggercount = "health";
1381                         if(autocvar_hud_panel_healtharmor_progressbar)
1382                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1383                         if(armor)
1384             if(autocvar_hud_panel_healtharmor_text)
1385                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1386                 }
1387                 else
1388                 {
1389                         biggercount = "armor";
1390                         if(autocvar_hud_panel_healtharmor_progressbar)
1391                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1392                         if(health)
1393             if(autocvar_hud_panel_healtharmor_text)
1394                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1395                 }
1396         if(autocvar_hud_panel_healtharmor_text)
1397                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1398
1399                 if(fuel)
1400                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1401         }
1402         else
1403         {
1404                 float panel_ar = mySize_x/mySize_y;
1405                 float is_vertical = (panel_ar < 1);
1406                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1407                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1408                 {
1409                         mySize_x *= 0.5;
1410                         if (autocvar_hud_panel_healtharmor_flip)
1411                                 health_offset_x = mySize_x;
1412                         else
1413                                 armor_offset_x = mySize_x;
1414                 }
1415                 else
1416                 {
1417                         mySize_y *= 0.5;
1418                         if (autocvar_hud_panel_healtharmor_flip)
1419                                 health_offset_y = mySize_y;
1420                         else
1421                                 armor_offset_y = mySize_y;
1422                 }
1423
1424                 float health_baralign, armor_baralign, fuel_baralign;
1425                 float health_iconalign, armor_iconalign;
1426                 if (autocvar_hud_panel_healtharmor_flip)
1427                 {
1428                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1429                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1430                         fuel_baralign = health_baralign;
1431                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1432                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1433                 }
1434                 else
1435                 {
1436                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1437                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1438                         fuel_baralign = armor_baralign;
1439                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1440                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1441                 }
1442
1443                 //if(health)
1444                 {
1445                         if(autocvar_hud_panel_healtharmor_progressbar)
1446                         {
1447                                 float p_health, pain_health_alpha;
1448                                 p_health = health;
1449                                 pain_health_alpha = 1;
1450                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1451                                 {
1452                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1453                                         {
1454                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1455                                                 {
1456                                                         if (time - old_p_healthtime < 1)
1457                                                                 old_p_health = prev_p_health;
1458                                                         else
1459                                                                 old_p_health = prev_health;
1460                                                         old_p_healthtime = time;
1461                                                 }
1462                                                 if (time - old_p_healthtime < 1)
1463                                                 {
1464                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1465                                                         prev_p_health = p_health;
1466                                                 }
1467                                         }
1468                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1469                                         {
1470                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1471                                                 {
1472                                                         if (time - health_damagetime >= 1)
1473                                                                 health_beforedamage = prev_health;
1474                                                         health_damagetime = time;
1475                                                 }
1476                                                 if (time - health_damagetime < 1)
1477                                                 {
1478                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1479                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1480                                                 }
1481                                         }
1482                                         prev_health = health;
1483
1484                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1485                                         {
1486                                                 float BLINK_FACTOR = 0.15;
1487                                                 float BLINK_BASE = 0.85;
1488                                                 float BLINK_FREQ = 9;
1489                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1490                                         }
1491                                 }
1492                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1493                         }
1494                         if(autocvar_hud_panel_healtharmor_text)
1495                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1496                 }
1497
1498                 if(armor)
1499                 {
1500                         if(autocvar_hud_panel_healtharmor_progressbar)
1501                         {
1502                                 float p_armor;
1503                                 p_armor = armor;
1504                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1505                                 {
1506                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1507                                         {
1508                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1509                                                 {
1510                                                         if (time - old_p_armortime < 1)
1511                                                                 old_p_armor = prev_p_armor;
1512                                                         else
1513                                                                 old_p_armor = prev_armor;
1514                                                         old_p_armortime = time;
1515                                                 }
1516                                                 if (time - old_p_armortime < 1)
1517                                                 {
1518                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1519                                                         prev_p_armor = p_armor;
1520                                                 }
1521                                         }
1522                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1523                                         {
1524                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1525                                                 {
1526                                                         if (time - armor_damagetime >= 1)
1527                                                                 armor_beforedamage = prev_armor;
1528                                                         armor_damagetime = time;
1529                                                 }
1530                                                 if (time - armor_damagetime < 1)
1531                                                 {
1532                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1533                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1534                                                 }
1535                                         }
1536                                         prev_armor = armor;
1537                                 }
1538                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1539                         }
1540                         if(autocvar_hud_panel_healtharmor_text)
1541                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1542                 }
1543
1544                 if(fuel)
1545                 {
1546                         if (is_vertical)
1547                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1548                         else
1549                                 mySize_y *= 0.2;
1550                         if (panel_ar >= 4)
1551                                 mySize_x *= 2; //restore full panel size
1552                         else if (panel_ar < 1/4)
1553                                 mySize_y *= 2; //restore full panel size
1554                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1555                 }
1556         }
1557 }
1558
1559 // Notification area (#4)
1560 //
1561
1562 void HUD_Notify_Push(string icon, string attacker, string victim)
1563 {
1564         if(icon != "")
1565         {
1566                 --kn_index;
1567                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
1568                 notify_times[kn_index] = time;
1569
1570                 // icon
1571                 if(notify_icon[kn_index]) { strunzone(notify_icon[kn_index]); }
1572                 notify_icon[kn_index] = strzone(icon);
1573
1574                 // attacker
1575                 if(notify_attackers[kn_index]) { strunzone(notify_attackers[kn_index]); }
1576                 notify_attackers[kn_index] = strzone(attacker);
1577
1578                 // victim
1579                 if(notify_victims[kn_index]) { strunzone(notify_victims[kn_index]); }
1580                 notify_victims[kn_index] = strzone(victim);
1581         }
1582 }
1583
1584 void HUD_Notify(void)
1585 {
1586         if(!autocvar__hud_configure)
1587         {
1588                 if(!autocvar_hud_panel_notify) return;
1589         }
1590
1591         HUD_Panel_UpdateCvars();
1592         vector pos, mySize;
1593         pos = panel_pos;
1594         mySize = panel_size;
1595
1596         HUD_Panel_DrawBg(1);
1597         if(panel_bg_padding)
1598         {
1599                 pos += '1 1 0' * panel_bg_padding;
1600                 mySize -= '2 2 0' * panel_bg_padding;
1601         }
1602
1603         float entries, height;
1604         entries = bound(1, floor(KN_MAX_ENTRIES * mySize_y/mySize_x), KN_MAX_ENTRIES);
1605         height = mySize_y/entries;
1606
1607         vector fontsize;
1608         float fontheight = height * autocvar_hud_panel_notify_fontsize;
1609         fontsize = '0.5 0.5 0' * fontheight;
1610
1611         float a;
1612         float when;
1613         when = autocvar_hud_panel_notify_time;
1614         float fadetime;
1615         fadetime = autocvar_hud_panel_notify_fadetime;
1616
1617         vector pos_attacker, pos_victim, pos_icon;
1618         float width_attacker;
1619         string attacker, victim, icon;
1620
1621         float i, j, step, limit;
1622         if(autocvar_hud_panel_notify_flip) //order items from the top down
1623         {
1624                 i = 0;
1625                 step = +1;
1626                 limit = entries;
1627         }
1628         else //order items from the bottom up
1629         {
1630                 i = entries - 1;
1631                 step = -1;
1632                 limit = -1;
1633         }
1634
1635         for(j = kn_index;  i != limit;  i += step, ++j)
1636         {
1637                 if(autocvar__hud_configure)
1638                 {
1639                         if (step == +1)
1640                                 a = i;
1641                         else // inverse order
1642                                 a = entries - 1 - i;
1643                         attacker = textShortenToWidth(sprintf(_("Player %d"), a+1), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1644                         victim = textShortenToWidth(sprintf(_("Player %d"), a+2), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1645                         icon = get_weaponinfo(WEP_FIRST + mod(floor(a*2.4), WEP_LAST)).model2;
1646                         a = bound(0, (when - a) / 4, 1);
1647                         goto hud_config_notifyprint;
1648                 }
1649                 else
1650                 {
1651                         if (j == KN_MAX_ENTRIES)
1652                                 j = 0;
1653
1654                         if(notify_times[j] + when > time)
1655                                 a = 1;
1656                         else if(fadetime)
1657                         {
1658                                 a = bound(0, (notify_times[j] + when + fadetime - time) / fadetime, 1);
1659                                 if(!a)
1660                                 {
1661                                         break;
1662                                 }
1663                         }
1664                         else
1665                         {
1666                                 break;
1667                         }
1668
1669                         attacker = notify_attackers[j];
1670                         victim = notify_victims[j];
1671                         icon = notify_icon[j];
1672                 }
1673
1674                 //type = notify_deathtype[j];
1675                 //w = DEATH_WEAPONOF(type);
1676
1677                 if(icon != "")
1678                 {
1679                         if((attacker != "") && (victim == ""))
1680                         {
1681                                 // Y [used by] X
1682                                 attacker = textShortenToWidth(attacker, 0.73 * mySize_x - height, fontsize, stringwidth_colors);
1683                                 pos_attacker = pos + eX * (0.27 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1684                                 pos_icon = pos + eX * 0.25 * mySize_x - eX * height + eY * i * height;
1685
1686                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1687                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1688                         }
1689                         else if((attacker != "") && (victim != ""))
1690                         {
1691                                 // X [did action to] Y
1692                                 attacker = textShortenToWidth(attacker, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1693                                 victim = textShortenToWidth(victim, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1694 :hud_config_notifyprint
1695                                 width_attacker = stringwidth(attacker, TRUE, fontsize);
1696                                 pos_attacker = pos + eX * (0.48 * mySize_x - height - width_attacker) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1697                                 pos_victim = pos + eX * (0.52 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1698                                 pos_icon = pos + eX * 0.5 * mySize_x - eX * height + eY * i * height;
1699
1700                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1701                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1702                                 drawcolorcodedstring(pos_victim, victim, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1703                         }
1704                 }
1705         }
1706 }
1707
1708 // Timer (#5)
1709 //
1710 // TODO: macro
1711 string seconds_tostring(float sec)
1712 {
1713         float minutes;
1714         minutes = floor(sec / 60);
1715
1716         sec -= minutes * 60;
1717         return sprintf("%d:%02d", minutes, sec);
1718 }
1719
1720 void HUD_Timer(void)
1721 {
1722         if(!autocvar__hud_configure)
1723         {
1724                 if(!autocvar_hud_panel_timer) return;
1725         }
1726
1727         HUD_Panel_UpdateCvars();
1728
1729         draw_beginBoldFont();
1730
1731         vector pos, mySize;
1732         pos = panel_pos;
1733         mySize = panel_size;
1734
1735         HUD_Panel_DrawBg(1);
1736         if(panel_bg_padding)
1737         {
1738                 pos += '1 1 0' * panel_bg_padding;
1739                 mySize -= '2 2 0' * panel_bg_padding;
1740         }
1741
1742         string timer;
1743         float timelimit, elapsedTime, timeleft, minutesLeft;
1744
1745         timelimit = getstatf(STAT_TIMELIMIT);
1746
1747         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1748         timeleft = ceil(timeleft);
1749
1750         minutesLeft = floor(timeleft / 60);
1751
1752         vector timer_color;
1753         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1754                 timer_color = '1 1 1'; //white
1755         else if(minutesLeft >= 1)
1756                 timer_color = '1 1 0'; //yellow
1757         else
1758                 timer_color = '1 0 0'; //red
1759
1760         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1761                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1762                         //while restart is still active, show 00:00
1763                         timer = seconds_tostring(0);
1764                 } else {
1765                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1766                         timer = seconds_tostring(elapsedTime);
1767                 }
1768         } else {
1769                 timer = seconds_tostring(timeleft);
1770         }
1771
1772         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1773
1774         draw_endBoldFont();
1775 }
1776
1777 // Radar (#6)
1778 //
1779 void HUD_Radar(void)
1780 {
1781         if (!autocvar__hud_configure)
1782         {
1783                 if (hud_panel_radar_maximized)
1784                 {
1785                         if (!hud_draw_maximized) return;
1786                 }
1787                 else
1788                 {
1789                         if (autocvar_hud_panel_radar == 0) return;
1790                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1791                         if(radar_panel_modified)
1792                         {
1793                                 panel.update_time = time; // forces reload of panel attributes
1794                                 radar_panel_modified = false;
1795                         }
1796                 }
1797         }
1798
1799         HUD_Panel_UpdateCvars();
1800
1801         float f = 0;
1802
1803         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1804         {
1805                 panel_size = autocvar_hud_panel_radar_maximized_size;
1806                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1807                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1808                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1809                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1810
1811                 string panel_bg;
1812                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1813                 if(precache_pic(panel_bg) == "")
1814                         panel_bg = "gfx/hud/default/border_default"; // fallback
1815                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
1816                         radar_panel_modified = true;
1817                 if(panel.current_panel_bg)
1818                         strunzone(panel.current_panel_bg);
1819                 panel.current_panel_bg = strzone(panel_bg);
1820
1821                 switch(hud_panel_radar_maximized_zoommode)
1822                 {
1823                         default:
1824                         case 0:
1825                                 f = current_zoomfraction;
1826                                 break;
1827                         case 1:
1828                                 f = 1 - current_zoomfraction;
1829                                 break;
1830                         case 2:
1831                                 f = 0;
1832                                 break;
1833                         case 3:
1834                                 f = 1;
1835                                 break;
1836                 }
1837
1838                 switch(hud_panel_radar_maximized_rotation)
1839                 {
1840                         case 0:
1841                                 teamradar_angle = view_angles_y - 90;
1842                                 break;
1843                         default:
1844                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1845                                 break;
1846                 }
1847         }
1848         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1849         {
1850                 switch(hud_panel_radar_zoommode)
1851                 {
1852                         default:
1853                         case 0:
1854                                 f = current_zoomfraction;
1855                                 break;
1856                         case 1:
1857                                 f = 1 - current_zoomfraction;
1858                                 break;
1859                         case 2:
1860                                 f = 0;
1861                                 break;
1862                         case 3:
1863                                 f = 1;
1864                                 break;
1865                 }
1866
1867                 switch(hud_panel_radar_rotation)
1868                 {
1869                         case 0:
1870                                 teamradar_angle = view_angles_y - 90;
1871                                 break;
1872                         default:
1873                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1874                                 break;
1875                 }
1876         }
1877
1878         vector pos, mySize;
1879         pos = panel_pos;
1880         mySize = panel_size;
1881
1882         HUD_Panel_DrawBg(1);
1883         if(panel_bg_padding)
1884         {
1885                 pos += '1 1 0' * panel_bg_padding;
1886                 mySize -= '2 2 0' * panel_bg_padding;
1887         }
1888
1889         float color2;
1890         entity tm;
1891         float scale2d, normalsize, bigsize;
1892
1893         teamradar_origin2d = pos + 0.5 * mySize;
1894         teamradar_size2d = mySize;
1895
1896         if(minimapname == "")
1897                 return;
1898
1899         teamradar_loadcvars();
1900
1901         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1902         teamradar_size2d = mySize;
1903
1904         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1905
1906         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1907         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1908         {
1909                 // max-min distance must fit the radar in any rotation
1910                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
1911         }
1912         else
1913         {
1914                 vector c0, c1, c2, c3, span;
1915                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
1916                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
1917                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
1918                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
1919                 span = '0 0 0';
1920                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
1921                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
1922
1923                 // max-min distance must fit the radar in x=x, y=y
1924                 bigsize = min(
1925                         teamradar_size2d_x * scale2d / (1.05 * span_x),
1926                         teamradar_size2d_y * scale2d / (1.05 * span_y)
1927                 );
1928         }
1929
1930         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
1931         if(bigsize > normalsize)
1932                 normalsize = bigsize;
1933
1934         teamradar_size =
1935                   f * bigsize
1936                 + (1 - f) * normalsize;
1937         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
1938                   f * mi_center
1939                 + (1 - f) * view_origin);
1940
1941         drawsetcliparea(
1942                 pos_x,
1943                 pos_y,
1944                 mySize_x,
1945                 mySize_y
1946         );
1947
1948         draw_teamradar_background(hud_panel_radar_foreground_alpha);
1949
1950         for(tm = world; (tm = find(tm, classname, "radarlink")); )
1951                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
1952         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
1953                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
1954         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
1955         {
1956                 color2 = GetPlayerColor(tm.sv_entnum);
1957                 //if(color == NUM_SPECTATOR || color == color2)
1958                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
1959         }
1960         draw_teamradar_player(view_origin, view_angles, '1 1 1');
1961
1962         drawresetcliparea();
1963 }
1964
1965 // Score (#7)
1966 //
1967 void HUD_UpdatePlayerTeams();
1968 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
1969 {
1970         float score;
1971         entity tm = world, pl;
1972 #define SCOREPANEL_MAX_ENTRIES 6
1973 #define SCOREPANEL_ASPECTRATIO 2
1974         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
1975         vector fontsize = '1 1 0' * (mySize_y/entries);
1976
1977         vector rgb, score_color;
1978         rgb = '1 1 1';
1979         score_color = '1 1 1';
1980
1981         float name_size = mySize_x*0.75;
1982         float spacing_size = mySize_x*0.04;
1983         const float highlight_alpha = 0.2;
1984         float i = 0, me_printed = 0, first_pl = 0;
1985         string s;
1986         if (autocvar__hud_configure)
1987         {
1988                 float players_per_team = 0;
1989                 if (team_count)
1990                 {
1991                         // show team scores in the first line
1992                         float score_size = mySize_x / team_count;
1993                         players_per_team = max(2, ceil((entries - 1) / team_count));
1994                         for(i=0; i<team_count; ++i) {
1995                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
1996                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1997                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
1998                         }
1999                         first_pl = 1;
2000                         pos_y += fontsize_y;
2001                 }
2002                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2003                 for (i=first_pl; i<entries; ++i)
2004                 {
2005                         //simulate my score is lower than all displayed players,
2006                         //so that I don't appear at all showing pure rankings.
2007                         //This is to better show the difference between the 2 ranking views
2008                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2009                         {
2010                                 rgb = '1 1 0';
2011                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2012                                 s = GetPlayerName(player_localnum);
2013                                 score = 7;
2014                         }
2015                         else
2016                         {
2017                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2018                                 score -= 3;
2019                         }
2020
2021                         if (team_count)
2022                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2023                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2024                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2025                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2026                         pos_y += fontsize_y;
2027                 }
2028                 return;
2029         }
2030
2031         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2032                 HUD_UpdatePlayerTeams();
2033         if (team_count)
2034         {
2035                 // show team scores in the first line
2036                 float score_size = mySize_x / team_count;
2037                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2038                         if(tm.team == NUM_SPECTATOR)
2039                                 continue;
2040                         if (tm.team == myteam)
2041                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2042                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2043                         ++i;
2044                 }
2045                 first_pl = 1;
2046                 pos_y += fontsize_y;
2047                 tm = teams.sort_next;
2048         }
2049         i = first_pl;
2050
2051         do
2052         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2053         {
2054                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2055                         continue;
2056
2057                 if (i == entries-1 && !me_printed && pl != me)
2058                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2059                 {
2060                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2061                                 if (pl.team != NUM_SPECTATOR)
2062                                         break;
2063
2064                         if (pl)
2065                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2066                         else
2067                                 rgb = '1 0 0'; //last: red
2068                         pl = me;
2069                 }
2070
2071                 if (pl == me)
2072                 {
2073                         if (i == first_pl)
2074                                 rgb = '0 1 0'; //first: green
2075                         me_printed = 1;
2076                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2077                 }
2078                 if (team_count)
2079                         score_color = Team_ColorRGB(pl.team) * 0.8;
2080                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2081                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2082                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2083                 pos_y += fontsize_y;
2084                 ++i;
2085         }
2086         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2087 }
2088
2089 void HUD_Score(void)
2090 {
2091         if(!autocvar__hud_configure)
2092         {
2093                 if(!autocvar_hud_panel_score) return;
2094                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2095         }
2096
2097         HUD_Panel_UpdateCvars();
2098         vector pos, mySize;
2099         pos = panel_pos;
2100         mySize = panel_size;
2101
2102         HUD_Panel_DrawBg(1);
2103         if(panel_bg_padding)
2104         {
2105                 pos += '1 1 0' * panel_bg_padding;
2106                 mySize -= '2 2 0' * panel_bg_padding;
2107         }
2108
2109         float score, distribution = 0;
2110         string sign;
2111         vector distribution_color;
2112         entity tm, pl, me;
2113
2114 #ifdef COMPAT_XON050_ENGINE
2115         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
2116 #else
2117         me = playerslots[player_localentnum - 1];
2118 #endif
2119
2120         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2121                 string timer, distrtimer;
2122
2123                 pl = players.sort_next;
2124                 if(pl == me)
2125                         pl = pl.sort_next;
2126                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2127                         if(pl.scores[ps_primary] == 0)
2128                                 pl = world;
2129
2130                 score = me.(scores[ps_primary]);
2131                 timer = TIME_ENCODED_TOSTRING(score);
2132
2133                 draw_beginBoldFont();
2134                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2135                         // distribution display
2136                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2137
2138                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2139
2140                         if (distribution <= 0) {
2141                                 distribution_color = '0 1 0';
2142                                 sign = "-";
2143                         }
2144                         else {
2145                                 distribution_color = '1 0 0';
2146                                 sign = "+";
2147                         }
2148                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2149                 }
2150                 // race record display
2151                 if (distribution <= 0)
2152                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2153                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2154                 draw_endBoldFont();
2155         } else if (!teamplay) { // non-teamgames
2156                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2157                 {
2158                         HUD_Score_Rankings(pos, mySize, me);
2159                         return;
2160                 }
2161                 // me vector := [team/connected frags id]
2162                 pl = players.sort_next;
2163                 if(pl == me)
2164                         pl = pl.sort_next;
2165
2166                 if(autocvar__hud_configure)
2167                         distribution = 42;
2168                 else if(pl)
2169                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2170                 else
2171                         distribution = 0;
2172
2173                 score = me.(scores[ps_primary]);
2174                 if(autocvar__hud_configure)
2175                         score = 123;
2176
2177                 if(distribution >= 5)
2178                         distribution_color = eY;
2179                 else if(distribution >= 0)
2180                         distribution_color = '1 1 1';
2181                 else if(distribution >= -5)
2182                         distribution_color = '1 1 0';
2183                 else
2184                         distribution_color = eX;
2185
2186                 string distribution_str;
2187                 distribution_str = ftos(distribution);
2188                 draw_beginBoldFont();
2189                 if (distribution >= 0)
2190                 {
2191                         if (distribution > 0)
2192                                 distribution_str = strcat("+", distribution_str);
2193                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2194                 }
2195                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2196                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2197                 draw_endBoldFont();
2198         } else { // teamgames
2199                 float row, column, rows = 0, columns = 0;
2200                 local noref vector offset = '0 0 0';
2201                 vector score_pos, score_size; //for scores other than myteam
2202                 if(autocvar_hud_panel_score_rankings)
2203                 {
2204                         HUD_Score_Rankings(pos, mySize, me);
2205                         return;
2206                 }
2207                 if(spectatee_status == -1)
2208                 {
2209                         rows = mySize_y/mySize_x;
2210                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * team_count + rows * rows) + rows + 0.5) / 2), team_count);
2211                         //                               ^^^ ammo item aspect goes here
2212
2213                         columns = ceil(team_count/rows);
2214
2215                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2216
2217                         float newSize;
2218                         if(score_size_x/score_size_y > 3)
2219                         {
2220                                 newSize = 3 * score_size_y;
2221                                 offset_x = score_size_x - newSize;
2222                                 pos_x += offset_x/2;
2223                                 score_size_x = newSize;
2224                         }
2225                         else
2226                         {
2227                                 newSize = 1/3 * score_size_x;
2228                                 offset_y = score_size_y - newSize;
2229                                 pos_y += offset_y/2;
2230                                 score_size_y = newSize;
2231                         }
2232                 }
2233                 else
2234                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2235
2236                 float max_fragcount;
2237                 max_fragcount = -99;
2238                 draw_beginBoldFont();
2239                 row = column = 0;
2240                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2241                         if(tm.team == NUM_SPECTATOR)
2242                                 continue;
2243                         score = tm.(teamscores[ts_primary]);
2244                         if(autocvar__hud_configure)
2245                                 score = 123;
2246
2247                         if (score > max_fragcount)
2248                                 max_fragcount = score;
2249
2250                         if (spectatee_status == -1)
2251                         {
2252                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2253                                 if (max_fragcount == score)
2254                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2255                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2256                                 ++row;
2257                                 if(row >= rows)
2258                                 {
2259                                         row = 0;
2260                                         ++column;
2261                                 }
2262                         }
2263                         else if(tm.team == myteam) {
2264                                 if (max_fragcount == score)
2265                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2266                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2267                         } else {
2268                                 if (max_fragcount == score)
2269                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2270                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2271                                 ++rows;
2272                         }
2273                 }
2274                 draw_endBoldFont();
2275         }
2276 }
2277
2278 // Race timer (#8)
2279 //
2280 void HUD_RaceTimer (void)
2281 {
2282         if(!autocvar__hud_configure)
2283         {
2284                 if(!autocvar_hud_panel_racetimer) return;
2285                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2286                 if(spectatee_status == -1) return;
2287         }
2288
2289         HUD_Panel_UpdateCvars();
2290
2291         draw_beginBoldFont();
2292
2293         vector pos, mySize;
2294         pos = panel_pos;
2295         mySize = panel_size;
2296
2297         HUD_Panel_DrawBg(1);
2298         if(panel_bg_padding)
2299         {
2300                 pos += '1 1 0' * panel_bg_padding;
2301                 mySize -= '2 2 0' * panel_bg_padding;
2302         }
2303
2304         // always force 4:1 aspect
2305         vector newSize = '0 0 0';
2306         if(mySize_x/mySize_y > 4)
2307         {
2308                 newSize_x = 4 * mySize_y;
2309                 newSize_y = mySize_y;
2310
2311                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2312         }
2313         else
2314         {
2315                 newSize_y = 1/4 * mySize_x;
2316                 newSize_x = mySize_x;
2317
2318                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2319         }
2320         mySize = newSize;
2321
2322         float a, t;
2323         string s, forcetime;
2324
2325         if(autocvar__hud_configure)
2326         {
2327                 s = "0:13:37";
2328                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2329                 s = _("^1Intermediate 1 (+15.42)");
2330                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2331                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2332                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2333         }
2334         else if(race_checkpointtime)
2335         {
2336                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2337                 s = "";
2338                 forcetime = "";
2339                 if(a > 0) // just hit a checkpoint?
2340                 {
2341                         if(race_checkpoint != 254)
2342                         {
2343                                 if(race_time && race_previousbesttime)
2344                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2345                                 else
2346                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2347                                 if(race_time)
2348                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2349                         }
2350                 }
2351                 else
2352                 {
2353                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2354                         {
2355                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2356                                 if(a > 0) // next one?
2357                                 {
2358                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2359                                 }
2360                         }
2361                 }
2362
2363                 if(s != "" && a > 0)
2364                 {
2365                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2366                 }
2367
2368                 if(race_penaltytime)
2369                 {
2370                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2371                         if(a > 0)
2372                         {
2373                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2374                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2375                         }
2376                 }
2377
2378                 if(forcetime != "")
2379                 {
2380                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2381                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2382                 }
2383                 else
2384                         a = 1;
2385
2386                 if(race_laptime && race_checkpoint != 255)
2387                 {
2388                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2389                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2390                 }
2391         }
2392         else
2393         {
2394                 if(race_mycheckpointtime)
2395                 {
2396                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2397                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2398                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2399                 }
2400                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2401                 {
2402                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2403                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2404                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2405                 }
2406
2407                 if(race_penaltytime && !race_penaltyaccumulator)
2408                 {
2409                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2410                         a = bound(0, (1 + t - time), 1);
2411                         if(a > 0)
2412                         {
2413                                 if(time < t)
2414                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2415                                 else
2416                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2417                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2418                         }
2419                 }
2420         }
2421
2422         draw_endBoldFont();
2423 }
2424
2425 // Vote window (#9)
2426 //
2427 float vote_yescount;
2428 float vote_nocount;
2429 float vote_needed;
2430 float vote_highlighted; // currently selected vote
2431
2432 float vote_active; // is there an active vote?
2433 float vote_prev; // previous state of vote_active to check for a change
2434 float vote_alpha;
2435 float vote_change; // "time" when vote_active changed
2436
2437 void HUD_Vote(void)
2438 {
2439         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2440         {
2441                 vote_active = 1;
2442                 if (autocvar__hud_configure)
2443                 {
2444                         vote_yescount = 0;
2445                         vote_nocount = 0;
2446                         print(_("^1You must answer before entering hud configure mode\n"));
2447                         cvar_set("_hud_configure", "0");
2448                 }
2449                 if(vote_called_vote)
2450                         strunzone(vote_called_vote);
2451                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2452                 uid2name_dialog = 1;
2453         }
2454
2455         if(!autocvar__hud_configure)
2456         {
2457                 if(!autocvar_hud_panel_vote) return;
2458
2459                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2460                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2461
2462                 if(panel_bg_alpha_str == "") {
2463                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2464                 }
2465                 panel_bg_alpha = stof(panel_bg_alpha_str);
2466         }
2467         else
2468         {
2469                 vote_yescount = 3;
2470                 vote_nocount = 2;
2471                 vote_needed = 4;
2472         }
2473
2474         string s;
2475         float a;
2476         if(vote_active != vote_prev) {
2477                 vote_change = time;
2478                 vote_prev = vote_active;
2479         }
2480
2481         if(vote_active || autocvar__hud_configure)
2482                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2483         else
2484                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2485
2486         if(!vote_alpha)
2487                 return;
2488
2489         HUD_Panel_UpdateCvars();
2490
2491         if(uid2name_dialog)
2492         {
2493                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2494                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2495         }
2496
2497     // these must be below above block
2498         vector pos, mySize;
2499         pos = panel_pos;
2500         mySize = panel_size;
2501
2502         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2503         HUD_Panel_DrawBg(a);
2504         a = panel_fg_alpha * a;
2505
2506         if(panel_bg_padding)
2507         {
2508                 pos += '1 1 0' * panel_bg_padding;
2509                 mySize -= '2 2 0' * panel_bg_padding;
2510         }
2511
2512         // always force 3:1 aspect
2513         vector newSize = '0 0 0';
2514         if(mySize_x/mySize_y > 3)
2515         {
2516                 newSize_x = 3 * mySize_y;
2517                 newSize_y = mySize_y;
2518
2519                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2520         }
2521         else
2522         {
2523                 newSize_y = 1/3 * mySize_x;
2524                 newSize_x = mySize_x;
2525
2526                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2527         }
2528         mySize = newSize;
2529
2530         s = _("A vote has been called for:");
2531         if(uid2name_dialog)
2532                 s = _("Allow servers to store and display your name?");
2533         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2534         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2535         if(autocvar__hud_configure)
2536                 s = _("^1Configure the HUD");
2537         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2538
2539         // print the yes/no counts
2540     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2541         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2542     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2543         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2544
2545         // draw the progress bar backgrounds
2546         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2547
2548         // draw the highlights
2549         if(vote_highlighted == 1) {
2550                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2551                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2552         }
2553         else if(vote_highlighted == -1) {
2554                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2555                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2556         }
2557
2558         // draw the progress bars
2559         if(vote_yescount && vote_needed)
2560         {
2561                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2562                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2563         }
2564
2565         if(vote_nocount && vote_needed)
2566         {
2567                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2568                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2569         }
2570
2571         drawresetcliparea();
2572 }
2573
2574 // Mod icons panel (#10)
2575 //
2576
2577 float mod_active; // is there any active mod icon?
2578
2579 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2580 {
2581         float stat;
2582         string pic;
2583         vector color;
2584 #ifdef GMQCC
2585         stat = -1;
2586         pic = "";
2587         color = '0 0 0';
2588 #endif
2589         switch(i)
2590         {
2591                 case 0:
2592                         stat = getstati(STAT_REDALIVE);
2593                         pic = "player_red.tga";
2594                         color = '1 0 0';
2595                         break;
2596                 case 1:
2597                         stat = getstati(STAT_BLUEALIVE);
2598                         pic = "player_blue.tga";
2599                         color = '0 0 1';
2600                         break;
2601                 case 2:
2602                         stat = getstati(STAT_YELLOWALIVE);
2603                         pic = "player_yellow.tga";
2604                         color = '1 1 0';
2605                         break;
2606                 default:
2607                 case 3:
2608                         stat = getstati(STAT_PINKALIVE);
2609                         pic = "player_pink.tga";
2610                         color = '1 0 1';
2611                         break;
2612         }
2613
2614         if(mySize_x/mySize_y > aspect_ratio)
2615         {
2616                 i = aspect_ratio * mySize_y;
2617                 myPos_x = myPos_x + (mySize_x - i) / 2;
2618                 mySize_x = i;
2619         }
2620         else
2621         {
2622                 i = 1/aspect_ratio * mySize_x;
2623                 myPos_y = myPos_y + (mySize_y - i) / 2;
2624                 mySize_y = i;
2625         }
2626
2627         if(layout)
2628         {
2629                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2630                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2631         }
2632         else
2633                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2634 }
2635
2636 // Clan Arena and Freeze Tag HUD modicons
2637 void HUD_Mod_CA(vector myPos, vector mySize)
2638 {
2639         mod_active = 1; // required in each mod function that always shows something
2640
2641         float layout;
2642         if(gametype == MAPINFO_TYPE_CA)
2643                 layout = autocvar_hud_panel_modicons_ca_layout;
2644         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2645                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2646         float rows, columns, aspect_ratio;
2647         rows = mySize_y/mySize_x;
2648         aspect_ratio = (layout) ? 2 : 1;
2649         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
2650         columns = ceil(team_count/rows);
2651
2652         int i;
2653         float row = 0, column = 0;
2654         vector pos, itemSize;
2655         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2656         for(i=0; i<team_count; ++i)
2657         {
2658                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2659
2660                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2661
2662                 ++row;
2663                 if(row >= rows)
2664                 {
2665                         row = 0;
2666                         ++column;
2667                 }
2668         }
2669 }
2670
2671 // CTF HUD modicon section
2672 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2673 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2674 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2675
2676 void HUD_Mod_CTF_Reset(void)
2677 {
2678         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2679 }
2680
2681 void HUD_Mod_CTF(vector pos, vector mySize)
2682 {
2683         vector redflag_pos, blueflag_pos;
2684         vector flag_size;
2685         float f; // every function should have that
2686
2687         float redflag, blueflag; // current status
2688         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2689         float stat_items;
2690
2691         stat_items = getstati(STAT_ITEMS, 0, 24);
2692         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2693         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2694
2695         if(redflag || blueflag)
2696                 mod_active = 1;
2697         else
2698                 mod_active = 0;
2699
2700         if(autocvar__hud_configure)
2701         {
2702                 redflag = 1;
2703                 blueflag = 2;
2704         }
2705
2706         // when status CHANGES, set old status into prevstatus and current status into status
2707         if (redflag != redflag_prevframe)
2708         {
2709                 redflag_statuschange_time = time;
2710                 redflag_prevstatus = redflag_prevframe;
2711                 redflag_prevframe = redflag;
2712         }
2713
2714         if (blueflag != blueflag_prevframe)
2715         {
2716                 blueflag_statuschange_time = time;
2717                 blueflag_prevstatus = blueflag_prevframe;
2718                 blueflag_prevframe = blueflag;
2719         }
2720
2721         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2722         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2723
2724         float BLINK_FACTOR = 0.15;
2725         float BLINK_BASE = 0.85;
2726         // note:
2727         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2728         // thus
2729         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2730         // ensure RMS == 1
2731         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2732
2733         string red_icon, red_icon_prevstatus;
2734         float red_alpha, red_alpha_prevstatus;
2735         red_alpha = red_alpha_prevstatus = 1;
2736         switch(redflag) {
2737                 case 1: red_icon = "flag_red_taken"; break;
2738                 case 2: red_icon = "flag_red_lost"; break;
2739                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2740                 default:
2741                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2742                                 red_icon = "flag_red_shielded";
2743                         else
2744                                 red_icon = string_null;
2745                         break;
2746         }
2747         switch(redflag_prevstatus) {
2748                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2749                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2750                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2751                 default:
2752                         if(redflag == 3)
2753                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2754                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2755                                 red_icon_prevstatus = "flag_red_shielded";
2756                         else
2757                                 red_icon_prevstatus = string_null;
2758                         break;
2759         }
2760
2761         string blue_icon, blue_icon_prevstatus;
2762         float blue_alpha, blue_alpha_prevstatus;
2763         blue_alpha = blue_alpha_prevstatus = 1;
2764         switch(blueflag) {
2765                 case 1: blue_icon = "flag_blue_taken"; break;
2766                 case 2: blue_icon = "flag_blue_lost"; break;
2767                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2768                 default:
2769                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2770                                 blue_icon = "flag_blue_shielded";
2771                         else
2772                                 blue_icon = string_null;
2773                         break;
2774         }
2775         switch(blueflag_prevstatus) {
2776                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2777                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2778                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2779                 default:
2780                         if(blueflag == 3)
2781                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2782                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2783                                 blue_icon_prevstatus = "flag_blue_shielded";
2784                         else
2785                                 blue_icon_prevstatus = string_null;
2786                         break;
2787         }
2788
2789         if(mySize_x > mySize_y) {
2790                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2791                         redflag_pos = pos;
2792                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2793                 } else {
2794                         blueflag_pos = pos;
2795                         redflag_pos = pos + eX * 0.5 * mySize_x;
2796                 }
2797                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2798         } else {
2799                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2800                         redflag_pos = pos;
2801                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2802                 } else {
2803                         blueflag_pos = pos;
2804                         redflag_pos = pos + eY * 0.5 * mySize_y;
2805                 }
2806                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2807         }
2808
2809         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2810         if(red_icon_prevstatus && f < 1)
2811                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2812         if(red_icon)
2813                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2814
2815         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2816         if(blue_icon_prevstatus && f < 1)
2817                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2818         if(blue_icon)
2819                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2820 }
2821
2822 // Keyhunt HUD modicon section
2823 float kh_runheretime;
2824
2825 void HUD_Mod_KH_Reset(void)
2826 {
2827         kh_runheretime = 0;
2828 }
2829
2830 void HUD_Mod_KH(vector pos, vector mySize)
2831 {
2832         mod_active = 1; // keyhunt should never hide the mod icons panel
2833         float kh_keys;
2834         float keyteam;
2835         float a, aa;
2836         vector p = '0 0 0', pa, kh_size = '0 0 0', kh_asize = '0 0 0';
2837
2838         kh_keys = getstati(STAT_KH_KEYS);
2839
2840         p_x = pos_x;
2841         if(mySize_x > mySize_y)
2842         {
2843                 p_y = pos_y + 0.25 * mySize_y;
2844                 pa = p - eY * 0.25 * mySize_y;
2845
2846                 kh_size_x = mySize_x * 0.25;
2847                 kh_size_y = 0.75 * mySize_y;
2848                 kh_asize_x = mySize_x * 0.25;
2849                 kh_asize_y = mySize_y * 0.25;
2850         }
2851         else
2852         {
2853                 p_y = pos_y + 0.125 * mySize_y;
2854                 pa = p - eY * 0.125 * mySize_y;
2855
2856                 kh_size_x = mySize_x * 0.5;
2857                 kh_size_y = 0.375 * mySize_y;
2858                 kh_asize_x = mySize_x * 0.5;
2859                 kh_asize_y = mySize_y * 0.125;
2860         }
2861
2862         float i, key;
2863
2864         float keycount;
2865         keycount = 0;
2866         for(i = 0; i < 4; ++i)
2867         {
2868                 key = floor(kh_keys / pow(32, i)) & 31;
2869                 keyteam = key - 1;
2870                 if(keyteam == 30 && keycount <= 4)
2871                         keycount += 4;
2872                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
2873                         keycount += 1;
2874         }
2875
2876         // this yields 8 exactly if "RUN HERE" shows
2877
2878         if(keycount == 8)
2879         {
2880                 if(!kh_runheretime)
2881                         kh_runheretime = time;
2882                 pa_y -= fabs(sin((time - kh_runheretime) * 3.5)) * 6; // make the arrows jump in case of RUN HERE
2883         }
2884         else
2885                 kh_runheretime = 0;
2886
2887         for(i = 0; i < 4; ++i)
2888         {
2889                 key = floor(kh_keys / pow(32, i)) & 31;
2890                 keyteam = key - 1;
2891                 switch(keyteam)
2892                 {
2893                         case 30: // my key
2894                                 keyteam = myteam;
2895                                 a = 1;
2896                                 aa = 1;
2897                                 break;
2898                         case -1: // no key
2899                                 a = 0;
2900                                 aa = 0;
2901                                 break;
2902                         default: // owned or dropped
2903                                 a = 0.2;
2904                                 aa = 0.5;
2905                                 break;
2906                 }
2907                 a = a * panel_fg_alpha;
2908                 aa = aa * panel_fg_alpha;
2909                 if(a > 0)
2910                 {
2911                         switch(keyteam)
2912                         {
2913                                 case NUM_TEAM_1:
2914                                         drawpic_aspect_skin(pa, "kh_redarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2915                                         break;
2916                                 case NUM_TEAM_2:
2917                                         drawpic_aspect_skin(pa, "kh_bluearrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2918                                         break;
2919                                 case NUM_TEAM_3:
2920                                         drawpic_aspect_skin(pa, "kh_yellowarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2921                                         break;
2922                                 case NUM_TEAM_4:
2923                                         drawpic_aspect_skin(pa, "kh_pinkarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2924                                         break;
2925                                 default:
2926                                         break;
2927                         }
2928                         switch(i) // YAY! switch(i) inside a for loop for i. DailyWTF, here we come!
2929                         {
2930                                 case 0:
2931                                         drawpic_aspect_skin(p, "kh_red", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2932                                         break;
2933                                 case 1:
2934                                         drawpic_aspect_skin(p, "kh_blue", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2935                                         break;
2936                                 case 2:
2937                                         drawpic_aspect_skin(p, "kh_yellow", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2938                                         break;
2939                                 case 3:
2940                                         drawpic_aspect_skin(p, "kh_pink", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2941                                         break;
2942                         }
2943                 }
2944                 if(mySize_x > mySize_y)
2945                 {
2946                         p_x += 0.25 * mySize_x;
2947                         pa_x += 0.25 * mySize_x;
2948                 }
2949                 else
2950                 {
2951                         if(i == 1)
2952                         {
2953                                 p_y = pos_y + 0.625 * mySize_y;
2954                                 pa_y = pos_y + 0.5 * mySize_y;
2955                                 p_x = pos_x;
2956                                 pa_x = pos_x;
2957                         }
2958                         else
2959                         {
2960                                 p_x += 0.5 * mySize_x;
2961                                 pa_x += 0.5 * mySize_x;
2962                         }
2963                 }
2964         }
2965 }
2966
2967 // Keepaway HUD mod icon
2968 float kaball_prevstatus; // last remembered status
2969 float kaball_statuschange_time; // time when the status changed
2970
2971 // we don't need to reset for keepaway since it immediately
2972 // autocorrects prevstatus as to if the player has the ball or not
2973
2974 void HUD_Mod_Keepaway(vector pos, vector mySize)
2975 {
2976         mod_active = 1; // keepaway should always show the mod HUD
2977
2978         float BLINK_FACTOR = 0.15;
2979         float BLINK_BASE = 0.85;
2980         float BLINK_FREQ = 5;
2981         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
2982
2983         float stat_items = getstati(STAT_ITEMS, 0, 24);
2984         float kaball = (stat_items/IT_KEY1) & 1;
2985
2986         if(kaball != kaball_prevstatus)
2987         {
2988                 kaball_statuschange_time = time;
2989                 kaball_prevstatus = kaball;
2990         }
2991
2992         vector kaball_pos, kaball_size;
2993
2994         if(mySize_x > mySize_y) {
2995                 kaball_pos = pos + eX * 0.25 * mySize_x;
2996                 kaball_size = eX * 0.5 * mySize_x + eY * mySize_y;
2997         } else {
2998                 kaball_pos = pos + eY * 0.25 * mySize_y;
2999                 kaball_size = eY * 0.5 * mySize_y + eX * mySize_x;
3000         }
3001
3002         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3003         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3004
3005         if(kaball_prevstatus && f < 1)
3006                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3007
3008         if(kaball)
3009                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3010 }
3011
3012
3013 // Nexball HUD mod icon
3014 void HUD_Mod_NexBall(vector pos, vector mySize)
3015 {
3016         float stat_items, nb_pb_starttime, dt, p;
3017
3018         stat_items = getstati(STAT_ITEMS, 0, 24);
3019         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3020
3021         if (stat_items & IT_KEY1)
3022                 mod_active = 1;
3023         else
3024                 mod_active = 0;
3025
3026         //Manage the progress bar if any
3027         if (nb_pb_starttime > 0)
3028         {
3029                 dt = mod(time - nb_pb_starttime, nb_pb_period);
3030                 // one period of positive triangle
3031                 p = 2 * dt / nb_pb_period;
3032                 if (p > 1)
3033                         p = 2 - p;
3034
3035                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize_x <= mySize_y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3036         }
3037
3038         if (stat_items & IT_KEY1)
3039                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3040 }
3041
3042 // Race/CTS HUD mod icons
3043 float crecordtime_prev; // last remembered crecordtime
3044 float crecordtime_change_time; // time when crecordtime last changed
3045 float srecordtime_prev; // last remembered srecordtime
3046 float srecordtime_change_time; // time when srecordtime last changed
3047
3048 float race_status_time;
3049 float race_status_prev;
3050 string race_status_name_prev;
3051 void HUD_Mod_Race(vector pos, vector mySize)
3052 {
3053         mod_active = 1; // race should never hide the mod icons panel
3054         entity me;
3055         me = playerslots[player_localnum];
3056         float t, score;
3057         float f; // yet another function has this
3058         score = me.(scores[ps_primary]);
3059
3060         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3061                 return; // no records in the actual race
3062
3063         // clientside personal record
3064         string rr;
3065         if(gametype == MAPINFO_TYPE_CTS)
3066                 rr = CTS_RECORD;
3067         else
3068                 rr = RACE_RECORD;
3069         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3070
3071         if(score && (score < t || !t)) {
3072                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3073                 if(autocvar_cl_autodemo_delete_keeprecords)
3074                 {
3075                         f = autocvar_cl_autodemo_delete;
3076                         f &= ~1;
3077                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3078                 }
3079         }
3080
3081         if(t != crecordtime_prev) {
3082                 crecordtime_prev = t;
3083                 crecordtime_change_time = time;
3084         }
3085
3086         vector textPos, medalPos;
3087         float squareSize;
3088         if(mySize_x > mySize_y) {
3089                 // text on left side
3090                 squareSize = min(mySize_y, mySize_x/2);
3091                 textPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eY * 0.5 * (mySize_y - squareSize);
3092                 medalPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eX * 0.5 * mySize_x + eY * 0.5 * (mySize_y - squareSize);
3093         } else {
3094                 // text on top
3095                 squareSize = min(mySize_x, mySize_y/2);
3096                 textPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eX * 0.5 * (mySize_x - squareSize);
3097                 medalPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eY * 0.5 * mySize_y + eX * 0.5 * (mySize_x - squareSize);
3098         }
3099
3100         f = time - crecordtime_change_time;
3101
3102         if (f > 1) {
3103                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3104                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3105         } else {
3106                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3107                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3108                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3109                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3110         }
3111
3112         // server record
3113         t = race_server_record;
3114         if(t != srecordtime_prev) {
3115                 srecordtime_prev = t;
3116                 srecordtime_change_time = time;
3117         }
3118         f = time - srecordtime_change_time;
3119
3120         if (f > 1) {
3121                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3122                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3123         } else {
3124                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3125                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3126                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3127                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3128         }
3129
3130         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3131                 race_status_time = time + 5;
3132                 race_status_prev = race_status;
3133                 if (race_status_name_prev)
3134                         strunzone(race_status_name_prev);
3135                 race_status_name_prev = strzone(race_status_name);
3136         }
3137
3138         // race "awards"
3139         float a;
3140         a = bound(0, race_status_time - time, 1);
3141
3142         string s;
3143         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3144
3145         float rank;
3146         if(race_status > 0)
3147                 rank = race_CheckName(race_status_name);
3148         else
3149                 rank = 0;
3150         string rankname;
3151         rankname = count_ordinal(rank);
3152
3153         vector namepos;
3154         namepos = medalPos + '0 0.8 0' * squareSize;
3155         vector rankpos;
3156         rankpos = medalPos + '0 0.15 0' * squareSize;
3157
3158         if(race_status == 0)
3159                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3160         else if(race_status == 1) {
3161                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3162                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3163                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3164         } else if(race_status == 2) {
3165                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3166                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3167                 else
3168                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3169                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3170                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3171         } else if(race_status == 3) {
3172                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3173                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3174                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3175         }
3176
3177         if (race_status_time - time <= 0) {
3178                 race_status_prev = -1;
3179                 race_status = -1;
3180                 if(race_status_name)
3181                         strunzone(race_status_name);
3182                 race_status_name = string_null;
3183                 if(race_status_name_prev)
3184                         strunzone(race_status_name_prev);
3185                 race_status_name_prev = string_null;
3186         }
3187 }
3188
3189 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
3190 {
3191         float stat, pps_ratio;
3192         string pic;
3193         vector color;
3194 #ifdef GMQCC
3195         stat = -1;
3196         pic = "";
3197         color = '0 0 0';
3198 #endif
3199         switch(i)
3200         {
3201                 case 0:
3202                         stat = getstatf(STAT_DOM_PPS_RED);
3203                         pic = "dom_icon_red";
3204                         color = '1 0 0';
3205                         break;
3206                 case 1:
3207                         stat = getstatf(STAT_DOM_PPS_BLUE);
3208                         pic = "dom_icon_blue";
3209                         color = '0 0 1';
3210                         break;
3211                 case 2:
3212                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3213                         pic = "dom_icon_yellow";
3214                         color = '1 1 0';
3215                         break;
3216                 default:
3217                 case 3:
3218                         stat = getstatf(STAT_DOM_PPS_PINK);
3219                         pic = "dom_icon_pink";
3220                         color = '1 0 1';
3221                         break;
3222         }
3223         pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3224
3225         if(mySize_x/mySize_y > aspect_ratio)
3226         {
3227                 i = aspect_ratio * mySize_y;
3228                 myPos_x = myPos_x + (mySize_x - i) / 2;
3229                 mySize_x = i;
3230         }
3231         else
3232         {
3233                 i = 1/aspect_ratio * mySize_x;
3234                 myPos_y = myPos_y + (mySize_y - i) / 2;
3235                 mySize_y = i;
3236         }
3237
3238         if (layout) // show text too
3239         {
3240                 //draw the text
3241                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3242                 if (layout == 2) // average pps
3243                         drawstring_aspect(myPos + eX * mySize_y, ftos_decimals(stat, 2), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3244                 else // percentage of average pps
3245                         drawstring_aspect(myPos + eX * mySize_y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3246         }
3247
3248         //draw the icon
3249         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3250         if (stat > 0)
3251         {
3252                 drawsetcliparea(myPos_x, myPos_y + mySize_y * (1 - pps_ratio), mySize_y, mySize_y * pps_ratio);
3253                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3254                 drawresetcliparea();
3255         }
3256 }
3257
3258 void HUD_Mod_Dom(vector myPos, vector mySize)
3259 {
3260         mod_active = 1; // required in each mod function that always shows something
3261
3262         float layout = autocvar_hud_panel_modicons_dom_layout;
3263         float rows, columns, aspect_ratio;
3264         rows = mySize_y/mySize_x;
3265         aspect_ratio = (layout) ? 3 : 1;
3266         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
3267         columns = ceil(team_count/rows);
3268
3269         int i;
3270         float row = 0, column = 0;
3271         vector pos, itemSize;
3272         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
3273         for(i=0; i<team_count; ++i)
3274         {
3275                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
3276
3277                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3278
3279                 ++row;
3280                 if(row >= rows)
3281                 {
3282                         row = 0;
3283                         ++column;
3284                 }
3285         }
3286 }
3287
3288 void HUD_ModIcons_SetFunc()
3289 {
3290         switch(gametype)
3291         {
3292                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3293                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3294                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3295                 case MAPINFO_TYPE_CTS:
3296                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3297                 case MAPINFO_TYPE_CA:
3298                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3299                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3300                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3301         }
3302 }
3303
3304 float mod_prev; // previous state of mod_active to check for a change
3305 float mod_alpha;
3306 float mod_change; // "time" when mod_active changed
3307
3308 void HUD_ModIcons(void)
3309 {
3310         if(!autocvar__hud_configure)
3311         {
3312                 if(!autocvar_hud_panel_modicons) return;
3313                 if(!HUD_ModIcons_GameType) return;
3314         }
3315
3316         HUD_Panel_UpdateCvars();
3317
3318         draw_beginBoldFont();
3319
3320         if(mod_active != mod_prev) {
3321                 mod_change = time;
3322                 mod_prev = mod_active;
3323         }
3324
3325         if(mod_active || autocvar__hud_configure)
3326                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3327         else
3328                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3329
3330         if(mod_alpha)
3331                 HUD_Panel_DrawBg(mod_alpha);
3332
3333         if(panel_bg_padding)
3334         {
3335                 panel_pos += '1 1 0' * panel_bg_padding;
3336                 panel_size -= '2 2 0' * panel_bg_padding;
3337         }
3338
3339         if(autocvar__hud_configure)
3340                 HUD_Mod_CTF(panel_pos, panel_size);
3341         else
3342                 HUD_ModIcons_GameType(panel_pos, panel_size);
3343
3344         draw_endBoldFont();
3345 }
3346
3347 // Draw pressed keys (#11)
3348 //
3349 void HUD_PressedKeys(void)
3350 {
3351         if(!autocvar__hud_configure)
3352         {
3353                 if(!autocvar_hud_panel_pressedkeys) return;
3354                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3355         }
3356
3357         HUD_Panel_UpdateCvars();
3358         vector pos, mySize;
3359         pos = panel_pos;
3360         mySize = panel_size;
3361
3362         HUD_Panel_DrawBg(1);
3363         if(panel_bg_padding)
3364         {
3365                 pos += '1 1 0' * panel_bg_padding;
3366                 mySize -= '2 2 0' * panel_bg_padding;
3367         }
3368
3369         // force custom aspect
3370         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3371         if(aspect)
3372         {
3373                 vector newSize = '0 0 0';
3374                 if(mySize_x/mySize_y > aspect)
3375                 {
3376                         newSize_x = aspect * mySize_y;
3377                         newSize_y = mySize_y;
3378
3379                         pos_x = pos_x + (mySize_x - newSize_x) / 2;
3380                 }
3381                 else
3382                 {
3383                         newSize_y = 1/aspect * mySize_x;
3384                         newSize_x = mySize_x;
3385
3386                         pos_y = pos_y + (mySize_y - newSize_y) / 2;
3387                 }
3388                 mySize = newSize;
3389         }
3390
3391         vector keysize;
3392         keysize = eX * mySize_x * (1/3.0) + eY * mySize_y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3393         float pressedkeys;
3394         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3395
3396         if(autocvar_hud_panel_pressedkeys_attack)
3397         {
3398                 drawpic_aspect_skin(pos + eX * keysize_x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3399                 drawpic_aspect_skin(pos + eX * keysize_x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3400                 pos_y += keysize_y;
3401         }
3402
3403         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3404         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3405         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3406         pos_y += keysize_y;
3407         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3408         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3409         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3410 }
3411
3412 // Handle chat as a panel (#12)
3413 //
3414 void HUD_Chat(void)
3415 {
3416         if(!autocvar__hud_configure)
3417         {
3418                 if (!autocvar_hud_panel_chat)
3419                 {
3420                         if (!autocvar_con_chatrect)
3421                                 cvar_set("con_chatrect", "0");
3422                         return;
3423                 }
3424                 if(autocvar__con_chat_maximized)
3425                 {
3426                         if(!hud_draw_maximized) return;
3427                 }
3428                 else if(chat_panel_modified)
3429                 {
3430                         panel.update_time = time; // forces reload of panel attributes
3431                         chat_panel_modified = false;
3432                 }
3433         }
3434
3435         HUD_Panel_UpdateCvars();
3436
3437         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3438         {
3439                 panel_pos_y = panel_bg_border;
3440                 panel_size_y = vid_conheight - panel_bg_border * 2;
3441                 if(panel.current_panel_bg == "0") // force a border when maximized
3442                 {
3443                         string panel_bg;
3444                         panel_bg = strcat(hud_skin_path, "/border_default");
3445                         if(precache_pic(panel_bg) == "")
3446                                 panel_bg = "gfx/hud/default/border_default";
3447                         if(panel.current_panel_bg)
3448                                 strunzone(panel.current_panel_bg);
3449                         panel.current_panel_bg = strzone(panel_bg);
3450                         chat_panel_modified = true;
3451                 }
3452                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3453         }
3454
3455         vector pos, mySize;
3456         pos = panel_pos;
3457         mySize = panel_size;
3458
3459         HUD_Panel_DrawBg(1);
3460
3461         if(panel_bg_padding)
3462         {
3463                 pos += '1 1 0' * panel_bg_padding;
3464                 mySize -= '2 2 0' * panel_bg_padding;
3465         }
3466
3467         if (!autocvar_con_chatrect)
3468                 cvar_set("con_chatrect", "1");
3469
3470         cvar_set("con_chatrect_x", ftos(pos_x/vid_conwidth));
3471         cvar_set("con_chatrect_y", ftos(pos_y/vid_conheight));
3472
3473         cvar_set("con_chatwidth", ftos(mySize_x/vid_conwidth));
3474         cvar_set("con_chat", ftos(floor(mySize_y/autocvar_con_chatsize - 0.5)));
3475
3476         if(autocvar__hud_configure)
3477         {
3478                 vector chatsize;
3479                 chatsize = '1 1 0' * autocvar_con_chatsize;
3480                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3481                 float i, a;
3482                 for(i = 0; i < autocvar_con_chat; ++i)
3483                 {
3484                         if(i == autocvar_con_chat - 1)
3485                                 a = panel_fg_alpha;
3486                         else
3487                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3488                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize_x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3489                         pos_y += chatsize_y;
3490                 }
3491         }
3492 }
3493
3494 // Engine info panel (#13)
3495 //
3496 float prevfps;
3497 float prevfps_time;
3498 float framecounter;
3499
3500 float frametimeavg;
3501 float frametimeavg1; // 1 frame ago
3502 float frametimeavg2; // 2 frames ago
3503 void HUD_EngineInfo(void)
3504 {
3505         if(!autocvar__hud_configure)
3506         {
3507                 if(!autocvar_hud_panel_engineinfo) return;
3508         }
3509
3510         HUD_Panel_UpdateCvars();
3511         vector pos, mySize;
3512         pos = panel_pos;
3513         mySize = panel_size;
3514
3515         HUD_Panel_DrawBg(1);
3516         if(panel_bg_padding)
3517         {
3518                 pos += '1 1 0' * panel_bg_padding;
3519                 mySize -= '2 2 0' * panel_bg_padding;
3520         }
3521
3522         float currentTime = gettime(GETTIME_REALTIME);
3523         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3524         {
3525                 float currentframetime = currentTime - prevfps_time;
3526                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3527                 frametimeavg2 = frametimeavg1;
3528                 frametimeavg1 = frametimeavg;
3529
3530                 float weight;
3531                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3532                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3533                 {
3534                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3535                                 prevfps = (1/currentframetime);
3536                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3537                 }
3538                 prevfps_time = currentTime;
3539         }
3540         else
3541         {
3542                 framecounter += 1;
3543                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3544                 {
3545                         prevfps = framecounter/(currentTime - prevfps_time);
3546                         framecounter = 0;
3547                         prevfps_time = currentTime;
3548                 }
3549         }
3550
3551         vector color;
3552         color = HUD_Get_Num_Color (prevfps, 100);
3553         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3554 }
3555
3556 // Info messages panel (#14)
3557 //
3558 #define drawInfoMessage(s)\
3559         if(autocvar_hud_panel_infomessages_flip)\
3560                 o_x = pos_x + mySize_x - stringwidth(s, TRUE, fontsize);\
3561         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);\
3562         o_y += fontsize_y;
3563 void HUD_InfoMessages(void)
3564 {
3565         if(!autocvar__hud_configure)
3566         {
3567                 if(!autocvar_hud_panel_infomessages) return;
3568         }
3569
3570         HUD_Panel_UpdateCvars();
3571         vector pos, mySize;
3572         pos = panel_pos;
3573         mySize = panel_size;
3574
3575         HUD_Panel_DrawBg(1);
3576         if(panel_bg_padding)
3577         {
3578                 pos += '1 1 0' * panel_bg_padding;
3579                 mySize -= '2 2 0' * panel_bg_padding;
3580         }
3581
3582         // always force 5:1 aspect
3583         vector newSize = '0 0 0';
3584         if(mySize_x/mySize_y > 5)
3585         {
3586                 newSize_x = 5 * mySize_y;
3587                 newSize_y = mySize_y;
3588
3589                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
3590         }
3591         else
3592         {
3593                 newSize_y = 1/5 * mySize_x;
3594                 newSize_x = mySize_x;
3595
3596                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
3597         }
3598
3599         mySize = newSize;
3600         entity tm;
3601         vector o;
3602         o = pos;
3603
3604         vector fontsize;
3605         fontsize = '0.20 0.20 0' * mySize_y;
3606
3607         float a;
3608         a = panel_fg_alpha;
3609
3610         string s;
3611         if(!autocvar__hud_configure)
3612         {
3613                 if(spectatee_status && !intermission)
3614                 {
3615                         a = 1;
3616                         if(spectatee_status == -1)
3617                                 s = _("^1Observing");
3618                         else
3619 #ifdef COMPAT_XON050_ENGINE
3620                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(spectatee_status - 1));
3621 #else
3622                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3623 #endif
3624                         drawInfoMessage(s)
3625
3626                         if(spectatee_status == -1)
3627                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3628                         else
3629                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3630                         drawInfoMessage(s)
3631
3632                         if(spectatee_status == -1)
3633                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3634                         else
3635                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3636                         drawInfoMessage(s)
3637
3638                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3639                         drawInfoMessage(s)
3640
3641                         if(gametype == MAPINFO_TYPE_LMS)
3642                         {
3643                                 entity sk;
3644                                 sk = playerslots[player_localnum];
3645                                 if(sk.(scores[ps_primary]) >= 666)
3646                                         s = _("^1Match has already begun");
3647                                 else if(sk.(scores[ps_primary]) > 0)
3648                                         s = _("^1You have no more lives left");
3649                                 else
3650                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3651                         }
3652                         else
3653                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3654                         drawInfoMessage(s)
3655
3656                         //show restart countdown:
3657                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3658                                 float countdown;
3659                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3660                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3661                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3662                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3663                                 o_y += fontsize_y;
3664                         }
3665                 }
3666                 if(warmup_stage && !intermission)
3667                 {
3668                         s = _("^2Currently in ^1warmup^2 stage!");
3669                         drawInfoMessage(s)
3670                 }
3671
3672                 string blinkcolor;
3673                 if(mod(time, 1) >= 0.5)
3674                         blinkcolor = "^1";
3675                 else
3676                         blinkcolor = "^3";
3677
3678                 if(ready_waiting && !intermission && !spectatee_status)
3679                 {
3680                         if(ready_waiting_for_me)
3681                         {
3682                                 if(warmup_stage)
3683                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3684                                 else
3685                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3686                         }
3687                         else
3688                         {
3689                                 if(warmup_stage)
3690                                         s = _("^2Waiting for others to ready up to end warmup...");
3691                                 else
3692                                         s = _("^2Waiting for others to ready up...");
3693                         }
3694                         drawInfoMessage(s)
3695                 }
3696                 else if(warmup_stage && !intermission && !spectatee_status)
3697                 {
3698                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3699                         drawInfoMessage(s)
3700                 }
3701
3702                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3703                 {
3704                         float ts_min = 0, ts_max = 0;
3705                         tm = teams.sort_next;
3706                         if (tm)
3707                         {
3708                                 for(; tm.sort_next; tm = tm.sort_next)
3709                                 {
3710                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3711                                                 continue;
3712                                         if(!ts_min) ts_min = tm.team_size;
3713                                         else ts_min = min(ts_min, tm.team_size);
3714                                         if(!ts_max) ts_max = tm.team_size;
3715                                         else ts_max = max(ts_max, tm.team_size);
3716                                 }
3717                                 if ((ts_max - ts_min) > 1)
3718                                 {
3719                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3720                                         tm = GetTeam(myteam, false);
3721                                         if (tm)
3722                                         if (tm.team != NUM_SPECTATOR)
3723                                         if (tm.team_size == ts_max)
3724                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3725                                         drawInfoMessage(s)
3726                                 }
3727                         }
3728                 }
3729         }
3730         else
3731         {
3732                 s = _("^7Press ^3ESC ^7to show HUD options.");
3733                 drawInfoMessage(s)
3734                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3735                 drawInfoMessage(s)
3736                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3737                 drawInfoMessage(s)
3738                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3739                 drawInfoMessage(s)
3740         }
3741 }
3742
3743 // Physics panel (#15)
3744 //
3745 vector acc_prevspeed;
3746 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3747 void HUD_Physics(void)
3748 {
3749         if(!autocvar__hud_configure)
3750         {
3751                 if(!autocvar_hud_panel_physics) return;
3752                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3753                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3754         }
3755
3756         HUD_Panel_UpdateCvars();
3757
3758         draw_beginBoldFont();
3759
3760         HUD_Panel_DrawBg(1);
3761         if(panel_bg_padding)
3762         {
3763                 panel_pos += '1 1 0' * panel_bg_padding;
3764                 panel_size -= '2 2 0' * panel_bg_padding;
3765         }
3766
3767         float acceleration_progressbar_scale = 0;
3768         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3769                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3770
3771         float text_scale;
3772         if (autocvar_hud_panel_physics_text_scale <= 0)
3773                 text_scale = 1;
3774         else
3775                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3776
3777         //compute speed
3778         float speed, conversion_factor;
3779         string unit;
3780
3781         switch(autocvar_hud_panel_physics_speed_unit)
3782         {
3783                 default:
3784                 case 1:
3785                         unit = _(" qu/s");
3786                         conversion_factor = 1.0;
3787                         break;
3788                 case 2:
3789                         unit = _(" m/s");
3790                         conversion_factor = 0.0254;
3791                         break;
3792                 case 3:
3793                         unit = _(" km/h");
3794                         conversion_factor = 0.0254 * 3.6;
3795                         break;
3796                 case 4:
3797                         unit = _(" mph");
3798                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3799                         break;
3800                 case 5:
3801                         unit = _(" knots");
3802                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3803                         break;
3804         }
3805
3806         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3807
3808         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3809         if (autocvar__hud_configure)
3810                 speed = floor( max_speed * 0.65 + 0.5 );
3811         else if(autocvar_hud_panel_physics_speed_vertical)
3812                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3813         else
3814                 speed = floor( vlen(vel - vel_z * '0 0 1') * conversion_factor + 0.5 );
3815
3816         //compute acceleration
3817         float acceleration, f;
3818         if (autocvar__hud_configure)
3819                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3820         else
3821         {
3822                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3823                 f = time - acc_prevtime;
3824                 if(autocvar_hud_panel_physics_acceleration_vertical)
3825                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3826                 else
3827                         acceleration = (vlen(vel - '0 0 1' * vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z));
3828
3829                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3830
3831                 acc_prevspeed = vel;
3832                 acc_prevtime = time;
3833
3834                 f = bound(0, f * 10, 1);
3835                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3836         }
3837
3838         //compute layout
3839         float panel_ar = panel_size_x/panel_size_y;
3840         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3841         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3842         {
3843                 panel_size_x *= 0.5;
3844                 if (autocvar_hud_panel_physics_flip)
3845                         speed_offset_x = panel_size_x;
3846                 else
3847                         acceleration_offset_x = panel_size_x;
3848         }
3849         else
3850         {
3851                 panel_size_y *= 0.5;
3852                 if (autocvar_hud_panel_physics_flip)
3853                         speed_offset_y = panel_size_y;
3854                 else
3855                         acceleration_offset_y = panel_size_y;
3856         }
3857         float speed_baralign, acceleration_baralign;
3858         if (autocvar_hud_panel_physics_baralign == 1)
3859                 acceleration_baralign = speed_baralign = 1;
3860     else if(autocvar_hud_panel_physics_baralign == 4)
3861                 acceleration_baralign = speed_baralign = 2;
3862         else if (autocvar_hud_panel_physics_flip)
3863         {
3864                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3865                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3866         }
3867         else
3868         {
3869                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3870                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3871         }
3872         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3873                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3874
3875         //draw speed
3876         if(speed)
3877         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3878                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3879         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3880         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3881         {
3882                 tmp_size_x = panel_size_x * 0.75;
3883                 tmp_size_y = panel_size_y * text_scale;
3884                 if (speed_baralign)
3885                         tmp_offset_x = panel_size_x - tmp_size_x;
3886                 //else
3887                         //tmp_offset_x = 0;
3888                 tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
3889                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3890
3891                 //draw speed unit
3892                 if (speed_baralign)
3893                         tmp_offset_x = 0;
3894                 else
3895                         tmp_offset_x = tmp_size_x;
3896                 if (autocvar_hud_panel_physics_speed_unit_show)
3897                 {
3898                         //tmp_offset_y = 0;
3899                         tmp_size_x = panel_size_x * (1 - 0.75);
3900                         tmp_size_y = panel_size_y * 0.4 * text_scale;
3901                         tmp_offset_y = (panel_size_y * 0.4 - tmp_size_y) / 2;
3902                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3903                 }
3904         }
3905
3906         //compute and draw top speed
3907         if (autocvar_hud_panel_physics_topspeed)
3908         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3909         {
3910                 if (autocvar__hud_configure)
3911                 {
3912                         top_speed = floor( max_speed * 0.75 + 0.5 );
3913                         f = 1;
3914                 }
3915                 else
3916                 {
3917                         if (speed >= top_speed)
3918                         {
3919                                 top_speed = speed;
3920                                 top_speed_time = time;
3921                         }
3922                         if (top_speed != 0)
3923                         {
3924                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3925                                 // divide by f to make it start from 1
3926                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3927                         }
3928             else //hide top speed 0, it would be stupid
3929                                 f = 0;
3930                 }
3931                 if (f > 0)
3932                 {
3933                         //top speed progressbar peak
3934                         if(speed < top_speed)
3935                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3936                         {
3937                                 float peak_offset_x;
3938                                 vector peak_size = '0 0 0';
3939                                 if (speed_baralign == 0)
3940                                         peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x;
3941                 else if (speed_baralign == 1)
3942                                         peak_offset_x = (1 - min(top_speed, max_speed)/max_speed) * panel_size_x;
3943                 else // if (speed_baralign == 2)
3944                     peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x * 0.5;
3945                                 peak_size_x = floor(panel_size_x * 0.01 + 1.5);
3946                 peak_size_y = panel_size_y;
3947                 if (speed_baralign == 2) // draw two peaks, on both sides
3948                 {
3949                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x + peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3950                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x - peak_offset_x + peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3951                 }
3952                 else
3953                     drawfill(panel_pos + speed_offset + eX * (peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3954                         }
3955
3956                         //top speed
3957                         tmp_offset_y = panel_size_y * 0.4;
3958                         tmp_size_x = panel_size_x * (1 - 0.75);
3959                         tmp_size_y = (panel_size_y - tmp_offset_y) * text_scale;
3960                         tmp_offset_y += (panel_size_y - tmp_offset_y - tmp_size_y) / 2;
3961                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
3962                 }
3963                 else
3964                         top_speed = 0;
3965         }
3966
3967         //draw acceleration
3968         if(acceleration)
3969         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
3970         {
3971                 vector progressbar_color;
3972                 if(acceleration < 0)
3973                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
3974                 else
3975                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
3976
3977                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
3978                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
3979                         f = sqrt(f);
3980
3981                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
3982                 {
3983                         tmp_size = acceleration_progressbar_scale * panel_size_x * eX + panel_size_y * eY;
3984
3985                         if (acceleration_baralign == 1)
3986                                 tmp_offset_x = panel_size_x - tmp_size_x;
3987                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
3988                                 tmp_offset_x = (panel_size_x - tmp_size_x) / 2;
3989                         else
3990                                 tmp_offset_x = 0;
3991                         tmp_offset_y = 0;
3992                 }
3993                 else
3994                 {
3995                         tmp_size = panel_size;
3996                         tmp_offset = '0 0 0';
3997                 }
3998
3999                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4000         }
4001         tmp_size_x = panel_size_x;
4002         tmp_size_y = panel_size_y * text_scale;
4003         tmp_offset_x = 0;
4004         tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
4005         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4006                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4007
4008         draw_endBoldFont();
4009 }
4010
4011 // CenterPrint (#16)
4012 //
4013 #define CENTERPRINT_MAX_MSGS 10
4014 #define CENTERPRINT_MAX_ENTRIES 50
4015 #define CENTERPRINT_SPACING 0.7
4016 float cpm_index;
4017 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4018 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4019 float centerprint_time[CENTERPRINT_MAX_MSGS];
4020 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4021 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4022 float centerprint_showing;
4023
4024 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4025 {
4026         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4027         float i, j;
4028
4029         if(strMessage == "" && new_id == 0)
4030                 return;
4031
4032         // strip trailing newlines
4033         j = strlen(strMessage) - 1;
4034         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4035                 --j;
4036         if (j < strlen(strMessage) - 1)
4037                 strMessage = substring(strMessage, 0, j + 1);
4038
4039         if(strMessage == "" && new_id == 0)
4040                 return;
4041
4042         // strip leading newlines
4043         j = 0;
4044         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4045                 ++j;
4046         if (j > 0)
4047                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4048
4049         if(strMessage == "" && new_id == 0)
4050                 return;
4051
4052         if (!centerprint_showing)
4053                 centerprint_showing = TRUE;
4054
4055         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4056         {
4057                 if (j == CENTERPRINT_MAX_MSGS)
4058                         j = 0;
4059                 if (new_id && new_id == centerprint_msgID[j])
4060                 {
4061                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4062                         {
4063                                 // fade out the current msg (duration and countdown_num are ignored)
4064                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4065                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4066                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4067                                 return;
4068                         }
4069                         break; // found a msg with the same id, at position j
4070                 }
4071         }
4072
4073         if (i == CENTERPRINT_MAX_MSGS)
4074         {
4075                 // a msg with the same id was not found, add the msg at the next position
4076                 --cpm_index;
4077                 if (cpm_index == -1)
4078                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4079                 j = cpm_index;
4080         }
4081         if(centerprint_messages[j])
4082                 strunzone(centerprint_messages[j]);
4083         centerprint_messages[j] = strzone(strMessage);
4084         centerprint_msgID[j] = new_id;
4085         if (duration < 0)
4086         {
4087                 centerprint_time[j] = -1;
4088                 centerprint_expire_time[j] = time;
4089         }
4090         else
4091         {
4092                 if(duration == 0)
4093                         duration = max(1, autocvar_hud_panel_centerprint_time);
4094                 centerprint_time[j] = duration;
4095                 centerprint_expire_time[j] = time + duration;
4096         }
4097         centerprint_countdown_num[j] = countdown_num;
4098 }
4099
4100 void centerprint_hud(string strMessage)
4101 {
4102         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4103 }
4104
4105 void reset_centerprint_messages(void)
4106 {
4107         float i;
4108         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4109         {
4110                 centerprint_expire_time[i] = 0;
4111                 centerprint_time[i] = 1;
4112                 centerprint_msgID[i] = 0;
4113                 if(centerprint_messages[i])
4114                         strunzone(centerprint_messages[i]);
4115                 centerprint_messages[i] = string_null;
4116         }
4117 }
4118 float hud_configure_cp_generation_time;
4119 void HUD_CenterPrint (void)
4120 {
4121         if(!autocvar__hud_configure)
4122         {
4123                 if(!autocvar_hud_panel_centerprint) return;
4124
4125                 if (hud_configure_prev && hud_configure_prev != -1)
4126                         reset_centerprint_messages();
4127         }
4128         else
4129         {
4130                 if (!hud_configure_prev)
4131                         reset_centerprint_messages();
4132                 if (time > hud_configure_cp_generation_time)
4133                 {
4134                         float r;
4135                         r = random();
4136                         if (r > 0.9)
4137                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4138                         else if (r > 0.8)
4139                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4140                         else
4141                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4142                         hud_configure_cp_generation_time = time + 1 + random()*4;
4143                 }
4144         }
4145
4146         // this panel fades only when the menu does
4147         float hud_fade_alpha_save = 0;
4148         if(scoreboard_fade_alpha)
4149         {
4150                 hud_fade_alpha_save = hud_fade_alpha;
4151                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4152         }
4153         HUD_Panel_UpdateCvars();
4154
4155         if(scoreboard_fade_alpha)
4156         {
4157                 hud_fade_alpha = hud_fade_alpha_save;
4158
4159                 // move the panel below the scoreboard
4160                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4161                         return;
4162                 vector target_pos;
4163
4164                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4165
4166                 if(target_pos_y > panel_pos_y)
4167                 {
4168                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4169                         panel_size_y = min(panel_size_y, vid_conheight - scoreboard_bottom);
4170                 }
4171         }
4172
4173         HUD_Panel_DrawBg(1);
4174
4175         if (!centerprint_showing)
4176                 return;
4177
4178         if(panel_bg_padding)
4179         {
4180                 panel_pos += '1 1 0' * panel_bg_padding;
4181                 panel_size -= '2 2 0' * panel_bg_padding;
4182         }
4183
4184         float entries, height;
4185         vector fontsize;
4186         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4187         // height = panel_size_y/entries;
4188         // fontsize = '1 1 0' * height;
4189         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4190         fontsize = '1 1 0' * height;
4191         entries = bound(1, floor(panel_size_y/height), CENTERPRINT_MAX_ENTRIES);
4192
4193         float i, j, k, n, g;
4194         float a, sz, align, current_msg_pos_y = 0, msg_size;
4195         vector pos;
4196         string ts;
4197         float all_messages_expired = TRUE;
4198
4199         pos = panel_pos;
4200         if (autocvar_hud_panel_centerprint_flip)
4201                 pos_y += panel_size_y;
4202         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4203         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4204         {
4205                 if (j == CENTERPRINT_MAX_MSGS)
4206                         j = 0;
4207                 if (centerprint_expire_time[j] <= time)
4208                 {
4209                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4210                         {
4211                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4212                                 if (centerprint_countdown_num[j] == 0)
4213                                         continue;
4214                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4215                         }
4216                         else if(centerprint_time[j] != -1)
4217                                 continue;
4218                 }
4219
4220                 all_messages_expired = FALSE;
4221
4222                 // fade the centerprint_hud in/out
4223                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4224                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4225                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4226                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4227                 else // Expiring soon, so fade it out.
4228                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4229
4230                 if (a <= 0.5/255.0)  // Guaranteed invisible - don't show.
4231                         continue;
4232                 if (a > 1)
4233                         a = 1;
4234
4235                 // set the size from fading in/out before subsequent fading
4236                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4237
4238                 // also fade it based on positioning
4239                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4240                 {
4241                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4242                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4243                 }
4244                 a *= panel_fg_alpha;
4245
4246                 // finally set the size based on the new theAlpha from subsequent fading
4247                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4248                 drawfontscale = sz * '1 1 0';
4249
4250                 if (centerprint_countdown_num[j])
4251                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4252                 else
4253                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4254
4255                 if (autocvar_hud_panel_centerprint_flip)
4256                 {
4257                         // check if the message can be entirely shown
4258                         for(k = 0; k < n; ++k)
4259                         {
4260                                 getWrappedLine_remaining = argv(k);
4261                                 while(getWrappedLine_remaining)
4262                                 {
4263                                         ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4264                                         if (ts != "")
4265                                                 pos_y -= fontsize_y;
4266                                         else
4267                                                 pos_y -= fontsize_y * CENTERPRINT_SPACING/2;
4268                                 }
4269                         }
4270                         current_msg_pos_y = pos_y; // save starting pos (first line) of the current message
4271                 }
4272
4273                 msg_size = pos_y;
4274                 for(k = 0; k < n; ++k)
4275                 {
4276                         getWrappedLine_remaining = argv(k);
4277                         while(getWrappedLine_remaining)
4278                         {
4279                                 ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4280                                 if (ts != "")
4281                                 {
4282                                         if (align)
4283                                                 pos_x = panel_pos_x + (panel_size_x - stringwidth(ts, TRUE, fontsize)) * align;
4284                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4285                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize_y, ts, fontsize, a, DRAWFLAG_NORMAL);
4286                                         pos_y += fontsize_y;
4287                                 }
4288                                 else
4289                                         pos_y += fontsize_y * CENTERPRINT_SPACING/2;
4290                         }
4291                 }
4292
4293                 ++g; // move next position number up
4294
4295                 msg_size = pos_y - msg_size;
4296                 if (autocvar_hud_panel_centerprint_flip)
4297                 {
4298                         pos_y = current_msg_pos_y - CENTERPRINT_SPACING * fontsize_y;
4299                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4300                                 pos_y += (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4301
4302                         if (pos_y < panel_pos_y) // check if the next message can be shown
4303                         {
4304                                 drawfontscale = '1 1 0';
4305                                 return;
4306                         }
4307                 }
4308                 else
4309                 {
4310                         pos_y += CENTERPRINT_SPACING * fontsize_y;
4311                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4312                                 pos_y -= (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4313
4314                         if(pos_y > panel_pos_y + panel_size_y - fontsize_y) // check if the next message can be shown
4315                         {
4316                                 drawfontscale = '1 1 0';
4317                                 return;
4318                         }
4319                 }
4320         }
4321         drawfontscale = '1 1 0';
4322         if (all_messages_expired)
4323         {
4324                 centerprint_showing = FALSE;
4325                 reset_centerprint_messages();
4326         }
4327 }
4328
4329 /*
4330 ==================
4331 Main HUD system
4332 ==================
4333 */
4334
4335 void HUD_Reset (void)
4336 {
4337         // reset gametype specific icons
4338         if(gametype == MAPINFO_TYPE_KEYHUNT)
4339                 HUD_Mod_KH_Reset();
4340         else if(gametype == MAPINFO_TYPE_CTF)
4341                 HUD_Mod_CTF_Reset();
4342 }
4343
4344 void HUD_Main (void)
4345 {
4346         float i;
4347         // global hud theAlpha fade
4348         if(menu_enabled == 1)
4349                 hud_fade_alpha = 1;
4350         else
4351                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4352
4353         if(scoreboard_fade_alpha)
4354                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4355
4356         HUD_Configure_Frame();
4357
4358         if(intermission == 2) // no hud during mapvote
4359                 hud_fade_alpha = 0;
4360
4361         // panels that we want to be active together with the scoreboard
4362         // they must fade only when the menu does
4363         if(scoreboard_fade_alpha == 1)
4364         {
4365                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4366                 return;
4367         }
4368
4369         if(!autocvar__hud_configure && !hud_fade_alpha)
4370                 return;
4371
4372         // Drawing stuff
4373         if (hud_skin_prev != autocvar_hud_skin)
4374         {
4375                 if (hud_skin_path)
4376                         strunzone(hud_skin_path);
4377                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4378                 if (hud_skin_prev)
4379                         strunzone(hud_skin_prev);
4380                 hud_skin_prev = strzone(autocvar_hud_skin);
4381         }
4382
4383 #ifdef COMPAT_XON050_ENGINE
4384     current_player = (spectatee_status > 0) ? spectatee_status : player_localentnum;
4385 #else
4386     current_player = player_localentnum;
4387 #endif
4388
4389         // draw the dock
4390         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4391         {
4392                 float f;
4393                 vector color;
4394                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4395                 if((teamplay) && hud_dock_color_team) {
4396                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4397                                 color = '1 0 0' * hud_dock_color_team;
4398                         else
4399                                 color = myteamcolors * hud_dock_color_team;
4400                 }
4401                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4402                         color = '1 0 0' * hud_dock_color_team;
4403                 }
4404                 else
4405                 {
4406                         string hud_dock_color = autocvar_hud_dock_color;
4407                         if(hud_dock_color == "shirt") {
4408                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4409                                 color = colormapPaletteColor(floor(f / 16), 0);
4410                         }
4411                         else if(hud_dock_color == "pants") {
4412                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4413                                 color = colormapPaletteColor(mod(f, 16), 1);
4414                         }
4415                         else
4416                                 color = stov(hud_dock_color);
4417                 }
4418
4419                 string pic;
4420                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4421                 if(precache_pic(pic) == "") {
4422                         pic = strcat(hud_skin_path, "/dock_medium");
4423                         if(precache_pic(pic) == "") {
4424                                 pic = "gfx/hud/default/dock_medium";
4425                         }
4426                 }
4427                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4428         }
4429
4430         // cache the panel order into the panel_order array
4431         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4432                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4433                         panel_order[i] = -1;
4434                 string s = "";
4435                 float p_num, warning = false;
4436                 float argc = tokenize_console(autocvar__hud_panelorder);
4437                 if (argc > HUD_PANEL_NUM)
4438                         warning = true;
4439                 //first detect wrong/missing panel numbers
4440                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4441                         p_num = stof(argv(i));
4442                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4443                                 if (panel_order[p_num] == -1) //found for the first time?
4444                                         s = strcat(s, ftos(p_num), " ");
4445                                 panel_order[p_num] = 1; //mark as found
4446                         }
4447                         else
4448                                 warning = true;
4449                 }
4450                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4451                         if (panel_order[i] == -1) {
4452                                 warning = true;
4453                                 s = strcat(s, ftos(i), " "); //add missing panel number
4454                         }
4455                 }
4456                 if (warning)
4457                         print(_("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n"));
4458
4459                 cvar_set("_hud_panelorder", s);
4460                 if(hud_panelorder_prev)
4461                         strunzone(hud_panelorder_prev);
4462                 hud_panelorder_prev = strzone(s);
4463
4464                 //now properly set panel_order
4465                 tokenize_console(s);
4466                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4467                         panel_order[i] = stof(argv(i));
4468                 }
4469         }
4470
4471         hud_draw_maximized = 0;
4472         // draw panels in order specified by panel_order array
4473         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4474                 (panel = hud_panel[panel_order[i]]).panel_draw();
4475
4476         hud_draw_maximized = 1; // panels that may be maximized must check this var
4477         // draw maximized panels on top
4478         if(hud_panel_radar_maximized)
4479                 (panel = HUD_PANEL(RADAR)).panel_draw();
4480         if(autocvar__con_chat_maximized)
4481                 (panel = HUD_PANEL(CHAT)).panel_draw();
4482
4483         HUD_Configure_PostDraw();
4484
4485         hud_configure_prev = autocvar__hud_configure;
4486 }