qcsrc/client/hud.qc

   1 #include "hud.qh"
   2 #include "_all.qh"
   3
   4 #include "hud_config.qh"
   5 #include "scoreboard.qh"
   6 #include "sortlist.qh"
   7 #include "teamradar.qh"
   8 #include "t_items.qh"
   9
  10 #include "../common/buffs.qh"
  11 #include "../common/constants.qh"
  12 #include "../common/counting.qh"
  13 #include "../common/deathtypes.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades.qh"
  16
  17 #include "../server/mutators/gamemode_ctf.qh"
  18
  19 #include "../common/stats.qh"
  20
  21 #include "../csqcmodellib/cl_player.qh"
  22
  23 #include "../warpzonelib/mathlib.qh"
  24
  25 /*
  26 ==================
  27 Misc HUD functions
  28 ==================
  29 */
  30
  31 // a border picture is a texture containing nine parts:
  32 //   1/4 width: left part
  33 //   1/2 width: middle part (stretched)
  34 //   1/4 width: right part
  35 // divided into
  36 //   1/4 height: top part
  37 //   1/2 height: middle part (stretched)
  38 //   1/4 height: bottom part
  39 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  40 {
  41     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  42     {
  43                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  44                 return;
  45     }
  46         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  47         {
  48                 // draw only the central part
  49                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  50                 return;
  51         }
  52
  53         vector dX, dY;
  54         vector width, height;
  55         vector bW, bH;
  56         //pic = draw_UseSkinFor(pic);
  57         width = eX * theSize.x;
  58         height = eY * theSize.y;
  59         if(theSize.x <= theBorderSize.x * 2)
  60         {
  61                 // not wide enough... draw just left and right then
  62                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  63                 if(theSize.y <= theBorderSize.y * 2)
  64                 {
  65                         // not high enough... draw just corners
  66                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  67                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  71                 }
  72                 else
  73                 {
  74                         dY = theBorderSize.x * eY;
  75                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  76                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  81                 }
  82         }
  83         else
  84         {
  85                 if(theSize.y <= theBorderSize.y * 2)
  86                 {
  87                         // not high enough... draw just top and bottom then
  88                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  89                         dX = theBorderSize.x * eX;
  90                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  91                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  93                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  94                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  95                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  96                 }
  97                 else
  98                 {
  99                         dX = theBorderSize.x * eX;
 100                         dY = theBorderSize.x * eY;
 101                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 102                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
 103                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 104                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 105                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
 106                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 107                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 108                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
 109                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 110                 }
 111         }
 112 }
 113
 114 vector HUD_Get_Num_Color (float x, float maxvalue)
 115 {
 116         float blinkingamt;
 117         vector color;
 118         if(x >= maxvalue) {
 119                 color.x = sin(2*M_PI*time);
 120                 color.y = 1;
 121                 color.z = sin(2*M_PI*time);
 122         }
 123         else if(x > maxvalue * 0.75) {
 124                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 125                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 126                 color.z = 0;
 127         }
 128         else if(x > maxvalue * 0.5) {
 129                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 130                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 131                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 132         }
 133         else if(x > maxvalue * 0.25) {
 134                 color.x = 1;
 135                 color.y = 1;
 136                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 137         }
 138         else if(x > maxvalue * 0.1) {
 139                 color.x = 1;
 140                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 141                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 142         }
 143         else {
 144                 color.x = 1;
 145                 color.y = 0;
 146                 color.z = 0;
 147         }
 148
 149         blinkingamt = (1 - x/maxvalue/0.25);
 150         if(blinkingamt > 0)
 151         {
 152                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 153                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 154                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 155         }
 156         return color;
 157 }
 158
 159 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
 160 {
 161         float aspect = size_y / size_x;
 162         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 163 }
 164
 165 vector HUD_GetTableSize(int item_count, vector psize, float item_aspect)
 166 {
 167         float columns, rows;
 168         float ratio, best_ratio = 0;
 169         float best_columns = 1, best_rows = 1;
 170         bool vertical = (psize.x / psize.y >= item_aspect);
 171         if(vertical)
 172         {
 173                 psize = eX * psize.y + eY * psize.x;
 174                 item_aspect = 1 / item_aspect;
 175         }
 176
 177         rows = ceil(sqrt(item_count));
 178         columns = ceil(item_count/rows);
 179         while(columns >= 1)
 180         {
 181                 ratio = (psize.x/columns) / (psize.y/rows);
 182                 if(ratio > item_aspect)
 183                         ratio = item_aspect * item_aspect / ratio;
 184
 185                 if(ratio <= best_ratio)
 186                         break; // ratio starts decreasing by now, skip next configurations
 187
 188                 best_columns = columns;
 189                 best_rows = rows;
 190                 best_ratio = ratio;
 191
 192                 if(columns == 1)
 193                         break;
 194
 195                 --columns;
 196                 rows = ceil(item_count/columns);
 197         }
 198
 199         if(vertical)
 200                 return eX * best_rows + eY * best_columns;
 201         else
 202                 return eX * best_columns + eY * best_rows;
 203 }
 204
 205 float stringwidth_colors(string s, vector theSize)
 206 {
 207         return stringwidth(s, true, theSize);
 208 }
 209
 210 float stringwidth_nocolors(string s, vector theSize)
 211 {
 212         return stringwidth(s, false, theSize);
 213 }
 214
 215 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 216 {
 217         position.x -= 2 / 3 * strlen(text) * theScale.x;
 218         drawstring(position, text, theScale, rgb, theAlpha, flag);
 219 }
 220
 221 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 222 {
 223         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 224         drawstring(position, text, theScale, rgb, theAlpha, flag);
 225 }
 226
 227 // return the string of the onscreen race timer
 228 string MakeRaceString(int cp, float mytime, float theirtime, float lapdelta, string theirname)
 229 {
 230         string col;
 231         string timestr;
 232         string cpname;
 233         string lapstr;
 234         lapstr = "";
 235
 236         if(theirtime == 0) // goal hit
 237         {
 238                 if(mytime > 0)
 239                 {
 240                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 241                         col = "^1";
 242                 }
 243                 else if(mytime == 0)
 244                 {
 245                         timestr = "+0.0";
 246                         col = "^3";
 247                 }
 248                 else
 249                 {
 250                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 251                         col = "^2";
 252                 }
 253
 254                 if(lapdelta > 0)
 255                 {
 256                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 257                         col = "^2";
 258                 }
 259                 else if(lapdelta < 0)
 260                 {
 261                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 262                         col = "^1";
 263                 }
 264         }
 265         else if(theirtime > 0) // anticipation
 266         {
 267                 if(mytime >= theirtime)
 268                         timestr = strcat("+", ftos_decimals(mytime - theirtime, TIME_DECIMALS));
 269                 else
 270                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(theirtime));
 271                 col = "^3";
 272         }
 273         else
 274         {
 275                 col = "^7";
 276                 timestr = "";
 277         }
 278
 279         if(cp == 254)
 280                 cpname = _("Start line");
 281         else if(cp == 255)
 282                 cpname = _("Finish line");
 283         else if(cp)
 284                 cpname = sprintf(_("Intermediate %d"), cp);
 285         else
 286                 cpname = _("Finish line");
 287
 288         if(theirtime < 0)
 289                 return strcat(col, cpname);
 290         else if(theirname == "")
 291                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 292         else
 293                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(theirname, col, lapstr)));
 294 }
 295
 296 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 297 int race_CheckName(string net_name)
 298 {
 299         int i;
 300         for (i=RANKINGS_CNT-1;i>=0;--i)
 301                 if(grecordholder[i] == net_name)
 302                         return i+1;
 303         return 0;
 304 }
 305
 306 int GetPlayerColorForce(int i)
 307 {
 308         if(!teamplay)
 309                 return 0;
 310         else
 311                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 312 }
 313
 314 int GetPlayerColor(int i)
 315 {
 316         if(!playerslots[i].gotscores) // unconnected
 317                 return NUM_SPECTATOR;
 318         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 319                 return NUM_SPECTATOR;
 320         else
 321                 return GetPlayerColorForce(i);
 322 }
 323
 324 string GetPlayerName(int i)
 325 {
 326         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 327 }
 328
 329
 330 /*
 331 ==================
 332 HUD panels
 333 ==================
 334 */
 335
 336 // draw the background/borders
 337 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 338         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 339                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 340 } while(0)
 341
 342 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 343 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 344 {
 345         if(!length_ratio || !theAlpha)
 346                 return;
 347         if(length_ratio > 1)
 348                 length_ratio = 1;
 349         if (baralign == 3)
 350         {
 351                 if(length_ratio < -1)
 352                         length_ratio = -1;
 353         }
 354         else if(length_ratio < 0)
 355                 return;
 356
 357         vector square;
 358         vector width, height;
 359         if(vertical) {
 360                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 361                 if(precache_pic(pic) == "") {
 362                         pic = "gfx/hud/default/progressbar_vertical";
 363                 }
 364
 365         if (baralign == 1) // bottom align
 366                         theOrigin.y += (1 - length_ratio) * theSize.y;
 367         else if (baralign == 2) // center align
 368             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 369         else if (baralign == 3) // center align, positive values down, negative up
 370                 {
 371                         theSize.y *= 0.5;
 372                         if (length_ratio > 0)
 373                                 theOrigin.y += theSize.y;
 374                         else
 375                         {
 376                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 377                                 length_ratio = -length_ratio;
 378                         }
 379                 }
 380                 theSize.y *= length_ratio;
 381
 382                 vector bH;
 383                 width = eX * theSize.x;
 384                 height = eY * theSize.y;
 385                 if(theSize.y <= theSize.x * 2)
 386                 {
 387                         // button not high enough
 388                         // draw just upper and lower part then
 389                         square = eY * theSize.y * 0.5;
 390                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 391                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 392                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 393                 }
 394                 else
 395                 {
 396                         square = eY * theSize.x;
 397                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 398                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 399                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 400                 }
 401         } else {
 402                 pic = strcat(hud_skin_path, "/", pic);
 403                 if(precache_pic(pic) == "") {
 404                         pic = "gfx/hud/default/progressbar";
 405                 }
 406
 407                 if (baralign == 1) // right align
 408                         theOrigin.x += (1 - length_ratio) * theSize.x;
 409         else if (baralign == 2) // center align
 410             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 411         else if (baralign == 3) // center align, positive values on the right, negative on the left
 412                 {
 413                         theSize.x *= 0.5;
 414                         if (length_ratio > 0)
 415                                 theOrigin.x += theSize.x;
 416                         else
 417                         {
 418                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 419                                 length_ratio = -length_ratio;
 420                         }
 421                 }
 422                 theSize.x *= length_ratio;
 423
 424                 vector bW;
 425                 width = eX * theSize.x;
 426                 height = eY * theSize.y;
 427                 if(theSize.x <= theSize.y * 2)
 428                 {
 429                         // button not wide enough
 430                         // draw just left and right part then
 431                         square = eX * theSize.x * 0.5;
 432                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 433                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 434                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 435                 }
 436                 else
 437                 {
 438                         square = eX * theSize.y;
 439                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 440                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 441                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 442                 }
 443         }
 444 }
 445
 446 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 447 {
 448         if(!theAlpha)
 449                 return;
 450
 451         string pic;
 452         pic = strcat(hud_skin_path, "/num_leading");
 453         if(precache_pic(pic) == "") {
 454                 pic = "gfx/hud/default/num_leading";
 455         }
 456
 457         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 458         if(mySize.x/mySize.y > 2)
 459                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 460         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 461 }
 462
 463 // Weapon icons (#0)
 464 //
 465 entity weaponorder[WEP_MAXCOUNT];
 466 void weaponorder_swap(int i, int j, entity pass)
 467 {
 468         entity h = weaponorder[i];
 469         weaponorder[i] = weaponorder[j];
 470         weaponorder[j] = h;
 471 }
 472
 473 string weaponorder_cmp_str;
 474 int weaponorder_cmp(int i, int j, entity pass)
 475 {
 476         int ai, aj;
 477         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 478         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 479         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 480 }
 481
 482 void HUD_Weapons(void)
 483 {
 484         // declarations
 485         WepSet weapons_stat = WepSet_GetFromStat();
 486         int i;
 487         float f, a;
 488         float screen_ar;
 489         vector center = '0 0 0';
 490         int weapon_count, weapon_id;
 491         int row, column, rows = 0, columns = 0;
 492         bool vertical_order = true;
 493         float aspect = autocvar_hud_panel_weapons_aspect;
 494
 495         float timeout = autocvar_hud_panel_weapons_timeout;
 496         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 497         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 498
 499         vector barsize = '0 0 0', baroffset = '0 0 0';
 500         vector ammo_color = '1 0 1';
 501         float ammo_alpha = 1;
 502
 503         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 504         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 505
 506         vector weapon_pos, weapon_size = '0 0 0';
 507         vector color;
 508
 509         // check to see if we want to continue
 510         if(hud != HUD_NORMAL) { return; }
 511
 512         if(!autocvar__hud_configure)
 513         {
 514                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 515                         return;
 516                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 517                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 518                 {
 519                         weaponprevtime = time;
 520                         return;
 521                 }
 522         }
 523
 524         // update generic hud functions
 525         HUD_Panel_UpdateCvars();
 526
 527         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 528         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 529         {
 530                 int weapon_cnt;
 531                 if(weaponorder_bypriority)
 532                         strunzone(weaponorder_bypriority);
 533                 if(weaponorder_byimpulse)
 534                         strunzone(weaponorder_byimpulse);
 535
 536                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 537                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 538                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 539
 540                 weapon_cnt = 0;
 541                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 542                 {
 543                         self = get_weaponinfo(i);
 544                         if(self.impulse >= 0)
 545                         {
 546                                 weaponorder[weapon_cnt] = self;
 547                                 ++weapon_cnt;
 548                         }
 549                 }
 550                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 551                         weaponorder[i] = world;
 552                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 553
 554                 weaponorder_cmp_str = string_null;
 555         }
 556
 557         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 558                 complain_weapon = 0;
 559
 560         if(autocvar__hud_configure)
 561         {
 562                 if(!weapons_stat)
 563                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 564                                 weapons_stat |= WepSet_FromWeapon(i);
 565
 566                 #if 0
 567                 /// debug code
 568                 if(cvar("wep_add"))
 569                 {
 570                         weapons_stat = '0 0 0';
 571                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % WEP_COUNT);
 572                         for(i = WEP_FIRST; i <= countw; ++i)
 573                                 weapons_stat |= WepSet_FromWeapon(i);
 574                 }
 575                 #endif
 576         }
 577
 578         // determine which weapons are going to be shown
 579         if (autocvar_hud_panel_weapons_onlyowned)
 580         {
 581                 if(autocvar__hud_configure)
 582                 {
 583                         if(menu_enabled != 2)
 584                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 585                 }
 586
 587                 // do we own this weapon?
 588                 weapon_count = 0;
 589                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 590                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 591                                 ++weapon_count;
 592
 593
 594                 // might as well commit suicide now, no reason to live ;)
 595                 if (weapon_count == 0)
 596                         return;
 597
 598                 vector old_panel_size = panel_size;
 599                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 600
 601                 // get the all-weapons layout
 602                 vector table_size = HUD_GetTableSize(WEP_COUNT, padded_panel_size, aspect);
 603                 columns = table_size.x;
 604                 rows = table_size.y;
 605                 weapon_size.x = padded_panel_size.x / columns;
 606                 weapon_size.y = padded_panel_size.y / rows;
 607
 608                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 609                 // we enlarge them a bit when possible to better match the desired aspect ratio
 610                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 611                 {
 612                         // maximum number of rows that allows to display items with the desired aspect ratio
 613                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 614                         columns = min(columns, ceil(weapon_count / max_rows));
 615                         rows = ceil(weapon_count / columns);
 616                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 617                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 618                         vertical_order = false;
 619                 }
 620                 else
 621                 {
 622                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 623                         rows = min(rows, ceil(weapon_count / max_columns));
 624                         columns = ceil(weapon_count / rows);
 625                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 626                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 627                         vertical_order = true;
 628                 }
 629
 630                 // reduce size of the panel
 631                 panel_size.x = columns * weapon_size.x;
 632                 panel_size.y = rows * weapon_size.y;
 633                 panel_size += '2 2 0' * panel_bg_padding;
 634
 635                 // center the resized panel, or snap it to the screen edge when close enough
 636                 if(panel_pos.x > vid_conwidth * 0.001)
 637                 {
 638                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 639                                 panel_pos.x += old_panel_size.x - panel_size.x;
 640                         else
 641                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 642                 }
 643                 else if(old_panel_size.x > vid_conwidth * 0.999)
 644                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 645
 646                 if(panel_pos.y > vid_conheight * 0.001)
 647                 {
 648                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 649                                 panel_pos.y += old_panel_size.y - panel_size.y;
 650                         else
 651                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 652                 }
 653                 else if(old_panel_size.y > vid_conheight * 0.999)
 654                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 655         }
 656         else
 657                 weapon_count = WEP_COUNT;
 658
 659         // animation for fading in/out the panel respectively when not in use
 660         if(!autocvar__hud_configure)
 661         {
 662                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 663                 {
 664                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 665
 666                         // fade the panel alpha
 667                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 668                         {
 669                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 670                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 671                         }
 672                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 673                         {
 674                                 panel_bg_alpha *= (1 - f);
 675                                 panel_fg_alpha *= (1 - f);
 676                         }
 677
 678                         // move the panel off the screen
 679                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 680                         {
 681                                 f *= f; // for a cooler movement
 682                                 center.x = panel_pos.x + panel_size.x/2;
 683                                 center.y = panel_pos.y + panel_size.y/2;
 684                                 screen_ar = vid_conwidth/vid_conheight;
 685                                 if (center.x/center.y < screen_ar) //bottom left
 686                                 {
 687                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 688                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 689                                         else //left
 690                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 691                                 }
 692                                 else //top right
 693                                 {
 694                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 695                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 696                                         else //top
 697                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 698                                 }
 699                                 if(f == 1)
 700                                         center.x = -1; // mark the panel as off screen
 701                         }
 702                         weaponprevtime = time - (1 - f) * timein_effect_length;
 703                 }
 704                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 705                 {
 706                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 707
 708                         // fade the panel alpha
 709                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 710                         {
 711                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 712                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 713                         }
 714                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 715                         {
 716                                 panel_bg_alpha *= (f);
 717                                 panel_fg_alpha *= (f);
 718                         }
 719
 720                         // move the panel back on screen
 721                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 722                         {
 723                                 f *= f; // for a cooler movement
 724                                 f = 1 - f;
 725                                 center.x = panel_pos.x + panel_size.x/2;
 726                                 center.y = panel_pos.y + panel_size.y/2;
 727                                 screen_ar = vid_conwidth/vid_conheight;
 728                                 if (center.x/center.y < screen_ar) //bottom left
 729                                 {
 730                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 731                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 732                                         else //left
 733                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 734                                 }
 735                                 else //top right
 736                                 {
 737                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 738                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 739                                         else //top
 740                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 741                                 }
 742                         }
 743                 }
 744         }
 745
 746         // draw the background, then change the virtual size of it to better fit other items inside
 747         HUD_Panel_DrawBg(1);
 748
 749         if(center.x == -1)
 750                 return;
 751
 752         if(panel_bg_padding)
 753         {
 754                 panel_pos += '1 1 0' * panel_bg_padding;
 755                 panel_size -= '2 2 0' * panel_bg_padding;
 756         }
 757
 758         // after the sizing and animations are done, update the other values
 759
 760         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 761         {
 762                 vector table_size = HUD_GetTableSize(WEP_COUNT, panel_size, aspect);
 763                 columns = table_size.x;
 764                 rows = table_size.y;
 765                 weapon_size.x = panel_size.x / columns;
 766                 weapon_size.y = panel_size.y / rows;
 767                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 768         }
 769
 770         // calculate position/size for visual bar displaying ammount of ammo status
 771         if (autocvar_hud_panel_weapons_ammo)
 772         {
 773                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 774                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 775
 776                 if(weapon_size.x/weapon_size.y > aspect)
 777                 {
 778                         barsize.x = aspect * weapon_size.y;
 779                         barsize.y = weapon_size.y;
 780                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 781                 }
 782                 else
 783                 {
 784                         barsize.y = 1/aspect * weapon_size.x;
 785                         barsize.x = weapon_size.x;
 786                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 787                 }
 788         }
 789         if(autocvar_hud_panel_weapons_accuracy)
 790                 Accuracy_LoadColors();
 791
 792         // draw items
 793         row = column = 0;
 794         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 795         vector noncurrent_pos = '0 0 0';
 796         vector noncurrent_size = weapon_size * bound(0, autocvar_hud_panel_weapons_noncurrent_scale, 1);
 797         float noncurrent_alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_weapons_noncurrent_alpha, 1);
 798         bool isCurrent;
 799
 800         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 801         {
 802                 // retrieve information about the current weapon to be drawn
 803                 self = weaponorder[i];
 804                 weapon_id = self.impulse;
 805                 isCurrent = (self.weapon == switchweapon);
 806
 807                 // skip if this weapon doesn't exist
 808                 if(!self || weapon_id < 0) { continue; }
 809
 810                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 811                 if(autocvar_hud_panel_weapons_onlyowned)
 812                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 813                         continue;
 814
 815                 // figure out the drawing position of weapon
 816                 weapon_pos = (panel_pos + eX * column * weapon_size.x + eY * row * weapon_size.y);
 817                 noncurrent_pos.x = weapon_pos.x + (weapon_size.x - noncurrent_size.x) / 2;
 818                 noncurrent_pos.y = weapon_pos.y + (weapon_size.y - noncurrent_size.y) / 2;
 819
 820                 // draw background behind currently selected weapon
 821                 if(isCurrent)
 822                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 823
 824                 // draw the weapon accuracy
 825                 if(autocvar_hud_panel_weapons_accuracy)
 826                 {
 827                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 828                         if(panel_weapon_accuracy >= 0)
 829                         {
 830                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 831                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 832                         }
 833                 }
 834
 835                 // drawing all the weapon items
 836                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 837                 {
 838                         // draw the weapon image
 839                         if(isCurrent)
 840                                 drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 841                         else
 842                                 drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '1 1 1', noncurrent_alpha, DRAWFLAG_NORMAL);
 843
 844                         // draw weapon label string
 845                         switch(autocvar_hud_panel_weapons_label)
 846                         {
 847                                 case 1: // weapon number
 848                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 849                                         break;
 850
 851                                 case 2: // bind
 852                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 853                                         break;
 854
 855                                 case 3: // weapon name
 856                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 857                                         break;
 858
 859                                 default: // nothing
 860                                         break;
 861                         }
 862
 863                         // draw ammo status bar
 864                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 865                         {
 866                                 float ammo_full;
 867                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 868
 869                                 if(a > 0)
 870                                 {
 871                                         switch(self.ammo_field)
 872                                         {
 873                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 874                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 875                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 876                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 877                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 878                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 879                                                 default: ammo_full = 60;
 880                                         }
 881
 882                                         drawsetcliparea(
 883                                                 weapon_pos.x + baroffset.x,
 884                                                 weapon_pos.y + baroffset.y,
 885                                                 barsize.x * bound(0, a/ammo_full, 1),
 886                                                 barsize.y
 887                                         );
 888
 889                                         drawpic_aspect_skin(
 890                                                 weapon_pos,
 891                                                 "weapon_ammo",
 892                                                 weapon_size,
 893                                                 ammo_color,
 894                                                 ammo_alpha,
 895                                                 DRAWFLAG_NORMAL
 896                                         );
 897
 898                                         drawresetcliparea();
 899                                 }
 900                         }
 901                 }
 902                 else // draw a "ghost weapon icon" if you don't have the weapon
 903                 {
 904                         drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '0.2 0.2 0.2', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 905                 }
 906
 907                 // draw the complain message
 908                 if(self.weapon == complain_weapon)
 909                 {
 910                         if(fadetime)
 911                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 912                         else
 913                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 914
 915                         string s;
 916                         if(complain_weapon_type == 0) {
 917                                 s = _("Out of ammo");
 918                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 919                         }
 920                         else if(complain_weapon_type == 1) {
 921                                 s = _("Don't have");
 922                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 923                         }
 924                         else {
 925                                 s = _("Unavailable");
 926                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 927                         }
 928                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 929                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 930                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 931                 }
 932
 933                 #if 0
 934                 /// debug code
 935                 if(!autocvar_hud_panel_weapons_onlyowned)
 936                 {
 937                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 938                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 939                 }
 940                 #endif
 941
 942                 // continue with new position for the next weapon
 943                 if(vertical_order)
 944                 {
 945                         ++column;
 946                         if(column >= columns)
 947                         {
 948                                 column = 0;
 949                                 ++row;
 950                         }
 951                 }
 952                 else
 953                 {
 954                         ++row;
 955                         if(row >= rows)
 956                         {
 957                                 row = 0;
 958                                 ++column;
 959                         }
 960                 }
 961         }
 962 }
 963
 964 // Ammo (#1)
 965 void DrawNadeProgressBar(vector myPos, vector mySize, float progress, vector color)
 966 {
 967         HUD_Panel_DrawProgressBar(
 968                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 969                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 970                 autocvar_hud_panel_ammo_progressbar_name,
 971                 progress, 0, 0, color,
 972                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 973 }
 974
 975 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 976 {
 977         float bonusNades    = getstatf(STAT_NADE_BONUS);
 978         float bonusProgress = getstatf(STAT_NADE_BONUS_SCORE);
 979         float bonusType     = getstati(STAT_NADE_BONUS_TYPE);
 980         vector nadeColor    = Nade_Color(bonusType);
 981         string nadeIcon     = Nade_Icon(bonusType);
 982
 983         vector iconPos, textPos;
 984
 985         if(autocvar_hud_panel_ammo_iconalign)
 986         {
 987                 iconPos = myPos + eX * 2 * mySize.y;
 988                 textPos = myPos;
 989         }
 990         else
 991         {
 992                 iconPos = myPos;
 993                 textPos = myPos + eX * mySize.y;
 994         }
 995
 996         if(bonusNades > 0 || bonusProgress > 0)
 997         {
 998                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 999
1000                 if(autocvar_hud_panel_ammo_text)
1001                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1002
1003                 if(draw_expanding)
1004                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
1005
1006                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1007         }
1008 }
1009
1010 void DrawAmmoItem(vector myPos, vector mySize, .int ammoType, bool isCurrent, bool isInfinite)
1011 {
1012         if(ammoType == ammo_none)
1013                 return;
1014
1015         // Initialize variables
1016
1017         int ammo;
1018         if(autocvar__hud_configure)
1019         {
1020                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
1021                 ammo = 60;
1022         }
1023         else
1024                 ammo = getstati(GetAmmoStat(ammoType));
1025
1026         if(!isCurrent)
1027         {
1028                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
1029                 myPos = myPos + (mySize - mySize * scale) * 0.5;
1030                 mySize = mySize * scale;
1031         }
1032
1033         vector iconPos, textPos;
1034         if(autocvar_hud_panel_ammo_iconalign)
1035         {
1036                 iconPos = myPos + eX * 2 * mySize.y;
1037                 textPos = myPos;
1038         }
1039         else
1040         {
1041                 iconPos = myPos;
1042                 textPos = myPos + eX * mySize.y;
1043         }
1044
1045         bool isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
1046
1047         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
1048         vector textColor;
1049         if(isInfinite)
1050                 textColor = '0.2 0.95 0';
1051         else if(isShadowed)
1052                 textColor = '0 0 0';
1053         else if(ammo < 10)
1054                 textColor = '0.8 0.04 0';
1055         else
1056                 textColor = '1 1 1';
1057
1058         float alpha;
1059         if(isCurrent)
1060                 alpha = panel_fg_alpha;
1061         else if(isShadowed)
1062                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
1063         else
1064                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
1065
1066         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
1067
1068         // Draw item
1069
1070         if(isCurrent)
1071                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1072
1073         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
1074                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
1075
1076         if(autocvar_hud_panel_ammo_text)
1077                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
1078
1079         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
1080 }
1081
1082 int nade_prevstatus;
1083 int nade_prevframe;
1084 float nade_statuschange_time;
1085 void HUD_Ammo(void)
1086 {
1087         if(hud != HUD_NORMAL) return;
1088         if(!autocvar__hud_configure)
1089         {
1090                 if(!autocvar_hud_panel_ammo) return;
1091                 if(spectatee_status == -1) return;
1092         }
1093
1094         HUD_Panel_UpdateCvars();
1095
1096         draw_beginBoldFont();
1097
1098         vector pos, mySize;
1099         pos = panel_pos;
1100         mySize = panel_size;
1101
1102         HUD_Panel_DrawBg(1);
1103         if(panel_bg_padding)
1104         {
1105                 pos += '1 1 0' * panel_bg_padding;
1106                 mySize -= '2 2 0' * panel_bg_padding;
1107         }
1108
1109         int rows = 0, columns, row, column;
1110         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1111         bool draw_nades = (nade_cnt > 0 || nade_score > 0);
1112         float nade_statuschange_elapsedtime;
1113         int total_ammo_count;
1114
1115         vector ammo_size;
1116         if (autocvar_hud_panel_ammo_onlycurrent)
1117                 total_ammo_count = 1;
1118         else
1119                 total_ammo_count = AMMO_COUNT;
1120
1121         if(draw_nades)
1122         {
1123                 ++total_ammo_count;
1124                 if (nade_cnt != nade_prevframe)
1125                 {
1126                         nade_statuschange_time = time;
1127                         nade_prevstatus = nade_prevframe;
1128                         nade_prevframe = nade_cnt;
1129                 }
1130         }
1131         else
1132                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1133
1134         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1135         columns = ceil((total_ammo_count)/rows);
1136         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1137
1138         vector offset = '0 0 0'; // fteqcc sucks
1139         float newSize;
1140         if(ammo_size.x/ammo_size.y > 3)
1141         {
1142                 newSize = 3 * ammo_size.y;
1143                 offset.x = ammo_size.x - newSize;
1144                 pos.x += offset.x/2;
1145                 ammo_size.x = newSize;
1146         }
1147         else
1148         {
1149                 newSize = 1/3 * ammo_size.x;
1150                 offset.y = ammo_size.y - newSize;
1151                 pos.y += offset.y/2;
1152                 ammo_size.y = newSize;
1153         }
1154
1155         int i;
1156         bool infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1157         row = column = 0;
1158         if(autocvar_hud_panel_ammo_onlycurrent)
1159         {
1160                 if(autocvar__hud_configure)
1161                 {
1162                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1163                 }
1164                 else
1165                 {
1166                         DrawAmmoItem(
1167                                 pos,
1168                                 ammo_size,
1169                                 (get_weaponinfo(switchweapon)).ammo_field,
1170                                 true,
1171                                 infinite_ammo
1172                         );
1173                 }
1174
1175                 ++row;
1176                 if(row >= rows)
1177                 {
1178                         row = 0;
1179                         column = column + 1;
1180                 }
1181         }
1182         else
1183         {
1184                 .int ammotype;
1185                 row = column = 0;
1186                 for(i = 0; i < AMMO_COUNT; ++i)
1187                 {
1188                         ammotype = GetAmmoFieldFromNum(i);
1189                         DrawAmmoItem(
1190                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1191                                 ammo_size,
1192                                 ammotype,
1193                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1194                                 infinite_ammo
1195                         );
1196
1197                         ++row;
1198                         if(row >= rows)
1199                         {
1200                                 row = 0;
1201                                 column = column + 1;
1202                         }
1203                 }
1204         }
1205
1206         if (draw_nades)
1207         {
1208                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1209
1210                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1211
1212                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1213         }
1214
1215         draw_endBoldFont();
1216 }
1217
1218 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha, float fadelerp)
1219 {
1220         vector newPos = '0 0 0', newSize = '0 0 0';
1221         vector picpos, numpos;
1222
1223         if (vertical)
1224         {
1225                 if(mySize.y/mySize.x > 2)
1226                 {
1227                         newSize.y = 2 * mySize.x;
1228                         newSize.x = mySize.x;
1229
1230                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1231                         newPos.x = myPos.x;
1232                 }
1233                 else
1234                 {
1235                         newSize.x = 1/2 * mySize.y;
1236                         newSize.y = mySize.y;
1237
1238                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1239                         newPos.y = myPos.y;
1240                 }
1241
1242                 if(icon_right_align)
1243                 {
1244                         numpos = newPos;
1245                         picpos = newPos + eY * newSize.x;
1246                 }
1247                 else
1248                 {
1249                         picpos = newPos;
1250                         numpos = newPos + eY * newSize.x;
1251                 }
1252
1253                 newSize.y /= 2;
1254                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1255                 // make number smaller than icon, it looks better
1256                 // reduce only y to draw numbers with different number of digits with the same y size
1257                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1258                 newSize.y *= 0.7;
1259                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1260                 return;
1261         }
1262
1263         if(mySize.x/mySize.y > 3)
1264         {
1265                 newSize.x = 3 * mySize.y;
1266                 newSize.y = mySize.y;
1267
1268                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1269                 newPos.y = myPos.y;
1270         }
1271         else
1272         {
1273                 newSize.y = 1/3 * mySize.x;
1274                 newSize.x = mySize.x;
1275
1276                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1277                 newPos.x = myPos.x;
1278         }
1279
1280         if(icon_right_align) // right align
1281         {
1282                 numpos = newPos;
1283                 picpos = newPos + eX * 2 * newSize.y;
1284         }
1285         else // left align
1286         {
1287                 numpos = newPos + eX * newSize.y;
1288                 picpos = newPos;
1289         }
1290
1291         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1292         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1293         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1294         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1295 }
1296
1297 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha)
1298 {
1299         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1300 }
1301
1302 // Powerups (#2)
1303 //
1304 void HUD_Powerups(void)
1305 {
1306         float strength_time, shield_time, superweapons_time;
1307         if(!autocvar__hud_configure)
1308         {
1309                 if(!autocvar_hud_panel_powerups) return;
1310                 if(spectatee_status == -1) return;
1311                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1312                 if (getstati(STAT_HEALTH) <= 0) return;
1313
1314                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1315                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1316                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1317
1318                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1319                         superweapons_time = 99; // force max
1320
1321                 // prevent stuff to show up on mismatch that will be fixed next frame
1322                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1323                         superweapons_time = 0;
1324         }
1325         else
1326         {
1327                 strength_time = 15;
1328                 shield_time = 27;
1329                 superweapons_time = 13;
1330         }
1331
1332         HUD_Panel_UpdateCvars();
1333
1334         draw_beginBoldFont();
1335
1336         vector pos, mySize;
1337         pos = panel_pos;
1338         mySize = panel_size;
1339
1340         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1341         if(panel_bg_padding)
1342         {
1343                 pos += '1 1 0' * panel_bg_padding;
1344                 mySize -= '2 2 0' * panel_bg_padding;
1345         }
1346
1347         float panel_ar = mySize.x/mySize.y;
1348         bool is_vertical = (panel_ar < 1);
1349         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1350
1351         int superweapons_is = -1;
1352
1353         if(superweapons_time)
1354         {
1355                 if(strength_time)
1356                 {
1357                         if(shield_time)
1358                                 superweapons_is = 0;
1359                         else
1360                                 superweapons_is = 2;
1361                 }
1362                 else
1363                 {
1364                         if(shield_time)
1365                                 superweapons_is = 1;
1366                         else
1367                                 superweapons_is = 2;
1368                 }
1369         }
1370
1371         // FIXME handle superweapons here
1372         if(superweapons_is == 0)
1373         {
1374                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1375                 {
1376                         mySize.x *= (1.0 / 3.0);
1377                         superweapons_offset.x = mySize.x;
1378                         if (autocvar_hud_panel_powerups_flip)
1379                                 shield_offset.x = 2*mySize.x;
1380                         else
1381                                 strength_offset.x = 2*mySize.x;
1382                 }
1383                 else
1384                 {
1385                         mySize.y *= (1.0 / 3.0);
1386                         superweapons_offset.y = mySize.y;
1387                         if (autocvar_hud_panel_powerups_flip)
1388                                 shield_offset.y = 2*mySize.y;
1389                         else
1390                                 strength_offset.y = 2*mySize.y;
1391                 }
1392         }
1393         else
1394         {
1395                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1396                 {
1397                         mySize.x *= 0.5;
1398                         if (autocvar_hud_panel_powerups_flip)
1399                                 shield_offset.x = mySize.x;
1400                         else
1401                                 strength_offset.x = mySize.x;
1402                 }
1403                 else
1404                 {
1405                         mySize.y *= 0.5;
1406                         if (autocvar_hud_panel_powerups_flip)
1407                                 shield_offset.y = mySize.y;
1408                         else
1409                                 strength_offset.y = mySize.y;
1410                 }
1411         }
1412
1413         bool shield_baralign, strength_baralign, superweapons_baralign;
1414         bool shield_iconalign, strength_iconalign, superweapons_iconalign;
1415
1416         if (autocvar_hud_panel_powerups_flip)
1417         {
1418                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1419                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1420                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1421                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1422         }
1423         else
1424         {
1425                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1426                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1427                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1428                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1429         }
1430
1431         if(superweapons_is == 0)
1432         {
1433                 superweapons_iconalign = strength_iconalign;
1434                 superweapons_baralign = 2;
1435         }
1436         else if(superweapons_is == 1)
1437         {
1438                 superweapons_offset = strength_offset;
1439                 superweapons_iconalign = strength_iconalign;
1440                 superweapons_baralign = strength_baralign;
1441         }
1442         else // if(superweapons_is == 2)
1443         {
1444                 superweapons_offset = shield_offset;
1445                 superweapons_iconalign = shield_iconalign;
1446                 superweapons_baralign = shield_baralign;
1447         }
1448
1449         if(shield_time)
1450         {
1451                 const float maxshield = 30;
1452                 float shield = ceil(shield_time);
1453                 if(autocvar_hud_panel_powerups_progressbar)
1454                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1455                 if(autocvar_hud_panel_powerups_text)
1456                 {
1457                         if(shield > 1)
1458                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1459                         if(shield <= 5)
1460                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1461                 }
1462         }
1463
1464         if(strength_time)
1465         {
1466                 const float maxstrength = 30;
1467                 float strength = ceil(strength_time);
1468                 if(autocvar_hud_panel_powerups_progressbar)
1469                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1470                 if(autocvar_hud_panel_powerups_text)
1471                 {
1472                         if(strength > 1)
1473                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1474                         if(strength <= 5)
1475                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1476                 }
1477         }
1478
1479         if(superweapons_time)
1480         {
1481                 const float maxsuperweapons = 30;
1482                 float superweapons = ceil(superweapons_time);
1483                 if(autocvar_hud_panel_powerups_progressbar)
1484                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1485                 if(autocvar_hud_panel_powerups_text)
1486                 {
1487                         if(superweapons > 1)
1488                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1489                         if(superweapons <= 5)
1490                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1491                 }
1492         }
1493
1494         draw_endBoldFont();
1495 }
1496
1497 // Health/armor (#3)
1498 //
1499
1500
1501 void HUD_HealthArmor(void)
1502 {
1503         int armor, health, fuel;
1504         if(!autocvar__hud_configure)
1505         {
1506                 if(!autocvar_hud_panel_healtharmor) return;
1507                 if(hud != HUD_NORMAL) return;
1508                 if(spectatee_status == -1) return;
1509
1510                 health = getstati(STAT_HEALTH);
1511                 if(health <= 0)
1512                 {
1513                         prev_health = -1;
1514                         return;
1515                 }
1516                 armor = getstati(STAT_ARMOR);
1517
1518                 // code to check for spectatee_status changes is in Ent_ClientData()
1519                 // prev_p_health and prev_health can be set to -1 there
1520
1521                 if (prev_p_health == -1)
1522                 {
1523                         // no effect
1524                         health_beforedamage = 0;
1525                         armor_beforedamage = 0;
1526                         health_damagetime = 0;
1527                         armor_damagetime = 0;
1528                         prev_health = health;
1529                         prev_armor = armor;
1530                         old_p_health = health;
1531                         old_p_armor = armor;
1532                         prev_p_health = health;
1533                         prev_p_armor = armor;
1534                 }
1535                 else if (prev_health == -1)
1536                 {
1537                         //start the load effect
1538                         health_damagetime = 0;
1539                         armor_damagetime = 0;
1540                         prev_health = 0;
1541                         prev_armor = 0;
1542                 }
1543                 fuel = getstati(STAT_FUEL);
1544         }
1545         else
1546         {
1547                 health = 150;
1548                 armor = 75;
1549                 fuel = 20;
1550         }
1551
1552         HUD_Panel_UpdateCvars();
1553
1554         draw_beginBoldFont();
1555
1556         vector pos, mySize;
1557         pos = panel_pos;
1558         mySize = panel_size;
1559
1560         HUD_Panel_DrawBg(1);
1561         if(panel_bg_padding)
1562         {
1563                 pos += '1 1 0' * panel_bg_padding;
1564                 mySize -= '2 2 0' * panel_bg_padding;
1565         }
1566
1567         int baralign = autocvar_hud_panel_healtharmor_baralign;
1568         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
1569
1570     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1571     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1572         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1573         {
1574                 vector v;
1575                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1576
1577                 float x;
1578                 x = floor(v.x + 1);
1579
1580         float maxtotal = maxhealth + maxarmor;
1581                 string biggercount;
1582                 if(v.z) // NOT fully armored
1583                 {
1584                         biggercount = "health";
1585                         if(autocvar_hud_panel_healtharmor_progressbar)
1586                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1587                         if(armor)
1588             if(autocvar_hud_panel_healtharmor_text)
1589                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1590                 }
1591                 else
1592                 {
1593                         biggercount = "armor";
1594                         if(autocvar_hud_panel_healtharmor_progressbar)
1595                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1596                         if(health)
1597             if(autocvar_hud_panel_healtharmor_text)
1598                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1599                 }
1600         if(autocvar_hud_panel_healtharmor_text)
1601                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1602
1603                 if(fuel)
1604                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1605         }
1606         else
1607         {
1608                 float panel_ar = mySize.x/mySize.y;
1609                 bool is_vertical = (panel_ar < 1);
1610                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1611                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1612                 {
1613                         mySize.x *= 0.5;
1614                         if (autocvar_hud_panel_healtharmor_flip)
1615                                 health_offset.x = mySize.x;
1616                         else
1617                                 armor_offset.x = mySize.x;
1618                 }
1619                 else
1620                 {
1621                         mySize.y *= 0.5;
1622                         if (autocvar_hud_panel_healtharmor_flip)
1623                                 health_offset.y = mySize.y;
1624                         else
1625                                 armor_offset.y = mySize.y;
1626                 }
1627
1628                 bool health_baralign, armor_baralign, fuel_baralign;
1629                 bool health_iconalign, armor_iconalign;
1630                 if (autocvar_hud_panel_healtharmor_flip)
1631                 {
1632                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1633                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1634                         fuel_baralign = health_baralign;
1635                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1636                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1637                 }
1638                 else
1639                 {
1640                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1641                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1642                         fuel_baralign = armor_baralign;
1643                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1644                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1645                 }
1646
1647                 //if(health)
1648                 {
1649                         if(autocvar_hud_panel_healtharmor_progressbar)
1650                         {
1651                                 float p_health, pain_health_alpha;
1652                                 p_health = health;
1653                                 pain_health_alpha = 1;
1654                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1655                                 {
1656                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1657                                         {
1658                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1659                                                 {
1660                                                         if (time - old_p_healthtime < 1)
1661                                                                 old_p_health = prev_p_health;
1662                                                         else
1663                                                                 old_p_health = prev_health;
1664                                                         old_p_healthtime = time;
1665                                                 }
1666                                                 if (time - old_p_healthtime < 1)
1667                                                 {
1668                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1669                                                         prev_p_health = p_health;
1670                                                 }
1671                                         }
1672                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1673                                         {
1674                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1675                                                 {
1676                                                         if (time - health_damagetime >= 1)
1677                                                                 health_beforedamage = prev_health;
1678                                                         health_damagetime = time;
1679                                                 }
1680                                                 if (time - health_damagetime < 1)
1681                                                 {
1682                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1683                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1684                                                 }
1685                                         }
1686                                         prev_health = health;
1687
1688                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1689                                         {
1690                                                 float BLINK_FACTOR = 0.15;
1691                                                 float BLINK_BASE = 0.85;
1692                                                 float BLINK_FREQ = 9;
1693                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1694                                         }
1695                                 }
1696                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1697                         }
1698                         if(autocvar_hud_panel_healtharmor_text)
1699                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1700                 }
1701
1702                 if(armor)
1703                 {
1704                         if(autocvar_hud_panel_healtharmor_progressbar)
1705                         {
1706                                 float p_armor;
1707                                 p_armor = armor;
1708                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1709                                 {
1710                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1711                                         {
1712                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1713                                                 {
1714                                                         if (time - old_p_armortime < 1)
1715                                                                 old_p_armor = prev_p_armor;
1716                                                         else
1717                                                                 old_p_armor = prev_armor;
1718                                                         old_p_armortime = time;
1719                                                 }
1720                                                 if (time - old_p_armortime < 1)
1721                                                 {
1722                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1723                                                         prev_p_armor = p_armor;
1724                                                 }
1725                                         }
1726                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1727                                         {
1728                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1729                                                 {
1730                                                         if (time - armor_damagetime >= 1)
1731                                                                 armor_beforedamage = prev_armor;
1732                                                         armor_damagetime = time;
1733                                                 }
1734                                                 if (time - armor_damagetime < 1)
1735                                                 {
1736                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1737                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1738                                                 }
1739                                         }
1740                                         prev_armor = armor;
1741                                 }
1742                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1743                         }
1744                         if(autocvar_hud_panel_healtharmor_text)
1745                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1746                 }
1747
1748                 if(fuel)
1749                 {
1750                         if (is_vertical)
1751                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1752                         else
1753                                 mySize.y *= 0.2;
1754                         if (panel_ar >= 4)
1755                                 mySize.x *= 2; //restore full panel size
1756                         else if (panel_ar < 1/4)
1757                                 mySize.y *= 2; //restore full panel size
1758                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1759                 }
1760         }
1761
1762         draw_endBoldFont();
1763 }
1764
1765 // Notification area (#4)
1766 //
1767
1768 void HUD_Notify_Push(string icon, string attacker, string victim)
1769 {
1770         if (icon == "")
1771                 return;
1772
1773         ++notify_count;
1774         --notify_index;
1775
1776         if (notify_index == -1)
1777                 notify_index = NOTIFY_MAX_ENTRIES-1;
1778
1779         // Free old strings
1780         if (notify_attackers[notify_index])
1781                 strunzone(notify_attackers[notify_index]);
1782
1783         if (notify_victims[notify_index])
1784                 strunzone(notify_victims[notify_index]);
1785
1786         if (notify_icons[notify_index])
1787                 strunzone(notify_icons[notify_index]);
1788
1789         // Allocate new strings
1790         if (victim != "")
1791         {
1792                 notify_attackers[notify_index] = strzone(attacker);
1793                 notify_victims[notify_index] = strzone(victim);
1794         }
1795         else
1796         {
1797                 // In case of a notification without a victim, the attacker
1798                 // is displayed on the victim's side. Instead of special
1799                 // treatment later on, we can simply switch them here.
1800                 notify_attackers[notify_index] = string_null;
1801                 notify_victims[notify_index] = strzone(attacker);
1802         }
1803
1804         notify_icons[notify_index] = strzone(icon);
1805         notify_times[notify_index] = time;
1806 }
1807
1808 void HUD_Notify(void)
1809 {
1810         if (!autocvar__hud_configure)
1811                 if (!autocvar_hud_panel_notify)
1812                         return;
1813
1814         HUD_Panel_UpdateCvars();
1815         HUD_Panel_DrawBg(1);
1816
1817         if (!autocvar__hud_configure)
1818                 if (notify_count == 0)
1819                         return;
1820
1821         vector pos, size;
1822         pos  = panel_pos;
1823         size = panel_size;
1824
1825         if (panel_bg_padding)
1826         {
1827                 pos  += '1 1 0' * panel_bg_padding;
1828                 size -= '2 2 0' * panel_bg_padding;
1829         }
1830
1831         float fade_start = max(0, autocvar_hud_panel_notify_time);
1832         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1833         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1834
1835         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1836         float entry_height = size.y / entry_count;
1837
1838         float panel_width_half = size.x * 0.5;
1839         float icon_width_half = entry_height * icon_aspect / 2;
1840         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1841
1842         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1843         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1844         vector icon_left = eX * (panel_width_half - icon_width_half);
1845         vector attacker_right = eX * name_maxwidth;
1846         vector victim_left = eX * (size.x - name_maxwidth);
1847
1848         vector attacker_pos, victim_pos, icon_pos;
1849         string attacker, victim, icon;
1850         int i, j, count, step, limit;
1851         float alpha;
1852
1853         if (autocvar_hud_panel_notify_flip)
1854         {
1855                 // Order items from the top down
1856                 i = 0;
1857                 step = +1;
1858                 limit = entry_count;
1859         }
1860         else
1861         {
1862                 // Order items from the bottom up
1863                 i = entry_count - 1;
1864                 step = -1;
1865                 limit = -1;
1866         }
1867
1868         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1869         {
1870                 if(autocvar__hud_configure)
1871                 {
1872                         attacker = sprintf(_("Player %d"), count + 1);
1873                         victim = sprintf(_("Player %d"), count + 2);
1874                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1875                         alpha = bound(0, 1.2 - count / entry_count, 1);
1876                 }
1877                 else
1878                 {
1879                         if (j == NOTIFY_MAX_ENTRIES)
1880                                 j = 0;
1881
1882                         if (notify_times[j] + fade_start > time)
1883                                 alpha = 1;
1884                         else if (fade_time != 0)
1885                         {
1886                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1887                                 if (alpha == 0)
1888                                         break;
1889                         }
1890                         else
1891                                 break;
1892
1893                         attacker = notify_attackers[j];
1894                         victim = notify_victims[j];
1895                         icon = notify_icons[j];
1896                 }
1897
1898                 if (icon != "" && victim != "")
1899                 {
1900                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1901
1902                         icon_pos = pos + icon_left + eY * i * entry_height;
1903                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1904
1905                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1906                         victim_pos = pos + victim_left + name_top;
1907                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1908
1909                         if (attacker != "")
1910                         {
1911                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1912                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1913                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1914                         }
1915                 }
1916         }
1917
1918         notify_count = count;
1919 }
1920
1921 // Timer (#5)
1922 //
1923 // TODO: macro
1924 string seconds_tostring(float sec)
1925 {
1926         float minutes;
1927         minutes = floor(sec / 60);
1928
1929         sec -= minutes * 60;
1930         return sprintf("%d:%02d", minutes, sec);
1931 }
1932
1933 void HUD_Timer(void)
1934 {
1935         if(!autocvar__hud_configure)
1936         {
1937                 if(!autocvar_hud_panel_timer) return;
1938         }
1939
1940         HUD_Panel_UpdateCvars();
1941
1942         draw_beginBoldFont();
1943
1944         vector pos, mySize;
1945         pos = panel_pos;
1946         mySize = panel_size;
1947
1948         HUD_Panel_DrawBg(1);
1949         if(panel_bg_padding)
1950         {
1951                 pos += '1 1 0' * panel_bg_padding;
1952                 mySize -= '2 2 0' * panel_bg_padding;
1953         }
1954
1955         string timer;
1956         float timelimit, elapsedTime, timeleft, minutesLeft;
1957
1958         timelimit = getstatf(STAT_TIMELIMIT);
1959
1960         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1961         timeleft = ceil(timeleft);
1962
1963         minutesLeft = floor(timeleft / 60);
1964
1965         vector timer_color;
1966         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1967                 timer_color = '1 1 1'; //white
1968         else if(minutesLeft >= 1)
1969                 timer_color = '1 1 0'; //yellow
1970         else
1971                 timer_color = '1 0 0'; //red
1972
1973         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1974                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1975                         //while restart is still active, show 00:00
1976                         timer = seconds_tostring(0);
1977                 } else {
1978                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1979                         timer = seconds_tostring(elapsedTime);
1980                 }
1981         } else {
1982                 timer = seconds_tostring(timeleft);
1983         }
1984
1985         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1986
1987         draw_endBoldFont();
1988 }
1989
1990 // Radar (#6)
1991 //
1992 void HUD_Radar(void)
1993 {
1994         if (!autocvar__hud_configure)
1995         {
1996                 if (hud_panel_radar_maximized)
1997                 {
1998                         if (!hud_draw_maximized) return;
1999                 }
2000                 else
2001                 {
2002                         if (autocvar_hud_panel_radar == 0) return;
2003                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
2004                         if(radar_panel_modified)
2005                         {
2006                                 panel.update_time = time; // forces reload of panel attributes
2007                                 radar_panel_modified = false;
2008                         }
2009                 }
2010         }
2011
2012         HUD_Panel_UpdateCvars();
2013
2014         float f = 0;
2015
2016         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2017         {
2018                 panel_size = autocvar_hud_panel_radar_maximized_size;
2019                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2020                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2021                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2022                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2023
2024                 string panel_bg;
2025                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2026                 if(precache_pic(panel_bg) == "")
2027                         panel_bg = "gfx/hud/default/border_default"; // fallback
2028                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2029                         radar_panel_modified = true;
2030                 if(panel.current_panel_bg)
2031                         strunzone(panel.current_panel_bg);
2032                 panel.current_panel_bg = strzone(panel_bg);
2033
2034                 switch(hud_panel_radar_maximized_zoommode)
2035                 {
2036                         default:
2037                         case 0:
2038                                 f = current_zoomfraction;
2039                                 break;
2040                         case 1:
2041                                 f = 1 - current_zoomfraction;
2042                                 break;
2043                         case 2:
2044                                 f = 0;
2045                                 break;
2046                         case 3:
2047                                 f = 1;
2048                                 break;
2049                 }
2050
2051                 switch(hud_panel_radar_maximized_rotation)
2052                 {
2053                         case 0:
2054                                 teamradar_angle = view_angles.y - 90;
2055                                 break;
2056                         default:
2057                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2058                                 break;
2059                 }
2060         }
2061         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2062         {
2063                 switch(hud_panel_radar_zoommode)
2064                 {
2065                         default:
2066                         case 0:
2067                                 f = current_zoomfraction;
2068                                 break;
2069                         case 1:
2070                                 f = 1 - current_zoomfraction;
2071                                 break;
2072                         case 2:
2073                                 f = 0;
2074                                 break;
2075                         case 3:
2076                                 f = 1;
2077                                 break;
2078                 }
2079
2080                 switch(hud_panel_radar_rotation)
2081                 {
2082                         case 0:
2083                                 teamradar_angle = view_angles.y - 90;
2084                                 break;
2085                         default:
2086                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2087                                 break;
2088                 }
2089         }
2090
2091         vector pos, mySize;
2092         pos = panel_pos;
2093         mySize = panel_size;
2094
2095         HUD_Panel_DrawBg(1);
2096         if(panel_bg_padding)
2097         {
2098                 pos += '1 1 0' * panel_bg_padding;
2099                 mySize -= '2 2 0' * panel_bg_padding;
2100         }
2101
2102         int color2;
2103         entity tm;
2104         float scale2d, normalsize, bigsize;
2105
2106         teamradar_origin2d = pos + 0.5 * mySize;
2107         teamradar_size2d = mySize;
2108
2109         if(minimapname == "")
2110                 return;
2111
2112         teamradar_loadcvars();
2113
2114         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2115         teamradar_size2d = mySize;
2116
2117         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2118
2119         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2120         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2121         {
2122                 // max-min distance must fit the radar in any rotation
2123                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2124         }
2125         else
2126         {
2127                 vector c0, c1, c2, c3, span;
2128                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2129                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2130                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2131                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2132                 span = '0 0 0';
2133                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2134                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2135
2136                 // max-min distance must fit the radar in x=x, y=y
2137                 bigsize = min(
2138                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2139                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2140                 );
2141         }
2142
2143         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2144         if(bigsize > normalsize)
2145                 normalsize = bigsize;
2146
2147         teamradar_size =
2148                   f * bigsize
2149                 + (1 - f) * normalsize;
2150         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2151                   f * mi_center
2152                 + (1 - f) * view_origin);
2153
2154         drawsetcliparea(
2155                 pos.x,
2156                 pos.y,
2157                 mySize.x,
2158                 mySize.y
2159         );
2160
2161         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2162
2163         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2164                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2165         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2166                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2167         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2168         {
2169                 color2 = GetPlayerColor(tm.sv_entnum);
2170                 //if(color == NUM_SPECTATOR || color == color2)
2171                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2172         }
2173         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2174
2175         drawresetcliparea();
2176 }
2177
2178 // Score (#7)
2179 //
2180 void HUD_UpdatePlayerTeams();
2181 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2182 {
2183         float score;
2184         entity tm = world, pl;
2185         int SCOREPANEL_MAX_ENTRIES = 6;
2186         float SCOREPANEL_ASPECTRATIO = 2;
2187         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2188         vector fontsize = '1 1 0' * (mySize.y/entries);
2189
2190         vector rgb, score_color;
2191         rgb = '1 1 1';
2192         score_color = '1 1 1';
2193
2194         float name_size = mySize.x*0.75;
2195         float spacing_size = mySize.x*0.04;
2196         const float highlight_alpha = 0.2;
2197         int i = 0, first_pl = 0;
2198         bool me_printed = false;
2199         string s;
2200         if (autocvar__hud_configure)
2201         {
2202                 float players_per_team = 0;
2203                 if (team_count)
2204                 {
2205                         // show team scores in the first line
2206                         float score_size = mySize.x / team_count;
2207                         players_per_team = max(2, ceil((entries - 1) / team_count));
2208                         for(i=0; i<team_count; ++i) {
2209                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2210                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2211                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2212                         }
2213                         first_pl = 1;
2214                         pos.y += fontsize.y;
2215                 }
2216                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2217                 for (i=first_pl; i<entries; ++i)
2218                 {
2219                         //simulate my score is lower than all displayed players,
2220                         //so that I don't appear at all showing pure rankings.
2221                         //This is to better show the difference between the 2 ranking views
2222                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2223                         {
2224                                 rgb = '1 1 0';
2225                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2226                                 s = GetPlayerName(player_localnum);
2227                                 score = 7;
2228                         }
2229                         else
2230                         {
2231                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2232                                 score -= 3;
2233                         }
2234
2235                         if (team_count)
2236                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2237                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2238                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2239                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2240                         pos.y += fontsize.y;
2241                 }
2242                 return;
2243         }
2244
2245         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2246                 HUD_UpdatePlayerTeams();
2247         if (team_count)
2248         {
2249                 // show team scores in the first line
2250                 float score_size = mySize.x / team_count;
2251                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2252                         if(tm.team == NUM_SPECTATOR)
2253                                 continue;
2254                         if (tm.team == myteam)
2255                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2256                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2257                         ++i;
2258                 }
2259                 first_pl = 1;
2260                 pos.y += fontsize.y;
2261                 tm = teams.sort_next;
2262         }
2263         i = first_pl;
2264
2265         do
2266         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2267         {
2268                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2269                         continue;
2270
2271                 if (i == entries-1 && !me_printed && pl != me)
2272                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2273                 {
2274                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2275                                 if (pl.team != NUM_SPECTATOR)
2276                                         break;
2277
2278                         if (pl)
2279                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2280                         else
2281                                 rgb = '1 0 0'; //last: red
2282                         pl = me;
2283                 }
2284
2285                 if (pl == me)
2286                 {
2287                         if (i == first_pl)
2288                                 rgb = '0 1 0'; //first: green
2289                         me_printed = true;
2290                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2291                 }
2292                 if (team_count)
2293                         score_color = Team_ColorRGB(pl.team) * 0.8;
2294                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2295                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2296                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2297                 pos.y += fontsize.y;
2298                 ++i;
2299         }
2300         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2301 }
2302
2303 void HUD_Score(void)
2304 {
2305         if(!autocvar__hud_configure)
2306         {
2307                 if(!autocvar_hud_panel_score) return;
2308                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2309         }
2310
2311         HUD_Panel_UpdateCvars();
2312         vector pos, mySize;
2313         pos = panel_pos;
2314         mySize = panel_size;
2315
2316         HUD_Panel_DrawBg(1);
2317         if(panel_bg_padding)
2318         {
2319                 pos += '1 1 0' * panel_bg_padding;
2320                 mySize -= '2 2 0' * panel_bg_padding;
2321         }
2322
2323         float score, distribution = 0;
2324         string sign;
2325         vector distribution_color;
2326         entity tm, pl, me;
2327
2328         me = playerslots[current_player];
2329
2330         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2331                 string timer, distrtimer;
2332
2333                 pl = players.sort_next;
2334                 if(pl == me)
2335                         pl = pl.sort_next;
2336                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2337                         if(pl.scores[ps_primary] == 0)
2338                                 pl = world;
2339
2340                 score = me.(scores[ps_primary]);
2341                 timer = TIME_ENCODED_TOSTRING(score);
2342
2343                 draw_beginBoldFont();
2344                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2345                         // distribution display
2346                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2347
2348                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2349
2350                         if (distribution <= 0) {
2351                                 distribution_color = '0 1 0';
2352                                 sign = "-";
2353                         }
2354                         else {
2355                                 distribution_color = '1 0 0';
2356                                 sign = "+";
2357                         }
2358                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2359                 }
2360                 // race record display
2361                 if (distribution <= 0)
2362                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2363                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2364                 draw_endBoldFont();
2365         } else if (!teamplay) { // non-teamgames
2366                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2367                 {
2368                         HUD_Score_Rankings(pos, mySize, me);
2369                         return;
2370                 }
2371                 // me vector := [team/connected frags id]
2372                 pl = players.sort_next;
2373                 if(pl == me)
2374                         pl = pl.sort_next;
2375
2376                 if(autocvar__hud_configure)
2377                         distribution = 42;
2378                 else if(pl)
2379                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2380                 else
2381                         distribution = 0;
2382
2383                 score = me.(scores[ps_primary]);
2384                 if(autocvar__hud_configure)
2385                         score = 123;
2386
2387                 if(distribution >= 5)
2388                         distribution_color = eY;
2389                 else if(distribution >= 0)
2390                         distribution_color = '1 1 1';
2391                 else if(distribution >= -5)
2392                         distribution_color = '1 1 0';
2393                 else
2394                         distribution_color = eX;
2395
2396                 string distribution_str;
2397                 distribution_str = ftos(distribution);
2398                 draw_beginBoldFont();
2399                 if (distribution >= 0)
2400                 {
2401                         if (distribution > 0)
2402                                 distribution_str = strcat("+", distribution_str);
2403                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2404                 }
2405                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2406                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2407                 draw_endBoldFont();
2408         } else { // teamgames
2409                 float row, column, rows = 0, columns = 0;
2410                 vector offset = '0 0 0';
2411                 vector score_pos, score_size; //for scores other than myteam
2412                 if(autocvar_hud_panel_score_rankings)
2413                 {
2414                         HUD_Score_Rankings(pos, mySize, me);
2415                         return;
2416                 }
2417                 if(spectatee_status == -1)
2418                 {
2419                         rows = HUD_GetRowCount(team_count, mySize, 3);
2420                         columns = ceil(team_count/rows);
2421                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2422
2423                         float newSize;
2424                         if(score_size.x/score_size.y > 3)
2425                         {
2426                                 newSize = 3 * score_size.y;
2427                                 offset.x = score_size.x - newSize;
2428                                 pos.x += offset.x/2;
2429                                 score_size.x = newSize;
2430                         }
2431                         else
2432                         {
2433                                 newSize = 1/3 * score_size.x;
2434                                 offset.y = score_size.y - newSize;
2435                                 pos.y += offset.y/2;
2436                                 score_size.y = newSize;
2437                         }
2438                 }
2439                 else
2440                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2441
2442                 float max_fragcount;
2443                 max_fragcount = -99;
2444                 draw_beginBoldFont();
2445                 row = column = 0;
2446                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2447                         if(tm.team == NUM_SPECTATOR)
2448                                 continue;
2449                         score = tm.(teamscores[ts_primary]);
2450                         if(autocvar__hud_configure)
2451                                 score = 123;
2452
2453                         if (score > max_fragcount)
2454                                 max_fragcount = score;
2455
2456                         if (spectatee_status == -1)
2457                         {
2458                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2459                                 if (max_fragcount == score)
2460                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2461                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2462                                 ++row;
2463                                 if(row >= rows)
2464                                 {
2465                                         row = 0;
2466                                         ++column;
2467                                 }
2468                         }
2469                         else if(tm.team == myteam) {
2470                                 if (max_fragcount == score)
2471                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2472                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2473                         } else {
2474                                 if (max_fragcount == score)
2475                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2476                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2477                                 ++rows;
2478                         }
2479                 }
2480                 draw_endBoldFont();
2481         }
2482 }
2483
2484 // Race timer (#8)
2485 //
2486 void HUD_RaceTimer (void)
2487 {
2488         if(!autocvar__hud_configure)
2489         {
2490                 if(!autocvar_hud_panel_racetimer) return;
2491                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2492                 if(spectatee_status == -1) return;
2493         }
2494
2495         HUD_Panel_UpdateCvars();
2496
2497         vector pos, mySize;
2498         pos = panel_pos;
2499         mySize = panel_size;
2500
2501         HUD_Panel_DrawBg(1);
2502         if(panel_bg_padding)
2503         {
2504                 pos += '1 1 0' * panel_bg_padding;
2505                 mySize -= '2 2 0' * panel_bg_padding;
2506         }
2507
2508         // always force 4:1 aspect
2509         vector newSize = '0 0 0';
2510         if(mySize.x/mySize.y > 4)
2511         {
2512                 newSize.x = 4 * mySize.y;
2513                 newSize.y = mySize.y;
2514
2515                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2516         }
2517         else
2518         {
2519                 newSize.y = 1/4 * mySize.x;
2520                 newSize.x = mySize.x;
2521
2522                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2523         }
2524         mySize = newSize;
2525
2526         float a, t;
2527         string s, forcetime;
2528
2529         if(autocvar__hud_configure)
2530         {
2531                 s = "0:13:37";
2532                 draw_beginBoldFont();
2533                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2534                 draw_endBoldFont();
2535                 s = _("^1Intermediate 1 (+15.42)");
2536                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2537                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2538                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2539         }
2540         else if(race_checkpointtime)
2541         {
2542                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2543                 s = "";
2544                 forcetime = "";
2545                 if(a > 0) // just hit a checkpoint?
2546                 {
2547                         if(race_checkpoint != 254)
2548                         {
2549                                 if(race_time && race_previousbesttime)
2550                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2551                                 else
2552                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2553                                 if(race_time)
2554                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2555                         }
2556                 }
2557                 else
2558                 {
2559                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2560                         {
2561                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2562                                 if(a > 0) // next one?
2563                                 {
2564                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2565                                 }
2566                         }
2567                 }
2568
2569                 if(s != "" && a > 0)
2570                 {
2571                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2572                 }
2573
2574                 if(race_penaltytime)
2575                 {
2576                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2577                         if(a > 0)
2578                         {
2579                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2580                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2581                         }
2582                 }
2583
2584                 draw_beginBoldFont();
2585
2586                 if(forcetime != "")
2587                 {
2588                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2589                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2590                 }
2591                 else
2592                         a = 1;
2593
2594                 if(race_laptime && race_checkpoint != 255)
2595                 {
2596                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2597                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2598                 }
2599
2600                 draw_endBoldFont();
2601         }
2602         else
2603         {
2604                 if(race_mycheckpointtime)
2605                 {
2606                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2607                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2608                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2609                 }
2610                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2611                 {
2612                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2613                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2614                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2615                 }
2616
2617                 if(race_penaltytime && !race_penaltyaccumulator)
2618                 {
2619                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2620                         a = bound(0, (1 + t - time), 1);
2621                         if(a > 0)
2622                         {
2623                                 if(time < t)
2624                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2625                                 else
2626                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2627                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2628                         }
2629                 }
2630         }
2631 }
2632
2633 // Vote window (#9)
2634 //
2635
2636 void HUD_Vote(void)
2637 {
2638         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2639         {
2640                 vote_active = 1;
2641                 if (autocvar__hud_configure)
2642                 {
2643                         vote_yescount = 0;
2644                         vote_nocount = 0;
2645                         print(_("^1You must answer before entering hud configure mode\n"));
2646                         cvar_set("_hud_configure", "0");
2647                 }
2648                 if(vote_called_vote)
2649                         strunzone(vote_called_vote);
2650                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2651                 uid2name_dialog = 1;
2652         }
2653
2654         if(!autocvar__hud_configure)
2655         {
2656                 if(!autocvar_hud_panel_vote) return;
2657
2658                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2659                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2660
2661                 if(panel_bg_alpha_str == "") {
2662                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2663                 }
2664                 panel_bg_alpha = stof(panel_bg_alpha_str);
2665         }
2666         else
2667         {
2668                 vote_yescount = 3;
2669                 vote_nocount = 2;
2670                 vote_needed = 4;
2671         }
2672
2673         string s;
2674         float a;
2675         if(vote_active != vote_prev) {
2676                 vote_change = time;
2677                 vote_prev = vote_active;
2678         }
2679
2680         if(vote_active || autocvar__hud_configure)
2681                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2682         else
2683                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2684
2685         if(!vote_alpha)
2686                 return;
2687
2688         HUD_Panel_UpdateCvars();
2689
2690         if(uid2name_dialog)
2691         {
2692                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2693                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2694         }
2695
2696     // these must be below above block
2697         vector pos, mySize;
2698         pos = panel_pos;
2699         mySize = panel_size;
2700
2701         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2702         HUD_Panel_DrawBg(a);
2703         a = panel_fg_alpha * a;
2704
2705         if(panel_bg_padding)
2706         {
2707                 pos += '1 1 0' * panel_bg_padding;
2708                 mySize -= '2 2 0' * panel_bg_padding;
2709         }
2710
2711         // always force 3:1 aspect
2712         vector newSize = '0 0 0';
2713         if(mySize.x/mySize.y > 3)
2714         {
2715                 newSize.x = 3 * mySize.y;
2716                 newSize.y = mySize.y;
2717
2718                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2719         }
2720         else
2721         {
2722                 newSize.y = 1/3 * mySize.x;
2723                 newSize.x = mySize.x;
2724
2725                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2726         }
2727         mySize = newSize;
2728
2729         s = _("A vote has been called for:");
2730         if(uid2name_dialog)
2731                 s = _("Allow servers to store and display your name?");
2732         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2733         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2734         if(autocvar__hud_configure)
2735                 s = _("^1Configure the HUD");
2736         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2737
2738         // print the yes/no counts
2739     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2740         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2741     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2742         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2743
2744         // draw the progress bar backgrounds
2745         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2746
2747         // draw the highlights
2748         if(vote_highlighted == 1) {
2749                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2750                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2751         }
2752         else if(vote_highlighted == -1) {
2753                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2754                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2755         }
2756
2757         // draw the progress bars
2758         if(vote_yescount && vote_needed)
2759         {
2760                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2761                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2762         }
2763
2764         if(vote_nocount && vote_needed)
2765         {
2766                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2767                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2768         }
2769
2770         drawresetcliparea();
2771 }
2772
2773 // Mod icons panel (#10)
2774 //
2775
2776 bool mod_active; // is there any active mod icon?
2777
2778 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
2779 {
2780         int stat = -1;
2781         string pic = "";
2782         vector color = '0 0 0';
2783         switch(i)
2784         {
2785                 case 0:
2786                         stat = getstati(STAT_REDALIVE);
2787                         pic = "player_red.tga";
2788                         color = '1 0 0';
2789                         break;
2790                 case 1:
2791                         stat = getstati(STAT_BLUEALIVE);
2792                         pic = "player_blue.tga";
2793                         color = '0 0 1';
2794                         break;
2795                 case 2:
2796                         stat = getstati(STAT_YELLOWALIVE);
2797                         pic = "player_yellow.tga";
2798                         color = '1 1 0';
2799                         break;
2800                 default:
2801                 case 3:
2802                         stat = getstati(STAT_PINKALIVE);
2803                         pic = "player_pink.tga";
2804                         color = '1 0 1';
2805                         break;
2806         }
2807
2808         if(mySize.x/mySize.y > aspect_ratio)
2809         {
2810                 i = aspect_ratio * mySize.y;
2811                 myPos.x = myPos.x + (mySize.x - i) / 2;
2812                 mySize.x = i;
2813         }
2814         else
2815         {
2816                 i = 1/aspect_ratio * mySize.x;
2817                 myPos.y = myPos.y + (mySize.y - i) / 2;
2818                 mySize.y = i;
2819         }
2820
2821         if(layout)
2822         {
2823                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2824                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2825         }
2826         else
2827                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2828 }
2829
2830 // Clan Arena and Freeze Tag HUD modicons
2831 void HUD_Mod_CA(vector myPos, vector mySize)
2832 {
2833         mod_active = 1; // required in each mod function that always shows something
2834
2835         int layout;
2836         if(gametype == MAPINFO_TYPE_CA)
2837                 layout = autocvar_hud_panel_modicons_ca_layout;
2838         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2839                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2840         int rows, columns;
2841         float aspect_ratio;
2842         aspect_ratio = (layout) ? 2 : 1;
2843         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2844         columns = ceil(team_count/rows);
2845
2846         int i;
2847         float row = 0, column = 0;
2848         vector pos, itemSize;
2849         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2850         for(i=0; i<team_count; ++i)
2851         {
2852                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2853
2854                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2855
2856                 ++row;
2857                 if(row >= rows)
2858                 {
2859                         row = 0;
2860                         ++column;
2861                 }
2862         }
2863 }
2864
2865 // CTF HUD modicon section
2866 int redflag_prevframe, blueflag_prevframe, yellowflag_prevframe, pinkflag_prevframe, neutralflag_prevframe; // status during previous frame
2867 int redflag_prevstatus, blueflag_prevstatus, yellowflag_prevstatus, pinkflag_prevstatus, neutralflag_prevstatus; // last remembered status
2868 float redflag_statuschange_time, blueflag_statuschange_time, yellowflag_statuschange_time, pinkflag_statuschange_time, neutralflag_statuschange_time; // time when the status changed
2869
2870 void HUD_Mod_CTF_Reset(void)
2871 {
2872         redflag_prevstatus = blueflag_prevstatus = yellowflag_prevstatus = pinkflag_prevstatus = neutralflag_prevstatus = 0;
2873         redflag_prevframe = blueflag_prevframe = yellowflag_prevframe = pinkflag_prevframe = neutralflag_prevframe = 0;
2874         redflag_statuschange_time = blueflag_statuschange_time = yellowflag_statuschange_time = pinkflag_statuschange_time = neutralflag_statuschange_time = 0;
2875 }
2876
2877 void HUD_Mod_CTF(vector pos, vector mySize)
2878 {
2879         vector redflag_pos, blueflag_pos, yellowflag_pos, pinkflag_pos, neutralflag_pos;
2880         vector flag_size;
2881         float f; // every function should have that
2882
2883         int redflag, blueflag, yellowflag, pinkflag, neutralflag; // current status
2884         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime, yellowflag_statuschange_elapsedtime, pinkflag_statuschange_elapsedtime, neutralflag_statuschange_elapsedtime; // time since the status changed
2885         bool ctf_oneflag; // one-flag CTF mode enabled/disabled
2886         int stat_items = getstati(STAT_CTF_FLAGSTATUS, 0, 24);
2887         float fs, fs2, fs3, size1, size2;
2888         vector e1, e2;
2889
2890         redflag = (stat_items/CTF_RED_FLAG_TAKEN) & 3;
2891         blueflag = (stat_items/CTF_BLUE_FLAG_TAKEN) & 3;
2892         yellowflag = (stat_items/CTF_YELLOW_FLAG_TAKEN) & 3;
2893         pinkflag = (stat_items/CTF_PINK_FLAG_TAKEN) & 3;
2894         neutralflag = (stat_items/CTF_NEUTRAL_FLAG_TAKEN) & 3;
2895
2896         ctf_oneflag = (stat_items & CTF_FLAG_NEUTRAL);
2897
2898         mod_active = (redflag || blueflag || yellowflag || pinkflag || neutralflag);
2899
2900         if (autocvar__hud_configure) {
2901                 redflag = 1;
2902                 blueflag = 2;
2903                 if (team_count >= 3)
2904                         yellowflag = 2;
2905                 if (team_count >= 4)
2906                         pinkflag = 3;
2907                 ctf_oneflag = neutralflag = 0; // disable neutral flag in hud editor?
2908         }
2909
2910         // when status CHANGES, set old status into prevstatus and current status into status
2911         #define X(team) do {                                                                                                                    \
2912                 if (team##flag != team##flag_prevframe) {                                                                       \
2913                 team##flag_statuschange_time = time;                                                                    \
2914                 team##flag_prevstatus = team##flag_prevframe;                                                   \
2915                 team##flag_prevframe = team##flag;                                                                              \
2916         }                                                                                                                                                       \
2917         team##flag_statuschange_elapsedtime = time - team##flag_statuschange_time;      \
2918     } while (0)
2919         X(red);
2920         X(blue);
2921         X(yellow);
2922         X(pink);
2923         X(neutral);
2924         #undef X
2925
2926         const float BLINK_FACTOR = 0.15;
2927         const float BLINK_BASE = 0.85;
2928         // note:
2929         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2930         // thus
2931         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2932         // ensure RMS == 1
2933         const float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2934
2935         #define X(team, cond) \
2936         string team##_icon, team##_icon_prevstatus; \
2937         int team##_alpha, team##_alpha_prevstatus; \
2938         team##_alpha = team##_alpha_prevstatus = 1; \
2939         do { \
2940                 switch (team##flag) { \
2941                         case 1: team##_icon = "flag_" #team "_taken"; break; \
2942                         case 2: team##_icon = "flag_" #team "_lost"; break; \
2943                         case 3: team##_icon = "flag_" #team "_carrying"; team##_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
2944                         default: \
2945                                 if ((stat_items & CTF_SHIELDED) && (cond)) { \
2946                                         team##_icon = "flag_" #team "_shielded"; \
2947                                 } else { \
2948                                         team##_icon = string_null; \
2949                                 } \
2950                                 break; \
2951                 } \
2952                 switch (team##flag_prevstatus) { \
2953                         case 1: team##_icon_prevstatus = "flag_" #team "_taken"; break; \
2954                         case 2: team##_icon_prevstatus = "flag_" #team "_lost"; break; \
2955                         case 3: team##_icon_prevstatus = "flag_" #team "_carrying"; team##_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
2956                         default: \
2957                                 if (team##flag == 3) { \
2958                                         team##_icon_prevstatus = "flag_" #team "_carrying"; /* make it more visible */\
2959                                 } else if((stat_items & CTF_SHIELDED) && (cond)) { \
2960                                         team##_icon_prevstatus = "flag_" #team "_shielded"; \
2961                                 } else { \
2962                                         team##_icon_prevstatus = string_null; \
2963                                 } \
2964                                 break; \
2965                 } \
2966         } while (0)
2967         X(red, myteam != NUM_TEAM_1);
2968         X(blue, myteam != NUM_TEAM_2);
2969         X(yellow, myteam != NUM_TEAM_3);
2970         X(pink, myteam != NUM_TEAM_4);
2971         X(neutral, true);
2972         #undef X
2973
2974         if (ctf_oneflag) {
2975                 // hacky, but these aren't needed
2976                 red_icon = red_icon_prevstatus = blue_icon = blue_icon_prevstatus = yellow_icon = yellow_icon_prevstatus = pink_icon = pink_icon_prevstatus = string_null;
2977                 fs = fs2 = fs3 = 1;
2978         } else switch (team_count) {
2979                 default:
2980                 case 2: fs = 0.5; fs2 = 0.5; fs3 = 0.5; break;
2981                 case 3: fs = 1; fs2 = 0.35; fs3 = 0.35; break;
2982                 case 4: fs = 0.75; fs2 = 0.25; fs3 = 0.5; break;
2983         }
2984
2985         if (mySize_x > mySize_y) {
2986                 size1 = mySize_x;
2987                 size2 = mySize_y;
2988                 e1 = eX;
2989                 e2 = eY;
2990         } else {
2991                 size1 = mySize_y;
2992                 size2 = mySize_x;
2993                 e1 = eY;
2994                 e2 = eX;
2995         }
2996
2997         switch (myteam) {
2998                 default:
2999                 case NUM_TEAM_1: {
3000                         redflag_pos = pos;
3001                         blueflag_pos = pos + eX * fs2 * size1;
3002                         yellowflag_pos = pos - eX * fs2 * size1;
3003                         pinkflag_pos = pos + eX * fs3 * size1;
3004                         break;
3005                 }
3006                 case NUM_TEAM_2: {
3007                         redflag_pos = pos + eX * fs2 * size1;
3008                         blueflag_pos = pos;
3009                         yellowflag_pos = pos - eX * fs2 * size1;
3010                         pinkflag_pos = pos + eX * fs3 * size1;
3011                         break;
3012                 }
3013                 case NUM_TEAM_3: {
3014                         redflag_pos = pos + eX * fs3 * size1;
3015                         blueflag_pos = pos - eX * fs2 * size1;
3016                         yellowflag_pos = pos;
3017                         pinkflag_pos = pos + eX * fs2 * size1;
3018                         break;
3019                 }
3020                 case NUM_TEAM_4: {
3021                         redflag_pos = pos - eX * fs2 * size1;
3022                         blueflag_pos = pos + eX * fs3 * size1;
3023                         yellowflag_pos = pos + eX * fs2 * size1;
3024                         pinkflag_pos = pos;
3025                         break;
3026                 }
3027         }
3028         neutralflag_pos = pos;
3029         flag_size = e1 * fs * size1 + e2 * size2;
3030
3031         #define X(team) do { \
3032                 f = bound(0, team##flag_statuschange_elapsedtime * 2, 1); \
3033                 if (team##_icon_prevstatus && f < 1) \
3034                         drawpic_aspect_skin_expanding(team##flag_pos, team##_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * team##_alpha_prevstatus, DRAWFLAG_NORMAL, f); \
3035                 if (team##_icon) \
3036                         drawpic_aspect_skin(team##flag_pos, team##_icon, flag_size, '1 1 1', panel_fg_alpha * team##_alpha * f, DRAWFLAG_NORMAL); \
3037         } while (0)
3038         X(red);
3039         X(blue);
3040         X(yellow);
3041         X(pink);
3042         X(neutral);
3043         #undef X
3044 }
3045
3046 // Keyhunt HUD modicon section
3047 vector KH_SLOTS[4];
3048
3049 void HUD_Mod_KH(vector pos, vector mySize)
3050 {
3051         mod_active = 1; // keyhunt should never hide the mod icons panel
3052
3053         // Read current state
3054
3055         int state = getstati(STAT_KH_KEYS);
3056         int i, key_state;
3057         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3058         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3059
3060         for(i = 0; i < 4; ++i)
3061         {
3062                 key_state = (bitshift(state, i * -5) & 31) - 1;
3063
3064                 if(key_state == -1)
3065                         continue;
3066
3067                 if(key_state == 30)
3068                 {
3069                         ++carrying_keys;
3070                         key_state = myteam;
3071                 }
3072
3073                 switch(key_state)
3074                 {
3075                         case NUM_TEAM_1: ++team1_keys; break;
3076                         case NUM_TEAM_2: ++team2_keys; break;
3077                         case NUM_TEAM_3: ++team3_keys; break;
3078                         case NUM_TEAM_4: ++team4_keys; break;
3079                         case 29: ++dropped_keys; break;
3080                 }
3081
3082                 ++all_keys;
3083         }
3084
3085         // Calculate slot measurements
3086
3087         vector slot_size;
3088
3089         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3090         {
3091                 // Quadratic arrangement
3092                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3093                 KH_SLOTS[0] = pos;
3094                 KH_SLOTS[1] = pos + eX * slot_size.x;
3095                 KH_SLOTS[2] = pos + eY * slot_size.y;
3096                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3097         }
3098         else
3099         {
3100                 if(mySize.x > mySize.y)
3101                 {
3102                         // Horizontal arrangement
3103                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3104                         for(i = 0; i < all_keys; ++i)
3105                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3106                 }
3107                 else
3108                 {
3109                         // Vertical arrangement
3110                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3111                         for(i = 0; i < all_keys; ++i)
3112                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3113                 }
3114         }
3115
3116         // Make icons blink in case of RUN HERE
3117
3118         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3119         float alpha;
3120         alpha = 1;
3121
3122         if(carrying_keys)
3123                 switch(myteam)
3124                 {
3125                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3126                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3127                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3128                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3129                 }
3130
3131         // Draw icons
3132
3133         i = 0;
3134
3135         while(team1_keys--)
3136                 if(myteam == NUM_TEAM_1 && carrying_keys)
3137                 {
3138                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3139                         --carrying_keys;
3140                 }
3141                 else
3142                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3143
3144         while(team2_keys--)
3145                 if(myteam == NUM_TEAM_2 && carrying_keys)
3146                 {
3147                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3148                         --carrying_keys;
3149                 }
3150                 else
3151                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3152
3153         while(team3_keys--)
3154                 if(myteam == NUM_TEAM_3 && carrying_keys)
3155                 {
3156                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3157                         --carrying_keys;
3158                 }
3159                 else
3160                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3161
3162         while(team4_keys--)
3163                 if(myteam == NUM_TEAM_4 && carrying_keys)
3164                 {
3165                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3166                         --carrying_keys;
3167                 }
3168                 else
3169                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3170
3171         while(dropped_keys--)
3172                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3173 }
3174
3175 // Keepaway HUD mod icon
3176 int kaball_prevstatus; // last remembered status
3177 float kaball_statuschange_time; // time when the status changed
3178
3179 // we don't need to reset for keepaway since it immediately
3180 // autocorrects prevstatus as to if the player has the ball or not
3181
3182 void HUD_Mod_Keepaway(vector pos, vector mySize)
3183 {
3184         mod_active = 1; // keepaway should always show the mod HUD
3185
3186         float BLINK_FACTOR = 0.15;
3187         float BLINK_BASE = 0.85;
3188         float BLINK_FREQ = 5;
3189         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3190
3191         int stat_items = getstati(STAT_ITEMS, 0, 24);
3192         int kaball = (stat_items/IT_KEY1) & 1;
3193
3194         if(kaball != kaball_prevstatus)
3195         {
3196                 kaball_statuschange_time = time;
3197                 kaball_prevstatus = kaball;
3198         }
3199
3200         vector kaball_pos, kaball_size;
3201
3202         if(mySize.x > mySize.y) {
3203                 kaball_pos = pos + eX * 0.25 * mySize.x;
3204                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3205         } else {
3206                 kaball_pos = pos + eY * 0.25 * mySize.y;
3207                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3208         }
3209
3210         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3211         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3212
3213         if(kaball_prevstatus && f < 1)
3214                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3215
3216         if(kaball)
3217                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3218 }
3219
3220
3221 // Nexball HUD mod icon
3222 void HUD_Mod_NexBall(vector pos, vector mySize)
3223 {
3224         float nb_pb_starttime, dt, p;
3225         int stat_items;
3226
3227         stat_items = getstati(STAT_ITEMS, 0, 24);
3228         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3229
3230         if (stat_items & IT_KEY1)
3231                 mod_active = 1;
3232         else
3233                 mod_active = 0;
3234
3235         //Manage the progress bar if any
3236         if (nb_pb_starttime > 0)
3237         {
3238                 dt = (time - nb_pb_starttime) % nb_pb_period;
3239                 // one period of positive triangle
3240                 p = 2 * dt / nb_pb_period;
3241                 if (p > 1)
3242                         p = 2 - p;
3243
3244                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3245         }
3246
3247         if (stat_items & IT_KEY1)
3248                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3249 }
3250
3251 // Race/CTS HUD mod icons
3252 float crecordtime_prev; // last remembered crecordtime
3253 float crecordtime_change_time; // time when crecordtime last changed
3254 float srecordtime_prev; // last remembered srecordtime
3255 float srecordtime_change_time; // time when srecordtime last changed
3256
3257 float race_status_time;
3258 int race_status_prev;
3259 string race_status_name_prev;
3260 void HUD_Mod_Race(vector pos, vector mySize)
3261 {
3262         mod_active = 1; // race should never hide the mod icons panel
3263         entity me;
3264         me = playerslots[player_localnum];
3265         float t, score;
3266         float f; // yet another function has this
3267         score = me.(scores[ps_primary]);
3268
3269         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3270                 return; // no records in the actual race
3271
3272         // clientside personal record
3273         string rr;
3274         if(gametype == MAPINFO_TYPE_CTS)
3275                 rr = CTS_RECORD;
3276         else
3277                 rr = RACE_RECORD;
3278         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3279
3280         if(score && (score < t || !t)) {
3281                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3282                 if(autocvar_cl_autodemo_delete_keeprecords)
3283                 {
3284                         f = autocvar_cl_autodemo_delete;
3285                         f &= ~1;
3286                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3287                 }
3288         }
3289
3290         if(t != crecordtime_prev) {
3291                 crecordtime_prev = t;
3292                 crecordtime_change_time = time;
3293         }
3294
3295         vector textPos, medalPos;
3296         float squareSize;
3297         if(mySize.x > mySize.y) {
3298                 // text on left side
3299                 squareSize = min(mySize.y, mySize.x/2);
3300                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3301                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3302         } else {
3303                 // text on top
3304                 squareSize = min(mySize.x, mySize.y/2);
3305                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3306                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3307         }
3308
3309         f = time - crecordtime_change_time;
3310
3311         if (f > 1) {
3312                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3313                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3314         } else {
3315                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3316                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3317                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3318                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3319         }
3320
3321         // server record
3322         t = race_server_record;
3323         if(t != srecordtime_prev) {
3324                 srecordtime_prev = t;
3325                 srecordtime_change_time = time;
3326         }
3327         f = time - srecordtime_change_time;
3328
3329         if (f > 1) {
3330                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3331                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3332         } else {
3333                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3334                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3335                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3336                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3337         }
3338
3339         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3340                 race_status_time = time + 5;
3341                 race_status_prev = race_status;
3342                 if (race_status_name_prev)
3343                         strunzone(race_status_name_prev);
3344                 race_status_name_prev = strzone(race_status_name);
3345         }
3346
3347         // race "awards"
3348         float a;
3349         a = bound(0, race_status_time - time, 1);
3350
3351         string s;
3352         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3353
3354         float rank;
3355         if(race_status > 0)
3356                 rank = race_CheckName(race_status_name);
3357         else
3358                 rank = 0;
3359         string rankname;
3360         rankname = count_ordinal(rank);
3361
3362         vector namepos;
3363         namepos = medalPos + '0 0.8 0' * squareSize;
3364         vector rankpos;
3365         rankpos = medalPos + '0 0.15 0' * squareSize;
3366
3367         if(race_status == 0)
3368                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3369         else if(race_status == 1) {
3370                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3371                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3372                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3373         } else if(race_status == 2) {
3374                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3375                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3376                 else
3377                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3378                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3379                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3380         } else if(race_status == 3) {
3381                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3382                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3383                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3384         }
3385
3386         if (race_status_time - time <= 0) {
3387                 race_status_prev = -1;
3388                 race_status = -1;
3389                 if(race_status_name)
3390                         strunzone(race_status_name);
3391                 race_status_name = string_null;
3392                 if(race_status_name_prev)
3393                         strunzone(race_status_name_prev);
3394                 race_status_name_prev = string_null;
3395         }
3396 }
3397
3398 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
3399 {
3400         float stat = -1;
3401         string pic = "";
3402         vector color = '0 0 0';
3403         switch(i)
3404         {
3405                 case 0:
3406                         stat = getstatf(STAT_DOM_PPS_RED);
3407                         pic = "dom_icon_red";
3408                         color = '1 0 0';
3409                         break;
3410                 case 1:
3411                         stat = getstatf(STAT_DOM_PPS_BLUE);
3412                         pic = "dom_icon_blue";
3413                         color = '0 0 1';
3414                         break;
3415                 case 2:
3416                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3417                         pic = "dom_icon_yellow";
3418                         color = '1 1 0';
3419                         break;
3420                 default:
3421                 case 3:
3422                         stat = getstatf(STAT_DOM_PPS_PINK);
3423                         pic = "dom_icon_pink";
3424                         color = '1 0 1';
3425                         break;
3426         }
3427         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3428
3429         if(mySize.x/mySize.y > aspect_ratio)
3430         {
3431                 i = aspect_ratio * mySize.y;
3432                 myPos.x = myPos.x + (mySize.x - i) / 2;
3433                 mySize.x = i;
3434         }
3435         else
3436         {
3437                 i = 1/aspect_ratio * mySize.x;
3438                 myPos.y = myPos.y + (mySize.y - i) / 2;
3439                 mySize.y = i;
3440         }
3441
3442         if (layout) // show text too
3443         {
3444                 //draw the text
3445                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3446                 if (layout == 2) // average pps
3447                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3448                 else // percentage of average pps
3449                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3450         }
3451
3452         //draw the icon
3453         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3454         if (stat > 0)
3455         {
3456                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3457                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3458                 drawresetcliparea();
3459         }
3460 }
3461
3462 void HUD_Mod_Dom(vector myPos, vector mySize)
3463 {
3464         mod_active = 1; // required in each mod function that always shows something
3465
3466         int layout = autocvar_hud_panel_modicons_dom_layout;
3467         int rows, columns;
3468         float aspect_ratio;
3469         aspect_ratio = (layout) ? 3 : 1;
3470         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3471         columns = ceil(team_count/rows);
3472
3473         int i;
3474         float row = 0, column = 0;
3475         vector pos, itemSize;
3476         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3477         for(i=0; i<team_count; ++i)
3478         {
3479                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3480
3481                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3482
3483                 ++row;
3484                 if(row >= rows)
3485                 {
3486                         row = 0;
3487                         ++column;
3488                 }
3489         }
3490 }
3491
3492 void HUD_ModIcons_SetFunc()
3493 {
3494         switch(gametype)
3495         {
3496                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3497                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3498                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3499                 case MAPINFO_TYPE_CTS:
3500                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3501                 case MAPINFO_TYPE_CA:
3502                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3503                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3504                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3505         }
3506 }
3507
3508 int mod_prev; // previous state of mod_active to check for a change
3509 float mod_alpha;
3510 float mod_change; // "time" when mod_active changed
3511
3512 void HUD_ModIcons(void)
3513 {
3514         if(!autocvar__hud_configure)
3515         {
3516                 if(!autocvar_hud_panel_modicons) return;
3517                 if(!HUD_ModIcons_GameType) return;
3518         }
3519
3520         HUD_Panel_UpdateCvars();
3521
3522         draw_beginBoldFont();
3523
3524         if(mod_active != mod_prev) {
3525                 mod_change = time;
3526                 mod_prev = mod_active;
3527         }
3528
3529         if(mod_active || autocvar__hud_configure)
3530                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3531         else
3532                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3533
3534         if(mod_alpha)
3535                 HUD_Panel_DrawBg(mod_alpha);
3536
3537         if(panel_bg_padding)
3538         {
3539                 panel_pos += '1 1 0' * panel_bg_padding;
3540                 panel_size -= '2 2 0' * panel_bg_padding;
3541         }
3542
3543         if(autocvar__hud_configure)
3544                 HUD_Mod_CTF(panel_pos, panel_size);
3545         else
3546                 HUD_ModIcons_GameType(panel_pos, panel_size);
3547
3548         draw_endBoldFont();
3549 }
3550
3551 // Draw pressed keys (#11)
3552 //
3553 void HUD_PressedKeys(void)
3554 {
3555         if(!autocvar__hud_configure)
3556         {
3557                 if(!autocvar_hud_panel_pressedkeys) return;
3558                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3559         }
3560
3561         HUD_Panel_UpdateCvars();
3562         vector pos, mySize;
3563         pos = panel_pos;
3564         mySize = panel_size;
3565
3566         HUD_Panel_DrawBg(1);
3567         if(panel_bg_padding)
3568         {
3569                 pos += '1 1 0' * panel_bg_padding;
3570                 mySize -= '2 2 0' * panel_bg_padding;
3571         }
3572
3573         // force custom aspect
3574         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3575         if(aspect)
3576         {
3577                 vector newSize = '0 0 0';
3578                 if(mySize.x/mySize.y > aspect)
3579                 {
3580                         newSize.x = aspect * mySize.y;
3581                         newSize.y = mySize.y;
3582
3583                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3584                 }
3585                 else
3586                 {
3587                         newSize.y = 1/aspect * mySize.x;
3588                         newSize.x = mySize.x;
3589
3590                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3591                 }
3592                 mySize = newSize;
3593         }
3594
3595         vector keysize;
3596         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3597         float pressedkeys;
3598         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3599
3600         if(autocvar_hud_panel_pressedkeys_attack)
3601         {
3602                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3603                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3604                 pos.y += keysize.y;
3605         }
3606
3607         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3608         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3609         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3610         pos.y += keysize.y;
3611         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3612         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3613         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3614 }
3615
3616 // Handle chat as a panel (#12)
3617 //
3618 void HUD_Chat(void)
3619 {
3620         if(!autocvar__hud_configure)
3621         {
3622                 if (!autocvar_hud_panel_chat)
3623                 {
3624                         if (!autocvar_con_chatrect)
3625                                 cvar_set("con_chatrect", "0");
3626                         return;
3627                 }
3628                 if(autocvar__con_chat_maximized)
3629                 {
3630                         if(!hud_draw_maximized) return;
3631                 }
3632                 else if(chat_panel_modified)
3633                 {
3634                         panel.update_time = time; // forces reload of panel attributes
3635                         chat_panel_modified = false;
3636                 }
3637         }
3638
3639         HUD_Panel_UpdateCvars();
3640
3641         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3642         {
3643                 panel_pos.y = panel_bg_border;
3644                 panel_size.y = vid_conheight - panel_bg_border * 2;
3645                 if(panel.current_panel_bg == "0") // force a border when maximized
3646                 {
3647                         string panel_bg;
3648                         panel_bg = strcat(hud_skin_path, "/border_default");
3649                         if(precache_pic(panel_bg) == "")
3650                                 panel_bg = "gfx/hud/default/border_default";
3651                         if(panel.current_panel_bg)
3652                                 strunzone(panel.current_panel_bg);
3653                         panel.current_panel_bg = strzone(panel_bg);
3654                         chat_panel_modified = true;
3655                 }
3656                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3657         }
3658
3659         vector pos, mySize;
3660         pos = panel_pos;
3661         mySize = panel_size;
3662
3663         HUD_Panel_DrawBg(1);
3664
3665         if(panel_bg_padding)
3666         {
3667                 pos += '1 1 0' * panel_bg_padding;
3668                 mySize -= '2 2 0' * panel_bg_padding;
3669         }
3670
3671         if (!autocvar_con_chatrect)
3672                 cvar_set("con_chatrect", "1");
3673
3674         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3675         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3676
3677         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3678         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3679
3680         if(autocvar__hud_configure)
3681         {
3682                 vector chatsize;
3683                 chatsize = '1 1 0' * autocvar_con_chatsize;
3684                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3685                 float i, a;
3686                 for(i = 0; i < autocvar_con_chat; ++i)
3687                 {
3688                         if(i == autocvar_con_chat - 1)
3689                                 a = panel_fg_alpha;
3690                         else
3691                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3692                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3693                         pos.y += chatsize.y;
3694                 }
3695         }
3696 }
3697
3698 // Engine info panel (#13)
3699 //
3700 float prevfps;
3701 float prevfps_time;
3702 int framecounter;
3703
3704 float frametimeavg;
3705 float frametimeavg1; // 1 frame ago
3706 float frametimeavg2; // 2 frames ago
3707 void HUD_EngineInfo(void)
3708 {
3709         if(!autocvar__hud_configure)
3710         {
3711                 if(!autocvar_hud_panel_engineinfo) return;
3712         }
3713
3714         HUD_Panel_UpdateCvars();
3715         vector pos, mySize;
3716         pos = panel_pos;
3717         mySize = panel_size;
3718
3719         HUD_Panel_DrawBg(1);
3720         if(panel_bg_padding)
3721         {
3722                 pos += '1 1 0' * panel_bg_padding;
3723                 mySize -= '2 2 0' * panel_bg_padding;
3724         }
3725
3726         float currentTime = gettime(GETTIME_REALTIME);
3727         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3728         {
3729                 float currentframetime = currentTime - prevfps_time;
3730                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3731                 frametimeavg2 = frametimeavg1;
3732                 frametimeavg1 = frametimeavg;
3733
3734                 float weight;
3735                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3736                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3737                 {
3738                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3739                                 prevfps = (1/currentframetime);
3740                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3741                 }
3742                 prevfps_time = currentTime;
3743         }
3744         else
3745         {
3746                 framecounter += 1;
3747                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3748                 {
3749                         prevfps = framecounter/(currentTime - prevfps_time);
3750                         framecounter = 0;
3751                         prevfps_time = currentTime;
3752                 }
3753         }
3754
3755         vector color;
3756         color = HUD_Get_Num_Color (prevfps, 100);
3757         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3758 }
3759
3760 // Info messages panel (#14)
3761 //
3762 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3763         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3764                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3765         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3766         o.y += fontsize.y;                                                                                                                                                                                              \
3767 } while(0)
3768 void HUD_InfoMessages(void)
3769 {
3770         if(!autocvar__hud_configure)
3771         {
3772                 if(!autocvar_hud_panel_infomessages) return;
3773         }
3774
3775         HUD_Panel_UpdateCvars();
3776         vector pos, mySize;
3777         pos = panel_pos;
3778         mySize = panel_size;
3779
3780         HUD_Panel_DrawBg(1);
3781         if(panel_bg_padding)
3782         {
3783                 pos += '1 1 0' * panel_bg_padding;
3784                 mySize -= '2 2 0' * panel_bg_padding;
3785         }
3786
3787         // always force 5:1 aspect
3788         vector newSize = '0 0 0';
3789         if(mySize.x/mySize.y > 5)
3790         {
3791                 newSize.x = 5 * mySize.y;
3792                 newSize.y = mySize.y;
3793
3794                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3795         }
3796         else
3797         {
3798                 newSize.y = 1/5 * mySize.x;
3799                 newSize.x = mySize.x;
3800
3801                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3802         }
3803
3804         mySize = newSize;
3805         entity tm;
3806         vector o;
3807         o = pos;
3808
3809         vector fontsize;
3810         fontsize = '0.20 0.20 0' * mySize.y;
3811
3812         float a;
3813         a = panel_fg_alpha;
3814
3815         string s;
3816         if(!autocvar__hud_configure)
3817         {
3818                 if(spectatee_status && !intermission)
3819                 {
3820                         a = 1;
3821                         if(spectatee_status == -1)
3822                                 s = _("^1Observing");
3823                         else
3824                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(current_player));
3825                         drawInfoMessage(s);
3826
3827                         if(spectatee_status == -1)
3828                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3829                         else
3830                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3831                         drawInfoMessage(s);
3832
3833                         if(spectatee_status == -1)
3834                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3835                         else
3836                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3837                         drawInfoMessage(s);
3838
3839                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3840                         drawInfoMessage(s);
3841
3842                         if(gametype == MAPINFO_TYPE_LMS)
3843                         {
3844                                 entity sk;
3845                                 sk = playerslots[player_localnum];
3846                                 if(sk.(scores[ps_primary]) >= 666)
3847                                         s = _("^1Match has already begun");
3848                                 else if(sk.(scores[ps_primary]) > 0)
3849                                         s = _("^1You have no more lives left");
3850                                 else
3851                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3852                         }
3853                         else
3854                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3855                         drawInfoMessage(s);
3856
3857                         //show restart countdown:
3858                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3859                                 float countdown;
3860                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3861                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3862                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3863                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3864                                 o.y += fontsize.y;
3865                         }
3866                 }
3867                 if(warmup_stage && !intermission)
3868                 {
3869                         s = _("^2Currently in ^1warmup^2 stage!");
3870                         drawInfoMessage(s);
3871                 }
3872
3873                 string blinkcolor;
3874                 if(time % 1 >= 0.5)
3875                         blinkcolor = "^1";
3876                 else
3877                         blinkcolor = "^3";
3878
3879                 if(ready_waiting && !intermission && !spectatee_status)
3880                 {
3881                         if(ready_waiting_for_me)
3882                         {
3883                                 if(warmup_stage)
3884                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3885                                 else
3886                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3887                         }
3888                         else
3889                         {
3890                                 if(warmup_stage)
3891                                         s = _("^2Waiting for others to ready up to end warmup...");
3892                                 else
3893                                         s = _("^2Waiting for others to ready up...");
3894                         }
3895                         drawInfoMessage(s);
3896                 }
3897                 else if(warmup_stage && !intermission && !spectatee_status)
3898                 {
3899                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3900                         drawInfoMessage(s);
3901                 }
3902
3903                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3904                 {
3905                         float ts_min = 0, ts_max = 0;
3906                         tm = teams.sort_next;
3907                         if (tm)
3908                         {
3909                                 for (; tm.sort_next; tm = tm.sort_next)
3910                                 {
3911                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3912                                                 continue;
3913                                         if(!ts_min) ts_min = tm.team_size;
3914                                         else ts_min = min(ts_min, tm.team_size);
3915                                         if(!ts_max) ts_max = tm.team_size;
3916                                         else ts_max = max(ts_max, tm.team_size);
3917                                 }
3918                                 if ((ts_max - ts_min) > 1)
3919                                 {
3920                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3921                                         tm = GetTeam(myteam, false);
3922                                         if (tm)
3923                                         if (tm.team != NUM_SPECTATOR)
3924                                         if (tm.team_size == ts_max)
3925                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3926                                         drawInfoMessage(s);
3927                                 }
3928                         }
3929                 }
3930         }
3931         else
3932         {
3933                 s = _("^7Press ^3ESC ^7to show HUD options.");
3934                 drawInfoMessage(s);
3935                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3936                 drawInfoMessage(s);
3937                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3938                 drawInfoMessage(s);
3939                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3940                 drawInfoMessage(s);
3941         }
3942 }
3943
3944 // Physics panel (#15)
3945 //
3946 vector acc_prevspeed;
3947 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3948 float physics_update_time, discrete_speed, discrete_acceleration;
3949 void HUD_Physics(void)
3950 {
3951         if(!autocvar__hud_configure)
3952         {
3953                 if(!autocvar_hud_panel_physics) return;
3954                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3955                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3956         }
3957
3958         HUD_Panel_UpdateCvars();
3959
3960         draw_beginBoldFont();
3961
3962         HUD_Panel_DrawBg(1);
3963         if(panel_bg_padding)
3964         {
3965                 panel_pos += '1 1 0' * panel_bg_padding;
3966                 panel_size -= '2 2 0' * panel_bg_padding;
3967         }
3968
3969         float acceleration_progressbar_scale = 0;
3970         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3971                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3972
3973         float text_scale;
3974         if (autocvar_hud_panel_physics_text_scale <= 0)
3975                 text_scale = 1;
3976         else
3977                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3978
3979         //compute speed
3980         float speed, conversion_factor;
3981         string unit;
3982
3983         switch(autocvar_hud_panel_physics_speed_unit)
3984         {
3985                 default:
3986                 case 1:
3987                         unit = _(" qu/s");
3988                         conversion_factor = 1.0;
3989                         break;
3990                 case 2:
3991                         unit = _(" m/s");
3992                         conversion_factor = 0.0254;
3993                         break;
3994                 case 3:
3995                         unit = _(" km/h");
3996                         conversion_factor = 0.0254 * 3.6;
3997                         break;
3998                 case 4:
3999                         unit = _(" mph");
4000                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
4001                         break;
4002                 case 5:
4003                         unit = _(" knots");
4004                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
4005                         break;
4006         }
4007
4008         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
4009
4010         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
4011         if (autocvar__hud_configure)
4012                 speed = floor( max_speed * 0.65 + 0.5 );
4013         else if(autocvar_hud_panel_physics_speed_vertical)
4014                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
4015         else
4016                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
4017
4018         //compute acceleration
4019         float acceleration, f;
4020         if (autocvar__hud_configure)
4021                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
4022         else
4023         {
4024                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
4025                 f = time - acc_prevtime;
4026                 if(autocvar_hud_panel_physics_acceleration_vertical)
4027                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
4028                 else
4029                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
4030
4031                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
4032
4033                 acc_prevspeed = vel;
4034                 acc_prevtime = time;
4035
4036                 if(autocvar_hud_panel_physics_acceleration_movingaverage)
4037                 {
4038                         f = bound(0, f * 10, 1);
4039                         acc_avg = acc_avg * (1 - f) + acceleration * f;
4040                         acceleration = acc_avg;
4041                 }
4042         }
4043
4044         int acc_decimals = 2;
4045         if(time > physics_update_time)
4046         {
4047                 // workaround for ftos_decimals returning a negative 0
4048                 if(discrete_acceleration > -1 / pow(10, acc_decimals) && discrete_acceleration < 0)
4049                         discrete_acceleration = 0;
4050                 discrete_acceleration = acceleration;
4051                 discrete_speed = speed;
4052                 physics_update_time += autocvar_hud_panel_physics_update_interval;
4053         }
4054
4055         //compute layout
4056         float panel_ar = panel_size.x/panel_size.y;
4057         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
4058         if (panel_ar >= 5 && !acceleration_progressbar_scale)
4059         {
4060                 panel_size.x *= 0.5;
4061                 if (autocvar_hud_panel_physics_flip)
4062                         speed_offset.x = panel_size.x;
4063                 else
4064                         acceleration_offset.x = panel_size.x;
4065         }
4066         else
4067         {
4068                 panel_size.y *= 0.5;
4069                 if (autocvar_hud_panel_physics_flip)
4070                         speed_offset.y = panel_size.y;
4071                 else
4072                         acceleration_offset.y = panel_size.y;
4073         }
4074         int speed_baralign, acceleration_baralign;
4075         if (autocvar_hud_panel_physics_baralign == 1)
4076                 acceleration_baralign = speed_baralign = 1;
4077     else if(autocvar_hud_panel_physics_baralign == 4)
4078                 acceleration_baralign = speed_baralign = 2;
4079         else if (autocvar_hud_panel_physics_flip)
4080         {
4081                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
4082                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
4083         }
4084         else
4085         {
4086                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
4087                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
4088         }
4089         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
4090                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
4091
4092         //draw speed
4093         if(speed)
4094         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4095                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4096         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
4097         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4098         {
4099                 tmp_size.x = panel_size.x * 0.75;
4100                 tmp_size.y = panel_size.y * text_scale;
4101                 if (speed_baralign)
4102                         tmp_offset.x = panel_size.x - tmp_size.x;
4103                 //else
4104                         //tmp_offset_x = 0;
4105                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4106                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(discrete_speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4107
4108                 //draw speed unit
4109                 if (speed_baralign)
4110                         tmp_offset.x = 0;
4111                 else
4112                         tmp_offset.x = tmp_size.x;
4113                 if (autocvar_hud_panel_physics_speed_unit_show)
4114                 {
4115                         //tmp_offset_y = 0;
4116                         tmp_size.x = panel_size.x * (1 - 0.75);
4117                         tmp_size.y = panel_size.y * 0.4 * text_scale;
4118                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
4119                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4120                 }
4121         }
4122
4123         //compute and draw top speed
4124         if (autocvar_hud_panel_physics_topspeed)
4125         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4126         {
4127                 if (autocvar__hud_configure)
4128                 {
4129                         top_speed = floor( max_speed * 0.75 + 0.5 );
4130                         f = 1;
4131                 }
4132                 else
4133                 {
4134                         if (speed >= top_speed)
4135                         {
4136                                 top_speed = speed;
4137                                 top_speed_time = time;
4138                         }
4139                         if (top_speed != 0)
4140                         {
4141                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4142                                 // divide by f to make it start from 1
4143                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4144                         }
4145             else //hide top speed 0, it would be stupid
4146                                 f = 0;
4147                 }
4148                 if (f > 0)
4149                 {
4150                         //top speed progressbar peak
4151                         if(speed < top_speed)
4152                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4153                         {
4154                                 float peak_offsetX;
4155                                 vector peak_size = '0 0 0';
4156                                 if (speed_baralign == 0)
4157                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4158                 else if (speed_baralign == 1)
4159                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4160                 else // if (speed_baralign == 2)
4161                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4162                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4163                 peak_size.y = panel_size.y;
4164                 if (speed_baralign == 2) // draw two peaks, on both sides
4165                 {
4166                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4167                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4168                 }
4169                 else
4170                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4171                         }
4172
4173                         //top speed
4174                         tmp_offset.y = panel_size.y * 0.4;
4175                         tmp_size.x = panel_size.x * (1 - 0.75);
4176                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4177                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4178                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4179                 }
4180                 else
4181                         top_speed = 0;
4182         }
4183
4184         //draw acceleration
4185         if(acceleration)
4186         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4187         {
4188                 vector progressbar_color;
4189                 if(acceleration < 0)
4190                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4191                 else
4192                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4193
4194                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4195                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4196                         f = (f >= 0 ? sqrt(f) : -sqrt(-f));
4197
4198                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4199                 {
4200                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4201
4202                         if (acceleration_baralign == 1)
4203                                 tmp_offset.x = panel_size.x - tmp_size.x;
4204                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4205                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4206                         else
4207                                 tmp_offset.x = 0;
4208                         tmp_offset.y = 0;
4209                 }
4210                 else
4211                 {
4212                         tmp_size = panel_size;
4213                         tmp_offset = '0 0 0';
4214                 }
4215
4216                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4217         }
4218
4219         if(autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4220         {
4221                 tmp_size.x = panel_size.x;
4222                 tmp_size.y = panel_size.y * text_scale;
4223                 tmp_offset.x = 0;
4224                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4225
4226                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(discrete_acceleration, acc_decimals), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4227         }
4228
4229         draw_endBoldFont();
4230 }
4231
4232 // CenterPrint (#16)
4233 //
4234 const int CENTERPRINT_MAX_MSGS = 10;
4235 const int CENTERPRINT_MAX_ENTRIES = 50;
4236 const float CENTERPRINT_SPACING = 0.7;
4237 int cpm_index;
4238 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4239 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
4240 float centerprint_time[CENTERPRINT_MAX_MSGS];
4241 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4242 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4243 bool centerprint_showing;
4244
4245 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
4246 {
4247         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4248         int i, j;
4249
4250         if(strMessage == "" && new_id == 0)
4251                 return;
4252
4253         // strip trailing newlines
4254         j = strlen(strMessage) - 1;
4255         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4256                 --j;
4257         if (j < strlen(strMessage) - 1)
4258                 strMessage = substring(strMessage, 0, j + 1);
4259
4260         if(strMessage == "" && new_id == 0)
4261                 return;
4262
4263         // strip leading newlines
4264         j = 0;
4265         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4266                 ++j;
4267         if (j > 0)
4268                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4269
4270         if(strMessage == "" && new_id == 0)
4271                 return;
4272
4273         if (!centerprint_showing)
4274                 centerprint_showing = true;
4275
4276         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4277         {
4278                 if (j == CENTERPRINT_MAX_MSGS)
4279                         j = 0;
4280                 if (new_id && new_id == centerprint_msgID[j])
4281                 {
4282                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4283                         {
4284                                 // fade out the current msg (duration and countdown_num are ignored)
4285                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4286                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4287                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4288                                 return;
4289                         }
4290                         break; // found a msg with the same id, at position j
4291                 }
4292         }
4293
4294         if (i == CENTERPRINT_MAX_MSGS)
4295         {
4296                 // a msg with the same id was not found, add the msg at the next position
4297                 --cpm_index;
4298                 if (cpm_index == -1)
4299                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4300                 j = cpm_index;
4301         }
4302         if(centerprint_messages[j])
4303                 strunzone(centerprint_messages[j]);
4304         centerprint_messages[j] = strzone(strMessage);
4305         centerprint_msgID[j] = new_id;
4306         if (duration < 0)
4307         {
4308                 centerprint_time[j] = -1;
4309                 centerprint_expire_time[j] = time;
4310         }
4311         else
4312         {
4313                 if(duration == 0)
4314                         duration = max(1, autocvar_hud_panel_centerprint_time);
4315                 centerprint_time[j] = duration;
4316                 centerprint_expire_time[j] = time + duration;
4317         }
4318         centerprint_countdown_num[j] = countdown_num;
4319 }
4320
4321 void centerprint_hud(string strMessage)
4322 {
4323         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4324 }
4325
4326 void reset_centerprint_messages(void)
4327 {
4328         int i;
4329         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4330         {
4331                 centerprint_expire_time[i] = 0;
4332                 centerprint_time[i] = 1;
4333                 centerprint_msgID[i] = 0;
4334                 if(centerprint_messages[i])
4335                         strunzone(centerprint_messages[i]);
4336                 centerprint_messages[i] = string_null;
4337         }
4338 }
4339 float hud_configure_cp_generation_time;
4340 void HUD_CenterPrint (void)
4341 {
4342         if(!autocvar__hud_configure)
4343         {
4344                 if(!autocvar_hud_panel_centerprint) return;
4345
4346                 if(hud_configure_prev)
4347                         reset_centerprint_messages();
4348         }
4349         else
4350         {
4351                 if(!hud_configure_prev)
4352                         reset_centerprint_messages();
4353                 if (time > hud_configure_cp_generation_time)
4354                 {
4355                         if(HUD_PANEL(CENTERPRINT) == highlightedPanel)
4356                         {
4357                                 float r;
4358                                 r = random();
4359                                 if (r > 0.8)
4360                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4361                                 else if (r > 0.55)
4362                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4363                                 else
4364                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4365                                 hud_configure_cp_generation_time = time + 1 + random()*4;
4366                         }
4367                         else
4368                         {
4369                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
4370                                 hud_configure_cp_generation_time = time + 10 - random()*3;
4371                         }
4372                 }
4373         }
4374
4375         // this panel fades only when the menu does
4376         float hud_fade_alpha_save = 0;
4377         if(scoreboard_fade_alpha)
4378         {
4379                 hud_fade_alpha_save = hud_fade_alpha;
4380                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4381         }
4382         HUD_Panel_UpdateCvars();
4383
4384         if(scoreboard_fade_alpha)
4385         {
4386                 hud_fade_alpha = hud_fade_alpha_save;
4387
4388                 // move the panel below the scoreboard
4389                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4390                         return;
4391                 vector target_pos;
4392
4393                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4394
4395                 if(target_pos.y > panel_pos.y)
4396                 {
4397                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4398                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4399                 }
4400         }
4401
4402         HUD_Panel_DrawBg(1);
4403
4404         if (!centerprint_showing)
4405                 return;
4406
4407         if(panel_bg_padding)
4408         {
4409                 panel_pos += '1 1 0' * panel_bg_padding;
4410                 panel_size -= '2 2 0' * panel_bg_padding;
4411         }
4412
4413         int entries;
4414         float height;
4415         vector fontsize;
4416         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4417         // height = panel_size_y/entries;
4418         // fontsize = '1 1 0' * height;
4419         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4420         fontsize = '1 1 0' * height;
4421         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4422
4423         int i, j, k, n, g;
4424         float a, sz, align, current_msg_posY = 0, msg_size;
4425         vector pos;
4426         string ts;
4427         bool all_messages_expired = true;
4428
4429         pos = panel_pos;
4430         if (autocvar_hud_panel_centerprint_flip)
4431                 pos.y += panel_size.y;
4432         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4433         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4434         {
4435                 if (j == CENTERPRINT_MAX_MSGS)
4436                         j = 0;
4437                 if (centerprint_expire_time[j] <= time)
4438                 {
4439                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4440                         {
4441                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4442                                 if (centerprint_countdown_num[j] == 0)
4443                                         continue;
4444                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4445                         }
4446                         else if(centerprint_time[j] != -1)
4447                                 continue;
4448                 }
4449
4450                 all_messages_expired = false;
4451
4452                 // fade the centerprint_hud in/out
4453                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4454                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4455                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4456                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4457                 else // Expiring soon, so fade it out.
4458                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4459
4460                 // while counting down show it anyway in order to hold the current message position
4461                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4462                         continue;
4463                 if (a > 1)
4464                         a = 1;
4465
4466                 // set the size from fading in/out before subsequent fading
4467                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4468
4469                 // also fade it based on positioning
4470                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4471                 {
4472                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4473                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4474                 }
4475                 a *= panel_fg_alpha;
4476
4477                 // finally set the size based on the new theAlpha from subsequent fading
4478                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4479                 drawfontscale = sz * '1 1 0';
4480
4481                 if (centerprint_countdown_num[j])
4482                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4483                 else
4484                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4485
4486                 if (autocvar_hud_panel_centerprint_flip)
4487                 {
4488                         // check if the message can be entirely shown
4489                         for(k = 0; k < n; ++k)
4490                         {
4491                                 getWrappedLine_remaining = argv(k);
4492                                 while(getWrappedLine_remaining)
4493                                 {
4494                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4495                                         if (ts != "")
4496                                                 pos.y -= fontsize.y;
4497                                         else
4498                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4499                                 }
4500                         }
4501                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4502                 }
4503
4504                 msg_size = pos.y;
4505                 for(k = 0; k < n; ++k)
4506                 {
4507                         getWrappedLine_remaining = argv(k);
4508                         while(getWrappedLine_remaining)
4509                         {
4510                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4511                                 if (ts != "")
4512                                 {
4513                                         if (align)
4514                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4515                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4516                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4517                                         pos.y += fontsize.y;
4518                                 }
4519                                 else
4520                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4521                         }
4522                 }
4523
4524                 ++g; // move next position number up
4525
4526                 msg_size = pos.y - msg_size;
4527                 if (autocvar_hud_panel_centerprint_flip)
4528                 {
4529                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4530                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4531                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4532
4533                         if (pos.y < panel_pos.y) // check if the next message can be shown
4534                         {
4535                                 drawfontscale = '1 1 0';
4536                                 return;
4537                         }
4538                 }
4539                 else
4540                 {
4541                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4542                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4543                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4544
4545                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4546                         {
4547                                 drawfontscale = '1 1 0';
4548                                 return;
4549                         }
4550                 }
4551         }
4552         drawfontscale = '1 1 0';
4553         if (all_messages_expired)
4554         {
4555                 centerprint_showing = false;
4556                 reset_centerprint_messages();
4557         }
4558 }
4559
4560 // Buffs (#18)
4561 //
4562 void HUD_Buffs(void)
4563 {
4564         int buffs = getstati(STAT_BUFFS, 0, 24);
4565         if(!autocvar__hud_configure)
4566         {
4567                 if(!autocvar_hud_panel_buffs) return;
4568                 if(spectatee_status == -1) return;
4569                 if(getstati(STAT_HEALTH) <= 0) return;
4570                 if(!buffs) return;
4571         }
4572         else
4573         {
4574                 buffs = Buff_Type_first.items; // force first buff
4575         }
4576
4577         int b = 0; // counter to tell other functions that we have buffs
4578         entity e;
4579         string s = "";
4580         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4581         {
4582                 ++b;
4583                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4584                 if(s == "")
4585                         s = o;
4586                 else
4587                         s = strcat(s, " ", o);
4588         }
4589
4590         HUD_Panel_UpdateCvars();
4591
4592         draw_beginBoldFont();
4593
4594         vector pos, mySize;
4595         pos = panel_pos;
4596         mySize = panel_size;
4597
4598         HUD_Panel_DrawBg(bound(0, b, 1));
4599         if(panel_bg_padding)
4600         {
4601                 pos += '1 1 0' * panel_bg_padding;
4602                 mySize -= '2 2 0' * panel_bg_padding;
4603         }
4604
4605         //float panel_ar = mySize_x/mySize_y;
4606         //bool is_vertical = (panel_ar < 1);
4607         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4608         vector buff_offset = '0 0 0';
4609
4610         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4611         {
4612                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4613                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4614         }
4615
4616         draw_endBoldFont();
4617 }
4618
4619
4620 /*
4621 ==================
4622 Main HUD system
4623 ==================
4624 */
4625
4626 void HUD_Reset (void)
4627 {
4628         // reset gametype specific icons
4629         if(gametype == MAPINFO_TYPE_CTF)
4630                 HUD_Mod_CTF_Reset();
4631 }
4632
4633 void HUD_Main (void)
4634 {
4635         int i;
4636         // global hud theAlpha fade
4637         if(menu_enabled == 1)
4638                 hud_fade_alpha = 1;
4639         else
4640                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4641
4642         if(scoreboard_fade_alpha)
4643                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4644
4645         HUD_Configure_Frame();
4646
4647         if(intermission == 2) // no hud during mapvote
4648                 hud_fade_alpha = 0;
4649
4650         // panels that we want to be active together with the scoreboard
4651         // they must fade only when the menu does
4652         if(scoreboard_fade_alpha == 1)
4653         {
4654                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4655                 return;
4656         }
4657
4658         if(!autocvar__hud_configure && !hud_fade_alpha)
4659                 return;
4660
4661         // Drawing stuff
4662         if (hud_skin_prev != autocvar_hud_skin)
4663         {
4664                 if (hud_skin_path)
4665                         strunzone(hud_skin_path);
4666                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4667                 if (hud_skin_prev)
4668                         strunzone(hud_skin_prev);
4669                 hud_skin_prev = strzone(autocvar_hud_skin);
4670         }
4671
4672         // draw the dock
4673         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4674         {
4675                 int f;
4676                 vector color;
4677                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4678                 if((teamplay) && hud_dock_color_team) {
4679                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4680                                 color = '1 0 0' * hud_dock_color_team;
4681                         else
4682                                 color = myteamcolors * hud_dock_color_team;
4683                 }
4684                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4685                         color = '1 0 0' * hud_dock_color_team;
4686                 }
4687                 else
4688                 {
4689                         string hud_dock_color = autocvar_hud_dock_color;
4690                         if(hud_dock_color == "shirt") {
4691                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4692                                 color = colormapPaletteColor(floor(f / 16), 0);
4693                         }
4694                         else if(hud_dock_color == "pants") {
4695                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4696                                 color = colormapPaletteColor(f % 16, 1);
4697                         }
4698                         else
4699                                 color = stov(hud_dock_color);
4700                 }
4701
4702                 string pic;
4703                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4704                 if(precache_pic(pic) == "") {
4705                         pic = strcat(hud_skin_path, "/dock_medium");
4706                         if(precache_pic(pic) == "") {
4707                                 pic = "gfx/hud/default/dock_medium";
4708                         }
4709                 }
4710                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4711         }
4712
4713         // cache the panel order into the panel_order array
4714         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4715                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4716                         panel_order[i] = -1;
4717                 string s = "";
4718                 int p_num;
4719                 bool warning = false;
4720                 int argc = tokenize_console(autocvar__hud_panelorder);
4721                 if (argc > HUD_PANEL_NUM)
4722                         warning = true;
4723                 //first detect wrong/missing panel numbers
4724                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4725                         p_num = stoi(argv(i));
4726                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4727                                 if (panel_order[p_num] == -1) //found for the first time?
4728                                         s = strcat(s, ftos(p_num), " ");
4729                                 panel_order[p_num] = 1; //mark as found
4730                         }
4731                         else
4732                                 warning = true;
4733                 }
4734                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4735                         if (panel_order[i] == -1) {
4736                                 warning = true;
4737                                 s = strcat(s, ftos(i), " "); //add missing panel number
4738                         }
4739                 }
4740                 if (warning)
4741                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4742
4743                 cvar_set("_hud_panelorder", s);
4744                 if(hud_panelorder_prev)
4745                         strunzone(hud_panelorder_prev);
4746                 hud_panelorder_prev = strzone(s);
4747
4748                 //now properly set panel_order
4749                 tokenize_console(s);
4750                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4751                         panel_order[i] = stof(argv(i));
4752                 }
4753         }
4754
4755         hud_draw_maximized = 0;
4756         // draw panels in order specified by panel_order array
4757         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4758                 (panel = hud_panel[panel_order[i]]).panel_draw();
4759
4760         hud_draw_maximized = 1; // panels that may be maximized must check this var
4761         // draw maximized panels on top
4762         if(hud_panel_radar_maximized)
4763                 (panel = HUD_PANEL(RADAR)).panel_draw();
4764         if(autocvar__con_chat_maximized)
4765                 (panel = HUD_PANEL(CHAT)).panel_draw();
4766
4767         HUD_Configure_PostDraw();
4768
4769         hud_configure_prev = autocvar__hud_configure;
4770 }