qcsrc/client/hud.qc

   1 #include "scoreboard.qh"
   2 #include "teamradar.qh"
   3 #include "../common/buffs.qh"
   4 #include "../common/counting.qh"
   5 #include "../common/mapinfo.qh"
   6 #include "../common/nades.qh"
   7 #include "../server/t_items.qh"
   8
   9 /*
  10 ==================
  11 Misc HUD functions
  12 ==================
  13 */
  14
  15 // a border picture is a texture containing nine parts:
  16 //   1/4 width: left part
  17 //   1/2 width: middle part (stretched)
  18 //   1/4 width: right part
  19 // divided into
  20 //   1/4 height: top part
  21 //   1/2 height: middle part (stretched)
  22 //   1/4 height: bottom part
  23 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  24 {
  25     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  26     {
  27                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  28                 return;
  29     }
  30         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  31         {
  32                 // draw only the central part
  33                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  34                 return;
  35         }
  36
  37         vector dX, dY;
  38         vector width, height;
  39         vector bW, bH;
  40         //pic = draw_UseSkinFor(pic);
  41         width = eX * theSize.x;
  42         height = eY * theSize.y;
  43         if(theSize.x <= theBorderSize.x * 2)
  44         {
  45                 // not wide enough... draw just left and right then
  46                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  47                 if(theSize.y <= theBorderSize.y * 2)
  48                 {
  49                         // not high enough... draw just corners
  50                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  51                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  55                 }
  56                 else
  57                 {
  58                         dY = theBorderSize.x * eY;
  59                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  60                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  61                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  62                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  63                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  64                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  65                 }
  66         }
  67         else
  68         {
  69                 if(theSize.y <= theBorderSize.y * 2)
  70                 {
  71                         // not high enough... draw just top and bottom then
  72                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  73                         dX = theBorderSize.x * eX;
  74                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  75                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  76                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  80                 }
  81                 else
  82                 {
  83                         dX = theBorderSize.x * eX;
  84                         dY = theBorderSize.x * eY;
  85                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  87                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  88                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  89                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  90                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  91                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  93                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  94                 }
  95         }
  96 }
  97
  98 vector HUD_Get_Num_Color (float x, float maxvalue)
  99 {
 100         float blinkingamt;
 101         vector color;
 102         if(x >= maxvalue) {
 103                 color.x = sin(2*M_PI*time);
 104                 color.y = 1;
 105                 color.z = sin(2*M_PI*time);
 106         }
 107         else if(x > maxvalue * 0.75) {
 108                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 109                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 110                 color.z = 0;
 111         }
 112         else if(x > maxvalue * 0.5) {
 113                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 114                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 115                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 116         }
 117         else if(x > maxvalue * 0.25) {
 118                 color.x = 1;
 119                 color.y = 1;
 120                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 121         }
 122         else if(x > maxvalue * 0.1) {
 123                 color.x = 1;
 124                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 125                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 126         }
 127         else {
 128                 color.x = 1;
 129                 color.y = 0;
 130                 color.z = 0;
 131         }
 132
 133         blinkingamt = (1 - x/maxvalue/0.25);
 134         if(blinkingamt > 0)
 135         {
 136                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 137                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 138                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 139         }
 140         return color;
 141 }
 142
 143 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
 144 {
 145         float aspect = size_y / size_x;
 146         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 147 }
 148
 149 vector HUD_GetTableSize(int item_count, vector psize, float item_aspect)
 150 {
 151         float columns, rows;
 152         float ratio, best_ratio = 0;
 153         float best_columns = 1, best_rows = 1;
 154         bool vertical = (psize.x / psize.y >= item_aspect);
 155         if(vertical)
 156         {
 157                 psize = eX * psize.y + eY * psize.x;
 158                 item_aspect = 1 / item_aspect;
 159         }
 160
 161         rows = ceil(sqrt(item_count));
 162         columns = ceil(item_count/rows);
 163         while(columns >= 1)
 164         {
 165                 ratio = (psize.x/columns) / (psize.y/rows);
 166                 if(ratio > item_aspect)
 167                         ratio = item_aspect * item_aspect / ratio;
 168
 169                 if(ratio <= best_ratio)
 170                         break; // ratio starts decreasing by now, skip next configurations
 171
 172                 best_columns = columns;
 173                 best_rows = rows;
 174                 best_ratio = ratio;
 175
 176                 if(columns == 1)
 177                         break;
 178
 179                 --columns;
 180                 rows = ceil(item_count/columns);
 181         }
 182
 183         if(vertical)
 184                 return eX * best_rows + eY * best_columns;
 185         else
 186                 return eX * best_columns + eY * best_rows;
 187 }
 188
 189 float stringwidth_colors(string s, vector theSize)
 190 {
 191         return stringwidth(s, true, theSize);
 192 }
 193
 194 float stringwidth_nocolors(string s, vector theSize)
 195 {
 196         return stringwidth(s, false, theSize);
 197 }
 198
 199 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 200 {
 201         position.x -= 2 / 3 * strlen(text) * theScale.x;
 202         drawstring(position, text, theScale, rgb, theAlpha, flag);
 203 }
 204
 205 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 206 {
 207         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 208         drawstring(position, text, theScale, rgb, theAlpha, flag);
 209 }
 210
 211 // return the string of the onscreen race timer
 212 string MakeRaceString(int cp, float mytime, float theirtime, float lapdelta, string theirname)
 213 {
 214         string col;
 215         string timestr;
 216         string cpname;
 217         string lapstr;
 218         lapstr = "";
 219
 220         if(theirtime == 0) // goal hit
 221         {
 222                 if(mytime > 0)
 223                 {
 224                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 225                         col = "^1";
 226                 }
 227                 else if(mytime == 0)
 228                 {
 229                         timestr = "+0.0";
 230                         col = "^3";
 231                 }
 232                 else
 233                 {
 234                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 235                         col = "^2";
 236                 }
 237
 238                 if(lapdelta > 0)
 239                 {
 240                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 241                         col = "^2";
 242                 }
 243                 else if(lapdelta < 0)
 244                 {
 245                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 246                         col = "^1";
 247                 }
 248         }
 249         else if(theirtime > 0) // anticipation
 250         {
 251                 if(mytime >= theirtime)
 252                         timestr = strcat("+", ftos_decimals(mytime - theirtime, TIME_DECIMALS));
 253                 else
 254                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(theirtime));
 255                 col = "^3";
 256         }
 257         else
 258         {
 259                 col = "^7";
 260                 timestr = "";
 261         }
 262
 263         if(cp == 254)
 264                 cpname = _("Start line");
 265         else if(cp == 255)
 266                 cpname = _("Finish line");
 267         else if(cp)
 268                 cpname = sprintf(_("Intermediate %d"), cp);
 269         else
 270                 cpname = _("Finish line");
 271
 272         if(theirtime < 0)
 273                 return strcat(col, cpname);
 274         else if(theirname == "")
 275                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 276         else
 277                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(theirname, col, lapstr)));
 278 }
 279
 280 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 281 int race_CheckName(string net_name)
 282 {
 283         int i;
 284         for (i=RANKINGS_CNT-1;i>=0;--i)
 285                 if(grecordholder[i] == net_name)
 286                         return i+1;
 287         return 0;
 288 }
 289
 290 int GetPlayerColorForce(int i)
 291 {
 292         if(!teamplay)
 293                 return 0;
 294         else
 295                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 296 }
 297
 298 int GetPlayerColor(int i)
 299 {
 300         if(!playerslots[i].gotscores) // unconnected
 301                 return NUM_SPECTATOR;
 302         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 303                 return NUM_SPECTATOR;
 304         else
 305                 return GetPlayerColorForce(i);
 306 }
 307
 308 string GetPlayerName(int i)
 309 {
 310         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 311 }
 312
 313
 314 /*
 315 ==================
 316 HUD panels
 317 ==================
 318 */
 319
 320 // draw the background/borders
 321 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 322         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 323                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 324 } while(0)
 325
 326 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 327 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 328 {
 329         if(!length_ratio || !theAlpha)
 330                 return;
 331         if(length_ratio > 1)
 332                 length_ratio = 1;
 333         if (baralign == 3)
 334         {
 335                 if(length_ratio < -1)
 336                         length_ratio = -1;
 337         }
 338         else if(length_ratio < 0)
 339                 return;
 340
 341         vector square;
 342         vector width, height;
 343         if(vertical) {
 344                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 345                 if(precache_pic(pic) == "") {
 346                         pic = "gfx/hud/default/progressbar_vertical";
 347                 }
 348
 349         if (baralign == 1) // bottom align
 350                         theOrigin.y += (1 - length_ratio) * theSize.y;
 351         else if (baralign == 2) // center align
 352             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 353         else if (baralign == 3) // center align, positive values down, negative up
 354                 {
 355                         theSize.y *= 0.5;
 356                         if (length_ratio > 0)
 357                                 theOrigin.y += theSize.y;
 358                         else
 359                         {
 360                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 361                                 length_ratio = -length_ratio;
 362                         }
 363                 }
 364                 theSize.y *= length_ratio;
 365
 366                 vector bH;
 367                 width = eX * theSize.x;
 368                 height = eY * theSize.y;
 369                 if(theSize.y <= theSize.x * 2)
 370                 {
 371                         // button not high enough
 372                         // draw just upper and lower part then
 373                         square = eY * theSize.y * 0.5;
 374                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 375                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 376                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 377                 }
 378                 else
 379                 {
 380                         square = eY * theSize.x;
 381                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 382                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 383                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 384                 }
 385         } else {
 386                 pic = strcat(hud_skin_path, "/", pic);
 387                 if(precache_pic(pic) == "") {
 388                         pic = "gfx/hud/default/progressbar";
 389                 }
 390
 391                 if (baralign == 1) // right align
 392                         theOrigin.x += (1 - length_ratio) * theSize.x;
 393         else if (baralign == 2) // center align
 394             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 395         else if (baralign == 3) // center align, positive values on the right, negative on the left
 396                 {
 397                         theSize.x *= 0.5;
 398                         if (length_ratio > 0)
 399                                 theOrigin.x += theSize.x;
 400                         else
 401                         {
 402                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 403                                 length_ratio = -length_ratio;
 404                         }
 405                 }
 406                 theSize.x *= length_ratio;
 407
 408                 vector bW;
 409                 width = eX * theSize.x;
 410                 height = eY * theSize.y;
 411                 if(theSize.x <= theSize.y * 2)
 412                 {
 413                         // button not wide enough
 414                         // draw just left and right part then
 415                         square = eX * theSize.x * 0.5;
 416                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 417                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 418                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 419                 }
 420                 else
 421                 {
 422                         square = eX * theSize.y;
 423                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 424                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 425                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 426                 }
 427         }
 428 }
 429
 430 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 431 {
 432         if(!theAlpha)
 433                 return;
 434
 435         string pic;
 436         pic = strcat(hud_skin_path, "/num_leading");
 437         if(precache_pic(pic) == "") {
 438                 pic = "gfx/hud/default/num_leading";
 439         }
 440
 441         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 442         if(mySize.x/mySize.y > 2)
 443                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 444         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 445 }
 446
 447 // Weapon icons (#0)
 448 //
 449 entity weaponorder[WEP_MAXCOUNT];
 450 void weaponorder_swap(int i, int j, entity pass)
 451 {
 452         entity h = weaponorder[i];
 453         weaponorder[i] = weaponorder[j];
 454         weaponorder[j] = h;
 455 }
 456
 457 string weaponorder_cmp_str;
 458 int weaponorder_cmp(int i, int j, entity pass)
 459 {
 460         int ai, aj;
 461         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 462         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 463         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 464 }
 465
 466 void HUD_Weapons(void)
 467 {
 468         // declarations
 469         WepSet weapons_stat = WepSet_GetFromStat();
 470         int i;
 471         float f, a;
 472         float screen_ar;
 473         vector center = '0 0 0';
 474         int weapon_count, weapon_id;
 475         int row, column, rows = 0, columns = 0;
 476         bool vertical_order = true;
 477         float aspect = autocvar_hud_panel_weapons_aspect;
 478
 479         float timeout = autocvar_hud_panel_weapons_timeout;
 480         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 481         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 482
 483         vector barsize = '0 0 0', baroffset = '0 0 0';
 484         vector ammo_color = '1 0 1';
 485         float ammo_alpha = 1;
 486
 487         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 488         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 489
 490         vector weapon_pos, weapon_size = '0 0 0';
 491         vector color;
 492
 493         // check to see if we want to continue
 494         if(hud != HUD_NORMAL) { return; }
 495
 496         if(!autocvar__hud_configure)
 497         {
 498                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 499                         return;
 500                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 501                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 502                 {
 503                         weaponprevtime = time;
 504                         return;
 505                 }
 506         }
 507
 508         // update generic hud functions
 509         HUD_Panel_UpdateCvars();
 510
 511         draw_beginBoldFont();
 512
 513         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 514         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 515         {
 516                 int weapon_cnt;
 517                 if(weaponorder_bypriority)
 518                         strunzone(weaponorder_bypriority);
 519                 if(weaponorder_byimpulse)
 520                         strunzone(weaponorder_byimpulse);
 521
 522                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 523                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 524                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 525
 526                 weapon_cnt = 0;
 527                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 528                 {
 529                         self = get_weaponinfo(i);
 530                         if(self.impulse >= 0)
 531                         {
 532                                 weaponorder[weapon_cnt] = self;
 533                                 ++weapon_cnt;
 534                         }
 535                 }
 536                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 537                         weaponorder[i] = world;
 538                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 539
 540                 weaponorder_cmp_str = string_null;
 541         }
 542
 543         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 544                 complain_weapon = 0;
 545
 546         if(autocvar__hud_configure)
 547         {
 548                 if(!weapons_stat)
 549                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 550                                 weapons_stat |= WepSet_FromWeapon(i);
 551
 552                 #if 0
 553                 /// debug code
 554                 if(cvar("wep_add"))
 555                 {
 556                         weapons_stat = '0 0 0';
 557                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % WEP_COUNT);
 558                         for(i = WEP_FIRST; i <= countw; ++i)
 559                                 weapons_stat |= WepSet_FromWeapon(i);
 560                 }
 561                 #endif
 562         }
 563
 564         // determine which weapons are going to be shown
 565         if (autocvar_hud_panel_weapons_onlyowned)
 566         {
 567                 if(autocvar__hud_configure)
 568                 {
 569                         if(menu_enabled != 2)
 570                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 571                 }
 572
 573                 // do we own this weapon?
 574                 weapon_count = 0;
 575                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 576                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 577                                 ++weapon_count;
 578
 579
 580                 // might as well commit suicide now, no reason to live ;)
 581                 if (weapon_count == 0)
 582                 {
 583                         draw_endBoldFont();
 584                         return;
 585                 }
 586
 587                 vector old_panel_size = panel_size;
 588                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 589
 590                 // get the all-weapons layout
 591                 vector table_size = HUD_GetTableSize(WEP_COUNT, padded_panel_size, aspect);
 592                 columns = table_size.x;
 593                 rows = table_size.y;
 594                 weapon_size.x = padded_panel_size.x / columns;
 595                 weapon_size.y = padded_panel_size.y / rows;
 596
 597                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 598                 // we enlarge them a bit when possible to better match the desired aspect ratio
 599                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 600                 {
 601                         // maximum number of rows that allows to display items with the desired aspect ratio
 602                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 603                         columns = min(columns, ceil(weapon_count / max_rows));
 604                         rows = ceil(weapon_count / columns);
 605                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 606                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 607                         vertical_order = false;
 608                 }
 609                 else
 610                 {
 611                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 612                         rows = min(rows, ceil(weapon_count / max_columns));
 613                         columns = ceil(weapon_count / rows);
 614                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 615                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 616                         vertical_order = true;
 617                 }
 618
 619                 // reduce size of the panel
 620                 panel_size.x = columns * weapon_size.x;
 621                 panel_size.y = rows * weapon_size.y;
 622                 panel_size += '2 2 0' * panel_bg_padding;
 623
 624                 // center the resized panel, or snap it to the screen edge when close enough
 625                 if(panel_pos.x > vid_conwidth * 0.001)
 626                 {
 627                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 628                                 panel_pos.x += old_panel_size.x - panel_size.x;
 629                         else
 630                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 631                 }
 632                 else if(old_panel_size.x > vid_conwidth * 0.999)
 633                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 634
 635                 if(panel_pos.y > vid_conheight * 0.001)
 636                 {
 637                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 638                                 panel_pos.y += old_panel_size.y - panel_size.y;
 639                         else
 640                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 641                 }
 642                 else if(old_panel_size.y > vid_conheight * 0.999)
 643                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 644         }
 645         else
 646                 weapon_count = WEP_COUNT;
 647
 648         // animation for fading in/out the panel respectively when not in use
 649         if(!autocvar__hud_configure)
 650         {
 651                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 652                 {
 653                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 654
 655                         // fade the panel alpha
 656                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 657                         {
 658                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 659                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 660                         }
 661                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 662                         {
 663                                 panel_bg_alpha *= (1 - f);
 664                                 panel_fg_alpha *= (1 - f);
 665                         }
 666
 667                         // move the panel off the screen
 668                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 669                         {
 670                                 f *= f; // for a cooler movement
 671                                 center.x = panel_pos.x + panel_size.x/2;
 672                                 center.y = panel_pos.y + panel_size.y/2;
 673                                 screen_ar = vid_conwidth/vid_conheight;
 674                                 if (center.x/center.y < screen_ar) //bottom left
 675                                 {
 676                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 677                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 678                                         else //left
 679                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 680                                 }
 681                                 else //top right
 682                                 {
 683                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 684                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 685                                         else //top
 686                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 687                                 }
 688                                 if(f == 1)
 689                                         center.x = -1; // mark the panel as off screen
 690                         }
 691                         weaponprevtime = time - (1 - f) * timein_effect_length;
 692                 }
 693                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 694                 {
 695                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 696
 697                         // fade the panel alpha
 698                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 699                         {
 700                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 701                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 702                         }
 703                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 704                         {
 705                                 panel_bg_alpha *= (f);
 706                                 panel_fg_alpha *= (f);
 707                         }
 708
 709                         // move the panel back on screen
 710                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 711                         {
 712                                 f *= f; // for a cooler movement
 713                                 f = 1 - f;
 714                                 center.x = panel_pos.x + panel_size.x/2;
 715                                 center.y = panel_pos.y + panel_size.y/2;
 716                                 screen_ar = vid_conwidth/vid_conheight;
 717                                 if (center.x/center.y < screen_ar) //bottom left
 718                                 {
 719                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 720                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 721                                         else //left
 722                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 723                                 }
 724                                 else //top right
 725                                 {
 726                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 727                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 728                                         else //top
 729                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 730                                 }
 731                         }
 732                 }
 733         }
 734
 735         // draw the background, then change the virtual size of it to better fit other items inside
 736         HUD_Panel_DrawBg(1);
 737
 738         if(center.x == -1)
 739         {
 740                 draw_endBoldFont();
 741                 return;
 742         }
 743
 744         if(panel_bg_padding)
 745         {
 746                 panel_pos += '1 1 0' * panel_bg_padding;
 747                 panel_size -= '2 2 0' * panel_bg_padding;
 748         }
 749
 750         // after the sizing and animations are done, update the other values
 751
 752         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 753         {
 754                 vector table_size = HUD_GetTableSize(WEP_COUNT, panel_size, aspect);
 755                 columns = table_size.x;
 756                 rows = table_size.y;
 757                 weapon_size.x = panel_size.x / columns;
 758                 weapon_size.y = panel_size.y / rows;
 759                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 760         }
 761
 762         // calculate position/size for visual bar displaying ammount of ammo status
 763         if (autocvar_hud_panel_weapons_ammo)
 764         {
 765                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 766                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 767
 768                 if(weapon_size.x/weapon_size.y > aspect)
 769                 {
 770                         barsize.x = aspect * weapon_size.y;
 771                         barsize.y = weapon_size.y;
 772                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 773                 }
 774                 else
 775                 {
 776                         barsize.y = 1/aspect * weapon_size.x;
 777                         barsize.x = weapon_size.x;
 778                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 779                 }
 780         }
 781         if(autocvar_hud_panel_weapons_accuracy)
 782                 Accuracy_LoadColors();
 783
 784         // draw items
 785         row = column = 0;
 786         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 787         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 788         {
 789                 // retrieve information about the current weapon to be drawn
 790                 self = weaponorder[i];
 791                 weapon_id = self.impulse;
 792
 793                 // skip if this weapon doesn't exist
 794                 if(!self || weapon_id < 0) { continue; }
 795
 796                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 797                 if(autocvar_hud_panel_weapons_onlyowned)
 798                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 799                         continue;
 800
 801                 // figure out the drawing position of weapon
 802                 weapon_pos = (panel_pos
 803                         + eX * column * weapon_size.x
 804                         + eY * row * weapon_size.y);
 805
 806                 // draw background behind currently selected weapon
 807                 if(self.weapon == switchweapon)
 808                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 809
 810                 // draw the weapon accuracy
 811                 if(autocvar_hud_panel_weapons_accuracy)
 812                 {
 813                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 814                         if(panel_weapon_accuracy >= 0)
 815                         {
 816                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 817                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 818                         }
 819                 }
 820
 821                 // drawing all the weapon items
 822                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 823                 {
 824                         // draw the weapon image
 825                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 826
 827                         // draw weapon label string
 828                         switch(autocvar_hud_panel_weapons_label)
 829                         {
 830                                 case 1: // weapon number
 831                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 832                                         break;
 833
 834                                 case 2: // bind
 835                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 836                                         break;
 837
 838                                 case 3: // weapon name
 839                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 840                                         break;
 841
 842                                 default: // nothing
 843                                         break;
 844                         }
 845
 846                         // draw ammo status bar
 847                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 848                         {
 849                                 float ammo_full;
 850                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 851
 852                                 if(a > 0)
 853                                 {
 854                                         switch(self.ammo_field)
 855                                         {
 856                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 857                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 858                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 859                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 860                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 861                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 862                                                 default: ammo_full = 60;
 863                                         }
 864
 865                                         drawsetcliparea(
 866                                                 weapon_pos.x + baroffset.x,
 867                                                 weapon_pos.y + baroffset.y,
 868                                                 barsize.x * bound(0, a/ammo_full, 1),
 869                                                 barsize.y
 870                                         );
 871
 872                                         drawpic_aspect_skin(
 873                                                 weapon_pos,
 874                                                 "weapon_ammo",
 875                                                 weapon_size,
 876                                                 ammo_color,
 877                                                 ammo_alpha,
 878                                                 DRAWFLAG_NORMAL
 879                                         );
 880
 881                                         drawresetcliparea();
 882                                 }
 883                         }
 884                 }
 885                 else // draw a "ghost weapon icon" if you don't have the weapon
 886                 {
 887                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 888                 }
 889
 890                 // draw the complain message
 891                 if(self.weapon == complain_weapon)
 892                 {
 893                         if(fadetime)
 894                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 895                         else
 896                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 897
 898                         string s;
 899                         if(complain_weapon_type == 0) {
 900                                 s = _("Out of ammo");
 901                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 902                         }
 903                         else if(complain_weapon_type == 1) {
 904                                 s = _("Don't have");
 905                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 906                         }
 907                         else {
 908                                 s = _("Unavailable");
 909                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 910                         }
 911                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 912                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 913                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 914                 }
 915
 916                 #if 0
 917                 /// debug code
 918                 if(!autocvar_hud_panel_weapons_onlyowned)
 919                 {
 920                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 921                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 922                 }
 923                 #endif
 924
 925                 // continue with new position for the next weapon
 926                 if(vertical_order)
 927                 {
 928                         ++column;
 929                         if(column >= columns)
 930                         {
 931                                 column = 0;
 932                                 ++row;
 933                         }
 934                 }
 935                 else
 936                 {
 937                         ++row;
 938                         if(row >= rows)
 939                         {
 940                                 row = 0;
 941                                 ++column;
 942                         }
 943                 }
 944         }
 945
 946         draw_endBoldFont();
 947 }
 948
 949 // Ammo (#1)
 950 void DrawNadeScoreBar(vector myPos, vector mySize, vector color)
 951 {
 952
 953         HUD_Panel_DrawProgressBar(
 954                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 955                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 956                 autocvar_hud_panel_ammo_progressbar_name,
 957                 getstatf(STAT_NADE_BONUS_SCORE), 0, 0, color,
 958                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 959
 960 }
 961
 962 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 963 {
 964         float theAlpha = 1, a, b;
 965         vector nade_color, picpos, numpos;
 966
 967         nade_color = Nade_Color(getstati(STAT_NADE_BONUS_TYPE));
 968
 969         a = getstatf(STAT_NADE_BONUS);
 970         b = getstatf(STAT_NADE_BONUS_SCORE);
 971
 972         if(autocvar_hud_panel_ammo_iconalign)
 973         {
 974                 numpos = myPos;
 975                 picpos = myPos + eX * 2 * mySize.y;
 976         }
 977         else
 978         {
 979                 numpos = myPos + eX * mySize.y;
 980                 picpos = myPos;
 981         }
 982
 983         DrawNadeScoreBar(myPos, mySize, nade_color);
 984
 985         if(b > 0 || a > 0)
 986         {
 987                 if(autocvar_hud_panel_ammo_text)
 988                         drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 989
 990                 if(draw_expanding)
 991                         drawpic_aspect_skin_expanding(picpos, "nade_nbg", '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, expand_time);
 992
 993                 drawpic_aspect_skin(picpos, "nade_bg" , '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 994                 drawpic_aspect_skin(picpos, "nade_nbg" , '1 1 0' * mySize.y, nade_color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 995         }
 996 }
 997
 998 void DrawAmmoItem(vector myPos, vector mySize, .int ammoType, bool isCurrent, bool isInfinite)
 999 {
1000         if(ammoType == ammo_none)
1001                 return;
1002
1003         // Initialize variables
1004
1005         int ammo;
1006         if(autocvar__hud_configure)
1007         {
1008                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
1009                 ammo = 60;
1010         }
1011         else
1012                 ammo = getstati(GetAmmoStat(ammoType));
1013
1014         if(!isCurrent)
1015         {
1016                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
1017                 myPos = myPos + (mySize - mySize * scale) * 0.5;
1018                 mySize = mySize * scale;
1019         }
1020
1021         vector iconPos, textPos;
1022         if(autocvar_hud_panel_ammo_iconalign)
1023         {
1024                 iconPos = myPos + eX * 2 * mySize.y;
1025                 textPos = myPos;
1026         }
1027         else
1028         {
1029                 iconPos = myPos;
1030                 textPos = myPos + eX * mySize.y;
1031         }
1032
1033         bool isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
1034
1035         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
1036         vector textColor;
1037         if(isInfinite)
1038                 textColor = '0.2 0.95 0';
1039         else if(isShadowed)
1040                 textColor = '0 0 0';
1041         else if(ammo < 10)
1042                 textColor = '0.8 0.04 0';
1043         else
1044                 textColor = '1 1 1';
1045
1046         float alpha;
1047         if(isCurrent)
1048                 alpha = panel_fg_alpha;
1049         else if(isShadowed)
1050                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
1051         else
1052                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
1053
1054         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
1055
1056         // Draw item
1057
1058         if(isCurrent)
1059                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1060
1061         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
1062                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
1063
1064         if(autocvar_hud_panel_ammo_text)
1065                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
1066
1067         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
1068 }
1069
1070 int nade_prevstatus;
1071 int nade_prevframe;
1072 float nade_statuschange_time;
1073 void HUD_Ammo(void)
1074 {
1075         if(hud != HUD_NORMAL) return;
1076         if(!autocvar__hud_configure)
1077         {
1078                 if(!autocvar_hud_panel_ammo) return;
1079                 if(spectatee_status == -1) return;
1080         }
1081
1082         HUD_Panel_UpdateCvars();
1083
1084         draw_beginBoldFont();
1085
1086         vector pos, mySize;
1087         pos = panel_pos;
1088         mySize = panel_size;
1089
1090         HUD_Panel_DrawBg(1);
1091         if(panel_bg_padding)
1092         {
1093                 pos += '1 1 0' * panel_bg_padding;
1094                 mySize -= '2 2 0' * panel_bg_padding;
1095         }
1096
1097         int rows = 0, columns, row, column;
1098         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1099         bool draw_nades = (nade_cnt > 0 || nade_score > 0);
1100         float nade_statuschange_elapsedtime;
1101         int total_ammo_count;
1102
1103         vector ammo_size;
1104         if (autocvar_hud_panel_ammo_onlycurrent)
1105                 total_ammo_count = 1;
1106         else
1107                 total_ammo_count = AMMO_COUNT;
1108
1109         if(draw_nades)
1110         {
1111                 ++total_ammo_count;
1112                 if (nade_cnt != nade_prevframe)
1113                 {
1114                         nade_statuschange_time = time;
1115                         nade_prevstatus = nade_prevframe;
1116                         nade_prevframe = nade_cnt;
1117                 }
1118         }
1119         else
1120                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1121
1122         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1123         columns = ceil((total_ammo_count)/rows);
1124         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1125
1126         vector offset = '0 0 0'; // fteqcc sucks
1127         float newSize;
1128         if(ammo_size.x/ammo_size.y > 3)
1129         {
1130                 newSize = 3 * ammo_size.y;
1131                 offset.x = ammo_size.x - newSize;
1132                 pos.x += offset.x/2;
1133                 ammo_size.x = newSize;
1134         }
1135         else
1136         {
1137                 newSize = 1/3 * ammo_size.x;
1138                 offset.y = ammo_size.y - newSize;
1139                 pos.y += offset.y/2;
1140                 ammo_size.y = newSize;
1141         }
1142
1143         int i;
1144         bool infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1145         row = column = 0;
1146         if(autocvar_hud_panel_ammo_onlycurrent)
1147         {
1148                 if(autocvar__hud_configure)
1149                 {
1150                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1151                 }
1152                 else
1153                 {
1154                         DrawAmmoItem(
1155                                 pos,
1156                                 ammo_size,
1157                                 (get_weaponinfo(switchweapon)).ammo_field,
1158                                 true,
1159                                 infinite_ammo
1160                         );
1161                 }
1162
1163                 ++row;
1164                 if(row >= rows)
1165                 {
1166                         row = 0;
1167                         column = column + 1;
1168                 }
1169         }
1170         else
1171         {
1172                 .int ammotype;
1173                 row = column = 0;
1174                 for(i = 0; i < AMMO_COUNT; ++i)
1175                 {
1176                         ammotype = GetAmmoFieldFromNum(i);
1177                         DrawAmmoItem(
1178                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1179                                 ammo_size,
1180                                 ammotype,
1181                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1182                                 infinite_ammo
1183                         );
1184
1185                         ++row;
1186                         if(row >= rows)
1187                         {
1188                                 row = 0;
1189                                 column = column + 1;
1190                         }
1191                 }
1192         }
1193
1194         if (draw_nades)
1195         {
1196                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1197
1198                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1199
1200                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1201         }
1202
1203         draw_endBoldFont();
1204 }
1205
1206 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha, float fadelerp)
1207 {
1208         vector newPos = '0 0 0', newSize = '0 0 0';
1209         vector picpos, numpos;
1210
1211         if (vertical)
1212         {
1213                 if(mySize.y/mySize.x > 2)
1214                 {
1215                         newSize.y = 2 * mySize.x;
1216                         newSize.x = mySize.x;
1217
1218                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1219                         newPos.x = myPos.x;
1220                 }
1221                 else
1222                 {
1223                         newSize.x = 1/2 * mySize.y;
1224                         newSize.y = mySize.y;
1225
1226                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1227                         newPos.y = myPos.y;
1228                 }
1229
1230                 if(icon_right_align)
1231                 {
1232                         numpos = newPos;
1233                         picpos = newPos + eY * newSize.x;
1234                 }
1235                 else
1236                 {
1237                         picpos = newPos;
1238                         numpos = newPos + eY * newSize.x;
1239                 }
1240
1241                 newSize.y /= 2;
1242                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1243                 // make number smaller than icon, it looks better
1244                 // reduce only y to draw numbers with different number of digits with the same y size
1245                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1246                 newSize.y *= 0.7;
1247                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1248                 return;
1249         }
1250
1251         if(mySize.x/mySize.y > 3)
1252         {
1253                 newSize.x = 3 * mySize.y;
1254                 newSize.y = mySize.y;
1255
1256                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1257                 newPos.y = myPos.y;
1258         }
1259         else
1260         {
1261                 newSize.y = 1/3 * mySize.x;
1262                 newSize.x = mySize.x;
1263
1264                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1265                 newPos.x = myPos.x;
1266         }
1267
1268         if(icon_right_align) // right align
1269         {
1270                 numpos = newPos;
1271                 picpos = newPos + eX * 2 * newSize.y;
1272         }
1273         else // left align
1274         {
1275                 numpos = newPos + eX * newSize.y;
1276                 picpos = newPos;
1277         }
1278
1279         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1280         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1281         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1282         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1283 }
1284
1285 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha)
1286 {
1287         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1288 }
1289
1290 // Powerups (#2)
1291 //
1292 void HUD_Powerups(void)
1293 {
1294         float strength_time, shield_time, superweapons_time;
1295         if(!autocvar__hud_configure)
1296         {
1297                 if(!autocvar_hud_panel_powerups) return;
1298                 if(spectatee_status == -1) return;
1299                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1300                 if (getstati(STAT_HEALTH) <= 0) return;
1301
1302                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1303                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1304                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1305
1306                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1307                         superweapons_time = 99; // force max
1308
1309                 // prevent stuff to show up on mismatch that will be fixed next frame
1310                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1311                         superweapons_time = 0;
1312         }
1313         else
1314         {
1315                 strength_time = 15;
1316                 shield_time = 27;
1317                 superweapons_time = 13;
1318         }
1319
1320         HUD_Panel_UpdateCvars();
1321
1322         draw_beginBoldFont();
1323
1324         vector pos, mySize;
1325         pos = panel_pos;
1326         mySize = panel_size;
1327
1328         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1329         if(panel_bg_padding)
1330         {
1331                 pos += '1 1 0' * panel_bg_padding;
1332                 mySize -= '2 2 0' * panel_bg_padding;
1333         }
1334
1335         float panel_ar = mySize.x/mySize.y;
1336         bool is_vertical = (panel_ar < 1);
1337         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1338
1339         int superweapons_is = -1;
1340
1341         if(superweapons_time)
1342         {
1343                 if(strength_time)
1344                 {
1345                         if(shield_time)
1346                                 superweapons_is = 0;
1347                         else
1348                                 superweapons_is = 2;
1349                 }
1350                 else
1351                 {
1352                         if(shield_time)
1353                                 superweapons_is = 1;
1354                         else
1355                                 superweapons_is = 2;
1356                 }
1357         }
1358
1359         // FIXME handle superweapons here
1360         if(superweapons_is == 0)
1361         {
1362                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1363                 {
1364                         mySize.x *= (1.0 / 3.0);
1365                         superweapons_offset.x = mySize.x;
1366                         if (autocvar_hud_panel_powerups_flip)
1367                                 shield_offset.x = 2*mySize.x;
1368                         else
1369                                 strength_offset.x = 2*mySize.x;
1370                 }
1371                 else
1372                 {
1373                         mySize.y *= (1.0 / 3.0);
1374                         superweapons_offset.y = mySize.y;
1375                         if (autocvar_hud_panel_powerups_flip)
1376                                 shield_offset.y = 2*mySize.y;
1377                         else
1378                                 strength_offset.y = 2*mySize.y;
1379                 }
1380         }
1381         else
1382         {
1383                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1384                 {
1385                         mySize.x *= 0.5;
1386                         if (autocvar_hud_panel_powerups_flip)
1387                                 shield_offset.x = mySize.x;
1388                         else
1389                                 strength_offset.x = mySize.x;
1390                 }
1391                 else
1392                 {
1393                         mySize.y *= 0.5;
1394                         if (autocvar_hud_panel_powerups_flip)
1395                                 shield_offset.y = mySize.y;
1396                         else
1397                                 strength_offset.y = mySize.y;
1398                 }
1399         }
1400
1401         bool shield_baralign, strength_baralign, superweapons_baralign;
1402         bool shield_iconalign, strength_iconalign, superweapons_iconalign;
1403
1404         if (autocvar_hud_panel_powerups_flip)
1405         {
1406                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1407                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1408                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1409                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1410         }
1411         else
1412         {
1413                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1414                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1415                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1416                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1417         }
1418
1419         if(superweapons_is == 0)
1420         {
1421                 superweapons_iconalign = strength_iconalign;
1422                 superweapons_baralign = 2;
1423         }
1424         else if(superweapons_is == 1)
1425         {
1426                 superweapons_offset = strength_offset;
1427                 superweapons_iconalign = strength_iconalign;
1428                 superweapons_baralign = strength_baralign;
1429         }
1430         else // if(superweapons_is == 2)
1431         {
1432                 superweapons_offset = shield_offset;
1433                 superweapons_iconalign = shield_iconalign;
1434                 superweapons_baralign = shield_baralign;
1435         }
1436
1437         if(shield_time)
1438         {
1439                 const float maxshield = 30;
1440                 float shield = ceil(shield_time);
1441                 if(autocvar_hud_panel_powerups_progressbar)
1442                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1443                 if(autocvar_hud_panel_powerups_text)
1444                 {
1445                         if(shield > 1)
1446                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1447                         if(shield <= 5)
1448                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1449                 }
1450         }
1451
1452         if(strength_time)
1453         {
1454                 const float maxstrength = 30;
1455                 float strength = ceil(strength_time);
1456                 if(autocvar_hud_panel_powerups_progressbar)
1457                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1458                 if(autocvar_hud_panel_powerups_text)
1459                 {
1460                         if(strength > 1)
1461                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1462                         if(strength <= 5)
1463                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1464                 }
1465         }
1466
1467         if(superweapons_time)
1468         {
1469                 const float maxsuperweapons = 30;
1470                 float superweapons = ceil(superweapons_time);
1471                 if(autocvar_hud_panel_powerups_progressbar)
1472                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1473                 if(autocvar_hud_panel_powerups_text)
1474                 {
1475                         if(superweapons > 1)
1476                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1477                         if(superweapons <= 5)
1478                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1479                 }
1480         }
1481
1482         draw_endBoldFont();
1483 }
1484
1485 // Health/armor (#3)
1486 //
1487
1488 // prev_* vars contain the health/armor at the previous FRAME
1489 // set to -1 when player is dead or was not playing
1490 int prev_health, prev_armor;
1491 float health_damagetime, armor_damagetime;
1492 int health_beforedamage, armor_beforedamage;
1493 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1494 int old_p_health, old_p_armor;
1495 float old_p_healthtime, old_p_armortime;
1496 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1497 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1498 int prev_p_health, prev_p_armor;
1499
1500 void HUD_HealthArmor(void)
1501 {
1502         int armor, health, fuel;
1503         if(!autocvar__hud_configure)
1504         {
1505                 if(!autocvar_hud_panel_healtharmor) return;
1506                 if(hud != HUD_NORMAL) return;
1507                 if(spectatee_status == -1) return;
1508
1509                 health = getstati(STAT_HEALTH);
1510                 if(health <= 0)
1511                 {
1512                         prev_health = -1;
1513                         return;
1514                 }
1515                 armor = getstati(STAT_ARMOR);
1516
1517                 // code to check for spectatee_status changes is in Ent_ClientData()
1518                 // prev_p_health and prev_health can be set to -1 there
1519
1520                 if (prev_p_health == -1)
1521                 {
1522                         // no effect
1523                         health_beforedamage = 0;
1524                         armor_beforedamage = 0;
1525                         health_damagetime = 0;
1526                         armor_damagetime = 0;
1527                         prev_health = health;
1528                         prev_armor = armor;
1529                         old_p_health = health;
1530                         old_p_armor = armor;
1531                         prev_p_health = health;
1532                         prev_p_armor = armor;
1533                 }
1534                 else if (prev_health == -1)
1535                 {
1536                         //start the load effect
1537                         health_damagetime = 0;
1538                         armor_damagetime = 0;
1539                         prev_health = 0;
1540                         prev_armor = 0;
1541                 }
1542                 fuel = getstati(STAT_FUEL);
1543         }
1544         else
1545         {
1546                 health = 150;
1547                 armor = 75;
1548                 fuel = 20;
1549         }
1550
1551         HUD_Panel_UpdateCvars();
1552         vector pos, mySize;
1553         pos = panel_pos;
1554         mySize = panel_size;
1555
1556         HUD_Panel_DrawBg(1);
1557         if(panel_bg_padding)
1558         {
1559                 pos += '1 1 0' * panel_bg_padding;
1560                 mySize -= '2 2 0' * panel_bg_padding;
1561         }
1562
1563         int baralign = autocvar_hud_panel_healtharmor_baralign;
1564         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
1565
1566     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1567     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1568         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1569         {
1570                 vector v;
1571                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1572
1573                 float x;
1574                 x = floor(v.x + 1);
1575
1576         float maxtotal = maxhealth + maxarmor;
1577                 string biggercount;
1578                 if(v.z) // NOT fully armored
1579                 {
1580                         biggercount = "health";
1581                         if(autocvar_hud_panel_healtharmor_progressbar)
1582                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1583                         if(armor)
1584             if(autocvar_hud_panel_healtharmor_text)
1585                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1586                 }
1587                 else
1588                 {
1589                         biggercount = "armor";
1590                         if(autocvar_hud_panel_healtharmor_progressbar)
1591                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1592                         if(health)
1593             if(autocvar_hud_panel_healtharmor_text)
1594                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1595                 }
1596         if(autocvar_hud_panel_healtharmor_text)
1597                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1598
1599                 if(fuel)
1600                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1601         }
1602         else
1603         {
1604                 float panel_ar = mySize.x/mySize.y;
1605                 bool is_vertical = (panel_ar < 1);
1606                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1607                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1608                 {
1609                         mySize.x *= 0.5;
1610                         if (autocvar_hud_panel_healtharmor_flip)
1611                                 health_offset.x = mySize.x;
1612                         else
1613                                 armor_offset.x = mySize.x;
1614                 }
1615                 else
1616                 {
1617                         mySize.y *= 0.5;
1618                         if (autocvar_hud_panel_healtharmor_flip)
1619                                 health_offset.y = mySize.y;
1620                         else
1621                                 armor_offset.y = mySize.y;
1622                 }
1623
1624                 bool health_baralign, armor_baralign, fuel_baralign;
1625                 bool health_iconalign, armor_iconalign;
1626                 if (autocvar_hud_panel_healtharmor_flip)
1627                 {
1628                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1629                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1630                         fuel_baralign = health_baralign;
1631                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1632                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1633                 }
1634                 else
1635                 {
1636                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1637                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1638                         fuel_baralign = armor_baralign;
1639                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1640                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1641                 }
1642
1643                 //if(health)
1644                 {
1645                         if(autocvar_hud_panel_healtharmor_progressbar)
1646                         {
1647                                 float p_health, pain_health_alpha;
1648                                 p_health = health;
1649                                 pain_health_alpha = 1;
1650                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1651                                 {
1652                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1653                                         {
1654                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1655                                                 {
1656                                                         if (time - old_p_healthtime < 1)
1657                                                                 old_p_health = prev_p_health;
1658                                                         else
1659                                                                 old_p_health = prev_health;
1660                                                         old_p_healthtime = time;
1661                                                 }
1662                                                 if (time - old_p_healthtime < 1)
1663                                                 {
1664                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1665                                                         prev_p_health = p_health;
1666                                                 }
1667                                         }
1668                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1669                                         {
1670                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1671                                                 {
1672                                                         if (time - health_damagetime >= 1)
1673                                                                 health_beforedamage = prev_health;
1674                                                         health_damagetime = time;
1675                                                 }
1676                                                 if (time - health_damagetime < 1)
1677                                                 {
1678                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1679                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1680                                                 }
1681                                         }
1682                                         prev_health = health;
1683
1684                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1685                                         {
1686                                                 float BLINK_FACTOR = 0.15;
1687                                                 float BLINK_BASE = 0.85;
1688                                                 float BLINK_FREQ = 9;
1689                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1690                                         }
1691                                 }
1692                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1693                         }
1694                         if(autocvar_hud_panel_healtharmor_text)
1695                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1696                 }
1697
1698                 if(armor)
1699                 {
1700                         if(autocvar_hud_panel_healtharmor_progressbar)
1701                         {
1702                                 float p_armor;
1703                                 p_armor = armor;
1704                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1705                                 {
1706                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1707                                         {
1708                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1709                                                 {
1710                                                         if (time - old_p_armortime < 1)
1711                                                                 old_p_armor = prev_p_armor;
1712                                                         else
1713                                                                 old_p_armor = prev_armor;
1714                                                         old_p_armortime = time;
1715                                                 }
1716                                                 if (time - old_p_armortime < 1)
1717                                                 {
1718                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1719                                                         prev_p_armor = p_armor;
1720                                                 }
1721                                         }
1722                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1723                                         {
1724                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1725                                                 {
1726                                                         if (time - armor_damagetime >= 1)
1727                                                                 armor_beforedamage = prev_armor;
1728                                                         armor_damagetime = time;
1729                                                 }
1730                                                 if (time - armor_damagetime < 1)
1731                                                 {
1732                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1733                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1734                                                 }
1735                                         }
1736                                         prev_armor = armor;
1737                                 }
1738                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1739                         }
1740                         if(autocvar_hud_panel_healtharmor_text)
1741                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1742                 }
1743
1744                 if(fuel)
1745                 {
1746                         if (is_vertical)
1747                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1748                         else
1749                                 mySize.y *= 0.2;
1750                         if (panel_ar >= 4)
1751                                 mySize.x *= 2; //restore full panel size
1752                         else if (panel_ar < 1/4)
1753                                 mySize.y *= 2; //restore full panel size
1754                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1755                 }
1756         }
1757 }
1758
1759 // Notification area (#4)
1760 //
1761
1762 void HUD_Notify_Push(string icon, string attacker, string victim)
1763 {
1764         if (icon == "")
1765                 return;
1766
1767         ++notify_count;
1768         --notify_index;
1769
1770         if (notify_index == -1)
1771                 notify_index = NOTIFY_MAX_ENTRIES-1;
1772
1773         // Free old strings
1774         if (notify_attackers[notify_index])
1775                 strunzone(notify_attackers[notify_index]);
1776
1777         if (notify_victims[notify_index])
1778                 strunzone(notify_victims[notify_index]);
1779
1780         if (notify_icons[notify_index])
1781                 strunzone(notify_icons[notify_index]);
1782
1783         // Allocate new strings
1784         if (victim != "")
1785         {
1786                 notify_attackers[notify_index] = strzone(attacker);
1787                 notify_victims[notify_index] = strzone(victim);
1788         }
1789         else
1790         {
1791                 // In case of a notification without a victim, the attacker
1792                 // is displayed on the victim's side. Instead of special
1793                 // treatment later on, we can simply switch them here.
1794                 notify_attackers[notify_index] = string_null;
1795                 notify_victims[notify_index] = strzone(attacker);
1796         }
1797
1798         notify_icons[notify_index] = strzone(icon);
1799         notify_times[notify_index] = time;
1800 }
1801
1802 void HUD_Notify(void)
1803 {
1804         if (!autocvar__hud_configure)
1805                 if (!autocvar_hud_panel_notify)
1806                         return;
1807
1808         HUD_Panel_UpdateCvars();
1809         HUD_Panel_DrawBg(1);
1810
1811         if (!autocvar__hud_configure)
1812                 if (notify_count == 0)
1813                         return;
1814
1815         vector pos, size;
1816         pos  = panel_pos;
1817         size = panel_size;
1818
1819         if (panel_bg_padding)
1820         {
1821                 pos  += '1 1 0' * panel_bg_padding;
1822                 size -= '2 2 0' * panel_bg_padding;
1823         }
1824
1825         float fade_start = max(0, autocvar_hud_panel_notify_time);
1826         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1827         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1828
1829         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1830         float entry_height = size.y / entry_count;
1831
1832         float panel_width_half = size.x * 0.5;
1833         float icon_width_half = entry_height * icon_aspect / 2;
1834         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1835
1836         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1837         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1838         vector icon_left = eX * (panel_width_half - icon_width_half);
1839         vector attacker_right = eX * name_maxwidth;
1840         vector victim_left = eX * (size.x - name_maxwidth);
1841
1842         vector attacker_pos, victim_pos, icon_pos;
1843         string attacker, victim, icon;
1844         int i, j, count, step, limit;
1845         float alpha;
1846
1847         if (autocvar_hud_panel_notify_flip)
1848         {
1849                 // Order items from the top down
1850                 i = 0;
1851                 step = +1;
1852                 limit = entry_count;
1853         }
1854         else
1855         {
1856                 // Order items from the bottom up
1857                 i = entry_count - 1;
1858                 step = -1;
1859                 limit = -1;
1860         }
1861
1862         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1863         {
1864                 if(autocvar__hud_configure)
1865                 {
1866                         attacker = sprintf(_("Player %d"), count + 1);
1867                         victim = sprintf(_("Player %d"), count + 2);
1868                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1869                         alpha = bound(0, 1.2 - count / entry_count, 1);
1870                 }
1871                 else
1872                 {
1873                         if (j == NOTIFY_MAX_ENTRIES)
1874                                 j = 0;
1875
1876                         if (notify_times[j] + fade_start > time)
1877                                 alpha = 1;
1878                         else if (fade_time != 0)
1879                         {
1880                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1881                                 if (alpha == 0)
1882                                         break;
1883                         }
1884                         else
1885                                 break;
1886
1887                         attacker = notify_attackers[j];
1888                         victim = notify_victims[j];
1889                         icon = notify_icons[j];
1890                 }
1891
1892                 if (icon != "" && victim != "")
1893                 {
1894                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1895
1896                         icon_pos = pos + icon_left + eY * i * entry_height;
1897                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1898
1899                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1900                         victim_pos = pos + victim_left + name_top;
1901                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1902
1903                         if (attacker != "")
1904                         {
1905                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1906                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1907                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1908                         }
1909                 }
1910         }
1911
1912         notify_count = count;
1913 }
1914
1915 // Timer (#5)
1916 //
1917 // TODO: macro
1918 string seconds_tostring(float sec)
1919 {
1920         float minutes;
1921         minutes = floor(sec / 60);
1922
1923         sec -= minutes * 60;
1924         return sprintf("%d:%02d", minutes, sec);
1925 }
1926
1927 void HUD_Timer(void)
1928 {
1929         if(!autocvar__hud_configure)
1930         {
1931                 if(!autocvar_hud_panel_timer) return;
1932         }
1933
1934         HUD_Panel_UpdateCvars();
1935
1936         draw_beginBoldFont();
1937
1938         vector pos, mySize;
1939         pos = panel_pos;
1940         mySize = panel_size;
1941
1942         HUD_Panel_DrawBg(1);
1943         if(panel_bg_padding)
1944         {
1945                 pos += '1 1 0' * panel_bg_padding;
1946                 mySize -= '2 2 0' * panel_bg_padding;
1947         }
1948
1949         string timer;
1950         float timelimit, elapsedTime, timeleft, minutesLeft;
1951
1952         timelimit = getstatf(STAT_TIMELIMIT);
1953
1954         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1955         timeleft = ceil(timeleft);
1956
1957         minutesLeft = floor(timeleft / 60);
1958
1959         vector timer_color;
1960         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1961                 timer_color = '1 1 1'; //white
1962         else if(minutesLeft >= 1)
1963                 timer_color = '1 1 0'; //yellow
1964         else
1965                 timer_color = '1 0 0'; //red
1966
1967         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1968                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1969                         //while restart is still active, show 00:00
1970                         timer = seconds_tostring(0);
1971                 } else {
1972                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1973                         timer = seconds_tostring(elapsedTime);
1974                 }
1975         } else {
1976                 timer = seconds_tostring(timeleft);
1977         }
1978
1979         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1980
1981         draw_endBoldFont();
1982 }
1983
1984 // Radar (#6)
1985 //
1986 void HUD_Radar(void)
1987 {
1988         if (!autocvar__hud_configure)
1989         {
1990                 if (hud_panel_radar_maximized)
1991                 {
1992                         if (!hud_draw_maximized) return;
1993                 }
1994                 else
1995                 {
1996                         if (autocvar_hud_panel_radar == 0) return;
1997                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1998                         if(radar_panel_modified)
1999                         {
2000                                 panel.update_time = time; // forces reload of panel attributes
2001                                 radar_panel_modified = false;
2002                         }
2003                 }
2004         }
2005
2006         HUD_Panel_UpdateCvars();
2007
2008         float f = 0;
2009
2010         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2011         {
2012                 panel_size = autocvar_hud_panel_radar_maximized_size;
2013                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2014                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2015                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2016                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2017
2018                 string panel_bg;
2019                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2020                 if(precache_pic(panel_bg) == "")
2021                         panel_bg = "gfx/hud/default/border_default"; // fallback
2022                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2023                         radar_panel_modified = true;
2024                 if(panel.current_panel_bg)
2025                         strunzone(panel.current_panel_bg);
2026                 panel.current_panel_bg = strzone(panel_bg);
2027
2028                 switch(hud_panel_radar_maximized_zoommode)
2029                 {
2030                         default:
2031                         case 0:
2032                                 f = current_zoomfraction;
2033                                 break;
2034                         case 1:
2035                                 f = 1 - current_zoomfraction;
2036                                 break;
2037                         case 2:
2038                                 f = 0;
2039                                 break;
2040                         case 3:
2041                                 f = 1;
2042                                 break;
2043                 }
2044
2045                 switch(hud_panel_radar_maximized_rotation)
2046                 {
2047                         case 0:
2048                                 teamradar_angle = view_angles.y - 90;
2049                                 break;
2050                         default:
2051                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2052                                 break;
2053                 }
2054         }
2055         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2056         {
2057                 switch(hud_panel_radar_zoommode)
2058                 {
2059                         default:
2060                         case 0:
2061                                 f = current_zoomfraction;
2062                                 break;
2063                         case 1:
2064                                 f = 1 - current_zoomfraction;
2065                                 break;
2066                         case 2:
2067                                 f = 0;
2068                                 break;
2069                         case 3:
2070                                 f = 1;
2071                                 break;
2072                 }
2073
2074                 switch(hud_panel_radar_rotation)
2075                 {
2076                         case 0:
2077                                 teamradar_angle = view_angles.y - 90;
2078                                 break;
2079                         default:
2080                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2081                                 break;
2082                 }
2083         }
2084
2085         vector pos, mySize;
2086         pos = panel_pos;
2087         mySize = panel_size;
2088
2089         HUD_Panel_DrawBg(1);
2090         if(panel_bg_padding)
2091         {
2092                 pos += '1 1 0' * panel_bg_padding;
2093                 mySize -= '2 2 0' * panel_bg_padding;
2094         }
2095
2096         int color2;
2097         entity tm;
2098         float scale2d, normalsize, bigsize;
2099
2100         teamradar_origin2d = pos + 0.5 * mySize;
2101         teamradar_size2d = mySize;
2102
2103         if(minimapname == "")
2104                 return;
2105
2106         teamradar_loadcvars();
2107
2108         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2109         teamradar_size2d = mySize;
2110
2111         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2112
2113         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2114         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2115         {
2116                 // max-min distance must fit the radar in any rotation
2117                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2118         }
2119         else
2120         {
2121                 vector c0, c1, c2, c3, span;
2122                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2123                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2124                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2125                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2126                 span = '0 0 0';
2127                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2128                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2129
2130                 // max-min distance must fit the radar in x=x, y=y
2131                 bigsize = min(
2132                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2133                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2134                 );
2135         }
2136
2137         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2138         if(bigsize > normalsize)
2139                 normalsize = bigsize;
2140
2141         teamradar_size =
2142                   f * bigsize
2143                 + (1 - f) * normalsize;
2144         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2145                   f * mi_center
2146                 + (1 - f) * view_origin);
2147
2148         drawsetcliparea(
2149                 pos.x,
2150                 pos.y,
2151                 mySize.x,
2152                 mySize.y
2153         );
2154
2155         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2156
2157         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2158                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2159         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2160                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2161         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2162         {
2163                 color2 = GetPlayerColor(tm.sv_entnum);
2164                 //if(color == NUM_SPECTATOR || color == color2)
2165                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2166         }
2167         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2168
2169         drawresetcliparea();
2170 }
2171
2172 // Score (#7)
2173 //
2174 void HUD_UpdatePlayerTeams();
2175 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2176 {
2177         float score;
2178         entity tm = world, pl;
2179         int SCOREPANEL_MAX_ENTRIES = 6;
2180         float SCOREPANEL_ASPECTRATIO = 2;
2181         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2182         vector fontsize = '1 1 0' * (mySize.y/entries);
2183
2184         vector rgb, score_color;
2185         rgb = '1 1 1';
2186         score_color = '1 1 1';
2187
2188         float name_size = mySize.x*0.75;
2189         float spacing_size = mySize.x*0.04;
2190         const float highlight_alpha = 0.2;
2191         int i = 0, first_pl = 0;
2192         bool me_printed = false;
2193         string s;
2194         if (autocvar__hud_configure)
2195         {
2196                 float players_per_team = 0;
2197                 if (team_count)
2198                 {
2199                         // show team scores in the first line
2200                         float score_size = mySize.x / team_count;
2201                         players_per_team = max(2, ceil((entries - 1) / team_count));
2202                         for(i=0; i<team_count; ++i) {
2203                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2204                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2205                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2206                         }
2207                         first_pl = 1;
2208                         pos.y += fontsize.y;
2209                 }
2210                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2211                 for (i=first_pl; i<entries; ++i)
2212                 {
2213                         //simulate my score is lower than all displayed players,
2214                         //so that I don't appear at all showing pure rankings.
2215                         //This is to better show the difference between the 2 ranking views
2216                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2217                         {
2218                                 rgb = '1 1 0';
2219                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2220                                 s = GetPlayerName(player_localnum);
2221                                 score = 7;
2222                         }
2223                         else
2224                         {
2225                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2226                                 score -= 3;
2227                         }
2228
2229                         if (team_count)
2230                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2231                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2232                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2233                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2234                         pos.y += fontsize.y;
2235                 }
2236                 return;
2237         }
2238
2239         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2240                 HUD_UpdatePlayerTeams();
2241         if (team_count)
2242         {
2243                 // show team scores in the first line
2244                 float score_size = mySize.x / team_count;
2245                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2246                         if(tm.team == NUM_SPECTATOR)
2247                                 continue;
2248                         if (tm.team == myteam)
2249                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2250                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2251                         ++i;
2252                 }
2253                 first_pl = 1;
2254                 pos.y += fontsize.y;
2255                 tm = teams.sort_next;
2256         }
2257         i = first_pl;
2258
2259         do
2260         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2261         {
2262                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2263                         continue;
2264
2265                 if (i == entries-1 && !me_printed && pl != me)
2266                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2267                 {
2268                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2269                                 if (pl.team != NUM_SPECTATOR)
2270                                         break;
2271
2272                         if (pl)
2273                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2274                         else
2275                                 rgb = '1 0 0'; //last: red
2276                         pl = me;
2277                 }
2278
2279                 if (pl == me)
2280                 {
2281                         if (i == first_pl)
2282                                 rgb = '0 1 0'; //first: green
2283                         me_printed = true;
2284                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2285                 }
2286                 if (team_count)
2287                         score_color = Team_ColorRGB(pl.team) * 0.8;
2288                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2289                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2290                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2291                 pos.y += fontsize.y;
2292                 ++i;
2293         }
2294         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2295 }
2296
2297 void HUD_Score(void)
2298 {
2299         if(!autocvar__hud_configure)
2300         {
2301                 if(!autocvar_hud_panel_score) return;
2302                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2303         }
2304
2305         HUD_Panel_UpdateCvars();
2306         vector pos, mySize;
2307         pos = panel_pos;
2308         mySize = panel_size;
2309
2310         HUD_Panel_DrawBg(1);
2311         if(panel_bg_padding)
2312         {
2313                 pos += '1 1 0' * panel_bg_padding;
2314                 mySize -= '2 2 0' * panel_bg_padding;
2315         }
2316
2317         float score, distribution = 0;
2318         string sign;
2319         vector distribution_color;
2320         entity tm, pl, me;
2321
2322         me = playerslots[player_localentnum - 1];
2323
2324         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2325                 string timer, distrtimer;
2326
2327                 pl = players.sort_next;
2328                 if(pl == me)
2329                         pl = pl.sort_next;
2330                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2331                         if(pl.scores[ps_primary] == 0)
2332                                 pl = world;
2333
2334                 score = me.(scores[ps_primary]);
2335                 timer = TIME_ENCODED_TOSTRING(score);
2336
2337                 draw_beginBoldFont();
2338                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2339                         // distribution display
2340                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2341
2342                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2343
2344                         if (distribution <= 0) {
2345                                 distribution_color = '0 1 0';
2346                                 sign = "-";
2347                         }
2348                         else {
2349                                 distribution_color = '1 0 0';
2350                                 sign = "+";
2351                         }
2352                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2353                 }
2354                 // race record display
2355                 if (distribution <= 0)
2356                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2357                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2358                 draw_endBoldFont();
2359         } else if (!teamplay) { // non-teamgames
2360                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2361                 {
2362                         HUD_Score_Rankings(pos, mySize, me);
2363                         return;
2364                 }
2365                 // me vector := [team/connected frags id]
2366                 pl = players.sort_next;
2367                 if(pl == me)
2368                         pl = pl.sort_next;
2369
2370                 if(autocvar__hud_configure)
2371                         distribution = 42;
2372                 else if(pl)
2373                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2374                 else
2375                         distribution = 0;
2376
2377                 score = me.(scores[ps_primary]);
2378                 if(autocvar__hud_configure)
2379                         score = 123;
2380
2381                 if(distribution >= 5)
2382                         distribution_color = eY;
2383                 else if(distribution >= 0)
2384                         distribution_color = '1 1 1';
2385                 else if(distribution >= -5)
2386                         distribution_color = '1 1 0';
2387                 else
2388                         distribution_color = eX;
2389
2390                 string distribution_str;
2391                 distribution_str = ftos(distribution);
2392                 draw_beginBoldFont();
2393                 if (distribution >= 0)
2394                 {
2395                         if (distribution > 0)
2396                                 distribution_str = strcat("+", distribution_str);
2397                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2398                 }
2399                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2400                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2401                 draw_endBoldFont();
2402         } else { // teamgames
2403                 float row, column, rows = 0, columns = 0;
2404                 vector offset = '0 0 0';
2405                 vector score_pos, score_size; //for scores other than myteam
2406                 if(autocvar_hud_panel_score_rankings)
2407                 {
2408                         HUD_Score_Rankings(pos, mySize, me);
2409                         return;
2410                 }
2411                 if(spectatee_status == -1)
2412                 {
2413                         rows = HUD_GetRowCount(team_count, mySize, 3);
2414                         columns = ceil(team_count/rows);
2415                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2416
2417                         float newSize;
2418                         if(score_size.x/score_size.y > 3)
2419                         {
2420                                 newSize = 3 * score_size.y;
2421                                 offset.x = score_size.x - newSize;
2422                                 pos.x += offset.x/2;
2423                                 score_size.x = newSize;
2424                         }
2425                         else
2426                         {
2427                                 newSize = 1/3 * score_size.x;
2428                                 offset.y = score_size.y - newSize;
2429                                 pos.y += offset.y/2;
2430                                 score_size.y = newSize;
2431                         }
2432                 }
2433                 else
2434                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2435
2436                 float max_fragcount;
2437                 max_fragcount = -99;
2438                 draw_beginBoldFont();
2439                 row = column = 0;
2440                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2441                         if(tm.team == NUM_SPECTATOR)
2442                                 continue;
2443                         score = tm.(teamscores[ts_primary]);
2444                         if(autocvar__hud_configure)
2445                                 score = 123;
2446
2447                         if (score > max_fragcount)
2448                                 max_fragcount = score;
2449
2450                         if (spectatee_status == -1)
2451                         {
2452                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2453                                 if (max_fragcount == score)
2454                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2455                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2456                                 ++row;
2457                                 if(row >= rows)
2458                                 {
2459                                         row = 0;
2460                                         ++column;
2461                                 }
2462                         }
2463                         else if(tm.team == myteam) {
2464                                 if (max_fragcount == score)
2465                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2466                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2467                         } else {
2468                                 if (max_fragcount == score)
2469                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2470                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2471                                 ++rows;
2472                         }
2473                 }
2474                 draw_endBoldFont();
2475         }
2476 }
2477
2478 // Race timer (#8)
2479 //
2480 void HUD_RaceTimer (void)
2481 {
2482         if(!autocvar__hud_configure)
2483         {
2484                 if(!autocvar_hud_panel_racetimer) return;
2485                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2486                 if(spectatee_status == -1) return;
2487         }
2488
2489         HUD_Panel_UpdateCvars();
2490
2491         draw_beginBoldFont();
2492
2493         vector pos, mySize;
2494         pos = panel_pos;
2495         mySize = panel_size;
2496
2497         HUD_Panel_DrawBg(1);
2498         if(panel_bg_padding)
2499         {
2500                 pos += '1 1 0' * panel_bg_padding;
2501                 mySize -= '2 2 0' * panel_bg_padding;
2502         }
2503
2504         // always force 4:1 aspect
2505         vector newSize = '0 0 0';
2506         if(mySize.x/mySize.y > 4)
2507         {
2508                 newSize.x = 4 * mySize.y;
2509                 newSize.y = mySize.y;
2510
2511                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2512         }
2513         else
2514         {
2515                 newSize.y = 1/4 * mySize.x;
2516                 newSize.x = mySize.x;
2517
2518                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2519         }
2520         mySize = newSize;
2521
2522         float a, t;
2523         string s, forcetime;
2524
2525         if(autocvar__hud_configure)
2526         {
2527                 s = "0:13:37";
2528                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2529                 s = _("^1Intermediate 1 (+15.42)");
2530                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2531                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2532                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2533         }
2534         else if(race_checkpointtime)
2535         {
2536                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2537                 s = "";
2538                 forcetime = "";
2539                 if(a > 0) // just hit a checkpoint?
2540                 {
2541                         if(race_checkpoint != 254)
2542                         {
2543                                 if(race_time && race_previousbesttime)
2544                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2545                                 else
2546                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2547                                 if(race_time)
2548                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2549                         }
2550                 }
2551                 else
2552                 {
2553                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2554                         {
2555                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2556                                 if(a > 0) // next one?
2557                                 {
2558                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2559                                 }
2560                         }
2561                 }
2562
2563                 if(s != "" && a > 0)
2564                 {
2565                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2566                 }
2567
2568                 if(race_penaltytime)
2569                 {
2570                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2571                         if(a > 0)
2572                         {
2573                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2574                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2575                         }
2576                 }
2577
2578                 if(forcetime != "")
2579                 {
2580                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2581                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2582                 }
2583                 else
2584                         a = 1;
2585
2586                 if(race_laptime && race_checkpoint != 255)
2587                 {
2588                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2589                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2590                 }
2591         }
2592         else
2593         {
2594                 if(race_mycheckpointtime)
2595                 {
2596                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2597                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2598                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2599                 }
2600                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2601                 {
2602                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2603                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2604                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2605                 }
2606
2607                 if(race_penaltytime && !race_penaltyaccumulator)
2608                 {
2609                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2610                         a = bound(0, (1 + t - time), 1);
2611                         if(a > 0)
2612                         {
2613                                 if(time < t)
2614                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2615                                 else
2616                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2617                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2618                         }
2619                 }
2620         }
2621
2622         draw_endBoldFont();
2623 }
2624
2625 // Vote window (#9)
2626 //
2627 int vote_yescount;
2628 int vote_nocount;
2629 int vote_needed;
2630 int vote_highlighted; // currently selected vote
2631
2632 int vote_active; // is there an active vote?
2633 int vote_prev; // previous state of vote_active to check for a change
2634 float vote_alpha;
2635 float vote_change; // "time" when vote_active changed
2636
2637 void HUD_Vote(void)
2638 {
2639         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2640         {
2641                 vote_active = 1;
2642                 if (autocvar__hud_configure)
2643                 {
2644                         vote_yescount = 0;
2645                         vote_nocount = 0;
2646                         print(_("^1You must answer before entering hud configure mode\n"));
2647                         cvar_set("_hud_configure", "0");
2648                 }
2649                 if(vote_called_vote)
2650                         strunzone(vote_called_vote);
2651                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2652                 uid2name_dialog = 1;
2653         }
2654
2655         if(!autocvar__hud_configure)
2656         {
2657                 if(!autocvar_hud_panel_vote) return;
2658
2659                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2660                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2661
2662                 if(panel_bg_alpha_str == "") {
2663                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2664                 }
2665                 panel_bg_alpha = stof(panel_bg_alpha_str);
2666         }
2667         else
2668         {
2669                 vote_yescount = 3;
2670                 vote_nocount = 2;
2671                 vote_needed = 4;
2672         }
2673
2674         string s;
2675         float a;
2676         if(vote_active != vote_prev) {
2677                 vote_change = time;
2678                 vote_prev = vote_active;
2679         }
2680
2681         if(vote_active || autocvar__hud_configure)
2682                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2683         else
2684                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2685
2686         if(!vote_alpha)
2687                 return;
2688
2689         HUD_Panel_UpdateCvars();
2690
2691         if(uid2name_dialog)
2692         {
2693                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2694                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2695         }
2696
2697     // these must be below above block
2698         vector pos, mySize;
2699         pos = panel_pos;
2700         mySize = panel_size;
2701
2702         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2703         HUD_Panel_DrawBg(a);
2704         a = panel_fg_alpha * a;
2705
2706         if(panel_bg_padding)
2707         {
2708                 pos += '1 1 0' * panel_bg_padding;
2709                 mySize -= '2 2 0' * panel_bg_padding;
2710         }
2711
2712         // always force 3:1 aspect
2713         vector newSize = '0 0 0';
2714         if(mySize.x/mySize.y > 3)
2715         {
2716                 newSize.x = 3 * mySize.y;
2717                 newSize.y = mySize.y;
2718
2719                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2720         }
2721         else
2722         {
2723                 newSize.y = 1/3 * mySize.x;
2724                 newSize.x = mySize.x;
2725
2726                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2727         }
2728         mySize = newSize;
2729
2730         s = _("A vote has been called for:");
2731         if(uid2name_dialog)
2732                 s = _("Allow servers to store and display your name?");
2733         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2734         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2735         if(autocvar__hud_configure)
2736                 s = _("^1Configure the HUD");
2737         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2738
2739         // print the yes/no counts
2740     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2741         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2742     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2743         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2744
2745         // draw the progress bar backgrounds
2746         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2747
2748         // draw the highlights
2749         if(vote_highlighted == 1) {
2750                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2751                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2752         }
2753         else if(vote_highlighted == -1) {
2754                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2755                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2756         }
2757
2758         // draw the progress bars
2759         if(vote_yescount && vote_needed)
2760         {
2761                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2762                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2763         }
2764
2765         if(vote_nocount && vote_needed)
2766         {
2767                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2768                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2769         }
2770
2771         drawresetcliparea();
2772 }
2773
2774 // Mod icons panel (#10)
2775 //
2776
2777 bool mod_active; // is there any active mod icon?
2778
2779 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
2780 {
2781         int stat = -1;
2782         string pic = "";
2783         vector color = '0 0 0';
2784         switch(i)
2785         {
2786                 case 0:
2787                         stat = getstati(STAT_REDALIVE);
2788                         pic = "player_red.tga";
2789                         color = '1 0 0';
2790                         break;
2791                 case 1:
2792                         stat = getstati(STAT_BLUEALIVE);
2793                         pic = "player_blue.tga";
2794                         color = '0 0 1';
2795                         break;
2796                 case 2:
2797                         stat = getstati(STAT_YELLOWALIVE);
2798                         pic = "player_yellow.tga";
2799                         color = '1 1 0';
2800                         break;
2801                 default:
2802                 case 3:
2803                         stat = getstati(STAT_PINKALIVE);
2804                         pic = "player_pink.tga";
2805                         color = '1 0 1';
2806                         break;
2807         }
2808
2809         if(mySize.x/mySize.y > aspect_ratio)
2810         {
2811                 i = aspect_ratio * mySize.y;
2812                 myPos.x = myPos.x + (mySize.x - i) / 2;
2813                 mySize.x = i;
2814         }
2815         else
2816         {
2817                 i = 1/aspect_ratio * mySize.x;
2818                 myPos.y = myPos.y + (mySize.y - i) / 2;
2819                 mySize.y = i;
2820         }
2821
2822         if(layout)
2823         {
2824                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2825                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2826         }
2827         else
2828                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2829 }
2830
2831 // Clan Arena and Freeze Tag HUD modicons
2832 void HUD_Mod_CA(vector myPos, vector mySize)
2833 {
2834         mod_active = 1; // required in each mod function that always shows something
2835
2836         int layout;
2837         if(gametype == MAPINFO_TYPE_CA)
2838                 layout = autocvar_hud_panel_modicons_ca_layout;
2839         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2840                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2841         int rows, columns;
2842         float aspect_ratio;
2843         aspect_ratio = (layout) ? 2 : 1;
2844         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2845         columns = ceil(team_count/rows);
2846
2847         int i;
2848         float row = 0, column = 0;
2849         vector pos, itemSize;
2850         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2851         for(i=0; i<team_count; ++i)
2852         {
2853                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2854
2855                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2856
2857                 ++row;
2858                 if(row >= rows)
2859                 {
2860                         row = 0;
2861                         ++column;
2862                 }
2863         }
2864 }
2865
2866 // CTF HUD modicon section
2867 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2868 int redflag_prevstatus, blueflag_prevstatus; // last remembered status
2869 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2870
2871 void HUD_Mod_CTF_Reset(void)
2872 {
2873         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2874 }
2875
2876 void HUD_Mod_CTF(vector pos, vector mySize)
2877 {
2878         vector redflag_pos, blueflag_pos;
2879         vector flag_size;
2880         float f; // every function should have that
2881
2882         int redflag, blueflag; // current status
2883         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2884         int stat_items;
2885
2886         stat_items = getstati(STAT_ITEMS, 0, 24);
2887         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2888         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2889
2890         if(redflag || blueflag)
2891                 mod_active = 1;
2892         else
2893                 mod_active = 0;
2894
2895         if(autocvar__hud_configure)
2896         {
2897                 redflag = 1;
2898                 blueflag = 2;
2899         }
2900
2901         // when status CHANGES, set old status into prevstatus and current status into status
2902         if (redflag != redflag_prevframe)
2903         {
2904                 redflag_statuschange_time = time;
2905                 redflag_prevstatus = redflag_prevframe;
2906                 redflag_prevframe = redflag;
2907         }
2908
2909         if (blueflag != blueflag_prevframe)
2910         {
2911                 blueflag_statuschange_time = time;
2912                 blueflag_prevstatus = blueflag_prevframe;
2913                 blueflag_prevframe = blueflag;
2914         }
2915
2916         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2917         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2918
2919         float BLINK_FACTOR = 0.15;
2920         float BLINK_BASE = 0.85;
2921         // note:
2922         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2923         // thus
2924         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2925         // ensure RMS == 1
2926         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2927
2928         string red_icon, red_icon_prevstatus;
2929         float red_alpha, red_alpha_prevstatus;
2930         red_alpha = red_alpha_prevstatus = 1;
2931         switch(redflag) {
2932                 case 1: red_icon = "flag_red_taken"; break;
2933                 case 2: red_icon = "flag_red_lost"; break;
2934                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2935                 default:
2936                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2937                                 red_icon = "flag_red_shielded";
2938                         else
2939                                 red_icon = string_null;
2940                         break;
2941         }
2942         switch(redflag_prevstatus) {
2943                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2944                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2945                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2946                 default:
2947                         if(redflag == 3)
2948                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2949                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2950                                 red_icon_prevstatus = "flag_red_shielded";
2951                         else
2952                                 red_icon_prevstatus = string_null;
2953                         break;
2954         }
2955
2956         string blue_icon, blue_icon_prevstatus;
2957         float blue_alpha, blue_alpha_prevstatus;
2958         blue_alpha = blue_alpha_prevstatus = 1;
2959         switch(blueflag) {
2960                 case 1: blue_icon = "flag_blue_taken"; break;
2961                 case 2: blue_icon = "flag_blue_lost"; break;
2962                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2963                 default:
2964                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2965                                 blue_icon = "flag_blue_shielded";
2966                         else
2967                                 blue_icon = string_null;
2968                         break;
2969         }
2970         switch(blueflag_prevstatus) {
2971                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2972                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2973                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2974                 default:
2975                         if(blueflag == 3)
2976                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2977                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2978                                 blue_icon_prevstatus = "flag_blue_shielded";
2979                         else
2980                                 blue_icon_prevstatus = string_null;
2981                         break;
2982         }
2983
2984         if(mySize.x > mySize.y) {
2985                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2986                         redflag_pos = pos;
2987                         blueflag_pos = pos + eX * 0.5 * mySize.x;
2988                 } else {
2989                         blueflag_pos = pos;
2990                         redflag_pos = pos + eX * 0.5 * mySize.x;
2991                 }
2992                 flag_size = eX * 0.5 * mySize.x + eY * mySize.y;
2993         } else {
2994                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2995                         redflag_pos = pos;
2996                         blueflag_pos = pos + eY * 0.5 * mySize.y;
2997                 } else {
2998                         blueflag_pos = pos;
2999                         redflag_pos = pos + eY * 0.5 * mySize.y;
3000                 }
3001                 flag_size = eY * 0.5 * mySize.y + eX * mySize.x;
3002         }
3003
3004         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
3005         if(red_icon_prevstatus && f < 1)
3006                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
3007         if(red_icon)
3008                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
3009
3010         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
3011         if(blue_icon_prevstatus && f < 1)
3012                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
3013         if(blue_icon)
3014                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
3015 }
3016
3017 // Keyhunt HUD modicon section
3018 vector KH_SLOTS[4];
3019
3020 void HUD_Mod_KH(vector pos, vector mySize)
3021 {
3022         mod_active = 1; // keyhunt should never hide the mod icons panel
3023
3024         // Read current state
3025
3026         int state = getstati(STAT_KH_KEYS);
3027         int i, key_state;
3028         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3029         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3030
3031         for(i = 0; i < 4; ++i)
3032         {
3033                 key_state = (bitshift(state, i * -5) & 31) - 1;
3034
3035                 if(key_state == -1)
3036                         continue;
3037
3038                 if(key_state == 30)
3039                 {
3040                         ++carrying_keys;
3041                         key_state = myteam;
3042                 }
3043
3044                 switch(key_state)
3045                 {
3046                         case NUM_TEAM_1: ++team1_keys; break;
3047                         case NUM_TEAM_2: ++team2_keys; break;
3048                         case NUM_TEAM_3: ++team3_keys; break;
3049                         case NUM_TEAM_4: ++team4_keys; break;
3050                         case 29: ++dropped_keys; break;
3051                 }
3052
3053                 ++all_keys;
3054         }
3055
3056         // Calculate slot measurements
3057
3058         vector slot_size;
3059
3060         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3061         {
3062                 // Quadratic arrangement
3063                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3064                 KH_SLOTS[0] = pos;
3065                 KH_SLOTS[1] = pos + eX * slot_size.x;
3066                 KH_SLOTS[2] = pos + eY * slot_size.y;
3067                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3068         }
3069         else
3070         {
3071                 if(mySize.x > mySize.y)
3072                 {
3073                         // Horizontal arrangement
3074                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3075                         for(i = 0; i < all_keys; ++i)
3076                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3077                 }
3078                 else
3079                 {
3080                         // Vertical arrangement
3081                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3082                         for(i = 0; i < all_keys; ++i)
3083                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3084                 }
3085         }
3086
3087         // Make icons blink in case of RUN HERE
3088
3089         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3090         float alpha;
3091         alpha = 1;
3092
3093         if(carrying_keys)
3094                 switch(myteam)
3095                 {
3096                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3097                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3098                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3099                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3100                 }
3101
3102         // Draw icons
3103
3104         i = 0;
3105
3106         while(team1_keys--)
3107                 if(myteam == NUM_TEAM_1 && carrying_keys)
3108                 {
3109                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3110                         --carrying_keys;
3111                 }
3112                 else
3113                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3114
3115         while(team2_keys--)
3116                 if(myteam == NUM_TEAM_2 && carrying_keys)
3117                 {
3118                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3119                         --carrying_keys;
3120                 }
3121                 else
3122                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3123
3124         while(team3_keys--)
3125                 if(myteam == NUM_TEAM_3 && carrying_keys)
3126                 {
3127                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3128                         --carrying_keys;
3129                 }
3130                 else
3131                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3132
3133         while(team4_keys--)
3134                 if(myteam == NUM_TEAM_4 && carrying_keys)
3135                 {
3136                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3137                         --carrying_keys;
3138                 }
3139                 else
3140                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3141
3142         while(dropped_keys--)
3143                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3144 }
3145
3146 // Keepaway HUD mod icon
3147 int kaball_prevstatus; // last remembered status
3148 float kaball_statuschange_time; // time when the status changed
3149
3150 // we don't need to reset for keepaway since it immediately
3151 // autocorrects prevstatus as to if the player has the ball or not
3152
3153 void HUD_Mod_Keepaway(vector pos, vector mySize)
3154 {
3155         mod_active = 1; // keepaway should always show the mod HUD
3156
3157         float BLINK_FACTOR = 0.15;
3158         float BLINK_BASE = 0.85;
3159         float BLINK_FREQ = 5;
3160         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3161
3162         int stat_items = getstati(STAT_ITEMS, 0, 24);
3163         int kaball = (stat_items/IT_KEY1) & 1;
3164
3165         if(kaball != kaball_prevstatus)
3166         {
3167                 kaball_statuschange_time = time;
3168                 kaball_prevstatus = kaball;
3169         }
3170
3171         vector kaball_pos, kaball_size;
3172
3173         if(mySize.x > mySize.y) {
3174                 kaball_pos = pos + eX * 0.25 * mySize.x;
3175                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3176         } else {
3177                 kaball_pos = pos + eY * 0.25 * mySize.y;
3178                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3179         }
3180
3181         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3182         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3183
3184         if(kaball_prevstatus && f < 1)
3185                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3186
3187         if(kaball)
3188                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3189 }
3190
3191
3192 // Nexball HUD mod icon
3193 void HUD_Mod_NexBall(vector pos, vector mySize)
3194 {
3195         float nb_pb_starttime, dt, p;
3196         int stat_items;
3197
3198         stat_items = getstati(STAT_ITEMS, 0, 24);
3199         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3200
3201         if (stat_items & IT_KEY1)
3202                 mod_active = 1;
3203         else
3204                 mod_active = 0;
3205
3206         //Manage the progress bar if any
3207         if (nb_pb_starttime > 0)
3208         {
3209                 dt = (time - nb_pb_starttime) % nb_pb_period;
3210                 // one period of positive triangle
3211                 p = 2 * dt / nb_pb_period;
3212                 if (p > 1)
3213                         p = 2 - p;
3214
3215                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3216         }
3217
3218         if (stat_items & IT_KEY1)
3219                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3220 }
3221
3222 // Race/CTS HUD mod icons
3223 float crecordtime_prev; // last remembered crecordtime
3224 float crecordtime_change_time; // time when crecordtime last changed
3225 float srecordtime_prev; // last remembered srecordtime
3226 float srecordtime_change_time; // time when srecordtime last changed
3227
3228 float race_status_time;
3229 int race_status_prev;
3230 string race_status_name_prev;
3231 void HUD_Mod_Race(vector pos, vector mySize)
3232 {
3233         mod_active = 1; // race should never hide the mod icons panel
3234         entity me;
3235         me = playerslots[player_localnum];
3236         float t, score;
3237         float f; // yet another function has this
3238         score = me.(scores[ps_primary]);
3239
3240         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3241                 return; // no records in the actual race
3242
3243         // clientside personal record
3244         string rr;
3245         if(gametype == MAPINFO_TYPE_CTS)
3246                 rr = CTS_RECORD;
3247         else
3248                 rr = RACE_RECORD;
3249         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3250
3251         if(score && (score < t || !t)) {
3252                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3253                 if(autocvar_cl_autodemo_delete_keeprecords)
3254                 {
3255                         f = autocvar_cl_autodemo_delete;
3256                         f &= ~1;
3257                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3258                 }
3259         }
3260
3261         if(t != crecordtime_prev) {
3262                 crecordtime_prev = t;
3263                 crecordtime_change_time = time;
3264         }
3265
3266         vector textPos, medalPos;
3267         float squareSize;
3268         if(mySize.x > mySize.y) {
3269                 // text on left side
3270                 squareSize = min(mySize.y, mySize.x/2);
3271                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3272                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3273         } else {
3274                 // text on top
3275                 squareSize = min(mySize.x, mySize.y/2);
3276                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3277                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3278         }
3279
3280         f = time - crecordtime_change_time;
3281
3282         if (f > 1) {
3283                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3284                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3285         } else {
3286                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3287                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3288                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3289                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3290         }
3291
3292         // server record
3293         t = race_server_record;
3294         if(t != srecordtime_prev) {
3295                 srecordtime_prev = t;
3296                 srecordtime_change_time = time;
3297         }
3298         f = time - srecordtime_change_time;
3299
3300         if (f > 1) {
3301                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3302                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3303         } else {
3304                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3305                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3306                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3307                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3308         }
3309
3310         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3311                 race_status_time = time + 5;
3312                 race_status_prev = race_status;
3313                 if (race_status_name_prev)
3314                         strunzone(race_status_name_prev);
3315                 race_status_name_prev = strzone(race_status_name);
3316         }
3317
3318         // race "awards"
3319         float a;
3320         a = bound(0, race_status_time - time, 1);
3321
3322         string s;
3323         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3324
3325         float rank;
3326         if(race_status > 0)
3327                 rank = race_CheckName(race_status_name);
3328         else
3329                 rank = 0;
3330         string rankname;
3331         rankname = count_ordinal(rank);
3332
3333         vector namepos;
3334         namepos = medalPos + '0 0.8 0' * squareSize;
3335         vector rankpos;
3336         rankpos = medalPos + '0 0.15 0' * squareSize;
3337
3338         if(race_status == 0)
3339                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3340         else if(race_status == 1) {
3341                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3342                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3343                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3344         } else if(race_status == 2) {
3345                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3346                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3347                 else
3348                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3349                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3350                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3351         } else if(race_status == 3) {
3352                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3353                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3354                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3355         }
3356
3357         if (race_status_time - time <= 0) {
3358                 race_status_prev = -1;
3359                 race_status = -1;
3360                 if(race_status_name)
3361                         strunzone(race_status_name);
3362                 race_status_name = string_null;
3363                 if(race_status_name_prev)
3364                         strunzone(race_status_name_prev);
3365                 race_status_name_prev = string_null;
3366         }
3367 }
3368
3369 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
3370 {
3371         float stat = -1;
3372         string pic = "";
3373         vector color = '0 0 0';
3374         switch(i)
3375         {
3376                 case 0:
3377                         stat = getstatf(STAT_DOM_PPS_RED);
3378                         pic = "dom_icon_red";
3379                         color = '1 0 0';
3380                         break;
3381                 case 1:
3382                         stat = getstatf(STAT_DOM_PPS_BLUE);
3383                         pic = "dom_icon_blue";
3384                         color = '0 0 1';
3385                         break;
3386                 case 2:
3387                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3388                         pic = "dom_icon_yellow";
3389                         color = '1 1 0';
3390                         break;
3391                 default:
3392                 case 3:
3393                         stat = getstatf(STAT_DOM_PPS_PINK);
3394                         pic = "dom_icon_pink";
3395                         color = '1 0 1';
3396                         break;
3397         }
3398         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3399
3400         if(mySize.x/mySize.y > aspect_ratio)
3401         {
3402                 i = aspect_ratio * mySize.y;
3403                 myPos.x = myPos.x + (mySize.x - i) / 2;
3404                 mySize.x = i;
3405         }
3406         else
3407         {
3408                 i = 1/aspect_ratio * mySize.x;
3409                 myPos.y = myPos.y + (mySize.y - i) / 2;
3410                 mySize.y = i;
3411         }
3412
3413         if (layout) // show text too
3414         {
3415                 //draw the text
3416                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3417                 if (layout == 2) // average pps
3418                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3419                 else // percentage of average pps
3420                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3421         }
3422
3423         //draw the icon
3424         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3425         if (stat > 0)
3426         {
3427                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3428                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3429                 drawresetcliparea();
3430         }
3431 }
3432
3433 void HUD_Mod_Dom(vector myPos, vector mySize)
3434 {
3435         mod_active = 1; // required in each mod function that always shows something
3436
3437         int layout = autocvar_hud_panel_modicons_dom_layout;
3438         int rows, columns;
3439         float aspect_ratio;
3440         aspect_ratio = (layout) ? 3 : 1;
3441         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3442         columns = ceil(team_count/rows);
3443
3444         int i;
3445         float row = 0, column = 0;
3446         vector pos, itemSize;
3447         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3448         for(i=0; i<team_count; ++i)
3449         {
3450                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3451
3452                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3453
3454                 ++row;
3455                 if(row >= rows)
3456                 {
3457                         row = 0;
3458                         ++column;
3459                 }
3460         }
3461 }
3462
3463 void HUD_ModIcons_SetFunc()
3464 {
3465         switch(gametype)
3466         {
3467                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3468                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3469                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3470                 case MAPINFO_TYPE_CTS:
3471                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3472                 case MAPINFO_TYPE_CA:
3473                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3474                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3475                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3476         }
3477 }
3478
3479 int mod_prev; // previous state of mod_active to check for a change
3480 float mod_alpha;
3481 float mod_change; // "time" when mod_active changed
3482
3483 void HUD_ModIcons(void)
3484 {
3485         if(!autocvar__hud_configure)
3486         {
3487                 if(!autocvar_hud_panel_modicons) return;
3488                 if(!HUD_ModIcons_GameType) return;
3489         }
3490
3491         HUD_Panel_UpdateCvars();
3492
3493         draw_beginBoldFont();
3494
3495         if(mod_active != mod_prev) {
3496                 mod_change = time;
3497                 mod_prev = mod_active;
3498         }
3499
3500         if(mod_active || autocvar__hud_configure)
3501                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3502         else
3503                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3504
3505         if(mod_alpha)
3506                 HUD_Panel_DrawBg(mod_alpha);
3507
3508         if(panel_bg_padding)
3509         {
3510                 panel_pos += '1 1 0' * panel_bg_padding;
3511                 panel_size -= '2 2 0' * panel_bg_padding;
3512         }
3513
3514         if(autocvar__hud_configure)
3515                 HUD_Mod_CTF(panel_pos, panel_size);
3516         else
3517                 HUD_ModIcons_GameType(panel_pos, panel_size);
3518
3519         draw_endBoldFont();
3520 }
3521
3522 // Draw pressed keys (#11)
3523 //
3524 void HUD_PressedKeys(void)
3525 {
3526         if(!autocvar__hud_configure)
3527         {
3528                 if(!autocvar_hud_panel_pressedkeys) return;
3529                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3530         }
3531
3532         HUD_Panel_UpdateCvars();
3533         vector pos, mySize;
3534         pos = panel_pos;
3535         mySize = panel_size;
3536
3537         HUD_Panel_DrawBg(1);
3538         if(panel_bg_padding)
3539         {
3540                 pos += '1 1 0' * panel_bg_padding;
3541                 mySize -= '2 2 0' * panel_bg_padding;
3542         }
3543
3544         // force custom aspect
3545         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3546         if(aspect)
3547         {
3548                 vector newSize = '0 0 0';
3549                 if(mySize.x/mySize.y > aspect)
3550                 {
3551                         newSize.x = aspect * mySize.y;
3552                         newSize.y = mySize.y;
3553
3554                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3555                 }
3556                 else
3557                 {
3558                         newSize.y = 1/aspect * mySize.x;
3559                         newSize.x = mySize.x;
3560
3561                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3562                 }
3563                 mySize = newSize;
3564         }
3565
3566         vector keysize;
3567         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3568         float pressedkeys;
3569         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3570
3571         if(autocvar_hud_panel_pressedkeys_attack)
3572         {
3573                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3574                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3575                 pos.y += keysize.y;
3576         }
3577
3578         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3579         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3580         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3581         pos.y += keysize.y;
3582         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3583         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3584         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3585 }
3586
3587 // Handle chat as a panel (#12)
3588 //
3589 void HUD_Chat(void)
3590 {
3591         if(!autocvar__hud_configure)
3592         {
3593                 if (!autocvar_hud_panel_chat)
3594                 {
3595                         if (!autocvar_con_chatrect)
3596                                 cvar_set("con_chatrect", "0");
3597                         return;
3598                 }
3599                 if(autocvar__con_chat_maximized)
3600                 {
3601                         if(!hud_draw_maximized) return;
3602                 }
3603                 else if(chat_panel_modified)
3604                 {
3605                         panel.update_time = time; // forces reload of panel attributes
3606                         chat_panel_modified = false;
3607                 }
3608         }
3609
3610         HUD_Panel_UpdateCvars();
3611
3612         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3613         {
3614                 panel_pos.y = panel_bg_border;
3615                 panel_size.y = vid_conheight - panel_bg_border * 2;
3616                 if(panel.current_panel_bg == "0") // force a border when maximized
3617                 {
3618                         string panel_bg;
3619                         panel_bg = strcat(hud_skin_path, "/border_default");
3620                         if(precache_pic(panel_bg) == "")
3621                                 panel_bg = "gfx/hud/default/border_default";
3622                         if(panel.current_panel_bg)
3623                                 strunzone(panel.current_panel_bg);
3624                         panel.current_panel_bg = strzone(panel_bg);
3625                         chat_panel_modified = true;
3626                 }
3627                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3628         }
3629
3630         vector pos, mySize;
3631         pos = panel_pos;
3632         mySize = panel_size;
3633
3634         HUD_Panel_DrawBg(1);
3635
3636         if(panel_bg_padding)
3637         {
3638                 pos += '1 1 0' * panel_bg_padding;
3639                 mySize -= '2 2 0' * panel_bg_padding;
3640         }
3641
3642         if (!autocvar_con_chatrect)
3643                 cvar_set("con_chatrect", "1");
3644
3645         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3646         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3647
3648         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3649         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3650
3651         if(autocvar__hud_configure)
3652         {
3653                 vector chatsize;
3654                 chatsize = '1 1 0' * autocvar_con_chatsize;
3655                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3656                 float i, a;
3657                 for(i = 0; i < autocvar_con_chat; ++i)
3658                 {
3659                         if(i == autocvar_con_chat - 1)
3660                                 a = panel_fg_alpha;
3661                         else
3662                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3663                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3664                         pos.y += chatsize.y;
3665                 }
3666         }
3667 }
3668
3669 // Engine info panel (#13)
3670 //
3671 float prevfps;
3672 float prevfps_time;
3673 int framecounter;
3674
3675 float frametimeavg;
3676 float frametimeavg1; // 1 frame ago
3677 float frametimeavg2; // 2 frames ago
3678 void HUD_EngineInfo(void)
3679 {
3680         if(!autocvar__hud_configure)
3681         {
3682                 if(!autocvar_hud_panel_engineinfo) return;
3683         }
3684
3685         HUD_Panel_UpdateCvars();
3686         vector pos, mySize;
3687         pos = panel_pos;
3688         mySize = panel_size;
3689
3690         HUD_Panel_DrawBg(1);
3691         if(panel_bg_padding)
3692         {
3693                 pos += '1 1 0' * panel_bg_padding;
3694                 mySize -= '2 2 0' * panel_bg_padding;
3695         }
3696
3697         float currentTime = gettime(GETTIME_REALTIME);
3698         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3699         {
3700                 float currentframetime = currentTime - prevfps_time;
3701                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3702                 frametimeavg2 = frametimeavg1;
3703                 frametimeavg1 = frametimeavg;
3704
3705                 float weight;
3706                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3707                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3708                 {
3709                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3710                                 prevfps = (1/currentframetime);
3711                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3712                 }
3713                 prevfps_time = currentTime;
3714         }
3715         else
3716         {
3717                 framecounter += 1;
3718                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3719                 {
3720                         prevfps = framecounter/(currentTime - prevfps_time);
3721                         framecounter = 0;
3722                         prevfps_time = currentTime;
3723                 }
3724         }
3725
3726         vector color;
3727         color = HUD_Get_Num_Color (prevfps, 100);
3728         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3729 }
3730
3731 // Info messages panel (#14)
3732 //
3733 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3734         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3735                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3736         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3737         o.y += fontsize.y;                                                                                                                                                                                              \
3738 } while(0)
3739 void HUD_InfoMessages(void)
3740 {
3741         if(!autocvar__hud_configure)
3742         {
3743                 if(!autocvar_hud_panel_infomessages) return;
3744         }
3745
3746         HUD_Panel_UpdateCvars();
3747         vector pos, mySize;
3748         pos = panel_pos;
3749         mySize = panel_size;
3750
3751         HUD_Panel_DrawBg(1);
3752         if(panel_bg_padding)
3753         {
3754                 pos += '1 1 0' * panel_bg_padding;
3755                 mySize -= '2 2 0' * panel_bg_padding;
3756         }
3757
3758         // always force 5:1 aspect
3759         vector newSize = '0 0 0';
3760         if(mySize.x/mySize.y > 5)
3761         {
3762                 newSize.x = 5 * mySize.y;
3763                 newSize.y = mySize.y;
3764
3765                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3766         }
3767         else
3768         {
3769                 newSize.y = 1/5 * mySize.x;
3770                 newSize.x = mySize.x;
3771
3772                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3773         }
3774
3775         mySize = newSize;
3776         entity tm;
3777         vector o;
3778         o = pos;
3779
3780         vector fontsize;
3781         fontsize = '0.20 0.20 0' * mySize.y;
3782
3783         float a;
3784         a = panel_fg_alpha;
3785
3786         string s;
3787         if(!autocvar__hud_configure)
3788         {
3789                 if(spectatee_status && !intermission)
3790                 {
3791                         a = 1;
3792                         if(spectatee_status == -1)
3793                                 s = _("^1Observing");
3794                         else
3795                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3796                         drawInfoMessage(s);
3797
3798                         if(spectatee_status == -1)
3799                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3800                         else
3801                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3802                         drawInfoMessage(s);
3803
3804                         if(spectatee_status == -1)
3805                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3806                         else
3807                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3808                         drawInfoMessage(s);
3809
3810                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3811                         drawInfoMessage(s);
3812
3813                         if(gametype == MAPINFO_TYPE_LMS)
3814                         {
3815                                 entity sk;
3816                                 sk = playerslots[player_localnum];
3817                                 if(sk.(scores[ps_primary]) >= 666)
3818                                         s = _("^1Match has already begun");
3819                                 else if(sk.(scores[ps_primary]) > 0)
3820                                         s = _("^1You have no more lives left");
3821                                 else
3822                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3823                         }
3824                         else
3825                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3826                         drawInfoMessage(s);
3827
3828                         //show restart countdown:
3829                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3830                                 float countdown;
3831                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3832                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3833                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3834                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3835                                 o.y += fontsize.y;
3836                         }
3837                 }
3838                 if(warmup_stage && !intermission)
3839                 {
3840                         s = _("^2Currently in ^1warmup^2 stage!");
3841                         drawInfoMessage(s);
3842                 }
3843
3844                 string blinkcolor;
3845                 if(time % 1 >= 0.5)
3846                         blinkcolor = "^1";
3847                 else
3848                         blinkcolor = "^3";
3849
3850                 if(ready_waiting && !intermission && !spectatee_status)
3851                 {
3852                         if(ready_waiting_for_me)
3853                         {
3854                                 if(warmup_stage)
3855                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3856                                 else
3857                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3858                         }
3859                         else
3860                         {
3861                                 if(warmup_stage)
3862                                         s = _("^2Waiting for others to ready up to end warmup...");
3863                                 else
3864                                         s = _("^2Waiting for others to ready up...");
3865                         }
3866                         drawInfoMessage(s);
3867                 }
3868                 else if(warmup_stage && !intermission && !spectatee_status)
3869                 {
3870                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3871                         drawInfoMessage(s);
3872                 }
3873
3874                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3875                 {
3876                         float ts_min = 0, ts_max = 0;
3877                         tm = teams.sort_next;
3878                         if (tm)
3879                         {
3880                                 for (; tm.sort_next; tm = tm.sort_next)
3881                                 {
3882                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3883                                                 continue;
3884                                         if(!ts_min) ts_min = tm.team_size;
3885                                         else ts_min = min(ts_min, tm.team_size);
3886                                         if(!ts_max) ts_max = tm.team_size;
3887                                         else ts_max = max(ts_max, tm.team_size);
3888                                 }
3889                                 if ((ts_max - ts_min) > 1)
3890                                 {
3891                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3892                                         tm = GetTeam(myteam, false);
3893                                         if (tm)
3894                                         if (tm.team != NUM_SPECTATOR)
3895                                         if (tm.team_size == ts_max)
3896                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3897                                         drawInfoMessage(s);
3898                                 }
3899                         }
3900                 }
3901         }
3902         else
3903         {
3904                 s = _("^7Press ^3ESC ^7to show HUD options.");
3905                 drawInfoMessage(s);
3906                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3907                 drawInfoMessage(s);
3908                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3909                 drawInfoMessage(s);
3910                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3911                 drawInfoMessage(s);
3912         }
3913 }
3914
3915 // Physics panel (#15)
3916 //
3917 vector acc_prevspeed;
3918 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3919 void HUD_Physics(void)
3920 {
3921         if(!autocvar__hud_configure)
3922         {
3923                 if(!autocvar_hud_panel_physics) return;
3924                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3925                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3926         }
3927
3928         HUD_Panel_UpdateCvars();
3929
3930         draw_beginBoldFont();
3931
3932         HUD_Panel_DrawBg(1);
3933         if(panel_bg_padding)
3934         {
3935                 panel_pos += '1 1 0' * panel_bg_padding;
3936                 panel_size -= '2 2 0' * panel_bg_padding;
3937         }
3938
3939         float acceleration_progressbar_scale = 0;
3940         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3941                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3942
3943         float text_scale;
3944         if (autocvar_hud_panel_physics_text_scale <= 0)
3945                 text_scale = 1;
3946         else
3947                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3948
3949         //compute speed
3950         float speed, conversion_factor;
3951         string unit;
3952
3953         switch(autocvar_hud_panel_physics_speed_unit)
3954         {
3955                 default:
3956                 case 1:
3957                         unit = _(" qu/s");
3958                         conversion_factor = 1.0;
3959                         break;
3960                 case 2:
3961                         unit = _(" m/s");
3962                         conversion_factor = 0.0254;
3963                         break;
3964                 case 3:
3965                         unit = _(" km/h");
3966                         conversion_factor = 0.0254 * 3.6;
3967                         break;
3968                 case 4:
3969                         unit = _(" mph");
3970                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3971                         break;
3972                 case 5:
3973                         unit = _(" knots");
3974                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3975                         break;
3976         }
3977
3978         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3979
3980         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3981         if (autocvar__hud_configure)
3982                 speed = floor( max_speed * 0.65 + 0.5 );
3983         else if(autocvar_hud_panel_physics_speed_vertical)
3984                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3985         else
3986                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
3987
3988         //compute acceleration
3989         float acceleration, f;
3990         if (autocvar__hud_configure)
3991                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3992         else
3993         {
3994                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3995                 f = time - acc_prevtime;
3996                 if(autocvar_hud_panel_physics_acceleration_vertical)
3997                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3998                 else
3999                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
4000
4001                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
4002
4003                 acc_prevspeed = vel;
4004                 acc_prevtime = time;
4005
4006                 f = bound(0, f * 10, 1);
4007                 acc_avg = acc_avg * (1 - f) + acceleration * f;
4008         }
4009
4010         //compute layout
4011         float panel_ar = panel_size.x/panel_size.y;
4012         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
4013         if (panel_ar >= 5 && !acceleration_progressbar_scale)
4014         {
4015                 panel_size.x *= 0.5;
4016                 if (autocvar_hud_panel_physics_flip)
4017                         speed_offset.x = panel_size.x;
4018                 else
4019                         acceleration_offset.x = panel_size.x;
4020         }
4021         else
4022         {
4023                 panel_size.y *= 0.5;
4024                 if (autocvar_hud_panel_physics_flip)
4025                         speed_offset.y = panel_size.y;
4026                 else
4027                         acceleration_offset.y = panel_size.y;
4028         }
4029         int speed_baralign, acceleration_baralign;
4030         if (autocvar_hud_panel_physics_baralign == 1)
4031                 acceleration_baralign = speed_baralign = 1;
4032     else if(autocvar_hud_panel_physics_baralign == 4)
4033                 acceleration_baralign = speed_baralign = 2;
4034         else if (autocvar_hud_panel_physics_flip)
4035         {
4036                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
4037                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
4038         }
4039         else
4040         {
4041                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
4042                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
4043         }
4044         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
4045                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
4046
4047         //draw speed
4048         if(speed)
4049         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4050                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4051         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
4052         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4053         {
4054                 tmp_size.x = panel_size.x * 0.75;
4055                 tmp_size.y = panel_size.y * text_scale;
4056                 if (speed_baralign)
4057                         tmp_offset.x = panel_size.x - tmp_size.x;
4058                 //else
4059                         //tmp_offset_x = 0;
4060                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4061                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4062
4063                 //draw speed unit
4064                 if (speed_baralign)
4065                         tmp_offset.x = 0;
4066                 else
4067                         tmp_offset.x = tmp_size.x;
4068                 if (autocvar_hud_panel_physics_speed_unit_show)
4069                 {
4070                         //tmp_offset_y = 0;
4071                         tmp_size.x = panel_size.x * (1 - 0.75);
4072                         tmp_size.y = panel_size.y * 0.4 * text_scale;
4073                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
4074                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4075                 }
4076         }
4077
4078         //compute and draw top speed
4079         if (autocvar_hud_panel_physics_topspeed)
4080         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4081         {
4082                 if (autocvar__hud_configure)
4083                 {
4084                         top_speed = floor( max_speed * 0.75 + 0.5 );
4085                         f = 1;
4086                 }
4087                 else
4088                 {
4089                         if (speed >= top_speed)
4090                         {
4091                                 top_speed = speed;
4092                                 top_speed_time = time;
4093                         }
4094                         if (top_speed != 0)
4095                         {
4096                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4097                                 // divide by f to make it start from 1
4098                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4099                         }
4100             else //hide top speed 0, it would be stupid
4101                                 f = 0;
4102                 }
4103                 if (f > 0)
4104                 {
4105                         //top speed progressbar peak
4106                         if(speed < top_speed)
4107                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4108                         {
4109                                 float peak_offsetX;
4110                                 vector peak_size = '0 0 0';
4111                                 if (speed_baralign == 0)
4112                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4113                 else if (speed_baralign == 1)
4114                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4115                 else // if (speed_baralign == 2)
4116                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4117                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4118                 peak_size.y = panel_size.y;
4119                 if (speed_baralign == 2) // draw two peaks, on both sides
4120                 {
4121                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4122                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4123                 }
4124                 else
4125                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4126                         }
4127
4128                         //top speed
4129                         tmp_offset.y = panel_size.y * 0.4;
4130                         tmp_size.x = panel_size.x * (1 - 0.75);
4131                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4132                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4133                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4134                 }
4135                 else
4136                         top_speed = 0;
4137         }
4138
4139         //draw acceleration
4140         if(acceleration)
4141         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4142         {
4143                 vector progressbar_color;
4144                 if(acceleration < 0)
4145                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4146                 else
4147                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4148
4149                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4150                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4151                         f = sqrt(f);
4152
4153                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4154                 {
4155                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4156
4157                         if (acceleration_baralign == 1)
4158                                 tmp_offset.x = panel_size.x - tmp_size.x;
4159                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4160                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4161                         else
4162                                 tmp_offset.x = 0;
4163                         tmp_offset.y = 0;
4164                 }
4165                 else
4166                 {
4167                         tmp_size = panel_size;
4168                         tmp_offset = '0 0 0';
4169                 }
4170
4171                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4172         }
4173         tmp_size.x = panel_size.x;
4174         tmp_size.y = panel_size.y * text_scale;
4175         tmp_offset.x = 0;
4176         tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4177         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4178                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4179
4180         draw_endBoldFont();
4181 }
4182
4183 // CenterPrint (#16)
4184 //
4185 const int CENTERPRINT_MAX_MSGS = 10;
4186 const int CENTERPRINT_MAX_ENTRIES = 50;
4187 const float CENTERPRINT_SPACING = 0.7;
4188 int cpm_index;
4189 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4190 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
4191 float centerprint_time[CENTERPRINT_MAX_MSGS];
4192 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4193 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4194 bool centerprint_showing;
4195
4196 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
4197 {
4198         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4199         int i, j;
4200
4201         if(strMessage == "" && new_id == 0)
4202                 return;
4203
4204         // strip trailing newlines
4205         j = strlen(strMessage) - 1;
4206         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4207                 --j;
4208         if (j < strlen(strMessage) - 1)
4209                 strMessage = substring(strMessage, 0, j + 1);
4210
4211         if(strMessage == "" && new_id == 0)
4212                 return;
4213
4214         // strip leading newlines
4215         j = 0;
4216         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4217                 ++j;
4218         if (j > 0)
4219                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4220
4221         if(strMessage == "" && new_id == 0)
4222                 return;
4223
4224         if (!centerprint_showing)
4225                 centerprint_showing = true;
4226
4227         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4228         {
4229                 if (j == CENTERPRINT_MAX_MSGS)
4230                         j = 0;
4231                 if (new_id && new_id == centerprint_msgID[j])
4232                 {
4233                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4234                         {
4235                                 // fade out the current msg (duration and countdown_num are ignored)
4236                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4237                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4238                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4239                                 return;
4240                         }
4241                         break; // found a msg with the same id, at position j
4242                 }
4243         }
4244
4245         if (i == CENTERPRINT_MAX_MSGS)
4246         {
4247                 // a msg with the same id was not found, add the msg at the next position
4248                 --cpm_index;
4249                 if (cpm_index == -1)
4250                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4251                 j = cpm_index;
4252         }
4253         if(centerprint_messages[j])
4254                 strunzone(centerprint_messages[j]);
4255         centerprint_messages[j] = strzone(strMessage);
4256         centerprint_msgID[j] = new_id;
4257         if (duration < 0)
4258         {
4259                 centerprint_time[j] = -1;
4260                 centerprint_expire_time[j] = time;
4261         }
4262         else
4263         {
4264                 if(duration == 0)
4265                         duration = max(1, autocvar_hud_panel_centerprint_time);
4266                 centerprint_time[j] = duration;
4267                 centerprint_expire_time[j] = time + duration;
4268         }
4269         centerprint_countdown_num[j] = countdown_num;
4270 }
4271
4272 void centerprint_hud(string strMessage)
4273 {
4274         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4275 }
4276
4277 void reset_centerprint_messages(void)
4278 {
4279         int i;
4280         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4281         {
4282                 centerprint_expire_time[i] = 0;
4283                 centerprint_time[i] = 1;
4284                 centerprint_msgID[i] = 0;
4285                 if(centerprint_messages[i])
4286                         strunzone(centerprint_messages[i]);
4287                 centerprint_messages[i] = string_null;
4288         }
4289 }
4290 float hud_configure_cp_generation_time;
4291 void HUD_CenterPrint (void)
4292 {
4293         if(!autocvar__hud_configure)
4294         {
4295                 if(!autocvar_hud_panel_centerprint) return;
4296
4297                 if(hud_configure_prev)
4298                         reset_centerprint_messages();
4299         }
4300         else
4301         {
4302                 if(!hud_configure_prev)
4303                         reset_centerprint_messages();
4304                 if (time > hud_configure_cp_generation_time)
4305                 {
4306                         float r;
4307                         r = random();
4308                         if (r > 0.75)
4309                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4310                         else if (r > 0.5)
4311                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4312                         else
4313                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4314                         hud_configure_cp_generation_time = time + 1 + random()*4;
4315                 }
4316         }
4317
4318         // this panel fades only when the menu does
4319         float hud_fade_alpha_save = 0;
4320         if(scoreboard_fade_alpha)
4321         {
4322                 hud_fade_alpha_save = hud_fade_alpha;
4323                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4324         }
4325         HUD_Panel_UpdateCvars();
4326
4327         if(scoreboard_fade_alpha)
4328         {
4329                 hud_fade_alpha = hud_fade_alpha_save;
4330
4331                 // move the panel below the scoreboard
4332                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4333                         return;
4334                 vector target_pos;
4335
4336                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4337
4338                 if(target_pos.y > panel_pos.y)
4339                 {
4340                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4341                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4342                 }
4343         }
4344
4345         HUD_Panel_DrawBg(1);
4346
4347         if (!centerprint_showing)
4348                 return;
4349
4350         if(panel_bg_padding)
4351         {
4352                 panel_pos += '1 1 0' * panel_bg_padding;
4353                 panel_size -= '2 2 0' * panel_bg_padding;
4354         }
4355
4356         int entries;
4357         float height;
4358         vector fontsize;
4359         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4360         // height = panel_size_y/entries;
4361         // fontsize = '1 1 0' * height;
4362         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4363         fontsize = '1 1 0' * height;
4364         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4365
4366         int i, j, k, n, g;
4367         float a, sz, align, current_msg_posY = 0, msg_size;
4368         vector pos;
4369         string ts;
4370         bool all_messages_expired = true;
4371
4372         pos = panel_pos;
4373         if (autocvar_hud_panel_centerprint_flip)
4374                 pos.y += panel_size.y;
4375         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4376         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4377         {
4378                 if (j == CENTERPRINT_MAX_MSGS)
4379                         j = 0;
4380                 if (centerprint_expire_time[j] <= time)
4381                 {
4382                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4383                         {
4384                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4385                                 if (centerprint_countdown_num[j] == 0)
4386                                         continue;
4387                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4388                         }
4389                         else if(centerprint_time[j] != -1)
4390                                 continue;
4391                 }
4392
4393                 all_messages_expired = false;
4394
4395                 // fade the centerprint_hud in/out
4396                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4397                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4398                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4399                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4400                 else // Expiring soon, so fade it out.
4401                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4402
4403                 // while counting down show it anyway in order to hold the current message position
4404                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4405                         continue;
4406                 if (a > 1)
4407                         a = 1;
4408
4409                 // set the size from fading in/out before subsequent fading
4410                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4411
4412                 // also fade it based on positioning
4413                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4414                 {
4415                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4416                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4417                 }
4418                 a *= panel_fg_alpha;
4419
4420                 // finally set the size based on the new theAlpha from subsequent fading
4421                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4422                 drawfontscale = sz * '1 1 0';
4423
4424                 if (centerprint_countdown_num[j])
4425                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4426                 else
4427                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4428
4429                 if (autocvar_hud_panel_centerprint_flip)
4430                 {
4431                         // check if the message can be entirely shown
4432                         for(k = 0; k < n; ++k)
4433                         {
4434                                 getWrappedLine_remaining = argv(k);
4435                                 while(getWrappedLine_remaining)
4436                                 {
4437                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4438                                         if (ts != "")
4439                                                 pos.y -= fontsize.y;
4440                                         else
4441                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4442                                 }
4443                         }
4444                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4445                 }
4446
4447                 msg_size = pos.y;
4448                 for(k = 0; k < n; ++k)
4449                 {
4450                         getWrappedLine_remaining = argv(k);
4451                         while(getWrappedLine_remaining)
4452                         {
4453                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4454                                 if (ts != "")
4455                                 {
4456                                         if (align)
4457                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4458                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4459                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4460                                         pos.y += fontsize.y;
4461                                 }
4462                                 else
4463                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4464                         }
4465                 }
4466
4467                 ++g; // move next position number up
4468
4469                 msg_size = pos.y - msg_size;
4470                 if (autocvar_hud_panel_centerprint_flip)
4471                 {
4472                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4473                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4474                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4475
4476                         if (pos.y < panel_pos.y) // check if the next message can be shown
4477                         {
4478                                 drawfontscale = '1 1 0';
4479                                 return;
4480                         }
4481                 }
4482                 else
4483                 {
4484                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4485                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4486                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4487
4488                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4489                         {
4490                                 drawfontscale = '1 1 0';
4491                                 return;
4492                         }
4493                 }
4494         }
4495         drawfontscale = '1 1 0';
4496         if (all_messages_expired)
4497         {
4498                 centerprint_showing = false;
4499                 reset_centerprint_messages();
4500         }
4501 }
4502
4503 // Buffs (#18)
4504 //
4505 void HUD_Buffs(void)
4506 {
4507         int buffs = getstati(STAT_BUFFS, 0, 24);
4508         if(!autocvar__hud_configure)
4509         {
4510                 if(!autocvar_hud_panel_buffs) return;
4511                 if(spectatee_status == -1) return;
4512                 if(getstati(STAT_HEALTH) <= 0) return;
4513                 if(!buffs) return;
4514         }
4515         else
4516         {
4517                 buffs = Buff_Type_first.items; // force first buff
4518         }
4519
4520         int b = 0; // counter to tell other functions that we have buffs
4521         entity e;
4522         string s = "";
4523         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4524         {
4525                 ++b;
4526                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4527                 if(s == "")
4528                         s = o;
4529                 else
4530                         s = strcat(s, " ", o);
4531         }
4532
4533         HUD_Panel_UpdateCvars();
4534
4535         draw_beginBoldFont();
4536
4537         vector pos, mySize;
4538         pos = panel_pos;
4539         mySize = panel_size;
4540
4541         HUD_Panel_DrawBg(bound(0, b, 1));
4542         if(panel_bg_padding)
4543         {
4544                 pos += '1 1 0' * panel_bg_padding;
4545                 mySize -= '2 2 0' * panel_bg_padding;
4546         }
4547
4548         //float panel_ar = mySize_x/mySize_y;
4549         //bool is_vertical = (panel_ar < 1);
4550         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4551         vector buff_offset = '0 0 0';
4552
4553         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4554         {
4555                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4556                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4557         }
4558
4559         draw_endBoldFont();
4560 }
4561
4562
4563 // Minigame
4564 //
4565 #include "../common/minigames/cl_minigames_hud.qc"
4566
4567 /*
4568 ==================
4569 Main HUD system
4570 ==================
4571 */
4572
4573 bool HUD_Panel_CheckFlags(int showflags)
4574 {
4575         if ( HUD_Minigame_Showpanels() )
4576                 return showflags & PANEL_SHOW_MINIGAME;
4577         return showflags & PANEL_SHOW_MAINGAME;
4578 }
4579
4580 void HUD_Panel_Draw(entity panent)
4581 {
4582         panel = panent;
4583         if ( HUD_Panel_CheckFlags(panel.panel_showflags) )
4584                 panel.panel_draw();
4585 }
4586
4587 void HUD_Reset (void)
4588 {
4589         // reset gametype specific icons
4590         if(gametype == MAPINFO_TYPE_CTF)
4591                 HUD_Mod_CTF_Reset();
4592 }
4593
4594 void HUD_Main (void)
4595 {
4596         int i;
4597         // global hud theAlpha fade
4598         if(menu_enabled == 1)
4599                 hud_fade_alpha = 1;
4600         else
4601                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4602
4603         if(scoreboard_fade_alpha)
4604                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4605
4606         HUD_Configure_Frame();
4607
4608         if(intermission == 2) // no hud during mapvote
4609                 hud_fade_alpha = 0;
4610
4611         // panels that we want to be active together with the scoreboard
4612         // they must fade only when the menu does
4613         if(scoreboard_fade_alpha == 1)
4614         {
4615                 HUD_Panel_Draw(HUD_PANEL(CENTERPRINT));
4616                 return;
4617         }
4618
4619         if(!autocvar__hud_configure && !hud_fade_alpha)
4620         {
4621                 hud_fade_alpha = 1;
4622                 HUD_Panel_Draw(HUD_PANEL(VOTE));
4623                 hud_fade_alpha = 0;
4624                 return;
4625         }
4626
4627         // Drawing stuff
4628         if (hud_skin_prev != autocvar_hud_skin)
4629         {
4630                 if (hud_skin_path)
4631                         strunzone(hud_skin_path);
4632                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4633                 if (hud_skin_prev)
4634                         strunzone(hud_skin_prev);
4635                 hud_skin_prev = strzone(autocvar_hud_skin);
4636         }
4637
4638     current_player = player_localentnum;
4639
4640         // draw the dock
4641         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4642         {
4643                 int f;
4644                 vector color;
4645                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4646                 if((teamplay) && hud_dock_color_team) {
4647                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4648                                 color = '1 0 0' * hud_dock_color_team;
4649                         else
4650                                 color = myteamcolors * hud_dock_color_team;
4651                 }
4652                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4653                         color = '1 0 0' * hud_dock_color_team;
4654                 }
4655                 else
4656                 {
4657                         string hud_dock_color = autocvar_hud_dock_color;
4658                         if(hud_dock_color == "shirt") {
4659                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4660                                 color = colormapPaletteColor(floor(f / 16), 0);
4661                         }
4662                         else if(hud_dock_color == "pants") {
4663                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4664                                 color = colormapPaletteColor(f % 16, 1);
4665                         }
4666                         else
4667                                 color = stov(hud_dock_color);
4668                 }
4669
4670                 string pic;
4671                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4672                 if(precache_pic(pic) == "") {
4673                         pic = strcat(hud_skin_path, "/dock_medium");
4674                         if(precache_pic(pic) == "") {
4675                                 pic = "gfx/hud/default/dock_medium";
4676                         }
4677                 }
4678                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4679         }
4680
4681         // cache the panel order into the panel_order array
4682         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4683                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4684                         panel_order[i] = -1;
4685                 string s = "";
4686                 int p_num;
4687                 bool warning = false;
4688                 int argc = tokenize_console(autocvar__hud_panelorder);
4689                 if (argc > HUD_PANEL_NUM)
4690                         warning = true;
4691                 //first detect wrong/missing panel numbers
4692                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4693                         p_num = stoi(argv(i));
4694                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4695                                 if (panel_order[p_num] == -1) //found for the first time?
4696                                         s = strcat(s, ftos(p_num), " ");
4697                                 panel_order[p_num] = 1; //mark as found
4698                         }
4699                         else
4700                                 warning = true;
4701                 }
4702                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4703                         if (panel_order[i] == -1) {
4704                                 warning = true;
4705                                 s = strcat(s, ftos(i), " "); //add missing panel number
4706                         }
4707                 }
4708                 if (warning)
4709                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4710
4711                 cvar_set("_hud_panelorder", s);
4712                 if(hud_panelorder_prev)
4713                         strunzone(hud_panelorder_prev);
4714                 hud_panelorder_prev = strzone(s);
4715
4716                 //now properly set panel_order
4717                 tokenize_console(s);
4718                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4719                         panel_order[i] = stof(argv(i));
4720                 }
4721         }
4722
4723         hud_draw_maximized = 0;
4724         // draw panels in order specified by panel_order array
4725         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4726                 HUD_Panel_Draw(hud_panel[panel_order[i]]);
4727
4728         hud_draw_maximized = 1; // panels that may be maximized must check this var
4729         // draw maximized panels on top
4730         if(hud_panel_radar_maximized)
4731                 HUD_Panel_Draw(HUD_PANEL(RADAR));
4732         if(autocvar__con_chat_maximized)
4733                 HUD_Panel_Draw(HUD_PANEL(CHAT));
4734
4735         HUD_Configure_PostDraw();
4736
4737         hud_configure_prev = autocvar__hud_configure;
4738 }