qcsrc/client/hud.qh

   1 float log(float f);
   2
   3 vector centerprint_start;
   4
   5 float panel_order[HUD_PANEL_NUM];
   6 string hud_panelorder_prev;
   7
   8 vector mousepos;
   9 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
  10 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
  11 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
  12 var float highlightedPanel = -1;
  13 var float highlightedPanel_prev = -1;
  14 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
  15
  16 const float BORDER_MULTIPLIER = 0.25;
  17 float scoreboard_bottom;
  18 float weapon_hits[WEP_MAXCOUNT];
  19 float weapon_fired[WEP_MAXCOUNT];
  20
  21 #define acc_color(i) stov(cvar_string(strcat("hud_panel_weapons_accuracy_color", ftos(i))))
  22 #define MAX_ACCURACY_LEVELS 10
  23 float acc_lev[MAX_ACCURACY_LEVELS];
  24 float acc_levels;
  25
  26 float complain_weapon;
  27 string complain_weapon_name;
  28 float complain_weapon_type;
  29 float complain_weapon_time;
  30
  31 float ps_primary, ps_secondary;
  32 float ts_primary, ts_secondary;
  33
  34 float last_weapon;
  35 float weapontime;
  36
  37 float teamnagger;
  38 float hud_accuracy_hud;
  39 float hud_border_thickness;
  40 float hud_accuracy_border_thickness;
  41
  42 float hud_configure_checkcollisions;
  43 float hud_configure_prev;
  44
  45 float hudShiftState;
  46 const float S_SHIFT = 1;
  47 const float S_CTRL = 2;
  48 const float S_ALT = 4;
  49
  50 float disable_menu_alphacheck; // 0 = enable alpha check, 1 = disable for entire hud, 2 = disable for one panel
  51 float hud_fade_alpha;
  52
  53 string hud_skin_path;
  54
  55 var vector progressbar_color;
  56
  57 var float highlightedPanel_backup = -1;
  58 var vector panel_pos_backup;
  59 var vector panel_size_backup;
  60
  61 var float highlightedPanel_copied = -1; //this is good only to know if there is something copied
  62 var vector panel_size_copied;
  63
  64 var float active_panel; // this panel has recently referred the UpdateCvars macro
  65 var string panel_name;
  66 var float panel_enabled;
  67 var vector panel_pos;
  68 var vector panel_size;
  69 var string panel_bg;
  70 var string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
  71 var vector panel_bg_color;
  72 var string panel_bg_color_str;
  73 var float panel_bg_color_team;
  74 var string panel_bg_color_team_str;
  75 var float panel_fg_alpha;
  76 var float panel_bg_alpha;
  77 var string panel_bg_alpha_str;
  78 var float panel_bg_border;
  79 var string panel_bg_border_str;
  80 var float panel_bg_padding;
  81 var string panel_bg_padding_str;
  82 var float panel_accuracy_yellow;
  83 var float panel_accuracy_onlycurrent;
  84 var float panel_accuracy_flip;
  85 var float panel_accuracy_iconalign;
  86 var float panel_accuracy_baralign;
  87 var float panel_accuracy_info_top;
  88 var float panel_accuracy_foreground_alpha;
  89 var float panel_accuracy_alreadyvoted_alpha;
  90
  91 var string picpath;
  92
  93 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
  94 // ----------------------
  95 // MACRO HELL STARTS HERE
  96 // ----------------------
  97 // Little help for the poor people who have to make sense of this: Start from the bottom
  98
  99 #define HUD_Panel_GetProgressBarColor(item) \
 100 switch(item) {\
 101         case "strength": progressbar_color = autocvar_hud_progressbar_strength_color; break;\
 102         case "shield": progressbar_color = autocvar_hud_progressbar_shield_color; break;\
 103         case "health": progressbar_color = autocvar_hud_progressbar_health_color; break;\
 104         case "armor": progressbar_color = autocvar_hud_progressbar_armor_color; break;\
 105         case "fuel": progressbar_color = autocvar_hud_progressbar_fuel_color; break;\
 106         case "nexball": progressbar_color = autocvar_hud_progressbar_nexball_color; break;\
 107 }
 108
 109 // Get value for panel_bg: if "" fetch default, else use panel_bg_str
 110 // comment on last line of macro: // we probably want to see a background in config mode at all times...
 111 #define HUD_Panel_GetBg()\
 112 if(!autocvar__hud_configure && panel_bg_str == "0") {\
 113         panel_bg = "0";\
 114 } else {\
 115         if(panel_bg_str == "") {\
 116                 panel_bg = autocvar_hud_panel_bg;\
 117         } else if(panel_bg_str == "0" && autocvar__hud_configure) {\
 118                 panel_bg = autocvar_hud_panel_bg;\
 119                 panel_bg_alpha_str = "0";\
 120         } else {\
 121                 panel_bg = panel_bg_str;\
 122         }\
 123         panel_bg = strcat(hud_skin_path, "/", panel_bg);\
 124         if(precache_pic(panel_bg) == "") {\
 125                 panel_bg = strcat(hud_skin_path, "/", "border");\
 126                 if(precache_pic(panel_bg) == "") {\
 127                         panel_bg = strcat("gfx/hud/default/", "border");\
 128                 }\
 129         }\
 130 }
 131
 132 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 133 #define HUD_Panel_GetColor()\
 134 if((teamplay) && panel_bg_color_team) {\
 135         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkey(player_localentnum - 1, "colors")), 16), 1) * panel_bg_color_team;\
 136 } else if (autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && panel_bg_color_team) {\
 137         panel_bg_color = '1 0 0' * panel_bg_color_team;\
 138 } else {\
 139         if(panel_bg_color_str == "") {\
 140                 panel_bg_color = autocvar_hud_panel_bg_color;\
 141         } else {\
 142                 if(panel_bg_color_str == "shirt") {\
 143                         panel_bg_color = colormapPaletteColor(floor(stof(getplayerkey(player_localentnum - 1, "colors")) / 16), 0);\
 144                 } else if(panel_bg_color_str == "pants") {\
 145                         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkey(player_localentnum - 1, "colors")), 16), 1);\
 146                 } else {\
 147                         panel_bg_color = stov(panel_bg_color_str);\
 148                 }\
 149         }\
 150 }
 151
 152 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 153 #define HUD_Panel_GetColorTeam()\
 154 if(panel_bg_color_team_str == "") {\
 155         panel_bg_color_team = autocvar_hud_panel_bg_color_team;\
 156 } else {\
 157         panel_bg_color_team = stof(panel_bg_color_team_str);\
 158 }
 159
 160 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 161 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 162 #define HUD_Panel_GetBgAlpha()\
 163 if(panel_bg_alpha_str == "") {\
 164         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);\
 165 }\
 166 panel_bg_alpha = stof(panel_bg_alpha_str);\
 167 if(autocvar__hud_configure && disable_menu_alphacheck == 2 && highlightedPanel == active_panel) {\
 168         panel_bg_alpha = (1 - autocvar__menu_alpha) * max(autocvar_hud_configure_bg_minalpha, panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 169 } else if(autocvar__hud_configure) {\
 170         panel_bg_alpha = max(autocvar_hud_configure_bg_minalpha, panel_bg_alpha);\
 171 } if(autocvar__hud_configure && !panel_enabled) {\
 172         panel_bg_alpha = 0.25;\
 173 } if(!(disable_menu_alphacheck == 2 && highlightedPanel == active_panel)) {\
 174         panel_bg_alpha *= hud_fade_alpha;\
 175 }
 176
 177 // Get value for panel_fg_alpha. Also do various minalpha checks
 178 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 179 // comment on line 4 of macro: // don't fade this panel when showing the panel-specific menu dialog
 180 #define HUD_Panel_GetFgAlpha()\
 181 panel_fg_alpha = autocvar_hud_panel_fg_alpha;\
 182 if(autocvar__hud_configure && !panel_enabled)\
 183         panel_fg_alpha = 0.25;\
 184 if(!(disable_menu_alphacheck == 2 && highlightedPanel == active_panel))\
 185         panel_fg_alpha *= hud_fade_alpha;
 186
 187 // Get border. See comments above, it's similar.
 188 #define HUD_Panel_GetBorder()\
 189 if(panel_bg_border_str == "") {\
 190         panel_bg_border = autocvar_hud_panel_bg_border;\
 191 } else {\
 192         panel_bg_border = stof(panel_bg_border_str);\
 193 }
 194
 195 // Scale the pos and size vectors to absolute coordinates
 196 #define HUD_Panel_GetScaledVectors()\
 197 panel_pos_x *= vid_conwidth;\
 198 panel_pos_y *= vid_conheight;\
 199 panel_size_x *= vid_conwidth;\
 200 panel_size_y *= vid_conheight;
 201
 202 // Get padding. See comments above, it's similar.
 203 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 204 #define HUD_Panel_GetPadding()\
 205 if(panel_bg_padding_str == "") {\
 206         panel_bg_padding = autocvar_hud_panel_bg_padding;\
 207 } else {\
 208         panel_bg_padding = stof(panel_bg_padding_str);\
 209 }\
 210 panel_bg_padding = min(min(panel_size_x, panel_size_y)/2 - 5, panel_bg_padding);
 211
 212 // Point to the macros above (stupid max macro length)
 213 #define HUD_Panel_StringVars()\
 214 HUD_Panel_GetBg()\
 215 HUD_Panel_GetColorTeam()\
 216 HUD_Panel_GetColor()\
 217 HUD_Panel_GetBgAlpha()\
 218 HUD_Panel_GetFgAlpha()\
 219 HUD_Panel_GetBorder()\
 220 HUD_Panel_GetScaledVectors()\
 221 HUD_Panel_GetPadding()
 222
 223 // return smoothly faded pos of given panel when a dialog is active
 224 var vector menu_enable_panelpos;
 225 #define HUD_Panel_GetMenuPos() \
 226 if(panel_size_x > panel_size_y)\
 227         menu_enable_panelpos = eX * 0.5 * vid_conwidth - eX * 0.5 * panel_size_x + eY * 0.82 * vid_conheight;\
 228 else\
 229         menu_enable_panelpos = eY * 0.5 * vid_conheight - eY * 0.5 * panel_size_y + eX * 0.7 * vid_conwidth;\
 230 panel_pos = (1 - autocvar__menu_alpha) * panel_pos + (autocvar__menu_alpha) * menu_enable_panelpos;
 231
 232 // return smoothly faded size of given panel when a dialog is active
 233 var vector menu_enable_maxsize;
 234 var vector menu_enable_size;
 235 #define HUD_Panel_GetMenuSize()\
 236 menu_enable_maxsize_x = 0.3 * vid_conwidth;\
 237 menu_enable_maxsize_y = 0.18 * vid_conheight;\
 238 if(panel_size_x > panel_size_y)\
 239 {\
 240         if(panel_size_y > menu_enable_maxsize_y)\
 241         {\
 242                 menu_enable_size_y = menu_enable_maxsize_y;\
 243                 menu_enable_size_x = panel_size_x * (menu_enable_maxsize_y/panel_size_y);\
 244                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 245         }\
 246 }\
 247 else\
 248 {\
 249         if(panel_size_x > menu_enable_maxsize_x)\
 250         {\
 251                 menu_enable_size_x = menu_enable_maxsize_x;\
 252                 menu_enable_size_y = panel_size_y * (menu_enable_maxsize_x/panel_size_x);\
 253                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 254         }\
 255 }
 256
 257 // Update all common cvars of given panel name
 258 #define HUD_Panel_UpdateCvars(name) \
 259 panel_enabled = autocvar_hud_panel_##name; \
 260 panel_pos = autocvar_hud_panel_##name##_pos; \
 261 panel_size = autocvar_hud_panel_##name##_size; \
 262 panel_bg_str = autocvar_hud_panel_##name##_bg; \
 263 panel_bg_color_str = autocvar_hud_panel_##name##_bg_color; \
 264 panel_bg_color_team_str = autocvar_hud_panel_##name##_bg_color_team; \
 265 panel_bg_alpha_str = autocvar_hud_panel_##name##_bg_alpha; \
 266 panel_bg_border_str = autocvar_hud_panel_##name##_bg_border; \
 267 panel_bg_padding_str = autocvar_hud_panel_##name##_bg_padding; \
 268 HUD_Panel_StringVars()\
 269 if(disable_menu_alphacheck == 2 && active_panel == highlightedPanel) {\
 270         HUD_Panel_GetMenuSize()\
 271         HUD_Panel_GetMenuPos()\
 272 }
 273
 274 // Update all common cvars of given panel id
 275 #define HUD_Panel_UpdateCvarsForId(id) \
 276 switch(id) { \
 277         case HUD_PANEL_WEAPONS: HUD_Panel_UpdateCvars(weapons) break; \
 278         case HUD_PANEL_AMMO: HUD_Panel_UpdateCvars(ammo) break; \
 279         case HUD_PANEL_POWERUPS: HUD_Panel_UpdateCvars(powerups) break; \
 280         case HUD_PANEL_HEALTHARMOR: HUD_Panel_UpdateCvars(healtharmor) break; \
 281         case HUD_PANEL_NOTIFY: HUD_Panel_UpdateCvars(notify) break; \
 282         case HUD_PANEL_TIMER: HUD_Panel_UpdateCvars(timer) break; \
 283         case HUD_PANEL_RADAR: HUD_Panel_UpdateCvars(radar) break; \
 284         case HUD_PANEL_SCORE: HUD_Panel_UpdateCvars(score) break; \
 285         case HUD_PANEL_RACETIMER: HUD_Panel_UpdateCvars(racetimer) break; \
 286         case HUD_PANEL_VOTE: HUD_Panel_UpdateCvars(vote) break; \
 287         case HUD_PANEL_MODICONS: HUD_Panel_UpdateCvars(modicons) break; \
 288         case HUD_PANEL_PRESSEDKEYS: HUD_Panel_UpdateCvars(pressedkeys) break; \
 289         case HUD_PANEL_CHAT: HUD_Panel_UpdateCvars(chat) break; \
 290         case HUD_PANEL_ENGINEINFO: HUD_Panel_UpdateCvars(engineinfo) break; \
 291         case HUD_PANEL_INFOMESSAGES: HUD_Panel_UpdateCvars(infomessages) break; \
 292 }
 293
 294 #define HUD_Panel_UpdatePosSize(name) \
 295 panel_pos = autocvar_hud_panel_##name##_pos; \
 296 panel_size = autocvar_hud_panel_##name##_size; \
 297 HUD_Panel_GetScaledVectors()\
 298 if(disable_menu_alphacheck == 2 && active_panel == highlightedPanel) {\
 299         HUD_Panel_GetMenuSize()\
 300         HUD_Panel_GetMenuPos()\
 301 }\
 302 panel_bg_border_str = autocvar_hud_panel_##name##_bg_border; \
 303 HUD_Panel_GetBorder()
 304
 305 // Update pos and size of given panel id
 306 #define HUD_Panel_UpdatePosSizeForId(id) \
 307 switch(id) { \
 308         case HUD_PANEL_WEAPONS: HUD_Panel_UpdatePosSize(weapons) break;\
 309         case HUD_PANEL_AMMO: HUD_Panel_UpdatePosSize(ammo) break;\
 310         case HUD_PANEL_POWERUPS: HUD_Panel_UpdatePosSize(powerups) break;\
 311         case HUD_PANEL_HEALTHARMOR: HUD_Panel_UpdatePosSize(healtharmor) break;\
 312         case HUD_PANEL_NOTIFY: HUD_Panel_UpdatePosSize(notify) break;\
 313         case HUD_PANEL_TIMER: HUD_Panel_UpdatePosSize(timer) break;\
 314         case HUD_PANEL_RADAR: HUD_Panel_UpdatePosSize(radar) break;\
 315         case HUD_PANEL_SCORE: HUD_Panel_UpdatePosSize(score) break;\
 316         case HUD_PANEL_RACETIMER: HUD_Panel_UpdatePosSize(racetimer) break;\
 317         case HUD_PANEL_VOTE: HUD_Panel_UpdatePosSize(vote) break;\
 318         case HUD_PANEL_MODICONS: HUD_Panel_UpdatePosSize(modicons) break;\
 319         case HUD_PANEL_PRESSEDKEYS: HUD_Panel_UpdatePosSize(pressedkeys) break;\
 320         case HUD_PANEL_CHAT: HUD_Panel_UpdatePosSize(chat) break;\
 321         case HUD_PANEL_ENGINEINFO: HUD_Panel_UpdatePosSize(engineinfo) break;\
 322         case HUD_PANEL_INFOMESSAGES: HUD_Panel_UpdatePosSize(infomessages)\
 323 }