qcsrc/client/hud.qh

   1 float log(float f);
   2
   3 vector centerprint_start;
   4
   5 float panel_order[HUD_PANEL_NUM];
   6 string hud_panelorder_prev;
   7
   8 vector mousepos;
   9 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
  10 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
  11 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
  12 var float highlightedPanel = -1;
  13 var float highlightedPanel_prev = -1;
  14 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
  15
  16 const float BORDER_MULTIPLIER = 0.25;
  17 float scoreboard_bottom;
  18 float weapon_hits[WEP_MAXCOUNT];
  19 float weapon_fired[WEP_MAXCOUNT];
  20
  21 #define acc_color(i) stov(cvar_string(strcat("hud_panel_weapons_accuracy_color", ftos(i))))
  22 #define MAX_ACCURACY_LEVELS 10
  23 float acc_lev[MAX_ACCURACY_LEVELS];
  24 float acc_levels;
  25
  26 float complain_weapon;
  27 string complain_weapon_name;
  28 float complain_weapon_type;
  29 float complain_weapon_time;
  30
  31 float ps_primary, ps_secondary;
  32 float ts_primary, ts_secondary;
  33
  34 float last_weapon;
  35 float weapontime;
  36
  37 float teamnagger;
  38 float hud_accuracy_hud;
  39 float hud_border_thickness;
  40 float hud_accuracy_border_thickness;
  41
  42 float hud_configure_checkcollisions;
  43 float hud_configure_prev;
  44
  45 float hudShiftState;
  46 const float S_SHIFT = 1;
  47 const float S_CTRL = 2;
  48 const float S_ALT = 4;
  49
  50 float disable_menu_alphacheck; // 0 = enable alpha check, 1 = disable for entire hud, 2 = disable for one panel
  51 float hud_fade_alpha;
  52
  53 string hud_skin_path;
  54
  55 var vector progressbar_color;
  56
  57 var float active_panel; // this panel has recently referred the UpdateCvars macro
  58 var string panel_name;
  59 var float panel_enabled;
  60 var vector panel_pos;
  61 var vector panel_size;
  62 var string panel_bg;
  63 var string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
  64 var vector panel_bg_color;
  65 var string panel_bg_color_str;
  66 var float panel_bg_color_team;
  67 var string panel_bg_color_team_str;
  68 var float panel_fg_alpha;
  69 var float panel_bg_alpha;
  70 var string panel_bg_alpha_str;
  71 var float panel_bg_border;
  72 var string panel_bg_border_str;
  73 var float panel_bg_padding;
  74 var string panel_bg_padding_str;
  75 var float panel_accuracy_yellow;
  76 var float panel_accuracy_onlycurrent;
  77 var float panel_accuracy_flip;
  78 var float panel_accuracy_iconalign;
  79 var float panel_accuracy_baralign;
  80 var float panel_accuracy_info_top;
  81 var float panel_accuracy_foreground_alpha;
  82 var float panel_accuracy_alreadyvoted_alpha;
  83
  84 var string picpath;
  85
  86 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
  87 // ----------------------
  88 // MACRO HELL STARTS HERE
  89 // ----------------------
  90 // Little help for the poor people who have to make sense of this: Start from the bottom
  91
  92 #define HUD_Panel_GetProgressBarColor(item) \
  93 switch(item) {\
  94         case "strength": progressbar_color = autocvar_hud_progressbar_strength_color; break;\
  95         case "shield": progressbar_color = autocvar_hud_progressbar_shield_color; break;\
  96         case "health": progressbar_color = autocvar_hud_progressbar_health_color; break;\
  97         case "armor": progressbar_color = autocvar_hud_progressbar_armor_color; break;\
  98         case "fuel": progressbar_color = autocvar_hud_progressbar_fuel_color; break;\
  99         case "nexball": progressbar_color = autocvar_hud_progressbar_nexball_color; break;\
 100 }
 101
 102 // Get value for panel_bg: if "" fetch default, else use panel_bg_str
 103 // comment on last line of macro: // we probably want to see a background in config mode at all times...
 104 #define HUD_Panel_GetBg()\
 105 if(!autocvar__hud_configure && panel_bg_str == "0") {\
 106         panel_bg = "0";\
 107 } else {\
 108         if(panel_bg_str == "") {\
 109                 panel_bg = autocvar_hud_panel_bg;\
 110         } else if(panel_bg_str == "0" && autocvar__hud_configure) {\
 111                 panel_bg = autocvar_hud_panel_bg;\
 112                 panel_bg_alpha_str = "0";\
 113         } else {\
 114                 panel_bg = panel_bg_str;\
 115         }\
 116         panel_bg = strcat(hud_skin_path, "/", panel_bg);\
 117         if(precache_pic(panel_bg) == "") {\
 118                 panel_bg = strcat(hud_skin_path, "/", "border");\
 119                 if(precache_pic(panel_bg) == "") {\
 120                         panel_bg = strcat("gfx/hud/default/", "border");\
 121                 }\
 122         }\
 123 }
 124
 125 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 126 #define HUD_Panel_GetColor()\
 127 if((teamplay) && panel_bg_color_team) {\
 128         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkey(player_localentnum - 1, "colors")), 16), 1) * panel_bg_color_team;\
 129 } else if (autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && panel_bg_color_team) {\
 130         panel_bg_color = '1 0 0' * panel_bg_color_team;\
 131 } else {\
 132         if(panel_bg_color_str == "") {\
 133                 panel_bg_color = autocvar_hud_panel_bg_color;\
 134         } else {\
 135                 if(panel_bg_color_str == "shirt") {\
 136                         panel_bg_color = colormapPaletteColor(floor(stof(getplayerkey(player_localentnum - 1, "colors")) / 16), 0);\
 137                 } else if(panel_bg_color_str == "pants") {\
 138                         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkey(player_localentnum - 1, "colors")), 16), 1);\
 139                 } else {\
 140                         panel_bg_color = stov(panel_bg_color_str);\
 141                 }\
 142         }\
 143 }
 144
 145 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 146 #define HUD_Panel_GetColorTeam()\
 147 if(panel_bg_color_team_str == "") {\
 148         panel_bg_color_team = autocvar_hud_panel_bg_color_team;\
 149 } else {\
 150         panel_bg_color_team = stof(panel_bg_color_team_str);\
 151 }
 152
 153 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 154 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 155 #define HUD_Panel_GetBgAlpha()\
 156 if(panel_bg_alpha_str == "") {\
 157         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);\
 158 }\
 159 panel_bg_alpha = stof(panel_bg_alpha_str);\
 160 if(autocvar__hud_configure && disable_menu_alphacheck == 2 && highlightedPanel == active_panel) {\
 161         panel_bg_alpha = (1 - autocvar__menu_alpha) * max(autocvar_hud_configure_bg_minalpha, panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 162 } else if(autocvar__hud_configure) {\
 163         panel_bg_alpha = max(autocvar_hud_configure_bg_minalpha, panel_bg_alpha);\
 164 } if(autocvar__hud_configure && !panel_enabled) {\
 165         panel_bg_alpha = 0.25;\
 166 } if(!(disable_menu_alphacheck == 2 && highlightedPanel == active_panel)) {\
 167         panel_bg_alpha *= hud_fade_alpha;\
 168 }
 169
 170 // Get value for panel_fg_alpha. Also do various minalpha checks
 171 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 172 // comment on line 4 of macro: // don't fade this panel when showing the panel-specific menu dialog
 173 #define HUD_Panel_GetFgAlpha()\
 174 panel_fg_alpha = autocvar_hud_panel_fg_alpha;\
 175 if(autocvar__hud_configure && !panel_enabled)\
 176         panel_fg_alpha = 0.25;\
 177 if(!(disable_menu_alphacheck == 2 && highlightedPanel == active_panel))\
 178         panel_fg_alpha *= hud_fade_alpha;
 179
 180 // Get border. See comments above, it's similar.
 181 #define HUD_Panel_GetBorder()\
 182 if(panel_bg_border_str == "") {\
 183         panel_bg_border = autocvar_hud_panel_bg_border;\
 184 } else {\
 185         panel_bg_border = stof(panel_bg_border_str);\
 186 }
 187
 188 // Scale the pos and size vectors to absolute coordinates
 189 #define HUD_Panel_GetScaledVectors()\
 190 panel_pos_x *= vid_conwidth;\
 191 panel_pos_y *= vid_conheight;\
 192 panel_size_x *= vid_conwidth;\
 193 panel_size_y *= vid_conheight;
 194
 195 // Get padding. See comments above, it's similar.
 196 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 197 #define HUD_Panel_GetPadding()\
 198 if(panel_bg_padding_str == "") {\
 199         panel_bg_padding = autocvar_hud_panel_bg_padding;\
 200 } else {\
 201         panel_bg_padding = stof(panel_bg_padding_str);\
 202 }\
 203 panel_bg_padding = min(min(panel_size_x, panel_size_y)/2 - 5, panel_bg_padding);
 204
 205 // Point to the macros above (stupid max macro length)
 206 #define HUD_Panel_StringVars()\
 207 HUD_Panel_GetBg()\
 208 HUD_Panel_GetColorTeam()\
 209 HUD_Panel_GetColor()\
 210 HUD_Panel_GetBgAlpha()\
 211 HUD_Panel_GetFgAlpha()\
 212 HUD_Panel_GetBorder()\
 213 HUD_Panel_GetScaledVectors()\
 214 HUD_Panel_GetPadding()
 215
 216 // return smoothly faded pos of given panel when a dialog is active
 217 var vector menu_enable_panelpos;
 218 #define HUD_Panel_GetMenuPos() \
 219 if(panel_size_x > panel_size_y)\
 220         menu_enable_panelpos = eX * 0.5 * vid_conwidth - eX * 0.5 * panel_size_x + eY * 0.82 * vid_conheight;\
 221 else\
 222         menu_enable_panelpos = eY * 0.5 * vid_conheight - eY * 0.5 * panel_size_y + eX * 0.7 * vid_conwidth;\
 223 panel_pos = (1 - autocvar__menu_alpha) * panel_pos + (autocvar__menu_alpha) * menu_enable_panelpos;
 224
 225 // return smoothly faded size of given panel when a dialog is active
 226 var vector menu_enable_maxsize;
 227 var vector menu_enable_size;
 228 #define HUD_Panel_GetMenuSize()\
 229 menu_enable_maxsize_x = 0.3 * vid_conwidth;\
 230 menu_enable_maxsize_y = 0.18 * vid_conheight;\
 231 if(panel_size_x > panel_size_y)\
 232 {\
 233         if(panel_size_y > menu_enable_maxsize_y)\
 234         {\
 235                 menu_enable_size_y = menu_enable_maxsize_y;\
 236                 menu_enable_size_x = panel_size_x * (menu_enable_maxsize_y/panel_size_y);\
 237                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 238         }\
 239 }\
 240 else\
 241 {\
 242         if(panel_size_x > menu_enable_maxsize_x)\
 243         {\
 244                 menu_enable_size_x = menu_enable_maxsize_x;\
 245                 menu_enable_size_y = panel_size_y * (menu_enable_maxsize_x/panel_size_x);\
 246                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 247         }\
 248 }
 249
 250 // Update all common cvars of given panel name
 251 #define HUD_Panel_UpdateCvars(name) \
 252 panel_enabled = autocvar_hud_panel_##name; \
 253 panel_pos = autocvar_hud_panel_##name##_pos; \
 254 panel_size = autocvar_hud_panel_##name##_size; \
 255 panel_bg_str = autocvar_hud_panel_##name##_bg; \
 256 panel_bg_color_str = autocvar_hud_panel_##name##_bg_color; \
 257 panel_bg_color_team_str = autocvar_hud_panel_##name##_bg_color_team; \
 258 panel_bg_alpha_str = autocvar_hud_panel_##name##_bg_alpha; \
 259 panel_bg_border_str = autocvar_hud_panel_##name##_bg_border; \
 260 panel_bg_padding_str = autocvar_hud_panel_##name##_bg_padding; \
 261 HUD_Panel_StringVars()\
 262 if(disable_menu_alphacheck == 2 && active_panel == highlightedPanel) {\
 263         HUD_Panel_GetMenuSize()\
 264         HUD_Panel_GetMenuPos()\
 265 }
 266
 267 // Update all common cvars of given panel id
 268 #define HUD_Panel_UpdateCvarsForId(id) \
 269 switch(id) { \
 270         case HUD_PANEL_WEAPONS: HUD_Panel_UpdateCvars(weapons) break; \
 271         case HUD_PANEL_AMMO: HUD_Panel_UpdateCvars(ammo) break; \
 272         case HUD_PANEL_POWERUPS: HUD_Panel_UpdateCvars(powerups) break; \
 273         case HUD_PANEL_HEALTHARMOR: HUD_Panel_UpdateCvars(healtharmor) break; \
 274         case HUD_PANEL_NOTIFY: HUD_Panel_UpdateCvars(notify) break; \
 275         case HUD_PANEL_TIMER: HUD_Panel_UpdateCvars(timer) break; \
 276         case HUD_PANEL_RADAR: HUD_Panel_UpdateCvars(radar) break; \
 277         case HUD_PANEL_SCORE: HUD_Panel_UpdateCvars(score) break; \
 278         case HUD_PANEL_RACETIMER: HUD_Panel_UpdateCvars(racetimer) break; \
 279         case HUD_PANEL_VOTE: HUD_Panel_UpdateCvars(vote) break; \
 280         case HUD_PANEL_MODICONS: HUD_Panel_UpdateCvars(modicons) break; \
 281         case HUD_PANEL_PRESSEDKEYS: HUD_Panel_UpdateCvars(pressedkeys) break; \
 282         case HUD_PANEL_CHAT: HUD_Panel_UpdateCvars(chat) break; \
 283         case HUD_PANEL_ENGINEINFO: HUD_Panel_UpdateCvars(engineinfo) break; \
 284         case HUD_PANEL_INFOMESSAGES: HUD_Panel_UpdateCvars(infomessages) break; \
 285 }
 286
 287 #define HUD_Panel_UpdatePosSize(name) \
 288 panel_pos = autocvar_hud_panel_##name##_pos; \
 289 panel_size = autocvar_hud_panel_##name##_size; \
 290 HUD_Panel_GetScaledVectors()\
 291 if(disable_menu_alphacheck == 2 && active_panel == highlightedPanel) {\
 292         HUD_Panel_GetMenuSize()\
 293         HUD_Panel_GetMenuPos()\
 294 }\
 295 panel_bg_border_str = autocvar_hud_panel_##name##_bg_border; \
 296 HUD_Panel_GetBorder()
 297
 298 // Update pos and size of given panel id
 299 #define HUD_Panel_UpdatePosSizeForId(id) \
 300 switch(id) { \
 301         case HUD_PANEL_WEAPONS: HUD_Panel_UpdatePosSize(weapons) break;\
 302         case HUD_PANEL_AMMO: HUD_Panel_UpdatePosSize(ammo) break;\
 303         case HUD_PANEL_POWERUPS: HUD_Panel_UpdatePosSize(powerups) break;\
 304         case HUD_PANEL_HEALTHARMOR: HUD_Panel_UpdatePosSize(healtharmor) break;\
 305         case HUD_PANEL_NOTIFY: HUD_Panel_UpdatePosSize(notify) break;\
 306         case HUD_PANEL_TIMER: HUD_Panel_UpdatePosSize(timer) break;\
 307         case HUD_PANEL_RADAR: HUD_Panel_UpdatePosSize(radar) break;\
 308         case HUD_PANEL_SCORE: HUD_Panel_UpdatePosSize(score) break;\
 309         case HUD_PANEL_RACETIMER: HUD_Panel_UpdatePosSize(racetimer) break;\
 310         case HUD_PANEL_VOTE: HUD_Panel_UpdatePosSize(vote) break;\
 311         case HUD_PANEL_MODICONS: HUD_Panel_UpdatePosSize(modicons) break;\
 312         case HUD_PANEL_PRESSEDKEYS: HUD_Panel_UpdatePosSize(pressedkeys) break;\
 313         case HUD_PANEL_CHAT: HUD_Panel_UpdatePosSize(chat) break;\
 314         case HUD_PANEL_ENGINEINFO: HUD_Panel_UpdatePosSize(engineinfo) break;\
 315         case HUD_PANEL_INFOMESSAGES: HUD_Panel_UpdatePosSize(infomessages)\
 316 }