qcsrc/client/hud/crosshair.qc

   1 #include "crosshair.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <client/view.qh>
   6 #include <common/deathtypes/all.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/mapobjects/trigger/viewloc.qh>
   9 #include <common/minigames/cl_minigames.qh>
  10 #include <common/minigames/cl_minigames_hud.qh>
  11 #include <common/mutators/mutator/overkill/oknex.qh>
  12 #include <common/vehicles/all.qh>
  13 #include <common/viewloc.qh>
  14 #include <common/wepent.qh>
  15 #include <lib/csqcmodel/cl_player.qh>
  16
  17 float pickup_crosshair_time, pickup_crosshair_size;
  18 float hitindication_crosshair_size;
  19 float use_vortex_chargepool;
  20
  21 float reticle_type;
  22
  23 vector wcross_origin;
  24 float wcross_scale_prev, wcross_alpha_prev;
  25 vector wcross_color_prev;
  26 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
  27 vector wcross_color_goal_prev;
  28 float wcross_changedonetime;
  29
  30 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
  31 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
  32 float wcross_name_changestarttime, wcross_name_changedonetime;
  33 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
  34
  35 float wcross_ring_prev;
  36
  37 entity trueaim;
  38 entity trueaim_rifle;
  39
  40 const float SHOTTYPE_HITTEAM = 1;
  41 const float SHOTTYPE_HITOBSTRUCTION = 2;
  42 const float SHOTTYPE_HITWORLD = 3;
  43 const float SHOTTYPE_HITENEMY = 4;
  44
  45 void TrueAim_Init()
  46 {
  47         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  48         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  49 }
  50
  51 float EnemyHitCheck()
  52 {
  53         float t, n;
  54         wcross_origin = project_3d_to_2d(trace_endpos);
  55         wcross_origin.z = 0;
  56         if(trace_ent)
  57                 n = trace_ent.entnum;
  58         else
  59                 n = trace_networkentity;
  60         if(n < 1)
  61                 return SHOTTYPE_HITWORLD;
  62         if(n > maxclients)
  63                 return SHOTTYPE_HITWORLD;
  64         t = entcs_GetTeam(n - 1);
  65         if(teamplay)
  66                 if(t == myteam)
  67                         return SHOTTYPE_HITTEAM;
  68         if(t == NUM_SPECTATOR)
  69                 return SHOTTYPE_HITWORLD;
  70         return SHOTTYPE_HITENEMY;
  71 }
  72
  73 float TrueAimCheck(entity wepent)
  74 {
  75         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
  76                 return SHOTTYPE_HITWORLD;
  77
  78         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  79         vector vecs, trueaimpoint, w_shotorg;
  80         vector mi, ma, dv;
  81         float shottype;
  82         entity ta;
  83         float mv;
  84
  85         mi = ma = '0 0 0';
  86         ta = trueaim;
  87         mv = MOVE_NOMONSTERS;
  88
  89         switch(wepent.activeweapon) // WEAPONTODO
  90         {
  91                 case WEP_VORTEX:
  92                 case WEP_OVERKILL_NEX:
  93                 case WEP_VAPORIZER:
  94                         mv = MOVE_NORMAL;
  95                         break;
  96                 case WEP_RIFLE:
  97                         ta = trueaim_rifle;
  98                         mv = MOVE_NORMAL;
  99                         if(zoomscript_caught)
 100                         {
 101                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 102                                 return EnemyHitCheck();
 103                         }
 104                         break;
 105                 case WEP_DEVASTATOR: // projectile has a size!
 106                         mi = '-3 -3 -3';
 107                         ma = '3 3 3';
 108                         break;
 109                 case WEP_FIREBALL: // projectile has a size!
 110                         mi = '-16 -16 -16';
 111                         ma = '16 16 16';
 112                         break;
 113                 case WEP_SEEKER: // projectile has a size!
 114                         mi = '-2 -2 -2';
 115                         ma = '2 2 2';
 116                         break;
 117                 case WEP_ELECTRO: // projectile has a size!
 118                         mi = '0 0 -3';
 119                         ma = '0 0 -3';
 120                         break;
 121         }
 122
 123         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 124
 125         vecs = decompressShotOrigin(STAT(SHOTORG));
 126
 127         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 128         trueaimpoint = trace_endpos;
 129         // move trueaimpoint a little bit forward to make the final tracebox reliable
 130         // since it sometimes doesn't reach a teammate by a hair
 131         trueaimpoint += view_forward;
 132
 133         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 134                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 135
 136         if(vecs.x > 0)
 137                 vecs.y = -vecs.y;
 138         else
 139                 vecs = '0 0 0';
 140
 141         dv = view_right * vecs.y + view_up * vecs.z;
 142         w_shotorg = traceorigin + dv;
 143
 144         // now move the vecs forward as much as requested if possible
 145         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 146         w_shotorg = trace_endpos - view_forward * nudge;
 147
 148         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 149         shottype = EnemyHitCheck();
 150         if(shottype != SHOTTYPE_HITWORLD)
 151                 return shottype;
 152
 153 #if 0
 154         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 155         // or rather, I know why, but see no fix
 156         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 157                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 158                 return SHOTTYPE_HITOBSTRUCTION;
 159 #endif
 160
 161         return SHOTTYPE_HITWORLD;
 162 }
 163
 164 void HUD_Crosshair_Vehicle(entity this)
 165 {
 166         if(hud != HUD_BUMBLEBEE_GUN)
 167         {
 168                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 169                 info.vr_crosshair(info, this);
 170         }
 171 }
 172
 173 vector crosshair_getcolor(entity this, float health_stat)
 174 {
 175         static float rainbow_last_flicker;
 176         static vector rainbow_prev_color;
 177         vector wcross_color = '0 0 0';
 178         switch(autocvar_crosshair_color_special)
 179         {
 180                 case 1: // weapon color
 181                 {
 182                         if(this != WEP_Null && hud == HUD_NORMAL)
 183                         {
 184                                 wcross_color = this.wpcolor;
 185                                 break;
 186                         }
 187                         else { goto normalcolor; }
 188                 }
 189
 190                 case 2: // color based on health and armor
 191                 {
 192                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 193                         float health_and_armor = floor(v.x + 1);
 194                         wcross_color = HUD_Get_Num_Color(health_and_armor, 200, false);
 195                         break;
 196                 }
 197
 198                 case 3: // rainbow/random color
 199                 {
 200                         if(time >= rainbow_last_flicker)
 201                         {
 202                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 203                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 204                         }
 205                         wcross_color = rainbow_prev_color;
 206                         break;
 207                 }
 208 LABEL(normalcolor)
 209                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 210         }
 211
 212         return wcross_color;
 213 }
 214
 215 void HUD_Crosshair(entity this)
 216 {
 217         // reset player's alpha here upon death since forced scoreboard prevents running the crosshair_chase code
 218         if(autocvar_chase_active > 0 && autocvar_crosshair_chase && STAT(HEALTH) <= 0 && csqcplayer)
 219                 csqcplayer.alpha = csqcplayer.m_alpha;
 220
 221         if (autocvar_chase_active > 0 && autocvar_chase_front)
 222         {
 223                 csqcplayer.alpha = csqcplayer.m_alpha;
 224                 return;
 225         }
 226
 227         float f, i, j;
 228         vector v;
 229         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) && !autocvar_cl_lockview
 230                 && spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair)
 231                 && !HUD_MinigameMenu_IsOpened())
 232         {
 233                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 234                         return;
 235
 236                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 237                         return;
 238
 239                 if (hud != HUD_NORMAL)
 240                 {
 241                         HUD_Crosshair_Vehicle(this);
 242                         return;
 243                 }
 244
 245                 string wcross_style;
 246                 float wcross_alpha, wcross_resolution;
 247                 wcross_style = autocvar_crosshair;
 248                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 249                         wcross_style = autocvar_crosshair_2d;
 250                 if (wcross_style == "0")
 251                         return;
 252                 wcross_resolution = autocvar_crosshair_size;
 253                 if (wcross_resolution == 0)
 254                         return;
 255                 wcross_alpha = autocvar_crosshair_alpha;
 256                 if (wcross_alpha == 0)
 257                         return;
 258
 259                 // TrueAim check
 260                 float shottype;
 261
 262                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 263                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 264                         wcross_origin = viewloc_mousepos;
 265                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 266                 {
 267                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 268                         float my_alpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
 269                         if(csqcplayer && autocvar_crosshair_chase_playeralpha && autocvar_crosshair_chase_playeralpha < 1
 270                                 && my_alpha > autocvar_crosshair_chase_playeralpha)
 271                         {
 272                                 bool hit = false;
 273                                 if (pointinsidebox(view_origin, csqcplayer.absmin, csqcplayer.absmax))
 274                                         hit = true;
 275                                 else
 276                                 {
 277                                         WarpZone_TraceLine(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 278                                         if(trace_ent == csqcplayer)
 279                                                 hit = true;
 280                                 }
 281                                 float prev_alpha = csqcplayer.alpha;
 282                                 if(hit)
 283                                         csqcplayer.alpha = max(csqcplayer.alpha - frametime * 5, autocvar_crosshair_chase_playeralpha);
 284                                 else
 285                                         csqcplayer.alpha = min(csqcplayer.alpha + frametime * 5, my_alpha);
 286
 287                                 if (csqcplayer.alpha != prev_alpha)
 288                                 {
 289                                         FOREACH_ENTITY_CLASS("ENT_CLIENT_MODEL", it.tag_entity == csqcplayer,
 290                                         {
 291                                                 it.alpha = csqcplayer.alpha;
 292                                         });
 293                                 }
 294                         }
 295                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 296                         wcross_origin = project_3d_to_2d(trace_endpos);
 297                 }
 298                 else
 299                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 300                 wcross_origin.z = 0;
 301                 if(autocvar_crosshair_hittest)
 302                 {
 303                         vector wcross_oldorigin;
 304                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 305                         wcross_oldorigin = wcross_origin;
 306                         shottype = TrueAimCheck(thiswep);
 307                         if(shottype == SHOTTYPE_HITWORLD)
 308                         {
 309                                 v = wcross_origin - wcross_oldorigin;
 310                                 v.x /= vid_conwidth;
 311                                 v.y /= vid_conheight;
 312                                 if(vdist(v, >, 0.01))
 313                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 314                         }
 315                         if(!autocvar_crosshair_hittest_showimpact)
 316                                 wcross_origin = wcross_oldorigin;
 317                 }
 318                 else
 319                         shottype = SHOTTYPE_HITWORLD;
 320
 321                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 322                 string wcross_name = "";
 323                 float wcross_scale, wcross_blur;
 324
 325                 entity e = WEP_Null;
 326                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 327                 {
 328                         entity wepent = viewmodels[0]; // TODO: unhardcode
 329                         e = wepent.switchingweapon;
 330                         if(e)
 331                         {
 332                                 if(autocvar_crosshair_per_weapon)
 333                                 {
 334                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 335                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 336                                         //if (wcross_resolution == 0)
 337                                                 //return;
 338
 339                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 340                                         wcross_resolution *= e.w_crosshair_size;
 341                                         wcross_name = e.w_crosshair;
 342                                 }
 343                         }
 344                 }
 345
 346                 if(wcross_name == "")
 347                         wcross_name = strcat("gfx/crosshair", wcross_style);
 348
 349                 // MAIN CROSSHAIR COLOR DECISION
 350                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
 351
 352                 if(autocvar_crosshair_effect_scalefade)
 353                 {
 354                         wcross_scale = wcross_resolution;
 355                         wcross_resolution = 1;
 356                 }
 357                 else
 358                 {
 359                         wcross_scale = 1;
 360                 }
 361
 362                 if(autocvar_crosshair_pickup)
 363                 {
 364                         float stat_pickup_time = STAT(LAST_PICKUP);
 365
 366                         if(pickup_crosshair_time < stat_pickup_time)
 367                         {
 368                                 if(time - stat_pickup_time < 5) // don't trigger the animation if it's too old
 369                                         pickup_crosshair_size = 1;
 370
 371                                 pickup_crosshair_time = stat_pickup_time;
 372                         }
 373
 374                         if(pickup_crosshair_size > 0)
 375                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 376                         else
 377                                 pickup_crosshair_size = 0;
 378
 379                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 380                 }
 381
 382                 // todo: make crosshair hit indication dependent on damage dealt
 383                 if(autocvar_crosshair_hitindication)
 384                 {
 385                         vector col = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 386
 387                         if(unaccounted_damage)
 388                         {
 389                                 hitindication_crosshair_size = 1;
 390                         }
 391
 392                         if(hitindication_crosshair_size > 0)
 393                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 394                         else
 395                                 hitindication_crosshair_size = 0;
 396
 397                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 398                         wcross_color.x += sin(hitindication_crosshair_size) * col.x;
 399                         wcross_color.y += sin(hitindication_crosshair_size) * col.y;
 400                         wcross_color.z += sin(hitindication_crosshair_size) * col.z;
 401                 }
 402
 403                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
 404                 // just show for teammates to give a sign that they're an invalid target
 405                 //if(shottype == SHOTTYPE_HITENEMY)
 406                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 407                 if(shottype == SHOTTYPE_HITTEAM)
 408                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 409
 410                 f = fabs(autocvar_crosshair_effect_time);
 411                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 412                 {
 413                         wcross_changedonetime = time + f;
 414                 }
 415                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 416                 {
 417                         wcross_name_changestarttime = time;
 418                         wcross_name_changedonetime = time + f;
 419                         if(wcross_name_goal_prev_prev)
 420                                 strunzone(wcross_name_goal_prev_prev);
 421                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 422                         wcross_name_goal_prev = strzone(wcross_name);
 423                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 424                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 425                         wcross_resolution_goal_prev = wcross_resolution;
 426                 }
 427
 428                 wcross_scale_goal_prev = wcross_scale;
 429                 wcross_alpha_goal_prev = wcross_alpha;
 430                 wcross_color_goal_prev = wcross_color;
 431
 432                 if((shottype == SHOTTYPE_HITTEAM && autocvar_crosshair_hittest_blur_teammate)
 433                         || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur_wall && !autocvar_chase_active))
 434                 {
 435                         wcross_blur = 1;
 436                         wcross_alpha *= 0.75;
 437                 }
 438                 else
 439                         wcross_blur = 0;
 440                 // *_prev is at time-frametime
 441                 // * is at wcross_changedonetime+f
 442                 // what do we have at time?
 443                 if(time < wcross_changedonetime)
 444                 {
 445                         f = frametime / (wcross_changedonetime - time + frametime);
 446                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 447                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 448                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 449                 }
 450
 451                 wcross_scale_prev = wcross_scale;
 452                 wcross_alpha_prev = wcross_alpha;
 453                 wcross_color_prev = wcross_color;
 454
 455                 MUTATOR_CALLHOOK(UpdateCrosshair);
 456
 457                 wcross_scale *= 1 - autocvar__menu_alpha;
 458                 wcross_alpha *= 1 - autocvar__menu_alpha;
 459                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 460
 461                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 462                 {
 463                         // crosshair rings for weapon stats
 464                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 465                         {
 466                                 // declarations and stats
 467                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 468                                 string ring_image = string_null, ring_inner_image = string_null;
 469                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 470
 471                                 ring_scale = autocvar_crosshair_ring_size;
 472
 473                                 entity wepent = viewmodels[0]; // TODO: unhardcode
 474
 475                                 int weapon_clipload = wepent.clip_load;
 476                                 int weapon_clipsize = wepent.clip_size;
 477
 478                                 float arc_heat = wepent.arc_heat_percent;
 479
 480                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 481                                         vortex_charge_movingavg = wepent.vortex_charge;
 482
 483                                 float charge = 0;
 484                                 float chargepool = 0;
 485                                 bool ring_vortex_enabled = false;
 486                                 if (autocvar_crosshair_ring && autocvar_crosshair_ring_vortex)
 487                                 {
 488                                         if (wepent.activeweapon == WEP_VORTEX)
 489                                         {
 490                                                 charge = wepent.vortex_charge;
 491                                                 chargepool = wepent.vortex_chargepool_ammo;
 492                                         }
 493                                         else if (wepent.activeweapon == WEP_OVERKILL_NEX)
 494                                         {
 495                                                 charge = wepent.oknex_charge;
 496                                                 chargepool = wepent.oknex_chargepool_ammo;
 497                                         }
 498                                         if (charge)
 499                                                 ring_vortex_enabled = true;
 500                                 }
 501
 502                                 if (ring_vortex_enabled)
 503                                 {
 504                                         if (chargepool || use_vortex_chargepool) {
 505                                                 use_vortex_chargepool = 1;
 506                                                 ring_inner_value = chargepool;
 507                                         } else {
 508                                                 float rate = autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate;
 509                                                 vortex_charge_movingavg = (1 - rate) * vortex_charge_movingavg + rate * charge;
 510                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (charge - vortex_charge_movingavg), 1);
 511                                         }
 512
 513                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 514                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
 515                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 516
 517                                         // draw the outer ring to show the current charge of the weapon
 518                                         ring_value = charge;
 519                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 520                                         ring_rgb = wcross_color;
 521                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 522                                 }
 523                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
 524                                 {
 525                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1);
 526                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 527                                         ring_rgb = wcross_color;
 528                                         ring_image = "gfx/crosshair_ring.tga";
 529                                 }
 530                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
 531                                 {
 532                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
 533                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 534                                         ring_rgb = wcross_color;
 535                                         ring_image = "gfx/crosshair_ring.tga";
 536                                 }
 537                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 538                                 {
 539                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 540                                         ring_scale = autocvar_crosshair_ring_reload_size;
 541                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 542                                         ring_rgb = wcross_color;
 543
 544                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 545                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 546                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 547                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 548                                         else
 549                                                 ring_image = "gfx/crosshair_ring.tga";
 550                                 }
 551                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
 552                                 {
 553                                         ring_value = arc_heat;
 554                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 555                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 556                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 557                                         ring_image = "gfx/crosshair_ring.tga";
 558                                 }
 559
 560                                 // if in weapon switch animation, fade ring out/in
 561                                 if(autocvar_crosshair_effect_time > 0)
 562                                 {
 563                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 564                                         if (f >= 1)
 565                                         {
 566                                                 wcross_ring_prev = ((ring_image) ? true : false);
 567                                         }
 568
 569                                         if(wcross_ring_prev)
 570                                         {
 571                                                 if(f < 1)
 572                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 573                                         }
 574                                         else
 575                                         {
 576                                                 if(f < 1)
 577                                                         ring_alpha *= bound(0, f, 1);
 578                                         }
 579                                 }
 580
 581                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 582                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 583
 584                                 if (ring_value)
 585                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 586                         }
 587
 588 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 589                         MACRO_BEGIN \
 590                                 vector scaled_sz = sz * wcross_size; \
 591                                 if(wcross_blur > 0) \
 592                                 { \
 593                                         for(i = -2; i <= 2; ++i) \
 594                                         for(j = -2; j <= 2; ++j) \
 595                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
 596                                 } \
 597                                 else \
 598                                 { \
 599                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
 600                                 } \
 601                         MACRO_END
 602
 603 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
 604                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 605
 606 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 607                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 608
 609                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 610                         {
 611                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 612                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 613                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 614                                 f = 1 - f;
 615                         }
 616                         else
 617                         {
 618                                 f = 1;
 619                         }
 620                         wcross_name_alpha_goal_prev = f;
 621
 622                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 623                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 624
 625                         if(autocvar_crosshair_dot)
 626                         {
 627                                 vector wcross_color_old;
 628                                 wcross_color_old = wcross_color;
 629
 630                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 631                                         wcross_color = stov(autocvar_crosshair_dot_color);
 632
 633                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 634                                 // FIXME why don't we use wcross_alpha here?
 635                                 wcross_color = wcross_color_old;
 636                         }
 637                 }
 638         }
 639         else
 640         {
 641                 wcross_scale_prev = 0;
 642                 wcross_alpha_prev = 0;
 643                 wcross_scale_goal_prev = 0;
 644                 wcross_alpha_goal_prev = 0;
 645                 wcross_changedonetime = 0;
 646                 strfree(wcross_name_goal_prev);
 647                 strfree(wcross_name_goal_prev_prev);
 648                 wcross_name_changestarttime = 0;
 649                 wcross_name_changedonetime = 0;
 650                 wcross_name_alpha_goal_prev = 0;
 651                 wcross_name_alpha_goal_prev_prev = 0;
 652                 wcross_resolution_goal_prev = 0;
 653                 wcross_resolution_goal_prev_prev = 0;
 654         }
 655 }
 656
 657 void DrawReticle(entity this)
 658 {
 659         if(!autocvar_cl_reticle || MUTATOR_CALLHOOK(DrawReticle))
 660         {
 661                 reticle_type = 0;
 662                 return;
 663         }
 664
 665         float is_dead = (STAT(HEALTH) <= 0);
 666         string reticle_image = string_null;
 667         bool wep_zoomed = false;
 668         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 669         {
 670                 entity wepe = viewmodels[slot];
 671                 Weapon wep = wepe.activeweapon;
 672                 if(wep != WEP_Null && wep.wr_zoom)
 673                 {
 674                         bool do_zoom = wep.wr_zoom(wep, NULL);
 675                         if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
 676                                 reticle_image = wep.w_reticle;
 677                         wep_zoomed += do_zoom;
 678                 }
 679         }
 680         // Draw the aiming reticle for weapons that use it
 681         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 682         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 683         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 684         if(spectatee_status || is_dead || hud != HUD_NORMAL || this.viewloc)
 685         {
 686                 // no zoom reticle while dead
 687                 reticle_type = 0;
 688         }
 689         else if(wep_zoomed && autocvar_cl_reticle_weapon)
 690         {
 691                 if(reticle_image) { reticle_type = 2; }
 692                 else { reticle_type = 0; }
 693         }
 694         else if(button_zoom || zoomscript_caught)
 695         {
 696                 // normal zoom
 697                 reticle_type = 1;
 698         }
 699
 700         if(reticle_type)
 701         {
 702                 vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 703                 if(autocvar_cl_reticle_stretch)
 704                 {
 705                         reticle_size.x = vid_conwidth;
 706                         reticle_size.y = vid_conheight;
 707                         reticle_pos.x = 0;
 708                         reticle_pos.y = 0;
 709                 }
 710                 else
 711                 {
 712                         reticle_size.x = max(vid_conwidth, vid_conheight);
 713                         reticle_size.y = max(vid_conwidth, vid_conheight);
 714                         reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
 715                         reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
 716                 }
 717
 718                 float f = (zoomscript_caught) ? 1 : current_zoomfraction;
 719
 720                 if(f)
 721                 {
 722                         switch(reticle_type)
 723                         {
 724                                 case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 725                                 case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 726                         }
 727                 }
 728         }
 729 }