qcsrc/client/hud/panel/engineinfo.qc

   1 #include "engineinfo.qh"
   2 // Engine info panel (#13)
   3
   4 float prevfps;
   5 float prevfps_time;
   6 int framecounter;
   7
   8 float frametimeavg;
   9 float frametimeavg1; // 1 frame ago
  10 float frametimeavg2; // 2 frames ago
  11 float autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage;
  12 float autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight;
  13 float autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold;
  14 void HUD_EngineInfo()
  15 {
  16         if(!autocvar__hud_configure)
  17         {
  18                 if(!autocvar_hud_panel_engineinfo) return;
  19         }
  20
  21         HUD_Panel_UpdateCvars();
  22         vector pos, mySize;
  23         pos = panel_pos;
  24         mySize = panel_size;
  25
  26         HUD_Scale_Enable();
  27         HUD_Panel_DrawBg(1);
  28         if(panel_bg_padding)
  29         {
  30                 pos += '1 1 0' * panel_bg_padding;
  31                 mySize -= '2 2 0' * panel_bg_padding;
  32         }
  33
  34         float currentTime = gettime(GETTIME_REALTIME);
  35         if(autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage)
  36         {
  37                 float currentframetime = currentTime - prevfps_time;
  38                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
  39                 frametimeavg2 = frametimeavg1;
  40                 frametimeavg1 = frametimeavg;
  41
  42                 float weight;
  43                 weight = autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight;
  44                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
  45                 {
  46                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * autocvar_hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
  47                                 prevfps = (1/currentframetime);
  48                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
  49                 }
  50                 prevfps_time = currentTime;
  51         }
  52         else
  53         {
  54                 framecounter += 1;
  55                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
  56                 {
  57                         prevfps = framecounter/(currentTime - prevfps_time);
  58                         framecounter = 0;
  59                         prevfps_time = currentTime;
  60                 }
  61         }
  62
  63         vector color;
  64         color = HUD_Get_Num_Color (prevfps, 100);
  65         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
  66 }