qcsrc/client/hud/panel/pressedkeys.qc

   1 #include "pressedkeys.qh"
   2
   3 #include <client/draw.qh>
   4
   5 // Pressed keys (#11)
   6
   7 void HUD_PressedKeys_Export(int fh)
   8 {
   9         // allow saving cvars that aesthetically change the panel into hud skin files
  10         HUD_Write_Cvar("hud_panel_pressedkeys_aspect");
  11         HUD_Write_Cvar("hud_panel_pressedkeys_attack");
  12 }
  13
  14 void HUD_PressedKeys()
  15 {
  16         if(!autocvar__hud_configure)
  17         {
  18                 if(!autocvar_hud_panel_pressedkeys || spectatee_status < 0) return;
  19                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
  20         }
  21
  22         HUD_Panel_LoadCvars();
  23         vector pos, mySize;
  24         pos = panel_pos;
  25         mySize = panel_size;
  26
  27         if (autocvar_hud_panel_pressedkeys_dynamichud)
  28                 HUD_Scale_Enable();
  29         else
  30                 HUD_Scale_Disable();
  31         HUD_Panel_DrawBg();
  32         if(panel_bg_padding)
  33         {
  34                 pos += '1 1 0' * panel_bg_padding;
  35                 mySize -= '2 2 0' * panel_bg_padding;
  36         }
  37
  38         // force custom aspect
  39         float aspect = autocvar_hud_panel_pressedkeys_aspect;
  40         if(aspect)
  41         {
  42                 vector newSize = '0 0 0';
  43                 if(mySize.x/mySize.y > aspect)
  44                 {
  45                         newSize.x = aspect * mySize.y;
  46                         newSize.y = mySize.y;
  47
  48                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
  49                 }
  50                 else
  51                 {
  52                         newSize.y = 1/aspect * mySize.x;
  53                         newSize.x = mySize.x;
  54
  55                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
  56                 }
  57                 mySize = newSize;
  58         }
  59
  60         vector keysize = vec2(mySize.x / (14/4), mySize.y / (3 - !autocvar_hud_panel_pressedkeys_attack));
  61         int pressedkeys = STAT(PRESSED_KEYS);
  62
  63         if(autocvar_hud_panel_pressedkeys_attack)
  64         {
  65                 drawpic_aspect_skin(pos + eX * (3/4 * keysize.x), ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  66                 drawpic_aspect_skin(pos + eX * (7/4 * keysize.x), ((pressedkeys & KEY_ATCK2) ? "key_atck2_inv.tga" : "key_atck2.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  67                 pos.y += keysize.y;
  68         }
  69
  70         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  71         drawpic_aspect_skin(pos + eX * (5/4 * keysize.x), ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  72         drawpic_aspect_skin(pos + eX * (10/4 * keysize.x), ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  73         pos.y += keysize.y;
  74         drawpic_aspect_skin(pos + eX * (1/4 * keysize.x), ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  75         drawpic_aspect_skin(pos + eX * (5/4 * keysize.x), ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  76         drawpic_aspect_skin(pos + eX * (9/4 * keysize.x), ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  77 }