qcsrc/client/hud/panel/radar.qc

   1 #include "radar.qh"
   2
   3 #include <common/ent_cs.qh>
   4 #include <common/mapinfo.qh>
   5 #include <client/mapvoting.qh>
   6 #include <client/teamradar.qh>
   7 #include <common/mutators/mutator/waypoints/all.qh>
   8
   9 // Radar (#6)
  10
  11 float HUD_Radar_Clickable()
  12 {
  13         return hud_panel_radar_mouse && !hud_panel_radar_temp_hidden;
  14 }
  15
  16 void HUD_Radar_Show_Maximized(bool doshow,float clickable)
  17 {
  18     TC(bool, doshow);
  19         hud_panel_radar_maximized = doshow;
  20         hud_panel_radar_temp_hidden = 0;
  21
  22         if ( doshow )
  23         {
  24                 if (clickable)
  25                 {
  26                         if(autocvar_hud_cursormode)
  27                                 setcursormode(1);
  28                         hud_panel_radar_mouse = 1;
  29
  30                         // we must unset the player's buttons, as they aren't released elsewhere
  31                         localcmd("-fire\n");
  32                         localcmd("-fire2\n");
  33                         localcmd("-use\n");
  34                         localcmd("-hook\n");
  35                         localcmd("-jump\n");
  36                 }
  37         }
  38         else if ( hud_panel_radar_mouse )
  39         {
  40                 hud_panel_radar_mouse = 0;
  41                 mouseClicked = 0;
  42                 if(autocvar_hud_cursormode)
  43                 if(!mv_active)
  44                         setcursormode(0);
  45         }
  46 }
  47 void HUD_Radar_Hide_Maximized()
  48 {
  49         HUD_Radar_Show_Maximized(false,false);
  50 }
  51
  52
  53 float HUD_Radar_InputEvent(int bInputType, float nPrimary, float nSecondary)
  54 {
  55     TC(int, bInputType);
  56         if(!hud_panel_radar_maximized || !hud_panel_radar_mouse ||
  57                 autocvar__hud_configure || mv_active)
  58                 return false;
  59
  60         if(bInputType == 3)
  61         {
  62                 mousepos_x = nPrimary;
  63                 mousepos_y = nSecondary;
  64                 return true;
  65         }
  66
  67         if(nPrimary == K_MOUSE1)
  68         {
  69                 if(bInputType == 0) // key pressed
  70                         mouseClicked |= S_MOUSE1;
  71                 else if(bInputType == 1) // key released
  72                         mouseClicked -= (mouseClicked & S_MOUSE1);
  73         }
  74         else if(nPrimary == K_MOUSE2)
  75         {
  76                 if(bInputType == 0) // key pressed
  77                         mouseClicked |= S_MOUSE2;
  78                 else if(bInputType == 1) // key released
  79                         mouseClicked -= (mouseClicked & S_MOUSE2);
  80         }
  81         else if ( nPrimary == K_ESCAPE && bInputType == 0 )
  82         {
  83                 HUD_Radar_Hide_Maximized();
  84         }
  85         else
  86         {
  87                 // allow console/use binds to work without hiding the map
  88                 string con_keys = strcat(findkeysforcommand("toggleconsole", 0), " ", findkeysforcommand("+use", 0)) ;
  89                 int keys = tokenize(con_keys); // findkeysforcommand returns data for this
  90                 int i;
  91                 for (i = 0; i < keys; ++i)
  92                 {
  93                         if(nPrimary == stof(argv(i)))
  94                                 return false;
  95                 }
  96
  97                 if ( STAT(HEALTH) <= 0 )
  98                 {
  99                         // Show scoreboard
 100                         if ( bInputType < 2 )
 101                         {
 102                                 con_keys = findkeysforcommand("+showscores", 0);
 103                                 keys = tokenize(con_keys);
 104                                 for (i = 0; i < keys; ++i)
 105                                 {
 106                                         if ( nPrimary == stof(argv(i)) )
 107                                         {
 108                                                 hud_panel_radar_temp_hidden = bInputType == 0;
 109                                                 return false;
 110                                         }
 111                                 }
 112                         }
 113                 }
 114                 else if ( bInputType == 0 )
 115                         HUD_Radar_Hide_Maximized();
 116
 117                 return false;
 118         }
 119
 120         return true;
 121 }
 122
 123 void HUD_Radar_Mouse()
 124 {
 125         if ( !hud_panel_radar_mouse ) return;
 126         if(mv_active) return;
 127
 128         if ( intermission )
 129         {
 130                 HUD_Radar_Hide_Maximized();
 131                 return;
 132         }
 133
 134         if(mouseClicked & S_MOUSE2)
 135         {
 136                 HUD_Radar_Hide_Maximized();
 137                 return;
 138         }
 139
 140         if(!autocvar_hud_cursormode)
 141         {
 142                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 143
 144                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
 145                 mousepos_y = bound(0, mousepos_y, vid_conheight);
 146         }
 147
 148         panel = HUD_PANEL(RADAR);
 149         HUD_Panel_LoadCvars();
 150
 151
 152         panel_size = autocvar_hud_panel_radar_maximized_size;
 153         panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
 154         panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
 155         panel_pos_x = (vid_conwidth - panel_size_x) / 2;
 156         panel_pos_y = (vid_conheight - panel_size_y) / 2;
 157
 158         if(mouseClicked & S_MOUSE1)
 159         {
 160                 // click outside
 161                 if ( mousepos_x < panel_pos_x || mousepos_x > panel_pos_x + panel_size_x ||
 162                          mousepos_y < panel_pos_y || mousepos_y > panel_pos_y + panel_size_y )
 163                 {
 164                         HUD_Radar_Hide_Maximized();
 165                         return;
 166                 }
 167                 vector pos = teamradar_texcoord_to_3dcoord(teamradar_2dcoord_to_texcoord(mousepos),view_origin_z);
 168                 localcmd(sprintf("cmd ons_spawn %f %f %f",pos_x,pos_y,pos_z));
 169
 170                 HUD_Radar_Hide_Maximized();
 171                 return;
 172         }
 173
 174
 175         draw_cursor_normal(mousepos, '1 1 1', 0.8);
 176 }
 177
 178 void HUD_Radar()
 179 {
 180         if (!autocvar__hud_configure)
 181         {
 182                 if (hud_panel_radar_maximized)
 183                 {
 184                         if (!hud_draw_maximized) return;
 185                 }
 186                 else
 187                 {
 188                         if (autocvar_hud_panel_radar == 0) return;
 189                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
 190                         if(radar_panel_modified)
 191                         {
 192                                 panel.update_time = time; // forces reload of panel attributes
 193                                 radar_panel_modified = false;
 194                         }
 195                 }
 196         }
 197
 198         if ( hud_panel_radar_temp_hidden )
 199                 return;
 200
 201         HUD_Panel_LoadCvars();
 202
 203         float f = 0;
 204
 205         if (hud_panel_radar_maximized && !autocvar__hud_configure)
 206         {
 207                 panel_size = autocvar_hud_panel_radar_maximized_size;
 208                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
 209                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
 210                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
 211                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
 212
 213                 string panel_bg;
 214                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
 215                 if(precache_pic(panel_bg) == "")
 216                         panel_bg = "gfx/hud/default/border_default"; // fallback
 217                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
 218                         radar_panel_modified = true;
 219                 if(panel.current_panel_bg)
 220                         strunzone(panel.current_panel_bg);
 221                 panel.current_panel_bg = strzone(panel_bg);
 222
 223                 switch(hud_panel_radar_maximized_zoommode)
 224                 {
 225                         default:
 226                         case 0:
 227                                 f = current_zoomfraction;
 228                                 break;
 229                         case 1:
 230                                 f = 1 - current_zoomfraction;
 231                                 break;
 232                         case 2:
 233                                 f = 0;
 234                                 break;
 235                         case 3:
 236                                 f = 1;
 237                                 break;
 238                 }
 239
 240                 switch(hud_panel_radar_maximized_rotation)
 241                 {
 242                         case 0:
 243                                 teamradar_angle = view_angles.y - 90;
 244                                 break;
 245                         default:
 246                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
 247                                 break;
 248                 }
 249         }
 250         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
 251         {
 252                 switch(hud_panel_radar_zoommode)
 253                 {
 254                         default:
 255                         case 0:
 256                                 f = current_zoomfraction;
 257                                 break;
 258                         case 1:
 259                                 f = 1 - current_zoomfraction;
 260                                 break;
 261                         case 2:
 262                                 f = 0;
 263                                 break;
 264                         case 3:
 265                                 f = 1;
 266                                 break;
 267                 }
 268
 269                 switch(hud_panel_radar_rotation)
 270                 {
 271                         case 0:
 272                                 teamradar_angle = view_angles.y - 90;
 273                                 break;
 274                         default:
 275                                 teamradar_angle = 90 * hud_panel_radar_rotation;
 276                                 break;
 277                 }
 278         }
 279
 280         vector pos, mySize;
 281         pos = panel_pos;
 282         mySize = panel_size;
 283
 284         if (autocvar_hud_panel_radar_dynamichud)
 285                 HUD_Scale_Enable();
 286         else
 287                 HUD_Scale_Disable();
 288         HUD_Panel_DrawBg();
 289         if(panel_bg_padding)
 290         {
 291                 pos += '1 1 0' * panel_bg_padding;
 292                 mySize -= '2 2 0' * panel_bg_padding;
 293         }
 294
 295         int color2;
 296         float scale2d, normalsize, bigsize;
 297
 298         teamradar_origin2d = HUD_Shift(pos + 0.5 * mySize);
 299         teamradar_size2d = mySize;
 300
 301         if(minimapname == "")
 302                 return;
 303
 304         teamradar_loadcvars();
 305
 306         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
 307         teamradar_size2d = HUD_Scale(mySize);
 308
 309         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
 310
 311         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
 312         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
 313         {
 314                 // max-min distance must fit the radar in any rotation
 315                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen(vec2(mi_scale)));
 316         }
 317         else
 318         {
 319                 vector c0, c1, c2, c3, span;
 320                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
 321                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
 322                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
 323                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
 324                 span = '0 0 0';
 325                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
 326                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
 327
 328                 // max-min distance must fit the radar in x=x, y=y
 329                 bigsize = min(
 330                         teamradar_size2d.x * scale2d / (1.05 * span.x),
 331                         teamradar_size2d.y * scale2d / (1.05 * span.y)
 332                 );
 333         }
 334
 335         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
 336         if(bigsize > normalsize)
 337                 normalsize = bigsize;
 338
 339         teamradar_size =
 340                   f * bigsize
 341                 + (1 - f) * normalsize;
 342         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
 343                   f * mi_center
 344                 + (1 - f) * view_origin);
 345
 346         drawsetcliparea(
 347                 pos.x,
 348                 pos.y,
 349                 mySize.x,
 350                 mySize.y
 351         );
 352
 353         draw_teamradar_background(hud_panel_radar_foreground_alpha);
 354
 355         IL_EACH(g_radarlinks, true, draw_teamradar_link(it.origin, it.velocity, it.team));
 356
 357         IL_EACH(g_radaricons, it.teamradar_icon, {
 358                 if ( hud_panel_radar_mouse )
 359                 if ( it.health >= 0 )
 360                 if ( it.team == myteam + 1 || gametype == MAPINFO_TYPE_RACE || !teamplay )
 361                 {
 362                         vector coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(it.origin));
 363                         if(vdist((mousepos - coord), <, 8))
 364                         {
 365                                 vector brightcolor;
 366                                 brightcolor_x = min(1,it.teamradar_color_x*1.5);
 367                                 brightcolor_y = min(1,it.teamradar_color_y*1.5);
 368                                 brightcolor_z = min(1,it.teamradar_color_z*1.5);
 369                                 drawpic(coord - '8 8 0', "gfx/teamradar_icon_glow", '16 16 0', brightcolor, panel_fg_alpha, 0);
 370                         }
 371                 }
 372                 entity icon = RadarIcons_from(it.teamradar_icon);
 373                 draw_teamradar_icon(it.origin, icon, it, spritelookupcolor(it, icon.netname, it.teamradar_color), panel_fg_alpha);
 374         });
 375         AL_EACH(_entcs, e, it != NULL, {
 376                 if (!it.m_entcs_private) continue;
 377                 if (it.sv_entnum == current_player) continue;
 378                 color2 = entcs_GetTeam(it.sv_entnum);
 379                 draw_teamradar_player(it.origin, it.angles, Team_ColorRGB(color2));
 380         });
 381         draw_teamradar_player(entcs_receiver(current_player).origin, view_angles, '1 1 1');
 382
 383         drawresetcliparea();
 384
 385         if ( hud_panel_radar_mouse )
 386         {
 387                 string message = "Click to select teleport destination";
 388
 389                 if ( STAT(HEALTH) <= 0 )
 390                 {
 391                         message = "Click to select spawn location";
 392                 }
 393
 394                 drawcolorcodedstring(pos + '0.5 0 0' * (mySize_x - stringwidth(message, true, hud_fontsize)) - '0 1 0' * hud_fontsize_y * 2,
 395                                                          message, hud_fontsize, hud_panel_radar_foreground_alpha, DRAWFLAG_NORMAL);
 396
 397                 hud_panel_radar_bottom = pos_y + mySize_y + hud_fontsize_y;
 398         }
 399 }