qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "prandom.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "sortlist.qh"
  20 #include "tuba.qh"
  21 #include "t_items.qh"
  22 #include "wall.qh"
  23 #include "waypointsprites.qh"
  24
  25 #include "../common/vehicles/unit/bumblebee.qh"
  26 #include "../common/vehicles/cl_vehicles.qh"
  27 #include "../common/vehicles/vehicles.qh"
  28
  29 #include "weapons/projectile.qh"
  30
  31 #include "../common/buffs.qh"
  32 #include "../common/deathtypes.qh"
  33 #include "../common/effects.qh"
  34 #include "../common/mapinfo.qh"
  35 #include "../common/monsters/all.qh"
  36 #include "../common/nades.qh"
  37 #include "../common/net_notice.qh"
  38 #include "../common/notifications.qh"
  39 #include "../common/stats.qh"
  40 #include "../common/teams.qh"
  41
  42 #include "../common/items/all.qh"
  43
  44 #include "../common/mutators/base.qh"
  45
  46 #include "../common/weapons/all.qh"
  47
  48 #include "../csqcmodellib/cl_model.qh"
  49 #include "../csqcmodellib/interpolate.qh"
  50
  51 #include "../common/triggers/include.qh"
  52
  53 #include "../common/turrets/cl_turrets.qh"
  54 #include "../common/turrets/turrets.qh"
  55
  56 #include "../warpzonelib/client.qh"
  57
  58 // --------------------------------------------------------------------------
  59 // BEGIN REQUIRED CSQC FUNCTIONS
  60 //include "main.qh"
  61
  62 entity clearentity_ent;
  63 void clearentity(entity e)
  64 {
  65         if (!clearentity_ent)
  66         {
  67                 clearentity_ent = spawn();
  68                 clearentity_ent.classname = "clearentity";
  69         }
  70         int n = e.entnum;
  71         copyentity(clearentity_ent, e);
  72         e.entnum = n;
  73 }
  74
  75 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  76 void menu_show_error()
  77 {
  78         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  79 }
  80
  81 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  82 // Useful for precaching things
  83
  84 void menu_sub_null()
  85 {
  86 }
  87
  88 string forcefog;
  89 void WaypointSprite_Load();
  90 void ConsoleCommand_macro_init();
  91 void CSQC_Init(void)
  92 {
  93         prvm_language = cvar_string("prvm_language");
  94
  95 #ifdef WATERMARK
  96         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  97 #endif
  98
  99         int i;
 100
 101         binddb = db_create();
 102         tempdb = db_create();
 103         ClientProgsDB = db_load("client.db");
 104         compressShortVector_init();
 105
 106         draw_endBoldFont();
 107         menu_visible = false;
 108         menu_show = menu_show_error;
 109         menu_action = func_null;
 110
 111         for(i = 0; i < 255; ++i)
 112                 if(getplayerkeyvalue(i, "viewentity") == "")
 113                         break;
 114         maxclients = i;
 115
 116         //registercommand("hud_configure");
 117         //registercommand("hud_save");
 118         //registercommand("menu_action");
 119
 120         ConsoleCommand_macro_init();
 121
 122         registercvar("hud_usecsqc", "1");
 123         registercvar("scoreboard_columns", "default");
 124
 125         registercvar("cl_nade_type", "3");
 126         registercvar("cl_pokenade_type", "zombie");
 127
 128         registercvar("cl_jumpspeedcap_min", "");
 129         registercvar("cl_jumpspeedcap_max", "");
 130
 131         gametype = 0;
 132
 133         // hud_fields uses strunzone on the titles!
 134         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 135                 hud_title[i] = strzone("(null)");
 136
 137         Cmd_HUD_SetFields(0);
 138
 139         postinit = false;
 140
 141         calledhooks = 0;
 142
 143         teams = Sort_Spawn();
 144         players = Sort_Spawn();
 145
 146         GetTeam(NUM_SPECTATOR, true); // add specs first
 147
 148         // needs to be done so early because of the constants they create
 149         static_init();
 150         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 151         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 152         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 153         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 154         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 155         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
 156
 157         WaypointSprite_Load();
 158
 159         // precaches
 160         precache_model("null");
 161         precache_sound("misc/hit.wav");
 162         precache_sound("misc/typehit.wav");
 163
 164         Projectile_Precache();
 165         Hook_Precache();
 166         GibSplash_Precache();
 167         Casings_Precache();
 168         Tuba_Precache();
 169         CSQCPlayer_Precache();
 170
 171         if(autocvar_cl_reticle)
 172         {
 173                 precache_pic("gfx/reticle_normal");
 174                 // weapon reticles are precached in weapon files
 175         }
 176
 177         get_mi_min_max_texcoords(1); // try the CLEVER way first
 178         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 179         shortmapname = mi_shortname;
 180
 181         if(precache_pic(minimapname) == "")
 182         {
 183                 // but maybe we have a non-clever minimap
 184                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 185                 if(precache_pic(minimapname) == "")
 186                         minimapname = ""; // FAIL
 187                 else
 188                         get_mi_min_max_texcoords(0); // load new texcoords
 189         }
 190
 191         mi_center = (mi_min + mi_max) * 0.5;
 192         mi_scale = mi_max - mi_min;
 193         minimapname = strzone(minimapname);
 194
 195         WarpZone_Init();
 196
 197         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 198         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 199 }
 200
 201 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 202 void Shutdown(void)
 203 {
 204         WarpZone_Shutdown();
 205
 206         remove(teams);
 207         remove(players);
 208         db_close(binddb);
 209         db_close(tempdb);
 210         if(autocvar_cl_db_saveasdump)
 211                 db_dump(ClientProgsDB, "client.db");
 212         else
 213                 db_save(ClientProgsDB, "client.db");
 214         db_close(ClientProgsDB);
 215
 216         if(camera_active)
 217                 cvar_set("chase_active",ftos(chase_active_backup));
 218
 219         // unset the event chasecam's chase_active
 220         if(autocvar_chase_active < 0)
 221                 cvar_set("chase_active", "0");
 222
 223         if (!isdemo())
 224         {
 225                 if (!(calledhooks & HOOK_START))
 226                         localcmd("\n_cl_hook_gamestart nop\n");
 227                 if (!(calledhooks & HOOK_END))
 228                         localcmd("\ncl_hook_gameend\n");
 229         }
 230 }
 231
 232 .float has_team;
 233 float SetTeam(entity o, int Team)
 234 {
 235         entity tm;
 236         if(teamplay)
 237         {
 238                 switch(Team)
 239                 {
 240                         case -1:
 241                         case NUM_TEAM_1:
 242                         case NUM_TEAM_2:
 243                         case NUM_TEAM_3:
 244                         case NUM_TEAM_4:
 245                                 break;
 246                         default:
 247                                 if(GetTeam(Team, false) == world)
 248                                 {
 249                                         dprintf("trying to switch to unsupported team %d\n", Team);
 250                                         Team = NUM_SPECTATOR;
 251                                 }
 252                                 break;
 253                 }
 254         }
 255         else
 256         {
 257                 switch(Team)
 258                 {
 259                         case -1:
 260                         case 0:
 261                                 break;
 262                         default:
 263                                 if(GetTeam(Team, false) == world)
 264                                 {
 265                                         dprintf("trying to switch to unsupported team %d\n", Team);
 266                                         Team = NUM_SPECTATOR;
 267                                 }
 268                                 break;
 269                 }
 270         }
 271         if(Team == -1) // leave
 272         {
 273                 if(o.has_team)
 274                 {
 275                         tm = GetTeam(o.team, false);
 276                         tm.team_size -= 1;
 277                         o.has_team = 0;
 278                         return true;
 279                 }
 280         }
 281         else
 282         {
 283                 if (!o.has_team)
 284                 {
 285                         o.team = Team;
 286                         tm = GetTeam(Team, true);
 287                         tm.team_size += 1;
 288                         o.has_team = 1;
 289                         return true;
 290                 }
 291                 else if(Team != o.team)
 292                 {
 293                         tm = GetTeam(o.team, false);
 294                         tm.team_size -= 1;
 295                         o.team = Team;
 296                         tm = GetTeam(Team, true);
 297                         tm.team_size += 1;
 298                         return true;
 299                 }
 300         }
 301         return false;
 302 }
 303
 304 void Playerchecker_Think()
 305 {
 306     int i;
 307         entity e;
 308         for(i = 0; i < maxclients; ++i)
 309         {
 310                 e = playerslots[i];
 311                 if(GetPlayerName(i) == "")
 312                 {
 313                         if(e.sort_prev)
 314                         {
 315                                 // player disconnected
 316                                 SetTeam(e, -1);
 317                                 RemovePlayer(e);
 318                                 e.sort_prev = world;
 319                                 //e.gotscores = 0;
 320                         }
 321                 }
 322                 else
 323                 {
 324                         if (!e.sort_prev)
 325                         {
 326                                 // player connected
 327                                 if (!e)
 328                                         playerslots[i] = e = spawn();
 329                                 e.sv_entnum = i;
 330                                 e.ping = 0;
 331                                 e.ping_packetloss = 0;
 332                                 e.ping_movementloss = 0;
 333                                 //e.gotscores = 0; // we might already have the scores...
 334                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 335                                 RegisterPlayer(e);
 336                                 HUD_UpdatePlayerPos(e);
 337                         }
 338                 }
 339         }
 340         self.nextthink = time + 0.2;
 341 }
 342
 343 void Porto_Init();
 344 void TrueAim_Init();
 345 void PostInit(void)
 346 {
 347         entity playerchecker;
 348         playerchecker = spawn();
 349         playerchecker.think = Playerchecker_Think;
 350         playerchecker.nextthink = time + 0.2;
 351
 352         Porto_Init();
 353         TrueAim_Init();
 354
 355         postinit = true;
 356 }
 357
 358 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 359 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 360 // All keys are in ascii.
 361 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 362 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 363 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 364 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 365 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 366 {
 367         float bSkipKey;
 368         bSkipKey = false;
 369
 370         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 371                 return true;
 372
 373         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 374                 return true;
 375
 376         if(menu_visible && menu_action)
 377                 if(menu_action(bInputType, nPrimary, nSecondary))
 378                         return true;
 379
 380         return bSkipKey;
 381 }
 382
 383 // END REQUIRED CSQC FUNCTIONS
 384 // --------------------------------------------------------------------------
 385
 386 // --------------------------------------------------------------------------
 387 // BEGIN OPTIONAL CSQC FUNCTIONS
 388
 389 void Ent_RemoveEntCS()
 390 {
 391         entcs_receiver[self.sv_entnum] = world;
 392 }
 393 void Ent_ReadEntCS()
 394 {
 395     int sf;
 396         InterpolateOrigin_Undo();
 397
 398         self.classname = "entcs_receiver";
 399         sf = ReadByte();
 400
 401         if(sf & 1)
 402                 self.sv_entnum = ReadByte();
 403         if(sf & 2)
 404         {
 405                 self.origin_x = ReadShort();
 406                 self.origin_y = ReadShort();
 407                 self.origin_z = ReadShort();
 408                 setorigin(self, self.origin);
 409         }
 410         if(sf & 4)
 411         {
 412                 self.angles_y = ReadByte() * 360.0 / 256;
 413                 self.angles_x = self.angles_z = 0;
 414         }
 415         if(sf & 8)
 416                 self.healthvalue = ReadByte() * 10;
 417         if(sf & 16)
 418                 self.armorvalue = ReadByte() * 10;
 419
 420         entcs_receiver[self.sv_entnum] = self;
 421         self.entremove = Ent_RemoveEntCS;
 422         self.iflags |= IFLAG_ORIGIN;
 423
 424         InterpolateOrigin_Note();
 425 }
 426
 427 void Ent_Remove();
 428
 429 void Ent_RemovePlayerScore()
 430 {
 431         if(self.owner) {
 432                 SetTeam(self.owner, -1);
 433                 self.owner.gotscores = 0;
 434                 for(int i = 0; i < MAX_SCORE; ++i) {
 435                         self.owner.(scores[i]) = 0; // clear all scores
 436                 }
 437         }
 438 }
 439
 440 void Ent_ReadPlayerScore()
 441 {
 442         int i, n;
 443         bool isNew;
 444         entity o;
 445
 446         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 447         // (no I've never heard of M-x replace-string, sed, or anything like that)
 448         isNew = !self.owner; // workaround for DP bug
 449         n = ReadByte()-1;
 450
 451 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 452         if(!isNew && n != self.sv_entnum)
 453         {
 454                 //print("A CSQC entity changed its owner!\n");
 455                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 456                 isNew = true;
 457                 Ent_Remove();
 458                 self.enttype = ENT_CLIENT_SCORES;
 459         }
 460 #endif
 461
 462         self.sv_entnum = n;
 463
 464         if (!(playerslots[self.sv_entnum]))
 465                 playerslots[self.sv_entnum] = spawn();
 466         o = self.owner = playerslots[self.sv_entnum];
 467         o.sv_entnum = self.sv_entnum;
 468         o.gotscores = 1;
 469
 470         //if (!o.sort_prev)
 471         //      RegisterPlayer(o);
 472         //playerchecker will do this for us later, if it has not already done so
 473
 474     int sf, lf;
 475 #if MAX_SCORE <= 8
 476         sf = ReadByte();
 477         lf = ReadByte();
 478 #else
 479         sf = ReadShort();
 480         lf = ReadShort();
 481 #endif
 482     int p;
 483         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 484                 if(sf & p)
 485                 {
 486                         if(lf & p)
 487                                 o.(scores[i]) = ReadInt24_t();
 488                         else
 489                                 o.(scores[i]) = ReadChar();
 490                 }
 491
 492         if(o.sort_prev)
 493                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 494
 495         self.entremove = Ent_RemovePlayerScore;
 496 }
 497
 498 void Ent_ReadTeamScore()
 499 {
 500         int i;
 501         entity o;
 502
 503         self.team = ReadByte();
 504         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 505
 506     int sf, lf;
 507 #if MAX_TEAMSCORE <= 8
 508         sf = ReadByte();
 509         lf = ReadByte();
 510 #else
 511         sf = ReadShort();
 512         lf = ReadShort();
 513 #endif
 514         int p;
 515         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 516                 if(sf & p)
 517                 {
 518                         if(lf & p)
 519                                 o.(teamscores[i]) = ReadInt24_t();
 520                         else
 521                                 o.(teamscores[i]) = ReadChar();
 522                 }
 523
 524         HUD_UpdateTeamPos(o);
 525 }
 526
 527 void Ent_ClientData()
 528 {
 529         float newspectatee_status;
 530
 531     int f = ReadByte();
 532
 533         scoreboard_showscores_force = (f & 1);
 534
 535         if(f & 2)
 536         {
 537                 newspectatee_status = ReadByte();
 538                 if(newspectatee_status == player_localnum + 1)
 539                         newspectatee_status = -1; // observing
 540         }
 541         else
 542                 newspectatee_status = 0;
 543
 544         spectatorbutton_zoom = (f & 4);
 545
 546         if(f & 8)
 547         {
 548                 angles_held_status = 1;
 549                 angles_held.x = ReadAngle();
 550                 angles_held.y = ReadAngle();
 551                 angles_held.z = 0;
 552         }
 553         else
 554                 angles_held_status = 0;
 555
 556         if(newspectatee_status != spectatee_status)
 557         {
 558                 // clear race stuff
 559                 race_laptime = 0;
 560                 race_checkpointtime = 0;
 561         }
 562         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 563         {
 564                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 565                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 566                 )
 567                         prev_p_health = -1;
 568                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 569                         prev_health = -1;
 570         }
 571         spectatee_status = newspectatee_status;
 572
 573         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 574 }
 575
 576 void Ent_Nagger()
 577 {
 578     int i, j, b, f;
 579
 580     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 581
 582         if(!(nags & 4))
 583         {
 584                 if(vote_called_vote)
 585                         strunzone(vote_called_vote);
 586                 vote_called_vote = string_null;
 587                 vote_active = 0;
 588         }
 589         else
 590         {
 591                 vote_active = 1;
 592         }
 593
 594         if(nags & 64)
 595         {
 596                 vote_yescount = ReadByte();
 597                 vote_nocount = ReadByte();
 598                 vote_needed = ReadByte();
 599                 vote_highlighted = ReadChar();
 600         }
 601
 602         if(nags & 128)
 603         {
 604                 if(vote_called_vote)
 605                         strunzone(vote_called_vote);
 606                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 607         }
 608
 609         if(nags & 1)
 610         {
 611                 for(j = 0; j < maxclients; ++j)
 612                         if(playerslots[j])
 613                                 playerslots[j].ready = 1;
 614                 for(i = 1; i <= maxclients; i += 8)
 615                 {
 616                         f = ReadByte();
 617                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 618                                 if (!(f & b))
 619                                         if(playerslots[j])
 620                                                 playerslots[j].ready = 0;
 621                 }
 622         }
 623
 624         ready_waiting = (nags & 1);
 625         ready_waiting_for_me = (nags & 2);
 626         vote_waiting = (nags & 4);
 627         vote_waiting_for_me = (nags & 8);
 628         warmup_stage = (nags & 16);
 629 }
 630
 631 void Ent_EliminatedPlayers()
 632 {
 633     int i, j, b, f;
 634
 635     int sf = ReadByte();
 636         if(sf & 1)
 637         {
 638                 for(j = 0; j < maxclients; ++j)
 639                         if(playerslots[j])
 640                                 playerslots[j].eliminated = 1;
 641                 for(i = 1; i <= maxclients; i += 8)
 642                 {
 643                         f = ReadByte();
 644                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 645                                 if (!(f & b))
 646                                         if(playerslots[j])
 647                                                 playerslots[j].eliminated = 0;
 648                 }
 649         }
 650 }
 651
 652 void Ent_RandomSeed()
 653 {
 654         float s;
 655         prandom_debug();
 656         s = ReadShort();
 657         psrandom(s);
 658 }
 659
 660 void Ent_ReadAccuracy(void)
 661 {
 662     int f, w;
 663     int sf = ReadInt24_t();
 664         if(sf == 0)
 665         {
 666                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 667                         weapon_accuracy[w] = -1;
 668                 return;
 669         }
 670
 671         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 672         {
 673                 if(sf & f)
 674                 {
 675             int b = ReadByte();
 676                         if(b == 0)
 677                                 weapon_accuracy[w] = -1;
 678                         else if(b == 255)
 679                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 680                         else
 681                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 682                 }
 683                 if(f == 0x800000)
 684                         f = 1;
 685                 else
 686                         f *= 2;
 687         }
 688 }
 689
 690 void Spawn_Draw(void)
 691 {
 692         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 693 }
 694
 695 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 696 {
 697         float teamnum = (ReadByte() - 1);
 698         vector spn_origin;
 699         spn_origin.x = ReadShort();
 700         spn_origin.y = ReadShort();
 701         spn_origin.z = ReadShort();
 702
 703         if(is_new)
 704         {
 705                 self.origin = spn_origin;
 706                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 707                 droptofloor();
 708
 709                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 710                 {
 711                         self.mdl = "models/spawnpoint.md3";
 712                         self.colormod = Team_ColorRGB(teamnum);
 713                         precache_model(self.mdl);
 714                         setmodel(self, self.mdl);
 715                         self.drawmask = MASK_NORMAL;
 716                         //self.movetype = MOVETYPE_NOCLIP;
 717                         //self.draw = Spawn_Draw;
 718                 }*/
 719                 if(autocvar_cl_spawn_point_particles)
 720                 {
 721                         if((serverflags & SERVERFLAG_TEAMPLAY))
 722                         {
 723                                 switch(teamnum)
 724                                 {
 725                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 726                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 727                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 728                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 729                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 730                                 }
 731                         }
 732                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 733
 734                         self.draw = Spawn_Draw;
 735                 }
 736         }
 737
 738         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 739 }
 740
 741 void Ent_ReadSpawnEvent(float is_new)
 742 {
 743         // If entnum is 0, ONLY do the local spawn actions
 744         // this way the server can disable the sending of
 745         // spawn origin or such to clients if wanted.
 746         float entnum = ReadByte();
 747
 748         if(entnum)
 749         {
 750                 self.origin_x = ReadShort();
 751                 self.origin_y = ReadShort();
 752                 self.origin_z = ReadShort();
 753
 754                 if(is_new)
 755                 {
 756                         float teamnum = GetPlayerColor(entnum - 1);
 757
 758                         if(autocvar_cl_spawn_event_particles)
 759                         {
 760                                 switch(teamnum)
 761                                 {
 762                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 764                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 765                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 766                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 767                                 }
 768                         }
 769                         if(autocvar_cl_spawn_event_sound)
 770                         {
 771                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 772                         }
 773                 }
 774         }
 775
 776         // local spawn actions
 777         if(is_new && (!entnum || (entnum == player_localentnum)))
 778         {
 779                 zoomin_effect = 1;
 780                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 781
 782                 if(autocvar_cl_unpress_zoom_on_spawn)
 783                 {
 784                         localcmd("-zoom\n");
 785                         button_zoom = false;
 786                 }
 787         }
 788
 789         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 790 }
 791
 792 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 793 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 794 void Ent_RadarLink();
 795 void Ent_Init();
 796 void Ent_ScoresInfo();
 797 void CSQC_Ent_Update(float bIsNewEntity)
 798 {
 799         float t;
 800         float savetime;
 801         t = ReadByte();
 802
 803         if(autocvar_developer_csqcentities)
 804                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 805
 806         // set up the "time" global for received entities to be correct for interpolation purposes
 807         savetime = time;
 808         if(servertime)
 809         {
 810                 time = servertime;
 811         }
 812         else
 813         {
 814                 serverprevtime = time;
 815                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 816                 time = serverprevtime + serverdeltatime;
 817         }
 818
 819 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 820         if(self.enttype)
 821         {
 822                 if(t != self.enttype || bIsNewEntity)
 823                 {
 824                         //print("A CSQC entity changed its type!\n");
 825                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 826                         Ent_Remove();
 827                         clearentity(self);
 828                         bIsNewEntity = 1;
 829                 }
 830         }
 831         else
 832         {
 833                 if(!bIsNewEntity)
 834                 {
 835                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 836                         bIsNewEntity = 1;
 837                 }
 838         }
 839 #endif
 840         self.enttype = t;
 841         switch(t)
 842         {
 843                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 844                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 845                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 846                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 847                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 848                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 849                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 850                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 851                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 852                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 853                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 854                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 855                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 856                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 857                 case ENT_CLIENT_INIT: Ent_Init(); break;
 858                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 859                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 860                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 861                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 862                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 863                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 864                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 865                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 866                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 867                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 868                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 869                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 870                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 871                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 872                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 873                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 874                 case ENT_CLIENT_TURRET: ent_turret(); break;
 875                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 876                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 877                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 878                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 879                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 880                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 881                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 882                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 883                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 884                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 885                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 886                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 887                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 888                 case ENT_CLIENT_DOOR: ent_door(); break;
 889                 case ENT_CLIENT_PLAT: ent_plat(); break;
 890                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 891                 case ENT_CLIENT_CORNER: ent_corner(); break;
 892                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 893                 case ENT_CLIENT_TRAIN: ent_train(); break;
 894                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 895                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 896
 897                 default:
 898                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 899                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 900                         break;
 901         }
 902
 903         time = savetime;
 904 }
 905 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 906 // used when an entity changes its type. For an entity that someone interacts
 907 // with others, make sure it can no longer do so.
 908 void Ent_Remove()
 909 {
 910         if(self.entremove)
 911                 self.entremove();
 912
 913         if(self.skeletonindex)
 914         {
 915                 skel_delete(self.skeletonindex);
 916                 self.skeletonindex = 0;
 917         }
 918
 919         if(self.snd_looping > 0)
 920         {
 921                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 922                 self.snd_looping = 0;
 923         }
 924
 925         self.enttype = 0;
 926         self.classname = "";
 927         self.draw = menu_sub_null;
 928         self.entremove = menu_sub_null;
 929         // TODO possibly set more stuff to defaults
 930 }
 931 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 932 void CSQC_Ent_Remove()
 933 {
 934         if(autocvar_developer_csqcentities)
 935                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 936
 937         if(wasfreed(self))
 938         {
 939                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 940                 return;
 941         }
 942         if(self.enttype)
 943                 Ent_Remove();
 944         remove(self);
 945 }
 946
 947 void Gamemode_Init()
 948 {
 949         if (!isdemo())
 950         {
 951                 if(!(calledhooks & HOOK_START))
 952                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 953                 calledhooks |= HOOK_START;
 954         }
 955 }
 956 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 957 void CSQC_Parse_StuffCmd(string strMessage)
 958 {
 959         if(autocvar_developer_csqcentities)
 960                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 961
 962         localcmd(strMessage);
 963 }
 964 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 965 void CSQC_Parse_Print(string strMessage)
 966 {
 967         if(autocvar_developer_csqcentities)
 968                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 969
 970         print(ColorTranslateRGB(strMessage));
 971 }
 972
 973 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 974 void CSQC_Parse_CenterPrint(string strMessage)
 975 {
 976         if(autocvar_developer_csqcentities)
 977                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 978
 979         centerprint_hud(strMessage);
 980 }
 981
 982 string notranslate_fogcmd1 = "\nfog ";
 983 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 984 void Fog_Force()
 985 {
 986         // TODO somehow thwart prvm_globalset client ...
 987
 988         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 989                 { localcmd("\nr_drawfog 0\n"); }
 990         else if(forcefog != "")
 991                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 992 }
 993
 994 void Gamemode_Init();
 995 void Ent_ScoresInfo()
 996 {
 997     int i;
 998         self.classname = "ent_client_scores_info";
 999         gametype = ReadInt24_t();
1000         HUD_ModIcons_SetFunc();
1001         for(i = 0; i < MAX_SCORE; ++i)
1002         {
1003                 if(scores_label[i])
1004                         strunzone(scores_label[i]);
1005                 scores_label[i] = strzone(ReadString());
1006                 scores_flags[i] = ReadByte();
1007         }
1008         for(i = 0; i < MAX_TEAMSCORE; ++i)
1009         {
1010                 if(teamscores_label[i])
1011                         strunzone(teamscores_label[i]);
1012                 teamscores_label[i] = strzone(ReadString());
1013                 teamscores_flags[i] = ReadByte();
1014         }
1015         HUD_InitScores();
1016         Gamemode_Init();
1017 }
1018
1019 void Ent_Init()
1020 {
1021         self.classname = "ent_client_init";
1022
1023         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1024
1025         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1026         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1027         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1028         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1029         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1030         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1031         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1032         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1033
1034         if(forcefog)
1035                 strunzone(forcefog);
1036         forcefog = strzone(ReadString());
1037
1038         armorblockpercent = ReadByte() / 255.0;
1039
1040         g_balance_mortar_bouncefactor = ReadCoord();
1041         g_balance_mortar_bouncestop = ReadCoord();
1042         g_balance_electro_secondary_bouncefactor = ReadCoord();
1043         g_balance_electro_secondary_bouncestop = ReadCoord();
1044
1045         vortex_scope = !ReadByte();
1046         rifle_scope = !ReadByte();
1047
1048         serverflags = ReadByte();
1049
1050         minelayer_maxmines = ReadByte();
1051
1052         hagar_maxrockets = ReadByte();
1053
1054         g_trueaim_minrange = ReadCoord();
1055         g_balance_porto_secondary = ReadByte();
1056
1057         if(!postinit)
1058                 PostInit();
1059 }
1060
1061 void Net_ReadRace()
1062 {
1063         float b;
1064
1065         b = ReadByte();
1066
1067         switch(b)
1068         {
1069                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1070                         race_checkpoint = ReadByte();
1071                         race_time = ReadInt24_t();
1072                         race_previousbesttime = ReadInt24_t();
1073                         if(race_previousbestname)
1074                                 strunzone(race_previousbestname);
1075                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1076
1077                         race_checkpointtime = time;
1078
1079                         if(race_checkpoint == 0 || race_checkpoint == 254)
1080                         {
1081                                 race_penaltyaccumulator = 0;
1082                                 race_laptime = time; // valid
1083                         }
1084
1085                         break;
1086
1087                 case RACE_NET_CHECKPOINT_CLEAR:
1088                         race_laptime = 0;
1089                         race_checkpointtime = 0;
1090                         break;
1091
1092                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1093                         race_laptime = ReadCoord();
1094                         race_checkpointtime = -99999;
1095                         // fall through
1096                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1097                         race_nextcheckpoint = ReadByte();
1098
1099                         race_nextbesttime = ReadInt24_t();
1100                         if(race_nextbestname)
1101                                 strunzone(race_nextbestname);
1102                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1103                         break;
1104
1105                 case RACE_NET_CHECKPOINT_HIT_RACE:
1106                         race_mycheckpoint = ReadByte();
1107                         race_mycheckpointtime = time;
1108                         race_mycheckpointdelta = ReadInt24_t();
1109                         race_mycheckpointlapsdelta = ReadByte();
1110                         if(race_mycheckpointlapsdelta >= 128)
1111                                 race_mycheckpointlapsdelta -= 256;
1112                         if(race_mycheckpointenemy)
1113                                 strunzone(race_mycheckpointenemy);
1114                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1115                         break;
1116
1117                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1118                         race_othercheckpoint = ReadByte();
1119                         race_othercheckpointtime = time;
1120                         race_othercheckpointdelta = ReadInt24_t();
1121                         race_othercheckpointlapsdelta = ReadByte();
1122                         if(race_othercheckpointlapsdelta >= 128)
1123                                 race_othercheckpointlapsdelta -= 256;
1124                         if(race_othercheckpointenemy)
1125                                 strunzone(race_othercheckpointenemy);
1126                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1127                         break;
1128
1129                 case RACE_NET_PENALTY_RACE:
1130                         race_penaltyeventtime = time;
1131                         race_penaltytime = ReadShort();
1132                         //race_penaltyaccumulator += race_penaltytime;
1133                         if(race_penaltyreason)
1134                                 strunzone(race_penaltyreason);
1135                         race_penaltyreason = strzone(ReadString());
1136                         break;
1137
1138                 case RACE_NET_PENALTY_QUALIFYING:
1139                         race_penaltyeventtime = time;
1140                         race_penaltytime = ReadShort();
1141                         race_penaltyaccumulator += race_penaltytime;
1142                         if(race_penaltyreason)
1143                                 strunzone(race_penaltyreason);
1144                         race_penaltyreason = strzone(ReadString());
1145                         break;
1146
1147                 case RACE_NET_SERVER_RECORD:
1148                         race_server_record = ReadInt24_t();
1149                         break;
1150                 case RACE_NET_SPEED_AWARD:
1151                         race_speedaward = ReadInt24_t();
1152                         if(race_speedaward_holder)
1153                                 strunzone(race_speedaward_holder);
1154                         race_speedaward_holder = strzone(ReadString());
1155                         break;
1156                 case RACE_NET_SPEED_AWARD_BEST:
1157                         race_speedaward_alltimebest = ReadInt24_t();
1158                         if(race_speedaward_alltimebest_holder)
1159                                 strunzone(race_speedaward_alltimebest_holder);
1160                         race_speedaward_alltimebest_holder = strzone(ReadString());
1161                         break;
1162                 case RACE_NET_SERVER_RANKINGS:
1163                         float prevpos, del;
1164             int pos = ReadShort();
1165                         prevpos = ReadShort();
1166                         del = ReadShort();
1167
1168                         // move other rankings out of the way
1169             int i;
1170                         if (prevpos) {
1171                                 for (i=prevpos-1;i>pos-1;--i) {
1172                                         grecordtime[i] = grecordtime[i-1];
1173                                         if(grecordholder[i])
1174                                                 strunzone(grecordholder[i]);
1175                                         grecordholder[i] = strzone(grecordholder[i-1]);
1176                                 }
1177                         } else if (del) { // a record has been deleted by the admin
1178                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1179                                         if (i == RANKINGS_CNT-1) { // clear out last record
1180                                                 grecordtime[i] = 0;
1181                                                 if (grecordholder[i])
1182                                                         strunzone(grecordholder[i]);
1183                                                 grecordholder[i] = string_null;
1184                                         }
1185                                         else {
1186                                                 grecordtime[i] = grecordtime[i+1];
1187                                                 if (grecordholder[i])
1188                                                         strunzone(grecordholder[i]);
1189                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1190                                         }
1191                                 }
1192                         } else { // player has no ranked record yet
1193                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1194                                         grecordtime[i] = grecordtime[i-1];
1195                                         if(grecordholder[i])
1196                                                 strunzone(grecordholder[i]);
1197                                         grecordholder[i] = strzone(grecordholder[i-1]);
1198                                 }
1199                         }
1200
1201                         // store new ranking
1202                         if(grecordholder[pos-1] != "")
1203                                 strunzone(grecordholder[pos-1]);
1204                         grecordholder[pos-1] = strzone(ReadString());
1205                         grecordtime[pos-1] = ReadInt24_t();
1206                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1207                                 race_myrank = pos;
1208                         break;
1209                 case RACE_NET_SERVER_STATUS:
1210                         race_status = ReadShort();
1211                         if(race_status_name)
1212                                 strunzone(race_status_name);
1213                         race_status_name = strzone(ReadString());
1214         }
1215 }
1216
1217 void Net_TeamNagger()
1218 {
1219         teamnagger = 1;
1220 }
1221
1222 void Net_ReadPingPLReport()
1223 {
1224         int e, pi, pl, ml;
1225         e = ReadByte();
1226         pi = ReadShort();
1227         pl = ReadByte();
1228         ml = ReadByte();
1229         if (!(playerslots[e]))
1230                 return;
1231         playerslots[e].ping = pi;
1232         playerslots[e].ping_packetloss = pl / 255.0;
1233         playerslots[e].ping_movementloss = ml / 255.0;
1234 }
1235
1236 void Net_WeaponComplain()
1237 {
1238         complain_weapon = ReadByte();
1239
1240         if(complain_weapon_name)
1241                 strunzone(complain_weapon_name);
1242         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1243
1244         complain_weapon_type = ReadByte();
1245
1246         complain_weapon_time = time;
1247         weapontime = time; // ping the weapon panel
1248
1249         switch(complain_weapon_type)
1250         {
1251                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1252                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1253                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1254         }
1255 }
1256
1257 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1258 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1259 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1260 float CSQC_Parse_TempEntity()
1261 {
1262         float bHandled;
1263                 bHandled  = true;
1264         // Acquire TE ID
1265         float nTEID;
1266                 nTEID = ReadByte();
1267
1268         if(autocvar_developer_csqcentities)
1269                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1270
1271                 // NOTE: Could just do return instead of break...
1272         switch(nTEID)
1273         {
1274                 case TE_CSQC_TARGET_MUSIC:
1275                         Net_TargetMusic();
1276                         bHandled = true;
1277                         break;
1278                 case TE_CSQC_PICTURE:
1279                         Net_MapVote_Picture();
1280                         bHandled = true;
1281                         break;
1282                 case TE_CSQC_RACE:
1283                         Net_ReadRace();
1284                         bHandled = true;
1285                         break;
1286                 case TE_CSQC_VORTEXBEAMPARTICLE:
1287                         Net_ReadVortexBeamParticle();
1288                         bHandled = true;
1289                         break;
1290                 case TE_CSQC_TEAMNAGGER:
1291                         Net_TeamNagger();
1292                         bHandled = true;
1293                         break;
1294                 case TE_CSQC_ARC:
1295                         Net_ReadArc();
1296                         bHandled = true;
1297                         break;
1298                 case TE_CSQC_PINGPLREPORT:
1299                         Net_ReadPingPLReport();
1300                         bHandled = true;
1301                         break;
1302                 case TE_CSQC_WEAPONCOMPLAIN:
1303                         Net_WeaponComplain();
1304                         bHandled = true;
1305                         break;
1306                 case TE_CSQC_VEHICLESETUP:
1307                         Net_VehicleSetup();
1308                         bHandled = true;
1309                         break;
1310                 case TE_CSQC_SVNOTICE:
1311                         cl_notice_read();
1312                         bHandled = true;
1313                         break;
1314                 case TE_CSQC_SHOCKWAVEPARTICLE:
1315                         Net_ReadShockwaveParticle();
1316                         bHandled = true;
1317                         break;
1318                 default:
1319                         // No special logic for this temporary entity; return 0 so the engine can handle it
1320                         bHandled = false;
1321                         break;
1322         }
1323
1324         return bHandled;
1325 }
1326
1327 string getcommandkey(string text, string command)
1328 {
1329         string keys;
1330         float n, j, k, l = 0;
1331
1332         if (!autocvar_hud_showbinds)
1333                 return text;
1334
1335         keys = db_get(binddb, command);
1336         if (keys == "")
1337         {
1338                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1339                 for(j = 0; j < n; ++j)
1340                 {
1341                         k = stof(argv(j));
1342                         if(k != -1)
1343                         {
1344                                 if ("" == keys)
1345                                         keys = keynumtostring(k);
1346                                 else
1347                                         keys = strcat(keys, ", ", keynumtostring(k));
1348
1349                                 ++l;
1350                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1351                                         break;
1352                         }
1353
1354                 }
1355                 if (keys == "")
1356                         keys = "NO_KEY";
1357                 db_put(binddb, command, keys);
1358         }
1359
1360         if (keys == "NO_KEY") {
1361                 if (autocvar_hud_showbinds > 1)
1362                         return sprintf(_("%s (not bound)"), text);
1363                 else
1364                         return text;
1365         }
1366         else if (autocvar_hud_showbinds > 1)
1367                 return sprintf("%s (%s)", text, keys);
1368         else
1369                 return keys;
1370 }