Load csqc cursor attributes from the current menu skin file rather than using constan...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2
3 #include <common/effects/qc/all.qh>
4 #include "hud/all.qh"
5 #include "mapvoting.qh"
6 #include "mutators/events.qh"
7 #include "quickmenu.qh"
8 #include "scoreboard.qh"
9 #include "shownames.qh"
10 #include <common/t_items.qh>
11 #include "wall.qh"
12 #include "weapons/projectile.qh"
13 #include <common/deathtypes/all.qh>
14 #include <common/items/all.qh>
15 #include <common/mapinfo.qh>
16 #include <common/minigames/cl_minigames.qh>
17 #include <common/minigames/cl_minigames_hud.qh>
18 #include <common/net_notice.qh>
19 #include <common/triggers/include.qh>
20 #include <common/vehicles/all.qh>
21 #include <lib/csqcmodel/cl_model.qh>
22 #include <lib/csqcmodel/interpolate.qh>
23 #include <lib/warpzone/client.qh>
24
25 // --------------------------------------------------------------------------
26 // BEGIN REQUIRED CSQC FUNCTIONS
27 //include "main.qh"
28
29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
30
31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
32 {
33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
35 }
36
37 void draw_cursor_normal(vector pos, vector col, float a)
38 {
39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
40 }
41
42 void LoadMenuSkinValues()
43 {
44         int fh = -1;
45         if(cvar_string("menu_skin") != "")
46         {
47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
49         }
50         if(fh < 0 && cvar_defstring("menu_skin") != "")
51         {
52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
55         }
56         if(fh < 0)
57         {
58                 draw_currentSkin = "gfx/menu/default";
59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
60         }
61
62         draw_currentSkin = strzone(draw_currentSkin);
63
64         if(fh >= 0)
65         {
66                 string s;
67                 while((s = fgets(fh)))
68                 {
69                         int n = tokenize_console(s);
70                         if (n < 2)
71                                 continue;
72                         if(substring(argv(0), 0, 2) == "//")
73                                 continue;
74                         if(argv(0) == "SIZE_CURSOR")
75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
76                         else if(argv(0) == "OFFSET_CURSOR")
77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
78                 }
79                 fclose(fh);
80         }
81 }
82
83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
84 // Useful for precaching things
85
86 void ConsoleCommand_macro_init();
87 void CSQC_Init()
88 {
89         prvm_language = strzone(cvar_string("prvm_language"));
90
91 #ifdef WATERMARK
92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
93 #endif
94
95         {
96                 int i = 0;
97                 for ( ; i < 255; ++i)
98                         if (getplayerkeyvalue(i, "viewentity") == "")
99                                 break;
100                 maxclients = i;
101         }
102
103         // needs to be done so early because of the constants they create
104         static_init();
105         static_init_late();
106         static_init_precache();
107
108         binddb = db_create();
109         tempdb = db_create();
110         ClientProgsDB = db_load("client.db");
111         compressShortVector_init();
112
113         draw_endBoldFont();
114
115         //registercommand("hud_configure");
116         //registercommand("hud_save");
117         //registercommand("menu_action");
118
119         ConsoleCommand_macro_init();
120
121         registercvar("hud_usecsqc", "1");
122         registercvar("scoreboard_columns", "default");
123
124         registercvar("cl_nade_type", "3");
125         registercvar("cl_pokenade_type", "zombie");
126
127         registercvar("cl_jumpspeedcap_min", "");
128         registercvar("cl_jumpspeedcap_max", "");
129
130         registercvar("cl_multijump", "0");
131
132         registercvar("cl_spawn_near_teammate", "1");
133
134         gametype = 0;
135
136         // hud_fields uses strunzone on the titles!
137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
138                 hud_title[i] = strzone("(null)");
139
140         Cmd_HUD_SetFields(0);
141
142         postinit = false;
143
144         calledhooks = 0;
145
146         teams = Sort_Spawn();
147         players = Sort_Spawn();
148
149         GetTeam(NUM_SPECTATOR, true); // add specs first
150
151         // precaches
152
153         if(autocvar_cl_reticle)
154         {
155                 precache_pic("gfx/reticle_normal");
156                 // weapon reticles are precached in weapon files
157         }
158
159         {
160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
162                 shortmapname = mi_shortname;
163
164                 if (precache_pic(minimapname) == "")
165                 {
166                         // but maybe we have a non-clever minimap
167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
168                         if (precache_pic(minimapname) == "")
169                                 minimapname = ""; // FAIL
170                         else
171                                 get_mi_min_max_texcoords(0); // load new texcoords
172                 }
173
174                 mi_center = (mi_min + mi_max) * 0.5;
175                 mi_scale = mi_max - mi_min;
176                 minimapname = strzone(minimapname);
177         }
178
179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
180         LoadMenuSkinValues();
181 }
182
183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
184 void Shutdown()
185 {
186         WarpZone_Shutdown();
187
188         remove(teams);
189         remove(players);
190         db_close(binddb);
191         db_close(tempdb);
192         if(autocvar_cl_db_saveasdump)
193                 db_dump(ClientProgsDB, "client.db");
194         else
195                 db_save(ClientProgsDB, "client.db");
196         db_close(ClientProgsDB);
197
198         if(camera_active)
199                 cvar_set("chase_active",ftos(chase_active_backup));
200
201         // unset the event chasecam's chase_active
202         if(autocvar_chase_active < 0)
203                 cvar_set("chase_active", "0");
204
205         if (!isdemo())
206         {
207                 if (!(calledhooks & HOOK_START))
208                         localcmd("\n_cl_hook_gamestart nop\n");
209                 if (!(calledhooks & HOOK_END))
210                         localcmd("\ncl_hook_gameend\n");
211         }
212
213         deactivate_minigame();
214         HUD_MinigameMenu_Close();
215 }
216
217 .float has_team;
218 float SetTeam(entity o, int Team)
219 {
220         devassert_once(Team);
221         entity tm;
222         if(teamplay)
223         {
224                 switch(Team)
225                 {
226                         case -1:
227                         case NUM_TEAM_1:
228                         case NUM_TEAM_2:
229                         case NUM_TEAM_3:
230                         case NUM_TEAM_4:
231                                 break;
232                         default:
233                                 if(GetTeam(Team, false) == world)
234                                 {
235                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
236                                         Team = NUM_SPECTATOR;
237                                 }
238                                 break;
239                 }
240         }
241         else
242         {
243                 switch(Team)
244                 {
245                         case -1:
246                         case 0:
247                                 break;
248                         default:
249                                 if(GetTeam(Team, false) == world)
250                                 {
251                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
252                                         Team = NUM_SPECTATOR;
253                                 }
254                                 break;
255                 }
256         }
257         if(Team == -1) // leave
258         {
259                 if(o.has_team)
260                 {
261                         tm = GetTeam(o.team, false);
262                         tm.team_size -= 1;
263                         o.has_team = 0;
264                         return true;
265                 }
266         }
267         else
268         {
269                 if (!o.has_team)
270                 {
271                         o.team = Team;
272                         tm = GetTeam(Team, true);
273                         tm.team_size += 1;
274                         o.has_team = 1;
275                         return true;
276                 }
277                 else if(Team != o.team)
278                 {
279                         tm = GetTeam(o.team, false);
280                         tm.team_size -= 1;
281                         o.team = Team;
282                         tm = GetTeam(Team, true);
283                         tm.team_size += 1;
284                         return true;
285                 }
286         }
287         return false;
288 }
289
290 void Playerchecker_Think()
291 {
292         SELFPARAM();
293     int i;
294         entity e;
295         for(i = 0; i < maxclients; ++i)
296         {
297                 e = playerslots[i];
298                 if(entcs_GetName(i) == "")
299                 {
300                         if(e.sort_prev)
301                         {
302                                 // player disconnected
303                                 SetTeam(e, -1);
304                                 RemovePlayer(e);
305                                 e.sort_prev = world;
306                                 //e.gotscores = 0;
307                         }
308                 }
309                 else
310                 {
311                         if (!e.sort_prev)
312                         {
313                                 // player connected
314                                 if (!e)
315                                 {
316                                         playerslots[i] = e = new(playerslot);
317                                         make_pure(e);
318                                 }
319                                 e.sv_entnum = i;
320                                 e.ping = 0;
321                                 e.ping_packetloss = 0;
322                                 e.ping_movementloss = 0;
323                                 //e.gotscores = 0; // we might already have the scores...
324                                 int t = entcs_GetScoreTeam(i);
325                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
326                                 RegisterPlayer(e);
327                                 HUD_UpdatePlayerPos(e);
328                         }
329                 }
330         }
331         this.nextthink = time + 0.2;
332 }
333
334 void Porto_Init();
335 void TrueAim_Init();
336 void PostInit()
337 {
338         entity playerchecker = new(playerchecker);
339         make_pure(playerchecker);
340         playerchecker.think = Playerchecker_Think;
341         playerchecker.nextthink = time + 0.2;
342
343         Porto_Init();
344         TrueAim_Init();
345
346         postinit = true;
347 }
348
349 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
350 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
351 // All keys are in ascii.
352 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
353 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
354 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
355 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
356 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
357 {
358         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
359                 return true;
360
361         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
362                 return true;
363
364         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
365                 return true;
366
367         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
368                 return true;
369
370         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
371                 return true;
372
373         return false;
374 }
375
376 // END REQUIRED CSQC FUNCTIONS
377 // --------------------------------------------------------------------------
378
379 // --------------------------------------------------------------------------
380 // BEGIN OPTIONAL CSQC FUNCTIONS
381
382 .void(entity) predraw_qc;
383 void PreDraw_self()
384 {
385         SELFPARAM();
386         if (this.predraw_qc) this.predraw_qc(this);
387 }
388
389 void setpredraw(entity this, void(entity) pdfunc)
390 {
391         this.predraw = PreDraw_self;
392         this.predraw_qc = pdfunc;
393 }
394
395 void Ent_Remove(entity this);
396
397 void Ent_RemovePlayerScore(entity this)
398 {
399         if(this.owner) {
400                 SetTeam(this.owner, -1);
401                 this.owner.gotscores = 0;
402                 for(int i = 0; i < MAX_SCORE; ++i) {
403                         this.owner.(scores[i]) = 0; // clear all scores
404                 }
405         }
406 }
407
408 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
409 {
410         make_pure(this);
411         int i, n;
412         bool isNew;
413         entity o;
414
415         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
416         // (no I've never heard of M-x replace-string, sed, or anything like that)
417         isNew = !this.owner; // workaround for DP bug
418         n = ReadByte()-1;
419
420 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
421         if(!isNew && n != this.sv_entnum)
422         {
423                 //print("A CSQC entity changed its owner!\n");
424                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
425                 isNew = true;
426                 Ent_Remove(this);
427         }
428 #endif
429
430         this.sv_entnum = n;
431
432         o = playerslots[this.sv_entnum];
433         if (!o)
434         {
435                 o = playerslots[this.sv_entnum] = new(playerslot);
436                 make_pure(o);
437         }
438         this.owner = o;
439         o.sv_entnum = this.sv_entnum;
440         o.gotscores = 1;
441
442         //if (!o.sort_prev)
443         //      RegisterPlayer(o);
444         //playerchecker will do this for us later, if it has not already done so
445
446     int sf, lf;
447 #if MAX_SCORE <= 8
448         sf = ReadByte();
449         lf = ReadByte();
450 #else
451         sf = ReadShort();
452         lf = ReadShort();
453 #endif
454     int p;
455         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
456                 if(sf & p)
457                 {
458                         if(lf & p)
459                                 o.(scores[i]) = ReadInt24_t();
460                         else
461                                 o.(scores[i]) = ReadChar();
462                 }
463
464         return = true;
465
466         if(o.sort_prev)
467                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
468
469         this.entremove = Ent_RemovePlayerScore;
470 }
471
472 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
473 {
474         make_pure(this);
475         int i;
476         entity o;
477
478         this.team = ReadByte();
479         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
480
481     int sf, lf;
482 #if MAX_TEAMSCORE <= 8
483         sf = ReadByte();
484         lf = ReadByte();
485 #else
486         sf = ReadShort();
487         lf = ReadShort();
488 #endif
489         int p;
490         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
491                 if(sf & p)
492                 {
493                         if(lf & p)
494                                 o.(teamscores[i]) = ReadInt24_t();
495                         else
496                                 o.(teamscores[i]) = ReadChar();
497                 }
498
499         return = true;
500
501         HUD_UpdateTeamPos(o);
502 }
503
504 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
505 {
506         make_pure(this);
507         float newspectatee_status;
508
509     int f = ReadByte();
510
511         scoreboard_showscores_force = (f & 1);
512
513         if(f & 2)
514         {
515                 newspectatee_status = ReadByte();
516                 if(newspectatee_status == player_localnum + 1)
517                         newspectatee_status = -1; // observing
518         }
519         else
520                 newspectatee_status = 0;
521
522         spectatorbutton_zoom = (f & 4);
523
524         if(f & 8)
525         {
526                 angles_held_status = 1;
527                 angles_held.x = ReadAngle();
528                 angles_held.y = ReadAngle();
529                 angles_held.z = 0;
530         }
531         else
532                 angles_held_status = 0;
533
534         return = true;
535
536         if(newspectatee_status != spectatee_status)
537         {
538                 // clear race stuff
539                 race_laptime = 0;
540                 race_checkpointtime = 0;
541         }
542         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
543         {
544                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
545                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
546                 )
547                         prev_p_health = -1;
548                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
549                         prev_health = -1;
550         }
551         spectatee_status = newspectatee_status;
552
553         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
554 }
555
556 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
557 {
558         make_pure(this);
559     int i, j, b, f;
560
561     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
562
563         if(!(nags & BIT(2)))
564         {
565                 if(vote_called_vote)
566                         strunzone(vote_called_vote);
567                 vote_called_vote = string_null;
568                 vote_active = 0;
569         }
570         else
571         {
572                 vote_active = 1;
573         }
574
575         if(nags & BIT(6))
576         {
577                 vote_yescount = ReadByte();
578                 vote_nocount = ReadByte();
579                 vote_needed = ReadByte();
580                 vote_highlighted = ReadChar();
581         }
582
583         if(nags & BIT(7))
584         {
585                 if(vote_called_vote)
586                         strunzone(vote_called_vote);
587                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
588         }
589
590         if(nags & 1)
591         {
592                 for(j = 0; j < maxclients; ++j)
593                         if(playerslots[j])
594                                 playerslots[j].ready = 1;
595                 for(i = 1; i <= maxclients; i += 8)
596                 {
597                         f = ReadByte();
598                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
599                                 if (!(f & b))
600                                         if(playerslots[j])
601                                                 playerslots[j].ready = 0;
602                 }
603         }
604
605         return = true;
606
607         ready_waiting = (nags & BIT(0));
608         ready_waiting_for_me = (nags & BIT(1));
609         vote_waiting = (nags & BIT(2));
610         vote_waiting_for_me = (nags & BIT(3));
611         warmup_stage = (nags & BIT(4));
612 }
613
614 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
615 {
616         make_pure(this);
617     int i, j, b, f;
618
619     int sf = ReadByte();
620         if(sf & 1)
621         {
622                 for(j = 0; j < maxclients; ++j)
623                         if(playerslots[j])
624                                 playerslots[j].eliminated = 1;
625                 for(i = 1; i <= maxclients; i += 8)
626                 {
627                         f = ReadByte();
628                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
629                                 if (!(f & b))
630                                         if(playerslots[j])
631                                                 playerslots[j].eliminated = 0;
632                 }
633         }
634         return true;
635 }
636
637 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
638 {
639         make_pure(this);
640         prandom_debug();
641         float s = ReadShort();
642         psrandom(s);
643         return true;
644 }
645
646 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
647 {
648         make_pure(this);
649     int sf = ReadInt24_t();
650         if (sf == 0) {
651                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
652                         weapon_accuracy[w] = -1;
653                 return true;
654         }
655
656         int f = 1;
657         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
658                 if (sf & f) {
659             int b = ReadByte();
660                         if (b == 0)
661                                 weapon_accuracy[w] = -1;
662                         else if (b == 255)
663                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
664                         else
665                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
666                 }
667                 f = (f == 0x800000) ? 1 : f * 2;
668         }
669         return true;
670 }
671
672 void Spawn_Draw(entity this)
673 {
674         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
675 }
676
677 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
678 {
679         float teamnum = (ReadByte() - 1);
680         vector spn_origin;
681         spn_origin.x = ReadShort();
682         spn_origin.y = ReadShort();
683         spn_origin.z = ReadShort();
684
685         //if(is_new)
686         //{
687                 this.origin = spn_origin;
688                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
689                 //droptofloor();
690
691                 /*if(autocvar_cl_spawn_point_model) // needs a model first
692                 {
693                         this.mdl = "models/spawnpoint.md3";
694                         this.colormod = Team_ColorRGB(teamnum);
695                         precache_model(this.mdl);
696                         setmodel(this, this.mdl);
697                         this.drawmask = MASK_NORMAL;
698                         //this.movetype = MOVETYPE_NOCLIP;
699                         //this.draw = Spawn_Draw;
700                 }*/
701                 if(autocvar_cl_spawn_point_particles)
702                 {
703                         if((serverflags & SERVERFLAG_TEAMPLAY))
704                         {
705                                 switch(teamnum)
706                                 {
707                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
708                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
709                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
710                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
711                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
712                                 }
713                         }
714                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
715
716                         this.draw = Spawn_Draw;
717                 }
718         //}
719
720         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
721         return true;
722 }
723
724 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
725 {
726         // If entnum is 0, ONLY do the local spawn actions
727         // this way the server can disable the sending of
728         // spawn origin or such to clients if wanted.
729         float entnum = ReadByte();
730
731         if(entnum)
732         {
733                 this.origin_x = ReadShort();
734                 this.origin_y = ReadShort();
735                 this.origin_z = ReadShort();
736
737                 if(is_new)
738                 {
739                         float teamnum = entcs_GetTeam(entnum - 1);
740
741                         if(autocvar_cl_spawn_event_particles)
742                         {
743                                 switch(teamnum)
744                                 {
745                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
746                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
747                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
748                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
749                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
750                                 }
751                         }
752                         if(autocvar_cl_spawn_event_sound)
753                         {
754                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
755                         }
756                 }
757         }
758         return = true;
759
760         // local spawn actions
761         if(is_new && (!entnum || (entnum == player_localentnum)))
762         {
763                 zoomin_effect = 1;
764                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
765
766                 if(autocvar_cl_unpress_zoom_on_spawn)
767                 {
768                         localcmd("-zoom\n");
769                         button_zoom = false;
770                 }
771         }
772         HUD_Radar_Hide_Maximized();
773         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
774 }
775
776 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
777 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
778 void CSQC_Ent_Update(bool isnew)
779 {
780         SELFPARAM();
781         this.sourceLoc = __FILE__ ":" STR(__LINE__);
782         int t = ReadByte();
783
784         // set up the "time" global for received entities to be correct for interpolation purposes
785         float savetime = time;
786         if(servertime)
787         {
788                 time = servertime;
789         }
790         else
791         {
792                 serverprevtime = time;
793                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
794                 time = serverprevtime + serverdeltatime;
795         }
796
797 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
798         if (this.enttype)
799         {
800                 if (t != this.enttype || isnew)
801                 {
802                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
803                         Ent_Remove(this);
804                         clearentity(this);
805                         isnew = true;
806                 }
807         }
808         else
809         {
810                 if (!isnew)
811                 {
812                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
813                         isnew = true;
814                 }
815         }
816 #endif
817         this.enttype = t;
818         bool done = false;
819         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
820                 if (isnew) this.classname = it.netname;
821                 if (autocvar_developer_csqcentities)
822             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
823                 done = it.m_read(this, NULL, isnew);
824                 break;
825         ));
826         time = savetime;
827         if (!done)
828         {
829                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
830         }
831 }
832
833 // Destructor, but does NOT deallocate the entity by calling remove(). Also
834 // used when an entity changes its type. For an entity that someone interacts
835 // with others, make sure it can no longer do so.
836 void Ent_Remove(entity this)
837 {
838         if(this.entremove) this.entremove(this);
839
840         if(this.skeletonindex)
841         {
842                 skel_delete(this.skeletonindex);
843                 this.skeletonindex = 0;
844         }
845
846         if(this.snd_looping > 0)
847         {
848                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
849                 this.snd_looping = 0;
850         }
851
852         this.enttype = 0;
853         this.classname = "";
854         this.draw = func_null;
855         this.entremove = func_null;
856         // TODO possibly set more stuff to defaults
857 }
858 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
859 void CSQC_Ent_Remove()
860 {
861         SELFPARAM();
862         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
863         if (wasfreed(this))
864         {
865                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
866                 return;
867         }
868         if (this.enttype) Ent_Remove(this);
869         remove(this);
870 }
871
872 void Gamemode_Init()
873 {
874         if (!isdemo())
875         {
876                 if(!(calledhooks & HOOK_START))
877                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
878                 calledhooks |= HOOK_START;
879         }
880 }
881 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
882 void CSQC_Parse_StuffCmd(string strMessage)
883 {
884         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
885         localcmd(strMessage);
886 }
887 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
888 void CSQC_Parse_Print(string strMessage)
889 {
890         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
891         print(ColorTranslateRGB(strMessage));
892 }
893
894 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
895 void CSQC_Parse_CenterPrint(string strMessage)
896 {
897         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
898         centerprint_hud(strMessage);
899 }
900
901 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
902 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
903 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
904 bool CSQC_Parse_TempEntity()
905 {
906         // Acquire TE ID
907         int nTEID = ReadByte();
908
909         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
910                 if (autocvar_developer_csqcentities)
911                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
912                 return it.m_read(NULL, NULL, true);
913         ));
914
915         if (autocvar_developer_csqcentities)
916                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
917
918         // No special logic for this temporary entity; return 0 so the engine can handle it
919         return false;
920 }
921
922 /** TODO somehow thwart prvm_globalset client ... */
923 string forcefog;
924 void Fog_Force()
925 {
926         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
927                 localcmd("\nr_drawfog 0\n");
928         else if (forcefog != "")
929                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
930 }
931
932 void Gamemode_Init();
933 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
934 {
935         make_pure(this);
936         gametype = ReadInt24_t();
937         HUD_ModIcons_SetFunc();
938         for (int i = 0; i < MAX_SCORE; ++i)
939         {
940                 if (scores_label[i]) strunzone(scores_label[i]);
941                 scores_label[i] = strzone(ReadString());
942                 scores_flags[i] = ReadByte();
943         }
944         for (int i = 0; i < MAX_TEAMSCORE; ++i)
945         {
946                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
947                 teamscores_label[i] = strzone(ReadString());
948                 teamscores_flags[i] = ReadByte();
949         }
950         return = true;
951         HUD_InitScores();
952         Gamemode_Init();
953 }
954
955 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
956 {
957         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
958
959         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
960         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
961         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
962         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
963         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
964         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
965         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
966         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
967
968         if (forcefog) strunzone(forcefog);
969         forcefog = strzone(ReadString());
970
971         armorblockpercent = ReadByte() / 255.0;
972
973         serverflags = ReadByte();
974
975         g_trueaim_minrange = ReadCoord();
976
977         return = true;
978
979         MUTATOR_CALLHOOK(Ent_Init);
980
981         if (!postinit) PostInit();
982 }
983
984 NET_HANDLE(TE_CSQC_RACE, bool isNew)
985 {
986         int b = ReadByte();
987
988         switch (b)
989         {
990                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
991                         race_checkpoint = ReadByte();
992                         race_time = ReadInt24_t();
993                         race_previousbesttime = ReadInt24_t();
994                         if(race_previousbestname)
995                                 strunzone(race_previousbestname);
996                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
997
998                         race_checkpointtime = time;
999
1000                         if(race_checkpoint == 0 || race_checkpoint == 254)
1001                         {
1002                                 race_penaltyaccumulator = 0;
1003                                 race_laptime = time; // valid
1004                         }
1005
1006                         break;
1007
1008                 case RACE_NET_CHECKPOINT_CLEAR:
1009                         race_laptime = 0;
1010                         race_checkpointtime = 0;
1011                         break;
1012
1013                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1014                         race_laptime = ReadCoord();
1015                         race_checkpointtime = -99999;
1016                         // fall through
1017                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1018                         race_nextcheckpoint = ReadByte();
1019
1020                         race_nextbesttime = ReadInt24_t();
1021                         if(race_nextbestname)
1022                                 strunzone(race_nextbestname);
1023                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1024                         break;
1025
1026                 case RACE_NET_CHECKPOINT_HIT_RACE:
1027                         race_mycheckpoint = ReadByte();
1028                         race_mycheckpointtime = time;
1029                         race_mycheckpointdelta = ReadInt24_t();
1030                         race_mycheckpointlapsdelta = ReadByte();
1031                         if(race_mycheckpointlapsdelta >= 128)
1032                                 race_mycheckpointlapsdelta -= 256;
1033                         if(race_mycheckpointenemy)
1034                                 strunzone(race_mycheckpointenemy);
1035                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1036                         break;
1037
1038                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1039                         race_othercheckpoint = ReadByte();
1040                         race_othercheckpointtime = time;
1041                         race_othercheckpointdelta = ReadInt24_t();
1042                         race_othercheckpointlapsdelta = ReadByte();
1043                         if(race_othercheckpointlapsdelta >= 128)
1044                                 race_othercheckpointlapsdelta -= 256;
1045                         if(race_othercheckpointenemy)
1046                                 strunzone(race_othercheckpointenemy);
1047                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1048                         break;
1049
1050                 case RACE_NET_PENALTY_RACE:
1051                         race_penaltyeventtime = time;
1052                         race_penaltytime = ReadShort();
1053                         //race_penaltyaccumulator += race_penaltytime;
1054                         if(race_penaltyreason)
1055                                 strunzone(race_penaltyreason);
1056                         race_penaltyreason = strzone(ReadString());
1057                         break;
1058
1059                 case RACE_NET_PENALTY_QUALIFYING:
1060                         race_penaltyeventtime = time;
1061                         race_penaltytime = ReadShort();
1062                         race_penaltyaccumulator += race_penaltytime;
1063                         if(race_penaltyreason)
1064                                 strunzone(race_penaltyreason);
1065                         race_penaltyreason = strzone(ReadString());
1066                         break;
1067
1068                 case RACE_NET_SERVER_RECORD:
1069                         race_server_record = ReadInt24_t();
1070                         break;
1071                 case RACE_NET_SPEED_AWARD:
1072                         race_speedaward = ReadInt24_t();
1073                         if(race_speedaward_holder)
1074                                 strunzone(race_speedaward_holder);
1075                         race_speedaward_holder = strzone(ReadString());
1076                         break;
1077                 case RACE_NET_SPEED_AWARD_BEST:
1078                         race_speedaward_alltimebest = ReadInt24_t();
1079                         if(race_speedaward_alltimebest_holder)
1080                                 strunzone(race_speedaward_alltimebest_holder);
1081                         race_speedaward_alltimebest_holder = strzone(ReadString());
1082                         break;
1083                 case RACE_NET_SERVER_RANKINGS:
1084                         float prevpos, del;
1085             int pos = ReadShort();
1086                         prevpos = ReadShort();
1087                         del = ReadShort();
1088
1089                         // move other rankings out of the way
1090             int i;
1091                         if (prevpos) {
1092                                 for (i=prevpos-1;i>pos-1;--i) {
1093                                         grecordtime[i] = grecordtime[i-1];
1094                                         if(grecordholder[i])
1095                                                 strunzone(grecordholder[i]);
1096                                         grecordholder[i] = strzone(grecordholder[i-1]);
1097                                 }
1098                         } else if (del) { // a record has been deleted by the admin
1099                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1100                                         if (i == RANKINGS_CNT-1) { // clear out last record
1101                                                 grecordtime[i] = 0;
1102                                                 if (grecordholder[i])
1103                                                         strunzone(grecordholder[i]);
1104                                                 grecordholder[i] = string_null;
1105                                         }
1106                                         else {
1107                                                 grecordtime[i] = grecordtime[i+1];
1108                                                 if (grecordholder[i])
1109                                                         strunzone(grecordholder[i]);
1110                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1111                                         }
1112                                 }
1113                         } else { // player has no ranked record yet
1114                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1115                                         grecordtime[i] = grecordtime[i-1];
1116                                         if(grecordholder[i])
1117                                                 strunzone(grecordholder[i]);
1118                                         grecordholder[i] = strzone(grecordholder[i-1]);
1119                                 }
1120                         }
1121
1122                         // store new ranking
1123                         if(grecordholder[pos-1] != "")
1124                                 strunzone(grecordholder[pos-1]);
1125                         grecordholder[pos-1] = strzone(ReadString());
1126                         grecordtime[pos-1] = ReadInt24_t();
1127                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1128                                 race_myrank = pos;
1129                         break;
1130                 case RACE_NET_SERVER_STATUS:
1131                         race_status = ReadShort();
1132                         if(race_status_name)
1133                                 strunzone(race_status_name);
1134                         race_status_name = strzone(ReadString());
1135         }
1136         return true;
1137 }
1138
1139 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1140 {
1141         teamnagger = 1;
1142         return true;
1143 }
1144
1145 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1146 {
1147         int i = ReadByte();
1148         int pi = ReadShort();
1149         int pl = ReadByte();
1150         int ml = ReadByte();
1151         return = true;
1152         entity e = playerslots[i];
1153         if (!e) return;
1154         e.ping = pi;
1155         e.ping_packetloss = pl / 255.0;
1156         e.ping_movementloss = ml / 255.0;
1157 }
1158
1159 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1160 {
1161         complain_weapon = ReadByte();
1162         complain_weapon_type = ReadByte();
1163         return = true;
1164
1165         complain_weapon_time = time;
1166         weapontime = time; // ping the weapon panel
1167
1168         switch(complain_weapon_type)
1169         {
1170                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1171                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1172                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1173         }
1174 }
1175
1176 string getcommandkey(string text, string command)
1177 {
1178         string keys;
1179         float n, j, k, l = 0;
1180
1181         if (!autocvar_hud_showbinds)
1182                 return text;
1183
1184         keys = db_get(binddb, command);
1185         if (keys == "")
1186         {
1187                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1188                 for(j = 0; j < n; ++j)
1189                 {
1190                         k = stof(argv(j));
1191                         if(k != -1)
1192                         {
1193                                 if ("" == keys)
1194                                         keys = keynumtostring(k);
1195                                 else
1196                                         keys = strcat(keys, ", ", keynumtostring(k));
1197
1198                                 ++l;
1199                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1200                                         break;
1201                         }
1202
1203                 }
1204                 if (keys == "")
1205                         keys = "NO_KEY";
1206                 db_put(binddb, command, keys);
1207         }
1208
1209         if (keys == "NO_KEY") {
1210                 if (autocvar_hud_showbinds > 1)
1211                         return sprintf(_("%s (not bound)"), text);
1212                 else
1213                         return text;
1214         }
1215         else if (autocvar_hud_showbinds > 1)
1216                 return sprintf("%s (%s)", text, keys);
1217         else
1218                 return keys;
1219 }