qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "prandom.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "sortlist.qh"
  20 #include "target_music.qh"
  21 #include "tturrets.qh"
  22 #include "tuba.qh"
  23 #include "t_items.qh"
  24 #include "wall.qh"
  25 #include "waypointsprites.qh"
  26
  27 #include "vehicles/bumblebee.qh"
  28 #include "vehicles/all.qh"
  29
  30 #include "weapons/projectile.qh"
  31
  32 #include "../common/buffs.qh"
  33 #include "../common/deathtypes.qh"
  34 #include "../common/mapinfo.qh"
  35 #include "../common/monsters/all.qh"
  36 #include "../common/nades.qh"
  37 #include "../common/net_notice.qh"
  38 #include "../common/notifications.qh"
  39 #include "../common/stats.qh"
  40 #include "../common/teams.qh"
  41
  42 #include "../common/items/all.qh"
  43
  44 #include "../common/weapons/all.qh"
  45
  46 #include "../csqcmodellib/cl_model.qh"
  47 #include "../csqcmodellib/interpolate.qh"
  48
  49 #include "../warpzonelib/client.qh"
  50
  51 // --------------------------------------------------------------------------
  52 // BEGIN REQUIRED CSQC FUNCTIONS
  53 //include "main.qh"
  54
  55 entity clearentity_ent;
  56 void clearentity(entity e)
  57 {
  58         if (!clearentity_ent)
  59         {
  60                 clearentity_ent = spawn();
  61                 clearentity_ent.classname = "clearentity";
  62         }
  63         int n = e.entnum;
  64         copyentity(clearentity_ent, e);
  65         e.entnum = n;
  66 }
  67
  68 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  69 void menu_show_error()
  70 {
  71         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  72 }
  73
  74 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  75 // Useful for precaching things
  76
  77 void menu_sub_null()
  78 {
  79 }
  80
  81 string forcefog;
  82 void WaypointSprite_Load();
  83 void ConsoleCommand_macro_init();
  84 void CSQC_Init(void)
  85 {
  86         prvm_language = cvar_string("prvm_language");
  87
  88 #ifdef WATERMARK
  89         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  90 #endif
  91
  92         int i;
  93
  94         binddb = db_create();
  95         tempdb = db_create();
  96         ClientProgsDB = db_load("client.db");
  97         compressShortVector_init();
  98
  99         draw_endBoldFont();
 100         menu_visible = false;
 101         menu_show = menu_show_error;
 102         menu_action = func_null;
 103
 104         for(i = 0; i < 255; ++i)
 105                 if(getplayerkeyvalue(i, "viewentity") == "")
 106                         break;
 107         maxclients = i;
 108
 109         //registercommand("hud_configure");
 110         //registercommand("hud_save");
 111         //registercommand("menu_action");
 112
 113         ConsoleCommand_macro_init();
 114
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default");
 117
 118         registercvar("cl_nade_type", "3");
 119         registercvar("cl_pokenade_type", "zombie");
 120
 121         gametype = 0;
 122
 123         // hud_fields uses strunzone on the titles!
 124         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 125                 hud_title[i] = strzone("(null)");
 126
 127         Cmd_HUD_SetFields(0);
 128
 129         postinit = false;
 130
 131         calledhooks = 0;
 132
 133         teams = Sort_Spawn();
 134         players = Sort_Spawn();
 135
 136         GetTeam(NUM_SPECTATOR, true); // add specs first
 137
 138         // needs to be done so early because of the constants they create
 139         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 140         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 141         CALL_ACCUMULATED_FUNCTION(RegisterItems);
 142         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 143         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 144         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 145         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 146         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 147
 148         initialize_minigames();
 149
 150         WaypointSprite_Load();
 151
 152         // precaches
 153         precache_model("null");
 154         precache_sound("misc/hit.wav");
 155         precache_sound("misc/typehit.wav");
 156
 157         Projectile_Precache();
 158         Hook_Precache();
 159         GibSplash_Precache();
 160         Casings_Precache();
 161         Vehicles_Precache();
 162         turrets_precache();
 163         Tuba_Precache();
 164         CSQCPlayer_Precache();
 165
 166         if(autocvar_cl_reticle)
 167         {
 168                 precache_pic("gfx/reticle_normal");
 169                 // weapon reticles are precached in weapon files
 170         }
 171
 172         get_mi_min_max_texcoords(1); // try the CLEVER way first
 173         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 174         shortmapname = mi_shortname;
 175
 176         if(precache_pic(minimapname) == "")
 177         {
 178                 // but maybe we have a non-clever minimap
 179                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 180                 if(precache_pic(minimapname) == "")
 181                         minimapname = ""; // FAIL
 182                 else
 183                         get_mi_min_max_texcoords(0); // load new texcoords
 184         }
 185
 186         mi_center = (mi_min + mi_max) * 0.5;
 187         mi_scale = mi_max - mi_min;
 188         minimapname = strzone(minimapname);
 189
 190         WarpZone_Init();
 191
 192         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 193         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 194 }
 195
 196 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 197 void Shutdown(void)
 198 {
 199         WarpZone_Shutdown();
 200
 201         remove(teams);
 202         remove(players);
 203         db_close(binddb);
 204         db_close(tempdb);
 205         if(autocvar_cl_db_saveasdump)
 206                 db_dump(ClientProgsDB, "client.db");
 207         else
 208                 db_save(ClientProgsDB, "client.db");
 209         db_close(ClientProgsDB);
 210
 211         if(camera_active)
 212                 cvar_set("chase_active",ftos(chase_active_backup));
 213
 214         // unset the event chasecam's chase_active
 215         if(autocvar_chase_active < 0)
 216                 cvar_set("chase_active", "0");
 217
 218         if (!isdemo())
 219         {
 220                 if (!(calledhooks & HOOK_START))
 221                         localcmd("\n_cl_hook_gamestart nop\n");
 222                 if (!(calledhooks & HOOK_END))
 223                         localcmd("\ncl_hook_gameend\n");
 224         }
 225
 226         deactivate_minigame();
 227         HUD_MinigameMenu_Close();
 228 }
 229
 230 .float has_team;
 231 float SetTeam(entity o, int Team)
 232 {
 233         entity tm;
 234         if(teamplay)
 235         {
 236                 switch(Team)
 237                 {
 238                         case -1:
 239                         case NUM_TEAM_1:
 240                         case NUM_TEAM_2:
 241                         case NUM_TEAM_3:
 242                         case NUM_TEAM_4:
 243                                 break;
 244                         default:
 245                                 if(GetTeam(Team, false) == world)
 246                                 {
 247                                         dprintf("trying to switch to unsupported team %d\n", Team);
 248                                         Team = NUM_SPECTATOR;
 249                                 }
 250                                 break;
 251                 }
 252         }
 253         else
 254         {
 255                 switch(Team)
 256                 {
 257                         case -1:
 258                         case 0:
 259                                 break;
 260                         default:
 261                                 if(GetTeam(Team, false) == world)
 262                                 {
 263                                         dprintf("trying to switch to unsupported team %d\n", Team);
 264                                         Team = NUM_SPECTATOR;
 265                                 }
 266                                 break;
 267                 }
 268         }
 269         if(Team == -1) // leave
 270         {
 271                 if(o.has_team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.has_team = 0;
 276                         return true;
 277                 }
 278         }
 279         else
 280         {
 281                 if (!o.has_team)
 282                 {
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         o.has_team = 1;
 287                         return true;
 288                 }
 289                 else if(Team != o.team)
 290                 {
 291                         tm = GetTeam(o.team, false);
 292                         tm.team_size -= 1;
 293                         o.team = Team;
 294                         tm = GetTeam(Team, true);
 295                         tm.team_size += 1;
 296                         return true;
 297                 }
 298         }
 299         return false;
 300 }
 301
 302 void Playerchecker_Think()
 303 {
 304     int i;
 305         entity e;
 306         for(i = 0; i < maxclients; ++i)
 307         {
 308                 e = playerslots[i];
 309                 if(GetPlayerName(i) == "")
 310                 {
 311                         if(e.sort_prev)
 312                         {
 313                                 // player disconnected
 314                                 SetTeam(e, -1);
 315                                 RemovePlayer(e);
 316                                 e.sort_prev = world;
 317                                 //e.gotscores = 0;
 318                         }
 319                 }
 320                 else
 321                 {
 322                         if (!e.sort_prev)
 323                         {
 324                                 // player connected
 325                                 if (!e)
 326                                         playerslots[i] = e = spawn();
 327                                 e.sv_entnum = i;
 328                                 e.ping = 0;
 329                                 e.ping_packetloss = 0;
 330                                 e.ping_movementloss = 0;
 331                                 //e.gotscores = 0; // we might already have the scores...
 332                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 333                                 RegisterPlayer(e);
 334                                 HUD_UpdatePlayerPos(e);
 335                         }
 336                 }
 337         }
 338         self.nextthink = time + 0.2;
 339 }
 340
 341 void Porto_Init();
 342 void TrueAim_Init();
 343 void PostInit(void)
 344 {
 345         entity playerchecker;
 346         playerchecker = spawn();
 347         playerchecker.think = Playerchecker_Think;
 348         playerchecker.nextthink = time + 0.2;
 349
 350         Porto_Init();
 351         TrueAim_Init();
 352
 353         postinit = true;
 354 }
 355
 356 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 357 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 358 // All keys are in ascii.
 359 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 360 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 361 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 362 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 363 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 364 {
 365         float bSkipKey;
 366         bSkipKey = false;
 367
 368         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 369                 return true;
 370
 371         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 372                 return true;
 373
 374         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 375                 return true;
 376
 377         if(menu_visible && menu_action)
 378                 if(menu_action(bInputType, nPrimary, nSecondary))
 379                         return true;
 380
 381         return bSkipKey;
 382 }
 383
 384 // END REQUIRED CSQC FUNCTIONS
 385 // --------------------------------------------------------------------------
 386
 387 // --------------------------------------------------------------------------
 388 // BEGIN OPTIONAL CSQC FUNCTIONS
 389 void Ent_RemoveEntCS()
 390 {
 391         entcs_receiver[self.sv_entnum] = world;
 392 }
 393 void Ent_ReadEntCS()
 394 {
 395     int sf;
 396         InterpolateOrigin_Undo();
 397
 398         self.classname = "entcs_receiver";
 399         sf = ReadByte();
 400
 401         if(sf & 1)
 402                 self.sv_entnum = ReadByte();
 403         if(sf & 2)
 404         {
 405                 self.origin_x = ReadShort();
 406                 self.origin_y = ReadShort();
 407                 self.origin_z = ReadShort();
 408                 setorigin(self, self.origin);
 409         }
 410         if(sf & 4)
 411         {
 412                 self.angles_y = ReadByte() * 360.0 / 256;
 413                 self.angles_x = self.angles_z = 0;
 414         }
 415         if(sf & 8)
 416                 self.healthvalue = ReadByte() * 10;
 417         if(sf & 16)
 418                 self.armorvalue = ReadByte() * 10;
 419
 420         entcs_receiver[self.sv_entnum] = self;
 421         self.entremove = Ent_RemoveEntCS;
 422         self.iflags |= IFLAG_ORIGIN;
 423
 424         InterpolateOrigin_Note();
 425 }
 426
 427 void Ent_Remove();
 428
 429 void Ent_RemovePlayerScore()
 430 {
 431         if(self.owner) {
 432                 SetTeam(self.owner, -1);
 433                 self.owner.gotscores = 0;
 434                 for(int i = 0; i < MAX_SCORE; ++i) {
 435                         self.owner.(scores[i]) = 0; // clear all scores
 436                 }
 437         }
 438 }
 439
 440 void Ent_ReadPlayerScore()
 441 {
 442         int i, n;
 443         bool isNew;
 444         entity o;
 445
 446         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 447         // (no I've never heard of M-x replace-string, sed, or anything like that)
 448         isNew = !self.owner; // workaround for DP bug
 449         n = ReadByte()-1;
 450
 451 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 452         if(!isNew && n != self.sv_entnum)
 453         {
 454                 //print("A CSQC entity changed its owner!\n");
 455                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 456                 isNew = true;
 457                 Ent_Remove();
 458                 self.enttype = ENT_CLIENT_SCORES;
 459         }
 460 #endif
 461
 462         self.sv_entnum = n;
 463
 464         if (!(playerslots[self.sv_entnum]))
 465                 playerslots[self.sv_entnum] = spawn();
 466         o = self.owner = playerslots[self.sv_entnum];
 467         o.sv_entnum = self.sv_entnum;
 468         o.gotscores = 1;
 469
 470         //if (!o.sort_prev)
 471         //      RegisterPlayer(o);
 472         //playerchecker will do this for us later, if it has not already done so
 473
 474     int sf, lf;
 475 #if MAX_SCORE <= 8
 476         sf = ReadByte();
 477         lf = ReadByte();
 478 #else
 479         sf = ReadShort();
 480         lf = ReadShort();
 481 #endif
 482     int p;
 483         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 484                 if(sf & p)
 485                 {
 486                         if(lf & p)
 487                                 o.(scores[i]) = ReadInt24_t();
 488                         else
 489                                 o.(scores[i]) = ReadChar();
 490                 }
 491
 492         if(o.sort_prev)
 493                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 494
 495         self.entremove = Ent_RemovePlayerScore;
 496 }
 497
 498 void Ent_ReadTeamScore()
 499 {
 500         int i;
 501         entity o;
 502
 503         self.team = ReadByte();
 504         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 505
 506     int sf, lf;
 507 #if MAX_TEAMSCORE <= 8
 508         sf = ReadByte();
 509         lf = ReadByte();
 510 #else
 511         sf = ReadShort();
 512         lf = ReadShort();
 513 #endif
 514         int p;
 515         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 516                 if(sf & p)
 517                 {
 518                         if(lf & p)
 519                                 o.(teamscores[i]) = ReadInt24_t();
 520                         else
 521                                 o.(teamscores[i]) = ReadChar();
 522                 }
 523
 524         HUD_UpdateTeamPos(o);
 525 }
 526
 527 void Ent_ClientData()
 528 {
 529         float newspectatee_status;
 530
 531     int f = ReadByte();
 532
 533         scoreboard_showscores_force = (f & 1);
 534
 535         if(f & 2)
 536         {
 537                 newspectatee_status = ReadByte();
 538                 if(newspectatee_status == player_localnum + 1)
 539                         newspectatee_status = -1; // observing
 540         }
 541         else
 542                 newspectatee_status = 0;
 543
 544         spectatorbutton_zoom = (f & 4);
 545
 546         if(f & 8)
 547         {
 548                 angles_held_status = 1;
 549                 angles_held.x = ReadAngle();
 550                 angles_held.y = ReadAngle();
 551                 angles_held.z = 0;
 552         }
 553         else
 554                 angles_held_status = 0;
 555
 556         if(newspectatee_status != spectatee_status)
 557         {
 558                 // clear race stuff
 559                 race_laptime = 0;
 560                 race_checkpointtime = 0;
 561         }
 562         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 563         {
 564                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 565                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 566                 )
 567                         prev_p_health = -1;
 568                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 569                         prev_health = -1;
 570         }
 571         spectatee_status = newspectatee_status;
 572
 573         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 574 }
 575
 576 void Ent_Nagger()
 577 {
 578     int i, j, b, f;
 579
 580     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 581
 582         if(!(nags & 4))
 583         {
 584                 if(vote_called_vote)
 585                         strunzone(vote_called_vote);
 586                 vote_called_vote = string_null;
 587                 vote_active = 0;
 588         }
 589         else
 590         {
 591                 vote_active = 1;
 592         }
 593
 594         if(nags & 64)
 595         {
 596                 vote_yescount = ReadByte();
 597                 vote_nocount = ReadByte();
 598                 vote_needed = ReadByte();
 599                 vote_highlighted = ReadChar();
 600         }
 601
 602         if(nags & 128)
 603         {
 604                 if(vote_called_vote)
 605                         strunzone(vote_called_vote);
 606                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 607         }
 608
 609         if(nags & 1)
 610         {
 611                 for(j = 0; j < maxclients; ++j)
 612                         if(playerslots[j])
 613                                 playerslots[j].ready = 1;
 614                 for(i = 1; i <= maxclients; i += 8)
 615                 {
 616                         f = ReadByte();
 617                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 618                                 if (!(f & b))
 619                                         if(playerslots[j])
 620                                                 playerslots[j].ready = 0;
 621                 }
 622         }
 623
 624         ready_waiting = (nags & 1);
 625         ready_waiting_for_me = (nags & 2);
 626         vote_waiting = (nags & 4);
 627         vote_waiting_for_me = (nags & 8);
 628         warmup_stage = (nags & 16);
 629 }
 630
 631 void Ent_EliminatedPlayers()
 632 {
 633     int i, j, b, f;
 634
 635     int sf = ReadByte();
 636         if(sf & 1)
 637         {
 638                 for(j = 0; j < maxclients; ++j)
 639                         if(playerslots[j])
 640                                 playerslots[j].eliminated = 1;
 641                 for(i = 1; i <= maxclients; i += 8)
 642                 {
 643                         f = ReadByte();
 644                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 645                                 if (!(f & b))
 646                                         if(playerslots[j])
 647                                                 playerslots[j].eliminated = 0;
 648                 }
 649         }
 650 }
 651
 652 void Ent_RandomSeed()
 653 {
 654         float s;
 655         prandom_debug();
 656         s = ReadShort();
 657         psrandom(s);
 658 }
 659
 660 void Ent_ReadAccuracy(void)
 661 {
 662     int f, w;
 663     int sf = ReadInt24_t();
 664         if(sf == 0)
 665         {
 666                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 667                         weapon_accuracy[w] = -1;
 668                 return;
 669         }
 670
 671         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 672         {
 673                 if(sf & f)
 674                 {
 675             int b = ReadByte();
 676                         if(b == 0)
 677                                 weapon_accuracy[w] = -1;
 678                         else if(b == 255)
 679                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 680                         else
 681                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 682                 }
 683                 if(f == 0x800000)
 684                         f = 1;
 685                 else
 686                         f *= 2;
 687         }
 688 }
 689
 690 void Spawn_Draw(void)
 691 {
 692         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 693 }
 694
 695 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 696 {
 697         float teamnum = (ReadByte() - 1);
 698         vector spn_origin;
 699         spn_origin.x = ReadShort();
 700         spn_origin.y = ReadShort();
 701         spn_origin.z = ReadShort();
 702
 703         if(is_new)
 704         {
 705                 self.origin = spn_origin;
 706                 setsize(self, PL_MIN, PL_MAX);
 707                 droptofloor();
 708
 709                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 710                 {
 711                         self.mdl = "models/spawnpoint.md3";
 712                         self.colormod = Team_ColorRGB(teamnum);
 713                         precache_model(self.mdl);
 714                         setmodel(self, self.mdl);
 715                         self.drawmask = MASK_NORMAL;
 716                         //self.movetype = MOVETYPE_NOCLIP;
 717                         //self.draw = Spawn_Draw;
 718                 }*/
 719                 if(autocvar_cl_spawn_point_particles)
 720                 {
 721                         if((serverflags & SERVERFLAG_TEAMPLAY))
 722                         {
 723                                 switch(teamnum)
 724                                 {
 725                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 726                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 727                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 728                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 729                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 730                                 }
 731                         }
 732                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 733
 734                         self.draw = Spawn_Draw;
 735                 }
 736         }
 737
 738         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 739 }
 740
 741 void Ent_ReadSpawnEvent(float is_new)
 742 {
 743         // If entnum is 0, ONLY do the local spawn actions
 744         // this way the server can disable the sending of
 745         // spawn origin or such to clients if wanted.
 746         float entnum = ReadByte();
 747
 748         if(entnum)
 749         {
 750                 self.origin_x = ReadShort();
 751                 self.origin_y = ReadShort();
 752                 self.origin_z = ReadShort();
 753
 754                 if(is_new)
 755                 {
 756                         float teamnum = GetPlayerColor(entnum - 1);
 757
 758                         if(autocvar_cl_spawn_event_particles)
 759                         {
 760                                 switch(teamnum)
 761                                 {
 762                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 764                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 765                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 766                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 767                                 }
 768                         }
 769                         if(autocvar_cl_spawn_event_sound)
 770                         {
 771                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 772                         }
 773                 }
 774         }
 775
 776         // local spawn actions
 777         if(is_new && (!entnum || (entnum == player_localentnum)))
 778         {
 779                 zoomin_effect = 1;
 780                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 781
 782                 if(autocvar_cl_unpress_zoom_on_spawn)
 783                 {
 784                         localcmd("-zoom\n");
 785                         button_zoom = false;
 786                 }
 787         }
 788
 789         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 790 }
 791
 792 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 793 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 794 void Ent_RadarLink();
 795 void Ent_Init();
 796 void Ent_ScoresInfo();
 797 void CSQC_Ent_Update(float bIsNewEntity)
 798 {
 799         float t;
 800         float savetime;
 801         t = ReadByte();
 802
 803         if(autocvar_developer_csqcentities)
 804                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 805
 806         // set up the "time" global for received entities to be correct for interpolation purposes
 807         savetime = time;
 808         if(servertime)
 809         {
 810                 time = servertime;
 811         }
 812         else
 813         {
 814                 serverprevtime = time;
 815                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 816                 time = serverprevtime + serverdeltatime;
 817         }
 818
 819 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 820         if(self.enttype)
 821         {
 822                 if(t != self.enttype || bIsNewEntity)
 823                 {
 824                         //print("A CSQC entity changed its type!\n");
 825                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 826                         Ent_Remove();
 827                         clearentity(self);
 828                         bIsNewEntity = 1;
 829                 }
 830         }
 831         else
 832         {
 833                 if(!bIsNewEntity)
 834                 {
 835                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 836                         bIsNewEntity = 1;
 837                 }
 838         }
 839 #endif
 840         self.enttype = t;
 841         switch(t)
 842         {
 843                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 844                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 845                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 846                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 847                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 848                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 849                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 850                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 851                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 852                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 853                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 854                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 855                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 856                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 857                 case ENT_CLIENT_INIT: Ent_Init(); break;
 858                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 859                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 860                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 861                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 862                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 863                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 864                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 865                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 866                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 867                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 868                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 869                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 870                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 871                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 872                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 873                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 874                 case ENT_CLIENT_TURRET: ent_turret(); break;
 875                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 876                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 877                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 878                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 879                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 880                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 881                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 882                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 883
 884                 default:
 885                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 886                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 887                         break;
 888         }
 889
 890         time = savetime;
 891 }
 892 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 893 // used when an entity changes its type. For an entity that someone interacts
 894 // with others, make sure it can no longer do so.
 895 void Ent_Remove()
 896 {
 897         if(self.entremove)
 898                 self.entremove();
 899
 900         if(self.skeletonindex)
 901         {
 902                 skel_delete(self.skeletonindex);
 903                 self.skeletonindex = 0;
 904         }
 905
 906         if(self.snd_looping > 0)
 907         {
 908                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 909                 self.snd_looping = 0;
 910         }
 911
 912         self.enttype = 0;
 913         self.classname = "";
 914         self.draw = menu_sub_null;
 915         self.entremove = menu_sub_null;
 916         // TODO possibly set more stuff to defaults
 917 }
 918 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 919 void CSQC_Ent_Remove()
 920 {
 921         if(autocvar_developer_csqcentities)
 922                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 923
 924         if(wasfreed(self))
 925         {
 926                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 927                 return;
 928         }
 929         if(self.enttype)
 930                 Ent_Remove();
 931         remove(self);
 932 }
 933
 934 void Gamemode_Init()
 935 {
 936         if (!isdemo())
 937         {
 938                 if(!(calledhooks & HOOK_START))
 939                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 940                 calledhooks |= HOOK_START;
 941         }
 942 }
 943 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 944 void CSQC_Parse_StuffCmd(string strMessage)
 945 {
 946         if(autocvar_developer_csqcentities)
 947                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 948
 949         localcmd(strMessage);
 950 }
 951 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 952 void CSQC_Parse_Print(string strMessage)
 953 {
 954         if(autocvar_developer_csqcentities)
 955                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 956
 957         print(ColorTranslateRGB(strMessage));
 958 }
 959
 960 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 961 void CSQC_Parse_CenterPrint(string strMessage)
 962 {
 963         if(autocvar_developer_csqcentities)
 964                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 965
 966         centerprint_hud(strMessage);
 967 }
 968
 969 string notranslate_fogcmd1 = "\nfog ";
 970 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 971 void Fog_Force()
 972 {
 973         // TODO somehow thwart prvm_globalset client ...
 974
 975         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 976                 { localcmd("\nr_drawfog 0\n"); }
 977         else if(forcefog != "")
 978                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 979 }
 980
 981 void Gamemode_Init();
 982 void Ent_ScoresInfo()
 983 {
 984     int i;
 985         self.classname = "ent_client_scores_info";
 986         gametype = ReadInt24_t();
 987         HUD_ModIcons_SetFunc();
 988         for(i = 0; i < MAX_SCORE; ++i)
 989         {
 990                 if(scores_label[i])
 991                         strunzone(scores_label[i]);
 992                 scores_label[i] = strzone(ReadString());
 993                 scores_flags[i] = ReadByte();
 994         }
 995         for(i = 0; i < MAX_TEAMSCORE; ++i)
 996         {
 997                 if(teamscores_label[i])
 998                         strunzone(teamscores_label[i]);
 999                 teamscores_label[i] = strzone(ReadString());
1000                 teamscores_flags[i] = ReadByte();
1001         }
1002         HUD_InitScores();
1003         Gamemode_Init();
1004 }
1005
1006 void Ent_Init()
1007 {
1008         self.classname = "ent_client_init";
1009
1010         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1011
1012         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1013         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1014         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1015         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1016         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1017         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1018         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1019         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1020
1021         if(forcefog)
1022                 strunzone(forcefog);
1023         forcefog = strzone(ReadString());
1024
1025         armorblockpercent = ReadByte() / 255.0;
1026
1027         g_balance_mortar_bouncefactor = ReadCoord();
1028         g_balance_mortar_bouncestop = ReadCoord();
1029         g_balance_electro_secondary_bouncefactor = ReadCoord();
1030         g_balance_electro_secondary_bouncestop = ReadCoord();
1031
1032         vortex_scope = !ReadByte();
1033         rifle_scope = !ReadByte();
1034
1035         serverflags = ReadByte();
1036
1037         minelayer_maxmines = ReadByte();
1038
1039         hagar_maxrockets = ReadByte();
1040
1041         g_trueaim_minrange = ReadCoord();
1042         g_balance_porto_secondary = ReadByte();
1043
1044         if(!postinit)
1045                 PostInit();
1046 }
1047
1048 void Net_ReadRace()
1049 {
1050         float b;
1051
1052         b = ReadByte();
1053
1054         switch(b)
1055         {
1056                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1057                         race_checkpoint = ReadByte();
1058                         race_time = ReadInt24_t();
1059                         race_previousbesttime = ReadInt24_t();
1060                         if(race_previousbestname)
1061                                 strunzone(race_previousbestname);
1062                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1063
1064                         race_checkpointtime = time;
1065
1066                         if(race_checkpoint == 0 || race_checkpoint == 254)
1067                         {
1068                                 race_penaltyaccumulator = 0;
1069                                 race_laptime = time; // valid
1070                         }
1071
1072                         break;
1073
1074                 case RACE_NET_CHECKPOINT_CLEAR:
1075                         race_laptime = 0;
1076                         race_checkpointtime = 0;
1077                         break;
1078
1079                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1080                         race_laptime = ReadCoord();
1081                         race_checkpointtime = -99999;
1082                         // fall through
1083                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1084                         race_nextcheckpoint = ReadByte();
1085
1086                         race_nextbesttime = ReadInt24_t();
1087                         if(race_nextbestname)
1088                                 strunzone(race_nextbestname);
1089                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1090                         break;
1091
1092                 case RACE_NET_CHECKPOINT_HIT_RACE:
1093                         race_mycheckpoint = ReadByte();
1094                         race_mycheckpointtime = time;
1095                         race_mycheckpointdelta = ReadInt24_t();
1096                         race_mycheckpointlapsdelta = ReadByte();
1097                         if(race_mycheckpointlapsdelta >= 128)
1098                                 race_mycheckpointlapsdelta -= 256;
1099                         if(race_mycheckpointenemy)
1100                                 strunzone(race_mycheckpointenemy);
1101                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1102                         break;
1103
1104                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1105                         race_othercheckpoint = ReadByte();
1106                         race_othercheckpointtime = time;
1107                         race_othercheckpointdelta = ReadInt24_t();
1108                         race_othercheckpointlapsdelta = ReadByte();
1109                         if(race_othercheckpointlapsdelta >= 128)
1110                                 race_othercheckpointlapsdelta -= 256;
1111                         if(race_othercheckpointenemy)
1112                                 strunzone(race_othercheckpointenemy);
1113                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1114                         break;
1115
1116                 case RACE_NET_PENALTY_RACE:
1117                         race_penaltyeventtime = time;
1118                         race_penaltytime = ReadShort();
1119                         //race_penaltyaccumulator += race_penaltytime;
1120                         if(race_penaltyreason)
1121                                 strunzone(race_penaltyreason);
1122                         race_penaltyreason = strzone(ReadString());
1123                         break;
1124
1125                 case RACE_NET_PENALTY_QUALIFYING:
1126                         race_penaltyeventtime = time;
1127                         race_penaltytime = ReadShort();
1128                         race_penaltyaccumulator += race_penaltytime;
1129                         if(race_penaltyreason)
1130                                 strunzone(race_penaltyreason);
1131                         race_penaltyreason = strzone(ReadString());
1132                         break;
1133
1134                 case RACE_NET_SERVER_RECORD:
1135                         race_server_record = ReadInt24_t();
1136                         break;
1137                 case RACE_NET_SPEED_AWARD:
1138                         race_speedaward = ReadInt24_t();
1139                         if(race_speedaward_holder)
1140                                 strunzone(race_speedaward_holder);
1141                         race_speedaward_holder = strzone(ReadString());
1142                         break;
1143                 case RACE_NET_SPEED_AWARD_BEST:
1144                         race_speedaward_alltimebest = ReadInt24_t();
1145                         if(race_speedaward_alltimebest_holder)
1146                                 strunzone(race_speedaward_alltimebest_holder);
1147                         race_speedaward_alltimebest_holder = strzone(ReadString());
1148                         break;
1149                 case RACE_NET_SERVER_RANKINGS:
1150                         float prevpos, del;
1151             int pos = ReadShort();
1152                         prevpos = ReadShort();
1153                         del = ReadShort();
1154
1155                         // move other rankings out of the way
1156             int i;
1157                         if (prevpos) {
1158                                 for (i=prevpos-1;i>pos-1;--i) {
1159                                         grecordtime[i] = grecordtime[i-1];
1160                                         if(grecordholder[i])
1161                                                 strunzone(grecordholder[i]);
1162                                         grecordholder[i] = strzone(grecordholder[i-1]);
1163                                 }
1164                         } else if (del) { // a record has been deleted by the admin
1165                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1166                                         if (i == RANKINGS_CNT-1) { // clear out last record
1167                                                 grecordtime[i] = 0;
1168                                                 if (grecordholder[i])
1169                                                         strunzone(grecordholder[i]);
1170                                                 grecordholder[i] = string_null;
1171                                         }
1172                                         else {
1173                                                 grecordtime[i] = grecordtime[i+1];
1174                                                 if (grecordholder[i])
1175                                                         strunzone(grecordholder[i]);
1176                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1177                                         }
1178                                 }
1179                         } else { // player has no ranked record yet
1180                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1181                                         grecordtime[i] = grecordtime[i-1];
1182                                         if(grecordholder[i])
1183                                                 strunzone(grecordholder[i]);
1184                                         grecordholder[i] = strzone(grecordholder[i-1]);
1185                                 }
1186                         }
1187
1188                         // store new ranking
1189                         if(grecordholder[pos-1] != "")
1190                                 strunzone(grecordholder[pos-1]);
1191                         grecordholder[pos-1] = strzone(ReadString());
1192                         grecordtime[pos-1] = ReadInt24_t();
1193                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1194                                 race_myrank = pos;
1195                         break;
1196                 case RACE_NET_SERVER_STATUS:
1197                         race_status = ReadShort();
1198                         if(race_status_name)
1199                                 strunzone(race_status_name);
1200                         race_status_name = strzone(ReadString());
1201         }
1202 }
1203
1204 void Net_TeamNagger()
1205 {
1206         teamnagger = 1;
1207 }
1208
1209 void Net_ReadPingPLReport()
1210 {
1211         int e, pi, pl, ml;
1212         e = ReadByte();
1213         pi = ReadShort();
1214         pl = ReadByte();
1215         ml = ReadByte();
1216         if (!(playerslots[e]))
1217                 return;
1218         playerslots[e].ping = pi;
1219         playerslots[e].ping_packetloss = pl / 255.0;
1220         playerslots[e].ping_movementloss = ml / 255.0;
1221 }
1222
1223 void Net_WeaponComplain()
1224 {
1225         complain_weapon = ReadByte();
1226
1227         if(complain_weapon_name)
1228                 strunzone(complain_weapon_name);
1229         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1230
1231         complain_weapon_type = ReadByte();
1232
1233         complain_weapon_time = time;
1234         weapontime = time; // ping the weapon panel
1235
1236         switch(complain_weapon_type)
1237         {
1238                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1239                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1240                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1241         }
1242 }
1243
1244 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1245 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1246 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1247 float CSQC_Parse_TempEntity()
1248 {
1249         float bHandled;
1250                 bHandled  = true;
1251         // Acquire TE ID
1252         float nTEID;
1253                 nTEID = ReadByte();
1254
1255         if(autocvar_developer_csqcentities)
1256                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1257
1258                 // NOTE: Could just do return instead of break...
1259         switch(nTEID)
1260         {
1261                 case TE_CSQC_TARGET_MUSIC:
1262                         Net_TargetMusic();
1263                         bHandled = true;
1264                         break;
1265                 case TE_CSQC_PICTURE:
1266                         Net_MapVote_Picture();
1267                         bHandled = true;
1268                         break;
1269                 case TE_CSQC_RACE:
1270                         Net_ReadRace();
1271                         bHandled = true;
1272                         break;
1273                 case TE_CSQC_VORTEXBEAMPARTICLE:
1274                         Net_ReadVortexBeamParticle();
1275                         bHandled = true;
1276                         break;
1277                 case TE_CSQC_TEAMNAGGER:
1278                         Net_TeamNagger();
1279                         bHandled = true;
1280                         break;
1281                 case TE_CSQC_ARC:
1282                         Net_ReadArc();
1283                         bHandled = true;
1284                         break;
1285                 case TE_CSQC_PINGPLREPORT:
1286                         Net_ReadPingPLReport();
1287                         bHandled = true;
1288                         break;
1289                 case TE_CSQC_WEAPONCOMPLAIN:
1290                         Net_WeaponComplain();
1291                         bHandled = true;
1292                         break;
1293                 case TE_CSQC_VEHICLESETUP:
1294                         Net_VehicleSetup();
1295                         bHandled = true;
1296                         break;
1297                 case TE_CSQC_SVNOTICE:
1298                         cl_notice_read();
1299                         bHandled = true;
1300                         break;
1301                 case TE_CSQC_SHOCKWAVEPARTICLE:
1302                         Net_ReadShockwaveParticle();
1303                         bHandled = true;
1304                         break;
1305                 default:
1306                         // No special logic for this temporary entity; return 0 so the engine can handle it
1307                         bHandled = false;
1308                         break;
1309         }
1310
1311         return bHandled;
1312 }
1313
1314 string getcommandkey(string text, string command)
1315 {
1316         string keys;
1317         float n, j, k, l = 0;
1318
1319         if (!autocvar_hud_showbinds)
1320                 return text;
1321
1322         keys = db_get(binddb, command);
1323         if (keys == "")
1324         {
1325                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1326                 for(j = 0; j < n; ++j)
1327                 {
1328                         k = stof(argv(j));
1329                         if(k != -1)
1330                         {
1331                                 if ("" == keys)
1332                                         keys = keynumtostring(k);
1333                                 else
1334                                         keys = strcat(keys, ", ", keynumtostring(k));
1335
1336                                 ++l;
1337                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1338                                         break;
1339                         }
1340
1341                 }
1342                 if (keys == "")
1343                         keys = "NO_KEY";
1344                 db_put(binddb, command, keys);
1345         }
1346
1347         if (keys == "NO_KEY") {
1348                 if (autocvar_hud_showbinds > 1)
1349                         return sprintf(_("%s (not bound)"), text);
1350                 else
1351                         return text;
1352         }
1353         else if (autocvar_hud_showbinds > 1)
1354                 return sprintf("%s (%s)", text, keys);
1355         else
1356                 return keys;
1357 }