qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         // needs to be done so early because of the constants they create
 104         static_init();
 105         static_init_late();
 106         static_init_precache();
 107
 108         binddb = db_create();
 109         tempdb = db_create();
 110         ClientProgsDB = db_load("client.db");
 111         compressShortVector_init();
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "0");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         gametype = 0;
 135
 136         // hud_fields uses strunzone on the titles!
 137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 138                 hud_title[i] = strzone("(null)");
 139
 140         Cmd_HUD_SetFields(0);
 141
 142         postinit = false;
 143
 144         calledhooks = 0;
 145
 146         teams = Sort_Spawn();
 147         players = Sort_Spawn();
 148
 149         GetTeam(NUM_SPECTATOR, true); // add specs first
 150
 151         // precaches
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 precache_pic("gfx/reticle_normal");
 156                 // weapon reticles are precached in weapon files
 157         }
 158
 159         {
 160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 162                 shortmapname = mi_shortname;
 163
 164                 if (precache_pic(minimapname) == "")
 165                 {
 166                         // but maybe we have a non-clever minimap
 167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 168                         if (precache_pic(minimapname) == "")
 169                                 minimapname = ""; // FAIL
 170                         else
 171                                 get_mi_min_max_texcoords(0); // load new texcoords
 172                 }
 173
 174                 mi_center = (mi_min + mi_max) * 0.5;
 175                 mi_scale = mi_max - mi_min;
 176                 minimapname = strzone(minimapname);
 177         }
 178
 179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 180         LoadMenuSkinValues();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void Shutdown()
 185 {
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         // unset the event chasecam's chase_active
 202         if(autocvar_chase_active < 0)
 203                 cvar_set("chase_active", "0");
 204
 205         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 206
 207         if (!isdemo())
 208         {
 209                 if (!(calledhooks & HOOK_START))
 210                         localcmd("\n_cl_hook_gamestart nop\n");
 211                 if (!(calledhooks & HOOK_END))
 212                         localcmd("\ncl_hook_gameend\n");
 213         }
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close();
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222         devassert_once(Team);
 223         entity tm;
 224         if(teamplay)
 225         {
 226                 switch(Team)
 227                 {
 228                         case -1:
 229                         case NUM_TEAM_1:
 230                         case NUM_TEAM_2:
 231                         case NUM_TEAM_3:
 232                         case NUM_TEAM_4:
 233                                 break;
 234                         default:
 235                                 if(GetTeam(Team, false) == world)
 236                                 {
 237                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 238                                         Team = NUM_SPECTATOR;
 239                                 }
 240                                 break;
 241                 }
 242         }
 243         else
 244         {
 245                 switch(Team)
 246                 {
 247                         case -1:
 248                         case 0:
 249                                 break;
 250                         default:
 251                                 if(GetTeam(Team, false) == world)
 252                                 {
 253                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 254                                         Team = NUM_SPECTATOR;
 255                                 }
 256                                 break;
 257                 }
 258         }
 259         if(Team == -1) // leave
 260         {
 261                 if(o.has_team)
 262                 {
 263                         tm = GetTeam(o.team, false);
 264                         tm.team_size -= 1;
 265                         o.has_team = 0;
 266                         return true;
 267                 }
 268         }
 269         else
 270         {
 271                 if (!o.has_team)
 272                 {
 273                         o.team = Team;
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         o.has_team = 1;
 277                         return true;
 278                 }
 279                 else if(Team != o.team)
 280                 {
 281                         tm = GetTeam(o.team, false);
 282                         tm.team_size -= 1;
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         return true;
 287                 }
 288         }
 289         return false;
 290 }
 291
 292 void Playerchecker_Think()
 293 {
 294         SELFPARAM();
 295     int i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(entcs_GetName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = world;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if (!e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if (!e)
 317                                 {
 318                                         playerslots[i] = e = new(playerslot);
 319                                         make_pure(e);
 320                                 }
 321                                 e.sv_entnum = i;
 322                                 e.ping = 0;
 323                                 e.ping_packetloss = 0;
 324                                 e.ping_movementloss = 0;
 325                                 //e.gotscores = 0; // we might already have the scores...
 326                                 int t = entcs_GetScoreTeam(i);
 327                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 328                                 RegisterPlayer(e);
 329                                 HUD_UpdatePlayerPos(e);
 330                         }
 331                 }
 332         }
 333         this.nextthink = time + 0.2;
 334 }
 335
 336 void Porto_Init();
 337 void TrueAim_Init();
 338 void PostInit()
 339 {
 340         entity playerchecker = new(playerchecker);
 341         make_pure(playerchecker);
 342         playerchecker.think = Playerchecker_Think;
 343         playerchecker.nextthink = time + 0.2;
 344
 345         Porto_Init();
 346         TrueAim_Init();
 347
 348         postinit = true;
 349 }
 350
 351 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 352 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 353 // All keys are in ascii.
 354 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 355 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 356 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 357 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 358 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 359 {
 360         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         return false;
 376 }
 377
 378 // END REQUIRED CSQC FUNCTIONS
 379 // --------------------------------------------------------------------------
 380
 381 // --------------------------------------------------------------------------
 382 // BEGIN OPTIONAL CSQC FUNCTIONS
 383
 384 .void(entity) predraw_qc;
 385 void PreDraw_self()
 386 {
 387         SELFPARAM();
 388         if (this.predraw_qc) this.predraw_qc(this);
 389 }
 390
 391 void setpredraw(entity this, void(entity) pdfunc)
 392 {
 393         this.predraw = PreDraw_self;
 394         this.predraw_qc = pdfunc;
 395 }
 396
 397 void Ent_Remove(entity this);
 398
 399 void Ent_RemovePlayerScore(entity this)
 400 {
 401         if(this.owner) {
 402                 SetTeam(this.owner, -1);
 403                 this.owner.gotscores = 0;
 404                 for(int i = 0; i < MAX_SCORE; ++i) {
 405                         this.owner.(scores[i]) = 0; // clear all scores
 406                 }
 407         }
 408 }
 409
 410 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 411 {
 412         make_pure(this);
 413         int i, n;
 414         bool isNew;
 415         entity o;
 416
 417         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 418         // (no I've never heard of M-x replace-string, sed, or anything like that)
 419         isNew = !this.owner; // workaround for DP bug
 420         n = ReadByte()-1;
 421
 422 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 423         if(!isNew && n != this.sv_entnum)
 424         {
 425                 //print("A CSQC entity changed its owner!\n");
 426                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 427                 isNew = true;
 428                 Ent_Remove(this);
 429         }
 430 #endif
 431
 432         this.sv_entnum = n;
 433
 434         o = playerslots[this.sv_entnum];
 435         if (!o)
 436         {
 437                 o = playerslots[this.sv_entnum] = new(playerslot);
 438                 make_pure(o);
 439         }
 440         this.owner = o;
 441         o.sv_entnum = this.sv_entnum;
 442         o.gotscores = 1;
 443
 444         //if (!o.sort_prev)
 445         //      RegisterPlayer(o);
 446         //playerchecker will do this for us later, if it has not already done so
 447
 448     int sf, lf;
 449 #if MAX_SCORE <= 8
 450         sf = ReadByte();
 451         lf = ReadByte();
 452 #else
 453         sf = ReadShort();
 454         lf = ReadShort();
 455 #endif
 456     int p;
 457         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 458                 if(sf & p)
 459                 {
 460                         if(lf & p)
 461                                 o.(scores[i]) = ReadInt24_t();
 462                         else
 463                                 o.(scores[i]) = ReadChar();
 464                 }
 465
 466         return = true;
 467
 468         if(o.sort_prev)
 469                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 470
 471         this.entremove = Ent_RemovePlayerScore;
 472 }
 473
 474 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 475 {
 476         make_pure(this);
 477         int i;
 478         entity o;
 479
 480         this.team = ReadByte();
 481         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 482
 483     int sf, lf;
 484 #if MAX_TEAMSCORE <= 8
 485         sf = ReadByte();
 486         lf = ReadByte();
 487 #else
 488         sf = ReadShort();
 489         lf = ReadShort();
 490 #endif
 491         int p;
 492         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 493                 if(sf & p)
 494                 {
 495                         if(lf & p)
 496                                 o.(teamscores[i]) = ReadInt24_t();
 497                         else
 498                                 o.(teamscores[i]) = ReadChar();
 499                 }
 500
 501         return = true;
 502
 503         HUD_UpdateTeamPos(o);
 504 }
 505
 506 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 507 {
 508         make_pure(this);
 509         float newspectatee_status;
 510
 511     int f = ReadByte();
 512
 513         scoreboard_showscores_force = (f & 1);
 514
 515         if(f & 2)
 516         {
 517                 newspectatee_status = ReadByte();
 518                 if(newspectatee_status == player_localnum + 1)
 519                         newspectatee_status = -1; // observing
 520         }
 521         else
 522                 newspectatee_status = 0;
 523
 524         spectatorbutton_zoom = (f & 4);
 525
 526         if(f & 8)
 527         {
 528                 angles_held_status = 1;
 529                 angles_held.x = ReadAngle();
 530                 angles_held.y = ReadAngle();
 531                 angles_held.z = 0;
 532         }
 533         else
 534                 angles_held_status = 0;
 535
 536         return = true;
 537
 538         if(newspectatee_status != spectatee_status)
 539         {
 540                 // clear race stuff
 541                 race_laptime = 0;
 542                 race_checkpointtime = 0;
 543                 hud_dynamic_shake_factor = -1;
 544         }
 545         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 546         {
 547                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 548                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 549                 )
 550                         prev_p_health = -1;
 551                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 552                         prev_health = -1;
 553         }
 554         spectatee_status = newspectatee_status;
 555
 556         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 557 }
 558
 559 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 560 {
 561         make_pure(this);
 562     int i, j, b, f;
 563
 564     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 565
 566         if(!(nags & BIT(2)))
 567         {
 568                 if(vote_called_vote)
 569                         strunzone(vote_called_vote);
 570                 vote_called_vote = string_null;
 571                 vote_active = 0;
 572         }
 573         else
 574         {
 575                 vote_active = 1;
 576         }
 577
 578         if(nags & BIT(6))
 579         {
 580                 vote_yescount = ReadByte();
 581                 vote_nocount = ReadByte();
 582                 vote_needed = ReadByte();
 583                 vote_highlighted = ReadChar();
 584         }
 585
 586         if(nags & BIT(7))
 587         {
 588                 if(vote_called_vote)
 589                         strunzone(vote_called_vote);
 590                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 591         }
 592
 593         if(nags & 1)
 594         {
 595                 for(j = 0; j < maxclients; ++j)
 596                         if(playerslots[j])
 597                                 playerslots[j].ready = 1;
 598                 for(i = 1; i <= maxclients; i += 8)
 599                 {
 600                         f = ReadByte();
 601                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 602                                 if (!(f & b))
 603                                         if(playerslots[j])
 604                                                 playerslots[j].ready = 0;
 605                 }
 606         }
 607
 608         return = true;
 609
 610         ready_waiting = (nags & BIT(0));
 611         ready_waiting_for_me = (nags & BIT(1));
 612         vote_waiting = (nags & BIT(2));
 613         vote_waiting_for_me = (nags & BIT(3));
 614         warmup_stage = (nags & BIT(4));
 615 }
 616
 617 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 618 {
 619         make_pure(this);
 620     int i, j, b, f;
 621
 622     int sf = ReadByte();
 623         if(sf & 1)
 624         {
 625                 for(j = 0; j < maxclients; ++j)
 626                         if(playerslots[j])
 627                                 playerslots[j].eliminated = 1;
 628                 for(i = 1; i <= maxclients; i += 8)
 629                 {
 630                         f = ReadByte();
 631                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 632                                 if (!(f & b))
 633                                         if(playerslots[j])
 634                                                 playerslots[j].eliminated = 0;
 635                 }
 636         }
 637         return true;
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 641 {
 642         make_pure(this);
 643         prandom_debug();
 644         float s = ReadShort();
 645         psrandom(s);
 646         return true;
 647 }
 648
 649 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 650 {
 651         make_pure(this);
 652     int sf = ReadInt24_t();
 653         if (sf == 0) {
 654                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 655                         weapon_accuracy[w] = -1;
 656                 return true;
 657         }
 658
 659         int f = 1;
 660         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 661                 if (sf & f) {
 662             int b = ReadByte();
 663                         if (b == 0)
 664                                 weapon_accuracy[w] = -1;
 665                         else if (b == 255)
 666                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 667                         else
 668                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 669                 }
 670                 f = (f == 0x800000) ? 1 : f * 2;
 671         }
 672         return true;
 673 }
 674
 675 void Spawn_Draw(entity this)
 676 {
 677         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 678 }
 679
 680 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 681 {
 682         float teamnum = (ReadByte() - 1);
 683         vector spn_origin;
 684         spn_origin.x = ReadShort();
 685         spn_origin.y = ReadShort();
 686         spn_origin.z = ReadShort();
 687
 688         //if(is_new)
 689         //{
 690                 this.origin = spn_origin;
 691                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 692                 //droptofloor();
 693
 694                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 695                 {
 696                         this.mdl = "models/spawnpoint.md3";
 697                         this.colormod = Team_ColorRGB(teamnum);
 698                         precache_model(this.mdl);
 699                         setmodel(this, this.mdl);
 700                         this.drawmask = MASK_NORMAL;
 701                         //this.movetype = MOVETYPE_NOCLIP;
 702                         //this.draw = Spawn_Draw;
 703                 }*/
 704                 if(autocvar_cl_spawn_point_particles)
 705                 {
 706                         if((serverflags & SERVERFLAG_TEAMPLAY))
 707                         {
 708                                 switch(teamnum)
 709                                 {
 710                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 711                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 712                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 713                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 714                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 715                                 }
 716                         }
 717                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 718
 719                         this.draw = Spawn_Draw;
 720                 }
 721         //}
 722
 723         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 724         return true;
 725 }
 726
 727 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 728 {
 729         // If entnum is 0, ONLY do the local spawn actions
 730         // this way the server can disable the sending of
 731         // spawn origin or such to clients if wanted.
 732         float entnum = ReadByte();
 733
 734         if(entnum)
 735         {
 736                 this.origin_x = ReadShort();
 737                 this.origin_y = ReadShort();
 738                 this.origin_z = ReadShort();
 739
 740                 if(is_new)
 741                 {
 742                         float teamnum = entcs_GetTeam(entnum - 1);
 743
 744                         if(autocvar_cl_spawn_event_particles)
 745                         {
 746                                 switch(teamnum)
 747                                 {
 748                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 749                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 750                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 751                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 752                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 753                                 }
 754                         }
 755                         if(autocvar_cl_spawn_event_sound)
 756                         {
 757                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 758                         }
 759                 }
 760         }
 761         return = true;
 762
 763         // local spawn actions
 764         if(is_new && (!entnum || (entnum == player_localentnum)))
 765         {
 766                 zoomin_effect = 1;
 767                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 768
 769                 if(autocvar_cl_unpress_zoom_on_spawn)
 770                 {
 771                         localcmd("-zoom\n");
 772                         button_zoom = false;
 773                 }
 774         }
 775         HUD_Radar_Hide_Maximized();
 776         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 777 }
 778
 779 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 780 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 781 void CSQC_Ent_Update(bool isnew)
 782 {
 783         SELFPARAM();
 784         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 785         int t = ReadByte();
 786
 787         // set up the "time" global for received entities to be correct for interpolation purposes
 788         float savetime = time;
 789         if(servertime)
 790         {
 791                 time = servertime;
 792         }
 793         else
 794         {
 795                 serverprevtime = time;
 796                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 797                 time = serverprevtime + serverdeltatime;
 798         }
 799
 800 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 801         if (this.enttype)
 802         {
 803                 if (t != this.enttype || isnew)
 804                 {
 805                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 806                         Ent_Remove(this);
 807                         clearentity(this);
 808                         isnew = true;
 809                 }
 810         }
 811         else
 812         {
 813                 if (!isnew)
 814                 {
 815                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 816                         isnew = true;
 817                 }
 818         }
 819 #endif
 820         this.enttype = t;
 821         bool done = false;
 822         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 823                 if (isnew) this.classname = it.netname;
 824                 if (autocvar_developer_csqcentities)
 825             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 826                 done = it.m_read(this, NULL, isnew);
 827                 break;
 828         ));
 829         time = savetime;
 830         if (!done)
 831         {
 832                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 833         }
 834 }
 835
 836 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 837 // used when an entity changes its type. For an entity that someone interacts
 838 // with others, make sure it can no longer do so.
 839 void Ent_Remove(entity this)
 840 {
 841         if(this.entremove) this.entremove(this);
 842
 843         if(this.skeletonindex)
 844         {
 845                 skel_delete(this.skeletonindex);
 846                 this.skeletonindex = 0;
 847         }
 848
 849         if(this.snd_looping > 0)
 850         {
 851                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 852                 this.snd_looping = 0;
 853         }
 854
 855         this.enttype = 0;
 856         this.classname = "";
 857         this.draw = func_null;
 858         this.entremove = func_null;
 859         // TODO possibly set more stuff to defaults
 860 }
 861 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 862 void CSQC_Ent_Remove()
 863 {
 864         SELFPARAM();
 865         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 866         if (wasfreed(this))
 867         {
 868                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 869                 return;
 870         }
 871         if (this.enttype) Ent_Remove(this);
 872         remove(this);
 873 }
 874
 875 void Gamemode_Init()
 876 {
 877         if (!isdemo())
 878         {
 879                 if(!(calledhooks & HOOK_START))
 880                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 881                 calledhooks |= HOOK_START;
 882         }
 883 }
 884 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 885 void CSQC_Parse_StuffCmd(string strMessage)
 886 {
 887         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 888         localcmd(strMessage);
 889 }
 890 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 891 void CSQC_Parse_Print(string strMessage)
 892 {
 893         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 894         print(ColorTranslateRGB(strMessage));
 895 }
 896
 897 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 898 void CSQC_Parse_CenterPrint(string strMessage)
 899 {
 900         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 901         centerprint_hud(strMessage);
 902 }
 903
 904 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 905 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 906 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 907 bool CSQC_Parse_TempEntity()
 908 {
 909         // Acquire TE ID
 910         int nTEID = ReadByte();
 911
 912         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
 913                 if (autocvar_developer_csqcentities)
 914                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 915                 return it.m_read(NULL, NULL, true);
 916         ));
 917
 918         if (autocvar_developer_csqcentities)
 919                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 920
 921         // No special logic for this temporary entity; return 0 so the engine can handle it
 922         return false;
 923 }
 924
 925 /** TODO somehow thwart prvm_globalset client ... */
 926 string forcefog;
 927 void Fog_Force()
 928 {
 929         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 930                 localcmd("\nr_drawfog 0\n");
 931         else if (forcefog != "")
 932                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 933 }
 934
 935 void Gamemode_Init();
 936 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 937 {
 938         make_pure(this);
 939         gametype = ReadInt24_t();
 940         HUD_ModIcons_SetFunc();
 941         for (int i = 0; i < MAX_SCORE; ++i)
 942         {
 943                 if (scores_label[i]) strunzone(scores_label[i]);
 944                 scores_label[i] = strzone(ReadString());
 945                 scores_flags[i] = ReadByte();
 946         }
 947         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 948         {
 949                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 950                 teamscores_label[i] = strzone(ReadString());
 951                 teamscores_flags[i] = ReadByte();
 952         }
 953         return = true;
 954         HUD_InitScores();
 955         Gamemode_Init();
 956 }
 957
 958 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 959 {
 960         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 961
 962         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 963         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 964         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 965         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 966         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 967         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 968         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 969         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 970
 971         if (forcefog) strunzone(forcefog);
 972         forcefog = strzone(ReadString());
 973
 974         armorblockpercent = ReadByte() / 255.0;
 975
 976         serverflags = ReadByte();
 977
 978         g_trueaim_minrange = ReadCoord();
 979
 980         return = true;
 981
 982         MUTATOR_CALLHOOK(Ent_Init);
 983
 984         if (!postinit) PostInit();
 985 }
 986
 987 NET_HANDLE(TE_CSQC_RACE, bool isNew)
 988 {
 989         int b = ReadByte();
 990
 991         switch (b)
 992         {
 993                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 994                         race_checkpoint = ReadByte();
 995                         race_time = ReadInt24_t();
 996                         race_previousbesttime = ReadInt24_t();
 997                         if(race_previousbestname)
 998                                 strunzone(race_previousbestname);
 999                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1000
1001                         race_checkpointtime = time;
1002
1003                         if(race_checkpoint == 0 || race_checkpoint == 254)
1004                         {
1005                                 race_penaltyaccumulator = 0;
1006                                 race_laptime = time; // valid
1007                         }
1008
1009                         break;
1010
1011                 case RACE_NET_CHECKPOINT_CLEAR:
1012                         race_laptime = 0;
1013                         race_checkpointtime = 0;
1014                         break;
1015
1016                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1017                         race_laptime = ReadCoord();
1018                         race_checkpointtime = -99999;
1019                         // fall through
1020                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1021                         race_nextcheckpoint = ReadByte();
1022
1023                         race_nextbesttime = ReadInt24_t();
1024                         if(race_nextbestname)
1025                                 strunzone(race_nextbestname);
1026                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1027                         break;
1028
1029                 case RACE_NET_CHECKPOINT_HIT_RACE:
1030                         race_mycheckpoint = ReadByte();
1031                         race_mycheckpointtime = time;
1032                         race_mycheckpointdelta = ReadInt24_t();
1033                         race_mycheckpointlapsdelta = ReadByte();
1034                         if(race_mycheckpointlapsdelta >= 128)
1035                                 race_mycheckpointlapsdelta -= 256;
1036                         if(race_mycheckpointenemy)
1037                                 strunzone(race_mycheckpointenemy);
1038                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1039                         break;
1040
1041                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1042                         race_othercheckpoint = ReadByte();
1043                         race_othercheckpointtime = time;
1044                         race_othercheckpointdelta = ReadInt24_t();
1045                         race_othercheckpointlapsdelta = ReadByte();
1046                         if(race_othercheckpointlapsdelta >= 128)
1047                                 race_othercheckpointlapsdelta -= 256;
1048                         if(race_othercheckpointenemy)
1049                                 strunzone(race_othercheckpointenemy);
1050                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1051                         break;
1052
1053                 case RACE_NET_PENALTY_RACE:
1054                         race_penaltyeventtime = time;
1055                         race_penaltytime = ReadShort();
1056                         //race_penaltyaccumulator += race_penaltytime;
1057                         if(race_penaltyreason)
1058                                 strunzone(race_penaltyreason);
1059                         race_penaltyreason = strzone(ReadString());
1060                         break;
1061
1062                 case RACE_NET_PENALTY_QUALIFYING:
1063                         race_penaltyeventtime = time;
1064                         race_penaltytime = ReadShort();
1065                         race_penaltyaccumulator += race_penaltytime;
1066                         if(race_penaltyreason)
1067                                 strunzone(race_penaltyreason);
1068                         race_penaltyreason = strzone(ReadString());
1069                         break;
1070
1071                 case RACE_NET_SERVER_RECORD:
1072                         race_server_record = ReadInt24_t();
1073                         break;
1074                 case RACE_NET_SPEED_AWARD:
1075                         race_speedaward = ReadInt24_t();
1076                         if(race_speedaward_holder)
1077                                 strunzone(race_speedaward_holder);
1078                         race_speedaward_holder = strzone(ReadString());
1079                         break;
1080                 case RACE_NET_SPEED_AWARD_BEST:
1081                         race_speedaward_alltimebest = ReadInt24_t();
1082                         if(race_speedaward_alltimebest_holder)
1083                                 strunzone(race_speedaward_alltimebest_holder);
1084                         race_speedaward_alltimebest_holder = strzone(ReadString());
1085                         break;
1086                 case RACE_NET_SERVER_RANKINGS:
1087                         float prevpos, del;
1088             int pos = ReadShort();
1089                         prevpos = ReadShort();
1090                         del = ReadShort();
1091
1092                         // move other rankings out of the way
1093             int i;
1094                         if (prevpos) {
1095                                 for (i=prevpos-1;i>pos-1;--i) {
1096                                         grecordtime[i] = grecordtime[i-1];
1097                                         if(grecordholder[i])
1098                                                 strunzone(grecordholder[i]);
1099                                         grecordholder[i] = strzone(grecordholder[i-1]);
1100                                 }
1101                         } else if (del) { // a record has been deleted by the admin
1102                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1103                                         if (i == RANKINGS_CNT-1) { // clear out last record
1104                                                 grecordtime[i] = 0;
1105                                                 if (grecordholder[i])
1106                                                         strunzone(grecordholder[i]);
1107                                                 grecordholder[i] = string_null;
1108                                         }
1109                                         else {
1110                                                 grecordtime[i] = grecordtime[i+1];
1111                                                 if (grecordholder[i])
1112                                                         strunzone(grecordholder[i]);
1113                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1114                                         }
1115                                 }
1116                         } else { // player has no ranked record yet
1117                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1118                                         grecordtime[i] = grecordtime[i-1];
1119                                         if(grecordholder[i])
1120                                                 strunzone(grecordholder[i]);
1121                                         grecordholder[i] = strzone(grecordholder[i-1]);
1122                                 }
1123                         }
1124
1125                         // store new ranking
1126                         if(grecordholder[pos-1] != "")
1127                                 strunzone(grecordholder[pos-1]);
1128                         grecordholder[pos-1] = strzone(ReadString());
1129                         grecordtime[pos-1] = ReadInt24_t();
1130                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1131                                 race_myrank = pos;
1132                         break;
1133                 case RACE_NET_SERVER_STATUS:
1134                         race_status = ReadShort();
1135                         if(race_status_name)
1136                                 strunzone(race_status_name);
1137                         race_status_name = strzone(ReadString());
1138         }
1139         return true;
1140 }
1141
1142 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1143 {
1144         teamnagger = 1;
1145         return true;
1146 }
1147
1148 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1149 {
1150         int i = ReadByte();
1151         int pi = ReadShort();
1152         int pl = ReadByte();
1153         int ml = ReadByte();
1154         return = true;
1155         entity e = playerslots[i];
1156         if (!e) return;
1157         e.ping = pi;
1158         e.ping_packetloss = pl / 255.0;
1159         e.ping_movementloss = ml / 255.0;
1160 }
1161
1162 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1163 {
1164         complain_weapon = ReadByte();
1165         complain_weapon_type = ReadByte();
1166         return = true;
1167
1168         complain_weapon_time = time;
1169         weapontime = time; // ping the weapon panel
1170
1171         switch(complain_weapon_type)
1172         {
1173                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1174                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1175                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1176         }
1177 }
1178
1179 string getcommandkey(string text, string command)
1180 {
1181         string keys;
1182         float n, j, k, l = 0;
1183
1184         if (!autocvar_hud_showbinds)
1185                 return text;
1186
1187         keys = db_get(binddb, command);
1188         if (keys == "")
1189         {
1190                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1191                 for(j = 0; j < n; ++j)
1192                 {
1193                         k = stof(argv(j));
1194                         if(k != -1)
1195                         {
1196                                 if ("" == keys)
1197                                         keys = keynumtostring(k);
1198                                 else
1199                                         keys = strcat(keys, ", ", keynumtostring(k));
1200
1201                                 ++l;
1202                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1203                                         break;
1204                         }
1205
1206                 }
1207                 if (keys == "")
1208                         keys = "NO_KEY";
1209                 db_put(binddb, command, keys);
1210         }
1211
1212         if (keys == "NO_KEY") {
1213                 if (autocvar_hud_showbinds > 1)
1214                         return sprintf(_("%s (not bound)"), text);
1215                 else
1216                         return text;
1217         }
1218         else if (autocvar_hud_showbinds > 1)
1219                 return sprintf("%s (%s)", text, keys);
1220         else
1221                 return keys;
1222 }