qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "hud/panel/quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         // needs to be done so early because of the constants they create
 104         static_init();
 105         static_init_late();
 106         static_init_precache();
 107
 108         binddb = db_create();
 109         tempdb = db_create();
 110         ClientProgsDB = db_load("client.db");
 111         compressShortVector_init();
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "1");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         gametype = 0;
 135
 136         // hud_fields uses strunzone on the titles!
 137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 138                 hud_title[i] = strzone("(null)");
 139
 140         Cmd_HUD_SetFields(0);
 141
 142         postinit = false;
 143
 144         calledhooks = 0;
 145
 146         teams = Sort_Spawn();
 147         players = Sort_Spawn();
 148
 149         GetTeam(NUM_SPECTATOR, true); // add specs first
 150
 151         // precaches
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 precache_pic("gfx/reticle_normal");
 156                 // weapon reticles are precached in weapon files
 157         }
 158
 159         {
 160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 162                 shortmapname = mi_shortname;
 163
 164                 if (precache_pic(minimapname) == "")
 165                 {
 166                         // but maybe we have a non-clever minimap
 167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 168                         if (precache_pic(minimapname) == "")
 169                                 minimapname = ""; // FAIL
 170                         else
 171                                 get_mi_min_max_texcoords(0); // load new texcoords
 172                 }
 173
 174                 mi_center = (mi_min + mi_max) * 0.5;
 175                 mi_scale = mi_max - mi_min;
 176                 minimapname = strzone(minimapname);
 177         }
 178
 179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 180         LoadMenuSkinValues();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void Shutdown()
 185 {
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         // unset the event chasecam's chase_active
 202         if(autocvar_chase_active < 0)
 203                 cvar_set("chase_active", "0");
 204
 205         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 206
 207         if (!isdemo())
 208         {
 209                 if (!(calledhooks & HOOK_START))
 210                         localcmd("\n_cl_hook_gamestart nop\n");
 211                 if (!(calledhooks & HOOK_END))
 212                         localcmd("\ncl_hook_gameend\n");
 213         }
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close();
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222     TC(int, Team);
 223         devassert_once(Team);
 224         entity tm;
 225         if(teamplay)
 226         {
 227                 switch(Team)
 228                 {
 229                         case -1:
 230                         case NUM_TEAM_1:
 231                         case NUM_TEAM_2:
 232                         case NUM_TEAM_3:
 233                         case NUM_TEAM_4:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == world)
 237                                 {
 238                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         else
 245         {
 246                 switch(Team)
 247                 {
 248                         case -1:
 249                         case 0:
 250                                 break;
 251                         default:
 252                                 if(GetTeam(Team, false) == world)
 253                                 {
 254                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 255                                         Team = NUM_SPECTATOR;
 256                                 }
 257                                 break;
 258                 }
 259         }
 260         if(Team == -1) // leave
 261         {
 262                 if(o.has_team)
 263                 {
 264                         tm = GetTeam(o.team, false);
 265                         tm.team_size -= 1;
 266                         o.has_team = 0;
 267                         return true;
 268                 }
 269         }
 270         else
 271         {
 272                 if (!o.has_team)
 273                 {
 274                         o.team = Team;
 275                         tm = GetTeam(Team, true);
 276                         tm.team_size += 1;
 277                         o.has_team = 1;
 278                         return true;
 279                 }
 280                 else if(Team != o.team)
 281                 {
 282                         tm = GetTeam(o.team, false);
 283                         tm.team_size -= 1;
 284                         o.team = Team;
 285                         tm = GetTeam(Team, true);
 286                         tm.team_size += 1;
 287                         return true;
 288                 }
 289         }
 290         return false;
 291 }
 292
 293 void Playerchecker_Think()
 294 {
 295         SELFPARAM();
 296     int i;
 297         entity e;
 298         for(i = 0; i < maxclients; ++i)
 299         {
 300                 e = playerslots[i];
 301                 if(entcs_GetName(i) == "")
 302                 {
 303                         if(e.sort_prev)
 304                         {
 305                                 // player disconnected
 306                                 SetTeam(e, -1);
 307                                 RemovePlayer(e);
 308                                 e.sort_prev = world;
 309                                 //e.gotscores = 0;
 310                         }
 311                 }
 312                 else
 313                 {
 314                         if (!e.sort_prev)
 315                         {
 316                                 // player connected
 317                                 if (!e)
 318                                 {
 319                                         playerslots[i] = e = new_pure(playerslot);
 320                                 }
 321                                 e.sv_entnum = i;
 322                                 e.ping = 0;
 323                                 e.ping_packetloss = 0;
 324                                 e.ping_movementloss = 0;
 325                                 //e.gotscores = 0; // we might already have the scores...
 326                                 int t = entcs_GetScoreTeam(i);
 327                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 328                                 RegisterPlayer(e);
 329                                 HUD_UpdatePlayerPos(e);
 330                         }
 331                 }
 332         }
 333         this.nextthink = time + 0.2;
 334 }
 335
 336 void TrueAim_Init();
 337 void PostInit()
 338 {
 339         entity playerchecker = new_pure(playerchecker);
 340         playerchecker.think = Playerchecker_Think;
 341         playerchecker.nextthink = time + 0.2;
 342
 343         TrueAim_Init();
 344
 345         postinit = true;
 346 }
 347
 348 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 349 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 350 // All keys are in ascii.
 351 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 352 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 353 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 354 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 355 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 356 {
 357     TC(int, bInputType);
 358         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 359                 return true;
 360
 361         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 362                 return true;
 363
 364         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 365                 return true;
 366
 367         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 368                 return true;
 369
 370         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 371                 return true;
 372
 373         return false;
 374 }
 375
 376 // END REQUIRED CSQC FUNCTIONS
 377 // --------------------------------------------------------------------------
 378
 379 // --------------------------------------------------------------------------
 380 // BEGIN OPTIONAL CSQC FUNCTIONS
 381
 382 .void(entity) predraw_qc;
 383 void PreDraw_self()
 384 {
 385         SELFPARAM();
 386         if (this.predraw_qc) this.predraw_qc(this);
 387 }
 388
 389 void setpredraw(entity this, void(entity) pdfunc)
 390 {
 391         this.predraw = PreDraw_self;
 392         this.predraw_qc = pdfunc;
 393 }
 394
 395 void Ent_Remove(entity this);
 396
 397 void Ent_RemovePlayerScore(entity this)
 398 {
 399         if(this.owner) {
 400                 SetTeam(this.owner, -1);
 401                 this.owner.gotscores = 0;
 402                 FOREACH(Scores, true, {
 403                         this.owner.(scores(it)) = 0; // clear all scores
 404                 });
 405         }
 406 }
 407
 408 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 409 {
 410         make_pure(this);
 411         entity o;
 412
 413         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 414         // (no I've never heard of M-x replace-string, sed, or anything like that)
 415         bool isNew = !this.owner; // workaround for DP bug
 416         int n = ReadByte()-1;
 417
 418 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 419         if(!isNew && n != this.sv_entnum)
 420         {
 421                 //print("A CSQC entity changed its owner!\n");
 422                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 423                 isNew = true;
 424                 Ent_Remove(this);
 425         }
 426 #endif
 427
 428         this.sv_entnum = n;
 429
 430         o = playerslots[this.sv_entnum];
 431         if (!o)
 432         {
 433                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 434         }
 435         this.owner = o;
 436         o.sv_entnum = this.sv_entnum;
 437         o.gotscores = 1;
 438
 439         //if (!o.sort_prev)
 440         //      RegisterPlayer(o);
 441         //playerchecker will do this for us later, if it has not already done so
 442
 443     int sf, lf;
 444         sf = ReadShort();
 445         lf = ReadShort();
 446         FOREACH(Scores, true, {
 447         int p = 1 << (i % 16);
 448                 if (sf & p)
 449                 {
 450                         if (lf & p)
 451                                 o.(scores(it)) = ReadInt24_t();
 452                         else
 453                                 o.(scores(it)) = ReadChar();
 454                 }
 455     });
 456
 457         return = true;
 458
 459         if(o.sort_prev)
 460                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 461
 462         this.entremove = Ent_RemovePlayerScore;
 463 }
 464
 465 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 466 {
 467         make_pure(this);
 468         int i;
 469         entity o;
 470
 471         this.team = ReadByte();
 472         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 473
 474     int sf, lf;
 475 #if MAX_TEAMSCORE <= 8
 476         sf = ReadByte();
 477         lf = ReadByte();
 478 #else
 479         sf = ReadShort();
 480         lf = ReadShort();
 481 #endif
 482         int p;
 483         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 484                 if(sf & p)
 485                 {
 486                         if(lf & p)
 487                                 o.(teamscores(i)) = ReadInt24_t();
 488                         else
 489                                 o.(teamscores(i)) = ReadChar();
 490                 }
 491
 492         return = true;
 493
 494         HUD_UpdateTeamPos(o);
 495 }
 496
 497 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 498 {
 499         make_pure(this);
 500         float newspectatee_status;
 501
 502     int f = ReadByte();
 503
 504         scoreboard_showscores_force = (f & 1);
 505
 506         if(f & 2)
 507         {
 508                 newspectatee_status = ReadByte();
 509                 if(newspectatee_status == player_localnum + 1)
 510                         newspectatee_status = -1; // observing
 511         }
 512         else
 513                 newspectatee_status = 0;
 514
 515         spectatorbutton_zoom = (f & 4);
 516
 517         if(f & 8)
 518         {
 519                 angles_held_status = 1;
 520                 angles_held.x = ReadAngle();
 521                 angles_held.y = ReadAngle();
 522                 angles_held.z = 0;
 523         }
 524         else
 525                 angles_held_status = 0;
 526
 527         return = true;
 528
 529         if(newspectatee_status != spectatee_status)
 530         {
 531                 // clear race stuff
 532                 race_laptime = 0;
 533                 race_checkpointtime = 0;
 534         }
 535         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 536         {
 537                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 538                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 539                 )
 540                         prev_p_health = -1;
 541                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 542                         prev_health = -1;
 543         }
 544         spectatee_status = newspectatee_status;
 545
 546         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 547 }
 548
 549 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 550 {
 551         make_pure(this);
 552     int i, j, b, f;
 553
 554     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 555
 556         if(!(nags & BIT(2)))
 557         {
 558                 if(vote_called_vote)
 559                         strunzone(vote_called_vote);
 560                 vote_called_vote = string_null;
 561                 vote_active = 0;
 562         }
 563         else
 564         {
 565                 vote_active = 1;
 566         }
 567
 568         if(nags & BIT(6))
 569         {
 570                 vote_yescount = ReadByte();
 571                 vote_nocount = ReadByte();
 572                 vote_needed = ReadByte();
 573                 vote_highlighted = ReadChar();
 574         }
 575
 576         if(nags & BIT(7))
 577         {
 578                 if(vote_called_vote)
 579                         strunzone(vote_called_vote);
 580                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 581         }
 582
 583         if(nags & 1)
 584         {
 585                 for(j = 0; j < maxclients; ++j)
 586                         if(playerslots[j])
 587                                 playerslots[j].ready = 1;
 588                 for(i = 1; i <= maxclients; i += 8)
 589                 {
 590                         f = ReadByte();
 591                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 592                                 if (!(f & b))
 593                                         if(playerslots[j])
 594                                                 playerslots[j].ready = 0;
 595                 }
 596         }
 597
 598         return = true;
 599
 600         ready_waiting = (nags & BIT(0));
 601         ready_waiting_for_me = (nags & BIT(1));
 602         vote_waiting = (nags & BIT(2));
 603         vote_waiting_for_me = (nags & BIT(3));
 604         warmup_stage = (nags & BIT(4));
 605 }
 606
 607 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 608 {
 609         make_pure(this);
 610     int i, j, b, f;
 611
 612     int sf = ReadByte();
 613         if(sf & 1)
 614         {
 615                 for(j = 0; j < maxclients; ++j)
 616                         if(playerslots[j])
 617                                 playerslots[j].eliminated = 1;
 618                 for(i = 1; i <= maxclients; i += 8)
 619                 {
 620                         f = ReadByte();
 621                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 622                                 if (!(f & b))
 623                                         if(playerslots[j])
 624                                                 playerslots[j].eliminated = 0;
 625                 }
 626         }
 627         return true;
 628 }
 629
 630 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 631 {
 632         make_pure(this);
 633         prandom_debug();
 634         float s = ReadShort();
 635         psrandom(s);
 636         return true;
 637 }
 638
 639 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 640 {
 641         make_pure(this);
 642     int sf = ReadInt24_t();
 643         if (sf == 0) {
 644                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 645                         weapon_accuracy[w] = -1;
 646                 return true;
 647         }
 648
 649         int f = 1;
 650         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 651                 if (sf & f) {
 652             int b = ReadByte();
 653                         if (b == 0)
 654                                 weapon_accuracy[w] = -1;
 655                         else if (b == 255)
 656                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 657                         else
 658                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 659                 }
 660                 f = (f == 0x800000) ? 1 : f * 2;
 661         }
 662         return true;
 663 }
 664
 665 void Spawn_Draw(entity this)
 666 {
 667         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 668 }
 669
 670 void Spawn_PreDraw(entity this)
 671 {
 672         float alph;
 673         vector org = getpropertyvec(VF_ORIGIN);
 674         if(this.fade_start)
 675                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 676         else
 677                 alph = 1;
 678         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 679         this.alpha = alph;
 680         if(alph <= 0)
 681                 this.drawmask = 0;
 682         else
 683                 this.drawmask = MASK_NORMAL;
 684 }
 685
 686 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 687 {
 688         float teamnum = (ReadByte() - 1);
 689         vector spn_origin;
 690         spn_origin.x = ReadCoord();
 691         spn_origin.y = ReadCoord();
 692         spn_origin.z = ReadCoord();
 693
 694         //if(is_new)
 695         //{
 696                 this.origin = spn_origin;
 697                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 698                 //droptofloor();
 699
 700                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 701                 {
 702                         this.mdl = "models/spawnpoint.md3";
 703                         this.colormod = Team_ColorRGB(teamnum);
 704                         precache_model(this.mdl);
 705                         setmodel(this, this.mdl);
 706                         this.drawmask = MASK_NORMAL;
 707                         //this.movetype = MOVETYPE_NOCLIP;
 708                         //this.draw = Spawn_Draw;
 709                 }*/
 710                 if(autocvar_cl_spawn_point_particles)
 711                 {
 712                         if((serverflags & SERVERFLAG_TEAMPLAY))
 713                         {
 714                                 switch(teamnum)
 715                                 {
 716                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 717                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 718                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 719                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 720                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 721                                 }
 722                         }
 723                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 724
 725                         this.draw = Spawn_Draw;
 726                         setpredraw(this, Spawn_PreDraw);
 727                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 728                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 729                 }
 730         //}
 731
 732         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 733         return true;
 734 }
 735
 736 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 737 {
 738         // If entnum is 0, ONLY do the local spawn actions
 739         // this way the server can disable the sending of
 740         // spawn origin or such to clients if wanted.
 741         float entnum = ReadByte();
 742
 743         if(entnum)
 744         {
 745                 this.origin_x = ReadCoord();
 746                 this.origin_y = ReadCoord();
 747                 this.origin_z = ReadCoord();
 748
 749                 if(is_new)
 750                 {
 751                         float teamnum = entcs_GetTeam(entnum - 1);
 752
 753                         if(autocvar_cl_spawn_event_particles)
 754                         {
 755                                 switch(teamnum)
 756                                 {
 757                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 758                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 759                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 760                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 761                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 762                                 }
 763                         }
 764                         if(autocvar_cl_spawn_event_sound)
 765                         {
 766                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 767                         }
 768                 }
 769         }
 770         return = true;
 771
 772         // local spawn actions
 773         if(is_new && (!entnum || (entnum == player_localentnum)))
 774         {
 775                 zoomin_effect = 1;
 776                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 777
 778                 if(autocvar_cl_unpress_zoom_on_spawn)
 779                 {
 780                         localcmd("-zoom\n");
 781                         button_zoom = false;
 782                 }
 783         }
 784         HUD_Radar_Hide_Maximized();
 785         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 786 }
 787
 788 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 789 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 790 void CSQC_Ent_Update(bool isnew)
 791 {
 792         SELFPARAM();
 793         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 794         int t = ReadByte();
 795
 796         // set up the "time" global for received entities to be correct for interpolation purposes
 797         float savetime = time;
 798         if(servertime)
 799         {
 800                 time = servertime;
 801         }
 802         else
 803         {
 804                 serverprevtime = time;
 805                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 806                 time = serverprevtime + serverdeltatime;
 807         }
 808
 809 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 810         if (this.enttype)
 811         {
 812                 if (t != this.enttype || isnew)
 813                 {
 814                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 815                         Ent_Remove(this);
 816                         clearentity(this);
 817                         isnew = true;
 818                 }
 819         }
 820         else
 821         {
 822                 if (!isnew)
 823                 {
 824                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 825                         isnew = true;
 826                 }
 827         }
 828 #endif
 829         this.enttype = t;
 830         bool done = false;
 831         FOREACH(LinkedEntities, it.m_id == t, {
 832                 if (isnew) this.classname = it.netname;
 833                 if (autocvar_developer_csqcentities)
 834             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 835                 done = it.m_read(this, NULL, isnew);
 836                 break;
 837         });
 838         time = savetime;
 839         if (!done)
 840         {
 841                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 842         }
 843 }
 844
 845 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 846 // used when an entity changes its type. For an entity that someone interacts
 847 // with others, make sure it can no longer do so.
 848 void Ent_Remove(entity this)
 849 {
 850         if(this.entremove) this.entremove(this);
 851
 852         if(this.skeletonindex)
 853         {
 854                 skel_delete(this.skeletonindex);
 855                 this.skeletonindex = 0;
 856         }
 857
 858         if(this.snd_looping > 0)
 859         {
 860                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 861                 this.snd_looping = 0;
 862         }
 863
 864         this.enttype = 0;
 865         this.classname = "";
 866         this.draw = func_null;
 867         this.entremove = func_null;
 868         // TODO possibly set more stuff to defaults
 869 }
 870 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 871 void CSQC_Ent_Remove()
 872 {
 873         SELFPARAM();
 874         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 875         if (wasfreed(this))
 876         {
 877                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 878                 return;
 879         }
 880         if (this.enttype) Ent_Remove(this);
 881         remove(this);
 882 }
 883
 884 void Gamemode_Init()
 885 {
 886         if (!isdemo())
 887         {
 888                 if(!(calledhooks & HOOK_START))
 889                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 890                 calledhooks |= HOOK_START;
 891         }
 892 }
 893 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 894 void CSQC_Parse_StuffCmd(string strMessage)
 895 {
 896         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 897         localcmd(strMessage);
 898 }
 899 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 900 void CSQC_Parse_Print(string strMessage)
 901 {
 902         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 903         print(ColorTranslateRGB(strMessage));
 904 }
 905
 906 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 907 void CSQC_Parse_CenterPrint(string strMessage)
 908 {
 909         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 910         centerprint_hud(strMessage);
 911 }
 912
 913 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 914 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 915 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 916 bool CSQC_Parse_TempEntity()
 917 {
 918         // Acquire TE ID
 919         int nTEID = ReadByte();
 920
 921         FOREACH(TempEntities, it.m_id == nTEID, {
 922                 if (autocvar_developer_csqcentities)
 923                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 924                 return it.m_read(NULL, NULL, true);
 925         });
 926
 927         if (autocvar_developer_csqcentities)
 928                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 929
 930         // No special logic for this temporary entity; return 0 so the engine can handle it
 931         return false;
 932 }
 933
 934 string forcefog;
 935 void Fog_Force()
 936 {
 937         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 938                 localcmd("\nr_drawfog 0\n");
 939         else if (forcefog != "")
 940                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 941 }
 942
 943 void Gamemode_Init();
 944 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 945 {
 946         make_pure(this);
 947         gametype = ReadInt24_t();
 948         HUD_ModIcons_SetFunc();
 949         FOREACH(Scores, true, {
 950                 if (scores_label(it)) strunzone(scores_label(it));
 951                 scores_label(it) = strzone(ReadString());
 952                 scores_flags(it) = ReadByte();
 953         });
 954         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 955         {
 956                 if (teamscores_label(i)) strunzone(teamscores_label(i));
 957                 teamscores_label(i) = strzone(ReadString());
 958                 teamscores_flags(i) = ReadByte();
 959         }
 960         return = true;
 961         HUD_InitScores();
 962         Gamemode_Init();
 963 }
 964
 965 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 966 {
 967         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 968
 969         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 970         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 971         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 972         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 973         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 974         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 975         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 976         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 977
 978         if (forcefog) strunzone(forcefog);
 979         forcefog = strzone(ReadString());
 980
 981         armorblockpercent = ReadByte() / 255.0;
 982
 983         serverflags = ReadByte();
 984
 985         g_trueaim_minrange = ReadCoord();
 986
 987         return = true;
 988
 989         MUTATOR_CALLHOOK(Ent_Init);
 990
 991         if (!postinit) PostInit();
 992 }
 993
 994 NET_HANDLE(TE_CSQC_RACE, bool isNew)
 995 {
 996         int b = ReadByte();
 997
 998         switch (b)
 999         {
1000                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1001                         race_checkpoint = ReadByte();
1002                         race_time = ReadInt24_t();
1003                         race_previousbesttime = ReadInt24_t();
1004                         if(race_previousbestname)
1005                                 strunzone(race_previousbestname);
1006                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1007
1008                         race_checkpointtime = time;
1009
1010                         if(race_checkpoint == 0 || race_checkpoint == 254)
1011                         {
1012                                 race_penaltyaccumulator = 0;
1013                                 race_laptime = time; // valid
1014                         }
1015
1016                         break;
1017
1018                 case RACE_NET_CHECKPOINT_CLEAR:
1019                         race_laptime = 0;
1020                         race_checkpointtime = 0;
1021                         break;
1022
1023                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1024                         race_laptime = ReadCoord();
1025                         race_checkpointtime = -99999;
1026                         // fall through
1027                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1028                         race_nextcheckpoint = ReadByte();
1029
1030                         race_nextbesttime = ReadInt24_t();
1031                         if(race_nextbestname)
1032                                 strunzone(race_nextbestname);
1033                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1034                         break;
1035
1036                 case RACE_NET_CHECKPOINT_HIT_RACE:
1037                         race_mycheckpoint = ReadByte();
1038                         race_mycheckpointtime = time;
1039                         race_mycheckpointdelta = ReadInt24_t();
1040                         race_mycheckpointlapsdelta = ReadByte();
1041                         if(race_mycheckpointlapsdelta >= 128)
1042                                 race_mycheckpointlapsdelta -= 256;
1043                         if(race_mycheckpointenemy)
1044                                 strunzone(race_mycheckpointenemy);
1045                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1046                         break;
1047
1048                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1049                         race_othercheckpoint = ReadByte();
1050                         race_othercheckpointtime = time;
1051                         race_othercheckpointdelta = ReadInt24_t();
1052                         race_othercheckpointlapsdelta = ReadByte();
1053                         if(race_othercheckpointlapsdelta >= 128)
1054                                 race_othercheckpointlapsdelta -= 256;
1055                         if(race_othercheckpointenemy)
1056                                 strunzone(race_othercheckpointenemy);
1057                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1058                         break;
1059
1060                 case RACE_NET_PENALTY_RACE:
1061                         race_penaltyeventtime = time;
1062                         race_penaltytime = ReadShort();
1063                         //race_penaltyaccumulator += race_penaltytime;
1064                         if(race_penaltyreason)
1065                                 strunzone(race_penaltyreason);
1066                         race_penaltyreason = strzone(ReadString());
1067                         break;
1068
1069                 case RACE_NET_PENALTY_QUALIFYING:
1070                         race_penaltyeventtime = time;
1071                         race_penaltytime = ReadShort();
1072                         race_penaltyaccumulator += race_penaltytime;
1073                         if(race_penaltyreason)
1074                                 strunzone(race_penaltyreason);
1075                         race_penaltyreason = strzone(ReadString());
1076                         break;
1077
1078                 case RACE_NET_SERVER_RECORD:
1079                         race_server_record = ReadInt24_t();
1080                         break;
1081                 case RACE_NET_SPEED_AWARD:
1082                         race_speedaward = ReadInt24_t();
1083                         if(race_speedaward_holder)
1084                                 strunzone(race_speedaward_holder);
1085                         race_speedaward_holder = strzone(ReadString());
1086                         break;
1087                 case RACE_NET_SPEED_AWARD_BEST:
1088                         race_speedaward_alltimebest = ReadInt24_t();
1089                         if(race_speedaward_alltimebest_holder)
1090                                 strunzone(race_speedaward_alltimebest_holder);
1091                         race_speedaward_alltimebest_holder = strzone(ReadString());
1092                         break;
1093                 case RACE_NET_SERVER_RANKINGS:
1094                         float prevpos, del;
1095             int pos = ReadShort();
1096                         prevpos = ReadShort();
1097                         del = ReadShort();
1098
1099                         // move other rankings out of the way
1100             int i;
1101                         if (prevpos) {
1102                                 for (i=prevpos-1;i>pos-1;--i) {
1103                                         grecordtime[i] = grecordtime[i-1];
1104                                         if(grecordholder[i])
1105                                                 strunzone(grecordholder[i]);
1106                                         grecordholder[i] = strzone(grecordholder[i-1]);
1107                                 }
1108                         } else if (del) { // a record has been deleted by the admin
1109                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1110                                         if (i == RANKINGS_CNT-1) { // clear out last record
1111                                                 grecordtime[i] = 0;
1112                                                 if (grecordholder[i])
1113                                                         strunzone(grecordholder[i]);
1114                                                 grecordholder[i] = string_null;
1115                                         }
1116                                         else {
1117                                                 grecordtime[i] = grecordtime[i+1];
1118                                                 if (grecordholder[i])
1119                                                         strunzone(grecordholder[i]);
1120                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1121                                         }
1122                                 }
1123                         } else { // player has no ranked record yet
1124                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1125                                         grecordtime[i] = grecordtime[i-1];
1126                                         if(grecordholder[i])
1127                                                 strunzone(grecordholder[i]);
1128                                         grecordholder[i] = strzone(grecordholder[i-1]);
1129                                 }
1130                         }
1131
1132                         // store new ranking
1133                         if(grecordholder[pos-1] != "")
1134                                 strunzone(grecordholder[pos-1]);
1135                         grecordholder[pos-1] = strzone(ReadString());
1136                         grecordtime[pos-1] = ReadInt24_t();
1137                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1138                                 race_myrank = pos;
1139                         break;
1140                 case RACE_NET_SERVER_STATUS:
1141                         race_status = ReadShort();
1142                         if(race_status_name)
1143                                 strunzone(race_status_name);
1144                         race_status_name = strzone(ReadString());
1145         }
1146         return true;
1147 }
1148
1149 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1150 {
1151         teamnagger = 1;
1152         return true;
1153 }
1154
1155 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1156 {
1157         int i = ReadByte();
1158         int pi = ReadShort();
1159         int pl = ReadByte();
1160         int ml = ReadByte();
1161         return = true;
1162         entity e = playerslots[i];
1163         if (!e) return;
1164         e.ping = pi;
1165         e.ping_packetloss = pl / 255.0;
1166         e.ping_movementloss = ml / 255.0;
1167 }
1168
1169 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1170 {
1171         complain_weapon = ReadByte();
1172         complain_weapon_type = ReadByte();
1173         return = true;
1174
1175         complain_weapon_time = time;
1176         weapontime = time; // ping the weapon panel
1177
1178         switch(complain_weapon_type)
1179         {
1180                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1181                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1182                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1183         }
1184 }
1185
1186 string getcommandkey(string text, string command)
1187 {
1188         string keys;
1189         float n, j, k, l = 0;
1190
1191         if (!autocvar_hud_showbinds)
1192                 return text;
1193
1194         keys = db_get(binddb, command);
1195         if (keys == "")
1196         {
1197                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1198                 for(j = 0; j < n; ++j)
1199                 {
1200                         k = stof(argv(j));
1201                         if(k != -1)
1202                         {
1203                                 if ("" == keys)
1204                                         keys = keynumtostring(k);
1205                                 else
1206                                         keys = strcat(keys, ", ", keynumtostring(k));
1207
1208                                 ++l;
1209                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1210                                         break;
1211                         }
1212
1213                 }
1214                 if (keys == "")
1215                         keys = "NO_KEY";
1216                 db_put(binddb, command, keys);
1217         }
1218
1219         if (keys == "NO_KEY") {
1220                 if (autocvar_hud_showbinds > 1)
1221                         return sprintf(_("%s (not bound)"), text);
1222                 else
1223                         return text;
1224         }
1225         else if (autocvar_hud_showbinds > 1)
1226                 return sprintf("%s (%s)", text, keys);
1227         else
1228                 return keys;
1229 }