qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "damage.qh"
   6 #include "effects.qh"
   7 #include "generator.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "scoreboard.qh"
  17 #include "shownames.qh"
  18 #include "tuba.qh"
  19 #include "t_items.qh"
  20 #include "wall.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23
  24 #include "mutators/events.qh"
  25
  26 #include "weapons/projectile.qh"
  27
  28 #include "../common/buffs/all.qh"
  29 #include "../common/deathtypes/all.qh"
  30 #include "../common/effects/effects.qh"
  31 #include "../common/mapinfo.qh"
  32 #include "../common/monsters/all.qh"
  33 #include "../common/nades/all.qh"
  34 #include "../common/net_notice.qh"
  35 #include "../common/notifications.qh"
  36 #include "../common/stats.qh"
  37 #include "../common/teams.qh"
  38
  39 #include "../common/items/all.qh"
  40
  41 #include "../common/mutators/base.qh"
  42
  43 #include "../common/weapons/all.qh"
  44
  45 #include "../csqcmodellib/cl_model.qh"
  46 #include "../csqcmodellib/interpolate.qh"
  47
  48 #include "../common/triggers/include.qh"
  49
  50 #include "../common/turrets/cl_turrets.qh"
  51
  52 #include "../warpzonelib/client.qh"
  53
  54 // --------------------------------------------------------------------------
  55 // BEGIN REQUIRED CSQC FUNCTIONS
  56 //include "main.qh"
  57
  58 entity clearentity_ent;
  59 void clearentity(entity e)
  60 {
  61         if (!clearentity_ent)
  62         {
  63                 clearentity_ent = spawn();
  64                 clearentity_ent.classname = "clearentity";
  65         }
  66         int n = e.entnum;
  67         copyentity(clearentity_ent, e);
  68         e.entnum = n;
  69 }
  70
  71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  72 void menu_show_error()
  73 {
  74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  75 }
  76
  77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  78 // Useful for precaching things
  79
  80 void menu_sub_null()
  81 {
  82 }
  83
  84 void draw_null(entity this) { }
  85
  86 string forcefog;
  87 void ConsoleCommand_macro_init();
  88 void CSQC_Init(void)
  89 {
  90         prvm_language = strzone(cvar_string("prvm_language"));
  91
  92 #ifdef WATERMARK
  93         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  94 #endif
  95
  96         int i;
  97
  98         binddb = db_create();
  99         tempdb = db_create();
 100         ClientProgsDB = db_load("client.db");
 101         compressShortVector_init();
 102
 103         draw_endBoldFont();
 104         menu_visible = false;
 105         menu_show = menu_show_error;
 106         menu_action = func_null;
 107
 108         for(i = 0; i < 255; ++i)
 109                 if(getplayerkeyvalue(i, "viewentity") == "")
 110                         break;
 111         maxclients = i;
 112
 113         //registercommand("hud_configure");
 114         //registercommand("hud_save");
 115         //registercommand("menu_action");
 116
 117         ConsoleCommand_macro_init();
 118
 119         registercvar("hud_usecsqc", "1");
 120         registercvar("scoreboard_columns", "default");
 121
 122         registercvar("cl_nade_type", "3");
 123         registercvar("cl_pokenade_type", "zombie");
 124
 125         registercvar("cl_jumpspeedcap_min", "");
 126         registercvar("cl_jumpspeedcap_max", "");
 127
 128         registercvar("cl_multijump", "0");
 129
 130         registercvar("cl_spawn_near_teammate", "1");
 131
 132         gametype = 0;
 133
 134         // hud_fields uses strunzone on the titles!
 135         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 136                 hud_title[i] = strzone("(null)");
 137
 138         Cmd_HUD_SetFields(0);
 139
 140         postinit = false;
 141
 142         calledhooks = 0;
 143
 144         teams = Sort_Spawn();
 145         players = Sort_Spawn();
 146
 147         GetTeam(NUM_SPECTATOR, true); // add specs first
 148
 149         // needs to be done so early because of the constants they create
 150         static_init();
 151         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 152
 153         // precaches
 154
 155         Projectile_Precache();
 156         Tuba_Precache();
 157
 158         if(autocvar_cl_reticle)
 159         {
 160                 precache_pic("gfx/reticle_normal");
 161                 // weapon reticles are precached in weapon files
 162         }
 163
 164         get_mi_min_max_texcoords(1); // try the CLEVER way first
 165         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 166         shortmapname = mi_shortname;
 167
 168         if(precache_pic(minimapname) == "")
 169         {
 170                 // but maybe we have a non-clever minimap
 171                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 172                 if(precache_pic(minimapname) == "")
 173                         minimapname = ""; // FAIL
 174                 else
 175                         get_mi_min_max_texcoords(0); // load new texcoords
 176         }
 177
 178         mi_center = (mi_min + mi_max) * 0.5;
 179         mi_scale = mi_max - mi_min;
 180         minimapname = strzone(minimapname);
 181
 182         WarpZone_Init();
 183
 184         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 185         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 186 }
 187
 188 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 189 void Shutdown(void)
 190 {
 191         WarpZone_Shutdown();
 192
 193         remove(teams);
 194         remove(players);
 195         db_close(binddb);
 196         db_close(tempdb);
 197         if(autocvar_cl_db_saveasdump)
 198                 db_dump(ClientProgsDB, "client.db");
 199         else
 200                 db_save(ClientProgsDB, "client.db");
 201         db_close(ClientProgsDB);
 202
 203         if(camera_active)
 204                 cvar_set("chase_active",ftos(chase_active_backup));
 205
 206         // unset the event chasecam's chase_active
 207         if(autocvar_chase_active < 0)
 208                 cvar_set("chase_active", "0");
 209
 210         if (!isdemo())
 211         {
 212                 if (!(calledhooks & HOOK_START))
 213                         localcmd("\n_cl_hook_gamestart nop\n");
 214                 if (!(calledhooks & HOOK_END))
 215                         localcmd("\ncl_hook_gameend\n");
 216         }
 217
 218         deactivate_minigame();
 219         HUD_MinigameMenu_Close();
 220 }
 221
 222 .float has_team;
 223 float SetTeam(entity o, int Team)
 224 {
 225         entity tm;
 226         if(teamplay)
 227         {
 228                 switch(Team)
 229                 {
 230                         case -1:
 231                         case NUM_TEAM_1:
 232                         case NUM_TEAM_2:
 233                         case NUM_TEAM_3:
 234                         case NUM_TEAM_4:
 235                                 break;
 236                         default:
 237                                 if(GetTeam(Team, false) == world)
 238                                 {
 239                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 240                                         Team = NUM_SPECTATOR;
 241                                 }
 242                                 break;
 243                 }
 244         }
 245         else
 246         {
 247                 switch(Team)
 248                 {
 249                         case -1:
 250                         case 0:
 251                                 break;
 252                         default:
 253                                 if(GetTeam(Team, false) == world)
 254                                 {
 255                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 256                                         Team = NUM_SPECTATOR;
 257                                 }
 258                                 break;
 259                 }
 260         }
 261         if(Team == -1) // leave
 262         {
 263                 if(o.has_team)
 264                 {
 265                         tm = GetTeam(o.team, false);
 266                         tm.team_size -= 1;
 267                         o.has_team = 0;
 268                         return true;
 269                 }
 270         }
 271         else
 272         {
 273                 if (!o.has_team)
 274                 {
 275                         o.team = Team;
 276                         tm = GetTeam(Team, true);
 277                         tm.team_size += 1;
 278                         o.has_team = 1;
 279                         return true;
 280                 }
 281                 else if(Team != o.team)
 282                 {
 283                         tm = GetTeam(o.team, false);
 284                         tm.team_size -= 1;
 285                         o.team = Team;
 286                         tm = GetTeam(Team, true);
 287                         tm.team_size += 1;
 288                         return true;
 289                 }
 290         }
 291         return false;
 292 }
 293
 294 void Playerchecker_Think()
 295 {SELFPARAM();
 296     int i;
 297         entity e;
 298         for(i = 0; i < maxclients; ++i)
 299         {
 300                 e = playerslots[i];
 301                 if(GetPlayerName(i) == "")
 302                 {
 303                         if(e.sort_prev)
 304                         {
 305                                 // player disconnected
 306                                 SetTeam(e, -1);
 307                                 RemovePlayer(e);
 308                                 e.sort_prev = world;
 309                                 //e.gotscores = 0;
 310                         }
 311                 }
 312                 else
 313                 {
 314                         if (!e.sort_prev)
 315                         {
 316                                 // player connected
 317                                 if (!e)
 318                                         playerslots[i] = e = spawn();
 319                                 e.sv_entnum = i;
 320                                 e.ping = 0;
 321                                 e.ping_packetloss = 0;
 322                                 e.ping_movementloss = 0;
 323                                 //e.gotscores = 0; // we might already have the scores...
 324                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 325                                 RegisterPlayer(e);
 326                                 HUD_UpdatePlayerPos(e);
 327                         }
 328                 }
 329         }
 330         self.nextthink = time + 0.2;
 331 }
 332
 333 void Porto_Init();
 334 void TrueAim_Init();
 335 void PostInit(void)
 336 {
 337         entity playerchecker;
 338         playerchecker = spawn();
 339         playerchecker.think = Playerchecker_Think;
 340         playerchecker.nextthink = time + 0.2;
 341
 342         Porto_Init();
 343         TrueAim_Init();
 344
 345         postinit = true;
 346 }
 347
 348 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 349 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 350 // All keys are in ascii.
 351 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 352 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 353 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 354 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 355 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 356 {
 357         float bSkipKey;
 358         bSkipKey = false;
 359
 360         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 367                 return true;
 368
 369         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if(menu_visible && menu_action)
 376                 if(menu_action(bInputType, nPrimary, nSecondary))
 377                         return true;
 378
 379         return bSkipKey;
 380 }
 381
 382 // END REQUIRED CSQC FUNCTIONS
 383 // --------------------------------------------------------------------------
 384
 385 // --------------------------------------------------------------------------
 386 // BEGIN OPTIONAL CSQC FUNCTIONS
 387
 388 void Ent_RemoveEntCS()
 389 {SELFPARAM();
 390         entcs_receiver[self.sv_entnum] = NULL;
 391 }
 392 void Ent_ReadEntCS()
 393 {SELFPARAM();
 394         InterpolateOrigin_Undo();
 395         self.classname = "entcs_receiver";
 396         int sf = ReadByte();
 397
 398         if(sf & BIT(0))
 399                 self.sv_entnum = ReadByte();
 400         if (sf & BIT(1))
 401         {
 402                 self.origin_x = ReadShort();
 403                 self.origin_y = ReadShort();
 404                 self.origin_z = ReadShort();
 405                 setorigin(self, self.origin);
 406         }
 407         if (sf & BIT(2))
 408         {
 409                 self.angles_y = ReadByte() * 360.0 / 256;
 410                 self.angles_x = self.angles_z = 0;
 411         }
 412         if (sf & BIT(3))
 413                 self.healthvalue = ReadByte() * 10;
 414         if (sf & BIT(4))
 415                 self.armorvalue = ReadByte() * 10;
 416
 417         entcs_receiver[self.sv_entnum] = self;
 418         self.entremove = Ent_RemoveEntCS;
 419         self.iflags |= IFLAG_ORIGIN;
 420
 421         InterpolateOrigin_Note();
 422 }
 423
 424 void Ent_Remove();
 425
 426 void Ent_RemovePlayerScore()
 427 {SELFPARAM();
 428         if(self.owner) {
 429                 SetTeam(self.owner, -1);
 430                 self.owner.gotscores = 0;
 431                 for(int i = 0; i < MAX_SCORE; ++i) {
 432                         self.owner.(scores[i]) = 0; // clear all scores
 433                 }
 434         }
 435 }
 436
 437 void Ent_ReadPlayerScore()
 438 {SELFPARAM();
 439         int i, n;
 440         bool isNew;
 441         entity o;
 442
 443         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 444         // (no I've never heard of M-x replace-string, sed, or anything like that)
 445         isNew = !self.owner; // workaround for DP bug
 446         n = ReadByte()-1;
 447
 448 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 449         if(!isNew && n != self.sv_entnum)
 450         {
 451                 //print("A CSQC entity changed its owner!\n");
 452                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 453                 isNew = true;
 454                 Ent_Remove();
 455                 self.enttype = ENT_CLIENT_SCORES;
 456         }
 457 #endif
 458
 459         self.sv_entnum = n;
 460
 461         if (!(playerslots[self.sv_entnum]))
 462                 playerslots[self.sv_entnum] = spawn();
 463         o = self.owner = playerslots[self.sv_entnum];
 464         o.sv_entnum = self.sv_entnum;
 465         o.gotscores = 1;
 466
 467         //if (!o.sort_prev)
 468         //      RegisterPlayer(o);
 469         //playerchecker will do this for us later, if it has not already done so
 470
 471     int sf, lf;
 472 #if MAX_SCORE <= 8
 473         sf = ReadByte();
 474         lf = ReadByte();
 475 #else
 476         sf = ReadShort();
 477         lf = ReadShort();
 478 #endif
 479     int p;
 480         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 481                 if(sf & p)
 482                 {
 483                         if(lf & p)
 484                                 o.(scores[i]) = ReadInt24_t();
 485                         else
 486                                 o.(scores[i]) = ReadChar();
 487                 }
 488
 489         if(o.sort_prev)
 490                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 491
 492         self.entremove = Ent_RemovePlayerScore;
 493 }
 494
 495 void Ent_ReadTeamScore()
 496 {SELFPARAM();
 497         int i;
 498         entity o;
 499
 500         self.team = ReadByte();
 501         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 502
 503     int sf, lf;
 504 #if MAX_TEAMSCORE <= 8
 505         sf = ReadByte();
 506         lf = ReadByte();
 507 #else
 508         sf = ReadShort();
 509         lf = ReadShort();
 510 #endif
 511         int p;
 512         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 513                 if(sf & p)
 514                 {
 515                         if(lf & p)
 516                                 o.(teamscores[i]) = ReadInt24_t();
 517                         else
 518                                 o.(teamscores[i]) = ReadChar();
 519                 }
 520
 521         HUD_UpdateTeamPos(o);
 522 }
 523
 524 void Ent_ClientData()
 525 {
 526         float newspectatee_status;
 527
 528     int f = ReadByte();
 529
 530         scoreboard_showscores_force = (f & 1);
 531
 532         if(f & 2)
 533         {
 534                 newspectatee_status = ReadByte();
 535                 if(newspectatee_status == player_localnum + 1)
 536                         newspectatee_status = -1; // observing
 537         }
 538         else
 539                 newspectatee_status = 0;
 540
 541         spectatorbutton_zoom = (f & 4);
 542
 543         if(f & 8)
 544         {
 545                 angles_held_status = 1;
 546                 angles_held.x = ReadAngle();
 547                 angles_held.y = ReadAngle();
 548                 angles_held.z = 0;
 549         }
 550         else
 551                 angles_held_status = 0;
 552
 553         if(newspectatee_status != spectatee_status)
 554         {
 555                 // clear race stuff
 556                 race_laptime = 0;
 557                 race_checkpointtime = 0;
 558         }
 559         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 560         {
 561                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 562                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 563                 )
 564                         prev_p_health = -1;
 565                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 566                         prev_health = -1;
 567         }
 568         spectatee_status = newspectatee_status;
 569
 570         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 571 }
 572
 573 void Ent_Nagger()
 574 {
 575     int i, j, b, f;
 576
 577     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 578
 579         if(!(nags & 4))
 580         {
 581                 if(vote_called_vote)
 582                         strunzone(vote_called_vote);
 583                 vote_called_vote = string_null;
 584                 vote_active = 0;
 585         }
 586         else
 587         {
 588                 vote_active = 1;
 589         }
 590
 591         if(nags & 64)
 592         {
 593                 vote_yescount = ReadByte();
 594                 vote_nocount = ReadByte();
 595                 vote_needed = ReadByte();
 596                 vote_highlighted = ReadChar();
 597         }
 598
 599         if(nags & 128)
 600         {
 601                 if(vote_called_vote)
 602                         strunzone(vote_called_vote);
 603                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 604         }
 605
 606         if(nags & 1)
 607         {
 608                 for(j = 0; j < maxclients; ++j)
 609                         if(playerslots[j])
 610                                 playerslots[j].ready = 1;
 611                 for(i = 1; i <= maxclients; i += 8)
 612                 {
 613                         f = ReadByte();
 614                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 615                                 if (!(f & b))
 616                                         if(playerslots[j])
 617                                                 playerslots[j].ready = 0;
 618                 }
 619         }
 620
 621         ready_waiting = (nags & 1);
 622         ready_waiting_for_me = (nags & 2);
 623         vote_waiting = (nags & 4);
 624         vote_waiting_for_me = (nags & 8);
 625         warmup_stage = (nags & 16);
 626 }
 627
 628 void Ent_EliminatedPlayers()
 629 {
 630     int i, j, b, f;
 631
 632     int sf = ReadByte();
 633         if(sf & 1)
 634         {
 635                 for(j = 0; j < maxclients; ++j)
 636                         if(playerslots[j])
 637                                 playerslots[j].eliminated = 1;
 638                 for(i = 1; i <= maxclients; i += 8)
 639                 {
 640                         f = ReadByte();
 641                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 642                                 if (!(f & b))
 643                                         if(playerslots[j])
 644                                                 playerslots[j].eliminated = 0;
 645                 }
 646         }
 647 }
 648
 649 void Ent_RandomSeed()
 650 {
 651         float s;
 652         prandom_debug();
 653         s = ReadShort();
 654         psrandom(s);
 655 }
 656
 657 void Ent_ReadAccuracy(void)
 658 {
 659     int f, w;
 660     int sf = ReadInt24_t();
 661         if(sf == 0)
 662         {
 663                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 664                         weapon_accuracy[w] = -1;
 665                 return;
 666         }
 667
 668         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 669         {
 670                 if(sf & f)
 671                 {
 672             int b = ReadByte();
 673                         if(b == 0)
 674                                 weapon_accuracy[w] = -1;
 675                         else if(b == 255)
 676                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 677                         else
 678                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 679                 }
 680                 if(f == 0x800000)
 681                         f = 1;
 682                 else
 683                         f *= 2;
 684         }
 685 }
 686
 687 void Spawn_Draw(entity this)
 688 {
 689         pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 690 }
 691
 692 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 693 {SELFPARAM();
 694         float teamnum = (ReadByte() - 1);
 695         vector spn_origin;
 696         spn_origin.x = ReadShort();
 697         spn_origin.y = ReadShort();
 698         spn_origin.z = ReadShort();
 699
 700         if(is_new)
 701         {
 702                 self.origin = spn_origin;
 703                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 704                 droptofloor();
 705
 706                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 707                 {
 708                         self.mdl = "models/spawnpoint.md3";
 709                         self.colormod = Team_ColorRGB(teamnum);
 710                         precache_model(self.mdl);
 711                         setmodel(self, self.mdl);
 712                         self.drawmask = MASK_NORMAL;
 713                         //self.movetype = MOVETYPE_NOCLIP;
 714                         //self.draw = Spawn_Draw;
 715                 }*/
 716                 if(autocvar_cl_spawn_point_particles)
 717                 {
 718                         if((serverflags & SERVERFLAG_TEAMPLAY))
 719                         {
 720                                 switch(teamnum)
 721                                 {
 722                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 723                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 724                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 725                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 726                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 727                                 }
 728                         }
 729                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 730
 731                         self.draw = Spawn_Draw;
 732                 }
 733         }
 734
 735         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 736 }
 737
 738 void Ent_ReadSpawnEvent(float is_new)
 739 {SELFPARAM();
 740         // If entnum is 0, ONLY do the local spawn actions
 741         // this way the server can disable the sending of
 742         // spawn origin or such to clients if wanted.
 743         float entnum = ReadByte();
 744
 745         if(entnum)
 746         {
 747                 self.origin_x = ReadShort();
 748                 self.origin_y = ReadShort();
 749                 self.origin_z = ReadShort();
 750
 751                 if(is_new)
 752                 {
 753                         float teamnum = GetPlayerColor(entnum - 1);
 754
 755                         if(autocvar_cl_spawn_event_particles)
 756                         {
 757                                 switch(teamnum)
 758                                 {
 759                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 760                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 761                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 762                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 763                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 764                                 }
 765                         }
 766                         if(autocvar_cl_spawn_event_sound)
 767                         {
 768                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 769                         }
 770                 }
 771         }
 772
 773         // local spawn actions
 774         if(is_new && (!entnum || (entnum == player_localentnum)))
 775         {
 776                 zoomin_effect = 1;
 777                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 778
 779                 if(autocvar_cl_unpress_zoom_on_spawn)
 780                 {
 781                         localcmd("-zoom\n");
 782                         button_zoom = false;
 783                 }
 784         }
 785         HUD_Radar_Hide_Maximized();
 786         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 787 }
 788
 789 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 790 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 791 void Ent_RadarLink();
 792 void Ent_Init();
 793 void Ent_ScoresInfo();
 794 void CSQC_Ent_Update(float bIsNewEntity)
 795 {SELFPARAM();
 796         int t = ReadByte();
 797
 798         if(autocvar_developer_csqcentities)
 799                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 800
 801         // set up the "time" global for received entities to be correct for interpolation purposes
 802         float savetime = time;
 803         if(servertime)
 804         {
 805                 time = servertime;
 806         }
 807         else
 808         {
 809                 serverprevtime = time;
 810                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 811                 time = serverprevtime + serverdeltatime;
 812         }
 813
 814 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 815         if(self.enttype)
 816         {
 817                 if(t != self.enttype || bIsNewEntity)
 818                 {
 819                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 820                         Ent_Remove();
 821                         clearentity(self);
 822                         bIsNewEntity = 1;
 823                 }
 824         }
 825         else
 826         {
 827                 if(!bIsNewEntity)
 828                 {
 829                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 830                         bIsNewEntity = 1;
 831                 }
 832         }
 833 #endif
 834         self.enttype = t;
 835         bool done = false;
 836         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 837                 it.m_read(self, bIsNewEntity);
 838                 done = true;
 839                 break;
 840         ));
 841         if (!done)
 842         switch(t)
 843         {
 844                 case ENT_CLIENT_MUTATOR: {
 845                         int mutID = ReadMutator();
 846                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 847                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 848                         break;
 849                 }
 850                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 851                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 852                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 853                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 854                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 855                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 856                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 857                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 858                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 859                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 860                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 861                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 862                 case ENT_CLIENT_INIT: Ent_Init(); break;
 863                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 864                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 865                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 866                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 867                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 868                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 869                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 870                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 871                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 872                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 873                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 874                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 875                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 876                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 877                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 878                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 879                 case ENT_CLIENT_TURRET: ent_turret(); break;
 880                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 881                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(this); break;
 882                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 883                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 884                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 885                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 886                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 887                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 888                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 889                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 890                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 891                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 892                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 893                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 894                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 895                 case ENT_CLIENT_DOOR: ent_door(); break;
 896                 case ENT_CLIENT_PLAT: ent_plat(); break;
 897                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 898                 case ENT_CLIENT_CORNER: ent_corner(); break;
 899                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 900                 case ENT_CLIENT_TRAIN: ent_train(); break;
 901                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 902                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 903
 904                 default:
 905                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 906                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 907                         break;
 908         }
 909
 910         time = savetime;
 911 }
 912 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 913 // used when an entity changes its type. For an entity that someone interacts
 914 // with others, make sure it can no longer do so.
 915 void Ent_Remove()
 916 {SELFPARAM();
 917         if(self.entremove)
 918                 self.entremove();
 919
 920         if(self.skeletonindex)
 921         {
 922                 skel_delete(self.skeletonindex);
 923                 self.skeletonindex = 0;
 924         }
 925
 926         if(self.snd_looping > 0)
 927         {
 928                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 929                 self.snd_looping = 0;
 930         }
 931
 932         self.enttype = 0;
 933         self.classname = "";
 934         self.draw = draw_null;
 935         self.entremove = menu_sub_null;
 936         // TODO possibly set more stuff to defaults
 937 }
 938 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 939 void CSQC_Ent_Remove()
 940 {SELFPARAM();
 941         if(autocvar_developer_csqcentities)
 942                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 943
 944         if(wasfreed(self))
 945         {
 946                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 947                 return;
 948         }
 949         if(self.enttype)
 950                 Ent_Remove();
 951         remove(self);
 952 }
 953
 954 void Gamemode_Init()
 955 {
 956         if (!isdemo())
 957         {
 958                 if(!(calledhooks & HOOK_START))
 959                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 960                 calledhooks |= HOOK_START;
 961         }
 962 }
 963 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 964 void CSQC_Parse_StuffCmd(string strMessage)
 965 {
 966         if(autocvar_developer_csqcentities)
 967                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 968
 969         localcmd(strMessage);
 970 }
 971 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 972 void CSQC_Parse_Print(string strMessage)
 973 {
 974         if(autocvar_developer_csqcentities)
 975                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 976
 977         print(ColorTranslateRGB(strMessage));
 978 }
 979
 980 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 981 void CSQC_Parse_CenterPrint(string strMessage)
 982 {
 983         if(autocvar_developer_csqcentities)
 984                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 985
 986         centerprint_hud(strMessage);
 987 }
 988
 989 string notranslate_fogcmd1 = "\nfog ";
 990 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 991 void Fog_Force()
 992 {
 993         // TODO somehow thwart prvm_globalset client ...
 994
 995         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 996                 { localcmd("\nr_drawfog 0\n"); }
 997         else if(forcefog != "")
 998                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 999 }
1000
1001 void Gamemode_Init();
1002 void Ent_ScoresInfo()
1003 {SELFPARAM();
1004     int i;
1005         self.classname = "ent_client_scores_info";
1006         gametype = ReadInt24_t();
1007         HUD_ModIcons_SetFunc();
1008         for(i = 0; i < MAX_SCORE; ++i)
1009         {
1010                 if(scores_label[i])
1011                         strunzone(scores_label[i]);
1012                 scores_label[i] = strzone(ReadString());
1013                 scores_flags[i] = ReadByte();
1014         }
1015         for(i = 0; i < MAX_TEAMSCORE; ++i)
1016         {
1017                 if(teamscores_label[i])
1018                         strunzone(teamscores_label[i]);
1019                 teamscores_label[i] = strzone(ReadString());
1020                 teamscores_flags[i] = ReadByte();
1021         }
1022         HUD_InitScores();
1023         Gamemode_Init();
1024 }
1025
1026 void Ent_Init()
1027 {SELFPARAM();
1028         self.classname = "ent_client_init";
1029
1030         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1031
1032         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1033         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1034         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1035         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1036         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1037         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1038         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1039         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1040
1041         if(forcefog)
1042                 strunzone(forcefog);
1043         forcefog = strzone(ReadString());
1044
1045         armorblockpercent = ReadByte() / 255.0;
1046
1047         g_balance_mortar_bouncefactor = ReadCoord();
1048         g_balance_mortar_bouncestop = ReadCoord();
1049         g_balance_electro_secondary_bouncefactor = ReadCoord();
1050         g_balance_electro_secondary_bouncestop = ReadCoord();
1051
1052         vortex_scope = !ReadByte();
1053         rifle_scope = !ReadByte();
1054
1055         serverflags = ReadByte();
1056
1057         minelayer_maxmines = ReadByte();
1058
1059         hagar_maxrockets = ReadByte();
1060
1061         g_trueaim_minrange = ReadCoord();
1062         g_balance_porto_secondary = ReadByte();
1063
1064         if(!postinit)
1065                 PostInit();
1066 }
1067
1068 void Net_ReadRace()
1069 {
1070         float b;
1071
1072         b = ReadByte();
1073
1074         switch(b)
1075         {
1076                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1077                         race_checkpoint = ReadByte();
1078                         race_time = ReadInt24_t();
1079                         race_previousbesttime = ReadInt24_t();
1080                         if(race_previousbestname)
1081                                 strunzone(race_previousbestname);
1082                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1083
1084                         race_checkpointtime = time;
1085
1086                         if(race_checkpoint == 0 || race_checkpoint == 254)
1087                         {
1088                                 race_penaltyaccumulator = 0;
1089                                 race_laptime = time; // valid
1090                         }
1091
1092                         break;
1093
1094                 case RACE_NET_CHECKPOINT_CLEAR:
1095                         race_laptime = 0;
1096                         race_checkpointtime = 0;
1097                         break;
1098
1099                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1100                         race_laptime = ReadCoord();
1101                         race_checkpointtime = -99999;
1102                         // fall through
1103                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1104                         race_nextcheckpoint = ReadByte();
1105
1106                         race_nextbesttime = ReadInt24_t();
1107                         if(race_nextbestname)
1108                                 strunzone(race_nextbestname);
1109                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1110                         break;
1111
1112                 case RACE_NET_CHECKPOINT_HIT_RACE:
1113                         race_mycheckpoint = ReadByte();
1114                         race_mycheckpointtime = time;
1115                         race_mycheckpointdelta = ReadInt24_t();
1116                         race_mycheckpointlapsdelta = ReadByte();
1117                         if(race_mycheckpointlapsdelta >= 128)
1118                                 race_mycheckpointlapsdelta -= 256;
1119                         if(race_mycheckpointenemy)
1120                                 strunzone(race_mycheckpointenemy);
1121                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1122                         break;
1123
1124                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1125                         race_othercheckpoint = ReadByte();
1126                         race_othercheckpointtime = time;
1127                         race_othercheckpointdelta = ReadInt24_t();
1128                         race_othercheckpointlapsdelta = ReadByte();
1129                         if(race_othercheckpointlapsdelta >= 128)
1130                                 race_othercheckpointlapsdelta -= 256;
1131                         if(race_othercheckpointenemy)
1132                                 strunzone(race_othercheckpointenemy);
1133                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1134                         break;
1135
1136                 case RACE_NET_PENALTY_RACE:
1137                         race_penaltyeventtime = time;
1138                         race_penaltytime = ReadShort();
1139                         //race_penaltyaccumulator += race_penaltytime;
1140                         if(race_penaltyreason)
1141                                 strunzone(race_penaltyreason);
1142                         race_penaltyreason = strzone(ReadString());
1143                         break;
1144
1145                 case RACE_NET_PENALTY_QUALIFYING:
1146                         race_penaltyeventtime = time;
1147                         race_penaltytime = ReadShort();
1148                         race_penaltyaccumulator += race_penaltytime;
1149                         if(race_penaltyreason)
1150                                 strunzone(race_penaltyreason);
1151                         race_penaltyreason = strzone(ReadString());
1152                         break;
1153
1154                 case RACE_NET_SERVER_RECORD:
1155                         race_server_record = ReadInt24_t();
1156                         break;
1157                 case RACE_NET_SPEED_AWARD:
1158                         race_speedaward = ReadInt24_t();
1159                         if(race_speedaward_holder)
1160                                 strunzone(race_speedaward_holder);
1161                         race_speedaward_holder = strzone(ReadString());
1162                         break;
1163                 case RACE_NET_SPEED_AWARD_BEST:
1164                         race_speedaward_alltimebest = ReadInt24_t();
1165                         if(race_speedaward_alltimebest_holder)
1166                                 strunzone(race_speedaward_alltimebest_holder);
1167                         race_speedaward_alltimebest_holder = strzone(ReadString());
1168                         break;
1169                 case RACE_NET_SERVER_RANKINGS:
1170                         float prevpos, del;
1171             int pos = ReadShort();
1172                         prevpos = ReadShort();
1173                         del = ReadShort();
1174
1175                         // move other rankings out of the way
1176             int i;
1177                         if (prevpos) {
1178                                 for (i=prevpos-1;i>pos-1;--i) {
1179                                         grecordtime[i] = grecordtime[i-1];
1180                                         if(grecordholder[i])
1181                                                 strunzone(grecordholder[i]);
1182                                         grecordholder[i] = strzone(grecordholder[i-1]);
1183                                 }
1184                         } else if (del) { // a record has been deleted by the admin
1185                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1186                                         if (i == RANKINGS_CNT-1) { // clear out last record
1187                                                 grecordtime[i] = 0;
1188                                                 if (grecordholder[i])
1189                                                         strunzone(grecordholder[i]);
1190                                                 grecordholder[i] = string_null;
1191                                         }
1192                                         else {
1193                                                 grecordtime[i] = grecordtime[i+1];
1194                                                 if (grecordholder[i])
1195                                                         strunzone(grecordholder[i]);
1196                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1197                                         }
1198                                 }
1199                         } else { // player has no ranked record yet
1200                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1201                                         grecordtime[i] = grecordtime[i-1];
1202                                         if(grecordholder[i])
1203                                                 strunzone(grecordholder[i]);
1204                                         grecordholder[i] = strzone(grecordholder[i-1]);
1205                                 }
1206                         }
1207
1208                         // store new ranking
1209                         if(grecordholder[pos-1] != "")
1210                                 strunzone(grecordholder[pos-1]);
1211                         grecordholder[pos-1] = strzone(ReadString());
1212                         grecordtime[pos-1] = ReadInt24_t();
1213                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1214                                 race_myrank = pos;
1215                         break;
1216                 case RACE_NET_SERVER_STATUS:
1217                         race_status = ReadShort();
1218                         if(race_status_name)
1219                                 strunzone(race_status_name);
1220                         race_status_name = strzone(ReadString());
1221         }
1222 }
1223
1224 void Net_TeamNagger()
1225 {
1226         teamnagger = 1;
1227 }
1228
1229 void Net_ReadPingPLReport()
1230 {
1231         int e, pi, pl, ml;
1232         e = ReadByte();
1233         pi = ReadShort();
1234         pl = ReadByte();
1235         ml = ReadByte();
1236         if (!(playerslots[e]))
1237                 return;
1238         playerslots[e].ping = pi;
1239         playerslots[e].ping_packetloss = pl / 255.0;
1240         playerslots[e].ping_movementloss = ml / 255.0;
1241 }
1242
1243 void Net_WeaponComplain()
1244 {
1245         complain_weapon = ReadByte();
1246
1247         if(complain_weapon_name)
1248                 strunzone(complain_weapon_name);
1249         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1250
1251         complain_weapon_type = ReadByte();
1252
1253         complain_weapon_time = time;
1254         weapontime = time; // ping the weapon panel
1255
1256         switch(complain_weapon_type)
1257         {
1258                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1259                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1260                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1261         }
1262 }
1263
1264 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1265 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1266 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1267 bool CSQC_Parse_TempEntity()
1268 {
1269         // Acquire TE ID
1270         int nTEID = ReadByte();
1271
1272         if (autocvar_developer_csqcentities)
1273                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1274
1275         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
1276                 it.m_read(NULL, true);
1277                 return true;
1278         ));
1279         switch (nTEID)
1280         {
1281                 case TE_CSQC_MUTATOR:
1282                         int mutID = ReadMutator();
1283                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1284                         return true;
1285                 case TE_CSQC_TARGET_MUSIC:
1286                         Net_TargetMusic();
1287                         return true;
1288                 case TE_CSQC_PICTURE:
1289                         Net_MapVote_Picture();
1290                         return true;
1291                 case TE_CSQC_RACE:
1292                         Net_ReadRace();
1293                         return true;
1294                 case TE_CSQC_VORTEXBEAMPARTICLE:
1295                         Net_ReadVortexBeamParticle();
1296                         return true;
1297                 case TE_CSQC_TEAMNAGGER:
1298                         Net_TeamNagger();
1299                         return true;
1300                 case TE_CSQC_ARC:
1301                         Net_ReadArc();
1302                         return true;
1303                 case TE_CSQC_PINGPLREPORT:
1304                         Net_ReadPingPLReport();
1305                         return true;
1306                 case TE_CSQC_WEAPONCOMPLAIN:
1307                         Net_WeaponComplain();
1308                         return true;
1309                 case TE_CSQC_VEHICLESETUP:
1310                         Net_VehicleSetup();
1311                         return true;
1312                 case TE_CSQC_SVNOTICE:
1313                         cl_notice_read();
1314                         return true;
1315                 case TE_CSQC_SHOCKWAVEPARTICLE:
1316                         Net_ReadShockwaveParticle();
1317                         return true;
1318                 default:
1319                         // No special logic for this temporary entity; return 0 so the engine can handle it
1320                         return false;
1321         }
1322 }
1323
1324 string getcommandkey(string text, string command)
1325 {
1326         string keys;
1327         float n, j, k, l = 0;
1328
1329         if (!autocvar_hud_showbinds)
1330                 return text;
1331
1332         keys = db_get(binddb, command);
1333         if (keys == "")
1334         {
1335                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1336                 for(j = 0; j < n; ++j)
1337                 {
1338                         k = stof(argv(j));
1339                         if(k != -1)
1340                         {
1341                                 if ("" == keys)
1342                                         keys = keynumtostring(k);
1343                                 else
1344                                         keys = strcat(keys, ", ", keynumtostring(k));
1345
1346                                 ++l;
1347                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1348                                         break;
1349                         }
1350
1351                 }
1352                 if (keys == "")
1353                         keys = "NO_KEY";
1354                 db_put(binddb, command, keys);
1355         }
1356
1357         if (keys == "NO_KEY") {
1358                 if (autocvar_hud_showbinds > 1)
1359                         return sprintf(_("%s (not bound)"), text);
1360                 else
1361                         return text;
1362         }
1363         else if (autocvar_hud_showbinds > 1)
1364                 return sprintf("%s (%s)", text, keys);
1365         else
1366                 return keys;
1367 }