qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "controlpoint.qh"
   4 #include "damage.qh"
   5 #include "effects.qh"
   6 #include "generator.qh"
   7 #include "gibs.qh"
   8 #include "hook.qh"
   9 #include "hud.qh"
  10 #include "hud_config.qh"
  11 #include "laser.qh"
  12 #include "mapvoting.qh"
  13 #include "modeleffects.qh"
  14 #include "mutators/events.qh"
  15 #include "particles.qh"
  16 #include "quickmenu.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "tuba.qh"
  20 #include "t_items.qh"
  21 #include "wall.qh"
  22 #include "weapons/projectile.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/items/all.qh"
  25 #include "../common/mapinfo.qh"
  26 #include "../common/minigames/cl_minigames.qh"
  27 #include "../common/minigames/cl_minigames_hud.qh"
  28 #include "../common/net_notice.qh"
  29 #include "../common/triggers/include.qh"
  30 #include "../common/turrets/cl_turrets.qh"
  31 #include "../common/vehicles/all.qh"
  32 #include "../lib/csqcmodel/cl_model.qh"
  33 #include "../lib/csqcmodel/interpolate.qh"
  34 #include "../lib/warpzone/client.qh"
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 entity clearentity_ent;
  41 void clearentity(entity e)
  42 {
  43         if (!clearentity_ent)
  44         {
  45                 clearentity_ent = new(clearentity);
  46         }
  47         int n = e.entnum;
  48         copyentity(clearentity_ent, e);
  49         e.entnum = n;
  50 }
  51
  52 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  53 void menu_show_error()
  54 {
  55         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  56 }
  57
  58 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  59 // Useful for precaching things
  60
  61 void menu_sub_null()
  62 {
  63 }
  64
  65 void draw_null(entity this) { }
  66
  67 string forcefog;
  68 void ConsoleCommand_macro_init();
  69 void CSQC_Init(void)
  70 {
  71         prvm_language = strzone(cvar_string("prvm_language"));
  72
  73 #ifdef WATERMARK
  74         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  75 #endif
  76
  77         int i;
  78
  79         binddb = db_create();
  80         tempdb = db_create();
  81         ClientProgsDB = db_load("client.db");
  82         compressShortVector_init();
  83
  84         draw_endBoldFont();
  85         menu_visible = false;
  86         menu_show = menu_show_error;
  87         menu_action = func_null;
  88
  89         for(i = 0; i < 255; ++i)
  90                 if(getplayerkeyvalue(i, "viewentity") == "")
  91                         break;
  92         maxclients = i;
  93
  94         //registercommand("hud_configure");
  95         //registercommand("hud_save");
  96         //registercommand("menu_action");
  97
  98         ConsoleCommand_macro_init();
  99
 100         registercvar("hud_usecsqc", "1");
 101         registercvar("scoreboard_columns", "default");
 102
 103         registercvar("cl_nade_type", "3");
 104         registercvar("cl_pokenade_type", "zombie");
 105
 106         registercvar("cl_jumpspeedcap_min", "");
 107         registercvar("cl_jumpspeedcap_max", "");
 108
 109         registercvar("cl_multijump", "0");
 110
 111         registercvar("cl_spawn_near_teammate", "1");
 112
 113         gametype = 0;
 114
 115         // hud_fields uses strunzone on the titles!
 116         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 117                 hud_title[i] = strzone("(null)");
 118
 119         Cmd_HUD_SetFields(0);
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(NUM_SPECTATOR, true); // add specs first
 129
 130         // needs to be done so early because of the constants they create
 131         static_init();
 132         static_init_late();
 133         static_init_precache();
 134
 135         // precaches
 136
 137         Projectile_Precache();
 138         Tuba_Precache();
 139
 140         if(autocvar_cl_reticle)
 141         {
 142                 precache_pic("gfx/reticle_normal");
 143                 // weapon reticles are precached in weapon files
 144         }
 145
 146         get_mi_min_max_texcoords(1); // try the CLEVER way first
 147         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 148         shortmapname = mi_shortname;
 149
 150         if(precache_pic(minimapname) == "")
 151         {
 152                 // but maybe we have a non-clever minimap
 153                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 154                 if(precache_pic(minimapname) == "")
 155                         minimapname = ""; // FAIL
 156                 else
 157                         get_mi_min_max_texcoords(0); // load new texcoords
 158         }
 159
 160         mi_center = (mi_min + mi_max) * 0.5;
 161         mi_scale = mi_max - mi_min;
 162         minimapname = strzone(minimapname);
 163
 164         WarpZone_Init();
 165
 166         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 167         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 168 }
 169
 170 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 171 void Shutdown(void)
 172 {
 173         WarpZone_Shutdown();
 174
 175         remove(teams);
 176         remove(players);
 177         db_close(binddb);
 178         db_close(tempdb);
 179         if(autocvar_cl_db_saveasdump)
 180                 db_dump(ClientProgsDB, "client.db");
 181         else
 182                 db_save(ClientProgsDB, "client.db");
 183         db_close(ClientProgsDB);
 184
 185         if(camera_active)
 186                 cvar_set("chase_active",ftos(chase_active_backup));
 187
 188         // unset the event chasecam's chase_active
 189         if(autocvar_chase_active < 0)
 190                 cvar_set("chase_active", "0");
 191
 192         if (!isdemo())
 193         {
 194                 if (!(calledhooks & HOOK_START))
 195                         localcmd("\n_cl_hook_gamestart nop\n");
 196                 if (!(calledhooks & HOOK_END))
 197                         localcmd("\ncl_hook_gameend\n");
 198         }
 199
 200         deactivate_minigame();
 201         HUD_MinigameMenu_Close();
 202 }
 203
 204 .float has_team;
 205 float SetTeam(entity o, int Team)
 206 {
 207         entity tm;
 208         if(teamplay)
 209         {
 210                 switch(Team)
 211                 {
 212                         case -1:
 213                         case NUM_TEAM_1:
 214                         case NUM_TEAM_2:
 215                         case NUM_TEAM_3:
 216                         case NUM_TEAM_4:
 217                                 break;
 218                         default:
 219                                 if(GetTeam(Team, false) == world)
 220                                 {
 221                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 222                                         Team = NUM_SPECTATOR;
 223                                 }
 224                                 break;
 225                 }
 226         }
 227         else
 228         {
 229                 switch(Team)
 230                 {
 231                         case -1:
 232                         case 0:
 233                                 break;
 234                         default:
 235                                 if(GetTeam(Team, false) == world)
 236                                 {
 237                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 238                                         Team = NUM_SPECTATOR;
 239                                 }
 240                                 break;
 241                 }
 242         }
 243         if(Team == -1) // leave
 244         {
 245                 if(o.has_team)
 246                 {
 247                         tm = GetTeam(o.team, false);
 248                         tm.team_size -= 1;
 249                         o.has_team = 0;
 250                         return true;
 251                 }
 252         }
 253         else
 254         {
 255                 if (!o.has_team)
 256                 {
 257                         o.team = Team;
 258                         tm = GetTeam(Team, true);
 259                         tm.team_size += 1;
 260                         o.has_team = 1;
 261                         return true;
 262                 }
 263                 else if(Team != o.team)
 264                 {
 265                         tm = GetTeam(o.team, false);
 266                         tm.team_size -= 1;
 267                         o.team = Team;
 268                         tm = GetTeam(Team, true);
 269                         tm.team_size += 1;
 270                         return true;
 271                 }
 272         }
 273         return false;
 274 }
 275
 276 void Playerchecker_Think()
 277 {SELFPARAM();
 278     int i;
 279         entity e;
 280         for(i = 0; i < maxclients; ++i)
 281         {
 282                 e = playerslots[i];
 283                 if(GetPlayerName(i) == "")
 284                 {
 285                         if(e.sort_prev)
 286                         {
 287                                 // player disconnected
 288                                 SetTeam(e, -1);
 289                                 RemovePlayer(e);
 290                                 e.sort_prev = world;
 291                                 //e.gotscores = 0;
 292                         }
 293                 }
 294                 else
 295                 {
 296                         if (!e.sort_prev)
 297                         {
 298                                 // player connected
 299                                 if (!e)
 300                                 {
 301                                         playerslots[i] = e = new(playerslot);
 302                                         make_pure(e);
 303                                 }
 304                                 e.sv_entnum = i;
 305                                 e.ping = 0;
 306                                 e.ping_packetloss = 0;
 307                                 e.ping_movementloss = 0;
 308                                 //e.gotscores = 0; // we might already have the scores...
 309                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 310                                 RegisterPlayer(e);
 311                                 HUD_UpdatePlayerPos(e);
 312                         }
 313                 }
 314         }
 315         self.nextthink = time + 0.2;
 316 }
 317
 318 void Porto_Init();
 319 void TrueAim_Init();
 320 void PostInit(void)
 321 {
 322         entity playerchecker = new(playerchecker);
 323         make_pure(playerchecker);
 324         playerchecker.think = Playerchecker_Think;
 325         playerchecker.nextthink = time + 0.2;
 326
 327         Porto_Init();
 328         TrueAim_Init();
 329
 330         postinit = true;
 331 }
 332
 333 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 334 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 335 // All keys are in ascii.
 336 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 337 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 338 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 339 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 340 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 341 {
 342         float bSkipKey;
 343         bSkipKey = false;
 344
 345         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 346                 return true;
 347
 348         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 349                 return true;
 350
 351         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 352                 return true;
 353
 354         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 355                 return true;
 356
 357         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 358                 return true;
 359
 360         if(menu_visible && menu_action)
 361                 if(menu_action(bInputType, nPrimary, nSecondary))
 362                         return true;
 363
 364         return bSkipKey;
 365 }
 366
 367 // END REQUIRED CSQC FUNCTIONS
 368 // --------------------------------------------------------------------------
 369
 370 // --------------------------------------------------------------------------
 371 // BEGIN OPTIONAL CSQC FUNCTIONS
 372
 373 void Ent_RemoveEntCS()
 374 {SELFPARAM();
 375         entcs_receiver[self.sv_entnum] = NULL;
 376 }
 377 void Ent_ReadEntCS()
 378 {SELFPARAM();
 379         make_pure(this);
 380         this.classname = "entcs_receiver";
 381         InterpolateOrigin_Undo();
 382         int sf = ReadByte();
 383
 384         if(sf & BIT(0))
 385                 self.sv_entnum = ReadByte();
 386         if (sf & BIT(1))
 387         {
 388                 self.origin_x = ReadShort();
 389                 self.origin_y = ReadShort();
 390                 self.origin_z = ReadShort();
 391                 setorigin(self, self.origin);
 392         }
 393         if (sf & BIT(2))
 394         {
 395                 self.angles_y = ReadByte() * 360.0 / 256;
 396                 self.angles_x = self.angles_z = 0;
 397         }
 398         if (sf & BIT(3))
 399                 self.healthvalue = ReadByte() * 10;
 400         if (sf & BIT(4))
 401                 self.armorvalue = ReadByte() * 10;
 402
 403         entcs_receiver[self.sv_entnum] = self;
 404         self.entremove = Ent_RemoveEntCS;
 405         self.iflags |= IFLAG_ORIGIN;
 406
 407         InterpolateOrigin_Note();
 408 }
 409
 410 void Ent_Remove();
 411
 412 void Ent_RemovePlayerScore()
 413 {SELFPARAM();
 414         if(self.owner) {
 415                 SetTeam(self.owner, -1);
 416                 self.owner.gotscores = 0;
 417                 for(int i = 0; i < MAX_SCORE; ++i) {
 418                         self.owner.(scores[i]) = 0; // clear all scores
 419                 }
 420         }
 421 }
 422
 423 void Ent_ReadPlayerScore()
 424 {SELFPARAM();
 425         make_pure(this);
 426         int i, n;
 427         bool isNew;
 428         entity o;
 429
 430         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 431         // (no I've never heard of M-x replace-string, sed, or anything like that)
 432         isNew = !self.owner; // workaround for DP bug
 433         n = ReadByte()-1;
 434
 435 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 436         if(!isNew && n != self.sv_entnum)
 437         {
 438                 //print("A CSQC entity changed its owner!\n");
 439                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 440                 isNew = true;
 441                 Ent_Remove();
 442                 self.enttype = ENT_CLIENT_SCORES;
 443         }
 444 #endif
 445
 446         self.sv_entnum = n;
 447
 448         o = playerslots[self.sv_entnum];
 449         if (!o)
 450         {
 451                 o = playerslots[self.sv_entnum] = new(playerslot);
 452                 make_pure(o);
 453         }
 454         self.owner = o;
 455         o.sv_entnum = self.sv_entnum;
 456         o.gotscores = 1;
 457
 458         //if (!o.sort_prev)
 459         //      RegisterPlayer(o);
 460         //playerchecker will do this for us later, if it has not already done so
 461
 462     int sf, lf;
 463 #if MAX_SCORE <= 8
 464         sf = ReadByte();
 465         lf = ReadByte();
 466 #else
 467         sf = ReadShort();
 468         lf = ReadShort();
 469 #endif
 470     int p;
 471         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 472                 if(sf & p)
 473                 {
 474                         if(lf & p)
 475                                 o.(scores[i]) = ReadInt24_t();
 476                         else
 477                                 o.(scores[i]) = ReadChar();
 478                 }
 479
 480         if(o.sort_prev)
 481                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 482
 483         self.entremove = Ent_RemovePlayerScore;
 484 }
 485
 486 void Ent_ReadTeamScore()
 487 {SELFPARAM();
 488         make_pure(this);
 489         int i;
 490         entity o;
 491
 492         self.team = ReadByte();
 493         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 494
 495     int sf, lf;
 496 #if MAX_TEAMSCORE <= 8
 497         sf = ReadByte();
 498         lf = ReadByte();
 499 #else
 500         sf = ReadShort();
 501         lf = ReadShort();
 502 #endif
 503         int p;
 504         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 505                 if(sf & p)
 506                 {
 507                         if(lf & p)
 508                                 o.(teamscores[i]) = ReadInt24_t();
 509                         else
 510                                 o.(teamscores[i]) = ReadChar();
 511                 }
 512
 513         HUD_UpdateTeamPos(o);
 514 }
 515
 516 void Ent_ClientData()
 517 {
 518         make_pure(self);
 519         float newspectatee_status;
 520
 521     int f = ReadByte();
 522
 523         scoreboard_showscores_force = (f & 1);
 524
 525         if(f & 2)
 526         {
 527                 newspectatee_status = ReadByte();
 528                 if(newspectatee_status == player_localnum + 1)
 529                         newspectatee_status = -1; // observing
 530         }
 531         else
 532                 newspectatee_status = 0;
 533
 534         spectatorbutton_zoom = (f & 4);
 535
 536         if(f & 8)
 537         {
 538                 angles_held_status = 1;
 539                 angles_held.x = ReadAngle();
 540                 angles_held.y = ReadAngle();
 541                 angles_held.z = 0;
 542         }
 543         else
 544                 angles_held_status = 0;
 545
 546         if(newspectatee_status != spectatee_status)
 547         {
 548                 // clear race stuff
 549                 race_laptime = 0;
 550                 race_checkpointtime = 0;
 551         }
 552         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 553         {
 554                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 555                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 556                 )
 557                         prev_p_health = -1;
 558                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 559                         prev_health = -1;
 560         }
 561         spectatee_status = newspectatee_status;
 562
 563         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 564 }
 565
 566 void Ent_Nagger()
 567 {
 568         make_pure(self);
 569     int i, j, b, f;
 570
 571     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 572
 573         if(!(nags & BIT(2)))
 574         {
 575                 if(vote_called_vote)
 576                         strunzone(vote_called_vote);
 577                 vote_called_vote = string_null;
 578                 vote_active = 0;
 579         }
 580         else
 581         {
 582                 vote_active = 1;
 583         }
 584
 585         if(nags & BIT(6))
 586         {
 587                 vote_yescount = ReadByte();
 588                 vote_nocount = ReadByte();
 589                 vote_needed = ReadByte();
 590                 vote_highlighted = ReadChar();
 591         }
 592
 593         if(nags & BIT(7))
 594         {
 595                 if(vote_called_vote)
 596                         strunzone(vote_called_vote);
 597                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 598         }
 599
 600         if(nags & 1)
 601         {
 602                 for(j = 0; j < maxclients; ++j)
 603                         if(playerslots[j])
 604                                 playerslots[j].ready = 1;
 605                 for(i = 1; i <= maxclients; i += 8)
 606                 {
 607                         f = ReadByte();
 608                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 609                                 if (!(f & b))
 610                                         if(playerslots[j])
 611                                                 playerslots[j].ready = 0;
 612                 }
 613         }
 614
 615         ready_waiting = (nags & BIT(0));
 616         ready_waiting_for_me = (nags & BIT(1));
 617         vote_waiting = (nags & BIT(2));
 618         vote_waiting_for_me = (nags & BIT(3));
 619         warmup_stage = (nags & BIT(4));
 620 }
 621
 622 void Ent_EliminatedPlayers()
 623 {
 624         make_pure(self);
 625     int i, j, b, f;
 626
 627     int sf = ReadByte();
 628         if(sf & 1)
 629         {
 630                 for(j = 0; j < maxclients; ++j)
 631                         if(playerslots[j])
 632                                 playerslots[j].eliminated = 1;
 633                 for(i = 1; i <= maxclients; i += 8)
 634                 {
 635                         f = ReadByte();
 636                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 637                                 if (!(f & b))
 638                                         if(playerslots[j])
 639                                                 playerslots[j].eliminated = 0;
 640                 }
 641         }
 642 }
 643
 644 void Ent_RandomSeed()
 645 {
 646         make_pure(self);
 647         prandom_debug();
 648         float s = ReadShort();
 649         psrandom(s);
 650 }
 651
 652 void Ent_ReadAccuracy()
 653 {
 654         make_pure(self);
 655     int sf = ReadInt24_t();
 656         if (sf == 0) {
 657                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 658                         weapon_accuracy[w] = -1;
 659                 return;
 660         }
 661
 662         int f = 1;
 663         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 664                 if (sf & f) {
 665             int b = ReadByte();
 666                         if (b == 0)
 667                                 weapon_accuracy[w] = -1;
 668                         else if (b == 255)
 669                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 670                         else
 671                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 672                 }
 673                 f = (f == 0x800000) ? 1 : f * 2;
 674         }
 675 }
 676
 677 void Spawn_Draw(entity this)
 678 {
 679         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 680 }
 681
 682 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 683 {SELFPARAM();
 684         float teamnum = (ReadByte() - 1);
 685         vector spn_origin;
 686         spn_origin.x = ReadShort();
 687         spn_origin.y = ReadShort();
 688         spn_origin.z = ReadShort();
 689
 690         //if(is_new)
 691         //{
 692                 self.origin = spn_origin;
 693                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 694                 //droptofloor();
 695
 696                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 697                 {
 698                         self.mdl = "models/spawnpoint.md3";
 699                         self.colormod = Team_ColorRGB(teamnum);
 700                         precache_model(self.mdl);
 701                         setmodel(self, self.mdl);
 702                         self.drawmask = MASK_NORMAL;
 703                         //self.movetype = MOVETYPE_NOCLIP;
 704                         //self.draw = Spawn_Draw;
 705                 }*/
 706                 if(autocvar_cl_spawn_point_particles)
 707                 {
 708                         if((serverflags & SERVERFLAG_TEAMPLAY))
 709                         {
 710                                 switch(teamnum)
 711                                 {
 712                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 713                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 714                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 715                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 716                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 717                                 }
 718                         }
 719                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 720
 721                         self.draw = Spawn_Draw;
 722                 }
 723         //}
 724
 725         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 726 }
 727
 728 void Ent_ReadSpawnEvent(float is_new)
 729 {SELFPARAM();
 730         // If entnum is 0, ONLY do the local spawn actions
 731         // this way the server can disable the sending of
 732         // spawn origin or such to clients if wanted.
 733         float entnum = ReadByte();
 734
 735         if(entnum)
 736         {
 737                 self.origin_x = ReadShort();
 738                 self.origin_y = ReadShort();
 739                 self.origin_z = ReadShort();
 740
 741                 if(is_new)
 742                 {
 743                         float teamnum = GetPlayerColor(entnum - 1);
 744
 745                         if(autocvar_cl_spawn_event_particles)
 746                         {
 747                                 switch(teamnum)
 748                                 {
 749                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, self.origin, '0 0 0', 1); break;
 750                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, self.origin, '0 0 0', 1); break;
 751                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, self.origin, '0 0 0', 1); break;
 752                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, self.origin, '0 0 0', 1); break;
 753                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); break;
 754                                 }
 755                         }
 756                         if(autocvar_cl_spawn_event_sound)
 757                         {
 758                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 759                         }
 760                 }
 761         }
 762
 763         // local spawn actions
 764         if(is_new && (!entnum || (entnum == player_localentnum)))
 765         {
 766                 zoomin_effect = 1;
 767                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 768
 769                 if(autocvar_cl_unpress_zoom_on_spawn)
 770                 {
 771                         localcmd("-zoom\n");
 772                         button_zoom = false;
 773                 }
 774         }
 775         HUD_Radar_Hide_Maximized();
 776         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 777 }
 778
 779 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 780 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 781 void Ent_RadarLink();
 782 void Ent_Init();
 783 void Ent_ScoresInfo();
 784 void CSQC_Ent_Update(float bIsNewEntity)
 785 {
 786         SELFPARAM();
 787         int t = ReadByte();
 788
 789         if(autocvar_developer_csqcentities)
 790                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, this, this.entnum, this.enttype, t);
 791
 792         // set up the "time" global for received entities to be correct for interpolation purposes
 793         float savetime = time;
 794         if(servertime)
 795         {
 796                 time = servertime;
 797         }
 798         else
 799         {
 800                 serverprevtime = time;
 801                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 802                 time = serverprevtime + serverdeltatime;
 803         }
 804
 805 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 806         if(this.enttype)
 807         {
 808                 if(t != this.enttype || bIsNewEntity)
 809                 {
 810                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(this), this.entnum, this.enttype, t);
 811                         Ent_Remove();
 812                         clearentity(this);
 813                         bIsNewEntity = 1;
 814                 }
 815         }
 816         else
 817         {
 818                 if(!bIsNewEntity)
 819                 {
 820                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(this), this.entnum, t);
 821                         bIsNewEntity = 1;
 822                 }
 823         }
 824 #endif
 825         this.enttype = t;
 826         bool done = false;
 827         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 828                 it.m_read(this, bIsNewEntity);
 829                 done = true;
 830                 break;
 831         ));
 832         if (!done)
 833         switch(t)
 834         {
 835                 #define HANDLE(t) case t: this.classname = #t; this.sourceLocFile = __FILE__; this.sourceLocLine = __LINE__;
 836                 HANDLE(ENT_CLIENT_MUTATOR) {
 837                         int mutID = ReadMutator();
 838                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 839                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(this), this.classname));
 840                         break;
 841                 }
 842                 HANDLE(ENT_CLIENT_ENTCS)                                        Ent_ReadEntCS();                                                                break;
 843                 HANDLE(ENT_CLIENT_SCORES)                                       Ent_ReadPlayerScore();                                                  break;
 844                 HANDLE(ENT_CLIENT_TEAMSCORES)                           Ent_ReadTeamScore();                                                    break;
 845                 HANDLE(ENT_CLIENT_POINTPARTICLES)                       Ent_PointParticles();                                                   break;
 846                 HANDLE(ENT_CLIENT_RAINSNOW)                                     Ent_RainOrSnow();                                                               break;
 847                 HANDLE(ENT_CLIENT_LASER)                                        Ent_Laser();                                                                    break;
 848                 HANDLE(ENT_CLIENT_NAGGER)                                       Ent_Nagger();                                                                   break;
 849                 HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS)            Ent_EliminatedPlayers();                                                break;
 850                 HANDLE(ENT_CLIENT_RADARLINK)                            Ent_RadarLink();                                                                break;
 851                 HANDLE(ENT_CLIENT_PROJECTILE)                           Ent_Projectile();                                                               break;
 852                 HANDLE(ENT_CLIENT_DAMAGEINFO)                           Ent_DamageInfo(bIsNewEntity);                                   break;
 853                 HANDLE(ENT_CLIENT_INIT)                                         Ent_Init();                                                                             break;
 854                 HANDLE(ENT_CLIENT_SCORES_INFO)                          Ent_ScoresInfo();                                                               break;
 855                 HANDLE(ENT_CLIENT_MAPVOTE)                                      Ent_MapVote();                                                                  break;
 856                 HANDLE(ENT_CLIENT_CLIENTDATA)                           Ent_ClientData();                                                               break;
 857                 HANDLE(ENT_CLIENT_RANDOMSEED)                           Ent_RandomSeed();                                                               break;
 858                 HANDLE(ENT_CLIENT_WALL)                                         Ent_Wall();                                                                             break;
 859                 HANDLE(ENT_CLIENT_MODELEFFECT)                          Ent_ModelEffect(bIsNewEntity);                                  break;
 860                 HANDLE(ENT_CLIENT_TUBANOTE)                                     Ent_TubaNote(bIsNewEntity);                                             break;
 861                 HANDLE(ENT_CLIENT_WARPZONE)                                     WarpZone_Read(bIsNewEntity);                                    break;
 862                 HANDLE(ENT_CLIENT_WARPZONE_CAMERA)                      WarpZone_Camera_Read(bIsNewEntity);                             break;
 863                 HANDLE(ENT_CLIENT_WARPZONE_TELEPORTED)          WarpZone_Teleported_Read(bIsNewEntity);                 break;
 864                 HANDLE(ENT_CLIENT_TRIGGER_MUSIC)                        Ent_ReadTriggerMusic();                                                 break;
 865                 HANDLE(ENT_CLIENT_HOOK)                                         Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK);    break;
 866                 HANDLE(ENT_CLIENT_INVENTORY)                            Inventory_Read(this);                                                   break;
 867                 HANDLE(ENT_CLIENT_ARC_BEAM)                                     Ent_ReadArcBeam(bIsNewEntity);                                  break;
 868                 HANDLE(ENT_CLIENT_ACCURACY)                                     Ent_ReadAccuracy();                                                             break;
 869                 HANDLE(ENT_CLIENT_AUXILIARYXHAIR)                       Net_AuXair2(bIsNewEntity);                                              break;
 870                 HANDLE(ENT_CLIENT_TURRET)                                       ent_turret();                                                                   break;
 871                 HANDLE(ENT_CLIENT_GENERATOR)                            ent_generator();                                                                break;
 872                 HANDLE(ENT_CLIENT_CONTROLPOINT_ICON)            ent_cpicon(this);                                                               break;
 873                 HANDLE(ENT_CLIENT_MODEL)                                        CSQCModel_Read(bIsNewEntity);                                   break;
 874                 HANDLE(ENT_CLIENT_ITEM)                                         ItemRead(bIsNewEntity);                                                 break;
 875                 HANDLE(ENT_CLIENT_BUMBLE_RAYGUN)                        bumble_raygun_read(bIsNewEntity);                               break;
 876                 HANDLE(ENT_CLIENT_SPAWNPOINT)                           Ent_ReadSpawnPoint(bIsNewEntity);                               break;
 877                 HANDLE(ENT_CLIENT_SPAWNEVENT)                           Ent_ReadSpawnEvent(bIsNewEntity);                               break;
 878                 HANDLE(ENT_CLIENT_NOTIFICATION)                         Read_Notification(bIsNewEntity);                                break;
 879                 HANDLE(ENT_CLIENT_MINIGAME)                                     ent_read_minigame();                                                    break;
 880                 HANDLE(ENT_CLIENT_VIEWLOC)                                      ent_viewloc();                                                                  break;
 881                 HANDLE(ENT_CLIENT_VIEWLOC_TRIGGER)                      ent_viewloc_trigger();                                                  break;
 882                 HANDLE(ENT_CLIENT_LADDER)                                       ent_func_ladder();                                                              break;
 883                 HANDLE(ENT_CLIENT_TRIGGER_PUSH)                         ent_trigger_push();                                                             break;
 884                 HANDLE(ENT_CLIENT_TARGET_PUSH)                          ent_target_push();                                                              break;
 885                 HANDLE(ENT_CLIENT_CONVEYOR)                                     ent_conveyor();                                                                 break;
 886                 HANDLE(ENT_CLIENT_DOOR)                                         ent_door();                                                                             break;
 887                 HANDLE(ENT_CLIENT_PLAT)                                         ent_plat();                                                                             break;
 888                 HANDLE(ENT_CLIENT_SWAMP)                                        ent_swamp();                                                                    break;
 889                 HANDLE(ENT_CLIENT_CORNER)                                       ent_corner();                                                                   break;
 890                 HANDLE(ENT_CLIENT_KEYLOCK)                                      ent_keylock();                                                                  break;
 891                 HANDLE(ENT_CLIENT_TRAIN)                                        ent_train();                                                                    break;
 892                 HANDLE(ENT_CLIENT_TRIGGER_IMPULSE)                      ent_trigger_impulse();                                                  break;
 893                 #undef HANDLE
 894                 default:
 895                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), this.enttype));
 896                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", this.enttype, num_for_edict(this), this.classname));
 897                         break;
 898         }
 899
 900         time = savetime;
 901 }
 902 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 903 // used when an entity changes its type. For an entity that someone interacts
 904 // with others, make sure it can no longer do so.
 905 void Ent_Remove()
 906 {SELFPARAM();
 907         if(self.entremove)
 908                 self.entremove();
 909
 910         if(self.skeletonindex)
 911         {
 912                 skel_delete(self.skeletonindex);
 913                 self.skeletonindex = 0;
 914         }
 915
 916         if(self.snd_looping > 0)
 917         {
 918                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 919                 self.snd_looping = 0;
 920         }
 921
 922         self.enttype = 0;
 923         self.classname = "";
 924         self.draw = draw_null;
 925         self.entremove = menu_sub_null;
 926         // TODO possibly set more stuff to defaults
 927 }
 928 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 929 void CSQC_Ent_Remove()
 930 {SELFPARAM();
 931         if(autocvar_developer_csqcentities)
 932                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 933
 934         if(wasfreed(self))
 935         {
 936                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 937                 return;
 938         }
 939         if(self.enttype)
 940                 Ent_Remove();
 941         remove(self);
 942 }
 943
 944 void Gamemode_Init()
 945 {
 946         if (!isdemo())
 947         {
 948                 if(!(calledhooks & HOOK_START))
 949                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 950                 calledhooks |= HOOK_START;
 951         }
 952 }
 953 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 954 void CSQC_Parse_StuffCmd(string strMessage)
 955 {
 956         if(autocvar_developer_csqcentities)
 957                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 958
 959         localcmd(strMessage);
 960 }
 961 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 962 void CSQC_Parse_Print(string strMessage)
 963 {
 964         if(autocvar_developer_csqcentities)
 965                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 966
 967         print(ColorTranslateRGB(strMessage));
 968 }
 969
 970 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 971 void CSQC_Parse_CenterPrint(string strMessage)
 972 {
 973         if(autocvar_developer_csqcentities)
 974                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 975
 976         centerprint_hud(strMessage);
 977 }
 978
 979 string notranslate_fogcmd1 = "\nfog ";
 980 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 981 void Fog_Force()
 982 {
 983         // TODO somehow thwart prvm_globalset client ...
 984
 985         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 986                 { localcmd("\nr_drawfog 0\n"); }
 987         else if(forcefog != "")
 988                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 989 }
 990
 991 void Gamemode_Init();
 992 void Ent_ScoresInfo()
 993 {SELFPARAM();
 994     int i;
 995         make_pure(this);
 996         gametype = ReadInt24_t();
 997         HUD_ModIcons_SetFunc();
 998         for(i = 0; i < MAX_SCORE; ++i)
 999         {
1000                 if(scores_label[i])
1001                         strunzone(scores_label[i]);
1002                 scores_label[i] = strzone(ReadString());
1003                 scores_flags[i] = ReadByte();
1004         }
1005         for(i = 0; i < MAX_TEAMSCORE; ++i)
1006         {
1007                 if(teamscores_label[i])
1008                         strunzone(teamscores_label[i]);
1009                 teamscores_label[i] = strzone(ReadString());
1010                 teamscores_flags[i] = ReadByte();
1011         }
1012         HUD_InitScores();
1013         Gamemode_Init();
1014 }
1015
1016 void Ent_Init()
1017 {SELFPARAM();
1018         make_pure(this);
1019
1020         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1021
1022         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1023         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1024         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1025         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1026         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1027         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1028         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1029         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1030
1031         if(forcefog)
1032                 strunzone(forcefog);
1033         forcefog = strzone(ReadString());
1034
1035         armorblockpercent = ReadByte() / 255.0;
1036
1037         g_balance_mortar_bouncefactor = ReadCoord();
1038         g_balance_mortar_bouncestop = ReadCoord();
1039         g_balance_electro_secondary_bouncefactor = ReadCoord();
1040         g_balance_electro_secondary_bouncestop = ReadCoord();
1041
1042         vortex_scope = !ReadByte();
1043         rifle_scope = !ReadByte();
1044
1045         serverflags = ReadByte();
1046
1047         minelayer_maxmines = ReadByte();
1048
1049         hagar_maxrockets = ReadByte();
1050
1051         g_trueaim_minrange = ReadCoord();
1052         g_balance_porto_secondary = ReadByte();
1053
1054         MUTATOR_CALLHOOK(Ent_Init);
1055
1056         if(!postinit)
1057                 PostInit();
1058 }
1059
1060 void Net_ReadRace()
1061 {
1062         float b;
1063
1064         b = ReadByte();
1065
1066         switch(b)
1067         {
1068                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1069                         race_checkpoint = ReadByte();
1070                         race_time = ReadInt24_t();
1071                         race_previousbesttime = ReadInt24_t();
1072                         if(race_previousbestname)
1073                                 strunzone(race_previousbestname);
1074                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1075
1076                         race_checkpointtime = time;
1077
1078                         if(race_checkpoint == 0 || race_checkpoint == 254)
1079                         {
1080                                 race_penaltyaccumulator = 0;
1081                                 race_laptime = time; // valid
1082                         }
1083
1084                         break;
1085
1086                 case RACE_NET_CHECKPOINT_CLEAR:
1087                         race_laptime = 0;
1088                         race_checkpointtime = 0;
1089                         break;
1090
1091                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1092                         race_laptime = ReadCoord();
1093                         race_checkpointtime = -99999;
1094                         // fall through
1095                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1096                         race_nextcheckpoint = ReadByte();
1097
1098                         race_nextbesttime = ReadInt24_t();
1099                         if(race_nextbestname)
1100                                 strunzone(race_nextbestname);
1101                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1102                         break;
1103
1104                 case RACE_NET_CHECKPOINT_HIT_RACE:
1105                         race_mycheckpoint = ReadByte();
1106                         race_mycheckpointtime = time;
1107                         race_mycheckpointdelta = ReadInt24_t();
1108                         race_mycheckpointlapsdelta = ReadByte();
1109                         if(race_mycheckpointlapsdelta >= 128)
1110                                 race_mycheckpointlapsdelta -= 256;
1111                         if(race_mycheckpointenemy)
1112                                 strunzone(race_mycheckpointenemy);
1113                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1114                         break;
1115
1116                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1117                         race_othercheckpoint = ReadByte();
1118                         race_othercheckpointtime = time;
1119                         race_othercheckpointdelta = ReadInt24_t();
1120                         race_othercheckpointlapsdelta = ReadByte();
1121                         if(race_othercheckpointlapsdelta >= 128)
1122                                 race_othercheckpointlapsdelta -= 256;
1123                         if(race_othercheckpointenemy)
1124                                 strunzone(race_othercheckpointenemy);
1125                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1126                         break;
1127
1128                 case RACE_NET_PENALTY_RACE:
1129                         race_penaltyeventtime = time;
1130                         race_penaltytime = ReadShort();
1131                         //race_penaltyaccumulator += race_penaltytime;
1132                         if(race_penaltyreason)
1133                                 strunzone(race_penaltyreason);
1134                         race_penaltyreason = strzone(ReadString());
1135                         break;
1136
1137                 case RACE_NET_PENALTY_QUALIFYING:
1138                         race_penaltyeventtime = time;
1139                         race_penaltytime = ReadShort();
1140                         race_penaltyaccumulator += race_penaltytime;
1141                         if(race_penaltyreason)
1142                                 strunzone(race_penaltyreason);
1143                         race_penaltyreason = strzone(ReadString());
1144                         break;
1145
1146                 case RACE_NET_SERVER_RECORD:
1147                         race_server_record = ReadInt24_t();
1148                         break;
1149                 case RACE_NET_SPEED_AWARD:
1150                         race_speedaward = ReadInt24_t();
1151                         if(race_speedaward_holder)
1152                                 strunzone(race_speedaward_holder);
1153                         race_speedaward_holder = strzone(ReadString());
1154                         break;
1155                 case RACE_NET_SPEED_AWARD_BEST:
1156                         race_speedaward_alltimebest = ReadInt24_t();
1157                         if(race_speedaward_alltimebest_holder)
1158                                 strunzone(race_speedaward_alltimebest_holder);
1159                         race_speedaward_alltimebest_holder = strzone(ReadString());
1160                         break;
1161                 case RACE_NET_SERVER_RANKINGS:
1162                         float prevpos, del;
1163             int pos = ReadShort();
1164                         prevpos = ReadShort();
1165                         del = ReadShort();
1166
1167                         // move other rankings out of the way
1168             int i;
1169                         if (prevpos) {
1170                                 for (i=prevpos-1;i>pos-1;--i) {
1171                                         grecordtime[i] = grecordtime[i-1];
1172                                         if(grecordholder[i])
1173                                                 strunzone(grecordholder[i]);
1174                                         grecordholder[i] = strzone(grecordholder[i-1]);
1175                                 }
1176                         } else if (del) { // a record has been deleted by the admin
1177                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1178                                         if (i == RANKINGS_CNT-1) { // clear out last record
1179                                                 grecordtime[i] = 0;
1180                                                 if (grecordholder[i])
1181                                                         strunzone(grecordholder[i]);
1182                                                 grecordholder[i] = string_null;
1183                                         }
1184                                         else {
1185                                                 grecordtime[i] = grecordtime[i+1];
1186                                                 if (grecordholder[i])
1187                                                         strunzone(grecordholder[i]);
1188                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1189                                         }
1190                                 }
1191                         } else { // player has no ranked record yet
1192                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1193                                         grecordtime[i] = grecordtime[i-1];
1194                                         if(grecordholder[i])
1195                                                 strunzone(grecordholder[i]);
1196                                         grecordholder[i] = strzone(grecordholder[i-1]);
1197                                 }
1198                         }
1199
1200                         // store new ranking
1201                         if(grecordholder[pos-1] != "")
1202                                 strunzone(grecordholder[pos-1]);
1203                         grecordholder[pos-1] = strzone(ReadString());
1204                         grecordtime[pos-1] = ReadInt24_t();
1205                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1206                                 race_myrank = pos;
1207                         break;
1208                 case RACE_NET_SERVER_STATUS:
1209                         race_status = ReadShort();
1210                         if(race_status_name)
1211                                 strunzone(race_status_name);
1212                         race_status_name = strzone(ReadString());
1213         }
1214 }
1215
1216 void Net_TeamNagger()
1217 {
1218         teamnagger = 1;
1219 }
1220
1221 void Net_ReadPingPLReport()
1222 {
1223         int e, pi, pl, ml;
1224         e = ReadByte();
1225         pi = ReadShort();
1226         pl = ReadByte();
1227         ml = ReadByte();
1228         if (!(playerslots[e]))
1229                 return;
1230         playerslots[e].ping = pi;
1231         playerslots[e].ping_packetloss = pl / 255.0;
1232         playerslots[e].ping_movementloss = ml / 255.0;
1233 }
1234
1235 void Net_WeaponComplain()
1236 {
1237         complain_weapon = ReadByte();
1238
1239         if(complain_weapon_name)
1240                 strunzone(complain_weapon_name);
1241         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1242
1243         complain_weapon_type = ReadByte();
1244
1245         complain_weapon_time = time;
1246         weapontime = time; // ping the weapon panel
1247
1248         switch(complain_weapon_type)
1249         {
1250                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1251                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1252                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1253         }
1254 }
1255
1256 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1257 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1258 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1259 bool CSQC_Parse_TempEntity()
1260 {
1261         // Acquire TE ID
1262         int nTEID = ReadByte();
1263
1264         if (autocvar_developer_csqcentities)
1265                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1266
1267         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
1268                 it.m_read(NULL, true);
1269                 return true;
1270         ));
1271         switch (nTEID)
1272         {
1273                 case TE_CSQC_MUTATOR:
1274                         int mutID = ReadMutator();
1275                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1276                         return true;
1277                 case TE_CSQC_TARGET_MUSIC:
1278                         Net_TargetMusic();
1279                         return true;
1280                 case TE_CSQC_PICTURE:
1281                         Net_MapVote_Picture();
1282                         return true;
1283                 case TE_CSQC_RACE:
1284                         Net_ReadRace();
1285                         return true;
1286                 case TE_CSQC_VORTEXBEAMPARTICLE:
1287                         Net_ReadVortexBeamParticle();
1288                         return true;
1289                 case TE_CSQC_TEAMNAGGER:
1290                         Net_TeamNagger();
1291                         return true;
1292                 case TE_CSQC_ARC:
1293                         Net_ReadArc();
1294                         return true;
1295                 case TE_CSQC_PINGPLREPORT:
1296                         Net_ReadPingPLReport();
1297                         return true;
1298                 case TE_CSQC_WEAPONCOMPLAIN:
1299                         Net_WeaponComplain();
1300                         return true;
1301                 case TE_CSQC_VEHICLESETUP:
1302                         Net_VehicleSetup();
1303                         return true;
1304                 case TE_CSQC_SVNOTICE:
1305                         cl_notice_read();
1306                         return true;
1307                 case TE_CSQC_SHOCKWAVEPARTICLE:
1308                         Net_ReadShockwaveParticle();
1309                         return true;
1310                 default:
1311                         // No special logic for this temporary entity; return 0 so the engine can handle it
1312                         return false;
1313         }
1314 }
1315
1316 string getcommandkey(string text, string command)
1317 {
1318         string keys;
1319         float n, j, k, l = 0;
1320
1321         if (!autocvar_hud_showbinds)
1322                 return text;
1323
1324         keys = db_get(binddb, command);
1325         if (keys == "")
1326         {
1327                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1328                 for(j = 0; j < n; ++j)
1329                 {
1330                         k = stof(argv(j));
1331                         if(k != -1)
1332                         {
1333                                 if ("" == keys)
1334                                         keys = keynumtostring(k);
1335                                 else
1336                                         keys = strcat(keys, ", ", keynumtostring(k));
1337
1338                                 ++l;
1339                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1340                                         break;
1341                         }
1342
1343                 }
1344                 if (keys == "")
1345                         keys = "NO_KEY";
1346                 db_put(binddb, command, keys);
1347         }
1348
1349         if (keys == "NO_KEY") {
1350                 if (autocvar_hud_showbinds > 1)
1351                         return sprintf(_("%s (not bound)"), text);
1352                 else
1353                         return text;
1354         }
1355         else if (autocvar_hud_showbinds > 1)
1356                 return sprintf("%s (%s)", text, keys);
1357         else
1358                 return keys;
1359 }