Fix #2175 "Gametype voting screen broken at connect"
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / mapvoting.qc
1 #include "mapvoting.qh"
2
3 #include "autocvars.qh"
4 #include "miscfunctions.qh"
5 #include "defs.qh"
6 #include "hud/_mod.qh"
7 #include "hud/panel/scoreboard.qh"
8
9 #include <common/mapinfo.qh>
10
11
12 int mv_num_maps;
13
14 string mv_maps[MAPVOTE_COUNT];
15 string mv_pics[MAPVOTE_COUNT];
16 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
17 string mv_desc[MAPVOTE_COUNT];
18 float mv_preview[MAPVOTE_COUNT];
19 float mv_votes[MAPVOTE_COUNT];
20 float mv_flags[MAPVOTE_COUNT];
21 float mv_flags_start[MAPVOTE_COUNT];
22 entity mv_pk3list;
23 float mv_abstain;
24 float mv_ownvote;
25 float mv_detail;
26 float mv_timeout;
27 float mv_top2_time;
28 float mv_top2_alpha;
29
30 int mv_selection;
31 int mv_columns;
32 int mv_mouse_selection;
33 int mv_selection_keyboard;
34
35 float gametypevote;
36 string mapvote_chosenmap;
37 vector gtv_text_size;
38 vector gtv_text_size_small;
39
40 const int NUM_SSDIRS = 4;
41 string ssdirs[NUM_SSDIRS];
42 int n_ssdirs;
43
44 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
45 {
46         TC(int, id);
47         string pre, post;
48         pre = sprintf("%d. ", id+1);
49         if(mv_detail)
50         {
51                 if(_count == 1)
52                         post = _(" (1 vote)");
53                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
54                         post = sprintf(_(" (%d votes)"), _count);
55                 else
56                         post = "";
57         }
58         else
59                 post = "";
60         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
61         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
62         return strcat(pre, map, post);
63 }
64
65 vector MapVote_RGB(int id)
66 {
67         TC(int, id);
68         if(!(mv_flags[id] & GTV_AVAILABLE))
69                 return '1 1 1';
70         if(id == mv_ownvote)
71                 return '0 1 0';
72         else if (id == mv_selection)
73                 return '1 1 0';
74         else
75                 return '1 1 1';
76 }
77
78 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
79 {
80         TC(int, id);
81         // Find the correct alpha
82         float alpha;
83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
84                 alpha = 0.2; // The gametype isn't supported by the map
85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
87         else
88                 alpha = 1; // Normal, full alpha
89         alpha *= panel_fg_alpha;
90
91         // Bounding box details
92         float rect_margin = hud_fontsize.y / 2;
93
94         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
95         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
96         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
97         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
98
99         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
100         vector rect_size = '1 1 0';
101         rect_size.x = tsize + rect_margin;
102         rect_size.y = maxh + rect_margin;
103
104         // Highlight selected item
105         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
106         {
107                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
108         }
109
110         // Highlight current vote
111         vector rgb = MapVote_RGB(id);
112         if(id == mv_ownvote)
113         {
114                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
115                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
116         }
117
118         vector offset = pos;
119
120         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
121         pos.y += title_gap;
122         maxh -= title_gap;
123
124         // Evaluate the image size
125         vector image_size = '1 1 0' * gtv_text_size.x * 3;
126         if ( maxh < image_size.y )
127                 image_size = '1 1 0' * maxh;
128         image_size *= 0.8;
129         float desc_padding = gtv_text_size.x * 0.6;
130         pos.x += image_size.x + desc_padding;
131         tsize -= image_size.x + desc_padding;
132
133         // Split the description into lines
134         entity title;
135         title = spawn();
136         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
137
138         string thelabel = mv_desc[id], ts;
139         entity last = title;
140         entity next = NULL;
141         float nlines = 0;
142         if( thelabel != "")
143         {
144                 float i,n = tokenizebyseparator(thelabel, "\n");
145                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
146                 {
147                         getWrappedLine_remaining = argv(i);
148                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
149                         {
150                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
151                                 if (ts != "")
152                                 {
153                                         next = spawn();
154                                         next.message = ts;
155                                         next.origin = pos-offset;
156                                         last.chain = next;
157                                         last = next;
158                                         pos.y += gtv_text_size_small.y;
159                                         nlines++;
160                                 }
161                         }
162                 }
163         }
164
165         // Center the contents in the bounding box
166         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
167         if ( maxh > 0 )
168                 offset.y += maxh/2;
169
170         // Draw the title
171         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
172
173         // Draw the icon
174         if(pic != "")
175                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
176
177         // Draw the description
178         for ( last = title.chain; last ; )
179         {
180                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
181                 next = last;
182                 last = last.chain;
183                 delete(next);
184         }
185
186         // Cleanup
187         delete(title);
188 }
189
190 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
191 {
192         TC(int, id);
193         vector img_size = '0 0 0';
194         string label;
195         float text_size;
196
197         float rect_margin = hud_fontsize.y / 2;
198
199         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
200         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
201         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
202         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
203
204         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
205         vector rect_size = '1 1 0';
206         rect_size.x = tsize + rect_margin;
207         rect_size.y = isize + rect_margin;
208
209         float img_ar = 4/3;
210         img_size.x = min(tsize, isize * img_ar);
211         img_size.y = img_size.x / img_ar;
212         img_size.y -= hud_fontsize.y;
213         img_size.x = img_size.y * img_ar;
214
215         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
216
217         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
218
219         text_size = stringwidth(label, false, hud_fontsize);
220
221         float save_rect_sizex = rect_size.x;
222         rect_size.x = max(img_size.x, text_size) + rect_margin;
223         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
224
225         vector text_pos = '0 0 0';
226         text_pos.x = pos.x + (tsize - text_size) / 2;
227         text_pos.y = pos.y + img_size.y;
228
229         pos.x += (tsize - img_size.x) / 2;
230
231         float theAlpha;
232         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
233                 theAlpha = mv_top2_alpha;
234         else
235                 theAlpha = 1;
236         theAlpha *= panel_fg_alpha;
237
238         // Highlight selected item
239         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
240                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
241
242         // Highlight current vote
243         vector rgb = MapVote_RGB(id);
244         if(id == mv_ownvote)
245         {
246                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
247                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
248         }
249
250         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
251
252         if(pic == "")
253         {
254                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
255         }
256         else
257         {
258                 if(drawgetimagesize(pic) == '0 0 0')
259                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
260                 else
261                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
262         }
263 }
264
265 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
266 {
267         TC(int, id);
268         vector rgb;
269         float text_size;
270         string label;
271
272         rgb = MapVote_RGB(id);
273
274         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
275
276         text_size = stringwidth(label, false, hud_fontsize);
277
278         pos.x -= text_size*0.5;
279         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
280 }
281
282 vector MapVote_GridVec(vector gridspec, int i, int m)
283 {
284         TC(int, i); TC(int, m);
285         int r = i % m;
286         return
287                 '1 0 0' * (gridspec.x * r)
288                 +
289                 '0 1 0' * (gridspec.y * (i - r) / m);
290 }
291
292 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
293 {
294
295         float c, r;
296
297         mv_mouse_selection = -1;
298
299         for (r = 0; r < rows; ++r)
300                 for (c = 0; c < columns; ++c)
301                 {
302                         if (mousepos.x >= topleft.x + cellsize.x *  c &&
303                                 mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
304                                 mousepos.y >= topleft.y + cellsize.y *  r &&
305                                 mousepos.y <= topleft.y + cellsize.y * (r + 1))
306                         {
307                                 mv_mouse_selection = r * columns + c;
308                                 break;
309                         }
310                 }
311
312         if (mv_mouse_selection >= mv_num_maps)
313                 mv_mouse_selection = -1;
314
315         if (mv_abstain && mv_mouse_selection < 0)
316                 mv_mouse_selection = mv_num_maps;
317
318         if ( mv_selection_keyboard )
319                 return mv_selection;
320
321         return mv_mouse_selection;
322 }
323
324 vector prev_mousepos;
325 void MapVote_Draw()
326 {
327         string map;
328         int i;
329         float tmp;
330         vector pos;
331         float center;
332         float rows;
333         vector dist = '0 0 0';
334
335         //if(intermission != 2) return;
336         if(!mv_active)
337                 return;
338
339         HUD_Panel_LoadCvars();
340
341         if (!autocvar_hud_cursormode)
342         {
343                 if (mousepos.x != prev_mousepos.x || mousepos.y != prev_mousepos.y)
344                 {
345                         mv_selection_keyboard = 0;
346                         prev_mousepos = mousepos;
347                 }
348         }
349
350         center = (vid_conwidth - 1)/2;
351         xmin = vid_conwidth * 0.08;
352         xmax = vid_conwidth - xmin;
353         ymin = 20;
354         ymax = vid_conheight - ymin;
355
356         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
357                 ymin += chat_sizey;
358         else
359                 ymax -= chat_sizey;
360
361         hud_fontsize = HUD_GetFontsize("hud_fontsize");
362         if (gametypevote)
363         {
364                 gtv_text_size = hud_fontsize * 1.4;
365                 gtv_text_size_small = hud_fontsize * 1.1;
366         }
367
368         pos.y = ymin;
369         pos.z = 0;
370
371         HUD_Scale_Disable();
372         draw_beginBoldFont();
373
374         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
375         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
376         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
377         pos.y += hud_fontsize.y * 2;
378
379         if( mapvote_chosenmap != "" )
380         {
381                 pos.y += hud_fontsize.y * 0.25;
382                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
383                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
384                 pos.y += hud_fontsize.y * 1.5;
385         }
386         pos.y += hud_fontsize.y * 0.5;
387
388         draw_endBoldFont();
389
390         i = ceil(max(0, mv_timeout - time));
391         map = sprintf(_("%d seconds left"), i);
392         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
393         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
394         pos.y += hud_fontsize.y * 1.5;
395         pos.y += hud_fontsize.y * 0.5;
396
397         // base for multi-column stuff...
398         pos.y += hud_fontsize.y;
399         pos.x = xmin;
400         ymin = pos.y;
401         float abstain_spacing = panel_bg_border + hud_fontsize.y;
402         if(mv_abstain)
403         {
404                 mv_num_maps -= 1;
405                 ymax -= abstain_spacing;
406         }
407
408         // higher than the image itself ratio for mapvote items to reserve space for long map names
409         int item_aspect = (gametypevote) ? 3/1 : 5/3;
410         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, vec2(xmax - xmin, ymax - ymin), item_aspect);
411         mv_columns = table_size.x;
412         rows = table_size.y;
413
414         dist.x = (xmax - xmin) / mv_columns;
415         dist.y = (ymax - pos.y) / rows;
416
417         // reduce size of too wide items
418         tmp = vid_conwidth / 3; // max width
419         if(dist.x > tmp)
420         {
421                 dist.x = tmp;
422                 dist.y = min(dist.y, dist.x / item_aspect);
423         }
424         tmp = vid_conheight / 3; // max height
425         if(dist.y > tmp)
426         {
427                 dist.y = tmp;
428                 dist.x = min(dist.x, dist.y * item_aspect);
429         }
430
431         // reduce size to fix aspect ratio
432         if(dist.x / dist.y > item_aspect)
433                 dist.x = dist.y * item_aspect;
434         else
435                 dist.y = dist.x / item_aspect;
436
437         // adjust table pos and size according to the new size
438         float offset;
439         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
440         xmin = pos.x += offset;
441         xmax -= offset;
442         offset = ((ymax - pos.y) - dist.y * rows) / 2;
443         ymax -= 2 * offset;
444
445         // override panel_pos and panel_size
446         panel_pos.x = pos.x;
447         panel_pos.y = pos.y;
448         panel_size.x = xmax - xmin;
449         panel_size.y = ymax - ymin;
450         HUD_Panel_DrawBg();
451
452         if(panel_bg_padding)
453         {
454                 // FIXME item AR gets slightly changed here...
455                 // it's rather hard to avoid it at this point
456                 dist.x -= 2 * panel_bg_padding / mv_columns;
457                 dist.y -= 2 * panel_bg_padding / rows;
458                 xmin = pos.x += panel_bg_padding;
459                 ymin = pos.y += panel_bg_padding;
460                 xmax -= 2 * panel_bg_padding;
461                 ymax -= 2 * panel_bg_padding;
462         }
463
464         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
465
466         if (mv_top2_time)
467                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
468
469         void (vector, float, float, string, string, float, float) DrawItem;
470
471         if(gametypevote)
472                 DrawItem = GameTypeVote_DrawGameTypeItem;
473         else
474                 DrawItem = MapVote_DrawMapItem;
475
476         for(i = 0; i < mv_num_maps; ++i)
477         {
478                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
479                 map = mv_maps[i];
480                 if(mv_preview[i])
481                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
482                 else
483                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
484         }
485
486         if(mv_abstain)
487                 ++mv_num_maps;
488
489         if(mv_abstain && i < mv_num_maps) {
490                 tmp = mv_votes[i];
491                 pos.y = ymax + abstain_spacing;
492                 pos.x = (xmax+xmin)*0.5;
493                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
494         }
495 }
496
497 void Cmd_MapVote_MapDownload(int argc)
498 {
499         TC(int, argc);
500         entity pak;
501
502         if(argc != 2 || !mv_pk3list)
503         {
504                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!"));
505                 return;
506         }
507
508         int id = stof(argv(1));
509         for(pak = mv_pk3list; pak; pak = pak.chain)
510                 if(pak.sv_entnum == id)
511                         break;
512
513         if(!pak || pak.sv_entnum != id) {
514                 LOG_INFO(_("^1Error:^7 Couldn't find pak index."));
515                 return;
516         }
517
518         if(PreviewExists(pak.message))
519         {
520                 mv_preview[id] = true;
521                 return;
522         } else {
523                 LOG_INFO(_("Requesting preview..."));
524                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
525         }
526 }
527
528 void MapVote_CheckPK3(string pic, string pk3, int id)
529 {
530         TC(int, id);
531         entity pak;
532         pak = spawn();
533         pak.netname = pk3;
534         pak.message = pic;
535         pak.sv_entnum = id;
536
537         pak.chain = mv_pk3list;
538         mv_pk3list = pak;
539
540         if(pk3 != "")
541         {
542                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
543         }
544         else
545         {
546                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
547         }
548 }
549
550 void MapVote_CheckPic(string pic, string pk3, int id)
551 {
552         TC(int, id);
553         // never try to retrieve a pic for the "don't care" 'map'
554         if(mv_abstain && id == mv_num_maps - 1)
555                 return;
556
557         if(PreviewExists(pic))
558         {
559                 mv_preview[id] = true;
560                 return;
561         }
562         MapVote_CheckPK3(pic, pk3, id);
563 }
564
565 void MapVote_ReadMask()
566 {
567         int i;
568         if ( mv_num_maps < 24 )
569         {
570                 int mask;
571                 if(mv_num_maps < 8)
572                         mask = ReadByte();
573                 else if(mv_num_maps < 16)
574                         mask = ReadShort();
575                 else
576                         mask = ReadLong();
577
578                 for(i = 0; i < mv_num_maps; ++i)
579                 {
580                         if (mask & BIT(i))
581                                 mv_flags[i] |= GTV_AVAILABLE;
582                         else
583                                 mv_flags[i] &= ~GTV_AVAILABLE;
584                 }
585         }
586         else
587         {
588                 for(i = 0; i < mv_num_maps; ++i )
589                         mv_flags[i] = ReadByte();
590         }
591 }
592
593 void MapVote_ReadOption(int i)
594 {
595         TC(int, i);
596         string map = strzone(ReadString());
597         string pk3 = strzone(ReadString());
598         int j = bound(0, ReadByte(), n_ssdirs - 1);
599
600         mv_maps[i] = map;
601         mv_pk3[i] = pk3;
602         mv_flags[i] = GTV_AVAILABLE;
603
604         string pic = strzone(strcat(ssdirs[j], "/", map));
605         mv_pics[i] = pic;
606         mv_preview[i] = false;
607         MapVote_CheckPic(pic, pk3, i);
608 }
609
610 void GameTypeVote_ReadOption(int i)
611 {
612         TC(int, i);
613         string gt = strzone(ReadString());
614
615         mv_maps[i] = gt;
616         mv_flags[i] = ReadByte();
617
618         string basetype = "";
619
620         if ( mv_flags[i] & GTV_CUSTOM )
621         {
622                 string name = ReadString();
623                 if ( strlen(name) < 1 )
624                         name = gt;
625                 mv_pk3[i] = strzone(name);
626                 mv_desc[i] = strzone(ReadString());
627                 basetype = strzone(ReadString());
628         }
629         else
630         {
631                 Gametype type = MapInfo_Type_FromString(gt);
632                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
633                 mv_desc[i] = MapInfo_Type_Description(type);
634         }
635
636         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
637         if(precache_pic(mv_picpath) == "")
638         {
639                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
640                 if(precache_pic(mv_picpath) == "")
641                 {
642                         mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, basetype);
643                         if(precache_pic(mv_picpath) == "")
644                         {
645                                 mv_picpath = strcat("gfx/menu/default/gametype_", basetype);
646                         }
647                 }
648         }
649         string pic = strzone(mv_picpath);
650         mv_pics[i] = pic;
651         mv_preview[i] = PreviewExists(pic);
652 }
653
654 void MapVote_Init()
655 {
656         mv_active = 1;
657         if(!autocvar_hud_cursormode) mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
658         mv_selection = -1;
659         mv_selection_keyboard = 0;
660
661         string s;
662         for(n_ssdirs = 0; ; ++n_ssdirs)
663         {
664                 s = ReadString();
665                 if(s == "")
666                         break;
667                 if(n_ssdirs < NUM_SSDIRS)
668                         ssdirs[n_ssdirs] = s;
669         }
670         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
671
672         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
673         mv_abstain = ReadByte();
674         if(mv_abstain)
675                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
676         mv_detail = ReadByte();
677
678         mv_ownvote = -1;
679         mv_timeout = ReadCoord();
680
681         gametypevote = ReadByte();
682
683         if(gametypevote)
684         {
685                 mapvote_chosenmap = strzone(ReadString());
686                 if ( gametypevote == 2 )
687                         gametypevote = 0;
688         }
689
690         MapVote_ReadMask();
691         int i;
692         for(i = 0; i < mv_num_maps; ++i )
693                 mv_flags_start[i] = mv_flags[i];
694
695         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
696         mv_pk3list = NULL; // I'm still paranoid!
697
698         for(i = 0; i < mv_num_maps; ++i)
699         {
700                 mv_votes[i] = 0;
701
702                 if ( gametypevote )
703                         GameTypeVote_ReadOption(i);
704                 else
705                         MapVote_ReadOption(i);
706         }
707
708         for(i = 0; i < n_ssdirs; ++i)
709                 ssdirs[n_ssdirs] = string_null;
710         n_ssdirs = 0;
711 }
712
713 void MapVote_SendChoice(int index)
714 {
715         TC(int, index);
716         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
717 }
718
719 int MapVote_MoveLeft(int pos)
720 {
721         TC(int, pos);
722         int imp;
723         if ( pos < 0 )
724                 imp = mv_num_maps - 1;
725         else
726                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
727         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
728                 imp = MapVote_MoveLeft(imp);
729         return imp;
730 }
731 int MapVote_MoveRight(int pos)
732 {
733         TC(int, pos);
734         int imp;
735         if ( pos < 0 )
736                 imp = 0;
737         else
738                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
739         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
740                 imp = MapVote_MoveRight(imp);
741         return imp;
742 }
743 int MapVote_MoveUp(int pos)
744 {
745         TC(int, pos);
746         int imp;
747         if ( pos < 0 )
748                 imp = mv_num_maps - 1;
749         else
750         {
751                 imp = pos - mv_columns;
752                 if ( imp < 0 )
753                 {
754                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
755                         if ( imp >= mv_num_maps )
756                                 imp -= mv_columns;
757                 }
758         }
759         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
760                 imp = MapVote_MoveUp(imp);
761         return imp;
762 }
763 int MapVote_MoveDown(int pos)
764 {
765         TC(int, pos);
766         int imp;
767         if ( pos < 0 )
768                 imp = 0;
769         else
770         {
771                 imp = pos + mv_columns;
772                 if ( imp >= mv_num_maps )
773                         imp = imp % mv_columns;
774         }
775         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
776                 imp = MapVote_MoveDown(imp);
777         return imp;
778 }
779
780 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
781 {
782         TC(int, bInputType);
783         float imp;
784
785         if (!mv_active)
786                 return false;
787
788         if(bInputType == 3)
789         {
790                 mousepos.x = nPrimary;
791                 mousepos.y = nSecondary;
792                 mv_selection_keyboard = 0;
793                 return true;
794         }
795
796         if (bInputType != 0)
797                 return false;
798
799         if ('0' <= nPrimary && nPrimary <= '9')
800         {
801                 imp = nPrimary - '0';
802                 if (imp == 0) imp = 10;
803                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
804                 return true;
805         }
806         switch(nPrimary)
807         {
808                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
809                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
810                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
811                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
812                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
813                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
814                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
815                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
816                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
817                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
818
819                 case K_RIGHTARROW:
820                         mv_selection_keyboard = 1;
821                         mv_selection = MapVote_MoveRight(mv_selection);
822                         return true;
823                 case K_LEFTARROW:
824                         mv_selection_keyboard = 1;
825                         mv_selection = MapVote_MoveLeft(mv_selection);
826                         return true;
827                 case K_DOWNARROW:
828                         mv_selection_keyboard = 1;
829                         mv_selection = MapVote_MoveDown(mv_selection);
830                         return true;
831                 case K_UPARROW:
832                         mv_selection_keyboard = 1;
833                         mv_selection = MapVote_MoveUp(mv_selection);
834                         return true;
835                 case K_KP_ENTER:
836                 case K_ENTER:
837                 case K_SPACE:
838                         if ( mv_selection_keyboard )
839                                 MapVote_SendChoice(mv_selection);
840                         return true;
841         }
842
843         if (nPrimary == K_MOUSE1)
844         {
845                 mv_selection_keyboard = 0;
846                 mv_selection = mv_mouse_selection;
847                 if (mv_selection >= 0)
848                 {
849                         imp = min(mv_selection + 1, mv_num_maps);
850                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
851                         return true;
852                 }
853         }
854
855         return false;
856 }
857
858 void MapVote_UpdateMask()
859 {
860         MapVote_ReadMask();
861         mv_top2_time = time;
862 }
863
864 void MapVote_UpdateVotes()
865 {
866         int i;
867         for(i = 0; i < mv_num_maps; ++i)
868         {
869                 if(mv_flags[i] & GTV_AVAILABLE)
870                 {
871                         if(mv_detail)
872                                 mv_votes[i] = ReadByte();
873                         else
874                                 mv_votes[i] = 0;
875                 }
876                 else
877                         mv_votes[i] = -1;
878         }
879
880         mv_ownvote = ReadByte()-1;
881 }
882
883 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
884 {
885         make_pure(this);
886         int sf = ReadByte();
887         return = true;
888
889         if(sf & 1)
890                 MapVote_Init();
891
892         if(sf & 2)
893                 MapVote_UpdateMask();
894
895         if(sf & 4)
896                 MapVote_UpdateVotes();
897 }
898
899 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
900 {
901         Net_MapVote_Picture();
902         return true;
903 }
904
905 void Net_MapVote_Picture()
906 {
907         int type = ReadByte();
908         mv_preview[type] = true;
909         mv_pics[type] = strzone(ReadPicture());
910 }