qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 float mv_active;
  16 string mv_maps[MAPVOTE_COUNT];
  17 string mv_pics[MAPVOTE_COUNT];
  18 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  19 string mv_desc[MAPVOTE_COUNT];
  20 float mv_preview[MAPVOTE_COUNT];
  21 float mv_votes[MAPVOTE_COUNT];
  22 float mv_flags[MAPVOTE_COUNT];
  23 float mv_flags_start[MAPVOTE_COUNT];
  24 entity mv_pk3list;
  25 float mv_abstain;
  26 float mv_ownvote;
  27 float mv_detail;
  28 float mv_timeout;
  29 float mv_top2_time;
  30 float mv_top2_alpha;
  31
  32 vector mv_mousepos;
  33 int mv_selection;
  34 int mv_columns;
  35 int mv_mouse_selection;
  36 int mv_selection_keyboard;
  37
  38 float gametypevote;
  39 string mapvote_chosenmap;
  40 vector gtv_text_size;
  41 vector gtv_text_size_small;
  42
  43 const int NUM_SSDIRS = 4;
  44 string ssdirs[NUM_SSDIRS];
  45 int n_ssdirs;
  46
  47 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  48 {
  49         string pre, post;
  50         pre = sprintf("%d. ", id+1);
  51         if(mv_detail)
  52         {
  53                 if(_count == 1)
  54                         post = _(" (1 vote)");
  55                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  56                         post = sprintf(_(" (%d votes)"), _count);
  57                 else
  58                         post = "";
  59         }
  60         else
  61                 post = "";
  62         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  63         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  64         return strcat(pre, map, post);
  65 }
  66
  67 vector MapVote_RGB(int id)
  68 {
  69         if(!(mv_flags[id] & GTV_AVAILABLE))
  70                 return '1 1 1';
  71         if(id == mv_ownvote)
  72                 return '0 1 0';
  73         else if (id == mv_selection)
  74                 return '1 1 0';
  75         else
  76                 return '1 1 1';
  77 }
  78
  79 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  80 {
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89
  90         // Bounding box details
  91         float rect_margin = hud_fontsize.y / 2;
  92         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  93         vector rect_size = '1 1 0';
  94         rect_size.x = tsize + rect_margin;
  95         rect_size.y = maxh + rect_margin;
  96
  97         // Highlight selected item
  98         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
  99         {
 100                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 101         }
 102
 103         // Highlight current vote
 104         vector rgb = MapVote_RGB(id);
 105         if(id == mv_ownvote)
 106         {
 107                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 108                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 109         }
 110
 111         vector offset = pos;
 112
 113         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 114         pos.y += title_gap;
 115         maxh -= title_gap;
 116
 117         // Evaluate the image size
 118         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 119         if ( maxh < image_size.y )
 120                 image_size = '1 1 0' * maxh;
 121         image_size *= 0.8;
 122         float desc_padding = gtv_text_size.x * 0.6;
 123         pos.x += image_size.x + desc_padding;
 124         tsize -= image_size.x + desc_padding;
 125
 126         // Split the description into lines
 127         entity title;
 128         title = spawn();
 129         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 130
 131         string thelabel = mv_desc[id], ts;
 132         entity last = title;
 133         entity next = world;
 134         float nlines = 0;
 135         if( thelabel != "")
 136         {
 137                 float i,n = tokenizebyseparator(thelabel, "\n");
 138                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 139                 {
 140                         getWrappedLine_remaining = argv(i);
 141                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 142                         {
 143                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 144                                 if (ts != "")
 145                                 {
 146                                         next = spawn();
 147                                         next.message = ts;
 148                                         next.origin = pos-offset;
 149                                         last.chain = next;
 150                                         last = next;
 151                                         pos.y += gtv_text_size_small.y;
 152                                         nlines++;
 153                                 }
 154                         }
 155                 }
 156         }
 157
 158         // Center the contents in the bounding box
 159         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 160         if ( maxh > 0 )
 161                 offset.y += maxh/2;
 162
 163         // Draw the title
 164         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 165
 166         // Draw the icon
 167         if(pic != "")
 168                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 169
 170         // Draw the description
 171         for ( last = title.chain; last ; )
 172         {
 173                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 174                 next = last;
 175                 last = last.chain;
 176                 remove(next);
 177         }
 178
 179         // Cleanup
 180         remove(title);
 181 }
 182
 183 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 184 {
 185         vector img_size = '0 0 0';
 186         vector rgb;
 187         string label;
 188         float text_size;
 189
 190         isize -= hud_fontsize.y; // respect the text when calculating the image size
 191
 192         rgb = MapVote_RGB(id);
 193
 194         img_size.y = isize;
 195         img_size.x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
 196
 197         pos.y = pos.y + img_size.y;
 198
 199         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 200
 201         text_size = stringwidth(label, false, hud_fontsize);
 202
 203         float theAlpha;
 204         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 205                 theAlpha = mv_top2_alpha;
 206         else
 207                 theAlpha = 1;
 208
 209         pos.x -= text_size*0.5;
 210         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 211
 212         pos.x = pos.x + text_size*0.5 - img_size.x*0.5;
 213         pos.y = pos.y - img_size.y;
 214
 215         pos += autocvar_scoreboard_border_thickness * '1 1 0';
 216         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
 217         if(pic == "")
 218         {
 219                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 220         }
 221         else
 222         {
 223                 if(drawgetimagesize(pic) == '0 0 0')
 224                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 225                 else
 226                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 227         }
 228
 229         if(id == mv_ownvote)
 230                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 231         else
 232                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 233
 234         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 235                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 236 }
 237
 238 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 239 {
 240         vector rgb;
 241         float text_size;
 242         string label;
 243
 244         rgb = MapVote_RGB(id);
 245
 246         pos.y = pos.y + hud_fontsize.y;
 247
 248         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 249
 250         text_size = stringwidth(label, false, hud_fontsize);
 251
 252         pos.x -= text_size*0.5;
 253         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 254 }
 255
 256 vector MapVote_GridVec(vector gridspec, int i, int m)
 257 {
 258         int r = i % m;
 259         return
 260                 '1 0 0' * (gridspec.x * r)
 261                 +
 262                 '0 1 0' * (gridspec.y * (i - r) / m);
 263 }
 264
 265 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 266 {
 267
 268         float c, r;
 269
 270         mv_mouse_selection = -1;
 271
 272         for (r = 0; r < rows; ++r)
 273                 for (c = 0; c < columns; ++c)
 274                 {
 275                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 276                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 277                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 278                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 279                         {
 280                                 mv_mouse_selection = r * columns + c;
 281                                 break;
 282                         }
 283                 }
 284
 285         if (mv_mouse_selection >= mv_num_maps)
 286                 mv_mouse_selection = -1;
 287
 288         if (mv_abstain && mv_mouse_selection < 0)
 289                 mv_mouse_selection = mv_num_maps;
 290
 291         if ( mv_selection_keyboard )
 292                 return mv_selection;
 293
 294         return mv_mouse_selection;
 295 }
 296
 297 void MapVote_Draw()
 298 {
 299         string map;
 300         int i;
 301         float tmp;
 302         vector pos;
 303         float isize;
 304         float center;
 305         float rows;
 306         float tsize;
 307         vector dist = '0 0 0';
 308
 309         if(!mv_active)
 310                 return;
 311
 312         if (!autocvar_hud_cursormode)
 313         {
 314                 vector mpos = mv_mousepos + getmousepos();
 315                 mpos.x = bound(0, mpos.x, vid_conwidth);
 316                 mpos.y = bound(0, mpos.y, vid_conheight);
 317
 318                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 319                         mv_selection_keyboard = 0;
 320                 mv_mousepos = mpos;
 321
 322         }
 323
 324         center = (vid_conwidth - 1)/2;
 325         xmin = vid_conwidth*0.05; // 5% border must suffice
 326         xmax = vid_conwidth - xmin;
 327         ymin = 20;
 328         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 329         if(i < 0)
 330                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 331         if(i >= 0 || ymax < (vid_conheight*0.5))
 332                 ymax = vid_conheight - ymin;
 333
 334         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 335
 336         pos.y = ymin;
 337         pos.z = 0;
 338
 339         draw_beginBoldFont();
 340         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 341         pos.x = center - stringwidth(map, false, '12 0 0');
 342         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 343         pos.y += 26;
 344
 345         if( mapvote_chosenmap != "" )
 346         {
 347                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize*1.5/2);
 348                 drawstring(pos, mapvote_chosenmap, hud_fontsize*1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 349                 pos.y += hud_fontsize.y*2;
 350         }
 351
 352         i = ceil(max(0, mv_timeout - time));
 353         map = sprintf(_("%d seconds left"), i);
 354         pos.x = center - stringwidth(map, false, '8 0 0');
 355         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 356         pos.y += 22;
 357         pos.x = xmin;
 358         draw_endBoldFont();
 359
 360         // base for multi-column stuff...
 361         ymin = pos.y;
 362         if(mv_abstain)
 363                 mv_num_maps -= 1;
 364
 365         rows = ceil(mv_num_maps / mv_columns);
 366
 367         dist.x = (xmax - xmin) / mv_columns;
 368         dist.y = (ymax - pos.y) / rows;
 369
 370         if ( gametypevote )
 371         {
 372                 tsize = dist.x - hud_fontsize.y;
 373                 isize = dist.y;
 374                 float maxheight = (ymax - pos.y) / 3;
 375                 if ( isize > maxheight )
 376                 {
 377                         pos.x += (isize - maxheight)/2;
 378                         isize = maxheight;
 379                 }
 380                 else
 381                         dist.y += hud_fontsize.y;
 382                 pos.x = ( vid_conwidth - dist.x * mv_columns ) / 2;
 383         }
 384         else
 385         {
 386                 tsize = dist.x - 10;
 387                 isize = min(dist.y - 10, 0.75 * tsize);
 388         }
 389
 390         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 391
 392         if ( !gametypevote )
 393                 pos.x += dist.x / 2;
 394         pos.y += (dist.y - isize) / 2;
 395         ymax -= isize;
 396
 397         if (mv_top2_time)
 398                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 399
 400         void (vector, float, float, string, string, float, float) DrawItem;
 401
 402         if(gametypevote)
 403                 DrawItem = GameTypeVote_DrawGameTypeItem;
 404         else
 405                 DrawItem = MapVote_DrawMapItem;
 406
 407         for(i = 0; i < mv_num_maps; ++i)
 408         {
 409                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 410                 map = mv_maps[i];
 411                 if(mv_preview[i])
 412                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, mv_pics[i], tmp, i);
 413                 else
 414                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, "", tmp, i);
 415         }
 416
 417         if(mv_abstain)
 418                 ++mv_num_maps;
 419
 420         if(mv_abstain && i < mv_num_maps) {
 421                 tmp = mv_votes[i];
 422                 pos.y = ymax + isize - hud_fontsize.y;
 423                 pos.x = (xmax+xmin)*0.5;
 424                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 425         }
 426
 427         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 428 }
 429
 430 void Cmd_MapVote_MapDownload(float argc)
 431 {
 432         entity pak;
 433
 434         if(argc != 2 || !mv_pk3list)
 435         {
 436                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 437                 return;
 438         }
 439
 440         int id = stof(argv(1));
 441         for(pak = mv_pk3list; pak; pak = pak.chain)
 442                 if(pak.sv_entnum == id)
 443                         break;
 444
 445         if(!pak || pak.sv_entnum != id) {
 446                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 447                 return;
 448         }
 449
 450         if(PreviewExists(pak.message))
 451         {
 452                 mv_preview[id] = true;
 453                 return;
 454         } else {
 455                 print(_("Requesting preview...\n"));
 456                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 457         }
 458 }
 459
 460 void MapVote_CheckPK3(string pic, string pk3, int id)
 461 {
 462         entity pak;
 463         pak = spawn();
 464         pak.netname = pk3;
 465         pak.message = pic;
 466         pak.sv_entnum = id;
 467
 468         pak.chain = mv_pk3list;
 469         mv_pk3list = pak;
 470
 471         if(pk3 != "")
 472         {
 473                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 474         }
 475         else
 476         {
 477                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 478         }
 479 }
 480
 481 void MapVote_CheckPic(string pic, string pk3, int id)
 482 {
 483         // never try to retrieve a pic for the "don't care" 'map'
 484         if(mv_abstain && id == mv_num_maps - 1)
 485                 return;
 486
 487         if(PreviewExists(pic))
 488         {
 489                 mv_preview[id] = true;
 490                 return;
 491         }
 492         MapVote_CheckPK3(pic, pk3, id);
 493 }
 494
 495 void MapVote_ReadMask()
 496 {
 497         int i;
 498         if ( mv_num_maps < 24 )
 499         {
 500                 int mask, power;
 501                 if(mv_num_maps < 8)
 502                         mask = ReadByte();
 503                 else if(mv_num_maps < 16)
 504                         mask = ReadShort();
 505                 else
 506                         mask = ReadLong();
 507
 508                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 509                 {
 510                         if ( mask & power )
 511                                 mv_flags[i] |= GTV_AVAILABLE;
 512                         else
 513                                 mv_flags[i] &= ~GTV_AVAILABLE;
 514                 }
 515         }
 516         else
 517         {
 518                 for(i = 0; i < mv_num_maps; ++i )
 519                         mv_flags[i] = ReadByte();
 520         }
 521 }
 522
 523 void MapVote_ReadOption(int i)
 524 {
 525         string map = strzone(ReadString());
 526         string pk3 = strzone(ReadString());
 527         int j = bound(0, ReadByte(), n_ssdirs - 1);
 528
 529         mv_maps[i] = map;
 530         mv_pk3[i] = pk3;
 531         mv_flags[i] = GTV_AVAILABLE;
 532
 533         string pic = strzone(strcat(ssdirs[j], "/", map));
 534         mv_pics[i] = pic;
 535         mv_preview[i] = false;
 536         MapVote_CheckPic(pic, pk3, i);
 537 }
 538
 539 void GameTypeVote_ReadOption(int i)
 540 {
 541         string gt = strzone(ReadString());
 542
 543         mv_maps[i] = gt;
 544         mv_flags[i] = ReadByte();
 545
 546         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 547         if(precache_pic(mv_picpath) == "")
 548                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 549         string pic = strzone(mv_picpath);
 550         mv_pics[i] = pic;
 551         mv_preview[i] = PreviewExists(pic);
 552
 553         if ( mv_flags[i] & GTV_CUSTOM )
 554         {
 555                 string name = ReadString();
 556                 if ( strlen(name) < 1 )
 557                         name = gt;
 558                 mv_pk3[i] = strzone(name);
 559                 mv_desc[i] = strzone(ReadString());
 560         }
 561         else
 562         {
 563                 int type = MapInfo_Type_FromString(gt);
 564                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 565                 mv_desc[i] = MapInfo_Type_Description(type);
 566         }
 567 }
 568
 569 void MapVote_Init()
 570 {
 571         precache_sound ("misc/invshot.wav");
 572
 573         mv_active = 1;
 574         if(autocvar_hud_cursormode) { setcursormode(1); }
 575         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 576         mv_selection = -1;
 577         mv_selection_keyboard = 0;
 578
 579         string s;
 580         for(n_ssdirs = 0; ; ++n_ssdirs)
 581         {
 582                 s = ReadString();
 583                 if(s == "")
 584                         break;
 585                 if(n_ssdirs < NUM_SSDIRS)
 586                         ssdirs[n_ssdirs] = s;
 587         }
 588         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 589
 590         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 591         mv_abstain = ReadByte();
 592         if(mv_abstain)
 593                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 594         mv_detail = ReadByte();
 595
 596         mv_ownvote = -1;
 597         mv_timeout = ReadCoord();
 598
 599         gametypevote = ReadByte();
 600
 601         float mv_real_num_maps = mv_num_maps - mv_abstain;
 602
 603         if(gametypevote)
 604         {
 605                 mapvote_chosenmap = strzone(ReadString());
 606                 if ( gametypevote == 2 )
 607                         gametypevote = 0;
 608
 609                 gtv_text_size = hud_fontsize*1.4;
 610                 gtv_text_size_small = hud_fontsize*1.1;
 611
 612                 if (mv_real_num_maps > 8 )
 613                         mv_columns = 3;
 614                 else
 615                         mv_columns = min(2, mv_real_num_maps);
 616     }
 617     else
 618         {
 619                 if (mv_real_num_maps > 16)
 620                         mv_columns = 5;
 621                 else if (mv_real_num_maps > 9)
 622                         mv_columns = 4;
 623                 else if(mv_real_num_maps > 3)
 624                         mv_columns = 3;
 625                 else
 626                         mv_columns = mv_real_num_maps;
 627         }
 628
 629         MapVote_ReadMask();
 630         int i;
 631         for(i = 0; i < mv_num_maps; ++i )
 632                 mv_flags_start[i] = mv_flags[i];
 633
 634         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 635         mv_pk3list = world; // I'm still paranoid!
 636
 637         for(i = 0; i < mv_num_maps; ++i)
 638         {
 639                 mv_votes[i] = 0;
 640
 641                 if ( gametypevote )
 642                         GameTypeVote_ReadOption(i);
 643                 else
 644                         MapVote_ReadOption(i);
 645         }
 646
 647         for(i = 0; i < n_ssdirs; ++i)
 648                 ssdirs[n_ssdirs] = string_null;
 649         n_ssdirs = 0;
 650 }
 651
 652 void MapVote_SendChoice(float index)
 653 {
 654         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 655 }
 656
 657 int MapVote_MoveLeft(int pos)
 658 {
 659         int imp;
 660         if ( pos < 0 )
 661                 imp = mv_num_maps - 1;
 662         else
 663                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 664         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 665                 imp = MapVote_MoveLeft(imp);
 666         return imp;
 667 }
 668 int MapVote_MoveRight(int pos)
 669 {
 670         int imp;
 671         if ( pos < 0 )
 672                 imp = 0;
 673         else
 674                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 675         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 676                 imp = MapVote_MoveRight(imp);
 677         return imp;
 678 }
 679 int MapVote_MoveUp(int pos)
 680 {
 681         int imp;
 682         if ( pos < 0 )
 683                 imp = mv_num_maps - 1;
 684         else
 685         {
 686                 imp = pos - mv_columns;
 687                 if ( imp < 0 )
 688                 {
 689                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 690                         if ( imp >= mv_num_maps )
 691                                 imp -= mv_columns;
 692                 }
 693         }
 694         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 695                 imp = MapVote_MoveUp(imp);
 696         return imp;
 697 }
 698 int MapVote_MoveDown(int pos)
 699 {
 700         int imp;
 701         if ( pos < 0 )
 702                 imp = 0;
 703         else
 704         {
 705                 imp = pos + mv_columns;
 706                 if ( imp >= mv_num_maps )
 707                         imp = imp % mv_columns;
 708         }
 709         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 710                 imp = MapVote_MoveDown(imp);
 711         return imp;
 712 }
 713
 714 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 715 {
 716         float imp;
 717
 718         if (!mv_active)
 719                 return false;
 720
 721         if(bInputType == 3)
 722         {
 723                 mv_mousepos.x = nPrimary;
 724                 mv_mousepos.y = nSecondary;
 725                 mv_selection_keyboard = 0;
 726                 return true;
 727         }
 728
 729         if (bInputType != 0)
 730                 return false;
 731
 732         if ('0' <= nPrimary && nPrimary <= '9')
 733         {
 734                 imp = nPrimary - '0';
 735                 if (imp == 0) imp = 10;
 736                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 737                 return true;
 738         }
 739         switch(nPrimary)
 740         {
 741                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 742                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 743                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 744                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 745                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 746                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 747                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 748                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 749                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 750                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 751
 752                 case K_RIGHTARROW:
 753                         mv_selection_keyboard = 1;
 754                         mv_selection = MapVote_MoveRight(mv_selection);
 755                         return true;
 756                 case K_LEFTARROW:
 757                         mv_selection_keyboard = 1;
 758                         mv_selection = MapVote_MoveLeft(mv_selection);
 759                         return true;
 760                 case K_DOWNARROW:
 761                         mv_selection_keyboard = 1;
 762                         mv_selection = MapVote_MoveDown(mv_selection);
 763                         return true;
 764                 case K_UPARROW:
 765                         mv_selection_keyboard = 1;
 766                         mv_selection = MapVote_MoveUp(mv_selection);
 767                         return true;
 768                 case K_KP_ENTER:
 769                 case K_ENTER:
 770                 case K_SPACE:
 771                         if ( mv_selection_keyboard )
 772                                 MapVote_SendChoice(mv_selection);
 773                         return true;
 774         }
 775
 776         if (nPrimary == K_MOUSE1)
 777         {
 778                 mv_selection_keyboard = 0;
 779                 mv_selection = mv_mouse_selection;
 780                 if (mv_selection >= 0)
 781                 {
 782                         imp = min(mv_selection + 1, mv_num_maps);
 783                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 784                         return true;
 785                 }
 786         }
 787
 788         return false;
 789 }
 790
 791 void MapVote_UpdateMask()
 792 {
 793         MapVote_ReadMask();
 794         mv_top2_time = time;
 795 }
 796
 797 void MapVote_UpdateVotes()
 798 {
 799         int i;
 800         for(i = 0; i < mv_num_maps; ++i)
 801         {
 802                 if(mv_flags[i] & GTV_AVAILABLE)
 803                 {
 804                         if(mv_detail)
 805                                 mv_votes[i] = ReadByte();
 806                         else
 807                                 mv_votes[i] = 0;
 808                 }
 809                 else
 810                         mv_votes[i] = -1;
 811         }
 812
 813         mv_ownvote = ReadByte()-1;
 814 }
 815
 816 void Ent_MapVote()
 817 {
 818         int sf = ReadByte();
 819
 820         if(sf & 1)
 821                 MapVote_Init();
 822
 823         if(sf & 2)
 824                 MapVote_UpdateMask();
 825
 826         if(sf & 4)
 827                 MapVote_UpdateVotes();
 828 }
 829
 830 void Net_MapVote_Picture()
 831 {
 832         int type = ReadByte();
 833         mv_preview[type] = true;
 834         mv_pics[type] = strzone(ReadPicture());
 835 }