qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "scoreboard.qh"
   3
   4 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
   5 {
   6         string pre, post;
   7         pre = sprintf("%d. ", id+1);
   8         if(mv_detail)
   9         {
  10                 if(_count == 1)
  11                         post = _(" (1 vote)");
  12                 else if(_count >= 0 && mv_avail[id] == GTV_AVAILABLE)
  13                         post = sprintf(_(" (%d votes)"), _count);
  14                 else
  15                         post = "";
  16         }
  17         else
  18                 post = "";
  19         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  20         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  21         return strcat(pre, map, post);
  22 }
  23
  24 string GameTypeVote_DescriptionByID(float id)
  25 {
  26         return MapInfo_Type_Description(MapInfo_Type_FromString(mv_maps[id]));
  27 }
  28
  29 vector MapVote_RGB(int id)
  30 {
  31         if(mv_avail[id] != GTV_AVAILABLE)
  32                 return '1 1 1';
  33         if(id == mv_ownvote)
  34                 return '0 1 0';
  35         else if (id == mv_selection)
  36                 return '1 1 0';
  37         else
  38                 return '1 1 1';
  39 }
  40
  41 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  42 {
  43         float alpha;
  44         float desc_padding = gtv_text_size.x * 3;
  45         float rect_margin = hud_fontsize.y / 2;
  46         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  47         vector rect_size = '1 1 0';
  48         rect_size.x = tsize + rect_margin;
  49         rect_size.y = maxh + rect_margin;
  50         vector rgb = MapVote_RGB(id);
  51         vector offset = pos;
  52         float nlines = 0;
  53
  54         if(mv_avail_start[id] != GTV_AVAILABLE)
  55                 alpha = 0.2;
  56         else if ( mv_avail[id] != GTV_AVAILABLE && mv_top2_alpha)
  57                 alpha = mv_top2_alpha;
  58         else
  59                 alpha = 1;
  60
  61         if(id == mv_selection && mv_avail[id] == GTV_AVAILABLE)
  62         {
  63                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
  64         }
  65         if(id == mv_ownvote)
  66         {
  67                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
  68                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
  69         }
  70
  71         entity title;
  72         title = spawn();
  73         title.message = MapVote_FormatMapItem(id, MapInfo_Type_ToText(MapInfo_Type_FromString(gtype)),
  74                                                                                   _count, tsize, gtv_text_size);
  75         title.origin = pos-offset;
  76
  77         pos.y += gtv_text_size_small.y;
  78         pos.y += gtv_text_size.y/2;
  79
  80         maxh -= gtv_text_size.y;
  81
  82         entity picent = spawn();
  83         picent.origin = pos-offset;
  84         picent.maxs = '1 1 0 ' * min(maxh, desc_padding) * 0.8;
  85
  86         pos.x += desc_padding;
  87         tsize -= desc_padding;
  88
  89         string thelabel = GameTypeVote_DescriptionByID(id), ts;
  90         entity last = title;
  91         entity next = world;
  92         if( thelabel != "")
  93         {
  94                 float i,n = tokenizebyseparator(thelabel, "\n");
  95                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
  96                 {
  97                         getWrappedLine_remaining = argv(i);
  98                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
  99                         {
 100                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 101                                 if (ts != "")
 102                                 {
 103                                         next = spawn();
 104                                         next.message = ts;
 105                                         next.origin = pos-offset;
 106                                         last.chain = next;
 107                                         last = next;
 108                                         pos.y += gtv_text_size_small.y;
 109                                         nlines++;
 110                                 }
 111                         }
 112                 }
 113         }
 114
 115         maxh -= max(nlines*gtv_text_size_small.y,picent.maxs.y);
 116         if ( maxh > 0 )
 117                 offset.y += maxh/2;
 118         drawstring(title.origin+offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 119
 120         if(pic != "")
 121                 drawpic(picent.origin+offset, pic, picent.maxs, '1 1 1', alpha, DRAWFLAG_NORMAL);
 122
 123         for ( last = title.chain; last ; )
 124         {
 125                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 126                 next = last;
 127                 last = last.chain;
 128                 remove(next);
 129         }
 130
 131         remove(picent);
 132         remove(title);
 133 }
 134
 135 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 136 {
 137         vector img_size = '0 0 0';
 138         vector rgb;
 139         string label;
 140         float text_size;
 141
 142         isize -= hud_fontsize.y; // respect the text when calculating the image size
 143
 144         rgb = MapVote_RGB(id);
 145
 146         img_size.y = isize;
 147         img_size.x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
 148
 149         pos.y = pos.y + img_size.y;
 150
 151         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 152
 153         text_size = stringwidth(label, false, hud_fontsize);
 154
 155         float theAlpha;
 156         if (mv_avail[id] != GTV_AVAILABLE && mv_top2_alpha)
 157                 theAlpha = mv_top2_alpha;
 158         else
 159                 theAlpha = 1;
 160
 161         pos.x -= text_size*0.5;
 162         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 163
 164         pos.x = pos.x + text_size*0.5 - img_size.x*0.5;
 165         pos.y = pos.y - img_size.y;
 166
 167         pos += autocvar_scoreboard_border_thickness * '1 1 0';
 168         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
 169         if(pic == "")
 170         {
 171                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 172         }
 173         else
 174         {
 175                 if(drawgetimagesize(pic) == '0 0 0')
 176                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 177                 else
 178                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 179         }
 180
 181         if(id == mv_ownvote)
 182                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 183         else
 184                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 185
 186         if(id == mv_selection && mv_avail[id] == GTV_AVAILABLE)
 187                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 188 }
 189
 190 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 191 {
 192         vector rgb;
 193         float text_size;
 194         string label;
 195
 196         rgb = MapVote_RGB(id);
 197
 198         pos.y = pos.y + hud_fontsize.y;
 199
 200         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 201
 202         text_size = stringwidth(label, false, hud_fontsize);
 203
 204         pos.x -= text_size*0.5;
 205         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 206 }
 207
 208 vector MapVote_GridVec(vector gridspec, int i, int m)
 209 {
 210         int r = i % m;
 211         return
 212                 '1 0 0' * (gridspec.x * r)
 213                 +
 214                 '0 1 0' * (gridspec.y * (i - r) / m);
 215 }
 216
 217 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 218 {
 219
 220         float c, r;
 221
 222         mv_mouse_selection = -1;
 223
 224         for (r = 0; r < rows; ++r)
 225                 for (c = 0; c < columns; ++c)
 226                 {
 227                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 228                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 229                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 230                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 231                         {
 232                                 mv_mouse_selection = r * columns + c;
 233                                 break;
 234                         }
 235                 }
 236
 237         if (mv_mouse_selection >= mv_num_maps)
 238                 mv_mouse_selection = -1;
 239
 240         if (mv_abstain && mv_mouse_selection < 0)
 241                 mv_mouse_selection = mv_num_maps;
 242
 243         if ( mv_selection_keyboard )
 244                 return mv_selection;
 245
 246         return mv_mouse_selection;
 247 }
 248
 249 void MapVote_Draw()
 250 {
 251         string map;
 252         int i;
 253         float tmp;
 254         vector pos;
 255         float isize;
 256         float center;
 257         float rows;
 258         float tsize;
 259         vector dist = '0 0 0';
 260
 261         if(!mv_active)
 262                 return;
 263
 264         if (!autocvar_hud_cursormode)
 265         {
 266                 vector mpos = mv_mousepos + getmousepos();
 267                 mpos.x = bound(0, mpos.x, vid_conwidth);
 268                 mpos.y = bound(0, mpos.y, vid_conheight);
 269
 270                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 271                         mv_selection_keyboard = 0;
 272                 mv_mousepos = mpos;
 273
 274         }
 275
 276         center = (vid_conwidth - 1)/2;
 277         xmin = vid_conwidth*0.05; // 5% border must suffice
 278         xmax = vid_conwidth - xmin;
 279         ymin = 20;
 280         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 281         if(i < 0)
 282                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 283         if(i >= 0 || ymax < (vid_conheight*0.5))
 284                 ymax = vid_conheight - ymin;
 285
 286         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 287
 288         pos.y = ymin;
 289         pos.z = 0;
 290
 291         draw_beginBoldFont();
 292         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 293         pos.x = center - stringwidth(map, false, '12 0 0');
 294         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 295         pos.y += 26;
 296
 297         if( mapvote_chosenmap != "" )
 298         {
 299                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize*1.5/2);
 300                 drawstring(pos, mapvote_chosenmap, hud_fontsize*1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 301                 pos.y += hud_fontsize.y*2;
 302         }
 303
 304         i = ceil(max(0, mv_timeout - time));
 305         map = sprintf(_("%d seconds left"), i);
 306         pos.x = center - stringwidth(map, false, '8 0 0');
 307         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 308         pos.y += 22;
 309         pos.x = xmin;
 310         draw_endBoldFont();
 311
 312         // base for multi-column stuff...
 313         ymin = pos.y;
 314         if(mv_abstain)
 315                 mv_num_maps -= 1;
 316
 317         rows = ceil(mv_num_maps / mv_columns);
 318
 319         dist.x = (xmax - xmin) / mv_columns;
 320         dist.y = (ymax - pos.y) / rows;
 321
 322         if ( gametypevote )
 323         {
 324                 tsize = dist.x - hud_fontsize.y;
 325                 isize = dist.y;
 326                 float maxheight = (ymax - pos.y) / 3;
 327                 if ( isize > maxheight )
 328                 {
 329                         pos.x += (isize - maxheight)/2;
 330                         isize = maxheight;
 331                 }
 332                 else
 333                         dist.y += hud_fontsize.y;
 334                 pos.x = ( vid_conwidth - dist.x * mv_columns ) / 2;
 335         }
 336         else
 337         {
 338                 tsize = dist.x - 10;
 339                 isize = min(dist.y - 10, 0.75 * tsize);
 340         }
 341
 342         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 343
 344         if ( !gametypevote )
 345                 pos.x += dist.x / 2;
 346         pos.y += (dist.y - isize) / 2;
 347         ymax -= isize;
 348
 349         if (mv_top2_time)
 350                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 351
 352         void (vector, float, float, string, string, float, float) DrawItem;
 353
 354         if(gametypevote)
 355                 DrawItem = GameTypeVote_DrawGameTypeItem;
 356         else
 357                 DrawItem = MapVote_DrawMapItem;
 358
 359         for(i = 0; i < mv_num_maps; ++i)
 360         {
 361                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 362                 map = mv_maps[i];
 363                 if(mv_preview[i])
 364                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, mv_pics[i], tmp, i);
 365                 else
 366                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, "", tmp, i);
 367         }
 368
 369         if(mv_abstain)
 370                 ++mv_num_maps;
 371
 372         if(mv_abstain && i < mv_num_maps) {
 373                 tmp = mv_votes[i];
 374                 pos.y = ymax + isize - hud_fontsize.y;
 375                 pos.x = (xmax+xmin)*0.5;
 376                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 377         }
 378
 379         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 380 }
 381
 382 void Cmd_MapVote_MapDownload(float argc)
 383 {
 384         float id;
 385         entity pak;
 386
 387         if(argc != 2 || !mv_pk3list)
 388         {
 389                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 390                 return;
 391         }
 392
 393         id = stof(argv(1));
 394         for(pak = mv_pk3list; pak; pak = pak.chain)
 395                 if(pak.sv_entnum == id)
 396                         break;
 397
 398         if(!pak || pak.sv_entnum != id) {
 399                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 400                 return;
 401         }
 402
 403         if(PreviewExists(pak.message))
 404         {
 405                 mv_preview[id] = true;
 406                 return;
 407         } else {
 408                 print(_("Requesting preview...\n"));
 409                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 410         }
 411 }
 412
 413 void MapVote_CheckPK3(string pic, string pk3, int id)
 414 {
 415         entity pak;
 416         pak = spawn();
 417         pak.netname = pk3;
 418         pak.message = pic;
 419         pak.sv_entnum = id;
 420
 421         pak.chain = mv_pk3list;
 422         mv_pk3list = pak;
 423
 424         if(pk3 != "")
 425         {
 426                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 427         }
 428         else
 429         {
 430                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 431         }
 432 }
 433
 434 void MapVote_CheckPic(string pic, string pk3, int id)
 435 {
 436         // never try to retrieve a pic for the "don't care" 'map'
 437         if(mv_abstain && id == mv_num_maps - 1)
 438                 return;
 439
 440         if(PreviewExists(pic))
 441         {
 442                 mv_preview[id] = true;
 443                 return;
 444         }
 445         MapVote_CheckPK3(pic, pk3, id);
 446 }
 447
 448 void MapVote_ReadMask()
 449 {
 450         int i;
 451         if ( mv_num_maps < 24 )
 452         {
 453                 int mask, power;
 454                 if(mv_num_maps < 8)
 455                         mask = ReadByte();
 456                 else if(mv_num_maps < 16)
 457                         mask = ReadShort();
 458                 else
 459                         mask = ReadLong();
 460
 461                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 462                         mv_avail[i] = (mask & power) ? GTV_AVAILABLE : GTV_FORBIDDEN;
 463         }
 464         else
 465         {
 466                 for(i = 0; i < mv_num_maps; ++i )
 467                         mv_avail[i] = ReadByte();
 468         }
 469 }
 470
 471 void MapVote_Init()
 472 {
 473         int i, j;
 474         string map, pk3, s;
 475
 476         precache_sound ("misc/invshot.wav");
 477
 478         mv_active = 1;
 479         if(autocvar_hud_cursormode) { setcursormode(1); }
 480         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 481         mv_selection = -1;
 482         mv_selection_keyboard = 0;
 483
 484         for(n_ssdirs = 0; ; ++n_ssdirs)
 485         {
 486                 s = ReadString();
 487                 if(s == "")
 488                         break;
 489                 if(n_ssdirs < NUM_SSDIRS)
 490                         ssdirs[n_ssdirs] = s;
 491         }
 492         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 493
 494         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 495         mv_abstain = ReadByte();
 496         if(mv_abstain)
 497                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 498         mv_detail = ReadByte();
 499
 500         mv_ownvote = -1;
 501         mv_timeout = ReadCoord();
 502
 503         gametypevote = ReadByte();
 504
 505         float mv_real_num_maps = mv_num_maps - mv_abstain;
 506
 507         if(gametypevote)
 508         {
 509                 mapvote_chosenmap = strzone(ReadString());
 510                 if ( gametypevote == 2 )
 511                         gametypevote = 0;
 512
 513                 gtv_text_size = hud_fontsize*1.4;
 514                 gtv_text_size_small = hud_fontsize*1.1;
 515
 516                 if (mv_real_num_maps > 8 )
 517                         mv_columns = 3;
 518                 else
 519                         mv_columns = min(2, mv_real_num_maps);
 520     }
 521     else
 522         {
 523                 if (mv_real_num_maps > 16)
 524                         mv_columns = 5;
 525                 else if (mv_real_num_maps > 9)
 526                         mv_columns = 4;
 527                 else if(mv_real_num_maps > 3)
 528                         mv_columns = 3;
 529                 else
 530                         mv_columns = mv_real_num_maps;
 531         }
 532
 533         MapVote_ReadMask();
 534         for(i = 0; i < mv_num_maps; ++i )
 535                 mv_avail_start[i] = mv_avail[i];
 536
 537         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 538         mv_pk3list = world; // I'm still paranoid!
 539
 540         for(i = 0; i < mv_num_maps; ++i)
 541         {
 542                 mv_votes[i] = 0;
 543
 544                 map = strzone(ReadString());
 545                 pk3 = strzone(ReadString());
 546                 j = bound(0, ReadByte(), n_ssdirs - 1);
 547
 548                 mv_maps[i] = map;
 549                 mv_pk3[i] = pk3;
 550                 mv_avail[i] = ReadByte();
 551
 552                 if(gametypevote)
 553                 {
 554                         //map = strzone(strcat("gfx/menu/default/gametype_", map));
 555                         //map = strzone(sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, map));
 556                         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, map);
 557                         if(precache_pic(mv_picpath) == "")
 558                                 mv_picpath = strcat("gfx/menu/default/gametype_", map);
 559                         map = strzone(mv_picpath);
 560                         mv_pics[i] = map;
 561                         mv_preview[i] = PreviewExists(map);
 562                 }
 563                 else
 564                 {
 565                         map = strzone(strcat(ssdirs[j], "/", map));
 566                         mv_pics[i] = map;
 567                         mv_preview[i] = false;
 568                         MapVote_CheckPic(map, pk3, i);
 569                 }
 570         }
 571
 572         for(i = 0; i < n_ssdirs; ++i)
 573                 ssdirs[n_ssdirs] = string_null;
 574         n_ssdirs = 0;
 575 }
 576
 577 void MapVote_SendChoice(float index)
 578 {
 579         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 580 }
 581
 582 int MapVote_MoveLeft(int pos)
 583 {
 584         int imp;
 585         if ( pos < 0 )
 586                 imp = mv_num_maps - 1;
 587         else
 588                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 589         if ( mv_avail[imp] != GTV_AVAILABLE && imp != mv_ownvote )
 590                 imp = MapVote_MoveLeft(imp);
 591         return imp;
 592 }
 593 int MapVote_MoveRight(int pos)
 594 {
 595         int imp;
 596         if ( pos < 0 )
 597                 imp = 0;
 598         else
 599                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 600         if ( mv_avail[imp] != GTV_AVAILABLE && imp != mv_ownvote )
 601                 imp = MapVote_MoveRight(imp);
 602         return imp;
 603 }
 604 int MapVote_MoveUp(int pos)
 605 {
 606         int imp;
 607         if ( pos < 0 )
 608                 imp = mv_num_maps - 1;
 609         else
 610         {
 611                 imp = pos - mv_columns;
 612                 if ( imp < 0 )
 613                 {
 614                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 615                         if ( imp >= mv_num_maps )
 616                                 imp -= mv_columns;
 617                 }
 618         }
 619         if ( mv_avail[imp] != GTV_AVAILABLE && imp != mv_ownvote )
 620                 imp = MapVote_MoveUp(imp);
 621         return imp;
 622 }
 623 int MapVote_MoveDown(int pos)
 624 {
 625         int imp;
 626         if ( pos < 0 )
 627                 imp = 0;
 628         else
 629         {
 630                 imp = pos + mv_columns;
 631                 if ( imp >= mv_num_maps )
 632                         imp = imp % mv_columns;
 633         }
 634         if ( mv_avail[imp] != GTV_AVAILABLE && imp != mv_ownvote )
 635                 imp = MapVote_MoveDown(imp);
 636         return imp;
 637 }
 638
 639 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 640 {
 641         float imp;
 642
 643         if (!mv_active)
 644                 return false;
 645
 646         if(bInputType == 3)
 647         {
 648                 mv_mousepos.x = nPrimary;
 649                 mv_mousepos.y = nSecondary;
 650                 mv_selection_keyboard = 0;
 651                 return true;
 652         }
 653
 654         if (bInputType != 0)
 655                 return false;
 656
 657         if ('0' <= nPrimary && nPrimary <= '9')
 658         {
 659                 imp = nPrimary - '0';
 660                 if (imp == 0) imp = 10;
 661                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 662                 return true;
 663         }
 664         switch(nPrimary)
 665         {
 666                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 667                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 668                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 669                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 670                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 671                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 672                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 673                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 674                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 675                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 676
 677                 case K_RIGHTARROW:
 678                         mv_selection_keyboard = 1;
 679                         mv_selection = MapVote_MoveRight(mv_selection);
 680                         return true;
 681                 case K_LEFTARROW:
 682                         mv_selection_keyboard = 1;
 683                         mv_selection = MapVote_MoveLeft(mv_selection);
 684                         return true;
 685                 case K_DOWNARROW:
 686                         mv_selection_keyboard = 1;
 687                         mv_selection = MapVote_MoveDown(mv_selection);
 688                         return true;
 689                 case K_UPARROW:
 690                         mv_selection_keyboard = 1;
 691                         mv_selection = MapVote_MoveUp(mv_selection);
 692                         return true;
 693                 case K_KP_ENTER:
 694                 case K_ENTER:
 695                 case K_SPACE:
 696                         if ( mv_selection_keyboard )
 697                                 MapVote_SendChoice(mv_selection);
 698                         return true;
 699         }
 700
 701         if (nPrimary == K_MOUSE1)
 702         {
 703                 mv_selection_keyboard = 0;
 704                 mv_selection = mv_mouse_selection;
 705                 if (mv_selection >= 0)
 706                 {
 707                         imp = min(mv_selection + 1, mv_num_maps);
 708                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 709                         return true;
 710                 }
 711         }
 712
 713         return false;
 714 }
 715
 716 void MapVote_UpdateMask()
 717 {
 718         MapVote_ReadMask();
 719         mv_top2_time = time;
 720 }
 721
 722 void MapVote_UpdateVotes()
 723 {
 724         int i;
 725         for(i = 0; i < mv_num_maps; ++i)
 726         {
 727                 if(mv_avail[i] == GTV_AVAILABLE)
 728                 {
 729                         if(mv_detail)
 730                                 mv_votes[i] = ReadByte();
 731                         else
 732                                 mv_votes[i] = 0;
 733                 }
 734                 else
 735                         mv_votes[i] = -1;
 736         }
 737
 738         mv_ownvote = ReadByte()-1;
 739 }
 740
 741 void Ent_MapVote()
 742 {
 743         int sf = ReadByte();
 744
 745         if(sf & 1)
 746                 MapVote_Init();
 747
 748         if(sf & 2)
 749                 MapVote_UpdateMask();
 750
 751         if(sf & 4)
 752                 MapVote_UpdateVotes();
 753 }
 754
 755 void Net_MapVote_Picture()
 756 {
 757         int type = ReadByte();
 758         mv_preview[type] = true;
 759         mv_pics[type] = strzone(ReadPicture());
 760 }