qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 float mv_active;
  16 string mv_maps[MAPVOTE_COUNT];
  17 string mv_pics[MAPVOTE_COUNT];
  18 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  19 string mv_desc[MAPVOTE_COUNT];
  20 float mv_preview[MAPVOTE_COUNT];
  21 float mv_votes[MAPVOTE_COUNT];
  22 float mv_flags[MAPVOTE_COUNT];
  23 float mv_flags_start[MAPVOTE_COUNT];
  24 entity mv_pk3list;
  25 float mv_abstain;
  26 float mv_ownvote;
  27 float mv_detail;
  28 float mv_timeout;
  29 float mv_top2_time;
  30 float mv_top2_alpha;
  31
  32 vector mv_mousepos;
  33 int mv_selection;
  34 int mv_columns;
  35 int mv_mouse_selection;
  36 int mv_selection_keyboard;
  37
  38 float gametypevote;
  39 string mapvote_chosenmap;
  40 vector gtv_text_size;
  41 vector gtv_text_size_small;
  42
  43 const int NUM_SSDIRS = 4;
  44 string ssdirs[NUM_SSDIRS];
  45 int n_ssdirs;
  46
  47 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  48 {
  49         string pre, post;
  50         pre = sprintf("%d. ", id+1);
  51         if(mv_detail)
  52         {
  53                 if(_count == 1)
  54                         post = _(" (1 vote)");
  55                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  56                         post = sprintf(_(" (%d votes)"), _count);
  57                 else
  58                         post = "";
  59         }
  60         else
  61                 post = "";
  62         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  63         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  64         return strcat(pre, map, post);
  65 }
  66
  67 vector MapVote_RGB(int id)
  68 {
  69         if(!(mv_flags[id] & GTV_AVAILABLE))
  70                 return '1 1 1';
  71         if(id == mv_ownvote)
  72                 return '0 1 0';
  73         else if (id == mv_selection)
  74                 return '1 1 0';
  75         else
  76                 return '1 1 1';
  77 }
  78
  79 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  80 {
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89
  90         // Bounding box details
  91         float rect_margin = hud_fontsize.y / 2;
  92
  93         pos.x += rect_margin;
  94         pos.y += rect_margin;
  95         maxh -= 2 * rect_margin;
  96         tsize -= 2 * rect_margin;
  97
  98         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  99         vector rect_size = '1 1 0';
 100         rect_size.x = tsize + rect_margin;
 101         rect_size.y = maxh + rect_margin;
 102
 103         // Highlight selected item
 104         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 105         {
 106                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 107         }
 108
 109         // Highlight current vote
 110         vector rgb = MapVote_RGB(id);
 111         if(id == mv_ownvote)
 112         {
 113                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 114                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 115         }
 116
 117         vector offset = pos;
 118
 119         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 120         pos.y += title_gap;
 121         maxh -= title_gap;
 122
 123         // Evaluate the image size
 124         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 125         if ( maxh < image_size.y )
 126                 image_size = '1 1 0' * maxh;
 127         image_size *= 0.8;
 128         float desc_padding = gtv_text_size.x * 0.6;
 129         pos.x += image_size.x + desc_padding;
 130         tsize -= image_size.x + desc_padding;
 131
 132         // Split the description into lines
 133         entity title;
 134         title = spawn();
 135         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 136
 137         string thelabel = mv_desc[id], ts;
 138         entity last = title;
 139         entity next = world;
 140         float nlines = 0;
 141         if( thelabel != "")
 142         {
 143                 float i,n = tokenizebyseparator(thelabel, "\n");
 144                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 145                 {
 146                         getWrappedLine_remaining = argv(i);
 147                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 148                         {
 149                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 150                                 if (ts != "")
 151                                 {
 152                                         next = spawn();
 153                                         next.message = ts;
 154                                         next.origin = pos-offset;
 155                                         last.chain = next;
 156                                         last = next;
 157                                         pos.y += gtv_text_size_small.y;
 158                                         nlines++;
 159                                 }
 160                         }
 161                 }
 162         }
 163
 164         // Center the contents in the bounding box
 165         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 166         if ( maxh > 0 )
 167                 offset.y += maxh/2;
 168
 169         // Draw the title
 170         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 171
 172         // Draw the icon
 173         if(pic != "")
 174                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 175
 176         // Draw the description
 177         for ( last = title.chain; last ; )
 178         {
 179                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 180                 next = last;
 181                 last = last.chain;
 182                 remove(next);
 183         }
 184
 185         // Cleanup
 186         remove(title);
 187 }
 188
 189 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 190 {
 191         vector img_size = '0 0 0';
 192         vector rgb;
 193         string label;
 194         float text_size;
 195
 196         rgb = MapVote_RGB(id);
 197
 198         float padding = hud_fontsize.y / 2;
 199
 200         pos.x += padding;
 201         pos.y += padding;
 202         isize -= 2 * padding;
 203         tsize -= 2 * padding;
 204
 205         float img_ar = 4/3;
 206         img_size.x = min(tsize, isize * img_ar);
 207         img_size.y = img_size.x / img_ar;
 208         img_size.y -= hud_fontsize.y - autocvar_scoreboard_border_thickness * 2;
 209         img_size.x = img_size.y * img_ar;
 210
 211         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 212
 213         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 214
 215         text_size = stringwidth(label, false, hud_fontsize);
 216
 217         vector text_pos = '0 0 0';
 218         text_pos.x = pos.x + (tsize - text_size) / 2;
 219         text_pos.y = pos.y + img_size.y + autocvar_scoreboard_border_thickness;
 220
 221         pos.x += (tsize - img_size.x) / 2;
 222
 223         float theAlpha;
 224         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 225                 theAlpha = mv_top2_alpha;
 226         else
 227                 theAlpha = 1;
 228         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 229
 230         if(pic == "")
 231         {
 232                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 233         }
 234         else
 235         {
 236                 if(drawgetimagesize(pic) == '0 0 0')
 237                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 238                 else
 239                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 240         }
 241
 242         if(id == mv_ownvote)
 243                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 244         else
 245                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 246
 247         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 248                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 249 }
 250
 251 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 252 {
 253         vector rgb;
 254         float text_size;
 255         string label;
 256
 257         rgb = MapVote_RGB(id);
 258
 259         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 260
 261         text_size = stringwidth(label, false, hud_fontsize);
 262
 263         pos.x -= text_size*0.5;
 264         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 265 }
 266
 267 vector MapVote_GridVec(vector gridspec, int i, int m)
 268 {
 269         int r = i % m;
 270         return
 271                 '1 0 0' * (gridspec.x * r)
 272                 +
 273                 '0 1 0' * (gridspec.y * (i - r) / m);
 274 }
 275
 276 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 277 {
 278
 279         float c, r;
 280
 281         mv_mouse_selection = -1;
 282
 283         for (r = 0; r < rows; ++r)
 284                 for (c = 0; c < columns; ++c)
 285                 {
 286                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 287                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 288                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 289                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 290                         {
 291                                 mv_mouse_selection = r * columns + c;
 292                                 break;
 293                         }
 294                 }
 295
 296         if (mv_mouse_selection >= mv_num_maps)
 297                 mv_mouse_selection = -1;
 298
 299         if (mv_abstain && mv_mouse_selection < 0)
 300                 mv_mouse_selection = mv_num_maps;
 301
 302         if ( mv_selection_keyboard )
 303                 return mv_selection;
 304
 305         return mv_mouse_selection;
 306 }
 307
 308 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 309 void MapVote_Draw()
 310 {
 311         string map;
 312         int i;
 313         float tmp;
 314         vector pos;
 315         float isize;
 316         float center;
 317         float rows;
 318         float tsize;
 319         vector dist = '0 0 0';
 320
 321         if(!mv_active)
 322                 return;
 323
 324         if (!autocvar_hud_cursormode)
 325         {
 326                 vector mpos = mv_mousepos + getmousepos();
 327                 mpos.x = bound(0, mpos.x, vid_conwidth);
 328                 mpos.y = bound(0, mpos.y, vid_conheight);
 329
 330                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 331                         mv_selection_keyboard = 0;
 332                 mv_mousepos = mpos;
 333
 334         }
 335
 336         center = (vid_conwidth - 1)/2;
 337         xmin = vid_conwidth*0.05; // 5% border must suffice
 338         xmax = vid_conwidth - xmin;
 339         ymin = 20;
 340         i = autocvar_con_chatpos; // *autocvar_con_chatsize;
 341         if(i < 0)
 342                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 343         if(i >= 0 || ymax < (vid_conheight*0.5))
 344                 ymax = vid_conheight - ymin;
 345
 346         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 347
 348         pos.y = ymin;
 349         pos.z = 0;
 350
 351         draw_beginBoldFont();
 352         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 353         pos.x = center - stringwidth(map, false, '12 0 0');
 354         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 355         pos.y += 26;
 356
 357         if( mapvote_chosenmap != "" )
 358         {
 359                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize*1.5/2);
 360                 drawstring(pos, mapvote_chosenmap, hud_fontsize*1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 361                 pos.y += hud_fontsize.y*2;
 362         }
 363
 364         i = ceil(max(0, mv_timeout - time));
 365         map = sprintf(_("%d seconds left"), i);
 366         pos.x = center - stringwidth(map, false, '8 0 0');
 367         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 368         pos.y += 22;
 369         pos.x = xmin;
 370         draw_endBoldFont();
 371
 372         // base for multi-column stuff...
 373         ymin = pos.y;
 374         if(mv_abstain)
 375                 mv_num_maps -= 1;
 376
 377         // for mapvote it would be better 4/3 but map name needs more horizzontal space
 378         int item_aspect = (gametypevote) ? 3/1 : 2/1;
 379         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 380         mv_columns = table_size.x;
 381         rows = table_size.y;
 382
 383         dist.x = (xmax - xmin) / mv_columns;
 384         dist.y = (ymax - pos.y) / rows;
 385
 386         // reduce size of too wide items
 387         tmp = vid_conwidth / 3; // max width
 388         if(dist.x > tmp)
 389         {
 390                 dist.x = tmp;
 391                 dist.y = min(dist.y, dist.x / item_aspect);
 392         }
 393         tmp = vid_conheight / 3; // max height
 394         if(dist.y > tmp)
 395         {
 396                 dist.y = tmp;
 397                 dist.x = min(dist.x, dist.y * item_aspect);
 398         }
 399
 400         // reduce size to fix aspect ratio
 401         if(dist.x / dist.y > item_aspect)
 402                 dist.x = dist.y * item_aspect;
 403         else
 404                 dist.y = dist.x / item_aspect;
 405
 406         // adjust table pos and size according to the new size
 407         float offset;
 408         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 409         xmin = pos.x += offset;
 410         xmax -= offset;
 411         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 412         ymin = pos.y += offset;
 413         ymax -= offset;
 414
 415         tsize = dist.x;
 416         isize = dist.y;
 417
 418         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 419
 420         if (mv_top2_time)
 421                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 422
 423         void (vector, float, float, string, string, float, float) DrawItem;
 424
 425         if(gametypevote)
 426                 DrawItem = GameTypeVote_DrawGameTypeItem;
 427         else
 428                 DrawItem = MapVote_DrawMapItem;
 429
 430         for(i = 0; i < mv_num_maps; ++i)
 431         {
 432                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 433                 map = mv_maps[i];
 434                 if(mv_preview[i])
 435                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, mv_pics[i], tmp, i);
 436                 else
 437                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, "", tmp, i);
 438         }
 439
 440         if(mv_abstain)
 441                 ++mv_num_maps;
 442
 443         if(mv_abstain && i < mv_num_maps) {
 444                 tmp = mv_votes[i];
 445                 pos.y = ymax + 2 * hud_fontsize.y;
 446                 pos.x = (xmax+xmin)*0.5;
 447                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 448         }
 449
 450         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 451 }
 452
 453 void Cmd_MapVote_MapDownload(float argc)
 454 {
 455         entity pak;
 456
 457         if(argc != 2 || !mv_pk3list)
 458         {
 459                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 460                 return;
 461         }
 462
 463         int id = stof(argv(1));
 464         for(pak = mv_pk3list; pak; pak = pak.chain)
 465                 if(pak.sv_entnum == id)
 466                         break;
 467
 468         if(!pak || pak.sv_entnum != id) {
 469                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 470                 return;
 471         }
 472
 473         if(PreviewExists(pak.message))
 474         {
 475                 mv_preview[id] = true;
 476                 return;
 477         } else {
 478                 print(_("Requesting preview...\n"));
 479                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 480         }
 481 }
 482
 483 void MapVote_CheckPK3(string pic, string pk3, int id)
 484 {
 485         entity pak;
 486         pak = spawn();
 487         pak.netname = pk3;
 488         pak.message = pic;
 489         pak.sv_entnum = id;
 490
 491         pak.chain = mv_pk3list;
 492         mv_pk3list = pak;
 493
 494         if(pk3 != "")
 495         {
 496                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 497         }
 498         else
 499         {
 500                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 501         }
 502 }
 503
 504 void MapVote_CheckPic(string pic, string pk3, int id)
 505 {
 506         // never try to retrieve a pic for the "don't care" 'map'
 507         if(mv_abstain && id == mv_num_maps - 1)
 508                 return;
 509
 510         if(PreviewExists(pic))
 511         {
 512                 mv_preview[id] = true;
 513                 return;
 514         }
 515         MapVote_CheckPK3(pic, pk3, id);
 516 }
 517
 518 void MapVote_ReadMask()
 519 {
 520         int i;
 521         if ( mv_num_maps < 24 )
 522         {
 523                 int mask, power;
 524                 if(mv_num_maps < 8)
 525                         mask = ReadByte();
 526                 else if(mv_num_maps < 16)
 527                         mask = ReadShort();
 528                 else
 529                         mask = ReadLong();
 530
 531                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 532                 {
 533                         if ( mask & power )
 534                                 mv_flags[i] |= GTV_AVAILABLE;
 535                         else
 536                                 mv_flags[i] &= ~GTV_AVAILABLE;
 537                 }
 538         }
 539         else
 540         {
 541                 for(i = 0; i < mv_num_maps; ++i )
 542                         mv_flags[i] = ReadByte();
 543         }
 544 }
 545
 546 void MapVote_ReadOption(int i)
 547 {
 548         string map = strzone(ReadString());
 549         string pk3 = strzone(ReadString());
 550         int j = bound(0, ReadByte(), n_ssdirs - 1);
 551
 552         mv_maps[i] = map;
 553         mv_pk3[i] = pk3;
 554         mv_flags[i] = GTV_AVAILABLE;
 555
 556         string pic = strzone(strcat(ssdirs[j], "/", map));
 557         mv_pics[i] = pic;
 558         mv_preview[i] = false;
 559         MapVote_CheckPic(pic, pk3, i);
 560 }
 561
 562 void GameTypeVote_ReadOption(int i)
 563 {
 564         string gt = strzone(ReadString());
 565
 566         mv_maps[i] = gt;
 567         mv_flags[i] = ReadByte();
 568
 569         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 570         if(precache_pic(mv_picpath) == "")
 571                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 572         string pic = strzone(mv_picpath);
 573         mv_pics[i] = pic;
 574         mv_preview[i] = PreviewExists(pic);
 575
 576         if ( mv_flags[i] & GTV_CUSTOM )
 577         {
 578                 string name = ReadString();
 579                 if ( strlen(name) < 1 )
 580                         name = gt;
 581                 mv_pk3[i] = strzone(name);
 582                 mv_desc[i] = strzone(ReadString());
 583         }
 584         else
 585         {
 586                 int type = MapInfo_Type_FromString(gt);
 587                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 588                 mv_desc[i] = MapInfo_Type_Description(type);
 589         }
 590 }
 591
 592 void MapVote_Init()
 593 {
 594         precache_sound ("misc/invshot.wav");
 595
 596         mv_active = 1;
 597         if(autocvar_hud_cursormode) { setcursormode(1); }
 598         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 599         mv_selection = -1;
 600         mv_selection_keyboard = 0;
 601
 602         string s;
 603         for(n_ssdirs = 0; ; ++n_ssdirs)
 604         {
 605                 s = ReadString();
 606                 if(s == "")
 607                         break;
 608                 if(n_ssdirs < NUM_SSDIRS)
 609                         ssdirs[n_ssdirs] = s;
 610         }
 611         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 612
 613         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 614         mv_abstain = ReadByte();
 615         if(mv_abstain)
 616                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 617         mv_detail = ReadByte();
 618
 619         mv_ownvote = -1;
 620         mv_timeout = ReadCoord();
 621
 622         gametypevote = ReadByte();
 623
 624         if(gametypevote)
 625         {
 626                 mapvote_chosenmap = strzone(ReadString());
 627                 if ( gametypevote == 2 )
 628                         gametypevote = 0;
 629
 630                 gtv_text_size = hud_fontsize*1.4;
 631                 gtv_text_size_small = hud_fontsize*1.1;
 632         }
 633
 634         MapVote_ReadMask();
 635         int i;
 636         for(i = 0; i < mv_num_maps; ++i )
 637                 mv_flags_start[i] = mv_flags[i];
 638
 639         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 640         mv_pk3list = world; // I'm still paranoid!
 641
 642         for(i = 0; i < mv_num_maps; ++i)
 643         {
 644                 mv_votes[i] = 0;
 645
 646                 if ( gametypevote )
 647                         GameTypeVote_ReadOption(i);
 648                 else
 649                         MapVote_ReadOption(i);
 650         }
 651
 652         for(i = 0; i < n_ssdirs; ++i)
 653                 ssdirs[n_ssdirs] = string_null;
 654         n_ssdirs = 0;
 655 }
 656
 657 void MapVote_SendChoice(float index)
 658 {
 659         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 660 }
 661
 662 int MapVote_MoveLeft(int pos)
 663 {
 664         int imp;
 665         if ( pos < 0 )
 666                 imp = mv_num_maps - 1;
 667         else
 668                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 669         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 670                 imp = MapVote_MoveLeft(imp);
 671         return imp;
 672 }
 673 int MapVote_MoveRight(int pos)
 674 {
 675         int imp;
 676         if ( pos < 0 )
 677                 imp = 0;
 678         else
 679                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 680         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 681                 imp = MapVote_MoveRight(imp);
 682         return imp;
 683 }
 684 int MapVote_MoveUp(int pos)
 685 {
 686         int imp;
 687         if ( pos < 0 )
 688                 imp = mv_num_maps - 1;
 689         else
 690         {
 691                 imp = pos - mv_columns;
 692                 if ( imp < 0 )
 693                 {
 694                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 695                         if ( imp >= mv_num_maps )
 696                                 imp -= mv_columns;
 697                 }
 698         }
 699         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 700                 imp = MapVote_MoveUp(imp);
 701         return imp;
 702 }
 703 int MapVote_MoveDown(int pos)
 704 {
 705         int imp;
 706         if ( pos < 0 )
 707                 imp = 0;
 708         else
 709         {
 710                 imp = pos + mv_columns;
 711                 if ( imp >= mv_num_maps )
 712                         imp = imp % mv_columns;
 713         }
 714         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 715                 imp = MapVote_MoveDown(imp);
 716         return imp;
 717 }
 718
 719 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 720 {
 721         float imp;
 722
 723         if (!mv_active)
 724                 return false;
 725
 726         if(bInputType == 3)
 727         {
 728                 mv_mousepos.x = nPrimary;
 729                 mv_mousepos.y = nSecondary;
 730                 mv_selection_keyboard = 0;
 731                 return true;
 732         }
 733
 734         if (bInputType != 0)
 735                 return false;
 736
 737         if ('0' <= nPrimary && nPrimary <= '9')
 738         {
 739                 imp = nPrimary - '0';
 740                 if (imp == 0) imp = 10;
 741                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 742                 return true;
 743         }
 744         switch(nPrimary)
 745         {
 746                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 747                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 748                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 749                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 750                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 751                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 752                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 753                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 754                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 755                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 756
 757                 case K_RIGHTARROW:
 758                         mv_selection_keyboard = 1;
 759                         mv_selection = MapVote_MoveRight(mv_selection);
 760                         return true;
 761                 case K_LEFTARROW:
 762                         mv_selection_keyboard = 1;
 763                         mv_selection = MapVote_MoveLeft(mv_selection);
 764                         return true;
 765                 case K_DOWNARROW:
 766                         mv_selection_keyboard = 1;
 767                         mv_selection = MapVote_MoveDown(mv_selection);
 768                         return true;
 769                 case K_UPARROW:
 770                         mv_selection_keyboard = 1;
 771                         mv_selection = MapVote_MoveUp(mv_selection);
 772                         return true;
 773                 case K_KP_ENTER:
 774                 case K_ENTER:
 775                 case K_SPACE:
 776                         if ( mv_selection_keyboard )
 777                                 MapVote_SendChoice(mv_selection);
 778                         return true;
 779         }
 780
 781         if (nPrimary == K_MOUSE1)
 782         {
 783                 mv_selection_keyboard = 0;
 784                 mv_selection = mv_mouse_selection;
 785                 if (mv_selection >= 0)
 786                 {
 787                         imp = min(mv_selection + 1, mv_num_maps);
 788                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 789                         return true;
 790                 }
 791         }
 792
 793         return false;
 794 }
 795
 796 void MapVote_UpdateMask()
 797 {
 798         MapVote_ReadMask();
 799         mv_top2_time = time;
 800 }
 801
 802 void MapVote_UpdateVotes()
 803 {
 804         int i;
 805         for(i = 0; i < mv_num_maps; ++i)
 806         {
 807                 if(mv_flags[i] & GTV_AVAILABLE)
 808                 {
 809                         if(mv_detail)
 810                                 mv_votes[i] = ReadByte();
 811                         else
 812                                 mv_votes[i] = 0;
 813                 }
 814                 else
 815                         mv_votes[i] = -1;
 816         }
 817
 818         mv_ownvote = ReadByte()-1;
 819 }
 820
 821 void Ent_MapVote()
 822 {
 823         int sf = ReadByte();
 824
 825         if(sf & 1)
 826                 MapVote_Init();
 827
 828         if(sf & 2)
 829                 MapVote_UpdateMask();
 830
 831         if(sf & 4)
 832                 MapVote_UpdateVotes();
 833 }
 834
 835 void Net_MapVote_Picture()
 836 {
 837         int type = ReadByte();
 838         mv_preview[type] = true;
 839         mv_pics[type] = strzone(ReadPicture());
 840 }